;** Rm_0033  *******************************************************************
;* Relacao de Frete por Notas Fiscais por Transportador                        *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 14/05/2013 por Bruno Carvalho
;Ultima Alteracao: 12/11/2014 por Andrey Fillipe
;Motivo Alteracao: Comentado na ask do TITULOS e da DUPLIC "Descricao Plano_Conta"
;Ultima Alteracao: 17/11/2014 por Kamila Gomes
;Motivo Alteracao: Ajustes para pegar lanctos CTAREC e CTAPAG com vencto no periodo
;Ultima Alteracao: 24/06/2016 por Kamila Gomes
;Motivo Alteracao: Ajustes Ask, quando Answer ‚ vazia deve manter a estrutura
;Ultima Alteracao: 10/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll
    
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") 
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter 
        Moveto [Codigo da Empresa       ] Check TypeIn "~VSDGEMPRESA.."
        Moveto [Nome Fantasia Empresa   ] Check
        Moveto [Numero do Documento     ] Check
        Moveto [Serie do Documento      ] Check
        Moveto [Codigo do Documento     ] Check 
        Moveto [Tipo do Documento       ] Check 
        Moveto [Data de Emissao         ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo                  ] Check TypeIn "as CodigoC"
        Moveto [Nome Fantasia EmitDest  ] Check TypeIn "as NomeC" 
        moveto [Razao Social            ] Check
        Moveto [Frete por Conta         ] TypeIn "1"                            ;por Codigo do Emitente
        Moveto [Codigo da Transportadora] Check TypeIn "~VSDGTRANSP.."
        Moveto [Situacao                ] TypeIn "Not C"
        Moveto [Valor do Frete          ] Check TypeIn "as Valor"
        Do_It!
        ClearAll   

        ;If IsEmpty("Answer")
        ;   Then Return
        ;EndIf

        ;*** Verificando o Transportador ***************************************
        {Ask} {Answer} Check 
        Moveto [Codigo da Transportadora] Example "CodT"  
        {Ask} {\\Sistemas\\Vendas\\Transpor}
        Moveto [Codigo da Transportadora] Example "CodT" 
        Moveto [Codigo_Pessoa           ] Check TypeIn "as Codigo"
        Do_It!         
        ClearAll
        
        {Ask} {Answer} Check 
        Moveto [Codigo                  ] Example "CodT" 
        {Ask} {\\Sistemas\\Cadastro\\Destinat}  
        Moveto [Codigo                  ] Example "CodT"
        Moveto [Razao Social            ] Check
        Do_It!         
        ClearAll
        
        If IsEmpty("Answer")
           Then Return
        EndIf
        
        Adiciona_Dados("TODOS")
EndIf   

EndProc   ; Seleciona()

;*******************************************************************************
;* Rotina Ajusta Dados                                                         *
;*******************************************************************************
Proc Ajusta_Dados()

;*** Caixa/Banco ****************************************************** 
If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont") 
   Then {Ask} TypeIn Tabela2 Enter  
        Moveto [Codigo da Empresa       ] Example "Empr"
        Moveto [Codigo                  ] Example "CodT"
        {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter
        Moveto [Codigo da Empresa       ] Check Example "Empr"
        Moveto [Nome Fantasia Empresa   ] Check
        Moveto [Numero do Documento     ] Check
        Moveto [Serie do Documento      ] Check
        Moveto [Codigo do Documento     ] Check
        Moveto [Tipo do Documento       ] Check
        Moveto [Data                    ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM ,as Data de Emissao"
        Moveto [Codigo do EmitDest      ] Check Example "CodT ,as CodigoC"
        Moveto [Nome Fantasia EmitDest  ] Check TypeIn "as NomeC"
        Moveto [Razao Social            ] Check 
        Moveto [Descricao Plano_Conta   ] TypeIn "..DIANTAMENTO..RANSP.."
        Moveto [Valor                   ] Check
        Moveto [Descricao da Conta      ] Check TyPeIn "as Tipo"
        Do_It!         
        ClearAll                
        
        If Not IsEmpty("Answer")
           Then Adiciona_Dados("CTACOR")
        EndIf  
EndIf

;*** Contas a Pagar *************************************************** 
If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos") 
   Then {Ask} TypeIn Tabela Enter  
        Moveto [Codigo da Empresa       ] Example "Empr"
        Moveto [Codigo                  ] Example "CodT"           
        {Ask} {\\Sistemas\\Ctapag\\Titulos}
        Moveto [Codigo da Empresa       ] Check Example "Empr"
        Moveto [Nome Fantasia Empresa   ] Check
        Moveto [Numero do Documento     ] Check
        Moveto [Serie do Documento      ] Check
        Moveto [Codigo do Documento     ] Check
        Moveto [Tipo do Documento       ] Check        
        Moveto [Data de Emissao         ] Check 
        Moveto [Codigo do Emitente      ] Check Example "CodT ,as CodigoC"
        Moveto [Nome Fantasia EmitDest  ] Check TypeIn "as NomeC"
        Moveto [Data de Vencimento      ] Check TypeIn "<=~VSDGDTFIM"
        Moveto [Razao Social            ] Check   
        Moveto [Saldo do Documento      ] Check TypeIn "> 0.01 ,as Valor" 
        ;Moveto [Descricao Plano_Conta   ] TypeIn "..BITO..RANS.."               ;Debito
        Do_It!         
        ClearAll
        
        If Not IsEmpty("Answer")
          Then Adiciona_Dados("CTAPAG")
        EndIf  
EndIf               

;*** Contas a Receber ************************************************* 
If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") 
   Then {Ask} TypeIn Tabela Enter  
        Moveto [Codigo da Empresa       ] Example "Empr"
        Moveto [Codigo                  ] Example "CodT"           
        {Ask} {\\Sistemas\\Ctarec\\Duplic}
        Moveto [Codigo da Empresa       ] Check Example "Empr"
        Moveto [Nome Fantasia Empresa   ] Check
        Moveto [Numero do Documento     ] Check
        Moveto [Serie do Documento      ] Check
        Moveto [Codigo do Documento     ] Check
        Moveto [Tipo do Documento       ] Check        
        Moveto [Data de Emissao         ] Check         
        Moveto [Codigo do Destinatario  ] Check Example "CodT ,as CodigoC"
        Moveto [Nome Fantasia EmitDest  ] Check TypeIn "as NomeC"
        Moveto [Data de Vencimento      ] Check TypeIn "<=~VSDGDTFIM"
        Moveto [Razao Social            ] Check   
        Moveto [Saldo do Documento      ] Check TypeIn "> 0.01 ,as Valor" 
        ;Moveto [Descricao Plano_Conta   ] TypeIn "..DITO..RANS.."               ;Credito
        Do_It!         
        ClearAll        
                              
        If Not IsEmpty("Answer")
          Then Adiciona_Dados("CTAREC")
        EndIf      
EnDIf

EndProc ;Ajusta_Dados()

;*******************************************************************************
;* Rotina Ajusta Dados                                                         *
;*******************************************************************************
Proc Adiciona_Dados(PARAM)
Private PARAM
ClearAll

Switch
  Case PARAM="TODOS"  : PARAM="Total"
  Case PARAM="CTACOR" : PARAM="Adiantamento"
  Case PARAM="CTAPAG" : PARAM="Debito"  
  Case PARAM="CTAREC" : PARAM="Credito"          
EndSwitch   

{Ask} {Answer}
Moveto [Codigo da Empresa       ] Example "Empre"
Moveto [Nome Fantasia Empresa   ] Example "NFEmp"
Moveto [Numero do Documento     ] Example "Docto"
Moveto [Serie do Documento      ] Example "Serie"
Moveto [Codigo do Documento     ] Example "CodD" 
Moveto [Tipo do Documento       ] Example "TipD" 
Moveto [Data de Emissao         ] Example "DataE"
If PARAM="Credito" Or PARAM="Debito"
   Then Moveto [Data de Vencimento] Example "DataV"
EndIf
Moveto [CodigoC                 ] Example "CC"
Moveto [NomeC                   ] Example "NC"

If PARAM="Total"
   Then Moveto [Codigo          ] Example "Codig"
EndIf   

Moveto [Razao Social            ] Example "RazS"
Moveto [Valor                   ] Example "Valor"

{Ask} TypeIn Tabela2 Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa       ] Example "Empre"
Moveto [Nome Fantasia Empresa   ] Example "NFEmp"
Moveto [Numero do Documento     ] Example "Docto"
Moveto [Serie do Documento      ] Example "Serie"
Moveto [Codigo do Documento     ] Example "CodD" 
Moveto [Tipo do Documento       ] Example "TipD" 
Moveto [Data de Emissao         ] Example "DataE"
If PARAM="Credito" Or PARAM="Debito"
   Then Moveto [Data de Vencimento] Example "DataV"
EndIf
Moveto [CodigoC                 ] Example "CC"
Moveto [NomeC                   ] Example "NC"

If PARAM="Total"
   Then Moveto [Codigo          ] Example "Codig"
EndIf   

Moveto [Razao Social            ] Example "RazS"
Moveto [Valor                   ] Example "Valor"
Moveto [Tipo                    ] TyPeIn "~PARAM"
Do_It!
ClearAll

EndProc ;Adiciona_Dados()

;*******************************************************************************
;* Rotina p/ Cabecalho                                                         *
;*******************************************************************************
Proc Cabecalho()

pag=pag+1

Print File ARQIMP CI_10CPP
Print File ARQIMP CI_6LPP
Print File ARQIMP "\n\n"

Print File ARQIMP "  "+Fill("-",78)+"\n"
Print File ARQIMP "  "+COMPLETA(NOMEMPRESA,37," ")+"Emissao.: "+
                  AlinhM(LTrim(Format("D13",Today())),10)+"-"+
                  AlinhM(LTrim(Time()),8)+"  Pag.: "+Format("W4,EIC",pag)+"\n"
Print File ARQIMP "  "+Fill("-",78)+"\n\n"

;Documento    DtEmissao   Cliente                    Valor Frete 
;-----------  ----------  -------------------------  ------------ 
;AAAA AAAAAA  AA/AA/AAAA  AAAA AAAAAAAAAAAAAAAAAAAA  A.AAA.AAA,AA 

Print File ARQIMP Format("W80,AC","Transportadora Acerto de "+StrVal(VSDGDTINI)+" ate "+StrVal(VSDGDTFIM))+"\n\n"
Print File ARQIMP "  Documento    DtEmissao   Cliente                    Valor Frete   DtVencto  "+"\n"
Print File ARQIMP "  -----------  ----------  -------------------------  ------------  ----------"+"\n"
                   
Print File ARQIMP "\027E"+"  Empresa: "+VSDGEMPRESA+" "+VSDGNOMEMP+"\027F"+"\n"
Print File ARQIMP "\027E"+"  Transp.: "+VSDGTRANSP+" "+VSDGNOMTRANSP+"\027F"+"\n\n"                       

Linha=4

EndProc   ; (Cabecalho)

;*******************************************************************************
;* Rotina p/ Fretes                                                            *
;*******************************************************************************
Proc Relacao()

CODEMP   = "*****"
CONT_CDA = 1
TOTF     = 0
pag      = 0

If Not IsAssigned(NOMEMPRESA) Then NOMEMPRESA="" EndIf

Cabecalho()

Sort Tabela2 On "Tipo"  

Scan For [Tipo]="Total"
  ;*** Se futuramente liberar para mais de uma empresa ************************* 
  If CODEMP<>[Codigo da Empresa] And CODEMP<>"*****"
     Then ;*** Imprimir Credito/Debito/Adiantamento Antes de Alterar Empresa ***
          Cred_Deb_Ad()
          Print File ARQIMP "\f"
          Cabecalho()
  EndIf  
  
  ;*** Imprimir a Empresa e o Transportador s˘ na primeira p gina **************
  If CODEMP<>[Codigo da Empresa]
     Then CODEMP=[Codigo da Empresa]
          ;Print File ARQIMP "\027E"+"  Empresa: "+CODEMP+" "+[Nome Fantasia Empresa]+"\027F"+"\n"
          ;Print File ARQIMP "\027E"+"  Transp.: "+VSDGTRANSP+" "+VSDGNOMTRANSP+"\027F"+"\n\n"          
  EndIf                                     
  
  Print File ARQIMP "  "+Format("W4",[Tipo do Documento])+" "+Format("W6",[Numero do Documento])+Spaces(2)
  Print File ARQIMP ""+Format("D13",[Data de Emissao])+Spaces(2)
  Print File ARQIMP ""+Format("W4",[CodigoC])+" "+Format("W20",[NomeC])+Spaces(2)
  Print File ARQIMP ""+Format("W12.2,EIC",[Valor])+"\n"

  Linha = Linha + 1
  If Linha >= 57
     Then Print File ARQIMP "\f" 
          Cabecalho()
  EndIf   
  
  TOTF = TOTF + [Valor]                             
EndScan
ClearAll

Cred_Deb_Ad()             
             
EndProc   ;Relacao() 

;*******************************************************************************
;* Rotina Imprimir Credito/Debito/Adiantamento                                 *
;*******************************************************************************
Proc Cred_Deb_Ad()

TITC = ""
TITD = ""
TITA = ""

TOTC = 0
TOTD = 0
TOTA = 0

;**** Credito ******************************************************************
Sort Tabela2 On "Tipo"  
Scan for [Tipo]="Credito"
  If CODEMP<>[Codigo da Empresa] Then Loop EndIf
  If TITC="" 
     Then Print File ARQIMP "\n"
          Print File ARQIMP "\027E"+"  ->      Credito:"+"\027F"+"\n" 
          TITC="Credito"
          Linha = Linha + 2
  EndIf  
  Print File ARQIMP "  "+Format("W4",[Tipo do Documento])+" "+Format("W6",[Numero do Documento])+Spaces(2)
  Print File ARQIMP ""+Format("D13",[Data de Emissao])+Spaces(29)
  Print File ARQIMP ""+Format("W12.2,EIC",[Valor])+Spaces(2)
  Print File ARQIMP ""+Format("D13",[Data de Vencimento])+"\n"
  TOTC = TOTC + [Valor]
  
  Linha = Linha + 1
  If Linha >= 57
     Then Print File ARQIMP "\f"
          Cabecalho()
          TITC=""
  EndIf   
  
EndScan
ClearAll

;**** Debito *******************************************************************   
Sort Tabela2 On "Tipo"  
Scan for [Tipo]="Debito"
  If CODEMP<>[Codigo da Empresa] Then Loop EndIf
  If TITD="" 
     Then Print File ARQIMP "\n"
          Print File ARQIMP "\027E"+"  ->       Debito:"+"\027F"+"\n" 
          TITD="Debito"
          Linha = Linha + 2
  EndIf
  Print File ARQIMP "  "+Format("W4",[Tipo do Documento])+" "+Format("W6",[Numero do Documento])+Spaces(2)
  Print File ARQIMP ""+Format("D13",[Data de Emissao])+Spaces(29)
  Print File ARQIMP ""+Format("W12.2,EIC",[Valor])+Spaces(2)
  Print File ARQIMP ""+Format("D13",[Data de Vencimento])+"\n"
  TOTD = TOTD + [Valor]
  
  Linha = Linha + 1
  If Linha >= 57
     Then Print File ARQIMP "\f"
          Cabecalho()
          TITD=""
  EndIf   
    
EndScan
ClearAll

;**** Adiantamento *************************************************************
Sort Tabela2 On "Tipo"  
Scan for [Tipo]="Adiantamento"
  If CODEMP<>[Codigo da Empresa] Then Loop EndIf
  If TITA="" 
     Then Print File ARQIMP "\n"
          Print File ARQIMP "\027E"+"  -> Adiantamento:"+"\027F"+"\n" 
          TITA="Adiantamento"
          Linha = Linha + 2
  EndIf                              
  Print File ARQIMP "  "+Format("W4",[Tipo do Documento])+" "+Format("W6",[Numero do Documento])+Spaces(2)
  Print File ARQIMP ""+Format("D13",[Data de Emissao])+Spaces(2)
  Print File ARQIMP ""+Format("W12.2,EIC",[Valor])+"\n"
  TOTA = TOTA + [Valor]
  
  Linha = Linha + 1
  If Linha >= 57
     Then Print File ARQIMP "\f"
          Cabecalho()
          TITA=""
  EndIf     
EndScan
ClearAll

;**** Totalizador **************************************************************
Linha = Linha + 8 
If Linha >= 57
   Then Print File ARQIMP "\f"
        Cabecalho()
EndIf   

NEG="\027E"
NOR="\027F"

Print File ARQIMP "\n\n" 
Print File ARQIMP " "+Fill("=",80)+"\n" 
Print File ARQIMP NEG+"  (F)"+NOR+" Total Frete   = "+Format("W17.2,EIC",TOTF)+"\n" 
Print File ARQIMP NEG+"  (C)"+NOR+" Total Credito = "+Format("W17.2,EIC",TOTC)+"\n"
Print File ARQIMP NEG+"  (D)"+NOR+" Total Debito  = "+Format("W17.2,EIC",TOTD)+"\n"
Print File ARQIMP NEG+"  (A)"+NOR+" Total Adiant  = "+Format("W17.2,EIC",TOTA)+"\n\n"

Print File ARQIMP "  TOTAL "+NEG+"(F)"+NOR+"-"+NEG+"(C)"+NOR+"+"+NEG+"(D)"+NOR+"-"+NEG+"(A)"+NOR+" = "
Print File ARQIMP Format("W13.2,EIC",(TOTF - TOTC + TOTD - TOTA))+"\n" 
Print File ARQIMP " "+Fill("=",80)+"\n" 

EndProc ;Cred_Deb_Ad()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""      
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_TRANSP"        : Campo="TG_EMPRESA"
            Case Campo="TG_DTINI"         : Campo="TG_TRANSP"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_TRANSP"
                         If IsBlank(VSDGEMPRESA) 
                            Then Campo="TG_EMPRESA" 
                                 VSDGNOMEMP="" 
                         EndIf
                    Case Campo="TG_TRANSP"  : Campo="TG_DTINI"
                         If IsBlank(VSDGTRANSP) 
                            Then Campo="TG_TRANSP"
                                 VSDGNOMTRANSP=""
                         EndIf   
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_EMPRESA":
     MSG_CAMPO="Informe a Empresa !"
  Case Campo="TG_TRANSP":
     MSG_CAMPO="Informe o Transportador !"     
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

ArqImp=PrivDir()+"RM_0033.TXT"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

VSDGEMPRESA =""
VSDGTRANSP  =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Transportadora Acerto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 06,12   Height 11 Width 72                                                            
                                                                                 
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Transportadora"  For "TG_TRANSP"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_TRANSP"    To VSDGTRANSP
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTRANSP" To VSDGNOMTRANSP            
            
    Label  @ 04,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM    

    Pushbutton @ 07,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  If IsBlank(VSDGDTINI)
     Then Mensagem("Data Inicial inv lida !")
          Loop
  EndIf   

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final inv lida !")
          Loop
  EndIf   

  AGUARDE("Aguarde, gerando o relat˘rio")
  Tabela2=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Vendas\\RM_0033" Tabela2  
  
  Tabela=Cria_Temp(PrivDir())
  
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    
    If Not IsTable("Answer") Then Loop EndIf
    
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile
  
  Ajusta_Dados()

  If IsEmpty(Tabela2)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Delete Tabela2
          Loop
  EndIf

  Relacao()
  ImpriArq(ARQIMP)
  
  ;CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0033" "R" Tabela "R"

  ;IMPRIREL(Tabela,"R")

  Delete Tabela
  Delete Tabela2  

EndWhile
ClearAll
Release Vars All
Release Procs All
