;** Rm_0120 ********************************************************************
;*  Emissao dos Titulos Recebidos por Conta                                    *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 12/11/2009 por Bruno Carvalho
;Motivo Alteracao: Adiconado "Op‡Æo de Relat¢rio"
;Ultima Alteracao: 05/05/2014 por Bruno Carvalho
;Motivo Alteracao: Ajustes para incluir no relatorio/excel apenas os campos necess rios  
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado filtro por DATA (Vencimento ou Pagamento)
;Ultima Alteracao: 01/11/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro por DATA (Vencimento ou Pagamento)
;Ultima Alteracao: 04/11/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro por DATA    
;Ultima Alteracao: 11/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado modelo 01B  #0274
;Ultima Alteracao: 10/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0120A" (71) neste script "RM_0120" (11)              

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa")
   Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Numero do Lancamento      ] Example "lanc"
        Moveto [Codigo da Empresa         ] TypeIn "~VSDGEMPRESA.."
        Moveto [Codigo do Representante   ] TypeIn "~VSDGREPRESEN.."
        Switch
          Case VSDGOPDT="V" :
               Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDT="E" :
               Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
        If VSDGCODMODELO = "71"  
           Then Moveto [Saldo do Documento] TypeIn ">=0.01"
        EndIf   
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
        Moveto [Numero do Lancamento] Example "lanc"
        If VSDGOPDT="P"
           Then Moveto [Data do Pagamento ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndIf
        Moveto [Codigo da Conta     ] TypeIn "~VSDGCONTA.."
        Moveto [Tipo da Baixa       ] TypeIn "Blank or NORMAL"
        Do_It!
        ClearAll                
EndIf

EndProc ;Seleciona()

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

Coedit Tabela
Scan
  [Valor do Desconto-1]=([Valor do Desconto-1]*-1)+[Valor do Juros]
  If IsBlank([Valor do Desconto-1]) Then [Valor do Desconto-1]=0 EndIf
  If IsBlank([Valor do Juros Devidos]) Then [Valor do Juros Devidos]=0 EndIf
EndScan
Do_It!
ClearAll

EndProc  ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESA" 
            Case Campo="TG_CONTA"         : Campo="TG_REPRESEN"
            Case Campo="TG_OPDT"          : Campo="TG_CONTA"
            Case Campo="TG_DTINI"         : Campo="TG_OPDT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"       : Campo="TG_REPRESEN" 
                    Case Campo="TG_REPRESEN"      : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"         : Campo="TG_OPDT"
                    Case Campo="TG_OPDT"          : Campo="TG_DTINI"
                         VSDGOPDT=ControlValue("TG_OPDT")
                         Switch 
                           Case VSDGOPDT="V" : VSDGDESCOPDT="DATA DE VENCIMENTO" 
                           Case VSDGOPDT="E" : VSDGDESCOPDT="DATA DE EMISSAO"
                           OtherWise         : VSDGOPDT="P" 
                                               VSDGDESCOPDT="DATA DE PAGAMENTO"                    
                         EndSwitch
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_OPDT":
     MSG_CAMPO="Op‡„o: P=Pagamento  E=EmissÆo  V=Vencimento "
Endswitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Data de Pagamento")                                              ;"RM_0120"
ModeloRelatoriosAdd("01B Data de Pagamento + Juros Devido")                              ;"RM_0120"
ModeloRelatoriosAdd("02  Data de Pagamento - Por Ordem de Tipo/N£mero do Documento")     ;"RM_0120"
ModeloRelatoriosAdd("71  Data de Emissao")                                               ;"RM_0120A"
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA = ""
VSDGCONTA   = ""
VSDGDTINI   = BlankDate()
VSDGDTFIM   = BlankDate()
VSDGDTREF   = Today()

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos Recebidos por Conta" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
    
    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR
    
    Label  @ 04,00 "Conta"  For "TG_CONTA"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 06,00 "Op‡äes de Datas" For "TG_OPDT"
    Accept @ 07,04 Width 04 "A1"  Picture "P,V,E" Tag "TG_OPDT" To VSDGOPDT
    Accept @ 07,09 Width 25 "A20"  Picture "!*!" Tag "TG_DESCOPDT" To VSDGDESCOPDT

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
  
    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  
  If Not IsEmpty(Tabela) And (VSDGCODMODELO="01" Or VSDGCODMODELO="02")
     Then {Ask} TypeIn Tabela Enter 
          Moveto [Codigo da Conta-1      ] Check
          Moveto [Descricao da Conta-1   ] Check
          Moveto [Codigo da Empresa      ] Check
          Moveto [Nome Fantasia Empresa  ] Check
          Moveto [Data do Pagamento      ] Check
          Moveto [Data a Receber         ] Check
          Moveto [Tipo do Documento      ] Check
          Moveto [Numero do Documento    ] Check
          Moveto [Nome Fantasia EmitDest ] Check
          Moveto [Tipo do Lancamento     ] Check
          Moveto [Descricao do Lancamento] Check
          Moveto [Valor do Recebimento   ] Check
          Moveto [Valor do Desconto-1    ] Check
          Moveto [Data de Vencimento     ] Check
          Moveto [Numero do Lancamento   ] Check
          Moveto [Sequencia da Baixa     ] Check
          Moveto [Codigo do Representante] Check
          Moveto [Descricao do Lancamento] Check
          Moveto [Tipo do Pagamento      ] Check
          Moveto [Tipo da Baixa          ] Check
          Moveto [Valor do Desconto      ] Check
          Do_It!
          ClearAll
          
          Copy "Answer" Tabela
  EndIf   
    
  switch
    case VSDGCODMODELO = "01"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010" "13" Tabela "R"
    case VSDGCODMODELO = "01B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010C" "1" Tabela "R"
    case VSDGCODMODELO = "02"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "R" Tabela "R"
    case VSDGCODMODELO = "71"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "1" Tabela "R"
  endswitch
  IMPRIREL(Tabela,"R")
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
