;** Rm_0050 *******************************************************************
;*  Emissao dos Titulos nao Pagos                                             *
;******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 25/02/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo da Baixa
;Ultima Alteracao: 08/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/07/2014 por Luis Gustavo
;Motivo Alteracao: Ajuste na data de emissao, estava pegando totdos os titulos, e nao os do periodo selecionado
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 08/06/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos") And
   IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa")
   Then {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
        Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Do_It!
        ClearAll
        If Not CriaC
           Then TabelaC=Cria_Temp(PrivDir())
                CriaC=True
        EndIf
        If IsTable(TabelaC)
           Then Add "Answer" TabelaC
           Else Rename "Answer" TabelaC
        EndIf

        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter
        Moveto [Numero do Lancamento] Example "numero"
        Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Data de Emissao     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa" Enter Check
        Moveto [Numero do Lancamento] Example "numero"
        Moveto [Tipo da Baixa       ] TypeIn "Blank or NORMAL"
        Do_It!
        ClearAll
        If Not CriaI
           Then TabelaI=Cria_Temp(PrivDir())
                CriaI=True
        EndIf
        If IsTable(TabelaI)
           Then Add "Answer" TabelaI
           Else Rename "Answer" TabelaI
        EndIf
EndIf
EndProc  ;  (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn TabelaC Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

{Ask} TypeIn TabelaC Enter TypeIn "Fast"
Moveto [Valor do Documento  ] Example "vr"
Moveto [Saldo do Documento  ] TypeIn "Changeto "  Example "vr"
Do_It!
ClearAll

Coedit TabelaI,TabelaC
Moveto [Numero do Lancamento]
Scan
   Numero=[Numero do Lancamento]
   Moveto TabelaI
   Moveto [Numero do Lancamento]
   Locate Numero
   If Not RetVal
      Then Moveto TabelaC
           Loop
   EndIf
   VRPG=0
   While [Numero do Lancamento]=Numero And Not RecordStatus("New")
     If [Data do Pagamento]<=VSDGDTFIM
        Then VRPG=VRPG+([Valor do Pagamento]+[Valor do Desconto])
     EndIf
     Down
   EndWhile
   Moveto TabelaC
   [Saldo do Documento]=[Saldo do Documento]-VRPG
EndScan
Do_It!
ClearAll

{Ask} TypeIn TabelaC Enter TypeIn "Fast Delete"
Moveto [Saldo do Documento  ] TypeIn "<=0.01"
Do_It!
ClearAll

Coedit TabelaC
Scan
   If [Data a Pagar]<VSDGDTFIM
      Then NDA=VSDGDTFIM-[Data a Pagar]
           TXM=[Multa]
      Else NDA=0
           TXM=0
   EndIf
   If [Data Limite Desconto]<=VSDGDTFIM
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)
   [Data de Vencimento]=[Data a Pagar]
EndScan
Do_It!
ClearAll
EndProc  ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA = ""
VSDGDTFIM   = BlankDate()
VSDGDTINI   = BlankDate()

While True
  ShowDialog "T¡tulos Emitidos e n„o Pagos" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 09 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Per¡odo EmissÆo de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    @ 03,35 ?? "<- NÆo pagos at‚ Data Final"


    Pushbutton @ 05,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  CriaC=False
  CriaI=False

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(TabelaC)
     Then MENSAGEM("N„o existem registros a processar")
          Delete TabelaC
          Delete TabelaI
          Loop
  EndIf
  Processa()

  CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1000" "9" TabelaC "R"

  IMPRIREL(TabelaC,"R")

  Delete TabelaC
  Delete TabelaI

EndWhile
ClearAll
Release Vars All
Release Procs All
