;** Rc_0045 *******************************************************************
;*  Relatorio de Clientes por Representante/Cidade                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 08/08/2003 por Karen Lauar Nery
;Ultima Alteracao: 11/12/2003 por Karen Lauar Nery
;Motivo Alteracao: Inclusao Status

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll
{Ask} {Destinat} Check
Moveto [Tipo                   ] TypeIn "C"
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Codigo Atividade       ] TypeIn "~VSDGATIVIDADE.."

Moveto [Cidade                 ] TypeIn CIDADE
Moveto [Inativo]
Switch
  Case VSDGSTATUS="1": TypeIn "N"
  Case VSDGSTATUS="2": TypeIn "S"
EndSwitch
Do_It!
ClearAll
EndProc ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog1(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_REPRESEN"       : Campo="NO"
            Case Campo="TG_STATUS"         : Campo="TG_REPRESEN"
            Case Campo="TG_ATIVIDADE"      : Campo="TG_STATUS"
            Case Campo="TG_CIDADE"         : Campo="TG_ATIVIDADE"
            Case Campo="YES" Or Campo="NO" : Campo="TG_REPRESEN"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_REPRESEN"     :Campo="TG_STATUS"
                    Case Campo="TG_STATUS"       :Campo="TG_ATIVIDADE"
                    Case Campo="TG_ATIVIDADE"    :Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"       :
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                         Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc
;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGSTATUS=""

While True

  ShowDialog "RelatĒrio de Clientes por Representante" Proc "SD_Dialog1"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 06,12   Height 13 Width 56

    Label  @ 00,00 "Representante"  For "TG_REPRESEN"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 02,00 "Status do Cliente" For "TG_STATUS"
    Accept @ 03,01 Width 04 "A1"  Picture "1,2,3" Tag "TG_STATUS" To VSDGSTATUS
    Accept @ 03,06 Width 23 "A12" Picture "!*!" Tag "TG_NOMSTATUS" To VSDGNOMSTATUS

    Label  @ 04,00 "Atividade Cliente" For "TG_ATIVIDADE"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_ATIVIDADE" To VSDGATIVIDADE
    Accept @ 05,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMATIV" To VSDGNOMATIV

    Label  @ 06,00 "Cidade"  For "TG_CIDADE"
    Accept @ 07,01 Width 23 "A20"  Picture "!*!" Tag "TG_CIDADE" To VSDGCIDADE

    Pushbutton @ 09,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Usuario_Vendedor() Then Loop EndIf  

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  Aguarde("Aguarde, Selecionando Registros")
  Seleciona()

  If IsEmpty("Answer")
     Then MENSAGEM("No Existem Registros a Processar")
          Loop
  EndIf

  AGUARDE("Aguarde, Gerando RelatĒrio")

  CopyReport "\\Base\\Sistemas\\Cadastro\\Rc_0040" "10" "Answer" "R"

  IMPRIREL("Answer","R")

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
