;** RO_0362 ********************************************************************
;** Imprime a Digitacao do Romaneio                    ** Limite Vertical**    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 27/02/2015 por Luis Gustavo
;Ultima Alteracao:   /  /     por 
;Motivo Alteracao:                                                   
     
;*******************************************************************************
;* ImpressÆo do Cabe‡alho                                                      *
;*******************************************************************************
Proc Cabecalho();
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf
Moveto "Faturac"
Print File ARQIMP chr(27)+chr(67)+chr(33) ;Imprime 33 Linhas por pagina
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP

Moveto "FaturaC"
Moveto [Codigo]
Ativa_Lookup()
Moveto [Codigo]
Locate [FaturaC->Codigo]
If RetVal
   Then ROTA="  "+[Codigo da Area]+" "+[Descricao da Area]
   Else ROTA="???"
EndIf
KeyPress "ESC"

Print File ARQIMP "\n"
Print File ARQIMP Spaces(48)+"Impressao: "+Format("D10",[Data de Emissao])+" - "+Time()+ "\n\n"

Print File ARQIMP "\014"
Print File ARQIMP "\027E"
Print File ARQIMP Spaces(20)+"Orcamento N§ "+Format("W06.3,AL",NOTAFISC)+"\n\n"
Print File ARQIMP "\020"

Print File ARQIMP "\027E"+"Cliente : "+Format("W05,AL",[Codigo])+Format("W46,AL",[Razao Social])+"\n"
Print File ARQIMP "\027F"

Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP

Print File ARQIMP Spaces(10)+Format("W40,AL",[Endereco])
Print File ARQIMP Format("W18,AL",[CGC])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Bairro])
Print File ARQIMP Format("W20,AL",[CEP])
Print File ARQIMP Format("W25,AL",[IE])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Cidade])
Print File ARQIMP Format("W7,AL",[UF])
Print File ARQIMP "Tel: "
Print File ARQIMP Format("W15,AL",[Telefone])

GetRecord "\\Sistemas\\Cadastro\\Destinat" [Codigo] To Cel
If RetVal And Not IsBlank(Cel["Celular"])
   Then Print File ARQIMP Spaces(01)+"Cel: "
        Print File ARQIMP Format("W15,AL",Cel["Celular"])+"\n"
   Else Print File ARQIMP "\n"
EndIf
   
Print File ARQIMP "Operacao: "
Print File ARQIMP Chr(27)+Chr(71)
Print File ARQIMP ""+[Codigo da Destinacao]+" "+[Descricao da Destinacao]+"\n"
Print File ARQIMP Chr(27)+Chr(72)

Print File ARQIMP "Vendedor: "+Format("W05,AL",[Codigo do Representante])
Print File ARQIMP Format("W25,AL",[Nome Fantasia Represent])+"\n"
Print File ARQIMP "\015"         ;Imprime 17 Caracteres por polegada

;********************* IMPRESSAO DOS ITENS ********************************
Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------------------------"+"\n"
Print File ARQIMP Spaces(02)+"Item                                                                          Un.Emb  Quant.Emb  Un  Quantidade  Unitario        Total"+"\n"
Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------------------------"+"\n"

EndProc ;(Cabecalho)

;*******************************************************************************
;* Checa linha na area de impressao dos itens                                  *
;*******************************************************************************
Proc Checa_Linha(Nl)
private nl

If (CONTADOR+nl)>(CONTA_ITENS)
   Then RodaPe(True)
        Cabecalho()
        CONTADOR=nl
        Moveto "FaturaI"
   Else CONTADOR=CONTADOR+nl
EndIf
EndProc

;*******************************************************************************
;* ImpressÆo dos Itens                                                         *
;*******************************************************************************
Proc Itens()
       
Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]

CONTA_ITENS = 0

While [Numero da OF]=[FaturaC->Numero da OF]
  CONTA_ITENS = CONTA_ITENS+1
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile

Switch
 ;Case CONTA_ITENS <= 2 : CONTA_ITENS  = 2
  Case CONTA_ITENS <=12 : CONTA_ITENS  = 12
  Case CONTA_ITENS > 12 : CONTA_ITENS  = 56 
EndSwitch

Home
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]

QUANT    = 0
TOT      = 0
CONTADOR = 0

While [Numero da OF]=[FaturaC->Numero da OF]
  Checa_Linha(1)
  
  Moveto [Codigo do Item]
  Ativa_Lookup()
  Moveto [Codigo do Item]
  Locate [FaturaI->Codigo do Item]
  If RetVal
     Then UNEMB=[Unidade Embalagem]
          If IsBlank([Fator Conversao Embalagem])
             Then FATCON=1
             Else FATCON=[Fator Conversao Embalagem]
          EndIf
     Else UNEMB=""
  EndIf
  KeyPress "ESC"
  UnlockRecord
  
  Print File ARQIMP Spaces(02)+Format("W04,AL",[Item da OF])
  Print File ARQIMP Spaces(01)+Format("W11,AL",[Codigo do Item])
  Print File ARQIMP Spaces(01)+Format("W60,AL",[Descricao do Item])
  If Not IsBlank(UNEMB)
     Then Print File ARQIMP Spaces(05)+Format("W03,Al",UNEMB)
          Print File ARQIMP Format("W10.2,EIC",([Quantidade]/FATCON))
  EndIf
  Print File ARQIMP Spaces(02)+Format("W03,Al",[Unidade Fiscal])
  Print File ARQIMP Format("W11.2,EIC",[Quantidade])
  Print File ARQIMP Format("W10.2,EIC",[Preco Unitario])
  Print File ARQIMP Format("W13.2,EIC",[Preco Total])+"\n"
  TOT    = TOT + [Preco Total]
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile

For ITEM From CONTADOR To CONTA_ITENS
    If CONTADOR = CONTA_ITENS 
       Then QuitLoop
    EndIf
    Print File ARQIMP "\n"
EndFor

Print File ARQIMP CI_8LPP
EndProc ;(Itens)

;*******************************************************************************
;* ImpressÆo do Rodap‚                                                         *
;*******************************************************************************
Proc Rodape(QUEBRAFORM)
Private QUEBRAFORM

Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------------------------"+"\n"

;********************* IMPRESSAO DOS TOTAIS **************************
Moveto "FaturaC"

Print File ARQIMP Spaces(106)+"Total.............."+Format("W11.2,EIC",TOT)+"\n"

Print File ARQIMP "          *** FAVOR MANTER O ENDERECO E O TELEFONE ATUALIZADOS ***"
Print File ARQIMP Spaces(40)+"Desconto"+Format("W06.2,EIC",[Taxa de Desconto]) + "%..."
Print File ARQIMP Format("W12.2,EIC",[Valor Desconto])+"\n"

Print File ARQIMP Spaces(106)+"DespAces..........."+Format("W11.2,EIC",[Valor Despesas Acessorias])+"\n"
Print File ARQIMP Spaces(106)+"Total Liquido......"+Format("W11.2,EIC",([Valor Mercadoria Liquido]+[Valor Despesas Acessorias]))+"\n\n"

Print File ARQIMP "Cond. Pagto: "+[Descricao CondPagto]
Print File ARQIMP "   NP: "+StrVal([Numero de Parcelas])
Print File ARQIMP "   CD: "+[Composicao de Dias]+"\n"
                              
Print File ARQIMP "OBS.: "
Print File ARQIMP Format("W75,AL",SubStr([Observacao na Nota Fiscal],001,73))+"\n\n"
;********************* IMPRESSAO DOS VENCIMENTOS **************************
Print File ARQIMP "\027E"
Print File ARQIMP "Vencimentos: "

Array DATA[9]
Array VALOR[9]
K=0
KV=0
Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
  K=K+1
  DATA[K]  = Format("D13",[Data])
  VALOR[K] = Format("W10.2,AR,EIC",[Valor])
  If K=9
     Then VENC()
          K=0
  EndIf
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile
If K>0
   Then VENC()
EndIf

Print File ARQIMP "\n"
Print File ARQIMP "\027F"

If QUEBRAFORM
   Then Print File ARQIMP "\n\n\n\n\n"
   Else Print File ARQIMP Spaces(38)+"   /   /     -                                   " + "\n"
        Print File ARQIMP Spaces(38)+"-------------------------------------------------" + "\n"
        Print File ARQIMP Spaces(38)+"              Data e Assinatura"+"\n"
        Print File ARQIMP "\n\n"
        Print File ARQIMP CI_6LPP
        Print File ARQIMP CI_10CPP
EndIf   

EndProc ;Rodape

;*******************************************************************************
;* Rotina de Impressao dos Vencimentos                                         *
;*******************************************************************************
Proc VENC()
If KV>0
   Then Print File ARQIMP Spaces(13)
EndIf

If IMPRIMINDO_PARCELAS
   Then Print File ARQIMP DATA[NP]+Spaces(02)+"\n"
        Print File ARQIMP Spaces(13)+VALOR[NP]+Spaces(02)+"\n\n"
        return
EndIF

For I From 1 to K
  Print File ARQIMP DATA[I]+Spaces(02)
EndFor
Print File ARQIMP "\n"
Print File ARQIMP Spaces(13)
For I From 1 to K
  Print File ARQIMP VALOR[I]+Spaces(02)
EndFor
Print File ARQIMP "\n\n"

KV=KV+1
EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
ArqImp=PrivDir()+"Ro_0362.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)

For Wc From 1 To 2 

  IMPRIMINDO_PARCELAS=FALSE
  NParc=[FaturaC->Numero de Parcelas]
  If NParc<1 Then NParc=1 EndIf

  For NP From 1 to NParc
    If [FaturaV->Forma de Pagamento]="NP"
       Then IMPRIMINDO_PARCELAS=TRUE
    EndIf
    Cabecalho()
    Itens()
    Rodape(False) 
    If IMPRIMINDO_PARCELAS=False Then QuitLoop EndIf
  EndFor

  If CONTA_ITENS = 12 And Wc = 2
     Then ;Print File ARQIMP "\f"
     Else If CONTA_ITENS = 56 And Wc = 1
             Then Print File ARQIMP "\f"
          EndIf
  EndIf
  
EndFor
NUMCOPIA=1
ImpriArq(ARQIMP)

Release Vars VALOR,DATA
Release Procs IMPFAT,VENC
LIMPAGUARDE()
