;** Rp_0102 ********************************************************************
;*  Recibo de Pagamento                                                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 08/07/2010 por Bruno Carvalho
;Ultima Alteracao:   /  /     por 
;Motivo Alteracao: 

;*******************************************************************************
;* Rotina para impressao do recibo de pagamento                             ****
;*****************+*************************************************************
Proc IMPRP()

If clieant<>[Duplic->Codigo do Destinatario]
   Then If clieant<>"****"
           Then Rodape()
        EndIf   
        clieant=[Duplic->Codigo do Destinatario]
        VR_RECIBO=0
        Cabecalho()
EndIf   
ITENS()

If ULTIMA_BAIXA 
   Then RODAPE()
EndIF

EndProc ;IMPRP()

;*******************************************************************************
;* Cabe‡alho                                                                   *
;*******************************************************************************
Proc CABECALHO()

Print File ARQIMP EPSON_FONTE_MENOR
Print File ARQIMP Fill("=",64)+"\n"

GetRecord "\\Sistemas\\Cadastro\\Destinat" [Duplic->Codigo do Destinatario] TO REG_DESTINAT
If Retval
   Then ENDERECO = REG_DESTINAT["Endereco"]
        BAIRRO   = REG_DESTINAT["Bairro"  ]
        CIDADE   = REG_DESTINAT["Cidade"  ]
        UF       = REG_DESTINAT["UF"      ]
        FONE     = REG_DESTINAT["Telefone"]
        CEP      = REG_DESTINAT["CEP"     ]  
   Else ENDERECO = ""
        BAIRRO   = ""
        CIDADE   = ""
        UF       = ""
        FONE     = ""
        CEP      = ""
EnDIf

TIT = ""
Switch
  Case [DupBaixa->Tipo da Baixa]="NORMAL"   : TIT = "RECIBO DE PAGAMENTO"
  Case [DupBaixa->Tipo da Baixa]="DEVOLUCAO": TIT = "RECIBO DE DEVOLUCAO"
  Case [DupBaixa->Tipo da Baixa]="CANCELADO": TIT = "RECIBO DE CANCELAMENTO"
EndSwitch
Print File ARQIMP Format("W64,AR",TIT+Spaces(3)+"EMISSAO: "+Format("D13",Today())+"-"+Time())+"\n"

Print File ARQIMP Fill("-",64)+"\n"
Print File ARQIMP "EMITIDO PARA CONTROLE INTERNO NAO TEM VALOR FISCAL"+"\n"
Print File ARQIMP Fill("-",64)+"\n"
Print File ARQIMP EPSON_NEG_ON + "CLIENTE..: " + EPSON_NEG_OFF  
Print File ARQIMP                 Format("W04,AL",[Duplic->Codigo do Destinatario])+"-"+
                                  Format("W20,AL",[Duplic->Nome Fantasia EmitDest])+Spaces(5)+
                                  Format("W20,AL",FONE)+"\n"
Print File ARQIMP "           " + Format("W40,AL",ENDERECO)+"\n"
Print File ARQIMP "           " + BAIRRO+Spaces(5)+CEP+Spaces(5)+CIDADE+"/"+UF+"\n"

Print File ARQIMP Spaces(01)+"                       --------------- Valores ---------------\n"
Print File ARQIMP Spaces(01)+"N Lanc.  Documento      Original Juro/Mult  Desconto     Total\n"
Print File ARQIMP Spaces(01)+"-------- ------------- --------- --------- --------- ---------\n"
 
EndProc ;CABECALHO()

;*******************************************************************************
;* Impressao dos Itens                                                         *
;*******************************************************************************
Proc ITENS()

Print File ARQIMP Spaces(01)+Format("W06,AL",[Duplic->Numero do Lancamento])
Print File ARQIMP Spaces(03)+Format("W10,AL",[Duplic->Numero do Documento])
Print File ARQIMP "-"+[Sequencia da Baixa]
Print File ARQIMP Format("W11.2,EIC",([Valor do Recebimento]+[Valor do Desconto])-[Valor do Juros])
Print File ARQIMP Format("W10.2,EIC",[Valor do Juros])
Print File ARQIMP Format("W10.2,EIC",[Valor do Desconto])
Print File ARQIMP Format("W10.2,EIC",[Valor do Recebimento])+"\n"

VR_RECIBO=VR_RECIBO+[Valor do Recebimento]
        
EndProc ;ITENS()

;*******************************************************************************
;* Impressao dos Rodap‚                                                        *
;*******************************************************************************
Proc RODAPE()

TIT = ""
Switch
  Case [DupBaixa->Tipo da Baixa]="NORMAL"    : TIT = Spaces(03)+"Valor Recebido: "
  Case [DupBaixa->Tipo da Baixa]="DEVOLUCAO" : TIT = Spaces(03)+"Valor Devolvido: "
  Case [DupBaixa->Tipo da Baixa]="CANCELADO" : TIT = Spaces(03)+"Valor Cancelado: "
EndSwitch

Print File ARQIMP Fill("-",64)+"\n"
Print File ARQIMP Format("W50,AR",("Data do Pagamento: "+Format("D13",[Data do Pagamento])+TIT))
Print File ARQIMP EPSON_NEG_ON+Format("W13,AR",Format("W13.2,EIC",NumVal(VR_RECIBO)))+EPSON_NEG_OFF+"\n"
Print File ARQIMP Fill("=",64)

If Not ULTIMA_BAIXA
   THEN PRINT FILE ARQIMP "\N\N"
   ELSE PRINT FILE ARQIMP FILL("\N",6)
ENDIF

Print File ARQIMP EPSON_GUILHOTINA

EndProc ;RODAPE()

;*******************************************************************************
;* Rotina Principal                                                            *
;*****************+*************************************************************
If Not IsAssigned(NOMEMPRESA)           Then NOMEMPRESA=""           EndIf
If Not IsAssigned(Sys_Reset_Impressora) Then Sys_Reset_Impressora="" EndIf

AGUARDE("Imprimindo Recibo de Pagamento-> "+[Duplic->Numero do Lancamento])

clieant = "****"

IMPRP()
LIMPAGUARDE()

Release Procs IMPRP, RODAPE, ITENS, CABECALHO