;** TransfNE  ******************************************************************
;*  Transferencia P/ Drive (Notas Fiscais de Entrada)                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 30/09/1999 por Anivel Augusto Rodrigues
;Ultima Alteracao: 02/08/2003 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 20/08/2010 por Bruno Carvalho
;Motivo Alteracao: ADD Filtragem por Tipo de Documento 
;Ultima Alteracao: 15/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Layout e Pacote
;Ultima Alteracao: 27/06/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo Arj para c:\Arj
;Ultima Alteracao: 17/11/2003 por Anivel Augusto Rodrigues
;Motivo Alteracao: InclusÆo TG_NLANC
;Ultima Alteracao: 01/12/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo de "ExecVise -> Vexe","Arj -> Varj"
;Ultima Alteracao: 08/12/2011 por Karina Andrade
;Motivo Alteracao: Nova nomeclatura para pacote gerado
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÆo gravar drive padrao

;*******************************************************************************
;* ROTINA PROCESSA  -> realiza o processamento da Transferencia                *
;*******************************************************************************
Proc PROCESSA()

AGUARDE("Aguarde, Transferindo Notas")
ClearAll
Array Arquivo[4]
Arquivo[1]="NotaEc"
Arquivo[2]="NotaEI"
Arquivo[3]="NotaeCP"
Arquivo[4]="NotaeCV"

Cont     = 1
SetDir "\\Sistemas\\Estoque"
For Cont From 1 To 4
    AGUARDE("Aguarde, Transferindo "+Upper(Arquivo[Cont]))
    If IsTable(Arquivo[Cont])
       Then If Arquivo[Cont]<>"NotaEc"
               Then {Ask} {NotaEc}
                    Moveto [Numero do Lancamento] Example "nlanc"
                    Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA.."
                    If NLANCTO<>"000000"
                       Then Moveto [Numero do Lancamento] TypeIn ",~NLANCTO"
                       Else Moveto [Codigo do Documento ] TypeIn "~VSDGTPDOCTO.."
                            Moveto [Data de Entrada     ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                    EndIf   
                    {Ask} TypeIn Arquivo[Cont] Enter Check
                    Moveto [Numero do Lancamento] Example "nlanc"
               Else {Ask} {NotaEc} Check
                    Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA.."
                    If NLANCTO<>"000000"
                       Then Moveto [Numero do Lancamento] TypeIn "~NLANCTO"
                       Else Moveto [Codigo do Documento ] TypeIn "~VSDGTPDOCTO.."
                            Moveto [Data de Entrada     ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                    EndIf        
            Endif
            Do_It!
            ClearAll
            If IsTable("C:\\"+Arquivo[Cont])
               Then Delete "C:\\"+Arquivo[Cont]
            Endif
            Create "C:\\"+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" "C:\\"+Arquivo[Cont]
            ClearAll
            
            If Arquivo[Cont]="NotaEc" And Not IsEmpty("Answer")
               Then Gerou_Dados=True
            EndIf     
    EndIf
EndFor

ClearAll
Limpaguarde()
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA    =""
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTREF"         : Campo="TG_EMPRESA"
            Case Campo="TG_NLANC"         : Campo="TG_DTREF"   
            Case Campo="TG_TPDOCTO"       : Campo="TG_NLANC"   
            Case Campo="TG_DTINI"         : Campo="TG_TPDOCTO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DRIVES"        : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :
                         If Isblank(VSDGEMPRESA)
                            Then VSDGNOMEMP=""
                                 Campo="TG_EMPRESA"
                            Else Campo="TG_DTREF"
                         EndIf

                    Case Campo="TG_DTREF"   : Campo="TG_NLANC"
                    Case Campo="TG_NLANC"   : Campo="TG_TPDOCTO"
                         VSDGNLANC=ControlValue("TG_NLANC")
                         If Not Isblank(VSDGNLANC)
                            Then Campo="TG_DRIVES"
                            
                                 VSDGTPDOCTO   ="" 
                                 VSDGNOMTPDOCTO=""
                                 VSDGDTINI     =BlankDate()
                                 VSDGDTFIM     =BlankDate()
                         EndIf        
                    
                    Case Campo="TG_TPDOCTO" : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   :
                         If Isblank(VSDGDTINI)
                            Then Mensagem("Data inicial invalida !")
                                 Campo="TG_DTINI"
                            Else Campo="TG_DTFIM"
                                 VSDGDTFIM=VSDGDTINI
                         EndIf
                    Case Campo="TG_DTFIM"   :
                         If VSDGDTFIM<VSDGDTINI
                            Then Mensagem("Data final invalida !")
                            Else Campo="TG_DRIVES"
                         EndIf
                    Case Campo="TG_DRIVES"   :
                         VSDGDRIVE=ControlValue("TG_DRIVES")
                         Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTREF" :
       MSG_CAMPO="Informe a data da Transa‡„o"
  Case Campo="TG_DRIVES":
       MSG_CAMPO="Selecione o drive desejado !"
       TECLA=Chr(27)+""+Chr(26)+"=Selecionar  "
  Case Campo="TG_EMPRESA":
       MSG_CAMPO="Informe uma empresa"
  Case Campo="TG_NLANC":
       MSG_CAMPO="Informe um lan‡amento espec¡fico ou Em Branco = Todos"
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a data inicial"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA=""
VSDGDTREF  =BlankDate()
VSDGTPDOCTO=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =Today()-1

DynArray Array_Drives[]
SysInfo Drives To Array_Drives
VSDGDRIVE=SubStr(Directory(),1,2)

While True
  ShowDialog "Exporta‡„o Notas [Estoque]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  

   @ 05,12   Height 15 Width 47
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 1,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
                                                                                                                    
    Label  @ 02,00 "Data Transa‡„o" For "TG_DTREF"
    Accept @ 03,01 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Label  @ 04,00 "N§Lan‡amento"  For "TG_NLANC"
    Accept @ 05,01 Width 09 "A6"  Picture "#*#" Tag "TG_NLANC" To VSDGNLANC

    Label  @ 06,02 "Tipo do Documento"  For "TG_TPDOCTO"
    Accept @ 07,03 Width 07 "A4"  Picture "!*!" Tag "TG_TPDOCTO" To VSDGTPDOCTO
    Accept @ 07,11 Width 23 "A20" Picture "!*!" Tag "TG_NOMTPDOCTO"  To VSDGNOMTPDOCTO

    Label  @ 08,00 "Per¡odo de Entrada" For "TG_DTINI"
    Label  @ 09,00 "de" For "TG_DTINI"
    Accept @ 09,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,17 "at‚" For "TG_DTFIM"
    Accept @ 09,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,37 "Drives:" For "TG_DRIVES"
    PickDynArrayIndex @ 01,38 Height 7 width 05
     Columns 1
      Array_Drives
       Tag "TG_DRIVES"
        To VSDGDRIVE             

    Pushbutton @ 11,10 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,22 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  
  If IsBlank(VSDGEMPRESA) Or
     IsBlank(VSDGDTREF)
     Then Mensagem("Informe os dados corretamente !")
          Loop
  EndIf

  NLANCTO=AlinhM(VSDGNLANC,6)
  DATAREF=AlinhM(StrVal(Day(VSDGDTREF)),2)+AlinhM(StrVal(Month(VSDGDTREF)),2)+SubStr(AlinhM(StrVal(Year(VSDGDTREF)),4),3,2)
  
  ARQ   =VSDGDRIVE+"\\YY"+DATAREF+".ARJ"
  ARQNEW=VSDGDRIVE+"\\PT_NFE"+"_"+VSDGEMPRESA+"_"+
         AlinhM(StrVal(Year(VSDGDTREF)),4) +
         AlinhM(StrVal(Month(VSDGDTREF)),2)+
         AlinhM(StrVal(Day(VSDGDTREF)),2)  +
         ".ARJ"

  Deleta_Arquivo("C:\\NOTAEC.*")
  Deleta_Arquivo("C:\\NOTAEI.*")
  Deleta_Arquivo("C:\\NOTAECP.*")
  Deleta_Arquivo("C:\\NOTAECV.*")
  Deleta_Arquivo(ARQ)
  Sleep(1000)
  ExecVise("REN "+ARQNEW+" \""+ARQ+"\"")
  Sleep(1000)
  Deleta_Arquivo(ARQ)
  Sleep(1000)

  Gerou_Dados=False
    
  Processa()

  Sleep(1000)

  If Not Gerou_Dados
     Then Mensagem("NÆo existe(m) nota(s) conforme sele‡Æo !// //Verificar Empresa, TpDocto, Data Referente !"+
                   "//Pacote nÆo foi gerado !")
     Else Aguarde("Aguarde, Compactando pacote de transa‡„o p/ "+ARQNEW)
          Executa_Programa("c:\\vise\\Varj.exe a "+ARQ+" C:\\NOTAE*.*")
          Sleep(1000)
          ExecVise("REN "+ARQ+" \""+ARQNEW+"\"")
          Deleta_Arquivo("C:\\NOTAEC.*")
          Deleta_Arquivo("C:\\NOTAEI.*")
          Deleta_Arquivo("C:\\NOTAECP.*")
          Deleta_Arquivo("C:\\NOTAECV.*")
        
          MSG="Pacote de transa‡„o gerado !// //"
          MSG=MSG+"Arquivo em "+ARQNEW+"// //"
          MSG=MSG+"Verifique !"
          Mensagem(MSG)
  EndIf

 EndWhile
ClearAll
Release Vars All
Release Procs All
