;** Et_Z252 ********************************************************************
;* Monta Etiqueta p/ Impressora Termica - Zebra - Ecologica                   *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 10/05/2010 por Bruno Carvalho
;Ultima Alteracao: 07/11/2018 por Bruno Carvalho
;Motivo Alteracao: Ajustes padrĈo p/ codigo de barras EAN8, EAN13 ou COD128 

;*******************************************************************************
Proc Monta_Etiqueta()

Moveto "Answer"
Print File Arquivo "O\n"
Print File Arquivo "N\n"
Print File Arquivo "q784\n"
Print File Arquivo "Q485,18+\n"
Print File Arquivo "S2\n"
Print File Arquivo "D8\n"
Print File Arquivo "ZB\n"

If Not IsBlank(CITEM[1])
   Then
        Print File Arquivo "A745,00,1,3,2,1,N,\""+DITEA[1]+"\"\n"
        Print File Arquivo "A710,00,1,3,2,1,N,\""+DITEB[1]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[1])>0 : Print File Arquivo "B670,085,1,E30,3,3,090,B,\""+CITEM[1]+"\"\n"
          Case Search("EAN8",TPBARRA[1])>0  : Print File Arquivo "B670,085,1,E80,3,3,090,B,\""+CITEM[1]+"\"\n"
          OtherWise                         : Print File Arquivo "B670,085,1,1,3,3,090,B,\""+CITEM[1]+"\"\n"
        EndSwitch 
EndIf

If Not IsBlank(CITEM[2])
   Then
        Print File Arquivo "A465,00,1,3,2,1,N,\""+DITEA[2]+"\"\n"
        Print File Arquivo "A430,00,1,3,2,1,N,\""+DITEB[2]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[2])>0 : Print File Arquivo "B390,085,1,E30,3,3,090,B,\""+CITEM[2]+"\"\n" 
          Case Search("EAN8",TPBARRA[2])>0  : Print File Arquivo "B390,085,1,E80,3,3,090,B,\""+CITEM[2]+"\"\n"
          OtherWise                         : Print File Arquivo "B390,085,1,1,3,3,090,B,\""+CITEM[2]+"\"\n"
        EndSwitch 
EndIf
If Not IsBlank(CITEM[3])
   Then
        Print File Arquivo "A189,00,1,3,2,1,N,\""+DITEA[3]+"\"\n"
        Print File Arquivo "A154,00,1,3,2,1,N,\""+DITEB[3]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[3])>0 : Print File Arquivo "B114,085,1,E30,3,3,090,B,\""+CITEM[3]+"\"\n" 
          Case Search("EAN8",TPBARRA[3])>0  : Print File Arquivo "B114,085,1,E80,3,3,090,B,\""+CITEM[3]+"\"\n"
          OtherWise                         : Print File Arquivo "B114,085,1,1,3,3,090,B,\""+CITEM[3]+"\"\n"
        EndSwitch 
EndIf

If CITEM[1]=CITEM[2] And CITEM[1]=CITEM[3]
   Then Print File Arquivo "P"+StrVal(CR)+"\n"
        ce=ce+((CR-1)*3)
   Else Print File Arquivo "P1\n"
EndIf
ne=3
EndProc

;*******************************************************************************
;* Monta Comandos p/ Impressora Termica                                        *
;*******************************************************************************
Proc Monta_Comandos()
If IsAssigned(DITEA)
   Then Release Vars DITEA, DITEB, CITEM, NEMPR, TPBARRA
EndIf
Array   DITEA[3]
Array   DITEB[3]
Array   CITEM[3]
Array TPBARRA[3]
Array   REFER[3]

Arquivo=PrivDir()+"et_Z001B.ejf"
Deleta_Arquivo(Arquivo)

ne=3
Coedit "Answer"
Scan
  te=[Quantidade]
  If (te-(3-ne))>3
     Then CR=Int((te-(3-ne))/3)
     Else CR=1
  EndIf
  ce=0
  While True
    ce=ce+1
    ne=ne+1
    If ne=4
       Then For i From 1 To 3
              DITEA[i]=""
              DITEB[i]=""              
              CITEM[i]=""
            TPBARRA[i]=""  
              REFER[i]=""
            EndFor
            ne=1
    EndIf
    DITEA[ne]=SubStr([Descricao do Item],01,31)
    DITEB[ne]=SubStr([Descricao do Item],32,31)
    CITEM[ne]=[Codigo do Item  ]
  TPBARRA[ne]=Upper([Tipo Codigo_Barras])
    If Search("EAN13",TPBARRA[ne])>0 Or Search("EAN8",TPBARRA[ne])>0
       Then CITEM[ne]=[Codigo de Barras]
    EndIf
    REFER[ne]  ="REF "+[Referencia]
    If ne=3   Then Monta_Etiqueta() EndIf
    If ce>=te Then QuitLoop         EndIf
  EndWhile
EndScan
If ne<3 Then Monta_Etiqueta() EndIf
Do_It!
ClearAll

ImpriArq(Arquivo)

Sleep 700
Deleta_Arquivo(Arquivo)
ClearAll
EndProc

Monta_Comandos()
Release Procs Monta_Etiqueta,Monta_Comandos

