;** ExpAvan ********************************************************************
;*  Exportacao de dados p/ Avanco                                              *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 20/02/2004 por Karen Lauar Nery
;Ultima Alteracao: 28/10/2004 por Nikolas M. Mateus
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 13/08/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Deleta_Arquivo
;Ultima Alteracao: 16/04/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Layout 7.0.14
;Ultima Alteracao: 02/06/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Versao 7.0.16
;Ultima Alteracao: 06/11/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Conversao de Valores
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Substitui‡Ćo Editor novo arquivo por FileWrite

;*******************************************************************************
;* Rotina p/ Selecionar Registros - Clientes                                   *
;*******************************************************************************
Proc SelecionaC()
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo ] Example "cod"
{Ask} {\\Sistemas\\CtaRec\\Duplic}
Moveto [Codigo do Destinatario] Check Example "cod"
Moveto [Saldo do Documento    ] Check TypeIn "> 0.01"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo do Destinatario] Check
Moveto [Saldo do Documento    ] TypeIn "Calc Sum as Valor a Receber"
Do_It!
ClearAll

EndProc   ; (SelecionaC)

;*******************************************************************************
;* Gera Arquivo Texto -- Clientes                                              *
;*******************************************************************************
Proc EXPORTAC()
ClearAll

ARQ=VSDGCAMINHO+"\\Cliente.TXT"
Deleta_Arquivo(ARQ)

ConsumidorFinal()


NR=NRecords("\\Sistemas\\Cadastro\\Destinat")
CC=0

View "Answer"
View "\\Sistemas\\Cadastro\\FichaCli"
View "\\Sistemas\\Cadastro\\DestMsg"
View "\\Sistemas\\Cadastro\\Destinat"
Scan

  Barra(NR, RecNo())
  AGUARDE("Aguarde, Exportando Clientes "+BARRA_STRING)

  If VSDGTIPOE="P"
     Then If Not (([Data da Manutencao]>= VSDGDTINI) And ([Data da Manutencao]<= VSDGDTFIM))
             Then Loop
          EndIf
  EndIf

  If [Tipo]<>"C"
     Then Loop
  EndIf

  CC=CC+1

  Print File ARQ AlinhM([Codigo],7)
  Print File ARQ AlinhM(SubStr(Tira_CharNum([CGC]),1,14),14)
  Print File ARQ Format("W14,AL",[IE])
  Print File ARQ Format("W35,AL",Tira_charEspecial([Razao Social]))
  Print File ARQ Format("W35,AL",Tira_charEspecial([Endereco]))
  Print File ARQ Format("W20,AL",Tira_charEspecial([Bairro]))
  Print File ARQ Format("W08,AL",SubStr([CEP],1,2)+SubStr([CEP],4,3)+SubStr([CEP],8,3))
  Print File ARQ Format("W20,AL",Tira_charEspecial([Cidade]))
  Print File ARQ Format("W2,AL",[UF])
  Print File ARQ AlinhM(SubStr(Tira_CharNum([Telefone]),1,12),12)
;;Moveto "\\Sistemas\\Cadastro\\DestMsg"
;;Moveto [Codigo]
;;Locate [\Sistemas\Cadastro\Destinat->Codigo]
;;If RetVal
;;   Then Print File ARQ Format("W30,AL",[Observacoes])
;;   Else Print File ARQ Fill(" ",30)
;;EndIf
  Print File ARQ Fill(" ",30)
  Moveto "\\Sistemas\\Cadastro\\Destinat"
  If [Situacao do Cliente]="PESSIMO"
     Then Print File ARQ "S"
     Else Print File ARQ "N"
  EndIf
;;Moveto "Answer"
;;Moveto [Codigo do Destinatario]
;;Locate [\Sistemas\Cadastro\Destinat->Codigo]
;;If RetVal
;;   Then Print File ARQ Valor_Str([Valor a Receber],10,2)
;;   Else Print File ARQ "0000000000"
;;EndIf
  Print File ARQ "0000000000"
;;Moveto "\\Sistemas\\Cadastro\\Fichacli"
;;Moveto [Codigo]
;;Locate [\Sistemas\Cadastro\Destinat->Codigo]
;;If RetVal
;;   Then Print File ARQ Valor_Str([Limite de Credito],10,2)
;;   Else Print File ARQ "0000000000"
;;EndIf
  Print File ARQ "0000000000"
  Moveto "\\Sistemas\\Cadastro\\Destinat"
  Print File ARQ "N"
  Print File ARQ "0000000000000000000"
  Print File ARQ "        "
  Print File ARQ "        "
  Print File ARQ "000000"
  Print File ARQ "000000"
  Print File ARQ "\n"

EndScan
ClearAll
EndProc ;(ExportaC)



Proc ConsumidorFinal()
Print File ARQ "000000101234567890   ISENTO        CONSUMIDOR FINAL                                                                                  "
Print File ARQ "DIVINOPOLIS         MG                                          N00000000000000000000N0000000000000000000                000000000000"
Print File ARQ "\n"
EndProc


Proc Mod11_CalcEan13(valor)

Valor=AlinhM(Valor,12)

dig1 =NumVal(SubStr(valor,01,1))
dig2 =NumVal(SubStr(valor,02,1))
dig3 =NumVal(SubStr(valor,03,1))
dig4 =NumVal(SubStr(valor,04,1))
dig5 =NumVal(SubStr(valor,05,1))
dig6 =NumVal(SubStr(valor,06,1))
dig7 =NumVal(SubStr(valor,07,1))
dig8 =NumVal(SubStr(valor,08,1))
dig9 =NumVal(SubStr(valor,09,1))
dig10=NumVal(SubStr(valor,10,1))
dig11=NumVal(SubStr(valor,11,1))
dig12=NumVal(SubStr(valor,12,1))

soma_dig_par   = 3 * (dig2 + dig4 + dig6 + dig8 + dig10 + dig12)
soma_dig_impar = dig1 + dig3 + dig5 + dig7 + dig9 + dig11
soma_dig       = soma_dig_par + soma_dig_impar
resultado = ((1 + Int((soma_dig) / 10)) * 10) - soma_dig
If resultado = 10
   Then digito_ean = 0
   Else digito_ean = resultado
EndIf

Return StrVal(Valor)+StrVal(digito_ean)
EndProc

;*******************************************************************************
;* Gera Arquivo Texto p/ Produtos                                              *
;*******************************************************************************
Proc EXPORTAP()
ClearAll

ARQ=VSDGCAMINHO+"\\Produto.TXT"
Deleta_Arquivo(ARQ)

NR=NRecords("\\Sistemas\\Estoque\\Itens")
CC=0

View "\\Sistemas\\Vendas\\TbPrIte"
View "\\Sistemas\\Estoque\\Itens"
Scan

  Barra(NR, RecNo())
  AGUARDE("Aguarde, Exportando Produtos "+BARRA_STRING)

  REG_OK=True
  If VSDGTIPOE="P"
     Then If Not (([Data da Manutencao]>= VSDGDTINI) And ([Data da Manutencao]<= VSDGDTFIM))
             Then REG_OK=False
          EndIf
  EndIf

  CODITEM=[Codigo do Item]
  Moveto "\\Sistemas\\Vendas\\TbPrIte"
  Moveto [Codigo da Tabela]
  Locate VSDGTABELA, CODITEM
  If Not RetVal
     Then REG_OK=False
     Else If VSDGTIPOE="P"
             Then If Not (([Data Ultimo Reajuste]>= VSDGDTINI) And ([Data Ultimo Reajuste]<= VSDGDTFIM))
                     Then REG_OK=False
                  EndIf
          EndIf
          PRECO=[Preco Unitario]
          If PRECO<=0
             Then REG_OK=False
          EndIf
  EndIf

  Moveto "\\Sistemas\\Estoque\\Itens"
  If Not REG_OK
     Then Loop
  EndIf

  CC=CC+1

;;If Not IsBlank([Codigo de Barras])
;;   Then a2=[Codigo de Barras]
;;   Else a2=[Codigo do Item  ]
;;EndIf
;;a2=Mod11_CalcEan13(SubStr(a2,1,12))

  a2=AlinhM([Codigo de Barras],14)

  Print File ARQ ""+a2
  Print File ARQ ""+Completa(Tira_CharEspecial([Descricao do Item]),35," ")
  Print File ARQ ""+Completa(Tira_CharEspecial([Unidade Fiscal   ]),3," ")
  Print File ARQ Completa(RTrim(SubStr(Tira_CharEspecial([Descricao do Item]),1,20)),20," ")
  Print File ARQ "N"
  Switch
   Case [Tributacao de ICMS]="D" :Print File ARQ "0"
   Case [Tributacao de ICMS]="I" :Print File ARQ "4"
   Case [Tributacao de ICMS]="S" :Print File ARQ "6"
   OtherWise                     :Print File ARQ "1"
  EndSwitch
  If [Tributacao de ICMS]="D"
     Then Switch
          Case [Aliquota de ICMS]=7  :Print File ARQ "07000700"
          Case [Aliquota de ICMS]=12 :Print File ARQ "12001200"
          Case [Aliquota de ICMS]=25 :Print File ARQ "25002500"
          Case [Aliquota de ICMS]=18 :Print File ARQ "18001800"
          OtherWise                  :Print File ARQ "00000000"
         EndSwitch
     Else Print File ARQ "00000000"
  EndIf
  Print File ARQ Fill("0",6 - Len([Aliquota Reduzida BCICMS])) +StrVal([Aliquota Reduzida BCICMS])
  Print File ARQ "N"
  Print File ARQ Completa([Fracionado],1,"N")
  Print File ARQ Completa([Composto  ],1,"N")
  Print File ARQ "0000 "
  
  Print File ARQ AlinhM(StrVal(Int(PRECO*1000)),10)

  Print File ARQ "N"
  Print File ARQ Format("W2,AL",SubStr([Codigo da Familia],2,2))
  Print File ARQ ""+Format("W3,AL",[Codigo do Grupo])
  Print File ARQ ""+Completa([Codigo do Item],14," ")

  Print File ARQ AlinhM(StrVal(Int([Desconto Maximo]*100)),5)

  Print File ARQ "  "
  If Not IsBlank([Codigo Concentrador])
     Then Print File ARQ AlinhM([Codigo Concentrador],14)
     Else Print File ARQ AlinhM([Codigo do Item     ],14)
  Endif
  Print File ARQ Fill("0",04 - Len([Fator de Conversao Saida]))+StrVal([Fator de Conversao Saida])
  Print File ARQ Format("W10,AL",SubStr([Descricao da Marca],1,10))
  If [Quantidade Maxima Venda]<=0
     Then Print File ARQ "999999"
     Else Print File ARQ Fill("0",6 - Len([Quantidade Maxima Venda]))+ StrVal([Quantidade Maxima Venda])
  EndIf
  Print File ARQ "000001"
  Print File ARQ "000000"
 ;Print File ARQ Format("W75,AL",SubStr([Descricao Complementar],1,75))
  Print File ARQ ""+Completa(Tira_CharEspecial([Descricao do Item]),75," ")
  Print FIle ARQ "\n"

EndScan
ClearAll

;*** Setores ***
ARQ=VSDGCAMINHO+"\\SETOR.TXT"
Deleta_Arquivo(ARQ)

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo da Familia   ] Check
Moveto [Descricao da Familia] Check
Moveto [Codigo do Grupo     ] Check
Moveto [Descricao do Grupo  ] Check
Do_It!
ClearAll

NR=NRecords("Answer")
View "Answer"
Scan

  Barra(NR, RecNo())
  AGUARDE("Aguarde, Exportando Setores "+BARRA_STRING)

  Print File ARQ ""+AlinhM(SubStr([Codigo da Familia],2,2),2)
  Print File ARQ ""+Completa(Tira_CharEspecial([Descricao da Familia]),30," ")
  Print File ARQ ""+AlinhM([Codigo do Grupo  ],3)
  Print File ARQ ""+Completa(Tira_CharEspecial([Descricao do Grupo  ]),30," ")

  Print FIle ARQ "\n"

EndScan
ClearAll
EndProc ;(ExportaP)

;*******************************************************************************
;* Gera Arquivo Texto -- Vendedores                                            *
;*******************************************************************************
Proc EXPORTAV()
ClearAll

ARQ=VSDGCAMINHO+"\\Vended01.TXT"
Deleta_Arquivo(ARQ)

NR=NRecords("\\Sistemas\\Cadastro\\Represen")
CC=0

View "\\Sistemas\\Cadastro\\Represen"
Scan
  Barra(NR, RecNo())
  AGUARDE("Aguarde, Exportando Vendedores"+BARRA_STRING)

  CC=CC+1
  Print File ARQ SubStr([Codigo do Representante],2,3)
  Print File ARQ Format("W35,AL",[Razao Social Represent])
  
  Print File ARQ AlinhM(StrVal(Int([Comissao do Representante]*100)),5)
  
  Print File ARQ "\n"

EndScan
ClearAll
EndProc ;(ExportaV)

;*******************************************************************************
;* Gera Arquivo Texto -- Cond.Pagamento                                        *
;*******************************************************************************
Proc EXPORTAPG()
ClearAll

ARQ=VSDGCAMINHO+"\\Planos.TXT"
Deleta_Arquivo(ARQ)

NR=NRecords("\\Sistemas\\Vendas\\CondPgto")
CC=0

View "\\Sistemas\\Vendas\\CondPgto"
Scan

  Barra(NR, RecNo())
  AGUARDE("Aguarde, Exportando Cond.Pagamento "+BARRA_STRING)

  CC=CC+1
  If IsBlank([Codigo_Avanco])
     Then Loop
  EndIf

  PRAZO=""
  j=1
  i=1
  While i<=[Numero de Parcelas]
    NDIAS=0
    pos_s=SearchFrom("/",[Composicao de Dias],j)
    If pos_s=0
       Then If i>1
               Then NDIAS=NumVal(SubStr([Composicao de Dias],j,(Len([Composicao de Dias])-(j-1))))
               Else If Not IsBlank([Composicao de Dias])
                       Then NDIAS=NumVal(SubStr([Composicao de Dias],j,Len([Composicao de Dias])))
                       Else NDIAS=0
                    EndIf
            EndIf
       Else NDIAS=NumVal(SubStr([Composicao de Dias],j,pos_s-j))
            j=pos_s+1
    EndIf
    PRAZO=PRAZO+AlinhM(StrVal(NDIAS),3)

    i=i+1
  EndWhile

  CC=CC+1

  Print File ARQ AlinhM([Codigo_Avanco],3)
  Print File ARQ AlinhM("0",6)
  Print File ARQ AlinhM(StrVal(([Taxa Financeira]*100)),6)
  Print File ARQ AlinhM(StrVal(([Taxa Desconto]*100)),6)
  Print File ARQ COMPLETA(PRAZO,36," ")
  Print File ARQ Format("W20,AL",[Descricao CondPagto])
  Print File ARQ "\n"

EndScan
ClearAll
EndProc ;(ExportaV)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_OPCOES"        : Campo="NO"
            Case Campo="TG_TABELA"        : Campo="TG_OPCOES"
            Case Campo="TG_TIPOE"         :
                 If VSDGOPCAO[2]=True
                    Then Campo="TG_TABELA"
                    Else Campo="TG_OPCOES"
                 EndIf
            Case Campo="TG_DTINI"         : Campo="TG_TIPOE"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CAMINHO"       :
                 If (VSDGOPCAO[1]=True Or VSDGOPCAO[2]=True)
                    Then If VSDGTIPOE="P"
                            Then Campo="TG_DTFIM"
                            Else Campo="TG_TIPOE"
                         EndIf
                    Else Campo="TG_OPCOES"
                 EndIf
            Case Campo="YES" Or Campo="NO": Campo="TG_OPCOES"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_OPCOES"     :
                         If (VSDGOPCAO[1]=False) And
                            (VSDGOPCAO[2]=False) And
                            (VSDGOPCAO[3]=False)
                            Then Campo="TG_OPCOES"
                            Else
                               Switch
                                 Case VSDGOPCAO[2]=True : Campo="TG_TABELA"
                                 Case VSDGOPCAO[1]=True : Campo="TG_TIPOE"
                                 Case VSDGOPCAO[3]=True : Campo="TG_CAMINHO"
                               EndSwitch
                         EndIf
                         If VSDGOPCAO[2]=False
                            Then VSDGTABELA  =""
                                 VSDGNOMTAB  =""
                                 VSDGTIPOE   =""
                                 VSDGNOMTIPOE=""
                         EndIf
                         If VSDGOPCAO[1]=False
                            Then VSDGTIPOE   =""
                                 VSDGNOMTIPOE=""
                         EndIf
                    Case Campo="TG_TABELA"     :
                        If Not IsBlank(VSDGTABELA)
                           Then Campo="TG_TIPOE"
                        EndIf
                    Case Campo="TG_TIPOE"      :
                        VSDGTIPOE=ControlValue("TG_TIPOE")
                        If IsBlank(VSDGTIPOE)
                           Then VSDGTIPOE="T"
                        EndIf
                        If VSDGTIPOE="T"
                           Then VSDGNOMTIPOE="TOTAL"
                                Campo="TG_CAMINHO"
                           Else VSDGNOMTIPOE="PARCIAL"
                                Campo="TG_DTINI"
                        EndIf
                    Case Campo="TG_DTINI"      :
                         If Not IsBlank(VSDGDTINI)
                            Then Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM"      : Campo="TG_CAMINHO"
                    Case Campo="TG_CAMINHO"    :
                         VSDGCAMINHO=ControlValue("TG_CAMINHO")
                         If IsBlanK(VSDGCAMINHO)
                            Then Campo="TG_CAMINHO"
                            Else Campo="YES"
                         EndIf
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
 Case Campo="TG_TIPOE"   : MSG_CAMPO="Tipo de Exporta‡„o (P=Parcial  T=Total)"
 Case Campo="TG_CAMINHO" : MSG_CAMPO="Caminho a ser gerado o arquivo.  Exemplo: C:\\Windows\\Desktop "
 Case Campo="TG_TABELA"  : MSG_CAMPO="Tabela de Pre‡o"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc


;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ConfOpcoes(Opcao)
Private Opcao

Switch
  Case Opcao="Ler":
       If IsFile("EX_0000.sc")
           Then Play "EX_0000"
           Else VSDGCAMINHO="C:\\PDVW"
       EndIf
  Case Opcao="Gravar":

       NCAMINHO=""
       For i From 1 to Len(VSDGCAMINHO)
         If SubStr(VSDGCAMINHO,i,1)=Chr(92)
            Then NCAMINHO=NCAMINHO+Chr(92)
         EndIf
         NCAMINHO=NCAMINHO+SubStr(VSDGCAMINHO,i,1)
       EndFor

       FileWrite        "EX_0000.sc" From ";****** Variaveis de Configura‡„o Caminho Vise Informatica"+"\n"
       FileWrite Append "EX_0000.sc" From "VSDGCAMINHO="+Chr(34)+NCAMINHO+Chr(34)+"\n"
EndSwitch
EndProc ;

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

ConfOpcoes("Ler")

Array VSDGOPCAO[4]
VSDGOPCAO[1]=False
VSDGOPCAO[2]=False
VSDGOPCAO[3]=False
VSDGOPCAO[4]=False
VSDGDTINI=BlankDate()
VSDGDTFIM=BlankDate()

While True
 ShowDialog "Exporta‡„o de dados p/ Avan‡o " Proc "SD_Dialog"
   Trigger "OPEN","ARRIVE"
    Key "TAB","ReverseTab","ENTER","ESC","F1",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140    
     @ 05,12 Height 19 Width 46

    Label  @ 00,00 "Op‡oes " For "TG_OPCOES"
    CheckBoxes @1,00 Height 4 Width 25 Tag "TG_OPCOES"
    "Clientes   "         to VSDGOPCAO[1],
    "Produtos   "         to VSDGOPCAO[2]
;;  "Vendedores "         to VSDGOPCAO[3],
;;  "Cond.Pagtos"         to VSDGOPCAO[4]

    Label  @ 06,00 "Tabela"  For "TG_TABELA"
    Accept @ 07,01 Width 08 "A5"  Picture "#*#" Tag "TG_TABELA" To VSDGTABELA
    Accept @ 07,10 Width 33 "A30" Picture "!*!" Tag "TG_NOMTAB" To VSDGNOMTAB

    Label  @ 08,00 "Tipo de Exportacao"  For "TG_TIPOE"
    Accept @ 09,05 Width 04 "A1"  Picture "P,T" Tag "TG_TIPOE" To VSDGTIPOE
    Accept @ 09,10 Width 33 "A12" Picture "!*!" Tag "TG_NOMTIPOE" To VSDGNOMTIPOE

    Label  @ 10,00 "Periodo da Inclu‡„o/Altera‡„o" For "TG_DTINI"
    Label  @ 11,00 "de" For "TG_DTINI"
    Accept @ 11,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,17 "at‚" For "TG_DTFIM"
    Accept @ 11,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 12,00 "Caminho"  For "TG_CAMINHO"
    Accept @ 13,01 Width 42 "A37"  Picture "!*!" Tag "TG_CAMINHO" To VSDGCAMINHO

    Pushbutton @ 15,08 width 13 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,24 width 13 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If Direxists(VSDGCAMINHO)=0
     Then Mensagem("Caminho especificado n„o existe !")
          Loop
  EndIf

  If SubStr(VSDGCAMINHO,Len(VSDGCAMINHO),1)="\\"
     Then VSDGCAMINHO=SubStr(VSDGCAMINHO,1,Len(VSDGCAMINHO)-1)
  EndIf

  If VSDGOPCAO[1]=True
     Then If IsEmpty("\\Sistemas\\Cadastro\\Destinat")
             Then Mensagem("N„o Existem Registros a Processar [Clientes] !")
          EndIf
          SelecionaC()
          ExportaC()
          If Not CC>0
             Then MENSAGEM("N„o Ocorreu Exporta‡„o  [Clientes] ")
          EndIf
  EndIf

  If VSDGOPCAO[2]=True
     Then If IsEmpty("\\Sistemas\\Estoque\\Itens")
             Then Mensagem("N„o Existem Registros a Processar [Produtos] !")
          EndIf
          ExportaP()
          If Not CC>0
             Then MENSAGEM("N„o Ocorreu Exporta‡„o [Produtos] !")
          EndIf
  EndIf

;;If VSDGOPCAO[3]=True
;;   Then If IsEmpty("\\Sistemas\\Cadastro\\Represen")
;;           Then Mensagem("N„o Existem Registros a Processar [Vendedores] !")
;;        EndIf
;;        ExportaV()
;;        If Not CC>0
;;           Then MENSAGEM("N„o Ocorreu Exporta‡„o [Vendedores] !")
;;        EndIf
;;EndIf

;;If VSDGOPCAO[4]=True
;;   Then If IsEmpty("\\Sistemas\\Vendas\\CondPgto")
;;           Then Mensagem("N„o Existem Registros a Processar [Cond.Pagtos] !")
;;        EndIf
;;        ExportaPG()
;;        If Not CC>0
;;           Then MENSAGEM("N„o Ocorreu Exporta‡„o [Cond.Pagtos] !")
;;        EndIf
;;EndIf

  ConfOpcoes("Gravar")
  Mensagem("Exporta‡„o Concluida !")

EndWhile
ClearAll
Release Vars All
Release Procs All
