;** Rm_4000  *******************************************************************
;*  Resumo de Fornecedores de leite                                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 09/02/2003 por Karen Lauar Nery
;Ultima Alteracao: 08/09/2004 por Jos‚ Luˇs Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 11/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 05/08/2017 por Bruno Carvalho
;Motivo Alteracao: Substituido [Valor INSS] -> [Valor TC]

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll
                                                                       
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI") And
   IsTable("\\Sistemas\\Latcinio\\"+Dir_Trab+"CompForC")
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check
        Moveto [Codigo da Empresa     ] Example "cemp" TypeIn " ,~VSDGEMPRESA.."
        Moveto [Numero do Documento   ] Example "numd"
        Moveto [Serie do Documento    ] Example "serd"
        Moveto [Codigo                ] Example "cod"
        Moveto [Data de Emissao       ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo do Documento   ] TypeIn "NF2"
        Moveto [Codigo da Destinacao  ] TypeIn "022 or 020"
        Moveto [Tipo Movimento Estoque] TypeIn "E"
        Moveto [Situacao              ] TypeIn "Not C"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter Check
        Moveto [Codigo da Empresa     ] Example "cemp"
        Moveto [Numero do Documento   ] Example "numd"
        Moveto [Serie do Documento    ] Example "serd"
        Moveto [Situacao_Item         ] TypeIn "Not C"
        {Ask} {\\Sistemas\\Latcinio\\CompForC}
        Moveto [Codigo                ] Example "cod"
        Moveto [Optante_Credito_ICMS  ] Check
        Do_It!
        ClearAll
EndIf

EndProc ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Processa()

{Ask} {Answer}
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Codigo                   ] Example "cod"
Moveto [Razao Social             ] Example "nom"
Moveto [IE                       ] Example "inse"
Moveto [Data de Emissao          ] Example "data"
Moveto [Numero do Documento      ] Example "numo"
Moveto [Preco Total              ] Example "pret"
Moveto [Quantidade               ] Example "qtde"
Moveto [Preco Unitario           ] Example "preu"
Moveto [Valor ICMS               ] Example "icms"
Moveto [Valor TC                 ] Example "inss"
Moveto [Valor Despesas Acessorias] Example "aces"
Moveto [Valor BCSubstituicao ICMS] Example "bcsub"
Moveto [Valor Substituicao ICMS  ] Example "sub"
Moveto [Valor Nota Fiscal        ] Example "vrnf"
Moveto [Optante_Credito_ICMS     ] Example "opt"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Codigo                   ] Example "cod"
Moveto [Razao Social             ] Example "nom"
Moveto [IE                       ] Example "inse"
Moveto [Data de Emissao          ] Example "data"
Moveto [Numero do Documento      ] Example "numo"
Moveto [Preco Total              ] Example "pret"
Moveto [Quantidade               ] Example "qtde"
Moveto [Preco Unitario           ] Example "preu"
Moveto [Valor ICMS               ] Example "icms"
Moveto [Valor TC                 ] Example "inss"
Moveto [Valor Despesas Acessorias] Example "aces"
Moveto [Valor BCSubstituicao ICMS] Example "bcsub"
Moveto [Valor Substituicao ICMS  ] Example "sub"
Moveto [Valor Nota Fiscal        ] Example "vrnf"
Moveto [Optante_Credito_ICMS     ] Example "opt"
Do_It!
ClearAll

EndProc  ;(Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA":Campo="TG_DTINI"
                    Case Campo="TG_DTINI"  :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM" :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;***********************************************+*******************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

While True

  ShowDialog "Resumo de Fornecimento de leite" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 26,26   Height 09 Width 56

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Perˇodo Referente" For "TG_DTINI"
    Label  @ 03,00 "de" For "TG_DTINI"
    Accept @ 03,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,17 "at‚" For "TG_DTFIM"
    Accept @ 03,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 05,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat˘rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_4000"
  Copy "\\Base\\Sistemas\\Vendas\\RM_4000" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
  EndWhile

  Switch
    Case Not IsTable("Answer") : MENSAGEM("N„o existem registros a processar")
                                 Loop
    Case IsEmpty("Answer")     : MENSAGEM("N„o existem registros a processar")
                                 Delete "Answer"
                                 Loop
  EndSwitch
  
  Processa()
  CopyReport "\\Base\\Sistemas\\Vendas\\Rm_4000" "2" Tabela "R"

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All

