;** Rm_0025D  *******************************************************************
;*  Relatorio de Notas Fiscais Transportadora/Cidade/Clientes                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 01/10/2012 por Nikolas
;Ultima Alteracao: 04/11/2014 por Kamila Gomes
;Motivo Alteracao: InclusÆo de contador de paginas
;Ultima Alteracao: 27/10/2016 por Rafael Matos
;Motivo Alteracao: Ajustes Layout para padroniza‡Æo
;Ultima Alteracao: 10/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 14/03/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes op‡Æo de datas               
;Ultima Alteracao: 28/01/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes chamada principal RM_0025

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc RM_0029D_Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")
   Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
        Moveto [Codigo                 ] Example "clie" TypeIn ", ~VSDGDESTINAT.."
        If CIDADE<>""
           Then Moveto [Cidade         ] TypeIn CIDADE
        EndIf   
        Moveto [UF                     ] TypeIn "~VSDGESTADO.."
        Moveto [Codigo da Area         ] TypeIn "~VSDGAREA.."
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check
        Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA.."
        If IsBlank(VSDGNCARREG)
            Then Switch
                   Case VSDGOPDTES="1" : Moveto [Data de Emissao ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                   Case VSDGOPDTES="2" : Moveto [Data de Saida   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                  EndSwitch
           Else Moveto [Numero_Carregamento] TypeIn "~VSDGNCARREG.."        
        EndIf
        Moveto [Codigo                  ] Example "clie"
        Moveto [Codigo da Transportadora] TypeIn "~VSDGTRANSP.."
        Moveto [Codigo da Destinacao    ] TypeIn "~VSDGDESTIN.."
        Moveto [Descricao da Destinacao ] TypeIn "..VEND.. Or ..SAIDA.. Or ..SERV.."
        Moveto [Frete por Conta         ] TypeIn "~VSDGFRETEPC.."
        Moveto [Codigo do Representante ] TypeIn "~VSDGREPRESEN.."
        Moveto [Placa do Veiculo        ] TypeIn "~VSDGVEICULO.."
        Moveto [Situacao                ] TypeIn "Not C"
        Do_It!
        ClearAll
EndIf

EndProc ; (RM_0029D_Seleciona)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_0029D_Principal()

AGUARDE("Aguarde, gerando o relat¢rio")
Tabela=Cria_Temp(PrivDir())

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  If IsTable("Answer")     Then Delete "Answer" EndIf
  RM_0029D_Seleciona()
  If Not IsTable("Answer") Then Loop EndIf
  If IsTable(Tabela)
     Then Add "Answer" Tabela
     Else Rename "Answer" Tabela
  EndIf
EndWhile

If not IsEmpty(Tabela)
   then ;------ contador de pag do relatorio, depende do num. de registros por folha ---
        NR = NRecords(Tabela)
        NPAG = Round(NR/55,1)
        If NPAG < 1 Then NPAG = 1 EndIf
        If numval(substr(strval(NPAG),3,1))<5 
           Then NPAG = Round(NPAG,0) + 1 
           Else NPAG = Round(NPAG,0)
        EndIf
        ;-------------------------------------------------------------------------------
        
        CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2000" "14" Tabela "R"
        IMPRIREL(Tabela,"R")
         
        Delete Tabela
   else MENSAGEM("N„o existem registros a processar")
EndIf

If IsTable(Tabela)   Then Delete Tabela   EndIf
If IsTable("Answer") Then Delete "Answer" EndIf

EndProc

;-- Chamada principal ----------------------------------------------------------
RM_0029D_Principal()

Release Vars Tabela
Release Procs RM_0029D_Principal, RM_0029D_Seleciona