;** Rm_0110b********************************************************************
;*  Emissao dos Titulos Recebidos por Cliente/Cheque                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 04/11/2009 por Cleber Alves
;Ultima Alteracao: 13/11/2009 por Cleber Alves
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 12/03/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÆo usar tipo do pagamento CH/CP
;Ultima Alteracao: 10/08/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes todos tipo de baixas            

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa")

   Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter 
        Moveto [Numero do Lancamento    ]  Example "lanc"
        Moveto [Codigo da Empresa       ] Check TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Destinatario  ] Check TypeIn "~VSDGDESTINAT.."
;;;;;;;;Moveto [Tipo do Pagamento       ] TypeIn "CH or CP"        ; ignorado em 12/03/10
        Moveto [Nome Fantasia Empresa   ] Check
        Moveto [Codigo do Representante ] Check
        Moveto [Nome Fantasia EmitDest  ] Check
        Moveto [Tipo do Documento       ] Check
        Moveto [Numero do Documento     ] Check
        Moveto [Data de Emissao         ] Check        
        Moveto [Numero Lancamento Cheque] Check ;;;TypeIn "Not Blank" ; ignorado em 10/08/10
        Moveto [Data de Vencimento      ] Check
        
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter 
        Moveto [Numero do Lancamento] Check Example "lanc" 
        Moveto [Sequencia da Baixa  ] Check 
        Moveto [Data do Pagamento   ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo da Baixa       ] TypeIn "Blank or NORMAL"
        Moveto [Valor do Recebimento] Check
        Moveto [Valor do Desconto   ] Check
        Moveto [Valor do juros      ] Check
        
        Do_It!
        ClearAll
        
        {Ask} Typein "\\Sistemas\\Cheqrec\\Chequei"  Enter
        Moveto [Numero do Lancamento ] Example "Nche" 
        Moveto [Numero_Cheque  ] Check
        Moveto [Data Vencimento] Check
        Moveto [Valor          ] Check
        Moveto [Codigo_Banco   ] Check
        {Ask} {Answer} Check
        Moveto [Numero Lancamento Cheque ] Example "Nche" TypeIn "!"
        Do_It!
        ClearAll
        
     
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
  [Valor do Desconto]=([Valor do Desconto]*-1)+[Valor do Juros]
  If IsBlank([Valor do Desconto]) Then [Valor do Desconto]=0 EndIf
EndScan
Do_It!
ClearAll

Sort Tabela On "Codigo da Empresa","Tipo do Documento","Numero do Documento","Sequencia da Baixa"

EditKey 
COD_EMP="*"
Tip_Doc="*" 
Num_Doc="*"
Seq_Baix="*"
Scan
If [Codigo da Empresa  ]=COD_EMP  and 
   [Tipo do Documento  ]=Tip_Doc  and
   [Numero do Documento]=Num_Doc       
   Then 
        If [Sequencia da Baixa ]<>Seq_Baix            
           Then seq=seq+1
           Else [Data do Pagamento      ]=Blankdate()                  
                [Valor do Recebimento   ]=Blanknum()
                [Valor do Desconto      ]=Blanknum()
                [Valor do juros         ]=Blanknum()
        EndIf    
        [Data de Emissao        ]=Blankdate()
        [Numero do Lancamento   ]=""
        [Codigo do Representante]="" 
              
        If Seq>0
           Then [Data Vencimento        ]=Blankdate()
                [Data de Vencimento     ]=Blankdate()
                [Codigo_Banco           ]=""
                [Numero_Cheque          ]=""
                [Valor                  ]=Blanknum()
        EndIf   

   else
        COD_EMP = [Codigo da Empresa  ]  
        Tip_Doc = [Tipo do Documento  ] 
        Num_Doc = [Numero do Documento] 
        Seq_Baix= [Sequencia da Baixa ]
        Seq     = 0            
EndIF 
EndScan
Do_It!
ClearAll

EndProc   ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESA"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""
VSDGDESTINAT  =""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

While True
  ShowDialog "T¡tulos Recebidos por Cliente/Cheque" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 11 Width 56
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 1,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Cliente"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 04,00 "Per¡odo de Pagamento" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "at‚" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 07,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

	CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010b" "R" Tabela "R"

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
