;** Rm_4203 ********************************************************************
;* Avaliacoes de Atendimentos por Empresa/Representante Sint‚tico I            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/11/2012 por Kamila Gomes            
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 14/07/2017 por Bruno Carvalho
;Motivo Alteracao: Ajustes "Notacavl" -> "NotaCC"                            

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaCC")
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaCC" Enter Check
         Moveto [Codigo da Empresa      ] Example "Empresa" 
         Moveto [Numero do Documento    ] Example "ndoc"
         Moveto [Serie do Documento     ] Example "sdoc" 
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter 
         Moveto [Codigo da Empresa      ] Example "Empresa" TypeIn ", ~VSDGEMPRESA.."
         Moveto [Numero do Documento    ] Example "ndoc"   
         Moveto [Serie do Documento     ] Example "sdoc"   
         Moveto [Nome Fantasia Empresa  ] Check                             
         Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
         Moveto [Codigo do Representante] Check 
         Moveto [Nome Fantasia Represent] Check
         Moveto [Descricao da Destinacao] TypeIn "..VEND.."
         Moveto [Tipo Movimento Estoque ] TypeIn "S"
         Moveto [Situacao               ] TypeIn "Not C"
         Do_It!
         ClearAll
         
         {Ask} {Answer}
         Moveto [Codigo da Empresa      ] Example "Empresa" 
         Moveto [Numero do Documento    ] Example "ndoc"
         Moveto [Serie do Documento     ] Example "sdoc"  
         Moveto [Nota                   ] Example "nota" 
         Moveto [Nome Fantasia Empresa  ] Example "nemp"                        
         Moveto [Data de Emissao        ] Example "dt"
         Moveto [Codigo do Representante] Example "crepr"
         Moveto [Nome Fantasia Represent] Example "nrepr"
         
         {Ask} TypeIn TabelaT Enter  TypeIn "Fast Insert"
         Moveto [Codigo da Empresa      ] Example "Empresa" 
         Moveto [Numero do Documento    ] Example "ndoc"
         Moveto [Serie do Documento     ] Example "sdoc"  
         Moveto [Nome Fantasia Empresa  ] Example "nemp"                       
         Moveto [Data de Emissao        ] Example "dt"
         Moveto [Codigo do Representante] Example "crepr"
         Moveto [Nome Fantasia Represent] Example "nrepr"
         Moveto [Nota                   ] Example "nota"
         Do_It!
         ClearAll
EndIf

EndProc ;(Seleciona)

;*******************************************************************************
;* Rotina p/ processar e ajustar Dados                                           *
;*******************************************************************************
Proc Processa()
ClearAll

{Ask} TypeIn TabelaT Enter Check
Do_It!
ClearAll

View Tabela
CoEdit "Answer"
Scan  
   Moveto Tabela
   Moveto [Codigo da Empresa]
   Locate [Answer->Codigo da Empresa],[Answer->Codigo do Representante]
   If Not RetVal
      Then End Down
           [Codigo da Empresa      ]=[Answer->Codigo da Empresa]
           [Codigo do Representante]=[Answer->Codigo do Representante]
           [Nome Fantasia Empresa  ]=[Answer->Nome Fantasia Empresa]
           [Nome Fantasia Represent]=[Answer->Nome Fantasia Represent]
   EndIf
   Switch
      Case [Answer->Nota]="1" : [Quantidade Otimo  ]=[Quantidade Otimo  ]+1
      Case [Answer->Nota]="2" : [Quantidade Bom    ]=[Quantidade Bom    ]+1
      Case [Answer->Nota]="3" : [Quantidade Regular]=[Quantidade Regular]+1
      Case [Answer->Nota]="4" : [Quantidade Pessimo]=[Quantidade Pessimo]+1
      OtherWise               : [Quantidade NA     ]=[Quantidade NA     ]+1
   EndSwitch
   [Total de Atendimentos]=[Total de Atendimentos]+1
   Moveto "Answer"
EndScan
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina p/ processar e ajustar Dados por Empresa                             *
;*******************************************************************************
Proc Processa2()
ClearAll

{Ask} TypeIn TabelaT Enter Check
Do_It!
ClearAll

View Tabela
CoEdit "Answer"
Scan  
   Moveto Tabela
   Moveto [Codigo da Empresa]
   Locate [Answer->Codigo da Empresa]
   If Not RetVal
      Then End Down
           [Codigo da Empresa      ]=[Answer->Codigo da Empresa]
           [Nome Fantasia Empresa  ]=[Answer->Nome Fantasia Empresa]
   EndIf
   Switch
      Case [Answer->Nota]="1" : [Quantidade Otimo  ]=[Quantidade Otimo  ]+1
      Case [Answer->Nota]="2" : [Quantidade Bom    ]=[Quantidade Bom    ]+1
      Case [Answer->Nota]="3" : [Quantidade Regular]=[Quantidade Regular]+1
      Case [Answer->Nota]="4" : [Quantidade Pessimo]=[Quantidade Pessimo]+1
      OtherWise               : [Quantidade NA     ]=[Quantidade NA     ]+1
   EndSwitch
   [Total de Atendimentos]=[Total de Atendimentos]+1
   Moveto "Answer"
EndScan
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"       :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         :Campo="TG_OPRELANALSINT"
                    Case Campo="TG_OPRELANALSINT" :
                        VSDGOPRELANALSINT=ControlValue("TG_OPRELANALSINT")
                        If VSDGOPRELANALSINT="2"
                           Then VSDGNOMOPRELANALSINT="Sintetico II"
                           Else VSDGNOMOPRELANALSINT="Sintetico I"
                                VSDGOPRELANALSINT="1"
                        EndIf
                        Campo="YES"
                    
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
     Case Campo="TG_OPRELANALSINT":
     MSG_CAMPO="1- Sintetico I  2- Sintetico II"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Atendimentos por Empresa/Representante" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 09 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡Æo de Relat¢rio" For "TG_OPRELANALSINT"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELANALSINT" To VSDGNOMOPRELANALSINT

    Pushbutton @ 05,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue
    
  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp("\\Sistemas\\Vendas\\")
  TabelaT=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Vendas\\Rm_4203" Tabela
  Copy "\\Base\\Sistemas\\Vendas\\Rm_4202" TabelaT

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(TabelaT)
     Then MENSAGEM("N„o existem registros a processar")
          Delete TabelaT
          Loop
  EndIf
  
  If VSDGOPRELANALSINT="1"
     Then Processa()
          CopyReport "\\Base\\Sistemas\\Vendas\\Rm_4203" "R" Tabela "R"    
     Else Processa2()
          CopyReport "\\Base\\Sistemas\\Vendas\\Rm_4203" "1" Tabela "R"
          
  EndIf
  
  IMPRIREL(Tabela,"R")
  
  Delete Tabela
  Delete TabelaT
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
