;** EV_0002 ********************************************************************
;** Impressao de Etiquetas para Enderecamento de volumes                       *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 25/01/2007 por Anivel Augusto Rodrigues
;Alterado em     :   /  /     por
;Motivo Alteracao:
;Ultima Alteracao: 14/08/2007 por Antonio Marcelo Alves
;Motivo Alteracao: Ajustes Deleta_Arquivo

;*******************************************************************************
Proc TestaImpressora()
;**** Teste da Impressora ****
While True
  If Not PrinterStatus()
     Then MENSAGEM("Impressora Fora de Linha ou Desligada")
          CONFGERAL("Imprime Certificados")
          If OK="S"
             Then Loop
             Else Return False
          EndIf
     Else Return True
  EndIf
EndWhile
EndProc

proc imprime_etiqueta()

if netiq>0
   Then

 ;Print File ARQIMP Chr(27)+"x1"      ; nql
 ;Print File ARQIMP  Chr(27)+"k0"      ; Roman

 Print File ARQIMP CI_10CPP+CI_6LPP+"\n"
 Print File ARQIMP CI_IEXP +CI_INEG+LINHA1+CI_FEXP+CI_FNEG+"\n\n"
 Print File ARQIMP CI_10CPP+LINHA2+"\n\n"
 Print File ARQIMP CI_10CPP+LINHA3+"\n"
 Print File ARQIMP CI_10CPP+LINHA4+"\n"
 Print File ARQIMP CI_10CPP+LINHA5+"\n\n"
 Print File ARQIMP CI_IEXP +CI_INEG+LINHA6+CI_FEXP+CI_FNEG+"\n"
 Print File ARQIMP CI_10CPP+CI_6LPP+"\n"

 ;Print File ARQIMP "x0"             ; Modulo Draft

 ;Print File ARQIMP CI_10CPP
 ;Print File ARQIMP CI_6LPP

EndIf

netiq =0
LINHA1=""
LINHA2=""
LINHA3=""
LINHA4=""
LINHA5=""
LINHA6=""

endproc

;********* Imprime Certificados *******
ArqImp=PrivDir()+"EtEndVol.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

netiq=0
Imprime_Etiqueta()

Fim=False
CoEdit "Answer"
Scan
  Moveto [Sequencia]

  Moveto [Codigo]
  Ativa_Lookup()
  Moveto [Codigo]
  Locate [Answer->Codigo]
  If RetVal
     Then RazaoSocial=[Razao Social]
          ENDERECO   =[Endereco    ]
          BAIRRO     =[Bairro      ]
          CIDADE     =[Cidade      ]
          ESTADO     =[UF          ]
          CEP        =[CEP         ]

     Else RazaoSocial="1234567890123456789012345678901234567890"
          ENDERECO   ="1234567890123456789012345678901234567890"
          BAIRRO     ="12345678901234567890"
          CIDADE     ="12345678901234567890"
          ESTADO     ="12"
          CEP        ="1234567890"
   EndIf

  KeyPress "ESC"

  For wi From 1 To [NCopias]
    AGUARDE("Imprimindo Etiquetas")
    If Not TestaImpressora()
       Then Fim=True
            QuitLoop
    EndIf

    LINHA1=LINHA1+spaces(4)+"PED "+[Numero do Pedido]
    LINHA2=LINHA2+RAZAOSOCIAL
    LINHA3=LINHA3+ENDERECO
    LINHA4=LINHA4+BAIRRO+" - "+CEP
    LINHA5=LINHA5+CIDADE+" - "+ESTADO
    LINHA6=LINHA6+[Tipo do Documento]+" "+[Numero do Documento]

    netiq=netiq+1
    If netiq=2
       Then Imprime_Etiqueta()
       Else LINHA1=Completa(LINHA1,22," ")
            LINHA2=Completa(LINHA2,43," ")
            LINHA3=Completa(LINHA3,43," ")
            LINHA4=Completa(LINHA4,43," ")
            LINHA5=Completa(LINHA5,43," ")
            LINHA6=Completa(LINHA6,22," ")
    EndIf

  EndFor
  If Fim Then QuitLoop EndIf
EndScan
Imprime_Etiqueta()
Do_It!
ClearAll

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)


LIMPAGUARDE()
Release Vars Fim, wwi, NomedaEmpresa,
        RazaoSocial, Endereco, Bairro, Cidade, Estado, Cep, Cont,
        LINHA1,LINHA2,LINHA3,LINHA4,LINHA5,LINHA6, netiq

