;** CB_0009 ********************************************************************
;* Carta de Cobranca IX                                                       *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido  em: 15/01/2010 por Cleber Alves
;Alterado em     :   /  /     por
;Motivo Alteracao:

;*******************************************************************************
;* Rotina para Impressao do Cabecalho da Carta                                 *
;*******************************************************************************
Proc IMPCAB_CARTA()

NFOLHA=NFOLHA+1

Print File ARQIMP "\n"  
Print File ARQIMP Spaces(65)+"Folha: "+StrVAl(NFOLHA)+"\n\n"

Print File ARQIMP Spaces(03)+"NOTIFICA€ÆO EXTRAJUDICIAL"+"\n\n\n"

Print File ARQIMP Spaces(03)+CLI_RAZ +" - "+CODCLIANT+"\n"
Print File ARQIMP Spaces(03)+CLI_END +"\n"
Print File ARQIMP Spaces(03)+CLI_BAIR+" - "+CLI_CEP+"\n"
Print File ARQIMP Spaces(03)+CLI_CID +"/"+CLI_UF+"\n\n\n"


Print File ARQIMP Spaces(03)+"    A empresa "+Format("w40,AC",EMP_RAZ)+", via de seu  gerente" +"\n"
Print File ARQIMP Spaces(03)+"infra assinado, vem atrav‚s desta notificar por inadimplˆncia no pagamento."+"\n"
Print File ARQIMP Spaces(03)+"    As parcelas em inadimplˆncia sÆo  aquelas  com  vencimentos  e  valores"+"\n"
Print File ARQIMP Spaces(03)+"abaixo especificados:"+"\n\n"

LINHA1="     Data   Numero       Data      Valor     Valor     Valor  Dias   Tipo"
LINHA2="   Emissao  Documento   Vencto     Total  Original     Juros  Atraso Documento"
         ;99/99/99 1234567890 99/99/99 99.999,99 99.999,99 99.999,99 99.999 1234567890


Print File ARQIMP LINHA1+"\n"
Print File ARQIMP LINHA2+"\n"

Nl=19
EndProc

;*******************************************************************************
;* Rotina para Impressao dos Titulos da Carta                                  *
;*******************************************************************************
Proc IMPTIT_CARTA()
Print File ARQIMP Spaces(3)+Format("D10",[Data de Emissao])+" "
Print File ARQIMP Format("W11,AL",[Numero do Documento])
Print File ARQIMP Format("D10",[Data de Vencimento])
Print File ARQIMP Format("W10.2,EIC",[Valor do Documento])
Print File ARQIMP Format("W10.2,EIC",[Saldo do Documento])
Print File ARQIMP Format("W10.2,EIC",[Valor do Desconto])
Print File ARQIMP Format("W7,EIC",Today()-[Data de Vencimento])+" "
Switch
  Case [Codigo do documento]="CH"       : Print File ARQIMP "Cheque"
  Case [Codigo do documento]="CP"       : Print File ARQIMP "Cheque"
  Case [Codigo do documento]="DUP"      : Print File ARQIMP "Duplicata"
  Case [Codigo do documento]="ROM"      : Print File ARQIMP "Duplicata"
  Case [Codigo do documento]="ROM1"     : Print File ARQIMP "Duplicata"
  Case [Codigo do documento]="DCC"      : Print File ARQIMP "Desp.Cartorio"
EndSwitch
Print File ARQIMP "\n"

nl=nl+1

EndProc

;*******************************************************************************
;* Rotina para Impressao nova Folha                                            *
;*******************************************************************************
Proc IMPNOVA_FOLHA()

NFOLHA=NFOLHA+1
Print File ARQIMP CI_INEG+" * Continua Pr¢xima Folha -> "+StrVAl(NFOLHA)+CI_FNEG+"\f"

Print File ARQIMP "\n"  
Print File ARQIMP Spaces(65)+"Folha: "+StrVAl(NFOLHA)+"\n\n"
nl=3
EndProc

;*******************************************************************************
;* Rotina para Impressao do Rodape da Carta                                    *
;*******************************************************************************
Proc IMPROD_CARTA()

Print File ARQIMP SPACES(22)+" TOTAL ->"+CI_INEG+
                             Format("W10.2,EIC",TOTVR)+
                             Format("W10.2,EIC",ORIVR)+Format("W10.2,EIC",JURVR)+
                             Format("W7,AR",NTIT)+" Titulos"+CI_FNEG+"\n\n"
nl=nl+2

if nl>49
   Then IMPNOVA_FOLHA()
EndIF

Print File ARQIMP Spaces(03)+"     Favor entrar em contato dentro de 48 horas para regularizar a situa‡Æo"+"\n"
Print File ARQIMP Spaces(03)+"sob pena da ado‡Æo das medidas judicias  cab¡veis.  Fone: " 
Print File ARQIMP Spaces(03)+""+CI_INEG+EMP_FONE+CI_FNEG+".\n\n\n"
Print File ARQIMP Spaces(03)+"     Tendo em vista que a emissÆo deste aviso ‚ autom tica, por computador,"+"\n"
Print File ARQIMP Spaces(03)+"caso V.S j  tenha pago at‚ a entrega do mesmo, solicitamos inutiliza-lo."+"\n\n\n"

Print File ARQIMP Spaces(03)+EMP_CID+", "+
                  StrVal(Day(Today()))+" DE "+
                  RTrim(MesExt(Month(Today())))+" DE "+
                  StrVal(Year(Today()))+"\n\n\n\n"
                  
Print File ARQIMP Spaces(03)+"----------------------------"+"\n"
Print File ARQIMP Spaces(03)+Format("W40,AL",EMP_RAZ)+"\n"
Print File ARQIMP Spaces(03)+"Setor de Cobran‡a"+"\n"
Print File ARQIMP Spaces(03)+Format("W30,AL",EMP_FONE)+"\n"

Print File ARQIMP "\f"

EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Seta_FilePrint("CB_0009")

AGUARDE("Imprimindo Carta de Cobran‡a")

CODEMPANT="***"
CODCLIANT="***"
CoEdit "Answer"
Scan

  If [Codigo da Empresa]<>CODEMPANT
     Then CODEMPANT=[Codigo da Empresa]

          Moveto [Codigo da Empresa]
          If Busca_Lookup("Codigo da Empresa",[Codigo da Empresa],"SM")
             Then EMP_NOMF=REG_BUSCA_LOOKUP["Nome Fantasia Empresa"]
                  EMP_RAZ =REG_BUSCA_LOOKUP["Razao Social Empresa" ]
                  EMP_END =REG_BUSCA_LOOKUP["Endereco Empresa"     ]
                  EMP_BAIR=REG_BUSCA_LOOKUP["Bairro Empresa"       ]
                  EMP_CID =REG_BUSCA_LOOKUP["Cidade Empresa"       ]
                  EMP_UF  =REG_BUSCA_LOOKUP["UF Empresa"           ]
                  EMP_CEP =REG_BUSCA_LOOKUP["CEP Empresa"          ]
                  EMP_FONE=REG_BUSCA_LOOKUP["Telefone Empresa"     ]
                  EMP_CONT=REG_BUSCA_LOOKUP["Contato Empresa"      ]
                  
          EndIf
  EndIf

  If [Codigo do Destinatario]<>CODCLIANT
     Then
          If CODCLIANT<>"***"
             Then IMPROD_CARTA()
          EndIf

          CODCLIANT=[Codigo do Destinatario]
          NFOLHA   =0
          TOTVR    =0
          ORIVR    =0
          JURVR    =0
          NTIT     =0
          Moveto [Codigo do Destinatario]
          If Busca_Lookup("Codigo",[Codigo do Destinatario],"SM")
             Then CLI_RAZ =REG_BUSCA_LOOKUP["Razao Social"]
                  CLI_END =REG_BUSCA_LOOKUP["Endereco"]
                  CLI_BAIR=REG_BUSCA_LOOKUP["Bairro"]
                  CLI_CID =REG_BUSCA_LOOKUP["Cidade"]
                  CLI_UF  =REG_BUSCA_LOOKUP["UF"]
                  CLI_CEP =REG_BUSCA_LOOKUP["CEP"]
                  CLI_FONE=REG_BUSCA_LOOKUP["Telefone"]
             Else CLI_RAZ ="????"
                  CLI_END =""
                  CLI_BAIR=""
                  CLI_CID =""
                  CLI_UF  =""
                  CLI_CEP =""
                  CLI_FONE=""
          EndIf
          IMPCAB_CARTA()
  EndIf

  If nl>60
     Then IMPNOVA_FOLHA()
  EndIf
 
  ImpTit_Carta()

  NTIT=NTIT+1
  ORIVR=ORIVR+[Saldo do Documento]
  TOTVR=TOTVR+[Valor do Documento]
  JURVR=JURVR+[Valor do Desconto]

EndScan
IMPROD_CARTA()
Do_It!
ClearAll

ImpriArq(ARQIMP)

LIMPAGUARDE()
Release Vars NL,NTIT,TOTVR,ORIVR,JURVR
Release Procs IMPCAB_Carta,IMPTit_Carta, ImpRod_Carta, IMPNOVA_FOLHA
