;** Rm_0021 ********************************************************************
;*  Rela‡Æo de Boletos e remessas gerados                                      *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 11/12/2015 por Kamila Gomes            
;Ultima Alteracao: 28/12/2015 por Kamila Gomes             
;Motivo Alteracao: Ajustes Remessa = 0                
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT  
;Ultima Alteracao: 03/01/2017 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog MensagemRadioButtons()               
;Ultima Alteracao: 09/10/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro data e op‡äes
;Ultima Alteracao: 09/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then 
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Destinatario] TypeIn "~VSDGDESTINAT.."
        Switch 
          Case VSDGOPDATA="1" :  Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDATA="2" :  Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
        Moveto [Saldo do Documento    ] TypeIn "> 0.01"
        Moveto [Codigo da Conta       ] TypeIn "~VSDGCONTA.."
        Switch
          Case VSDGOPREL =1 : Moveto [Documento no Banco    ] TypeIn "not blank" 
                              Moveto [Numero_do_Lote        ] TypeIn "blank or 0"

          Case VSDGOPREL =2 : Moveto [Documento no Banco    ] TypeIn "not blank"
                              Moveto [Numero_do_Lote        ] TypeIn "not blank, not 0"  
                              

          Case VSDGOPREL =3 : Moveto [Documento no Banco    ] TypeIn "not blank"

          Case VSDGOPREL =4 : Moveto [Documento no Banco    ] TypeIn "blank"
                              Moveto [Tipo do Pagamento     ] TypeIn "BO"

        EndSwitch   
        Do_It!
        ClearAll

        Adiciona_Dados("Boletos")
EndIf
EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Adicionar Dados na Tabela                                         *
;*******************************************************************************
Proc Adiciona_Dados(a)

{Ask} {Answer}
Moveto [Numero do Lancamento  ] Example "nlanc"
Moveto [Codigo da Empresa     ] Example "cemp"
Moveto [Nome Fantasia Empresa ] Example "nemp"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Codigo do Destinatario] Example "cdest"
Moveto [Nome Fantasia EmitDest] Example "ndest"
Moveto [Data de Emissao       ] Example "dtemi"
Moveto [Data de Vencimento    ] Example "dtvenc"
Moveto [Valor do Documento    ] Example "vdoc"
Moveto [Saldo do Documento    ] Example "sddoc"
Moveto [Valor do Desconto     ] Example "vdesc"
Moveto [Data Limite Desconto  ] Example "dtdesc"
Moveto [Multa                 ] Example "multa"
Moveto [Taxa de Juros         ] Example "txjuros"
Moveto [Tipo Taxa de Juros    ] Example "tpjuros"
Moveto [NDias Taxa de Juros   ] Example "ndias"
Moveto [Codigo da Conta       ] Example "cconta"
Moveto [Descricao da Conta    ] Example "nconta"
Moveto [Documento no Banco    ] Example "docbanco"
Moveto [Razao Social          ] Example "razao"
Moveto [Valor de Juros        ] Example "vjuros"
Moveto [Codigo Plano_Conta    ] Example "plcont"
Moveto [Descricao Plano_Conta ] Example "nplcont"
Moveto [Codigo CCusto         ] Example "ccusto"
Moveto [Descricao CCusto      ] Example "nccusto"
Moveto [Seq_Nosso_Numero      ] Example "sNossoNum"
Moveto [Numero_do_Lote        ] Example "nlote"
        
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero do Lote        ] Example "nlote"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Numero do Lancamento  ] Example "nlanc"
Moveto [Codigo do Destinatario] Example "cdest"
Moveto [Nome Fantasia EmitDest] Example "ndest"
Moveto [Razao Social          ] Example "razao"
Moveto [Saldo do Documento    ] Example "sddoc"
Moveto [Data de Vencimento    ] Example "dtvenc"
Moveto [Codigo da Conta       ] Example "cconta"
Moveto [Descricao da Conta    ] Example "nconta"
Moveto [Codigo da Empresa     ] Example "cemp"
Moveto [Nome Fantasia Empresa ] Example "nemp"
;Data da Operacao
Moveto [Multa                 ] Example "multa"
Moveto [Taxa de Juros         ] Example "txjuros"
Moveto [Valor de Juros        ] Example "vjuros"
Moveto [Tipo Taxa de Juros    ] Example "tpjuros"
Moveto [NDias Taxa de Juros   ] Example "ndias"
Moveto [Documento no Banco    ] Example "docbanco"
Moveto [Codigo Plano_Conta    ] Example "plcont"
Moveto [Descricao Plano_Conta ] Example "nplcont"
Moveto [Codigo CCusto         ] Example "ccusto"
Moveto [Descricao CCusto      ] Example "nccusto"
Moveto [Data de Emissao       ] Example "dtemi"
Moveto [Valor do Documento    ] Example "vdoc"
Moveto [Seq_Nosso_Numero      ] Example "sNossoNum"
Moveto [Valor do Desconto     ] Example "vdesc"
Moveto [Data Limite Desconto  ] Example "dtdesc"

Do_It!
ClearAll


EndProc
;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf


{Ask} TypeIn "\\Sistemas\\Ctarec\\AltBolC" Enter 
Moveto [Numero do Lote  ] Example "nlote"
If VSDGOPDATA="3"
   Then Moveto [Data da Operacao] Example "dtOp" TypeIn " ,>=~VSDGDTINI,<=~VSDGDTFIM"
   Else Moveto [Data da Operacao] Example "dtOp"
EndIf
{Ask} TypeIn Tabela Enter
Moveto [Numero do Lote  ] Example "nlote"
Moveto [Data da Operacao] TypeIn "Changeto _dtOp"
Do_It!
ClearAll

If VSDGOPDATA="3"
   Then 
        {Ask} TypeIn Tabela Enter TypeIn "Fast Delete"
        Moveto [Data da Operacao] TypeIn "Blank"
        Do_It!
        ClearAll
   Else 
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Numero do Lote] TypeIn "0, Changeto Blank"
        Do_It!
        ClearAll
EndIf

EndProc  ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESATE"
            Case Campo="TG_CONTA"         : Campo="TG_DESTINAT"
            Case Campo="TG_OPREL"         : Campo="TG_CONTA" 
            Case Campo="TG_OPDATA"        : Campo="TG_OPREL"
            Case Campo="TG_DTINI"         : Campo="TG_OPDATA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"  : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : Campo="TG_OPREL"
                    Case Campo="TG_OPREL"      : Campo="TG_OPDATA"
                    Case Campo="TG_OPDATA"     :
                         VSDGOPDATA = ControlValue("TG_OPDATA")
                         If VSDGOPREL = 2 
                            Then Switch
                                    Case VSDGOPDATA="2": VSDGNOMOPDATA="DATA DE VENCIMENTO"
                                    Case VSDGOPDATA="3": VSDGNOMOPDATA="DATA DE OPERACAO" 
                                    OtherWise          : VSDGOPDATA="1"
                                                         VSDGNOMOPDATA="DATA DE EMISSAO"
                                 EndSwitch 
                            Else If VSDGOPDATA="2"
                                    Then VSDGNOMOPDATA="DATA DE VENCIMENTO"
                                    Else VSDGOPDATA="1"
                                         VSDGNOMOPDATA="DATA DE EMISSAO"
                                 EndIf
                         EndIf
                         Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPDATA":
       If VSDGOPREL = 2 
          Then MSG_CAMPO="1-EMISSAO  2-VENCIMENTO  3-OPERACAO"
          Else MSG_CAMPO="1-EMISSAO  2-VENCIMENTO"
       EndIf
  Case Campo="TG_OPREL":
       MensagemRadioButtons()     
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""
VSDGOPREL     =""
VSDGCONTA     =""
VSDGOPDATA    =""
VSDGDESTINAT  =""
VSDGDTINI     =BlankDate()
VSDGDTFIM     =BlankDate()

While True
  ShowDialog "Rela‡„o de Boletos a Receber" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 17 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 1,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
    
    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST
    
    Label  @ 04,00 "Conta"  For "TG_CONTA"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label @ 07,00 "Op‡„o de Rela‡„o" For "TG_OPREL"
    RadioButtons @ 08,01 Height 5 Width 32
      "~1~ = Boletos sem Remessa",
      "~2~ = Boletos com Remessa",
      "~3~ = Boletos com/sem remessa",
      "~4~ = Boletos nÆo gerados[BO]"
        Tag "TG_OPREL"
        To VSDGOPREL 
    
    
    Label  @ 00,35 "Op‡äes de Datas" For "TG_OPDATA"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPDATA" To VSDGOPDATA
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPDATA" To VSDGNOMOPDATA

    Label  @ 02,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 13,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 13,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Ctarec\\Rm_0021"
  Copy  "\\Base\\Sistemas\\Ctarec\\Rm_0021" Tabela

    Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
