;** Rm_0090 ********************************************************************
;*  Emissao dos Pedidos por Ordem de Data de Entrega e Produto - Resumo IV     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 25/06/2002 por Douglas Rodrigues
;Ultima Alteracao: 31/03/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao novos TG_..
;Ultima Alteracao: 16/04/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Ask
;Ultima Alteracao: 23/05/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Estado/Cidade

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()

ClearAll
{Ask} {\\Sistemas\\Vendas\\PedidoC}
Moveto [Numero do Pedido      ] Example "Pedido"
Moveto [Codigo da Empresa     ] CheckPLus TypeIn "~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa ] CheckPLus
Moveto [Nome Fantasia EmitDest] CheckPLus
Moveto [Data de Entrega       ] CheckPLus TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Situacao do Pedido    ] TypeIn "ABERTO"
Moveto [Cidade                ] CheckPlus TypeIn CIDADE
Moveto [UF                    ] CheckPlus TypeIn "~VSDGESTADO.."
{Ask} {\\Sistemas\\Vendas\\PedidoI}
Moveto [Numero do Pedido       ] CheckPLus Example "Pedido"
Moveto [Codigo do Item         ] CheckPLus example "item" TypeIn ",~VSDGITEM.."
Moveto [Descricao do Item      ] CheckPLus
Moveto [Codigo da Cor_Tecido   ] CheckPLus
Moveto [Descricao da Cor_Tecido] CheckPLus
Moveto [Tamanho                ] CheckPLus
Moveto [Quantidade             ] CheckPLus TypeIn ">" Example "qf"
Moveto [Quantidade Faturada    ] CheckPLus Example "qf"
Moveto [Unidade Fiscal         ] CheckPLus
Moveto [Preco Unitario         ] CheckPLus
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "item"
Moveto [Codigo da Familia      ] CheckPLus TypeIn "~VSDGFAMI.."
Moveto [Descricao da Familia   ] CheckPLus
Moveto [Codigo do Grupo        ] CheckPLus TypeIn "~VSDGGRP.."
Moveto [Descricao do Grupo     ] CheckPLus
Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
Moveto [Peso Liquido           ] CheckPLus

Do_It!
ClearAll

If Not IsEmpty("Answer")
   Then CopyReport "\\Base\\Sistemas\\Producao\\Rm_0031" "R" "Answer" "R"
EndIf
ClearAll
EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_ESTADO"         : Campo="TG_EMPRESA"
            Case Campo="TG_CIDADE"         : Campo="TG_ESTADO"
            Case Campo="TG_MARCA"          : Campo="TG_CIDADE"
            Case Campo="TG_FAMI"           : Campo="TG_MARCA"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_ITEM"           : Campo="TG_GRP"
            Case Campo="TG_DTINI"          : Campo="TG_ITEM"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     :Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"      :Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"      :Campo="TG_MARCA"
                      If Upper(VSDGCIDADE)="TODAS"
                         Then CIDADE=""
                         Else CIDADE=VSDGCIDADE
                      EndIf
                    Case Campo="TG_MARCA"   : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"    : Campo="TG_GRP"
                    Case Campo="TG_GRP"     : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc
;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA=""
VSDGMARCA  =""
VSDGFAMI   =""
VSDGGRUP   =""
VSDGTPITEM = ""
VSDGDTINI  = BlankDate()
VSDGDTFIM  = BlankDate()
While True

  ShowDialog "Resumo de Item/Entrega IV" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
  @ 05,12   Height 19 Width 65

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Estado"  For "TG_ESTADO"
    Accept @ 03,01 Width 07 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    Accept @ 03,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMESTADO"  To VSDGNOMESTADO

    Label  @ 02,35 "Cidade"  For "TG_CIDADE"
    Accept @ 03,36 Width 23 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE

    Label  @ 04,00 "Marca"  For "TG_MARCA"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 05,09 Width 33 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 06,00 "Familia"  For "TG_FAMI"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 07,09 Width 33 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 08,00 "Grupo"  For "TG_GRP"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"    To VSDGGRP
    Accept @ 09,09 Width 33 "A30" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP

    Label  @ 10,00 "Item"  For "TG_ITEM"
    Accept @ 11,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 11,15 Width 37 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 12,00 "Per¡odo de Entrega" For "TG_DTINI"
    Label  @ 13,00 "de" For "TG_DTINI"
    Accept @ 13,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 13,17 "at‚" For "TG_DTFIM"
    Accept @ 13,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 15,14 width 11 "~O~k"      OK     Default Value "Ok"  Tag "YES" To BottonValue
    Pushbutton @ 15,28 width 11 "~C~ancela" CANCEL                     Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando Relat¢rio")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar!")
          Loop
  EndIf

  IMPRIREL("Answer","R")

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
