;** Rm_2011 ********************************************************************
;*  Emissao dos Titulos a Pagar por Emitente/Saldo                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 29/01/2015 por Luis Gustavo
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog    
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 01/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de lan‡amento
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 03/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Showdialog                       
;Ultima Alteracao: 18/05/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes titulos relatorios

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona(PARAM)
Private PARAM, DATAFINAL
ClearAll

If IsTable("\\Sistemas\\CtaPag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\CtaPag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo do Emitente] TypeIn "~VSDGDESTINAT.."
       If PARAM = 2
          Then If Not IsBlank(VSDGDTINI)
                  Then DATAFINAL = VSDGDTINI - 1
                       Moveto [Data de Vencimento    ] TypeIn "<=~DATAFINAL"
               EndIf
          Else Moveto [Data de Vencimento    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       EndIf
       Moveto [Saldo do Documento    ] TypeIn "> 0.01"
       Switch
         Case ListaRegra_VSDGTPLANC_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPLANC
         Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPLANC.."
       EndSwitch    
       Do_It!
       ClearAll
EndIf

If PARAM = 2 And Not IsEmpty("Answer") 
   Then {Ask} TypeIn Tabela Enter
        Moveto [Valor de Juros] TypeIn "Changeto 0.00"
        Do_It!
        ClearAll
   
        If Not IsBlank(VSDGDTINI)
           Then Processa("Answer")
   
                {Ask} {Answer}
                Moveto [Codigo do Emitente    ] Check
                Moveto [Valor do Documento    ] TypeIn "Calc Sum as Valor do Documento"
                Do_It!
                ClearAll
                
                {Ask} {Answer}
                Moveto [Codigo do Emitente    ] Check Example "a"
                Moveto [Valor do Documento    ] Check
                {Ask} TypeIn Tabela Enter
                Moveto [Codigo do Emitente    ] Example "a"
                Do_It!
                ClearAll
                
                
                View Tabela
                Coedit "Answer"
                Scan
                  COD = [Codigo do Emitente   ]
                  
                  Moveto Tabela
                  Moveto [Codigo do Emitente  ]
                  Locate COD
                  If RetVal
                     Then [Valor de Juros] = [Answer->Valor do Documento]
                  EndIf    
                
                  Moveto "Answer"
                EndScan
                Do_It!
                ClearAll
        EndIf             
EndIf      

Release Vars PARAM, DATAFINAL
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar os Vencimentos                                         *
;*******************************************************************************
Proc Selecionav()

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa     ] Check
Moveto [Codigo do Emitente    ] Check
Moveto [Data de Vencimento    ] TypeIn "Calc Average as Data de Vencimento"

Do_It!
ClearAll

View "Answer"
Coedit Tabela
Scan
  CODEMP = [Codigo da Empresa]
  CODDES = [Codigo do Emitente]
  
  Moveto "Answer"
  Moveto [Codigo da Empresa]
  Locate CODEMP,CODDES
  If RetVal
     Then  Moveto Tabela 
           Moveto [Data Limite Desconto]
           []=[Answer->Data de Vencimento]
           UnLockRecord
  EndIf
EndScan
Do_It!
ClearAll

EndProc   ; (Selecionav)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa(TabelaRef)
Private TabelaRef

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn TabelaRef Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit TabelaRef
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
;;         [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
;;         [Observacoes]=""
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=Round((([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100),2)
      Else VRJUROS=Round((([Valor de Juros]/[NDias Taxa de Juros])*NDA),2)
           VRJUROS=VRJUROS+Round((([Saldo do Documento]*TXM)/100),2)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll

Release Vars TabelaRef
EndProc     ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPLANC"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESATE"
            Case Campo="TG_TPLANC"        : Campo="TG_DESTINAT"
            Case Campo="TG_DTINI"         : Campo="TG_TPLANC"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"      : Campo="TG_TPLANC"
                    Case Campo="TG_TPLANC"        : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="" :
       MSG_CAMPO=""     
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Vencimento")
ModeloRelatoriosAdd("01B Por Pessoa/Vencimento + Observa‡äes")
ModeloRelatoriosAdd("02  Por Pessoa/Vencimento + Saldo Anterior")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

VSDGEMPRESA      = ""
VSDGDESTINAT     = ""
VSDGNOMLANC      = ""
VSDGDTINI        = BlankDate()            
VSDGDTFIM        = BlankDate()

ModeloRelatoriosCarregaLista()

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPLANC]")

While True
  ShowDialog "Titulos … Pagar por Emitente/Tipo Lan‡amento" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"     
   @ 05,12   Height 16 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 04,00 "Tipo do Lan‡amento"  For "TG_TPLANC"
    Accept @ 05,04 Width 04 "A1"  Picture "A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,X,Z" Tag "TG_TPLANC" To VSDGTPLANC
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMLANC"  To VSDGNOMLANC

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 09,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 10,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 10,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona(1)
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa(Tabela)
  Selecionav()
  Seleciona(2)
  
  switch
    case VSDGCODMODELO="02"  : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1000a" "R" Tabela "R"
    case VSDGCODMODELO="01B" : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1000a" "3" Tabela "R"
    case VSDGCODMODELO="01"  : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1000a" "1" Tabela "R"
  Endswitch
  
  
  IMPRIREL(Tabela,"R")

  Delete Tabela
  
EndWhile
ClearAll
Release Vars All
Release Procs All
