;** Rm_3160C *******************************************************************
;* Resumo de Vendas/Custo por Familia/Marca/Produto                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/09/2012 por Bruno Carvalho
;Ultima Alteracao: 17/10/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes layout e processo 
;Ultima Alteracao: 18/10/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao modelo sintetico 

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then If Not IsBlank(VSDGFAMI) or
           Not IsBlank(VSDGMARCA)
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] Check TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp"
        Moveto [Numero do Documento    ] Check Example "ndoc"
        Moveto [Serie do Documento     ] Check Example "sdoc"
        Moveto [Item do Documento      ] Check
        Moveto [Codigo do Item         ] Check Example "cite"
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] Check
        Moveto [Preco Unitario         ] Check
        Moveto [Preco Total            ] Check
        Moveto [Valor Desconto Total   ] Check
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        {Ask} {Answer} Check
        Moveto [Descricao da Destinacao] TypeIn "Not ..TRANSF.."
        Do_It!
        ClearAll

        Adiciona_Dados("VENDAS")
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Numero do Documento    ] Example "numd"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Unitario         ] Example "prun"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes" 
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Vendas_Embalagem       ] Example "prun"   
Moveto [Descricao da Destinacao] Example "numd"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Quantidade      ] Example "qtde"
       Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
  Case Tipo="DEVOLUCOES":
       Moveto [Vendas_Quantidade      ] TypeIn "_qtde*-1"
       Moveto [Vendas_Preco Total     ] TypeIn "(_ptot-_vdes)*-1"
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf
             
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Unidade Embalagem      ] Example "une"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Descricao da Familia   ] Example "dfam"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Descricao da Marca     ] Example "dmar"
Moveto [Codigo Fornecedor      ] Example "codf"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Moveto [Unidade Embalagem      ] TypeIn "changeto _une"
Moveto [Codigo da Familia      ] TypeIn "changeto _cfam"
Moveto [Descricao da Familia   ] TypeIn "changeto _dfam"
Moveto [Codigo da Marca        ] TypeIn "changeto _cmar"
Moveto [Descricao da Marca     ] TypeIn "changeto _dmar"
Moveto [Nome Fantasia Represent] TypeIn "changeto _codf" ;Codigo do Fornecedor (Ir  constar apenas uma ocorrˆncia)
Do_It!
ClearAll                 

;***** Tabela de Preco*********
{Ask} {\\Sistemas\\Vendas\\TbPrite}
Moveto [Codigo da Tabela         ] TypeIn "~VSDGTABELA"
Moveto [Codigo do Item           ] example "item"
Moveto [Preco Unitario           ] example "vr"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item           ] example "item"
Moveto [Total_Vendas_TipoItem    ] TypeIn "Changeto " example "vr"
Do_It!
ClearAll

;***** Calculos **********
CoEdit Tabela
Scan
  [Vendas_Embalagem     ]=Round([Vendas_Preco Total       ]/[Vendas_Quantidade],2)
  [Total_Vendas_Area    ]=Round([Total_Vendas_TipoItem    ]*[Vendas_Quantidade],2)
EndScan
Do_It!
ClearAll 

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_FAMI"          : Campo="TG_EMPRESA"
            Case Campo="TG_MARCA"         : Campo="TG_FAMI"
            Case Campo="TG_TABELA"        : Campo="TG_MARCA"
            Case Campo="TG_DTINI"         : Campo="TG_TABELA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog       
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"        : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_TABELA"
                    Case Campo="TG_TABELA"     : 
                         If IsBlank(VSDGTABELA)
                            Then VSDGNOMTAB=""
                                 Campo="TG_TABELA" 
                            Else Campo="TG_DTINI"         
                         EndIf     
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_OPRELANALSINT"
                    Case Campo="TG_OPRELANALSINT" :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog                                           
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGFAMI    =""
VSDGGRUP    =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Vendas/Vr Ref. por Familia/Marca/Produto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 55

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,02 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,10 Width 33 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP
                
    Label  @ 02,00 "Familia"  For "TG_FAMI"
    Accept @ 03,03 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 03,10 Width 33 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 04,00 "Marca"  For "TG_MARCA"
    Accept @ 05,03 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 05,10 Width 33 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 06,00 "Tabela de Pre‡o"  For "TG_TABELA"
    Accept @ 07,01 Width 08 "A5"  Picture "#*#" Tag "TG_TABELA"    To VSDGTABELA
    Accept @ 07,10 Width 33 "A70" Picture "!*!" Tag "TG_NOMTAB" To VSDGNOMTAB
                      
    Label  @ 08,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 09,00 "de" For "TG_DTINI"
    Accept @ 09,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,17 "at‚" For "TG_DTFIM"
    Accept @ 09,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
                           
    Label  @ 10,00 "Op‡„o do Relat¢rio" For "TG_OPRELANALSINT"
    Accept @ 11,01 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 11,06 Width 28 "A25"  Picture "!*!" Tag "TG_NOMOPRELANASINT" To VSDGNOMOPRELANALSINT
    
    Pushbutton @ 14,12 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,26 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

    @ 12,01 ?? "** Sem Transferencias **"
  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If IsBlank(VSDGTABELA)
     Then Mensagem("Tabela de Pre‡o deve ser informada !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  VSDGMES=AlinhM(StrVal(Month(VSDGDTFIM)),2)
  VSDGANO=StrVal(Year(VSDGDTFIM))

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_3104"
  Copy "\\Base\\Sistemas\\Vendas\\RM_3104" Tabela

  Tabela2=Cria_Temp(PrivDir())
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  If VSDGOPRELANALSINT="1"
     Then IMPRIREL(Tabela,"2") 
     Else IMPRIREL(Tabela,"3")
  EndIf   

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
