;** EV_0005 ********************************************************************
;** Impressao de Etiquetas para Enderecamento de Volumes            StarTextil *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 24/01/2011 por Bruno Carvalho
;Alterado em     : 01/03/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes Cliente "0233" (End. Entrega)
;Alterado em     : 10/09/2012 por Bruno Carvalho 
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 15/06/2016 por Bruno Carvalho 
;Motivo Alteracao: Adicionado Pega_Endereco() e ajustado dados do endere‡o
;Ultima Alteracao: 15/06/2016 por Bruno Carvalho 
;Motivo Alteracao: Adicionado Pega_Endereco() e ajustado dados do endere‡o

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc Pega_Endereco(PARAM)
Private PARAM

VSD_E_Endereco=""
VSD_E_Bairro  =""
VSD_E_CEP     =""
VSD_E_Cidade  =""
VSD_E_UF      =""

VSD_C_Endereco=""
VSD_C_Bairro  =""
VSD_C_CEP     =""
VSD_C_Cidade  =""
VSD_C_UF      =""    

GetRecord "\\Sistemas\\Vendas\\FaturaCC" PARAM To REG_ENTCOB
If RetVal
   Then VSD_E_Endereco=REG_ENTCOB["Endereco de Entrega"]
        VSD_E_Bairro  =REG_ENTCOB["Bairro de Entrega"]
        VSD_E_CEP     =REG_ENTCOB["CEP de Entrega"]
        VSD_E_Cidade  =REG_ENTCOB["Cidade de Entrega"]
        VSD_E_UF      =REG_ENTCOB["UF de Entrega"]

        VSD_C_Endereco=REG_ENTCOB["Endereco de Cobranca"]
        VSD_C_Bairro  =REG_ENTCOB["Bairro de Cobranca"]
        VSD_C_CEP     =REG_ENTCOB["CEP de Cobranca"]
        VSD_C_Cidade  =REG_ENTCOB["Cidade de Cobranca"]
        VSD_C_UF      =REG_ENTCOB["UF de Cobranca"] 
EndIf   
 
EndProc ;Pega_Endereco() 

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc TestaImpressora()
;**** Teste da Impressora ****
While True
  If Not PrinterStatus()
     Then MENSAGEM("Impressora Fora de Linha ou Desligada")
          CONFGERAL("Imprime Certificados")
          If OK="S"
             Then Loop
             Else Return False
          EndIf
     Else Return True
  EndIf
EndWhile
EndProc

;********* Imprime Certificados *******
ArqImp=PrivDir()+"EtEndVol.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf
END_ENT = False
Fim     = False
View "\\Sistemas\\Vendas\\FaturaC"
CoEdit "Answer"
Scan
  NUM_OF = [Numero da OF     ]
  
  Moveto "\\Sistemas\\Vendas\\FaturaC"
  Moveto [Numero da OF]
  Locate NUM_OF
  If RetVal
     Then Pega_Endereco([FaturaC->Numero da OF]) 
          NVOLUME = [Numero de Volumes  ]
          TP_DOC  = [Docto Nota Gerada  ] 
          If SYS_CODIGO_CLIENTE="0233" And VSD_E_Endereco<>"" And VSD_E_Endereco<>"O MESMO"
             Then ENDERECO = VSD_E_Endereco
                  BAIRRO   = VSD_E_Bairro
                  CIDADE   = VSD_E_Cidade
                  ESTADO   = VSD_E_UF
                  CEP      = VSD_E_CEP
                  END_ENT  = True 
          EndIf
     Else NVOLUME ="12345"
          TP_DOC  =""
  EndIf
  Moveto  "Answer"
  Moveto [Sequencia]

  For wi From 1 To [NCopias]
    AGUARDE("Imprimindo Certificados")
    If Not TestaImpressora()
       Then Fim=True
            QuitLoop
    EndIf

    Moveto [Codigo]
    Ativa_Lookup()
    Moveto [Codigo]
    Locate [Answer->Codigo]
    If RetVal
       Then CODIGO     =[Codigo      ]
            RAZAOSOCIAL=[Razao Social]
            If Not END_ENT
               Then ENDERECO   =[Endereco]
                    BAIRRO     =[Bairro  ]
                    CIDADE     =[Cidade  ]
                    ESTADO     =[UF      ]
                    CEP        =[CEP     ]
            EndIf
       Else CODIGO=""
            RazaoSocial="1234567890123456789012345678901234567890"
            ENDERECO   ="1234567890123456789012345678901234567890"
            BAIRRO     ="12345678901234567890"
            CIDADE     ="12345678901234567890"
            ESTADO     ="12"
            CEP        ="1234567890"
     EndIf

    KeyPress "ESC"
    
    Print File ARQIMP  CI_IEXP+CI_INEG+ [Nome Fantasia Empresa]+CI_FEXP+CI_FNEG+"\n\n\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ SubStr(CODIGO,1,4)+" "+SubStr(RAZAOSOCIAL,01,18)+CI_FEXP+CI_FNEG+"\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ Spaces(05)+SubStr(RAZAOSOCIAL,19,18)+CI_FEXP+CI_FNEG+"\n\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ "N§ de Vol.:"+Format("W16,AL",NVOLUME)+CI_FEXP+CI_FNEG+"\n\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ SubStr(ENDERECO,01,23)   +CI_FEXP+CI_FNEG+"\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ SubStr(ENDERECO,24,23)   +CI_FEXP+CI_FNEG+"\n\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ BAIRRO+CI_FEXP+CI_FNEG+"\n\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ CIDADE+CI_FEXP+CI_FNEG+" - "
    Print File ARQIMP  CI_IEXP+CI_INEG+ ESTADO+CI_FEXP+CI_FNEG+"\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ CEP   +Spaces(7)+CI_FEXP+CI_FNEG+"\n\n"
    Print File ARQIMP  CI_IEXP+CI_INEG+ TP_DOC+" "+[Numero do Documento]+CI_FEXP+CI_FNEG+"\n\n"
  EndFor
  If Fim Then QuitLoop EndIf
EndScan
Do_It!
ClearAll

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)


LIMPAGUARDE()
Release Vars Fim, wwi, NomedaEmpresa, RazaoSocial, Endereco, Bairro, Cidade, Estado, Cep, Cont

