;** Rm_0145 ********************************************************************
;*  Relatorio de Documentos c/ Alteracao de Conta/Carteira                     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 11/02/2003 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 01/11/2012 por Bruno Carvalho
;Motivo Alteracao: Add ASK "Destinat" e alterado estrutura "RM_1400" p/ ajustador dados
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 14/03/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtrar Conta,Pessoa,TipoCarteira
;Ultima Alteracao: 26/04/2017 por Rafael/Anivel
;Motivo Alteracao: Ajustes TG_NLACRC              
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog modelo relatorio  

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"AltTitC") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"AltTitI")
   Then 
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"AltTitC" Enter Check
        Moveto [Numero do Lote           ] Example "nl" TypeIn ", ~VSDGNLACRC.."
        Moveto [Codigo da Empresa        ]              TypeIn "~VSDGEMPRESA.."
        Moveto [Codigo da Conta          ]              TypeIn "~VSDGCONTA.."
        Switch
          Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
          Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
        EndSwitch     
        Moveto [Data da Operacao         ]              TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        If VSDGCODMODELO="01B"
           Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
                Moveto [Codigo           ] Example "Cod"
                Moveto [Endereco         ] Check
                Moveto [Bairro           ] Check
                Moveto [CEP              ] Check
                Moveto [Cidade           ] Check
                Moveto [UF               ] Check
                Moveto [CGC              ] Check
                Moveto [IE               ] Check
        EndIf
        
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"AltTitI" Enter Check
        Moveto [Numero do Lote           ] Example "nl"
        If VSDGCODMODELO="01B"
           Then Moveto [Codigo do Destinatario] Example "Cod" TypeIn ", ~VSDGDESTINAT.."
           else Moveto [Codigo do Destinatario]               TypeIn "~VSDGDESTINAT.."
        EndIf
        Do_It!
        ClearAll
  
EndIf

EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPCART" 
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_NLACRC"        : Campo="TG_EMPRESA"
            Case Campo="TG_CONTA"         : Campo="TG_NLACRC"
            Case Campo="TG_DESTINAT"      : Campo="TG_CONTA"
            Case Campo="TG_TPCART"        : Campo="TG_DESTINAT"
            Case Campo="TG_DTINI"         : Campo="TG_TPCART"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_NLACRC"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_NLACRC" 
                    Case Campo="TG_NLACRC"   : 
                      if VSDGNLACRC=0 or isblank(VSDGNLACRC)
                         then 
                              Campo="TG_CONTA"
                         else
                              Campo="TG_CODMODELO"
                              VSDGCONTA        =""   VSDGNOMCONTA=""
                              VSDGDESTINAT     =""   VSDGNOMDEST =""
                              VSDGTPCART       =""   VSDGNOMCART =""
                              VSDGDTINI        =BlankDate()
                              VSDGDTFIM        =Today()
                         
                      endif   
                    Case Campo="TG_CONTA"    : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT" : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"    : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"    : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO":Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Lote/Titulos")
ModeloRelatoriosAdd("01B Por Lote/Pessoa/Titulos")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

VSDGEMPRESA      =""
VSDGDESTINAT     =""
VSDGCONTA        =""
VSDGTPCART       =""
VSDGDTINI        =BlankDate()
VSDGDTFIM        =BlankDate()
VSDGNLACRC       =BlankNum()
VSDGNLACRC       ="" 
VSDGOPRELAT=""

ModeloRelatoriosCarregaLista()

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPCART]")

While True

  ShowDialog "Rela‡„o de altera‡„o de Conta/Carteira" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"  
   @ 05,12   Height 20 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Lote" For "TG_NLACRC"
    Accept @ 03,01 Width 09 "S"                 Tag "TG_NLACRC" To VSDGNLACRC
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNLACRC" To VSDGNOMNLACRC

    Label  @ 04,00 "Conta"  For "TG_CONTA"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 06,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 08,01 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 09,04 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Label  @ 10,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
                                
    Label  @ 13,00  "Modelo de ~R~elat˘rio"  For "TG_CODMODELO"
    Accept @ 14,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 14,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 16,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 16,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGNLACRC=0
     Then VSDGNLACRC=BlankNum()
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela                                  
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  
  switch
    case VSDGCODMODELO="01"  : CopyReport "\\Base\\Sistemas\\CtaRec\\RM_1400" "R" Tabela "R"
    case VSDGCODMODELO="01B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1400" "1" Tabela "R"
  endswitch
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All

