;** CP_0098b ********************************************************************
;** Impressao de Certificado de Postagem - Multiplos  *** BARATON ***          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 29/04/2003 por Anivel Augusto Rodrigues
;Alterado em     : 30/03/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Alterado em     : 20/06/2006 por Antonio Marcelo Alves
;Motivo Alteracao: Inclusao ImpriArq()
;Ultima Alteracao: 14/08/2007 por Antonio Marcelo Alves
;Motivo Alteracao: Ajustes Deleta_Arquivo


;*******************************************************************************
Proc TestaImpressora()
;**** Teste da Impressora ****
While True
  If Not PrinterStatus()
     Then MENSAGEM("Impressora Fora de Linha ou Desligada")
          CONFGERAL("Imprime Certificados")
          If OK="S"
             Then Loop
             Else Return False
          EndIf
     Else Return True
  EndIf
EndWhile
EndProc

Proc Cabecalho()
Print File ARQIMP "\n\n\n\n"
Print File ARQIMP Spaces(59)+"20304919"+"       "+AlinhM(StrVal(Day(Today())),2)+AlinhM(StrVal(Month(Today())),2)+"\n\n"
Print File ARQIMP Spaces(46)+"02137348" +"        "+"7310465802"+"\n\n"
EndProc

Proc Rodape()
While NCP < 8
  Print File ARQIMP "\n\n\n\n\n\n"
  NCP=NCP+1
EndWhile

Print File ARQIMP "\n\n\n"
Print File ARQIMP Spaces(04)+Format("W43,AL",NomedaEmpresa)
Print File ARQIMP "Cartao: 00003020380"+"\f"

Print File ARQIMP CI_10CPP
Print File ARQIMP CI_6LPP

NCP=0
EndProc


;********* Imprime Certificados *******

ARQIMP = "CertPost.TXT"
If IsFile(ARQIMP)
   Then Deleta_Arquivo(ArqImp)
EndIf
Fim=False
NomedaEmpresa="BARATON DISTR. DO BRASIL LTDA"
NCP=0

CoEdit "Answer"
Scan
  Moveto [Sequencia]

  For wi From 1 To [NCopias]
    AGUARDE("Imprimindo Certificados")
    If Not TestaImpressora()
       Then Fim=True
            QuitLoop
    EndIf

    Print File ARQIMP CI_10CPP
    Print File ARQIMP CI_6LPP

    If NCP>7
       Then Rodape()
            ConfGeral("Prepare Formulario, continuar a impress„o ?")
            If OK<>"S"
               Then Fim=True
                    QuitLoop
            EndIf
    EndIf
    If NCP=0
       Then Cabecalho()
    EndIf

    Moveto [Codigo]
    Ativa_Lookup()
    Moveto [Codigo]
    Locate [Answer->Codigo]
    If RetVal
       Then RazaoSocial=[Razao Social]
            CEP        =[CEP         ]
       Else RazaoSocial="???"
            CEP        ="???"
    EndIf
    KeyPress "ESC"

    Print File ARQIMP Spaces(05)+Format("W43,AL",RazaoSocial)+"\n\n"
    Print File ARQIMP Spaces(32)+CEP+"\n\n"
    Print File ARQIMP Spaces(09)+"XX\n\n"
    NCP=NCP+1

  EndFor
  If Fim Then QuitLoop EndIf
EndScan
If Not Fim
   Then Rodape()
EndIf
Do_It!
ClearAll


;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)



LIMPAGUARDE()
Release Procs Cabecalho, Rodape
Release Vars Fim, wwi, NomedaEmpresa
