;** Rm_0231  *******************************************************************
;*  Emissao dos Titulos a Receber por Repr/Cidade/Cliente/Vencto               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 13/05/2015 por Kamila Gomes            
;Ultima Alteracao: 18/05/2015 por Bruno Carvalho                  
;Motivo Alteracao: Ajustes p/ ProgramaÆo de Visita   
;Ultima Alteracao: 06/07/2015 por Bruno Carvalho                  
;Motivo Alteracao: Foi pedido p/ retirar o link pelo representante 
;Ultima Alteracao: 07/07/2015 por Bruno Carvalho                  
;Motivo Alteracao: Ajustes na Proc Seleciona()
;Ultima Alteracao: 07/07/2015 por Bruno Carvalho                  
;Motivo Alteracao: Removido o link com a programaÆo e ajustes no relatorio
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll


{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                  ] Check 
Moveto [Cidade                  ] TypeIn "_Cid"
Moveto [UF                      ] TypeIn "_UF"
{Ask} {VisitaC} 
Moveto [Numero da Programacao   ] Check TypeIn "_nprog ,~VSDGPROGREP.."
Moveto [Codigo do Representante ] Check
{Ask} {VisitaCD} 
Moveto [Numero da Programacao   ] TypeIn "_nprog"
Moveto [Cidade                  ] Check TypeIn "_Cid"
Moveto [UF                      ] Check TypeIn "_UF"
Do_It!
ClearAll

{Ask} {Answer} 
Moveto [Numero da Programacao   ] Example "nprog"
Moveto [Codigo                  ] Example "cli" 
Moveto [Cidade                  ] Check 
Moveto [UF                      ] Check 
{Ask} {\\Sistemas\\Ctarec\\Duplic} Check
Moveto [Codigo do Destinatario  ] Example "cli"
Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA2.."
Moveto [Tipo do Pagamento       ] TypeIn "~VSDGTPPAGTO.."
If VSDGSO_PENDENTES="SIM"
   Then Moveto [Tipo do Lancamento] TypeIn "P"
   Else Moveto [Tipo do Lancamento] TypeIn "Not P, Not J"
EndIf
Moveto [Data de Vencimento      ] TypeIn ">=~VSDGDTINI2,<=~VSDGDTFIM2"
Moveto [Saldo do Documento      ] TypeIn "> 0.01"
Do_It!
ClearAll
EndProc


;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit "Answer"
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll
EndProc    ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_PROGREP"       : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI2"        : Campo="TG_PROGREP"
            Case Campo="TG_DTFIM2"        : Campo="TG_DTINI2"
            Case Campo="TG_TPPAGTO"       : Campo="TG_DTFIM2"
            Case Campo="TG_SN_SOPENDENTES"  : Campo="TG_TPPAGTO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13: 
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_PROGREP"
                    Case Campo="TG_PROGREP"     : Campo="TG_DTINI2"
                         If IsBlank(VSDGPROGREP)
                            Then Mensagem("A programao deve ser informada!")
                                 Campo="TG_PROGREP"
                         EndIf
                    Case Campo="TG_DTINI2"      : Campo="TG_DTFIM2"
                    Case Campo="TG_DTFIM2"      : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"     : Campo="TG_SN_SOPENDENTES"
                    Case Campo="TG_SN_SOPENDENTES": Campo="YES"
                         VSDGSO_PENDENTES=ControlValue("TG_SN_SOPENDENTES")
                         If IsBlank(VSDGSO_PENDENTES)
                            Then VSDGSO_PENDENTES="NAO"
                         EndIf
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_PROGREP":
       MSG_CAMPO="Informe uma ProgramaÆo"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
VSDGEMPRESA =""
VSDGTPPAGTO =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
VSDGDTINI2  =BlankDate()
VSDGDTFIM2  =BlankDate()
VSDGPROGREP =""
VSDGREPRESEN=""

While True
  ShowDialog "T¡tulos a Receber por Represent/Cidade/Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 16 Width 72
    
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "ProgramaÆo"  For "TG_PROGREP"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_PROGREP" To VSDGPROGREP
    Accept @ 03,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMPROGREP" To VSDGNOMPROGREP

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI2"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI2" To VSDGDTINI2
    Label  @ 05,16 "at" For "TG_DTFIM2"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM2" To VSDGDTFIM2

    Label  @ 06,00 "Tipo de Pagamento"  For "TG_TPPAGTO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 08,00 "Emitir s¢ os Pendentes"  For "TG_SN_SOPENDENTES"
    Accept @ 09,01 Width 07 "A3"  Picture "SIM,NAO" Tag "TG_SN_SOPENDENTES" To VSDGSO_PENDENTES

    Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue
  EndDialog

  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGPROGREP<>""
     Then GetRecord "\\Sistemas\\Visita\\VisitaC" VSDGPROGREP To REG_VISITA 
          If RetVal
             Then VSDGDTINI = REG_VISITA["Data Inicial"]
                  VSDGDTFIM = REG_VISITA["Data Final"]
          EndIf
     Else If IsBlank(VSDGDTINI) Or IsBlank(VSDGDTFIM)
             Then Switch
                    Case IsBlank(VSDGDTINI) : Mensagem(" necess rio informar o per¡odo inicial referente s programaes!")
                    Case IsBlank(VSDGDTFIM) : Mensagem(" necess rio informar o per¡odo final referente s programaes!")
                  EndSwitch  
                  Loop
          EndIf
  EndIf   

  If VSDGDTFIM2=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
                                                    
  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, processando")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("No existem registros a processar")
          Loop
  EndIf
  PROCESSA()

  CopyReport "\\Base\\Sistemas\\Visita\\Rm_0241" "R" "Answer" "R"

  IMPRIREL("Answer","R")

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All