;* Rm_0300 *********************************************************************
;*  Emissao Posicao da Carteira de Titulos a Receber                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 13/01/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 05/04/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes dtref sempre hoje            
;Ultima Alteracao: 11/09/2019 por Anivel Augusto Rodrigues     
;Motivo Alteracao: Ignorar Titulo descontado

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()

View Tabela
CoEdit "Duplic"
NR = NRecords("Duplic")
Scan
  Barra(NR, RecNo())
  Aguarde("Aguarde, Processando Titulos "+BARRA_STRING)

  If (Not IsBlank(VSDGEMPRESA) And
      [Codigo da Empresa]<>VSDGEMPRESA) Or [Saldo do Documento]<=0
     Then Loop
  EndIf
  
  if [Tipo do Lancamento  ]="A"   ; titulo descontado
     Then Loop
  EndIf

  NDIAS=VSDGDTREF-[Data de Vencimento]

  Moveto Tabela
  Moveto [Codigo da Empresa]
  Locate [Duplic->Codigo da Empresa]
  If Not RetVal
    Then End Down
         [Codigo da Empresa]    =[Duplic->Codigo da Empresa]
  EndIf

  If NDIAS>0
    Then Switch
          Case NDIAS>120              :
             [Vencido_Vr_Acima_120Dias]=[Vencido_Vr_Acima_120Dias]+[Duplic->Saldo do Documento]
             [Vencido_NT_Acima_120Dias]=[Vencido_NT_Acima_120Dias]+1
          Case NDIAS>90 AND NDIAS<=120:
             [Vencido_Vr_de90_120Dias]=[Vencido_Vr_de90_120Dias]+[Duplic->Saldo do Documento]
             [Vencido_NT_de90_120Dias]=[Vencido_NT_de90_120Dias]+1
          Case NDIAS>60 AND NDIAS<=90 :
             [Vencido_Vr_de60_90Dias]=[Vencido_Vr_de60_90Dias]+[Duplic->Saldo do Documento]
             [Vencido_NT_de60_90Dias]=[Vencido_NT_de60_90Dias]+1
          Case NDIAS>30 AND NDIAS<=60 :
             [Vencido_Vr_de30_60Dias]=[Vencido_Vr_de30_60Dias]+[Duplic->Saldo do Documento]
             [Vencido_NT_de30_60Dias]=[Vencido_NT_de30_60Dias]+1
          Case NDIAS>0 AND NDIAS<=30  :
             [Vencido_Vr_Ate_30Dias]=[Vencido_Vr_Ate_30Dias]+[Duplic->Saldo do Documento]
             [Vencido_NT_Ate_30Dias]=[Vencido_NT_Ate_30Dias]+1
         EndSwitch
         [Total de Vencidos   ]=[Total de Vencidos   ]+[Duplic->Saldo do Documento]
         [Total de Vencidos_NT]=[Total de Vencidos_NT]+1
    Else NDIAS=NDIAS*-1
         Switch
          Case NDIAS>120:
             [A Vencer_Vr_Acima_120Dias]=[A Vencer_Vr_Acima_120Dias]+[Duplic->Saldo do Documento]
             [A Vencer_NT_Acima_120Dias]=[A Vencer_NT_Acima_120Dias]+1
          Case NDIAS>90 AND NDIAS<=120 :
             [A Vencer_Vr_de90_120Dias]=[A Vencer_Vr_de90_120Dias]+[Duplic->Saldo do Documento]
             [A Vencer_NT_de90_120Dias]=[A Vencer_NT_de90_120Dias]+1
          Case NDIAS>60 AND NDIAS<=90  :
             [A Vencer_Vr_de60_90Dias]=[A Vencer_Vr_de60_90Dias]+[Duplic->Saldo do Documento]
             [A Vencer_NT_de60_90Dias]=[A Vencer_NT_de60_90Dias]+1
          Case NDIAS>30 AND NDIAS<=60  :
             [A Vencer_Vr_de30_60Dias]=[A Vencer_Vr_de30_60Dias]+[Duplic->Saldo do Documento]
             [A Vencer_NT_de30_60Dias]=[A Vencer_NT_de30_60Dias]+1
          Case NDIAS>=0 AND NDIAS<=30  :
             [A Vencer_Vr_Ate_30Dias]=[A Vencer_Vr_Ate_30Dias]+[Duplic->Saldo do Documento]
             [A Vencer_NT_Ate_30Dias]=[A Vencer_NT_Ate_30Dias]+1
         EndSwitch
         [Total A Vencer   ]=[Total A Vencer   ]+[Duplic->Saldo do Documento]
         [Total A Vencer_NT]=[Total A Vencer_NT]+1
  EndIf
  [Total da Empresa   ]=[Total A Vencer   ]+[Total de Vencidos   ]
  [Total da Empresa_NT]=[Total A Vencer_NT]+[Total de Vencidos_NT]

  [Saldo_Anterior     ]=[Total da Empresa   ]
  [Saldo_Anterior_NT  ]=[Total da Empresa_NT]

  If [Duplic->Data_Inclusao]=VSDGDTREF
     Then [Emitidos   ]=[Emitidos   ]+[Duplic->Valor do Documento]
          [Emitidos_NT]=[Emitidos_NT]+1
  EndIf

  UnLockRecord

  Moveto "Duplic"
EndScan
Do_IT!
ClearAll

View Tabela
CoEdit "DupBaixa"
NR = NRecords("DupBaixa")

Scan
  Barra(NR, RecNo())
  Aguarde("Aguarde, Processando Baixas "+BARRA_STRING)

  If (Not IsBlank(VSDGEMPRESA) And
      [Codigo da Empresa]<>VSDGEMPRESA)
     Then Loop
  EndIf

  If [Data_Inclusao       ]<>VSDGDTREF
     Then Loop
  EndIf

  Moveto Tabela
  Moveto [Codigo da Empresa]
  Locate [DupBaixa->Codigo da Empresa]
  If Not RetVal
    Then End Down
         [Codigo da Empresa]    =[DupBaixa->Codigo da Empresa]
  EndIf

  Switch
    Case [DupBaixa->Tipo da Baixa]="NORMAL":
         [Baixados_Normal     ]=([Baixados_Normal   ]+[DupBaixa->Valor do Recebimento]+[DupBaixa->Valor do Desconto])-[DupBaixa->Valor do Juros]
         [Baixados_Normal_NT  ]= [Baixados_Normal_NT]+1
         [Descontos_Concedidos]=[Descontos_Concedidos]+[DupBaixa->Valor do Desconto]
         [Juros_Recebidos     ]=[Juros_Recebidos     ]+[DupBaixa->Valor do Juros   ]
    Case [DupBaixa->Tipo da Baixa]="CANCELADO":
         [Baixados_Cancelado   ]=([Baixados_Cancelado   ]+[DupBaixa->Valor do Recebimento]+[DupBaixa->Valor do Desconto])-[DupBaixa->Valor do Juros]
         [Baixados_Cancelado_NT]= [Baixados_Cancelado_NT]+1
    Case [DupBaixa->Tipo da Baixa]="DEVOLVIDO":
         [Baixados_Devolvido   ]=([Baixados_Devolvido   ]+[DupBaixa->Valor do Recebimento]+[DupBaixa->Valor do Desconto])-[DupBaixa->Valor do Juros]
         [Baixados_Devolvido_NT]= [Baixados_Devolvido_NT]+1
  EndSwitch
  [Saldo_Anterior   ]=([Saldo_Anterior     ]-[Emitidos   ])+
                       [Baixados_Normal    ]+[Baixados_Cancelado   ]+[Baixados_Devolvido   ]
  [Saldo_Anterior_NT]=([Saldo_Anterior_NT  ]-[Emitidos_NT])+
                       [Baixados_Normal_NT ]+[Baixados_Cancelado_NT]+[Baixados_Devolvido_NT]

  UnLockRecord

  Moveto "DupBaixa"
EndScan
Do_IT!
ClearAll

;***** Ajusta Dados ************************************
{Ask} {\\Sistemas\\Cadastro\\Empresas}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] Example "nemp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
Do_It!
ClearAll

EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTREF":
    MSG_CAMPO="Informe o periodo de referˆncia"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGDTREF   =Today()

While True
  ShowDialog "Posi‡„o da Carteria de T¡tulos a Receber" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 09 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Data de Hoje" For "TG_DTREF"
    Accept @ 03,01 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Pushbutton @ 05,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue


  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  VSDGDTREF   =Today()

  Tabela=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Ctarec\\RM_0300" Tabela
  Empty(Tabela)

  AGUARDE("Aguarde, Processando Dados")
  Seleciona()

  If IsEmpty(Tabela)
    Then MENSAGEM("N„o existem registros para processar")
         Delete Tabela
         Loop
  EndIf

  IMPRIREL(Tabela,"R")
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All

