

;nÆo usar mais - utilizar rm_0501 - posic‡Æo da carteira de pedidos
;Ver com An¡vel


;Rm_0403C **********************************************************************
;* Emissao de Pedidos X                                                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 26/05/2011 Karina Andrade
;Ultima Alteracao: 30/05/2011 Karina Andrade
;Motivo Alteracao: Ajustes Totais
;Ultima Alteracao: 03/06/2011 Karina Andrade
;Motivo Alteracao: Ajustes Totais e Report
;Ultima Alteracao: 16/11/2012 Kamila Gomes  
;Motivo Alteracao: Acrescentado op‡Æo de relatorio com itens
;Ultima Alteracao: 19/03/2013 Bruno Carvalho
;Motivo Alteracao: Alterado campo [NBM] p/ [Descricao da Unidade]
;Ultima Alteracao: 19/03/2013 Bruno Carvalho
;Motivo Alteracao: Alterado campo [Fator Conversao] p/ [Aliquota de IR]
;Ultima Alteracao: 08/05/2013 por Bruno Carvalho  
;Motivo Alteracao: Ajustes para buscar Mˆs Fechado
;Ultima Alteracao: 27/06/2013 por Kamila Gomes
;Motivo Alteracao: Ajustes para filtrar por Empresa
;Ultima Alteracao: 07/06/2014 por Kamila Gomes
;Motivo Alteracao: Inclu¡do no filtro Sita‡Æo, a op‡Æo SUSPENSO
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro de Gerencia
;Ultima Alteracao: 26/10/2015 por Andrey Fillipe
;Motivo Alteracao: Ajustes mudado o report do PedidoI "14" para RM_0403 "4"
;                  Estava pegando registro em branco quando era mˆs fechado
;Ultima Alteracao: 04/08/2016 por Bruno Carvalho
;Motivo Alteracao: Ajsutado filtro p/ ser informado a data de emissÆo e a data de entrega  **FechaMˆs
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll       

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If Not IsBlank (VSDGGERENCIA)
           Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        EndIf
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Codigo da Empresa    ] Check TypeIn "~VSDGEMPRESA.."
        Moveto [Nome Fantasia Empresa] Check
        Moveto [Numero do Pedido     ] Example "Pedido" TypeIn ",~VSDGPEDIDO.."
        If Not VSDGDEENTREGA[1]
           Then Moveto [Data de Emissao ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                Moveto [Data de Entrega ] Check
           Else Moveto [Data de Emissao ] Check
                Moveto [Data de Entrega ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndIf
        
        If VSDGSITUACAO<>"TODOS"
           Then Moveto [Situacao do Pedido] Check TypeIn "~VSDGSITUACAO"
           Else Moveto [Situacao do Pedido] Check
        EndIf
        Moveto [Codigo                 ] Check TypeIn "~VSDGDESTINAT.."
        Moveto [Nome Fantasia EmitDest ] Check
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. Or ..SAIDA.. Or ..SERV.."
        Moveto [Cidade                 ] Check
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter Check
        Moveto [Numero do Pedido] Example "Pedido"
        Moveto [Codigo da Marca ] TypeIn "~VSDGMARCA.."
        Do_It!
        ClearAll
        
        If IsEmpty("Answer")
          Then Return
        EndIf
            
        ;; *** Ajustando contador de Pedidos ****
        Sort "Answer" On "Numero do Pedido"
        ClearAll
        
        Edit "Answer"
        NPED="***"
        Scan
          
          If [Numero do Pedido]=NPED
             Then [Aliquota de IR]=0
             Else [Aliquota de IR]=1
                  NPED=[Numero do Pedido]
          EndIf
          
          [Preco Total   ]=[Preco Total   ]-[Valor Desconto Total]
          [Valor do IR  ]=[Preco Total]
          If [Quantidade]>[Quantidade Faturada]
             Then [Valor do INSS]=Round(([Preco Total]/[Quantidade])*[Quantidade Faturada],2)
             Else [Valor do INSS]=[Preco Total]
          EndIf
        
          If [Descricao da Unidade]="CANCELADO"
            Then [Valor IPI por Unidade]=[Valor do IR ]
                 [MVA                  ]=[Quantidade  ]
            Else [Valor IPI por Unidade]= 0
                 [MVA                  ]= 0
          EndIf              
          
        EndScan
        Do_It!
        ClearAll
EndIf

EndProc; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_PEDIDO"        : Campo="TG_EMPRESA"
            Case Campo="TG_SITUACAO"      : Campo="TG_PEDIDO"
            Case Campo="TG_MARCA"         : Campo="TG_SITUACAO"
            Case Campo="TG_DESTINAT"      : Campo="TG_MARCA"
            Case Campo="TG_REPRESEN"      : Campo="TG_DESTINAT"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI2"        : Campo="TG_GERENCIA"
            Case Campo="TG_DTFIM2"        : Campo="TG_DTINI2"
            Case Campo="TG_ENTREGA"       : Campo="TG_DTFIM2"
            Case Campo="TG_DTINI"         : Campo="TG_ENTREGA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_UTILIZAITENS"  : If VSDGDEENTREGA[1]
                                               Then Campo="TG_DTFIM"
                                               Else Campo="TG_ENTREGA"
                                            EndIf   
            Case Campo="YES" Or Campo="NO": Campo="TG_PEDIDO"

          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"         : Campo="TG_PEDIDO"
                    Case Campo="TG_PEDIDO"          : Campo="TG_SITUACAO"
                    Case Campo="TG_SITUACAO"        :
                                VSDGSITUACAO=ControlValue("TG_SITUACAO")
                                If IsBlank(VSDGSITUACAO)
                                   Then VSDGSITUACAO="TODOS"
                                EndIf
                                Campo="TG_MARCA"
                    Case Campo="TG_MARCA"           : Campo="TG_DESTINAT" 
                    Case Campo="TG_DESTINAT"        : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"        : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"        : Campo="TG_DTINI2"
                    Case Campo="TG_DTINI2"          : Campo="TG_DTFIM2"
                    Case Campo="TG_DTFIM2"          : Campo="TG_ENTREGA"
                    Case Campo="TG_ENTREGA"         : If VSDGDEENTREGA[1] 
                                                         Then Campo="TG_DTINI"
                                                         Else Campo="TG_UTILIZAITENS"
                                                      EndIf   
                    Case Campo="TG_DTINI"           : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"           : Campo="TG_UTILIZAITENS"
                    Case Campo="TG_UTILIZAITENS"    :
                      VSDGUTILIZAITENS=ControlValue("TG_UTILIZAITENS")
                      If IsBlank(VSDGUTILIZAITENS)
                          Then VSDGUTILIZAITENS="S"
                      EndIf
                      If VSDGUTILIZAITENS="C"
                        Then VSDGNOMUTILIZAITENS="COM ITENS"
                        Else VSDGNOMUTILIZAITENS="SEM ITENS"
                      EndIf
                      Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_PEDIDO":
     MSG_CAMPO="Em Branco = Todos"
  Case Campo="TG_TPDATA":
       MSG_CAMPO="1 = EMISSAO  2 = ENTREGA"
  Case Campo="TG_SITUACAO":
    MSG_CAMPO="A = Aberto  F = Faturado  C = Cancelado  S = Suspenso  Em Branco = Todos"
  Case Campo="TG_UTILIZAITENS":
    MSG_CAMPO="C = Com Itens  S = Sem Itens"
  Case Campo="TG_ENTREGA":
    MensagemCheckBoxes()  
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA          = ""
VSDGPEDIDO           = ""
VSDGSITUACAO         = ""
VSDGMARCA            = ""
VSDGNOMTPDATA        = ""
VSDGNOMOPRELANALSINT = ""
VSDGREPRESEN         = ""
VSDGGERENCIA         = ""
VSDGDTINI            = BlankDate()
VSDGDTFIM            = BlankDate()
VSDGDTINI2           = BlankDate()
VSDGDTFIM2           = BlankDate()

Array VSDGDEENTREGA[1]
VSDGDEENTREGA[1]=False
            
While True
  ShowDialog "Emiss„o Pedidos por Representante" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 19 Width 74
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Pedido"  For "TG_PEDIDO"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_PEDIDO" To VSDGPEDIDO
    Accept @ 03,09 Width 21 "A19" Picture "!*!" Tag "TG_NOMPEDIDO" To VSDGNOMPEDIDO

    Label  @ 02,35 "Situa‡„o"  For "TG_SITUACAO"
    Accept @ 03,36 Width 12 "A9"  Picture "ABERTO,FATURADO,CANCELADO,SUSPENSO" Tag "TG_SITUACAO"  To VSDGSITUACAO

    Label  @ 04,00 "Marca"  For "TG_MARCA"
    Accept @ 05,01 Width 07 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 05,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 04,35 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,36 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,44 Width 23 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 06,00 "Representante"  For "TG_REPRESEN"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 07,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 06,35 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 07,36 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 07,44 Width 13 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 08,00 "Pedidos emitidos em: " For "TG_DTINI2"
    Label  @ 09,00 "de" For "TG_DTINI2"
    Accept @ 09,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI2" To VSDGDTINI2
    Label  @ 09,17 "at‚" For "TG_DTFIM2"
    Accept @ 09,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM2" To VSDGDTFIM2
    
    CheckBoxes @09,36 Height 1 Width 30 Tag "TG_ENTREGA"
    "Utiliza Data de Entrega" to VSDGDEENTREGA[1]

    Label  @ 10,00 "Pedidos entregue em: " For "TG_DTINI"
    Label  @ 11,00 "de" For "TG_DTINI"
    Accept @ 11,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,17 "at‚" For "TG_DTFIM"
    Accept @ 11,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
            
    Label  @ 12,00 "Op‡„o do Relat¢rio" For "TG_UTILIZAITENS"
    Accept @ 13,01 Width 04 "A1"  Picture "C,S" Tag "TG_UTILIZAITENS" To VSDGUTILIZAITENS
    Accept @ 13,06 Width 28 "A25"  Picture "!*!" Tag "TG_NOMUTILIZAITENS" To VSDGNOMUTILIZAITENS

    Pushbutton @ 15,24 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,38 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Usuario_Vendedor() Then Loop EndIf  

  If VSDGDTFIM2=BlankDate()
     Then Mensagem("Data Final de Emiss„o Invalida !")
  EndIf
  
  If VSDGDEENTREGA[1] And VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final de Entrega Invalida !")
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  
  If VSDGDEENTREGA[1]                              
     Then DATA_INI = VSDGDTINI2  ;Data Inicio -> Data de EmissÆo 
          DATA_FIM = VSDGDTFIM   ;Data Fim    -> Data Final do Periodo de Entrega
     Else ;---- Data de EmissÆo ------------------------------------------------
          VSDGDTINI = VSDGDTINI2
          VSDGDTFIM = VSDGDTFIM2
          DATA_INI  = VSDGDTINI
          DATA_FIM  = VSDGDTFIM
  EndIf
  
  Monta_Dir_Trab(DATA_INI,DATA_FIM)
  While Novo_Dir_Trab()
    If IsTable("Answer") Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile
  Release Vars DATA_INI,DATA_FIM
  If Not VSDGDEENTREGA[1]                              
     Then VSDGDTINI = BlankDate()
          VSDGDTFIM = BlankDate()
  EndIf        
  
  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  
  If VSDGUTILIZAITENS="S"
     Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0403" "4" Tabela "R"
     Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0403" "R"  Tabela "R"
  EndIf
  
  IMPRIREL(Tabela,"R")
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
