;** Rm_0400  *******************************************************************
;*  Relacao de Servicos e Valor por Prestador                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 13/04/2007 por Anivel Augusto Rodrigues
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 04/11/2019 por Bruno Carvalho
;Motivo Alteracao: Otimiza‡Æo ao inserir o registro na TABELA 
;Ultima Alteracao: 25/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   

;*******************************************************************************
; Rotina p/ Selecionar Registros                                               *
;*******************************************************************************
Proc Seleciona()

ClearAll

If IsTable("\\Sistemas\\Faccao\\"+Dir_Trab+"RFACC") And
   IsTable("\\Sistemas\\Faccao\\"+Dir_Trab+"Vales")
   Then Aguarde("Aguarde, verificando dados -> programa‡Æo ")
        
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
        Moveto [Codigo                ] TypeIn "_Cod"
        Moveto [Codigo Atividade      ] TypeIn "~VSDGATIVIDADE.."
        {Ask} TypeIn "\\Sistemas\\Faccao\\"+Dir_Trab+"RFACC" Enter
        Moveto [Numero_Producao       ] Check
        Moveto [Numero_Programacao    ] Check
        Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA.."
        Moveto [Nome Fantasia Empresa ] Check
        Moveto [Destino_Producao      ] Check
        Moveto [Codigo                ] Check TypeIn "_Cod, ~VSDGDESTINAT.."
        Moveto [Nome Fantasia EmitDest] Check
        Moveto [Razao Social          ] Check
        Moveto [Data_Producao         ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Quantidade_Produzida  ] Check
        Moveto [Valor Total           ] Check
        Moveto [Codigo da Tabela      ] Check
        Do_It!
        ClearAll
        
        TabelaRFACC=Adiciona_Indice_Temp("Numero_Producao")
        
        {Ask} TypeIn TabelaRFACC Enter 
        Moveto [Numero_Producao       ] Example "num"
        Moveto [Numero_Programacao    ] Example "nprog"
        Moveto [Codigo da Empresa     ] Example "cemp"
        Moveto [Nome Fantasia Empresa ] Example "nemp"
        Moveto [Destino_Producao      ] Example "dpr"
        Moveto [Codigo                ] Example "ccli"
        Moveto [Nome Fantasia EmitDest] Example "ncli"
        Moveto [Razao Social          ] Example "rcli"
        Moveto [Data_Producao         ] Example "dp"  
        Moveto [Quantidade_Produzida  ] Example "qprod"
        Moveto [Valor Total           ] Example "vrt"
        Moveto [Codigo da Tabela      ] Example "ctab"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Numero_Producao       ] Example "num"
        Moveto [Numero_Programacao    ] Example "nprog"
        Moveto [Codigo da Empresa     ] Example "cemp"
        Moveto [Nome Fantasia Empresa ] Example "nemp"
        Moveto [Destino_Producao      ] Example "dpr"
        Moveto [Codigo                ] Example "ccli"
        Moveto [Nome Fantasia EmitDest] Example "ncli"
        Moveto [Razao Social          ] Example "rcli"
        Moveto [Data                  ] Example "dp"
        Moveto [Quantidade_Produzida  ] Example "qprod"
        Moveto [Valor                 ] Example "vrt"
        Moveto [Valor Servicos        ] Example "vrt"
        Moveto [Codigo da Tabela      ] Example "ctab"
        Moveto [Tipo                  ] TypeIn "Servicos"
        Do_It!
        ClearAll
        
        Delete TabelaRFACC

        Aguarde("Aguarde, verificando dados -> vales ")

        {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
        Moveto [Codigo                ] TypeIn "_Cod"
        Moveto [Codigo Atividade      ] TypeIn "~VSDGATIVIDADE.."
        {Ask} TypeIn "\\Sistemas\\Faccao\\"+Dir_Trab+"Vales" Enter
        Moveto [Numero do Lancamento  ] Check
        Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA.."
        Moveto [Nome Fantasia Empresa ] Check
        Moveto [Codigo                ] Check TypeIn "_Cod, ~VSDGDESTINAT.."
        Moveto [Nome Fantasia EmitDest] Check
        Moveto [Razao Social          ] Check
        Moveto [Data                  ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Descricao             ] Check
        Moveto [Valor                 ] Check
        Do_It!
        ClearAll
        
        TabelaVALES=Adiciona_Indice_Temp("Numero do Lancamento")
        
        {Ask} TypeIn TabelaVALES Enter
        Moveto [Numero do Lancamento  ] Example "num"
        Moveto [Codigo da Empresa     ] Example "cemp"
        Moveto [Nome Fantasia Empresa ] Example "nemp"
        Moveto [Codigo                ] Example "ccli"
        Moveto [Nome Fantasia EmitDest] Example "ncli"
        Moveto [Razao Social          ] Example "rcli"
        Moveto [Data                  ] Example "dp"  
        Moveto [Descricao             ] Example "descr"
        Moveto [Valor                 ] Example "vrt"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Numero do Lancamento  ] Example "num"
        Moveto [Codigo da Empresa     ] Example "cemp"
        Moveto [Nome Fantasia Empresa ] Example "nemp"
        Moveto [Codigo                ] Example "ccli"
        Moveto [Nome Fantasia EmitDest] Example "ncli"
        Moveto [Razao Social          ] Example "rcli"
        Moveto [Data                  ] Example "dp"
        Moveto [Descricao             ] Example "descr"
        Moveto [Valor                 ] Example "vrt"
        Moveto [Valor Vales           ] Example "vrt"
        Moveto [Tipo                  ] TypeIn "Vales"
        Do_It!
        ClearAll
        
        Delete TabelaVALES        
EndIf

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_ATIVIDADE"     : Campo="TG_EMPRESA"
            Case Campo="TG_DESTINAT"      : Campo="TG_ATIVIDADE"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_ATIVIDADE"
                    Case Campo="TG_ATIVIDADE"  : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo = "YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Prestador/Lan‡amentos")
ModeloRelatoriosAdd("02  Por Prestador              - Sint‚tico")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""
VSDGATIVIDADE =""
VSDGDESTINAT  =""
VSDGDTINI     =BlankDate()
VSDGDTFIM     =BlankDate()

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Apura‡Æo de Servi‡os e Vales por Prestador" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 16 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Atividade"  For "TG_ATIVIDADE"
    Accept @ 03,01 Width 07 "A4"  Picture "!*!" Tag "TG_ATIVIDADE" To VSDGATIVIDADE
    Accept @ 03,09 Width 25 "A30"  Picture "#*#" Tag "TG_NOMATIV" To VSDGNOMATIV

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 09,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 10,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 10,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp("\\Sistemas\\Faccao\\")
  Copy "\\Base\\Sistemas\\Faccao\\Rm_0400" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  Switch
    Case VSDGCODMODELO="01": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0400" "R" Tabela "R"
    Case VSDGCODMODELO="02": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0400" "1" Tabela "R"
  EndSwitch

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
