;** Ro_0180 ********************************************************************
;** Imprime Romaneio                            ** MERC. TOIZINHO "            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 22/08/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 15/06/2016 por Bruno Carvalho 
;Motivo Alteracao: Adicionado Pega_Endereco_Fatura() e ajustado dados do endere‡o
;Ultima Alteracao: 26/06/2018 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes itens mercadoria/servico

;*******************************************************************************
;* Rotina para Impressao do Relatorio                                          *
;*******************************************************************************
Proc IMPRO()

;************************* IMPRESSAO DO CABECALHO *****************************
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf

Moveto "FaturaC"
Pega_Endereco_Fatura([Numero da OF])

;******************************** IMPRESSAO CABECALHO ********************************

Print File ARQIMP "   * *  MERCEARIA DO TOIZINHO  * *"+"\n"
Switch
  Case Search("DEV",[Descricao da Destinacao])>0            : Print File ARQIMP Completa("DEVOLU€ŽO",25," ")
  Case Search("SIMPLES REMESSA",[Descricao da Destinacao])>0: Print File ARQIMP Completa("SIMPLES REMESSA",25," ")
  Case [Codigo da Destinacao]="005"                         : Print File ARQIMP Completa(SubStr([Descricao da Destinacao],1,24),25," ")
  Case Search("VEND",[Descricao da Destinacao])>0           : Print File ARQIMP Completa("OR€AMENTO",25," ")
  OtherWise                                                 : Print File ARQIMP Completa(SubStr([Descricao da Destinacao],1,24),25," ")
EndSwitch
Print File ARQIMP "Numero: "+Format("W06,AR",NOTAFISC)+"\n\n"

Print File ARQIMP "Emissao : "+Format("D13",Today())+"-"+Time()+"\n"
Print File ARQIMP "Vendedor: "+Format("W21,AL",[Nome Fantasia Represent])+"\n\n"

Print File ARQIMP "Cliente: "+[Codigo]+Spaces(08)+[CGC]+"\n"
Print File ARQIMP " "+SubStr([Razao Social],1,37)+"\n"
Print File ARQIMP " "+SubStr([Endereco    ],1,37)+"\n"
Print File ARQIMP " "+Completa([Bairro],24," ")+[CEP]+"\n"
Print File ARQIMP " "+Completa([UF]+"/"+[Cidade],23," ")+SubStr([Telefone],1,15)+"\n"

If Not IsBlank([Nome do Autorizado])
   Then Print File ARQIMP Completa("Autorizado",21," ")+[CPF do Autorizado]+"\n"
        Print File ARQIMP " "+SubStr([Nome do Autorizado],1,38)+"\n"
EndIf

Print File ARQIMP "\n"

;******************************** IMPRESSAO DOS ITENS ********************************
Print File ARQIMP "Produto Qtd Un      VrUnit      VrTotal"+"\n"
Print File ARQIMP "---------------------------------------"+"\n"

Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
   Print File ARQIMP Format("W11,AL",[Codigo do Item])+
                     Format("W28,AL",[Descricao do Item])+"\n"

   Print File ARQIMP Format("W11.3,EIC",[Quantidade])+" "+
                     Format("W03,AL",[Unidade Fiscal])+"x "+
                     Format("W09.2,EIC",[Preco Unitario])+" = "+
                     Format("W10.2,EIC",[Preco Total])+"\n"

   Skip
   If EOT() Then QuitLoop EndIf
EndWhile

Moveto "FaturaC"
Print File ARQIMP Spaces(29)+"----------"+"\n"
Print File ARQIMP Spaces(29)+Format("W10.2,EIC",[Valor Mercadoria])+"\n"
Print File ARQIMP Fill("-",39)+"\n"


;******************************** IMPRESSAO RODAPE *** ********************************
Print File ARQIMP "Vr.Mercadorias  Vr.Desconto  Vr a Pagar"+"\n"
Print File ARQIMP Format("W13.2,EIC",[Valor Mercadoria])+
                  Format("W13.2,EIC",[Valor Desconto])+
                  Format("W13.2,EIC",[Valor Nota Fiscal])+"\n"
Print File ARQIMP Spaces(29)+"----------"+"\n\n"

Print File ARQIMP "  -----------------------------------  "+"\n"
Print File ARQIMP "       Assinatura do Cliente           "+"\n\n"

Print File ARQIMP "Cond.Pagto: "+[Descricao CondPagto]+"\n"

Print File ARQIMP "Venctos"+"\n"

Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
If RetVal
   Then wcl=0
        LINHA=""
        While ([Numero da OF]=[FaturaC->Numero da OF])
          wcl=wcl+1
          LINHA=LINHA+Format("D10",[Data])+" "+Completa(LTrim(Format("W09.2,EIC",[Valor])),9," ")+" "
          If wcl=2
             Then Print File ARQIMP LINHA+"\n"
                  LINHA=""
                  wcl=0
          EndIf
          Skip
          If EOT() Then QuitLoop EndIf
        EndWhile
        If wcl>0
           Then Print File ARQIMP LINHA+"\n"
        EndIf
EndIf
Print File Arqimp "\n"

Moveto "FaturaC"
If Not IsBlank(VSD_E_Endereco) And VSD_E_Endereco<>"O MESMO"
   Then Print File Arqimp "Entregar"+"\n"
        Print File ARQIMP " "+SubStr(VSD_E_Endereco,1,38)+"\n"
        Print File ARQIMP " "+Completa(VSD_E_Bairro,24," ")+VSD_E_CEP+"\n"
        Print File ARQIMP " "+VSD_E_UF+"/"+VSD_E_Cidade+"\n"
EndIf

If Not IsBlank([Observacao na Nota Fiscal])
   Then Print File Arqimp "Obs"+"\n"

        nlobs=Len([FaturaC->Observacao na Nota Fiscal])/38
        If nlobs-Int(nlobs)>0
           Then nlobs=Int(nlobs)+1
           Else nlobs=Int(nlobs)
        EndIf

        posobs=1
        For i from 1 to nlobs
          Print File ARQIMP " "+SubStr([Observacao na Nota Fiscal],posobs,38)+"\n"
          posobs=posobs+38
        EndFor
EndIf

Print File ARQIMP "---------------------------------------"+"\n"
Print File ARQIMP "      AGRADECEMOS A PREFERENCIA        "+"\n"
Print File ARQIMP "NAO VALE COMO NF PROCURE CUPOM NO CAIXA"+"\n"
Print File ARQIMP "---------------------------------------"+"\n\n\n\n\n"

EndProc ; (IMPRO)

;*******************************************************************************
;* Rotina Principal                                                            *
;*****************+*************************************************************
ArqImp=PrivDir()+"Ro_Elgin.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)
IMPRO()

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)

Release Vars posobs,nlobs,LINHA,wcl
Release Procs IMPRO
LIMPAGUARDE()

