;** Rm_0091  *******************************************************************
;*  Emissao de Cheques em Liquidado Conta/Descontado                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 24/06/09 por Humberto F.Santos.
;Ultima Alteracao: 28/12/2015 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes corre‡Æo gerais
;Ultima Alteracao: 09/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 05/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro de observa‡Æo e valor 
;Ultima Alteracao: 06/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes exibir cliente do cheque    
;Ultima Alteracao: 17/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes inclusÆo depositado            
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog      
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()

ClearAll

  If IsTable("\\Sistemas\\CheqRec\\"+Dir_Trab+"BordChc") And 
     IsTable("\\Sistemas\\Cheqrec\\"+Dir_Trab+"BordChi")
      Then  {Ask} TypeIn "\\Sistemas\\CheqRec\\"+Dir_Trab+"BordChc" Enter Check
       
        Moveto [Numero do Lote        ]  Example "b"
        Moveto [Codigo da Empresa     ]  TypeIn  "~VSDGEMPRESA2.."
        Moveto [Codigo da Conta Trf   ]  TypeIn "~VSDGCONTA.."
        Moveto [Tipo de Destino       ]  
        switch
          case VSDGOPCAO[1]=True and VSDGOPCAO[2]=True: TypeIn "DESCONT.. or DEPOSIT.."
          case VSDGOPCAO[1]=True                      : TypeIn "DESCONT.."
          case VSDGOPCAO[2]=True                      : TypeIn "DEPOSIT.."
        endswitch
        Moveto [Observacao do Lote    ]  TypeIn VSDGOBS
        {Ask} TypeIn "\\Sistemas\\CheqRec\\"+Dir_Trab+"BordChi" Enter Check
        Moveto [Numero do Lote        ] Example "b"
        Moveto [Data Vencimento       ] TypeIn  ">=~VSDGDTINI ,<=~VSDGDTFIM" 
        Moveto [Valor                 ] TypeIn  VSDGVALOR 
        Do_It!
        ClearAll

        {Ask} {Answer} Check
        moveto [Codigo_Cliente        ] typein "_cclie!"
        {Ask} {\\Sistemas\\Cadastro\\Destinat} 
        moveto [Codigo                ] Check typein "_cclie, as PessoaResponsavelCodigo"
        moveto [Razao Social          ] Check Typein         "as PessoaResponsavelNome"
        Do_It!
        ClearAll

EndIf
EndProc      ; (Seleciona)

;*******************************************************************************
;* Rotina para Processar  Registros                                            *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_OBS"           : Campo="TG_CONTA"
            Case Campo="TG_VALOR"         : Campo="TG_OBS"
            Case Campo="TG_DTINI"         : Campo="TG_VALOR"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPCOES"        : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : Campo="TG_OBS"
                    Case Campo="TG_OBS"        : Campo="TG_VALOR"
                      VSDGOBS=controlvalue("TG_OBS")
                    Case Campo="TG_VALOR"      : Campo="TG_DTINI"
                      VSDGVALOR=controlvalue("TG_VALOR")
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_OPCOES"
                    Case Campo="TG_OPCOES"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_OBS":
       MSG_CAMPO="Use .. como no CTRL+Z para filtrar a observa‡Æo !"
  Case Campo="TG_VALOR":
       MSG_CAMPO="Informe se necessario o valor do cheque para filtrar !"
  Case Campo="TG_OPCOES":
       MensagemCheckBoxes()
Endswitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
VSDGCONTA=""
VSDGEMPRESA=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

VSDGOBS    =""
VSDGVALOR  =Blanknum()

Array VSDGOPCAO[2]

VSDGOPCAO[1]= True
VSDGOPCAO[2]= True

While True
  ShowDialog "Rela‡„o de Cheques Descontados/Depositados por Conta" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 03,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA

    Label  @ 04,00 "Observa‡Æo do Border“"  For "TG_OBS"
    Accept @ 05,01 Width 33 "A100"  Picture "!*!" Tag "TG_OBS"    To VSDGOBS

    Label  @ 06,00 "Valor do Cheque"  For "TG_VALOR"
    Accept @ 07,03 Width 13 "$"                   Tag "TG_VALOR"    To VSDGVALOR
   
    Label  @ 08,00 "Per¡odo Vencimento Cheque de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡”es de Destino " For "TG_OPCOES"
    CheckBoxes @1,35 Height 3 Width 20 Tag "TG_OPCOES"
    "Descontados" to VSDGOPCAO[1],
    "Depositados" to VSDGOPCAO[2]

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  If VSDGOPCAO[1]=false or VSDGOPCAO[2]=false
     Then Mensagem("Op‡Æo de Destino inv lida, nÆo selecionado !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  CopyReport "\\Base\\Sistemas\\CheqRec\\Rm_0013" "R" Tabela "R"

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
