;** CB_0008 ********************************************************************
;* Carta de Cobranca VIII                                                      *
;*******************************************************************************
;Desenvolvido  em: 15/01/2010 por Cleber Alves
;Alterado em     :   /  /     por
;Motivo Alteracao:

;*******************************************************************************
;* Rotina para Impressao do Cabecalho da Carta                                 *
;*******************************************************************************
Proc IMPCAB_CARTA()

NFOLHA=NFOLHA+1

Print File ARQIMP "\n\n\n"

;Print File ARQIMP CI_INEG+Format("W80,AC",EMP_NOMF)+CI_FNEG+"\n\n\n"

Print File ARQIMP Spaces(03)+EMP_CID+", "+
                  StrVal(Day(Today()))+" DE "+
                  RTrim(MesExt(Month(Today())))+" DE "+
                  StrVal(Year(Today()))+"\n\n"

Print File ARQIMP Spaces(03)+"Ilmo(a) Sr(a) "+CI_INEG+CLI_RAZ+CI_FNEG+".\n\n\n"

Print File ARQIMP Spaces(03)+"   Tendo em vista que, at‚ a presente data, nosso sistema  n„o  acusou  o"+"\n"
Print File ARQIMP Spaces(03)+"pagamento da(s) sua(s) presta‡Æo (s)  vencidas  conforme  rela‡Æo  abaixo"+"\n"
Print File ARQIMP Spaces(03)+"e aviso emitido anteriormente, solicitamos que sejam tomadas  as  devidas"+"\n"
Print File ARQIMP Spaces(03)+"providˆncias para quita‡„o desse(s) d‚bito(s)."+"\n\n"

Print File ARQIMP Spaces(03)+"   Contamos com sua colabora‡„o para entrar em contato com nosso setor de"+"\n"
Print File ARQIMP Spaces(03)+"cobran‡a no prazo m ximo de 03  dias  £teis  ap¢s  o  recebimento  desta,"+"\n"
Print File ARQIMP Spaces(03)+"evitando assim, que seu cadastro seja encaminhado ao SPC e ao nosso setor"+"\n"
Print File ARQIMP Spaces(03)+"de cobran‡a judicial (advocacia)."+"\n\n"

Print File ARQIMP Spaces(03)+"   Evite problemas desnecess rios ! Procure-nos imediatamente."+"\n\n\n"


Print File ARQIMP Spaces(03)+"Atenciosamente, --------------------"+"\n"
Print File ARQIMP Spaces(03)+"                "+Format("W20,AC",EMP_NOMF)+"\n\n"


Print File ARQIMP Spaces(03)+"D‚bitos Vencidos"+" - FOLHA: "+StrVal(NFOLHA)+"\n"
Print File ARQIMP Fill("-",80)+"\n"

LINHA1="   Numero       Data       Valor     Valor  Dias   "
LINHA2="   Documento   Vencto      Total  Original  Atraso "
         ;1234567890 99/99/99 99.999,99 99.999,99  99.999 1234567890


Print File ARQIMP LINHA1+"\n"
Print File ARQIMP LINHA2+"\n"

Nl=27
EndProc

;*******************************************************************************
;* Rotina para Impressao dos Titulos da Carta                                  *
;*******************************************************************************
Proc IMPTIT_CARTA()

If (Today()-[Data de Vencimento])<= 0
   Then DAtraso = "  EM ABERTO"
   Else DAtraso = Format("W8,EIC",Today()-[Data de Vencimento]) 
EndIF

Print File ARQIMP Spaces(03)+Format("W11,AL",[Numero do Documento])
Print File ARQIMP Format("D10",[Data de Vencimento])
Print File ARQIMP Format("W10.2,EIC",[Valor do Documento])
Print File ARQIMP Format("W10.2,EIC",[Saldo do Documento])
Print File ARQIMP DAtraso

Print File ARQIMP "\n"

nl=nl+1

EndProc

;*******************************************************************************
;* Rotina para Impressao nova Folha                                            *
;*******************************************************************************
Proc IMPNOVA_FOLHA()

NFOLHA=NFOLHA+1
Print File ARQIMP CI_INEG+" * Continua Pr¢xima Folha -> "+StrVAl(NFOLHA)+CI_FNEG+"\f"

Print File ARQIMP "\n"  
Print File ARQIMP Spaces(65)+"Folha: "+StrVAl(NFOLHA)+"\n\n"
nl=3
EndProc

;*******************************************************************************
;* Rotina para Impressao do Rodape da Carta                                    *
;*******************************************************************************
Proc IMPROD_CARTA()

Print File ARQIMP SPACES(02)+" TOTAL ->"+CI_INEG+Format("W10.2,EIC,AL",TOTVR)+CI_FNEG+"\n"
nl=nl+1

if nl>48
   Then IMPNOVA_FOLHA()
EndIF

Print File ARQIMP Fill("-",80)+"\n\n"
Print File ARQIMP Spaces(03)+ CI_INEG+"* Os valores em atraso ser„o reajustados ap¢s a data de vencimento."+CI_FNEG+"\n\n"

Print File ARQIMP Spaces(03)+ CI_INEG+"* Aten‡„o: Caso j  tenha efetuado o pagamento, favor ignorar este aviso."+CI_FNEG+"\n\n\n"

Print File ARQIMP "   Ilmo(a) Sr(a)"+"\n\n"

Print File ARQIMP "   "+CLI_RAZ +" - "+CODCLIANT+"\n"
Print File ARQIMP "   "+CLI_END +"\n"
Print File ARQIMP "   "+CLI_BAIR+" - "+CLI_CEP+"\n"
Print File ARQIMP "   "+CLI_CID +"/"+CLI_UF+"\n\n"

Print File ARQIMP Fill("-",80)+"\n"

Print File ARQIMP "   "+EMP_RAZ +"\n"
Print File ARQIMP "   "+EMP_END +" - "
Print File ARQIMP "   "+EMP_BAIR+" - "+EMP_CEP+"\n"
Print File ARQIMP "   "+EMP_CID +"/"+EMP_UF+" - "+EMP_FONE

Print File ARQIMP "\f"

EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Seta_FilePrint("CB_0008")

AGUARDE("Imprimindo Carta de Cobran‡a")

CODEMPANT="***"
CODCLIANT="***"
CoEdit "Answer"
Scan

  If [Codigo da Empresa]<>CODEMPANT
     Then CODEMPANT=[Codigo da Empresa]

          Moveto [Codigo da Empresa]
          If Busca_Lookup("Codigo da Empresa",[Codigo da Empresa],"SM")
             Then EMP_NOMF=REG_BUSCA_LOOKUP["Nome Fantasia Empresa"]
                  EMP_RAZ =REG_BUSCA_LOOKUP["Razao Social Empresa" ]
                  EMP_END =REG_BUSCA_LOOKUP["Endereco Empresa"     ]
                  EMP_BAIR=REG_BUSCA_LOOKUP["Bairro Empresa"       ]
                  EMP_CID =REG_BUSCA_LOOKUP["Cidade Empresa"       ]
                  EMP_UF  =REG_BUSCA_LOOKUP["UF Empresa"           ]
                  EMP_CEP =REG_BUSCA_LOOKUP["CEP Empresa"          ]
                  EMP_FONE=REG_BUSCA_LOOKUP["Telefone Empresa"     ]
                  EMP_CONT=REG_BUSCA_LOOKUP["Contato Empresa"      ]
                  
          EndIf
  EndIf

  If [Codigo do Destinatario]<>CODCLIANT
     Then
          If CODCLIANT<>"***"
             Then IMPROD_CARTA()
          EndIf

          CODCLIANT=[Codigo do Destinatario]
          NFOLHA   =0
          TOTVR    =0
          ORIVR    =0
          JURVR    =0
          NTIT     =0
          Moveto [Codigo do Destinatario]
          If Busca_Lookup("Codigo",[Codigo do Destinatario],"SM")
             Then CLI_RAZ =REG_BUSCA_LOOKUP["Razao Social"]
                  CLI_END =REG_BUSCA_LOOKUP["Endereco"]
                  CLI_BAIR=REG_BUSCA_LOOKUP["Bairro"]
                  CLI_CID =REG_BUSCA_LOOKUP["Cidade"]
                  CLI_UF  =REG_BUSCA_LOOKUP["UF"]
                  CLI_CEP =REG_BUSCA_LOOKUP["CEP"]
                  CLI_FONE=REG_BUSCA_LOOKUP["Telefone"]
             Else CLI_RAZ ="????"
                  CLI_END =""
                  CLI_BAIR=""
                  CLI_CID =""
                  CLI_UF  =""
                  CLI_CEP =""
                  CLI_FONE=""
          EndIf
          IMPCAB_CARTA()
  EndIf

  If nl>60
     Then IMPNOVA_FOLHA()
  EndIf
 
  ImpTit_Carta()

  NTIT=NTIT+1
  ORIVR=ORIVR+[Saldo do Documento]
  TOTVR=TOTVR+[Valor do Documento]
  JURVR=JURVR+[Valor do Desconto]

EndScan
IMPROD_CARTA()
Do_It!
ClearAll

ImpriArq(ARQIMP)

LIMPAGUARDE()
Release Vars NL,NTIT,TOTVR,ORIVR,JURVR
Release Procs IMPCAB_Carta,IMPTit_Carta, ImpRod_Carta, IMPNOVA_FOLHA
