;** Ft_Cf *****************************************************************************
;*  Monta Nota Fiscal dos Cupons em Aberto (Contas a Receber) ; Executado pelo Fatura *
;**************************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 21/08/2000 por Douglas Rodrigues
;Ultima Alteracao: 03/09/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes CUP..
;Ultima Alteracao: 19/10/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cupom
;Ultima Alteracao: 07/12/2015 por Anivel Augusto Rodrigues
;Motivo Alteracao: exclusao referencia ao campo INSS
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\CtaRec\\Duplic}
Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA"
Moveto [Numero do Documento    ] Check
Moveto [Tipo do Documento      ] TypeIn "CUP.."
Moveto [Serie do Documento     ] Check
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Codigo do Destinatario ] TypeIn "~VSDGDESTINAT"
Moveto [Saldo do Documento     ] TypeIn ">0.01"
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

OBS_NF=""
Wc=""
View "Answer"
If NRecords("Answer")=1
   Then OBS_NF="Conforme Cupom Fiscal-> "+[Numero do Documento]
   Else Scan
          If RecNo()=1
             Then Wc=[Numero do Documento]
             Else Wc=Wc+", "+[Numero do Documento]
          EndIf
         EndScan
         OBS_NF="Conforme Cupons Fiscais-> "+Wc
EndIf
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "emp"
Moveto [Numero do Documento    ] Example "numero"
Moveto [Serie do Documento     ] Example "serie"
{Ask} {NotaI} Check
Moveto [Codigo da Empresa      ] Example "emp"
Moveto [Numero do Documento    ] Example "numero"
Moveto [Serie do Documento     ] Example "serie"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo do Item          ] Check
Moveto [Quantidade              ] TypeIn "Calc Sum as Quantidade"
Moveto [Preco Unitario          ] Check
Moveto [Tributacao de IPI       ] Check
Moveto [Aliquota Reduzida BCIPI ] Check
Moveto [Aliquota de IPI         ] Check
Moveto [Tributacao de ICMS      ] Check
Moveto [Aliquota Reduzida BCICMS] Check
Moveto [Aliquota de ICMS        ] Check
Moveto [Tributacao de ISSQN     ] Check
Moveto [Aliquota de ISSQN       ] Check
Do_It!
ClearAll

EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina Geracao dos Dados da FaturaI,FaturaC                                 *
;*******************************************************************************
Proc Gera_NF()

SEQ = 1
CoEdit "\\Sistemas\\Estoque\\Itens","Answer","FaturaI","FaturaC"

Moveto "FaturaI"
Moveto [Numero da Of]
Locate ORDFAT
If RetVal
   Then While True
          Del
          Locate Next ORDFAT
          If Not RetVal
             Then QuitLoop
          EndIf
        EndWhile
EndIf
Moveto "FaturaC"
Moveto [Numero da OF]
Locate ORDFAT
Moveto "Answer"
Scan
  Moveto "FaturaI"
  End
  Down
  [Numero da OF            ]=ORDFAT
  [Item da OF              ]=SEQ
  [Numero Pedido_Orcamento ]=""
;  [Item Pedido_Orcamento   ]=
  [Codigo do Item          ]=[Answer->Codigo do Item]
  [Quantidade              ]=[Answer->Quantidade    ]
  [Preco Unitario          ]=[Answer->Preco Unitario]
  [Preco Total             ]=[Answer->Quantidade]*[Answer->Preco Unitario]
  [Preco Unitario Tabela   ]=[Preco Unitario]
  [Tributacao de IPI       ]=[Answer->Tributacao de IPI       ]
  [Aliquota Reduzida BCIPI ]=[Answer->Aliquota Reduzida BCIPI ]
  [Aliquota de IPI         ]=[Answer->Aliquota de IPI         ]
  [Valor do IPI            ]=NDecimal(([Preco Total]*[Aliquota de IPI])/100,2)
  [Tributacao de ICMS      ]=[Answer->Tributacao de ICMS      ]
  [Aliquota Reduzida BCICMS]=[Answer->Aliquota Reduzida BCICMS]
  [Aliquota de ICMS        ]=[Answer->Aliquota de ICMS        ]
  [Valor do ICMS           ]=NDecimal(([Preco Total]*[Aliquota de ICMS])/100,2)
  [Tributacao de ISSQN     ]=[Answer->Tributacao de ISSQN     ]
  [Aliquota de ISSQN       ]=[Answer->Aliquota de ISSQN       ]
  [Valor do ISSQN          ]=NDecimal(([Preco Total]*[Aliquota de ISSQN])/100,2)
  SEQ=SEQ+1
  Moveto "Answer"
EndScan
Moveto "FaturaC"
Moveto [Numero da OF]
Locate ORDFAT
[Codigo                   ]=VSDGDESTINAT
If IsBlank([Observacao na Nota Fiscal])
   Then [Observacao na Nota Fiscal]=OBS_NF
   Else [Observacao na Nota Fiscal]=[Observacao na Nota Fiscal]+" "+OBS_NF
EndIf
Do_It!
ClearAll
EndProc  ; (Gera_NF)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If INICIO_DIALOG
   Then Campo="TG_DESTINAT"
        INICIO_DIALOG=False
EndIf

If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_DESTINAT"      : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_DESTINAT"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_DESTINAT":
                         If Not IsBlank(VSDGDESTINAT)
                            Then Campo="TG_DTINI"
                            Else VSDGNOMDEST=""
                         EndIf
                    Case Campo="TG_DTINI"   :
                         If Not IsBlank(VSDGDTINI)
                            Then Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM" :
                         If Not IsBlank(VSDGDTFIM)
                            Then Campo="YES"
                         EndIf
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DESTINAT":
       MSG_CAMPO="Informe o Cliente"
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a Data Inicial"
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
LimpAguarde()

VSDGEMPRESA  = [FaturaC->Codigo da Empresa     ]
VSDGNOMEMP   = [FaturaC->Nome Fantasia Empresa ]
VSDGDESTINAT = [FaturaC->Codigo                ]
VSDGNOMDEST  = [FaturaC->Nome Fantasia EmitDest]
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()
INICIO_DIALOG= True
ClearAll
Echo Normal
Echo Off

While True

  ShowDialog "Relaciona Cupons Fiscais para montar Nota Fiscal" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB"
   @ 05,12   Height 11 Width 56

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 04,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "at‚" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 07,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  Confirma()
  If OK="N" Then Loop EndIf

  AGUARDE("Aguarde, gerando dados")
  Seleciona()

  If IsEmpty("Answer")
     Then Mensagem("N„o existem registros a processar")
          INICIO_DIALOG=True
          Loop
  EndIf

  Gera_NF()
  ClearAll
  If IsTable("Answer")
     Then Delete "Answer"
  EndIf
  QuitLoop

EndWhile
ClearAll
Release Vars VSDGEMPRESA,VSDGNOMEMP,VSDGDESTINAT,VSDGNOMDEST,VSDGDTINI,VSDGDTFIM,OBS_NF,SEQ
Release Procs Seleciona,Gera_NF,SD_Dialog

