;** Expentit *******************************************************************
;*  Geracao dos Itens de Entrada                                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 15/10/2004 por Jos LuĦs Ameno da Silva
;Ultima Alteracao: 20/08/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desprezar item notai cancalado

;*******************************************************************************
;* Rotina p/ Selecionar Registros Vendas                                       *
;*******************************************************************************
Proc GERA()

ClearAll
{Ask} TypeIn Dir_Buscag + "NotaC" Enter
Moveto [UF                       ] Check
Moveto [Data de Emissao          ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Codigo da Empresa        ] Check Example "ce" TypeIn ", ~VSDGEMPRESA.."
Moveto [Numero do Documento      ] Check Example "nd"
Moveto [Serie do Documento       ] Check Example "sd"
Moveto [Tipo Movimento Estoque   ] TypeIn "E"

{Ask} TypeIn Dir_Buscag + "NotaI" Enter
Moveto [Codigo da Empresa        ] Example "ce"
Moveto [Numero do Documento      ] Example "nd"
Moveto [Serie do Documento       ] Example "sd"
Moveto [NCM                      ] Check
Moveto [Unidade Fiscal           ] Check
Moveto [Quantidade               ] Check
Moveto [Preco Total              ] Check
Moveto [Aliquota de IPI          ] Check
Moveto [Valor do IPI             ] Check
Moveto [CFO                      ] Check
Moveto [Codigo do Item           ] Check Example "it"
Moveto [Tipo Tributacao          ] Check
Moveto [Valor Desconto Total     ] Check
Moveto [Aliquota de ICMS         ] Check
Moveto [Descricao do Item        ] Check
Moveto [Aliquota Reduzida BCICMS ] Check
Moveto [Situacao_Item            ] TypeIn "Not C"

{Ask} TypeIn "\\Sistemas\\Estoque\\Itens" Enter
Moveto [Codigo do Item           ] Example "it"
Moveto [Codigo de Barras         ] Check

Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

If Not IsTable("\\Sistemas\\Exporta\\It1TempE")
   Then Rename "Answer" "\\Sistemas\\Exporta\\It1TempE"
   Else Add "Answer" "\\Sistemas\\Exporta\\It1TempE"
EndIf

EndProc

;*******************************************************************************
;* Rotina p/ Selecionar Registros Estoque                                      *
;*******************************************************************************
Proc GERA2()

ClearAll
{Ask} TypeIn Dir_Buscag + "NotaEC" Enter
Moveto [UF                       ] Check
Moveto [Data de Emissao          ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Codigo da Empresa        ] Check Example "ce" TypeIn ", ~VSDGEMPRESA.."
Moveto [Numero do Documento      ] Check
Moveto [Serie do Documento       ] Check
Moveto [Numero do Lancamento     ] Example "nl"

{Ask} TypeIn Dir_Buscag + "NotaEI" Enter
Moveto [Numero do Lancamento     ] Example "nl"
Moveto [Codigo da Empresa        ] Example "ce"
Moveto [NCM                      ] Check
Moveto [Unidade Fiscal           ] Check
Moveto [Quantidade               ] Check
Moveto [Preco Total              ] Check
Moveto [Aliquota de IPI          ] Check
Moveto [Valor do IPI             ] Check
Moveto [CFO                      ] Check
Moveto [Codigo do Item           ] Check Example "it"
Moveto [Tipo Tributacao          ] Check
Moveto [Valor Desconto Total     ] Check
Moveto [Aliquota de ICMS         ] Check
Moveto [Descricao do Item        ] Check
Moveto [Aliquota Reduzida BCICMS ] Check

{Ask} TypeIn "\\Sistemas\\Estoque\\Itens" Enter
Moveto [Codigo do Item           ] Example "it"
Moveto [Codigo de Barras         ] Check

Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

If Not IsTable("\\Sistemas\\Exporta\\It2TempE")
   Then Rename "Answer" "\\Sistemas\\Exporta\\It2TempE"
   Else Add "Answer" "\\Sistemas\\Exporta\\It2TempE"
EndIf

EndProc


;*****************************************************************************************
;* Rotina principal
;*****************************************************************************************
LimpAguarde()
Aguarde("Aguarde, Processando Dados Entradas")

View "\\Sistemas\\Estoque\\Itens"

If IsTable("\\Sistemas\\Exporta\\It_TempE")
   Then Empty "\\Sistemas\\Exporta\\It_TempE"
   Else Copy "\\Base\\Sistemas\\Exporta\\It_TempE" "\\Sistemas\\Exporta\\It_TempE"
EndIf
If IsTable("\\Sistemas\\Exporta\\It1TempE")
   Then Empty "\\Sistemas\\Exporta\\It1TempE"
EndIf
If IsTable("\\Sistemas\\Exporta\\It2TempE")
   Then Empty "\\Sistemas\\Exporta\\It2TempE"
EndIf

SetDir "\\Sistemas\\Vendas\\"
Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()

  If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")
     Then Dir_Buscag  = "\\Sistemas\\Vendas\\"+Dir_Trab
          Gera()
  EndIf

EndWhile

SetDir "\\Sistemas\\Estoque\\"
Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()

  If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC")
     Then Dir_Buscag  = "\\Sistemas\\Estoque\\"+Dir_Trab
          Gera2()
  EndIf

EndWhile

SetDir "\\Sistemas\\Exporta"
View "\\Sistemas\\Exporta\\It_TempE"

If IsTable("\\Sistemas\\Exporta\\It1TempE") And Not IsEmpty("\\Sistemas\\Exporta\\It1TempE")
   Then Coedit "\\Sistemas\\Exporta\\It1TempE"
        NR=NRecords("\\Sistemas\\Exporta\\It1TempE")
        Barra(NR, RecNo())
        AGUARDE("Aguarde, Exportando Entradas-Vendas "+BARRA_STRING)
        Scan
           Moveto "\\Sistemas\\Exporta\\It_TempE"
           End Down
           [Codigo da Empresa       ]=[It1TempE->Codigo da Empresa]
           [Numero do Documento     ]=[It1TempE->Numero do Documento]
           [Serie do Documento      ]=[It1TempE->Serie do Documento]
           [Data de Emissao         ]=[It1TempE->Data de Emissao]
           [UF                      ]=[It1TempE->UF]
           [Codigo do Item          ]=[It1TempE->Codigo do Item]
           [Descricao do Item       ]=[It1TempE->Descricao do Item]
           [Quantidade              ]=[It1TempE->Quantidade]
           [Unidade Fiscal          ]=[It1TempE->Unidade Fiscal]
           [Preco Total             ]=[It1TempE->Preco Total]
           [Aliquota de IPI         ]=[It1TempE->Aliquota de IPI]
           [Valor do IPI            ]=[It1TempE->Valor do IPI]
           [Aliquota Reduzida BCICMS]=[It1TempE->Aliquota Reduzida BCICMS]
           [Aliquota de ICMS        ]=[It1TempE->Aliquota de ICMS]
           [Valor Desconto Total    ]=[It1TempE->Valor Desconto Total]
           [Tipo Tributacao         ]=[It1TempE->Tipo Tributacao]
           [CFO                     ]=[It1TempE->CFO]
           [NCM                     ]=[It1TempE->NCM]
           [Codigo de Barras        ]=[It1TempE->Codigo de Barras]
           Moveto "\\Sistemas\\Exporta\\It1TempE"
        EndScan
EndIf

Do_It!

If IsTable("\\Sistemas\\Exporta\\It2TempE") And  Not IsEmpty("\\Sistemas\\Exporta\\It2TempE")
   Then Coedit "\\Sistemas\\Exporta\\It2TempE"
        NR=NRecords("\\Sistemas\\Exporta\\It2TempE")
        Barra(NR, RecNo())
        AGUARDE("Aguarde, Exportando Entradas-Estoque "+BARRA_STRING)
        Scan
           Moveto "\\Sistemas\\Exporta\\It_TempE"
           End Down
           [Codigo da Empresa       ]=[It2TempE->Codigo da Empresa]
           [Numero do Documento     ]=[It2TempE->Numero do Documento]
           [Serie do Documento      ]=[It2TempE->Serie do Documento]
           [Data de Emissao         ]=[It2TempE->Data de Emissao]
           [UF                      ]=[It2TempE->UF]
           [Codigo do Item          ]=[It2TempE->Codigo do Item]
           [Descricao do Item       ]=[It2TempE->Descricao do Item]
           [Quantidade              ]=[It2TempE->Quantidade]
           [Unidade Fiscal          ]=[It2TempE->Unidade Fiscal]
           [Preco Total             ]=[It2TempE->Preco Total]
           [Aliquota de IPI         ]=[It2TempE->Aliquota de IPI]
           [Valor do IPI            ]=[It2TempE->Valor do IPI]
           [Aliquota Reduzida BCICMS]=[It2TempE->Aliquota Reduzida BCICMS]
           [Aliquota de ICMS        ]=[It2TempE->Aliquota de ICMS]
           [Valor Desconto Total    ]=[It2TempE->Valor Desconto Total]
           [Tipo Tributacao         ]=[It2TempE->Tipo Tributacao]
           [CFO                     ]=[It2TempE->CFO]
           [NCM                     ]=[It2TempE->NCM]
           [Codigo de Barras        ]=[It2TempE->Codigo de Barras]
           Moveto "\\Sistemas\\Exporta\\It2TempE"
        EndScan
EndIf
Do_It!
ClearAll
If IsTable("\\Sistemas\\Exporta\\It1TempE")
   Then Delete("\\Sistemas\\Exporta\\It1TempE")
Endif
If IsTable("\\Sistemas\\Exporta\\It2TempE")
   Then Delete("\\Sistemas\\Exporta\\It2TempE")
Endif
LimpAguarde()
Release Procs GERA,GERA2

