;** Voltames *******************************************************************
;*  Programa p/ Restauracao de Meses Fechados                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 09/04/2014 por Andrey Fillipe            
;Ultima Alteracao:   /  /     por                          
;Motivo Alteracao:                                  

;*******************************************************************************
; Mdfe_C/Mdfe_mdd/Mdfe_rvc/Mdfe_rvp/Mdfe_rvr/Mdfe_uc/Mdfe_ut/                  *
;*******************************************************************************
Proc MANIFESTOS()
ClearAll
MSG_AGUARDE="Aguarde, restaurando manifestos emitidos "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(8,1))
If IsTable("Mdfe_C")
   Then {Ask} {Mdfe_C} Check
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        Do_It!
        ClearAll
        If IsEmpty("Answer")
           Then Mensagem("Mˆs sem movimenta‡„o p/ Manifesto Eletronico !")
                Return
           Else Rename "Answer" "MDFETemp"
                ClearAll
        EndIf
   Else Mensagem("Tabela [Mdfe_C] n„o encontrada !")
        Return
EndIf

Aguarde(MSG_AGUARDE+Barra(8,2))
If IsTable("Mdfe_mdd") And
   IsTable("Mdfe_C")
   Then {Ask} {Mdfe_C}
        Moveto [Numero da OM] Example "DOCTO"
        
        {Ask} {Mdfe_mdd} Check
        Moveto [Numero da OM] Example "DOCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","Mdfe_mdd")
EndIf

Aguarde(MSG_AGUARDE+Barra(8,3))
If IsTable("Mdfe_rvc") And
   IsTable("Mdfe_C")
   Then {Ask} {Mdfe_C}
        Moveto [Numero da OM] Example "DOCTO"
        
        {Ask} {Mdfe_rvc} Check
        Moveto [Numero da OM] Example "DOCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","Mdfe_rvc")
EndIf

Aguarde(MSG_AGUARDE+Barra(8,4))
If IsTable("Mdfe_rvp") And
   IsTable("Mdfe_C")
   Then {Ask} {Mdfe_C}
        Moveto [Numero da OM] Example "DOCTO"
        
        {Ask} {Mdfe_rvp} Check
        Moveto [Numero da OM] Example "DOCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","Mdfe_rvp")
EndIf

Aguarde(MSG_AGUARDE+Barra(8,5))
If IsTable("Mdfe_rvr") And
   IsTable("Mdfe_C")
   Then {Ask} {Mdfe_C}
        Moveto [Numero da OM] Example "DOCTO"
        
        {Ask} {Mdfe_rvr} Check
        Moveto [Numero da OM] Example "DOCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","Mdfe_rvr")
EndIf

Aguarde(MSG_AGUARDE+Barra(8,6))
If IsTable("Mdfe_uc") And
   IsTable("Mdfe_C")
   Then {Ask} {Mdfe_C}
        Moveto [Numero da OM] Example "DOCTO"
        
        {Ask} {Mdfe_uc} Check
        Moveto [Numero da OM] Example "DOCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","Mdfe_uc")
EndIf

Aguarde(MSG_AGUARDE+Barra(8,7))
If IsTable("Mdfe_ut") And
   IsTable("Mdfe_C")
   Then {Ask} {Mdfe_C}
        Moveto [Numero da OM] Example "DOCTO"
        
        {Ask} {Mdfe_ut} Check
        Moveto [Numero da OM] Example "DOCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","Mdfe_ut")
EndIf

Aguarde(MSG_AGUARDE+Barra(8,8))
Add_Sub_Rest_Tabela("MDFETemp","Mdfe_C")

EndProc

;*******************************************************************************
;* Rotina Add/Subtract/Reestruct                                               *
;*******************************************************************************
Proc Add_Sub_Rest_Tabela(TABORIG,TABDEST)
Private TABORIG,TABDEST

Add TABORIG Diretorio+TABDEST ClearImage
SaveTables

Subtract TABORIG TABDEST ClearImage
SaveTables

{Modify} {Restructure} TypeIn TABDEST Enter Do_It! ClearImage
Delete TABORIG
SAVETABLES

EndProc

;*******************************************************************************
;* Rotina Bloqueia Tabelas da Pasta                                            *
;*******************************************************************************
Proc BloqueiaTabelas(Pasta)
Private MSG, Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then Lock Pasta+Array_Tabelas[i] FL
          If Not RetVal
             Then MSG="O usu rio "+Upper(ErrorUser())+" esta usando o Sistema !// //"
                  MSG=MSG+Completa("- Contact -lo para liberar o Sistema;",40," ")+"//"
                  MSG=MSG+Completa("- Esta rotina ser  abortado.",40," ")+"// //"
                  MSG=MSG+"Execute esta rotina novamente para que//"
                  MSG=MSG+"a mesma seja concluida corretamente !"
                  Mensagem(MSG)
                  Return False
          EndIf
  EndIf
EndFor

Return True
EndProc

;*******************************************************************************
;* Rotina Desbloqueia Tabelas da Pasta                                         *
;*******************************************************************************
Proc DesbloqueiaTabelas(Pasta)
Private Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then UnLock Pasta+Array_Tabelas[i] FL
  EndIf
EndFor

EndProc

;*******************************************************************************
;* Rotina Monta Lista de Tabelas a Processar                                   *
;*******************************************************************************
Proc ListadeTabelas()
If IsAssigned(Array_Tabelas)
   Then Release Vars Array_Tabelas
EndIf
DynArray Array_Tabelas[]

Array_Tabelas[01]="Mdfe_C"
Array_Tabelas[02]="Mdfe_mdd"
Array_Tabelas[03]="Mdfe_rvc"
Array_Tabelas[04]="Mdfe_rvp"
Array_Tabelas[05]="Mdfe_rvr"
Array_Tabelas[06]="Mdfe_uc"
Array_Tabelas[07]="Mdfe_ut"

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DIRETORIOS"    : Campo="TG_EMPRESA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
          SYS_TECLA_ACIONADA=Evento["KeyCode"]
          Seta_Tecla_Acionada()
          CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_DIRETORIOS"
                    Case Campo="TG_DIRETORIOS" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_RADIO":
       TECLA="=Selecionar"
       MSG_CAMPO="Selecione a Op‡„o desejada !"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""

While True
  Diretorio="\\Sistemas\\Mdfe\\"
  Diretorios_Fechames(Diretorio)

  ShowDialog "Restaura‡Æo mensal [ MDFE ]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 04,17   Height 19 Width 75

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 0,09 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 0,16 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    PickDynArray @2,01 Height 12 width 69
     Columns 7
      Array_Diretorios
       Tag "TG_DIRETORIOS"
        To ArrayElement
    Label @ 01,00 "Ano_Mes em aberto"  For "TG_DIRETORIOS"

    Pushbutton @ 15,24 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,38 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If DynArraySize(Array_Diretorios)<1
     Then Mensagem("Sem Pasta fechames !")
          Loop
  EndIf

  ANO_MES=Array_Diretorios[ArrayElement]

  Diretorio="\\Sistemas\\Mdfe\\"
  DiretorioFechames=Diretorio+"Fechames\\"+ANO_MES+"\\"
  If DirExists(DiretorioFechames)=0
     Then Mensagem("N„o existe a pasta do "+ANO_MES+" selecionado !")
          Loop
  EndIf

  If Not Verifica_Usuario() Then Loop EndIf
  ListadeTabelas()
  If (BloqueiaTabelas(Diretorio)) And
     (BloqueiaTabelas(DiretorioFechaMes))
     Then SetDir DiretorioFechaMes
          MANIFESTOS()
          SetDir Diretorio
  EndIf

  DesbloqueiaTabelas(Diretorio)
  DesbloqueiaTabelas(DiretorioFechaMes)
  If Not Tem_Tabelas(Diretorio+"Fechames\\"+ANO_MES)
     Then Deleta_Arvore(SubStr(Directory(),1,2)+Diretorio+"Fechames\\"+ANO_MES)
  EndIf

  LimpAguarde()
  MENSAGEM("Fim de Opera‡„o !")

EndWhile
ClearAll
Release Vars All
Release Procs All
