;** Rm_0401 ********************************************************************
;* Resumo de Vendas por Cliente/Produto - ECF                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 11/04/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 29/08/2005 por Davi Pereira Carrano
;Motivo Alteracao: ajustes
;Ultima Alteracao: 19/10/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cupom
;Ultima Alteracao: 28/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo de Pagamento
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas *****************************************************************
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "codc"
Moveto [Tipo Assistencia       ] TypeIn "CONTRATANTE"
{Ask} {NotaC}
Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Numero do Documento    ] Example "ndoc"
Moveto [Serie do Documento     ] Example "sdoc"
Moveto [Tipo do Documento      ] TypeIn "CUP.."
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Descricao da Destinacao] TypeIn "..VEND.."
Moveto [Codigo                 ] Check Example "codc" TypeIn ",~VSDGDESTINAT.."
Moveto [Nome Fantasia EmitDest ] Check
Moveto [Tipo Movimento Estoque ] TypeIn "S"
Switch
  Case SYS_CODIGO_CLIENTE="0070" : Moveto [Condicao de Pagamento  ] TypeIn "04"
  OtherWise                      : Moveto [Forma de Pagamento     ] TypeIn "\"NO\""
EndSwitch
Moveto [Nome Fantasia Represent] Check
Moveto [Situacao               ] TypeIn "Not C"
Moveto [Tipo de Pagamento      ] Check
{Ask} {NotaI}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Numero do Documento    ] Example "ndoc"
Moveto [Serie do Documento     ] Example "sdoc"
Moveto [Codigo do Item         ] Check
Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Preco Unitario         ] Check
Moveto [Taxa Desconto Unitario ] Check
Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
Moveto [Situacao_Item          ] TypeIn "Not C"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] Example "nemp"
Moveto [Codigo                 ] Example "ccli"
Moveto [Nome Fantasia EmitDest ] Example "ncli"
Moveto [Nome Fantasia Represent] Example "frot"
Moveto [Tipo de Pagamento      ] Example "tpg"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unif"
Moveto [Preco Unitario         ] Example "puni"
Moveto [Taxa Desconto Unitario ] Example "txd"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] Example "nemp"
Moveto [Codigo                 ] Example "ccli"
Moveto [Nome Fantasia EmitDest ] Example "ncli"
Moveto [Nome Fantasia Represent] Example "frot"
Moveto [Tipo de Pagamento      ] Example "tpg"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unif"
Moveto [Preco Unitario         ] Example "puni"
Moveto [Taxa de Desconto       ] Example "txd"
Moveto [Vendas_Quantidade      ] Example "qtde"
Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Codigo da Familia      ] Example "fam"
Moveto [Descricao da Familia   ] Example "dfam"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Codigo da Familia      ] TypeIn "Changeto " Example "fam"
Moveto [Descricao da Familia   ] TypeIn "Changeto " Example "dfam"
Do_It!
ClearAll

Edit Tabela
Scan
  [Vendas_Liquida    ]=[Vendas_Preco Total]
  [Vendas_Preco Total]=NDecimal([Vendas_Quantidade]*[Preco Unitario],2)
EndScan
Do_It!
ClearAll

;**** Relacao de Ecf's ********
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "codc"
Moveto [Tipo Assistencia       ] TypeIn "CONTRATANTE"
{Ask} {NotaC}
Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA.."
Moveto [Numero do Documento    ] Check
Moveto [Tipo do Documento      ] TypeIn "CUP.."
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Descricao da Destinacao] TypeIn "..VEND.."
Moveto [Codigo                 ] Check Example "codc" TypeIn ",~VSDGDESTINAT.."
Moveto [Tipo Movimento Estoque ] TypeIn "S"
Moveto [Forma de Pagamento     ] TypeIn "\"NO\""
Moveto [Situacao               ] TypeIn "Not C"
Do_It!
ClearAll


If Not IsEmpty("Answer") Then
 Sort "Answer" On "Codigo da Empresa", "Codigo", "Numero do Documento"
 ClearAll

 code="????"
 codc="????"
 View "\\Sistemas\\Vendas\\RM_0401"
 CoEdit "Answer"
 Scan For [Codigo da Empresa]<>"" And
          [Codigo           ]<>""

   Moveto "\\Sistemas\\Vendas\\Rm_0401"
   If [Answer->Codigo da Empresa]<>code or
      [Answer->Codigo           ]<>codc
      Then End Down
           [Codigo da Empresa]=[Answer->Codigo da Empresa]
           [Codigo           ]=[Answer->Codigo           ]
           code=[Codigo da Empresa]
           codc=[Codigo           ]
           [Observacao]=[Answer->Numero do Documento]
      Else [Observacao]=[Observacao]+", "+[Answer->Numero do Documento]
   EndIf
   Moveto "Answer"

 EndScan
 Do_It!
 ClearAll
EndIf

EndProc  ;  (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Tipo do Item           ] Check
Moveto [Codigo do Item         ] Check
Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Codigo                 ] Check
Moveto [Nome Fantasia EmitDest ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Tipo de Pagamento      ] Check
Moveto [Preco Unitario         ] Check
Moveto [Codigo da Familia      ] Check
Moveto [Descricao da Familia   ] Check
Moveto [Taxa de Desconto       ] Check
Moveto [Vendas_Quantidade      ] TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Moveto [Vendas_Liquida         ] TypeIn "Calc Sum as VendasLiquida"
Do_It!
ClearAll
Empty Tabela
Add "Answer" Tabela

EndProc   ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESA"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT":Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

VSDGEMPRESA =""
VSDGDESTINAT=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Resumo de Vendas Cliente/Produto - ECF Vise" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 11 Width 56

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT"  To VSDGDESTINAT
    Accept @ 03,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMDEST" To VSDGNOMDEST

    Label  @ 04,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "at‚" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 07,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0400"
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0401"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0400" Tabela
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0401" "Rm_0401"

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If Not IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")
       Then Loop
    EndIf
    SetDir "\\Sistemas\\Vendas\\"+Dir_Trab
    Seleciona()

  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  IMPRIREL(Tabela,"2")

  Delete Tabela
  Delete "RM_0401"

EndWhile
ClearAll
Release Vars All
Release Procs All
