;** RO_0102F *******************************************************************
;** Script do modelo Ent_102B feito p/ Impressora PROCOMP   ** Concretos Vico **
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido  em: 26/03/2013 por Bruno Carvalho
;Ultima Alteracao: 08/04/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes conforme solicita‡Æo
;Ultima Alteracao: 03/06/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ a palavra DEVOLUCAO ser exibida quando for Nota de DEV.
;Ultima Alteracao: 16/09/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes para tres casas decimais na impressao do campo quantidade

;*******************************************************************************
;* Rotina para Impressao do Relatorio                                          *
;*******************************************************************************
Proc IMPRO()

;************************* IMPRESSAO DO CABECALHO ******************************
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf
                                  
Moveto "FaturaC"

Switch
  Case Search("DEVOL",[Descricao da Destinacao])>0 : COMPLEMENTO="DEVOLUCAO" 
  OtherWise                                        : COMPLEMENTO="" 
EndSwitch

Print File ARQIMP Fill("=",45)+"\n"
Print File ARQIMP Format("W45,AC"," ** CONTROLE BALCAO ** "+COMPLEMENTO)+"\n"
Print File ARQIMP "DATA: "+Format("D13",[Data de Emissao])+Spaces(12)+"ORCAMENTO: "+NOTAFISC+"\n" 
Print File ARQIMP "NOME: "+Format("W05,AL",[Codigo])+Format("W34,AL",[Nome Fantasia EmitDest])+"\n"    

Print File ARQIMP Fill("-",45)+"\n"

;LOC.        CODIGO    UN       QUANTIDADE
;DESCRICAO                      MARCA
;---------- ------------------- ---------------
;AAAAAAAAAA 9999999999 AA       999.999,99 
;AAAAAAAAAAAAAAAAAAAAAAAAAAAAAA AAAAAAAAAAAAAAA

Print File ARQIMP "LOC.        CODIGO    UN       QUANTIDADE    "+"\n"
Print File ARQIMP "DESCRICAO                      MARCA         "+"\n"  
Print File ARQIMP "---------- ------------------- --------------"+"\n"

Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
QUANT=0
TOT  =0

While [Numero da OF]=[FaturaC->Numero da OF]
   Moveto [Codigo do Item]
   Ativa_Lookup()
   Moveto [Codigo do Item]
   Locate [FaturaI->Codigo do Item]
   If RetVal
      Then LOC  = [Localizacao]
           MARC = [Descricao da Marca]
      Else LOC  = ""
           MARC = ""
   EndIf   
   KeyPress "ESC"
   Print File ARQIMP Format("W10,AL",LOC)+Spaces(1)
   Print File ARQIMP Format("W10,AL",[Codigo do Item])+Spaces(1)    
   Print File ARQIMP Format("W3,AL",[Unidade Fiscal])+Spaces(6)
   Print File ARQIMP Format("W14.3,AR",[Quantidade])+Spaces(1)+"\n"
   Print File ARQIMP Format("W30,AL",[Descricao do Item])+Spaces(1)
   Print File ARQIMP Format("W15,AL",MARC)+"\n"

   TOT = TOT + 1

   Skip
   If EOT() Then QuitLoop EndIf
EndWhile

If TOT < 6
   Then While TOT <= 6
          TOT = TOT + 1
          Print File ARQIMP "\n"
        EndWhile
EndIf   

Print File ARQIMP Fill("=",45)+"\n"

Print File ARQIMP "\n\n\n\n\n\n" ;Espa‡amento p/ guilhotina do romaneio

EndProc ;IMPRO()

;*******************************************************************************
;* Rotina Principal                                                            *
;*****************+*************************************************************
ArqImp=PrivDir()+"RO_0102F.Txt" 

If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)
IMPRO()

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)

Release Vars CLIENTE,END_ENT,BAI_ENT,CID_ENT,CEP_ENT
Release Procs IMPRO
LIMPAGUARDE()