;** Rm_4201 ********************************************************************
;*  Relatorio p/ Conferencia Pedidos                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 29/09/2011 por Anivel Augusto Rodrigues
;Ultima Alteracao: 25/07/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes Diret¢rio Mˆs Fechado
;Ultima Alteracao: 14/11/2014 por Andrey Fillipe
;Motivo Alteracao: Ajustes para nao sair diferenca em branco
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()
ClearAll


If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   (IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI") Or
    IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoG"))
    Then  {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
          Moveto [Numero do Pedido       ] Check
          Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA.."
          Moveto [Nome Fantasia Empresa  ] Check
          Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Moveto [Razao Social           ] Check
          Moveto [Descricao CondPagto    ] Check
          Moveto [Tipo de Pagamento      ] Check
          Moveto [Descricao da Destinacao] Check
          Moveto [Situacao do Pedido     ] Check         
          Moveto [Valor Mercadoria       ] Check
          Do_It!
          ClearAll
          
          Processa()
EndIf
          
EndProc ;Seleciona()          
  
;*******************************************************************************
;* Rotina para processar os registros                                          *
;*******************************************************************************
Proc Processa()

{Ask} {Answer}
Moveto [Numero do Pedido       ] Example "ndoc"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] Example "nfem"
Moveto [Data de Emissao        ] Example "dtem"
Moveto [Razao Social           ] Example "razs"
Moveto [Descricao CondPagto    ] Example "dcpg"
Moveto [Tipo de Pagamento      ] Example "tppg"
Moveto [Descricao da Destinacao] Example "ddes"
Moveto [Situacao do Pedido     ] Example "stnf"
Moveto [Valor Mercadoria       ] Example "vrme"

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero do Pedido       ] Example "ndoc"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] Example "nfem"
Moveto [Data de Emissao        ] Example "dtem"
Moveto [Razao Social           ] Example "razs"
Moveto [Descricao CondPagto    ] Example "dcpg"
Moveto [Tipo de Pagamento      ] Example "tppg"
Moveto [Descricao da Destinacao] Example "ddes"
Moveto [Situacao do Pedido     ] Example "stnf"
Moveto [Valor Mercadoria       ] Example "vrme"
Do_It!
ClearAll

Tabela3=Cria_Temp(PrivDir())
Rename "Answer" Tabela3

;*** Itens PadrÆo ****
{Ask} TypeIn Tabela3 Enter
Moveto [Numero do Pedido       ] Example "ndoc"
{Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter
Moveto [Numero do Pedido       ] Check Example "ndoc"
Moveto [Quantidade             ] TypeIn "Calc Sum as Qtd"
Moveto [Preco Total            ] TypeIn "Calc Sum as Valor"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero do Pedido       ] Example "ndoc"
Moveto [Qtd                    ] TypeIn "_qtd"
Moveto [Valor                  ] TypeIn "_vr"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Numero do Pedido       ] Example "ndoc"
Moveto [Soma Itens             ] TypeIn "Changeto _vr"
Moveto [Soma Itens Pecas       ] TypeIn "Changeto _qtd"
Do_It!
ClearAll

;*** Itens Grade ****
{Ask} TypeIn Tabela3 Enter
Moveto [Numero do Pedido       ] Example "ndoc"
{Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoG" Enter
Moveto [Numero do Pedido       ] Check Example "ndoc"
Moveto [Quantidade             ] TypeIn "Calc Sum as Qtd"
Moveto [Preco Total            ] TypeIn "Calc Sum as Valor"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero do Pedido       ] Example "ndoc"
Moveto [Qtd                    ] TypeIn "_qtd"
Moveto [Valor                  ] TypeIn "_vr"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Numero do Pedido       ] Example "ndoc"
Moveto [Soma Itens Grade       ] TypeIn "Changeto _vr"
Moveto [Soma Itens Grade Pecas ] TypeIn "Changeto _qtd"
Do_It!
ClearAll

Delete Tabela3

EndProc   ;  (Processa)

;*******************************************************************************
;* Rotina Processa                                                             *
;*******************************************************************************
Proc Processa2()

Edit TabelaTEMP
Scan

  [Diferenca Itens      ]=NDecimal([Soma Itens      ]-[Valor Mercadoria      ],2)
  [Diferenca Itens Grade]=NDecimal([Soma Itens Grade]-[Valor Mercadoria      ],2)
  [Diferenca Itens Pecas]=NDecimal([Soma Itens Pecas]-[Soma Itens Grade Pecas],2)

  If [Diferenca Itens      ]=0 Or [Diferenca Itens      ]=-0.00 Then [Diferenca Itens      ]=BlankNum() EndIf
  If [Diferenca Itens Grade]=0 Or [Diferenca Itens Grade]=-0.00 Then [Diferenca Itens Grade]=BlankNum() EndIf
  If [Diferenca Itens Pecas]=0 Or [Diferenca Itens Pecas]=-0    Then [Diferenca Itens Pecas]=BlankNum() EndIf

  If SYS_CLIENTE_CONFEC=""
     Then
          [Soma Itens Grade     ]=BlankNum()
          [Soma Itens Pecas     ]=BlankNum()
          [Diferenca Itens Grade]=BlankNum()
          [Diferenca Itens Pecas]=BlankNum()
  EndIf   

EndScan
Do_It!
ClearAll

{Ask} TypeIn TabelaTEMP Enter TypeIn "Delete"
Moveto [Diferenca Itens Pecas] TypeIn "Blank"
Moveto [Diferenca Itens Grade] TypeIn "Blank"
Moveto [Diferenca Itens      ] TypeIn "Blank"
Do_It!
ClearAll

EndProc ;(Processa2)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_DTINI"          : Campo="TG_EMPRESA"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            ;Case Campo="TG_OPRELATORIO"    : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"       : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="YES"
                    ;Case Campo="TG_DTFIM"         : Campo="TG_OPRELATORIO"
                    ;Case Campo="TG_OPRELATORIO" :
                    ;     VSDGOPRELATORIO=ControlValue("TG_OPRELATORIO")
                    ;     Switch
                    ;        Case VSDGOPRELATORIO="3": VSDGNOMOPRELATORIO=""
                    ;        Case VSDGOPRELATORIO="2": VSDGNOMOPRELATORIO=""
                    ;        OtherWise:                VSDGOPRELATORIO="1"
                    ;                                  VSDGNOMOPRELATORIO="Simples"
                    ;     EndSwitch
                    ;     Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  ;Case Campo="TG_OPRELATORIO":
  ;   MSG_CAMPO="1=Simples    2= 3= "
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

If Not IsAssigned(SYS_CLIENTE_CONFEC)  Then SYS_CLIENTE_CONFEC="*"  EndIf

VSDGEMPRESA =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Relat¢rio Conferˆncia Pedidos" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 09,12 Height 09 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 05,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
 
  Tabela    =Cria_Temp("\\Sistemas\\Vendas\\")
  TabelaTEMP=Cria_Temp(PrivDir())
  
  Copy "\\Base\\Sistemas\\Vendas\\RM_4201" Tabela
  Empty(Tabela)

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
   If IsTable("Answer")     Then Delete "Answer" EndIf 
   Seleciona()
   If Not IsTable("Answer") Then Loop EndIf
   If IsTable(TabelaTEMP)
      Then Add Tabela TabelaTEMP
      Else Copy Tabela TabelaTEMP
   EndIf
   Empty(Tabela)
  EndWhile
  
  If IsEmpty(TabelaTEMP)
     Then MENSAGEM("N„o existem registros a processar")
          Delete TabelaTEMP
          Loop
  EndIf
  
  Processa2()
  
  If IsEmpty(TabelaTEMP)
     Then MENSAGEM("N„o foi detectada nenhuma diferen‡a")
          Delete TabelaTEMP
          Loop
  EndIf
  
  CopyReport "\\Base\\Sistemas\\Vendas\\RM_4201" "R" TabelaTEMP "R"
  IMPRIREL(TabelaTEMP,"R")
  
  ;Foi anulado esse processo pois nÆo havia mais de uma op‡Æo nesse relatorio! Em 25.07.2012!
  ;Se for o caso, quando surgir mais de uma op‡Æo, habilitar as linhas e fazer o ajuste! 
  ;Switch
  ;  Case VSDGOPRELATORIO="1": CopyReport "\\Base\\Sistemas\\Vendas\\RM_4201" "R" TabelaTEMP "R"
  ;                            IMPRIREL(TabelaTEMP,"R")
  ;EndSwitch

  Delete Tabela
  Delete TabelaTEMP

EndWhile
ClearAll
Release Vars All
Release Procs All
