;** Rm_0760A *******************************************************************
;* Tipo Pgto/Cond. Pagto - C/ Quantidade de Documento, Porcentagem e Ranking   *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 23/07/2014 por Bruno Carvalho
;Ultima Alteracao: 13/11/2014 por Kamila Gomes
;Motivo Alteracao: Inclusao da op‡Æo de ranking por forma de pagamento e comp. de dias
;Ultima Alteracao: 04/02/2015 por Kamila Gomes
;Motivo Alteracao: Ajustes Montagem da Composi‡Æo de Dias
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()              
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 14/11/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes campo temporario que nÆo existe mais na tabela nota c "Aliquota de ICMS"
;Ultima Alteracao: 09/01/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nova logica, nova tabela e novos reports                                                 
;Ultima Alteracao: 05/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Seta_Ordem_Report()       
;Ultima Alteracao: 27/05/2019 por Kamila Gomes
;Motivo Alteracao: Ajustes Seleciona()            
;Ultima Alteracao: 18/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modelo relatorio e reports

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI") and
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV")
   Then 
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ] Example "cite"
        Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check 
        Moveto [Codigo da Empresa      ] Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        Moveto [Tipo de Pagamento      ] TypeIn "V or P"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo do Item         ] Example "cite" 
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        if not isblank("Answer") and
           (VSDGCODMODELO = "02" or VSDGCODMODELO = "03"  or VSDGCODMODELO = "04")
           then
                {Ask} {Answer} Check 
                Moveto [Codigo da Empresa      ] Example "cemp" 
                Moveto [Numero do Documento    ] Example "ndoc"
                Moveto [Serie do Documento     ] Example "sdoc"
                Moveto [Forma de Pagamento     ] Check ; desmarcar campo
                Moveto [Valor Mercadoria       ] Check ; desmarcar campo
                {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV" Enter
                Moveto [Codigo da Empresa      ] Example "cemp"
                Moveto [Numero do Documento    ] Example "ndoc"
                Moveto [Serie do Documento     ] Example "sdoc"
                Moveto [Forma de Pagamento     ] CheckPlus
                Moveto [Valor                  ] CheckPlus typein "As Valor Mercadoria"
                Do_It!
                ClearAll
        endif

        if not isblank("Answer") and
           (VSDGCODMODELO = "02" or VSDGCODMODELO = "03"  or VSDGCODMODELO = "04")
           then
                NR=NRecords("Answer")
                
                View "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV" imagerights readonly
                Coedit "Answer" 
                Scan
                  Barra(NR, RecNo())
                  Aguarde("Aguarde, montando composicao de dias "+BARRA_STRING)

                  if VSDGCODMODELO = "02" or
                     VSDGCODMODELO = "03" or
                     VSDGCODMODELO = "04" 
                     then [Valor Desconto]=BlankNum()
                  endif   
                  
                  COMPDIAS = ""
                  EMPRESA  = [Codigo da Empresa  ]
                  NDOCTO   = [Numero do Documento]
                  SDOCTO   = [Serie do Documento ]
                  
                  moveto "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV"
                  Moveto [Codigo da Empresa]
                  Locate EMPRESA,NDOCTO,SDOCTO
                  If RetVal
                     Then While [Codigo da Empresa  ]=EMPRESA And
                                [Numero do Documento]=NDOCTO  And
                                [Serie do Documento ]=SDOCTO

                                ndias=StrVal([Data]-[Answer->Data de Emissao])
            
                                switch
                                  case VSDGCODMODELO = "03" or
                                       VSDGCODMODELO = "04" :

                                    if [Forma de Pagamento]<>[Answer->Forma de Pagamento]
                                       then
                                            ndias="" 
                                    EndIf
                                  
                                endswitch 

                                if not isblank(ndias)
                                   then 
                                        If COMPDIAS = ""
                                           Then COMPDIAS = ndias
                                           Else COMPDIAS = COMPDIAS + "/" + ndias
                                        EndIf
                                endif    

                                Skip
                                If Eot() Then QuitLoop EndIf
                          EndWhile
                  EndIf
                  
                  Moveto "Answer"
                  If COMPDIAS <> ""
                     Then [Composicao de Dias] = COMPDIAS
                  EndIf
                  
                EndScan
                Do_It!
                ClearAll
        endif
        
        Adiciona_Dados()
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados()

If IsEmpty("Answer")
   Then Return
EndIf
   
{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
moveto [Tipo de Pagamento      ] typein "_tppg"
moveto [Condicao de Pagamento  ] typein "_cdpg"
moveto [Descricao CondPagto    ] typein "_dcdpg"
moveto [Composicao de Dias     ] typein "_compd"
moveto [Forma de Pagamento     ] typein "_frpg"
Moveto [Valor Mercadoria       ] Example "ptot"
Moveto [Valor Desconto         ] Example "vdes"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
switch
  case VSDGCODMODELO = "01" :
    moveto [Tipo de Pagamento      ] typein "_tppg"
    moveto [Condicao de Pagamento  ] typein "_cdpg"
    moveto [Descricao CondPagto    ] typein "_dcdpg"
   
  case VSDGCODMODELO = "02" :
    moveto [Tipo de Pagamento      ] typein "_tppg"
    moveto [Composicao de Dias     ] typein "_compd"
   
  case VSDGCODMODELO = "03" :
    moveto [Forma de Pagamento     ] typein "_frpg"
    moveto [Composicao de Dias     ] typein "_compd"
   
  case VSDGCODMODELO = "04" :
    moveto [Tipo de Pagamento      ] typein "_tppg"
    moveto [Forma de Pagamento     ] typein "_frpg"
   
endswitch
Moveto [Vendas_Preco Total     ] Example "ptot" 
Moveto [Vendas_Descontos       ] Example "vdes"
Moveto [NumeroVendas           ] typein "1"
Do_It!
ClearAll       

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

switch
  case VSDGCODMODELO = "01"  or
       VSDGCODMODELO = "02"  or
       VSDGCODMODELO = "04" :
    {Ask} TypeIn Tabela Enter TypeIn "Fast"
    Moveto [Tipo de Pagamento      ] TypeIn "V"
    Moveto [TipoPagamentoDescricao ] TypeIn "changeto \"1 - A VISTA\""
    down
    Moveto [Tipo de Pagamento      ] TypeIn "P"
    Moveto [TipoPagamentoDescricao ] TypeIn "changeto \"2 - A PRAZO\""
    down
    Moveto [Tipo de Pagamento      ] TypeIn "Not V, Not P"
    Moveto [TipoPagamentoDescricao ] TypeIn "changeto \"9 - OUTROS\""
    Do_It!
    ClearAll
   
endswitch

switch
  case VSDGCODMODELO = "03" or
       VSDGCODMODELO = "04" :
    {Ask} {\\Sistemas\\Cadastro\\TpPagto}
    Moveto [Tipo do Pagamento        ] typein "_cpg"
    Moveto [Descricao Tipo Pagamento ] typein "_dpg"
    {Ask} TypeIn Tabela Enter TypeIn "Fast"
    Moveto [Forma de Pagamento       ] typein "_cpg"
    Moveto [Descricao Tipo Pagamento ] typein "changeto _dpg"
    Do_It!
    ClearAll
   
endswitch

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as \"Vendas_Preco Total\""
Moveto [Vendas_Descontos       ] Check TypeIn "Calc Sum as \"Vendas_Descontos\""
Moveto [NumeroVendas           ] Check TypeIn "Calc Sum as \"NumeroVendas\""
Do_It!
ClearAll     

Delete Tabela
Rename "Answer" Tabela
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_MARCA"           : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"           : Campo="TG_MARCA"
            Case Campo="TG_DTFIM"           : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALFRANK" : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"       : Campo="TG_OPRELCODALFRANK"
            Case Campo="YES" Or Campo="NO"  : Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"       : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"           : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"           : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"           : Campo="TG_OPRELCODALFRANK"
                    Case Campo="TG_OPRELCODALFRANK" : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"       : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="" :
     MSG_CAMPO=""
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Tipo Pagto/Condi‡Æo de Pagamento     -VrMercadoria")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Tipo Pagto/Composi‡Æo de Dias        -Vencimentos")
ModeloRelatoriosAdd("04  Tipo Pagto/Forma de Pagamento        -Vencimentos")
ModeloRelatoriosAdd("03  Forma de Pagamento/Composi‡Æo de Dias-Vencimentos")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA         = ""
VSDGMARCA           = ""
VSDGDTINI           = BlankDate()
VSDGDTFIM           = BlankDate()
VSDGOPRELCODALFRANK = ""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Resumo de Vendas por Condi‡Æo de Pagamento" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 14 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Marca"  For "TG_MARCA"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡„o de Ordem" For "TG_OPRELCODALFRANK"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPRELCODALFRANK" To VSDGOPRELCODALFRANK
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALFRANK" To VSDGNOMOPRELCODALFRANK

    Label  @ 07,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 08,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 08,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 10,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_0760A"
  Copy "\\Base\\Sistemas\\Vendas\\RM_0760A" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  
  switch
    case VSDGCODMODELO = "01" : 
      CopyReport "\\Base\\Sistemas\\Vendas\\RM_0760A" "R" Tabela "R"
      Switch
        Case VSDGOPRELCODALFRANK="2" : Seta_Ordem_Report(Tabela,"R","Condicao de Pagamento","Descricao CondPagto"  ,"")
        Case VSDGOPRELCODALFRANK="3" : Seta_Ordem_Report(Tabela,"R","Condicao de Pagamento","Vendas_Preco Total"   ,"D")
        OtherWise                    : Seta_Ordem_Report(Tabela,"R","Condicao de Pagamento","Condicao de Pagamento","")
      EndSwitch

    case VSDGCODMODELO = "02" : 
      CopyReport "\\Base\\Sistemas\\Vendas\\RM_0760A" "1" Tabela "R"
      Switch
        Case VSDGOPRELCODALFRANK="3" : Seta_Ordem_Report(Tabela,"R","Composicao de Dias","Vendas_Preco Total","D")
        OtherWise                    : Seta_Ordem_Report(Tabela,"R","Composicao de Dias","Composicao de Dias","")
      EndSwitch
    
    case VSDGCODMODELO = "03" : 
      CopyReport "\\Base\\Sistemas\\Vendas\\RM_0760A" "2" Tabela "R"
      Switch
        Case VSDGOPRELCODALFRANK="3" : Seta_Ordem_Report(Tabela,"R","Composicao de Dias","Vendas_Preco Total","D")
        OtherWise                    : Seta_Ordem_Report(Tabela,"R","Composicao de Dias","Composicao de Dias","")
      EndSwitch
    
    case VSDGCODMODELO = "04" : 
      CopyReport "\\Base\\Sistemas\\Vendas\\RM_0760A" "3" Tabela "R"
      Switch
        Case VSDGOPRELCODALFRANK="2" : Seta_Ordem_Report(Tabela,"R","Forma de Pagamento","Descricao Tipo Pagamento","")
        Case VSDGOPRELCODALFRANK="3" : Seta_Ordem_Report(Tabela,"R","Forma de Pagamento","Vendas_Preco Total"      ,"D")
        OtherWise                    : Seta_Ordem_Report(Tabela,"R","Forma de Pagamento","Forma de Pagamento"      ,"")
      EndSwitch

  endswitch
  IMPRIREL(Tabela,"R") 

  Delete Tabela
EndWhile
ClearAll
Release Vars All
Release Procs All
