;** Rm_0040 ********************************************************************
;*  Emissao da Rela‡Æo de Ordem de Compras Simples                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 26/09/2001 por Douglas Rodrigues
;Alterado em     : 21/07/2008 por Nikolas
;Motivo Alteracao: Inclusao TG_COMPRADOR
;Ultima Alteracao: 19/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 28/12/2016 por Rafael Matos 
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT                 

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll
{Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
Moveto [Codigo            ] example "cemit"
Moveto [Codigo Atividade  ] TypeIn "~VSDGATIVIDADE.."
{Ask} {OcC} Check
Moveto [Numero da OC          ] Example "Oc"
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo                ] example "cemit" TypeIn ", ~VSDGDESTINAT.."
Moveto [Data de Entrega       ] ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Codigo do Comprador   ] TypeIn "~VSDGCOMPRADOR.."
Moveto [Situacao da OC        ] TypeIn "~SITUACAO.."

Do_It!
ClearAll
EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_COMPRADOR"      : Campo="TG_EMPRESA"
            Case Campo="TG_ATIVIDADE"      : Campo="TG_COMPRADOR"
            Case Campo="TG_DESTINAT"       : Campo="TG_ATIVIDADE"
            Case Campo="TG_DTINI"          : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_SITUACAO"       : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_COMPRADOR"
                    Case Campo="TG_COMPRADOR": Campo="TG_ATIVIDADE"
                    Case Campo="TG_ATIVIDADE": Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT" : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"    : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"    : Campo="TG_SITUACAO"
                    Case Campo="TG_SITUACAO" : Campo="YES"
                         VSDGSITUACAO=ControlValue("TG_SITUACAO")
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_SITUACAO":
       MSG_CAMPO="Situacao: Aberto, Suspenso, Cancelada, Entregue, Todas"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  = ""
VSDGDESTINAT = ""
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()
VSDGSITUACAO = ""
VSDGATIVIDADE= ""
VSDGCOMPRADOR= ""
VSDGNOMCOMPRADOR= ""
VSDGNOMATIV  = ""

While True
  ShowDialog "Rela‡„o de Ordens de Compras" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140
  @ 05,12   Height 17 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A24" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Comprador"  For "TG_COMPRADOR"
    Accept @ 03,01 Width 07 "A4"  Picture "!*!" Tag "TG_COMPRADOR" To VSDGCOMPRADOR
    Accept @ 03,09 Width 25 "A30"  Picture "#*#" Tag "TG_NOMCOMPRADOR" To VSDGNOMCOMPRADOR

    Label  @ 04,00 "Atividade"  For "TG_ATIVIDADE"
    Accept @ 05,01 Width 07 "A4"  Picture "!*!" Tag "TG_ATIVIDADE" To VSDGATIVIDADE
    Accept @ 05,09 Width 25 "A30"  Picture "#*#" Tag "TG_NOMATIV" To VSDGNOMATIV

    Label  @ 06,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 07,01 Width 07 "A04" Picture "[&,#][#*#]" Tag "TG_DESTINAT"   To VSDGDESTINAT
    Accept @ 07,09 Width 25 "A24" Picture "!*!" Tag "TG_NOMDEST"    To VSDGNOMDEST

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 10,00 "Situacao"  For "TG_SITUACAO"
    Accept @ 11,01 Width 33 "A9"  Picture "ABERTO,SUSPENSO,CANCELADA,ENTREGUE,TODAS" Tag "TG_SITUACAO"  To VSDGSITUACAO

    Pushbutton @ 13,22 width 11 "~O~k"      OK     Default Value "Ok"  Tag "YES" To BottonValue
    Pushbutton @ 13,36 width 11 "~C~ancela" CANCEL                     Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  If VSDGSITUACAO="TODAS"
     Then SITUACAO=""
     Else SITUACAO=VSDGSITUACAO
  EndIf

  AGUARDE("Aguarde, Gerando Relat¢rio")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar!")
          Loop
  EndIf

  CopyReport "\\Base\\Sistemas\\Compras\\Rm_0040" "R" "Answer" "R"

  IMPRIREL("Answer","R")

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
