;** TransfNF  ******************************************************************
;*  Transferencia P/ Drives  (Notas Fiscais)                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 30/09/1999 por Anivel Augusto Rodrigues
;Ultima Alteracao: 05/08/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 29/07/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novo pacote
;Ultima Alteracao: 15/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Layout e Pacote
;Ultima Alteracao: 27/06/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo Arj para c:\Arj
;Ultima Alteracao: 10/08/2011 por Karina Andrade
;Motivo Alteracao: Add novas tabelas
;Ultima Alteracao: 25/10/2011 por Bruno Carvalho
;Motivo Alteracao: Add Tabela "NotaOCP"
;Ultima Alteracao: 30/11/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo de "ExecVise -> Vexe","Arj -> Varj"
;Ultima Alteracao: 08/12/2011 por Karina Andrade
;Motivo Alteracao: Nova nomeclatura para pacote gerado
;Ultima Alteracao: 07/05/2012 por Bruno Carvalho
;Motivo Alteracao: Add Sleep na rotina onde ‚ processado o ARJ
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Substitui‡Æo Editor novo arquivo por FileWrite

;*******************************************************************************
;* ROTINA PROCESSA  -> realiza o processamento da Transferencia                *
;*******************************************************************************
Proc PROCESSA()

AGUARDE("Aguarde, Transferindo Notas")
ClearAll
Array Arquivo[10]
Arquivo[1] ="NotaC"
Arquivo[2] ="Notaidd"
Arquivo[3] ="Notaiad"
Arquivo[4] ="NotaOCP"
Arquivo[5] ="Notaidv"
Arquivo[6] ="Notatg"
Arquivo[7] ="NotaI"
Arquivo[8] ="NotaR"
Arquivo[9] ="NotaCTR"
Arquivo[10] ="NotaV"


Cont     = 1

SetDir "\\Sistemas\\Vendas"
For Cont From 1 To 10
    AGUARDE("Aguarde, Transferindo "+Arquivo[Cont]+" [ "+StrVal(Cont)+"/10 ]")
    If IsTable(Arquivo[Cont])
       Then If Arquivo[Cont]<>"NotaC"
               Then {Ask} {NotaC}
                    Moveto [Codigo da Empresa  ] Example "cemp" TypeIn ", ~VSDGEMPRESA.."
                    Moveto [Numero do Documento] Example "ndoc"
                    Moveto [Serie do Documento ] Example "sdoc"
                    Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                    Moveto [Tipo do Documento  ] TypeIn "Not CUP.."
                    Moveto [Codigo do Documento] TypeIn "~VSDGTPDOCTO.."
                    {Ask} TypeIn Arquivo[Cont] Enter Check
                    Moveto [Codigo da Empresa  ] Example "cemp"
                    Moveto [Numero do Documento] Example "ndoc"
                    Moveto [Serie do Documento ] Example "sdoc"
               Else {Ask} {NotaC} Check
                    Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
                    Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                    Moveto [Tipo do Documento  ] TypeIn "Not CUP.."
                    Moveto [Codigo do Documento] TypeIn "~VSDGTPDOCTO.."
            Endif
            Do_It!
            ClearAll

            If IsTable("C:\\"+Arquivo[Cont])
               Then Delete "C:\\"+Arquivo[Cont]
            Endif
            Create "C:\\"+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" "C:\\"+Arquivo[Cont]
            ClearAll

            If Arquivo[Cont]="NotaC" And Not IsEmpty("Answer")
               Then Gerou_Dados=True
            EndIf   
    EndIf
EndFor


AGUARDE("Aguarde, Transferindo Destinat [ 9/10 ]")
If IsTable("\\Sistemas\\Cadastro\\Destinat")
   Then {Ask} {\\Sistemas\\Cadastro\\Destinat} Check
        Moveto [Codigo] Example "cod"
        {Ask} {\\Sistemas\\Cadastro\\FichaCli}
        Moveto [Codigo] Example "cod"
        Moveto [Data da Primeira Compra] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Do_It!
        ClearAll
        If IsTable("C:\\Destinat")
           Then Delete "C:\\Destinat"
        Endif
        Create "C:\\Destinat" Like "\\Sistemas\\Cadastro\\Destinat"
        Add "Answer" "C:\\Destinat"
EndIf
ClearAll
Limpaguarde()
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTREF"         : Campo="TG_EMPRESA"
            Case Campo="TG_TPDOCTO"       : Campo="TG_DTREF"
            Case Campo="TG_DTINI"         : Campo="TG_TPDOCTO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DRIVES"        : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_DTREF"
                    Case Campo="TG_DTREF"   : Campo="TG_TPDOCTO"
                    Case Campo="TG_TPDOCTO" : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="TG_DRIVES"
                    Case Campo="TG_DRIVES"   :
                         VSDGDRIVE=ControlValue("TG_DRIVES")
                         Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf

Switch
  Case Campo="TG_DTREF" :
       MSG_CAMPO="Informe a data da Transa‡„o"
  Case Campo="TG_DRIVES":
       MSG_CAMPO="Selecione o drive desejado !"
       TECLA=Chr(27)+""+Chr(26)+"=Selecionar  "
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA=""
VSDGDTREF  =BlankDate()
VSDGTPDOCTO=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

DynArray Array_Drives[]
SysInfo Drives To Array_Drives
If IsFile("OEXPNFS.sc")
    Then Play "OEXPNFS"
    Else VSDGDRIVE=SubStr(Directory(),1,2)
EndIf

While True
  ShowDialog "Exporta‡„o Notas [Faturamento]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  

   @ 05,12   Height 13 Width 47

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 1,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Data Transa‡„o" For "TG_DTREF"
    Accept @ 03,01 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Label  @ 04,00 "Tipo do Documento"  For "TG_TPDOCTO"
    Accept @ 05,01 Width 07 "A4"  Picture "!*!" Tag "TG_TPDOCTO" To VSDGTPDOCTO
    Accept @ 05,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMTPDOCTO"  To VSDGNOMTPDOCTO

    Label  @ 06,00 "Periodo Referente" For "TG_DTINI"
    Label  @ 07,00 "de" For "TG_DTINI"
    Accept @ 07,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,17 "ate" For "TG_DTFIM"
    Accept @ 07,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,37 "Drives:" For "TG_DRIVES"
    PickDynArrayIndex @ 01,38 Height 7 width 05
     Columns 1
      Array_Drives
       Tag "TG_DRIVES"
        To VSDGDRIVE

    Pushbutton @ 09,10 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,22 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGEMPRESA) Or
     IsBlank(VSDGDTREF)
     Then Mensagem("Informe os dados corretamente !")
          Loop
  EndIf

  DATAREF=AlinhM(StrVal(Day(VSDGDTREF)),2)+AlinhM(StrVal(Month(VSDGDTREF)),2)+SubStr(AlinhM(StrVal(Year(VSDGDTREF)),4),3,2)

  ARQ   =VSDGDRIVE+"\\YY"+DATAREF+".ARJ"
  ARQNEW=VSDGDRIVE+"\\PT_ENF"+"_"+VSDGEMPRESA+"_"+
         AlinhM(StrVal(Year(VSDGDTREF)),4) +
         AlinhM(StrVal(Month(VSDGDTREF)),2)+
         AlinhM(StrVal(Day(VSDGDTREF)),2)  +
         ".ARJ"

  Deleta_Arquivo("C:\\NOTAC.*")
  Deleta_Arquivo("C:\\NOTAIDD.*")
  Deleta_Arquivo("C:\\NOTAIAD.*")
  Deleta_Arquivo("C:\\NOTAOCP.*")
  Deleta_Arquivo("C:\\NOTAIDV.*")
  Deleta_Arquivo("C:\\NOTATG.*")
  Deleta_Arquivo("C:\\NOTAI.*")
  Deleta_Arquivo("C:\\NOTAR.*")
  Deleta_Arquivo("C:\\NOTACTR.*")
  Deleta_Arquivo("C:\\NOTAV.*")
  Deleta_Arquivo("C:\\DESTINAT.*")
  Deleta_Arquivo(ARQ)
  Sleep(1000)
  ExecVise("REN "+ARQNEW+" \""+ARQ+"\"")
  Sleep(1000)
  Deleta_Arquivo(ARQ)
  Sleep(1000)

  Gerou_Dados=False
  Processa()

  Sleep(1000)

  If Not Gerou_Dados
     Then Mensagem("NÆo existe(m) nota(s) conforme sele‡Æo !// //Verificar Empresa, TpDocto, Data Referente !"+
                   "//Pacote nÆo foi gerado !")
     Else Aguarde("Aguarde, Compactando pacote de transa‡„o p/ "+ARQNEW)
          Executa_Programa("c:\\vise\\Varj.exe a "+ARQ+" C:\\NOTA*.* C:\\DESTINAT.*")
          Sleep 1000
          
          ExecVise("REN "+ARQ+" \""+ARQNEW+"\"")
          Sleep 1000
          
          Deleta_Arquivo("C:\\NOTAC.*")
          Deleta_Arquivo("C:\\NOTAIDD.*")
          Deleta_Arquivo("C:\\NOTAIAD.*")
          Deleta_Arquivo("C:\\NOTAOCP.*")
          Deleta_Arquivo("C:\\NOTAIDV.*")
          Deleta_Arquivo("C:\\NOTATG.*")
          Deleta_Arquivo("C:\\NOTAI.*")
          Deleta_Arquivo("C:\\NOTAR.*")
          Deleta_Arquivo("C:\\NOTACTR.*")
          Deleta_Arquivo("C:\\NOTAV.*")
          Deleta_Arquivo("C:\\DESTINAT.*")          
          Sleep 1000
          
          MSG="Pacote de transa‡„o gerado !// //"
          MSG=MSG+"Arquivo em "+ARQNEW+"// //"
          MSG=MSG+"Verifique !"
          Mensagem(MSG)
  EndIf

  FileWrite        "OEXPNFS.sc" From ";****** Variaveis de Configura‡„o Drive Padrao Vise Informatica"+"\n"
  FileWrite Append "OEXPNFS.sc" From "VSDGDRIVE="+CHR(34)+VSDGDRIVE+Chr(34)+"\n"

EndWhile
ClearAll
Release Vars All
Release Procs All
