;** Rm_0081 ********************************************************************
;*  Emissao dos Titulos a Receber por Cliente com Cheques Pendentes            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/05/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 09/02/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Opcao de Cheques
;Ultima Alteracao: 07/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cheques em Cobranca
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 01/07/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Cheques Trocados
;Ultima Alteracao: 08/07/2011 por Karina Andrade
;Motivo Alteracao: Ajustes ShowDialog
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT 
;Ultima Alteracao: 03/01/2017 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog MensagemRadioButtons()                
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
       Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo do Destinatario ] TypeIn "~VSDGDESTINAT.."
       Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
       Moveto [Data de Vencimento     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       Moveto [Saldo do Documento     ] TypeIn "> 0.01"
       Switch                                                                                  
         Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
         Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
       EndSwitch   
       Do_It!
       ClearAll
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Cheques a Descontar                                     *
;*******************************************************************************
Proc Cheque()
ClearAll

{Ask} {\\Sistemas\\CheqRec\\ChequeC} Check
Moveto [Numero do Lancamento   ] Example "NUM"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo                 ] TypeIn "~VSDGDESTINAT.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
{Ask} {\\Sistemas\\CheqRec\\ChequeI} Check
Moveto [Numero do Lancamento] Example "NUM"
If VSDGOPCHEQ=1
   Then Moveto [Situacao    ] TypeIn "Not \"LIQUIDADO\", Not \"SEM FUNDO\", Not \"EM COBRANCA\", Not \"TROCADO..\""
   ELSE Moveto [Situacao    ] TypeIn "Not \"LIQUIDADO\", Not \"EM COBRANCA\", Not \"TROCADO..\""
EndIf
Moveto [Data Vencimento     ] TypeIn ">=~VSDGDTINI ,<=~VSDGDTFIM"
Do_It!
ClearAll
If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                ] Example "codigo"
Moveto [Nome Fantasia EmitDest] Example "nome"
{Ask} {Answer} TypeIn "Fast"
Moveto [Codigo      ] Example "codigo"
Moveto [Razao Social] TypeIn "Changeto " Example "nome"
Do_It!
ClearAll

CoEdit Tabela,"Answer"
Moveto [Codigo]
Scan
  Moveto Tabela
  End
  Down
  [Codigo da Empresa     ] = [Answer->Codigo da Empresa    ]
  [Nome Fantasia Empresa ] = [Answer->Nome Fantasia Empresa]
  [Codigo do Destinatario] = [Answer->Codigo               ]
  If Len([Answer->Razao Social])>20
     Then [Nome Fantasia EmitDest] = SubStr([Answer->Razao Social],1,20)
     Else [Nome Fantasia EmitDest] = [Answer->Razao Social]
  EndIf
  [Data de Vencimento     ] = [Answer->Data Vencimento]
  [Data a Receber         ] = [Answer->Data Vencimento]
  [Tipo do Documento      ] = "CH"
  [Numero do Documento    ] = [Answer->Numero_Cheque  ]
  [Valor do Documento     ] = [Answer->Valor          ]
  [Saldo do Documento     ] = [Answer->Valor          ]
  [Valor do Desconto      ] = 0
  [Data de Emissao        ] = [Answer->Data de Entrada]
  [Numero do Lancamento   ] = StrVal([Answer->Numero do Lancamento])
  [Codigo da Conta        ] = ""
  [Codigo do Representante] = [Answer->Codigo do Representante]
  [Nome Fantasia Represent] = [Answer->Nome Fantasia Represent]
  [Documento no Banco     ] = "* "+[Answer->Situacao]
  [Tipo do Pagamento      ] = ""

  Moveto "Answer"

EndScan
Do_It!
ClearAll
EndProc ; (Cheque)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

   If SubStr([Documento no Banco],1,2)="* "
      Then [Observacoes]=[Documento no Banco]
   EndIf

EndScan
Do_It!
ClearAll
EndProc     ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPCART"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESATE"
            Case Campo="TG_REPRESEN"      : Campo="TG_DESTINAT"
            Case Campo="TG_DTINI"         : Campo="TG_REPRESEN"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_TPCART"        : Campo="TG_DDPROTESTO"
            Case Campo="TG_OPCHEQ"        : Campo="TG_TPCART"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"     : Campo="TG_OPCHEQ"
                    Case Campo="TG_OPCHEQ"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
     MSG_CAMPO="Informe o Numero de Dias a Protestar apos Vencimento"
  Case Campo="TG_OPCHEQ":
       MensagemRadioButtons()
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc  ; (SD_Dialog)

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""
VSDGDESTINAT  =""
VSDGTPCART    =""
VSDGDDPROTESTO=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()
VSDGOPCHEQ        = 1
VSDGNOMOPCHEQ     = ""

ListaRegra_TGAtivado="[TG_TPCART]"

While True
  ShowDialog "Titulos a Receber por Cliente+Cheques Pendentes" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"
        
   @ 05,12   Height 13 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 03,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Label @ 05,35 "Op‡„o Cheque " For "TG_OPCHEQ"
    RadioButtons @ 06,35 Height 5 Width 32
      "~1~ = somente os a Descontar",
      "~2~ = a Descontar + Sem Fundo"
        Tag "TG_OPCHEQ"
        To VSDGOPCHEQ

    Pushbutton @ 09,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue


  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  Cheque()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "12" Tabela "R"

  IMPRIREL(Tabela,"R")

  If IsTable("Answer")
     Then Delete "Answer"
  EndIf

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
