;** Rm_1270 ********************************************************************
;*  Rela‡Ćo de Clientes - Duplicatas                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 29/10/2012 por Bruno Carvalho
;Alterado em		 : 28/03/2014 por Bruno Carvalho
;Motivo Alteracao: Ajustes  
;Ultima Alteracao: 17/06/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes logica e novo desenho report                  
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                   
;Ultima Alteracao: 21/11/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes erro variavel
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog modelo relatorio  
 
;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\CtaRec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\CtaRec\\"+Dir_Trab+"DupBaixa")
   Then
        If VSDGTPPGTO="1"
           Then 
                {Ask} TypeIn "\\Sistemas\\CtaRec\\"+Dir_Trab+"Duplic" Enter
                Moveto [Numero do Lancamento  ] Check Example "NLAN" TypeIn "!"
                Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA.."
                Moveto [Nome Fantasia Empresa ] Check
                Moveto [Numero do Documento   ] Check
                Moveto [Tipo do Documento     ] Check 
                Moveto [Serie do Documento    ] Check 
                If VSDGOPDTEMISVENC="2"
                   Then Moveto [Data de Emissao   ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                        Moveto [Data de Vencimento] Check 
                   ELse Moveto [Data de Emissao   ] Check 
                        Moveto [Data de Vencimento] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                EndIf   
                Moveto [Valor do Documento    ] Check 
                Moveto [Saldo do Documento    ] Check 
                Moveto [Codigo do Destinatario] Check TypeIn "~VSDGDESTINAT.."
                Moveto [Razao Social          ] Check
                Moveto [Documento Referente   ] Check
                Moveto [Tipo Docto Gerador    ] Check
                Moveto [Numero Docto Gerador  ] Check
                {Ask} TypeIn "\\Sistemas\\CtaRec\\"+Dir_Trab+"DupBaixa" Enter
                Moveto [Numero do Lancamento  ] Example "NLAN"
                Moveto [Sequencia da Baixa    ] Check
                Moveto [Data do Pagamento     ] Check 
                Moveto [Valor do Recebimento  ] Check 
                Moveto [Valor do Juros        ] Check 
                Moveto [Valor do Desconto     ] Check  
                Do_It!
                ClearAll
           
           else 
                {Ask} TypeIn "\\Sistemas\\CtaRec\\"+Dir_Trab+"Duplic" Enter
                Moveto [Numero do Lancamento  ] Check Example "NLAN" TypeIn "!" 
                Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA.."
                Moveto [Nome Fantasia Empresa ] Check
                Moveto [Numero do Documento   ] Check
                Moveto [Serie do Documento    ] Check 
                Moveto [Tipo do Documento     ] Check 
                If VSDGOPDTEMISVENC="2"
                   Then Moveto [Data de Emissao   ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                        Moveto [Data de Vencimento] Check 
                   ELse Moveto [Data de Emissao   ] Check 
                        Moveto [Data de Vencimento] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                EndIf   
                Moveto [Valor do Documento    ] Check 
                Moveto [Saldo do Documento    ] Check 
                Moveto [Codigo do Destinatario] Check TypeIn "~VSDGDESTINAT.."
                Moveto [Razao Social          ] Check
                Moveto [Documento Referente   ] Check
                Moveto [Tipo Docto Gerador    ] Check
                Moveto [Numero Docto Gerador  ] Check
                {Ask} TypeIn "\\Sistemas\\CtaRec\\"+Dir_Trab+"DupBaixa" Enter
                Moveto [Numero do Lancamento  ] Example "NLAN"
                Moveto [Sequencia da Baixa    ] TypeIn "Calc Max as Sequencia da Baixa"
                Moveto [Data do Pagamento     ] TypeIn "Calc Max as Data do Pagamento"
                Moveto [Valor do Recebimento  ] TypeIn "Calc Sum as Valor do Recebimento"
                Moveto [Valor do Juros        ] TypeIn "Calc Sum as Valor do Juros"
                Moveto [Valor do Desconto     ] TypeIn "Calc Sum as Valor do Desconto"
                Do_It!
                ClearAll
        EndIf        

        {Ask} {Answer}
        Moveto [Numero do Lancamento ] Example "NLAN" 
        Moveto [Codigo da Empresa    ] Example "EMPRE"
        Moveto [Nome Fantasia Empresa] Example "NFEMP"
        Moveto [Numero do Documento  ] Example "DOCTO"
        Moveto [Serie do Documento   ] Example "SERIE"
        Moveto [Tipo do Documento    ] Example "TPDOC" 
        Moveto [Data de Emissao      ] Example "DATEM"
        Moveto [Data de Vencimento   ] Example "DATVE"
        Moveto [Codigo do Destinatario] Example "CODIG"
        Moveto [Razao Social         ] Example "NOMEC"
        Moveto [Valor do Documento   ] Example "VRDUP"
        Moveto [Saldo do Documento   ] Example "SALD"
        Moveto [Documento Referente  ] Example "NNF"
        Moveto [Sequencia da Baixa   ] Example "SEQB"
        Moveto [Data do Pagamento    ] Example "DTPG"
        Moveto [Valor do Recebimento ] Example "VREC"
        Moveto [Valor do Juros       ] Example "VJUR"
        Moveto [Valor do Desconto    ] Example "VDES"
        Moveto [Tipo Docto Gerador   ] Example "TDOCTOORIG"
        Moveto [Numero Docto Gerador ] Example "NDOCTOORIG"
        
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Numero do Lancamento ] Example "NLAN"
        Moveto [Codigo da Empresa    ] Example "EMPRE"
        Moveto [Nome Fantasia Empresa] Example "NFEMP"
        Moveto [Numero do Documento  ] Example "DOCTO"
        Moveto [Serie do Documento   ] Example "SERIE"
        Moveto [Tipo do Documento    ] Example "TPDOC" 
        Moveto [Codigo               ] Example "CODIG"
        Moveto [Razao Social         ] Example "NOMEC"
        Moveto [Data de Emissao      ] Example "DATEM"
        Moveto [Data Vencimento      ] Example "DATVE"
        Moveto [Valor do Documento   ] Example "VRDUP"
        Moveto [Saldo do Documento   ] Example "SALD"
        Moveto [Documento Referente  ] Example "NNF"
        Moveto [Sequencia da Baixa   ] Example "SEQB"
        Moveto [Data Pagamento       ] Example "DTPG"
        Moveto [Valor do Pagamento   ] Example "VREC"
        Moveto [Valor do Juros       ] Example "VJUR"
        Moveto [Valor do Desconto    ] Example "VDES"
        Moveto [Tipo Documento Origem  ] Example "TDOCTOORIG"
        Moveto [Numero Documento Origem] Example "NDOCTOORIG"
        Do_It!
        ClearAll
        
EndIf                      

EndProc  ; (Seleciona)

;*******************************************************************************
;*                                                                             *
;*******************************************************************************
Proc Processa()

Sort Tabela on "Numero do Lancamento", "Sequencia da Baixa"

NUMLANC="***"
Coedit Tabela
Scan
  If [Numero do Lancamento]<>NUMLANC
     Then NUMLANC=[Numero do Lancamento]
          [Soma_Valor do Documento]=[Valor do Documento]
          [Soma_Saldo do Documento]=[Saldo do Documento]
  EndIf
  [DocumentoOrigem]=[Codigo da Empresa]+"."+[Tipo Documento Origem]+"."+[Numero Documento Origem]   
EndScan
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Valor do Pagamento  ] TypeIn "blank, Changeto 0" Down
Moveto [Valor do Juros      ] TypeIn "blank, Changeto 0" Down
Moveto [Valor do Desconto   ] TypeIn "blank, Changeto 0"
Do_It!
ClearAll       
               
If VSDGCODMODELO="01" 
   then return
endif   

;-- Sintetico ------------------------------------------------------------------
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Codigo                 ] Check
Moveto [Razao Social           ] Check
Moveto [Soma_Valor do Documento] TypeIn "Calc Sum as Valor do Documento"
Moveto [Soma_Saldo do Documento] TypeIn "Calc Sum as Saldo do Documento"
Moveto [Valor do Pagamento     ] TypeIn "Calc Sum as Valor do Pagamento"
Moveto [Valor do Juros         ] TypeIn "Calc Sum as Valor do Juros"
Moveto [Valor do Desconto      ] TypeIn "Calc Sum as Valor do Desconto"
Do_It!
ClearAll       

Empty(Tabela)

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "EMPRE"
Moveto [Nome Fantasia Empresa  ] Example "NFEMP"
Moveto [Codigo                 ] Example "CODIG"
Moveto [Razao Social           ] Example "NOMEC"
Moveto [Valor do Documento     ] Example "VRDUP"
Moveto [Saldo do Documento     ] Example "SALD"
Moveto [Valor do Pagamento     ] Example "VREC"
Moveto [Valor do Juros         ] Example "VJUR"
Moveto [Valor do Desconto      ] Example "VDES"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "EMPRE"
Moveto [Nome Fantasia Empresa  ] Example "NFEMP"
Moveto [Codigo                 ] Example "CODIG"
Moveto [Razao Social           ] Example "NOMEC"
Moveto [Soma_Valor do Documento] Example "VRDUP"
Moveto [Soma_Saldo do Documento] Example "SALD"
Moveto [Valor do Pagamento     ] Example "VREC"
Moveto [Valor do Juros         ] Example "VJUR"
Moveto [Valor do Desconto      ] Example "VDES"
Do_It!
ClearAll

endproc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_DESTINAT"       : Campo="TG_EMPRESA"
            Case Campo="TG_OPDTEMISVENC"   : Campo="TG_DESTINAT"
            Case Campo="TG_DTINI"          : Campo="TG_OPDTEMISVENC" 
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_TPPGTO"         : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"      : Campo="TG_TPPGTO"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT" : Campo="TG_OPDTEMISVENC"
                    Case Campo="TG_OPDTEMISVENC": Campo="TG_DTINI"
                    Case Campo="TG_DTINI"    : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"    : Campo="TG_TPPGTO"
                    Case Campo="TG_TPPGTO"   : Campo="TG_CODMODELO"
                         VSDGTPPGTO=ControlValue("TG_TPPGTO")
                         Switch
                           Case VSDGTPPGTO="2" : VSDGNOMTPPGTO="éLTIMO/ACUMULADO"
                           otherwise           : VSDGTPPGTO="1"
                                                 VSDGNOMTPPGTO="DETALHAR"
                         EndSwitch 
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_TPPGTO" :
       MSG_CAMPO="1=Detalhar  2=éltimo Pagto/Acumulado"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Pessoa/Titulos")
ModeloRelatoriosAdd("01B Por Pessoa         - Sint‚tico")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
If Not IsAssigned (SYS_CODIGO_CLIENTE) Then SYS_CODIGO_CLIENTE = "" EndIf

VSDGEMPRESA  = ""
VSDGDESTINAT = ""
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()
VSDGOPDTEMISVENC   =""
VSDGNOMOPDTEMISVENC=""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Rela‡„o de Titulos por Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP
                                                                                                      
    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A04" Picture "[&,#][#*#]" Tag "TG_DESTINAT"     To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST" To VSDGNOMDEST

    Label  @ 04,00 "Op‡äes de Datas" For "TG_OPDTEMISVENC"
    Accept @ 05,04 Width 04 "A1"  Picture "1,2"  Tag "TG_OPDTEMISVENC"    To VSDGOPDTEMISVENC
    Accept @ 05,09 Width 25 "A20" Picture "!*!"  Tag "TG_NOMOPDTEMISVENC" To VSDGNOMOPDTEMISVENC

    Label  @ 06,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 08,00 "Op‡„o de Pagamento" For "TG_TPPGTO"
    Accept @ 09,04 Width 04 "A1"  Picture "1,2"  Tag "TG_TPPGTO"     To VSDGTPPGTO
    Accept @ 09,09 Width 25 "A20" Picture "!*!"  Tag "TG_NOMTPPGTO" To VSDGNOMTPPGTO

    Label  @ 11,00  "Modelo de ~R~elat˘rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, Gerando Relat˘rio")

  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\CtaRec\\RM_0260"
  Copy "\\Base\\Sistemas\\CtaRec\\RM_0260" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile
  Processa()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  switch
    case VSDGCODMODELO="01"  : 
          If VSDGOPDTEMISVENC="2" 
            Then IMPRIREL(Tabela,"R")
            Else IMPRIREL(Tabela,"1")
          EndIf

    case VSDGCODMODELO="01B" : IMPRIREL(Tabela,"2")
    
  endswitch

  Delete Tabela
  
EndWhile
ClearAll
Release Vars All
Release Procs All
