;** RestauCF *******************************************************************
;*  Restaura‡ao de ECF's                                                       *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/06/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 06/10/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 14/08/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Deleta_Arquivo
;Ultima Alteracao: 09/11/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TpDoctos
;Ultima Alteracao: 14/02/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Posto    
;Ultima Alteracao: 13/03/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Verifica se j  existe lancto dos Cheques
;Ultima Alteracao: 20/01/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes caminho execvise 
;Ultima Alteracao: 16/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Layout
;Ultima Alteracao: 27/06/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Ćo Arj para c:\Arj
;Ultima Alteracao: 28/09/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Dados dos Cheques
;Ultima Alteracao: 30/11/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Ćo de "ExecVise -> Vexe","Arj -> Varj"
;Ultima Alteracao: 08/12/2011 por Karina Andrade
;Motivo Alteracao: Nova nomeclatura pacote importado
;Ultima Alteracao: 03/01/2012 por Karina Andrade
;Motivo Alteracao: Ajustes nome pacote importado
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Substitui‡Ćo Editor novo arquivo por FileWrite

;*******************************************************************************
;* ROTINA PROCESSA  -> realiza o processamento da Restaura‡ao                  *
;*******************************************************************************
Proc PROCESSA()
ClearAll

If Not IsTable(VSDGDRIVE+"\\NotaC") Or
   Not IsTable(VSDGDRIVE+"\\NotaI") Or
   Not IsTable(VSDGDRIVE+"\\NotaV") Or
   Not IsTable(VSDGDRIVE+"\\ECF_C") Or
   Not IsTable(VSDGDRIVE+"\\ECF_T")
   Then Mensagem("A Unidade "+VSDGDRIVE+" n„o contem dados de Cupons Fiscais !")
        Return
EndIf

AGUARDE("Aguarde, Restaurando NotaI"+" [ 1/8]")
{Ask} TypeIn VSDGDRIVE+"\\NotaC" Enter
Moveto [Codigo da Empresa      ] Example "e" TypeIn ",~VSDGEMPRESA.."
Moveto [Numero do Documento    ] Example "d"
Moveto [Serie do Documento     ] Example "s"
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Tipo do Documento      ] TypeIn "CUP.."
{Ask} TypeIn VSDGDRIVE+"\\NotaI" Enter Check
Moveto [Codigo da Empresa      ] Example "e"
Moveto [Numero do Documento    ] Example "d"
Moveto [Serie do Documento     ] Example "s"
Do_It!
ClearAll

If SYS_CODIGO_CLIENTE="0001"
   Then {Ask} {Answer}
        Moveto [Codigo da Empresa    ] TypeIn "Changeto 0010"
        Do_It!
        ClearAll
EndIf


{Tools} {More} {Add} {Answer} {NotaI} {NewEntries}
ClearAll
If IsTable("keyViol")
   Then Delete("KeyViol")
EndIf


AGUARDE("Aguarde, Restaurando NotaV"+" [ 2/8]")
{Ask} TypeIn VSDGDRIVE+"\\NotaC" Enter
Moveto [Codigo da Empresa      ] Example "e" TypeIn ",~VSDGEMPRESA.."
Moveto [Numero do Documento    ] Example "d"
Moveto [Serie do Documento     ] Example "s"
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Tipo do Documento      ] TypeIn "CUP.."
{Ask} TypeIn VSDGDRIVE+"\\NotaV" Enter Check
Moveto [Codigo da Empresa      ] Example "e"
Moveto [Numero do Documento    ] Example "d"
Moveto [Serie do Documento     ] Example "s"
Do_It!
ClearAll

If SYS_CODIGO_CLIENTE="0001"
   Then {Ask} {Answer}
        Moveto [Codigo da Empresa    ] TypeIn "Changeto 0010"
        Do_It!
        ClearAll
EndIf

{Tools} {More} {Add} {Answer} {NotaV} {NewEntries}
ClearAll
If IsTable("keyViol")
   Then Delete("KeyViol")
EndIf

AGUARDE("Aguarde, Restaurando NotaC"+" [ 3/8]")
{Ask} TypeIn VSDGDRIVE+"\\NotaC" Enter Check
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Tipo do Documento      ] TypeIn "CUP.."
Do_It!
ClearAll

If SYS_CODIGO_CLIENTE="0001"
   Then {Ask} {Answer}
        Moveto [Codigo da Empresa    ] TypeIn "Changeto 0010"
        Moveto [Nome Fantasia Empresa] TypeIn "Changeto MINAS LACK"
        Do_It!
        ClearAll
EndIf

{Tools} {More} {Add} {Answer} {NotaC} {NewEntries}
ClearAll
If IsTable("keyViol")
   Then Delete("KeyViol")
EndIf

AGUARDE("Aguarde, Restaurando Tipos de Documentos")
{Ask} TypeIn VSDGDRIVE+"\\Tpdoctos" Enter Check
Do_It!
ClearAll

{Tools} {More} {Add} {Answer} {\\Sistemas\\Cadastro\\TpDoctos} {NewEntries}
ClearAll
If IsTable("keyViol")
   Then Delete("KeyViol")
EndIf


AGUARDE("Aguarde, Restaurando ECF_C"+" [ 4/8]")
{Ask} TypeIn VSDGDRIVE+"\\ECF_C" Enter Check
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Data                   ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Do_It!
ClearAll

If SYS_CODIGO_CLIENTE="0001"
   Then {Ask} {Answer}
        Moveto [Codigo da Empresa    ] TypeIn "Changeto 0010"
        Do_It!
        ClearAll
EndIf

{Tools} {More} {Add} {Answer} {ECF_C} {NewEntries}
ClearAll
If IsTable("keyViol")
   Then Delete("KeyViol")
EndIf

AGUARDE("Aguarde, Restaurando ECF_T"+" [ 5/8]")
{Ask} TypeIn VSDGDRIVE+"\\ECF_T" Enter Check
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Data                   ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Do_It!
ClearAll

If SYS_CODIGO_CLIENTE="0001"
   Then {Ask} {Answer}
        Moveto [Codigo da Empresa    ] TypeIn "Changeto 0010"
        Do_It!
        ClearAll
EndIf

{Tools} {More} {Add} {Answer} {ECF_T} {NewEntries}
ClearAll
If IsTable("keyViol")
   Then Delete("KeyViol")
EndIf

AGUARDE("Aguarde, Atualizando Cheques"+" [ 6/8]")
{Ask} TypeIn VSDGDRIVE+"\\NotaC" Enter Check
Moveto [Codigo da Empresa      ] Example "e" TypeIn ",~VSDGEMPRESA.."
Moveto [Numero do Documento    ] Example "d"
Moveto [Serie do Documento     ] Example "s"
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Tipo do Documento      ] TypeIn "CUP.."
Moveto [Situacao               ] TypeIn "Not C"
{Ask} TypeIn VSDGDRIVE+"\\NotaV" Enter Check
Moveto [Codigo da Empresa      ] Example "e"
Moveto [Numero do Documento    ] Example "d"
Moveto [Serie do Documento     ] Example "s"
Moveto [Forma de Pagamento     ] TypeIn "CH Or CP"
Do_It!
ClearAll

If SYS_CODIGO_CLIENTE="0001"
   Then {Ask} {Answer}
        Moveto [Codigo da Empresa    ] TypeIn "Changeto 0010"
        Moveto [Nome Fantasia Empresa] TypeIn "Changeto MINAS LACK"
        Moveto [Codigo da Empresa-1  ] TypeIn "Changeto 0010"
        Do_It!
        ClearAll
EndIf

View "\\Sistemas\\CheqRec\\ChequeC"
View "\\Sistemas\\CheqRec\\ChequeI"
View "NotaC"
View "P_Cupom"
Coedit "Answer"
NR = NRecords("Answer")
CODEMP="****"
SERDOC="****"
NUMDOC="****"
Scan 
  If NR=0 Then QuitLoop EndIf
  Barra(NR, RecNo())
  Aguarde("Aguarde, Processando "+" [ 6/8]"+BARRA_STRING)

  If CODEMP<>[Codigo da Empresa]
     Then CODEMP=[Codigo da Empresa]
          Moveto "P_Cupom"
          PARAM_NLCHQ_IGUAL_NF=[NLCheque_Igual_NF]
          Moveto "Answer"
  EndIf

  If [Codigo da Empresa  ]<>CODEMP Or
     [Serie do Documento ]<>SERDOC Or
     [Numero do Documento]<>NUMDOC
     Then
           CODEMP=[Codigo da Empresa  ]
           SERDOC=[Serie do Documento ]
           NUMDOC=[Numero do Documento]

           Moveto "\\Sistemas\\CheqRec\\ChequeC"
           If PARAM_NLCHQ_IGUAL_NF="S"
             Then NUMEROL=NumVal([Answer->Numero do Documento])
                  Moveto [Numero do Lancamento]
                  Locate NUMEROL
             Else Moveto [Observacao do Lancamento]
                  Locate "REF. "+[Answer->Codigo da Empresa]+"/"+[Answer->Tipo do Documento]+"/"+[Answer->Numero do Documento]
           EndIf
           If RetVal
              Then NUMEROL=[Numero do Lancamento]
                   Moveto "\\Sistemas\\CheqRec\\ChequeI"
                   Moveto [Numero do Lancamento]
                   Locate NUMEROL
                   If RetVal
                      Then While [Numero do Lancamento]=NUMEROL
                             If [Situacao]="LIQUIDADO" Or [Situacao]="PRORROGADO"
                                Then MSG="Cuidado !. Existem Cheques Liquidados ou Prorrogados p/ esta Nota.//"
                                     MSG=MSG+"Os Cheques n„o podem ser atualizados por aqui//"
                                     MSG=MSG+"Verificar no Controle de Cheques Ok !//"
                                     MSG=MSG+"Lan‡amento: "+StrVal(NUMEROL)+"  CH: "+SubStr([Observacao do Cheque],1,12)
                                     Mensagem(MSG)
                                     Skip
                                     If EOT() Then QuitLoop EndIf
                                Else Del
                             EndIf
                           EndWhile
                   EndIf
              Else While True
                     Moveto "\\Sistemas\\CheqRec\\ChequeC"
                     Moveto [Numero do Lancamento]

                     If PARAM_NLCHQ_IGUAL_NF="S"
                        Then NUMEROL=NumVal([Answer->Numero do Documento])
                        Else End
                             If [Numero do Lancamento]=BlankNum()
                                Then NUMEROL=1
                                Else NUMEROL=[Numero do Lancamento]+1
                             EndIf
                     EndIf
                     Locate NUMEROL
                     If Not RetVal
                        Then End
                             Down
                             [Numero do Lancamento   ]=NUMEROL
                     EndIf
                     If Not IsLockRecord() Then QuitLoop EndIf
                   EndWhile
                   Moveto [Numero do Lancamento]
                   Locate NUMEROL
                   If RetVal
                      Then [Codigo da Empresa       ]=[Answer->Codigo da Empresa       ]
                           [Data de Entrada         ]=[Answer->Data de Emissao         ]
                           [Codigo                  ]=[Answer->Codigo                  ]
                           [Codigo do Representante ]=[Answer->Codigo do Representante ]
                           [Observacao do Lancamento]="REF. "+[Answer->Codigo da Empresa]+"/"+[Answer->Tipo do Documento]+"/"+[Answer->Numero do Documento]
                           UnLockRecord
                   EndIf
           EndIf

           Moveto "NotaC"
           Moveto [Codigo da Empresa]
           Locate [Answer->Codigo da Empresa  ],
                  [Answer->Numero do Documento],
                  [Answer->Serie do Documento ]
           If RetVal
              Then [Numero Lancamento Cheque]=NUMEROL
                   UnLockRecord
           EndIf
  EndIf

  Moveto "\\Sistemas\\CheqRec\\ChequeI"
  Moveto [Numero do Lancamento]
  Locate NUMEROL, NumVal([Answer->Sequencia])
  If Not RetVal
     Then End
          Down
          [Numero do Lancamento]=NUMEROL
          [Sequencia do Cheque ]=NumVal([Answer->Sequencia])
          [Codigo_Banco        ]=[Answer->Codigo_Banco   ]
          [Agencia             ]=[Answer->Agencia        ]
          [Numero_Conta        ]=[Answer->Numero_Conta   ]
          [Numero_Cheque       ]=[Answer->Numero_Cheque  ]
          [CPF                 ]=[Answer->CPF            ]
          [Tipo_Emitente       ]=[Answer->Tipo_Emitente  ]
          [Titular_Cheque      ]=[Answer->Titular_Cheque ]
          [Cidade              ]=[Answer->Cidade-1       ]
          [UF                  ]=[Answer->UF-1           ]
          [Data Vencimento     ]=[Answer->Data           ]
          [Valor               ]=[Answer->Valor          ]
          [Observacao do Cheque]=[Answer->Observacao     ]
          [Sistema Origem      ]="NF"
          [Tipo do Documento   ]="CF"
          [Numero do Documento ]=[Answer->Numero do Documento ]
          [Situacao            ]="EM ABERTO"
          [Codigo_Cliente      ]=[Answer->Codigo              ]
          [Data_Entrada        ]=Today()
          Controle_Dia()
          [Codigo CMC7         ]=[Answer->Codigo CMC7         ]
          UnLockRecord
  EndIf

  Moveto "Answer"
EndScan
Do_It!
ClearAll


AGUARDE("Aguarde, Atualizando Ficha Financeira"+" [ 7/8]")
View "\\Sistemas\\Cadastro\\FichaCli"
Tabela=VSDGDRIVE+"\\"+"NotaC"

Coedit "\\Sistemas\\Cadastro\\FichaCli",Tabela
Scan
  If [Tipo]="C" And Search("VEND",[Descricao da Destinacao])>0
     Then
          CCLIE =[Codigo           ]
          DTEMI =[Data de Emissao  ]
          VRNF  =[Valor Nota Fiscal]

          Moveto "\\Sistemas\\Cadastro\\FichaCli"
          Moveto [Codigo]
          Locate CCLIE
          If Not RetVal
             Then End Down
                  [Codigo]=CCLIE
          EndIf

          If IsBlank([Data da Primeira Compra ])
             Then [Data da Primeira Compra ]=DTEMI
                  [Valor da Primeira Compra]=VRNF
          EndIf
          If VRNF>=[Maior Fatura]
             Then [Maior Fatura        ]=VRNF
                  [Data da Maior Fatura]=DTEMI
          EndIf

          If [Data da Ultima Compra ]<=DTEMI
             Then [Data da Ultima Compra ]=DTEMI
                  [Valor da Ultima Compra]=VRNF
          EndIf
          UnLockRecord
  EndIf
  Moveto VSDGDRIVE+"\\"+"NotaC"
EndScan
Do_It!
Clearall
IMPCUP=True

;****************** Posto **************************
AGUARDE("Aguarde, Restaurando Placas de Veiculos"+" [ 8/8]")
If DirExists("\\Sistemas\\Posto\\")=0
   Then Return
Endif    
If Not IsTable("\\Sistemas\\Posto\\Abast_P")
   Then Return
EndIf    
           
If Not IsTable(VSDGDRIVE+"\\"+"ABAST_P") Or
   IsEmpty(VSDGDRIVE+"\\"+"ABAST_P")
   Then Return
EndIf

{Ask} TypeIn VSDGDRIVE+"\\"+"ABAST_P" Enter Check
Do_It!
ClearAll

{Tools} {More} {Add} {Answer} {\\Sistemas\\Posto\\Abast_P} {NewEntries} ClearAll

{Ask} {\\Sistemas\\Posto\\Abast_P}
Moveto [Codigo             ] Example "clie"
Moveto [Placa              ] Example "pvei"
Moveto [Ultima_Kilometragem] Example "ukm"
{Ask} {Answer} Check
Moveto [Codigo             ] Example "clie"
Moveto [Placa              ] Example "pvei"
Moveto [Ultima_Kilometragem] TypeIn ">" Example "ukm"
Do_It!
ClearAll

Add "Answer" "\\Sistemas\\Posto\\Abast_P"

ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA    =""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
Switch
   Case Evento["KeyCode"] =   9: Temp=False
   Case Evento["KeyCode"] = -59: Dialog_F1()
   Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
         Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
         SYS_TECLA_ACIONADA=Evento["KeyCode"]
         Seta_Tecla_Acionada()
         CancelDialog
   Case Evento["KeyCode"] =  27:
        Temp=False
        Switch
          Case Campo="TG_EMPRESA"       : Campo="NO"
          Case Campo="TG_DTREF"         : Campo="TG_EMPRESA"
          Case Campo="TG_DTINI"         : Campo="TG_DTREF"
          Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
          Case Campo="TG_DRIVES"        : Campo="TG_DTFIM"
          Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
        EndSwitch
    Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_DTREF"
                    Case Campo="TG_DTREF"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   :
                         If Isblank(VSDGDTINI)
                            Then Mensagem("Data inicial invalida !")
                                 Campo="TG_DTINI"
                            Else Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM"   :
                         If IsBlank(VSDGDTFIM) Or
                            VSDGDTFIM<VSDGDTINI
                            Then Mensagem("Data final invalida !")
                            Else Campo="TG_DRIVES"
                         EndIf
                    Case Campo="TG_DRIVES"   :
                         VSDGDRIVE=ControlValue("TG_DRIVES")
                         Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf
Switch
  Case Campo="TG_EMPRESA":
       MSG_CAMPO="Informe uma Empresa"
  Case Campo="TG_DTREF" :
       MSG_CAMPO="Informe a data da Transa‡„o"
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a data inicial"
  Case Campo="TG_DRIVES":
       MSG_CAMPO="Selecione o drive desejado !"
       TECLA=Chr(27)+""+Chr(26)+"=Selecionar  "
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

Proc Deleta_Arquivos()

  Deleta_Arquivo(VSDGDRIVE+"\\NOTA*.DB")
  Deleta_Arquivo(VSDGDRIVE+"\\NOTA*.PX")
  Deleta_Arquivo(VSDGDRIVE+"\\NOTA*.MB")
  Deleta_Arquivo(VSDGDRIVE+"\\ECF_C.*")
  Deleta_Arquivo(VSDGDRIVE+"\\ECF_T.*")
  Deleta_Arquivo(VSDGDRIVE+"\\TPDOCTOS.*")
  Deleta_Arquivo(VSDGDRIVE+"\\ABASTC_.*")
  Sleep 2000
  
EndProc
;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf

VSDGEMPRESA=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =Today()-1
VSDGDTREF  =BlankDate()

DynArray Array_Drives[]
SysInfo Drives To Array_Drives
If IsFile("OIMPECF.sc")
   Then Play "OIMPECF"
   Else VSDGDRIVE=SubStr(Directory(),1,2)
EndIf

While True
  ShowDialog "Importa‡„o Cupom Fiscal" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
    -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140
   @ 05,12   Height 11 Width 47

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 1,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Data Transa‡„o" For "TG_DTREF"
    Accept @ 03,01 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Label  @ 04,00 "Perˇodo Referente" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "at‚" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,37 "Drives:" For "TG_DRIVES"
    PickDynArrayIndex @ 01,38 Height 5 width 05
    Columns 1
    Array_Drives
    Tag "TG_DRIVES"
    To VSDGDRIVE

    Pushbutton @ 07,10 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,22 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  
  IMPCUP=False

  Deleta_Arquivos()
  
  If VSDGEMPRESA="" 
    Then CODEMP="0000" 
    Else CODEMP=VSDGEMPRESA
  EndIf

  ARQ_ARJ="PT_ECF_"+CODEMP+"_"+
          AlinhM(StrVal(Year(VSDGDTREF)),4) +
          AlinhM(StrVal(Month(VSDGDTREF)),2)+
          AlinhM(StrVal(Day(VSDGDTREF)),2)  +
          ".ARJ"

	Aguarde("Aguarde, Descompactando arquivos de "+VSDGDRIVE+"\\"+ARQ_ARJ)
  Executa_Programa("c:\\vise\\Varj.exe e -y "+VSDGDRIVE+"\\"+ARQ_ARJ+" "+VSDGDRIVE+"\\")
  Sleep 3000

  Processa()
  Deleta_Arquivos()
  LimpAguarde()
  
  If IMPCUP
     Then ARQ_IMP=VSDGDRIVE+"\\IMPORTADO_"+
                  Substr(ARQ_ARJ,1,20)+"_"+
                  Substr(Time(),1,2)  +
                  Substr(Time(),4,2)  +
                  Substr(Time(),7,2)  +
                  ".ARJ"
  
          ExecVise("REN "+VSDGDRIVE+"\\"+ARQ_ARJ+" \""+ARQ_IMP+"\"")
          
          MSG="Opera‡ao Finalizada.// //"
          MSG=MSG+"NĆo esque‡a de Reprocessar o Estoque !"
     Else MSG="Opera‡„o Cancelada !"
  EndIf   
  Mensagem(MSG)
  
  FileWrite        "OIMPECF.sc" From ";****** Variaveis de Configura‡„o Drive Padrao Vise Informatica"+"\n"
  FileWrite Append "OIMPECF.sc" From "VSDGDRIVE="+CHR(34)+VSDGDRIVE+Chr(34)+"\n"

EndWhile
ClearAll
Release Vars All
Release Procs All
