;** RM_3081A  *******************************************************************
;* Resumo de Vendas por Usuario/Item                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 06/03/2018 por Anivel Augusto Rodrigues
;Ultima Alteracao: 05/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes agrupado RM_3081    
;Ultima Alteracao: 05/03/2020 por Anivel Augusto Rodrigues                                     
;Motivo Alteracao: Substituido pelo RM_3081

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc RM_3081A_Seleciona()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then
        If Not IsBlank(VSDGMARCA) or
           Not IsBlank(VSDGFAMI) or
           Not IsBlank(VSDGGRP)
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        EndIf

        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
				Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ]       Example "ndoc"
        Moveto [Serie do Documento     ]       Example "sdoc"
        Moveto [Codigo                 ]       TypeIn "~VSDGDESTINAT.."
        Moveto [Codigo_Usuario         ] Check TypeIn "~VSDGCHAPA.."
        If IsBlank(VSDGNCONTROLE)
           Then Switch
                  Case VSDGOPDTESI="1" : Moveto [Data de Emissao ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                  Case VSDGOPDTESI="2" : Moveto [Data de Saida   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                  Case VSDGOPDTESI="3" : Moveto [Data_Inclusao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                EndSwitch
        EndIf
        Moveto [Situacao               ] TypeIn "Not C"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Numero_Controle_Dia    ] TypeIn "~VSDGNCONTROLE.."

        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo do Item         ] Check 
        If Not IsBlank(VSDGMARCA) Or
           Not IsBlank(VSDGFAMI) Or
           Not IsBlank(VSDGGRP)
           Then Moveto [Codigo do Item ] Example "cite" TypeIn ", ~VSDGITEM.."
           Else Moveto [Codigo do Item ]                TypeIn   "~VSDGITEM.."
        EndIf
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        RM_3081A_Adiciona_Dados("VENDAS")
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc RM_3081A_Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo_Usuario         ] Example "cu"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo_Usuario         ] Example "cu"
Moveto [Codigo do Item         ] Example "cite"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Quantidade      ] Example "qtde"
       Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc RM_3081A_Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Unidade Fiscal         ] Example "unf"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Usuarios}
Moveto [Chapa                  ] Example "cu"
Moveto [Nome                   ] Example "du"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo_Usuario         ] Example "cu"
Moveto [Nome_Usuario           ] typein "changeto _du"
Do_It!
ClearAll

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as \"Vendas_Quantidade\""
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as \"Vendas_Preco Total\""
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_3081A_Principal()

AGUARDE("Aguarde, gerando o relatĒrio")

Tabela=Cria_Temp(PrivDir())
Empty "\\Base\\Sistemas\\Vendas\\RM_3081"
Copy "\\Base\\Sistemas\\Vendas\\RM_3081" Tabela

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  RM_3081A_Seleciona()
EndWhile

If not IsEmpty(Tabela)
   Then 
        RM_3081A_Processa()

        Switch
          Case VSDGCODMODELO="1U" : CopyReport "\\Base\\Sistemas\\Vendas\\Rm_3081"  "R" "Answer" "R"
        EndSwitch
        IMPRIREL("Answer","R")

   Else MENSAGEM("No existem registros a processar")
EndIf

;;;Delete Tabela
EndProc

;-- Chamada principal ----------------------------------------------------------
RM_3081A_Principal()

Release Vars Tabela
Release Procs RM_3081A_Principal, RM_3081A_Seleciona, RM_3081A_Adiciona_Dados, RM_3081A_Processa

