;** ExpSaida *******************************************************************
;*  Exportacao Registro de Saida - Fiscal para Arquivo Texto                   *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 10/11/2005 por Davi Pereira Carrano
;Motivo Alteracao: Envia para o Diretorio Visao

;*******************************************************************************
;* Gera Arquivo Texto p/ Registro de Saida                                     *
;*******************************************************************************
Proc EXPORTA_S()
ClearAll

C=0
NR=NRecords("\\Sistemas\\Vendas\\RegSaida")

If DirExists("\\Sistemas\\Exporta\\Dados\\Asplan")=0
   Then comando="Md \\Sistemas\\Exporta\\Dados\\Asplan"
        @ 01,00 Run NoRefresh comando
EndIf

ARQ ="\\Sistemas\\Exporta\\Dados\\Asplan\\MS"+"0"+PREFIXO+MES+".TXT"
If IsFile(ARQ)
   Then Run NoRefresh "Del "+ARQ+">Nul"
EndIf
View "\\Sistemas\\Vendas\\RegSaida"

Scan
   Barra(NR, RecNo())
   AGUARDE("Aguarde, Exportando Dados Saidas "+BARRA_STRING)

   C=C+1

   CGCCPF=""
   TIPOP =""
   If SubStr([CGC],03,1)="." and
      SubStr([CGC],07,1)="." and
      SubStr([CGC],11,1)="/" and
      SubStr([CGC],16,1)="-"
      Then TIPOP  ="J"
           CGCCPF=SubStr([CGC],01,2)+
                  SubStr([CGC],04,3)+
                  SubStr([CGC],08,3)+
                  SubStr([CGC],12,4)+
                  SubStr([CGC],17,2)
      Else If SubStr([CGC],04,1)="." and
              SubStr([CGC],08,1)="." and
              SubStr([CGC],12,1)="-"
              Then TIPOP  ="F"
                   CGCCPF=SubStr([CGC],01,3)+
                          SubStr([CGC],05,3)+
                          SubStr([CGC],09,3)+
                          SubStr([CGC],13,2)
           EndIf
   EndIf

   Print File ARQ AlinhM([Codigo da Empresa     ],4)
   Print File ARQ AlinhM([Numero da Nota Fiscal ],10)
   Print File ARQ Fill("0",3)
   Print File ARQ Fill(" ",5)
   Print File ARQ Completa(Substr([Razao Social],1,30),30," ")
   Print File ARQ Completa(CGCCPF,14," ")
   Print File ARQ Completa(Substr([IE],1,15),15," ")
   Print File ARQ AlinhM([Estado Cliente],2)
   ESPECIE = " "
   SERIE   = " "
   Switch
       Case Strim([Especie da Nota Fiscal]) = "CX1" And Strim([Serie da Nota Fiscal]) = "CUP":
            ESPECIE = "ECF"
            SERIE   = "EC  "
       Case Strim([Especie da Nota Fiscal]) = "C/F" And Strim([Serie da Nota Fiscal]) = "CX1":
            ESPECIE = "ECF"
            SERIE   = "EC  "
       Case Strim([Especie da Nota Fiscal]) = "NF" And Strim([Serie da Nota Fiscal]) = "F":
            ESPECIE = "NF "
            SERIE   = "F   "
       Case Strim([Especie da Nota Fiscal]) = "NF" And Strim([Serie da Nota Fiscal]) = "M-1":
            ESPECIE = "NF "
            SERIE   = "1   "
       Case Strim([Especie da Nota Fiscal]) = "TEL" And Strim([Serie da Nota Fiscal]) = "U":
            ESPECIE = "TEL"
            SERIE   = "U   "
       Case Strim([Especie da Nota Fiscal]) = "CEM" And Strim([Serie da Nota Fiscal]) = "U":
            ESPECIE = "CEM"
            SERIE   = "U   "
       Case Strim([Especie da Nota Fiscal]) = "NF" And Strim([Serie da Nota Fiscal]) = "D":
            ESPECIE = "NF "
            SERIE   = "2   "
       Case Strim([Especie da Nota Fiscal]) = "NFS" And Strim([Serie da Nota Fiscal]) = "1":
            ESPECIE = "NF "
            SERIE   = "1   "
       Case Strim([Especie da Nota Fiscal]) = "NFS" And Strim([Serie da Nota Fiscal]) = "F":
            ESPECIE = "NF "
            SERIE   = "U   "
       Case Strim([Especie da Nota Fiscal]) = "NF" And Strim([Serie da Nota Fiscal]) = "S-1":
            ESPECIE = "NFS"
            SERIE   = "1   "
       Case Strim([Especie da Nota Fiscal]) = "CTR" And Strim([Serie da Nota Fiscal]) = "U":
            ESPECIE = "CTR"
            SERIE   = "U   "
       Otherwise:
            ESPECIE = Strim([Especie da Nota Fiscal])
            SERIE   = Strim([Serie da Nota Fiscal  ])
   EndSwitch
   Print File ARQ Completa(ESPECIE,4," ")
   Print File ARQ Completa(SERIE,3," ")

   Print File ARQ DATA2STR_S([Data de Emissao])
   Print File ARQ DATA2STR_S([Data de Saida])
   Print File ARQ VALOR2STR_S([Valor Contabil    ],13)
   Print File ARQ VALOR2STR_S([Base Calculo ICMS ],13)
   Print File ARQ VALOR2STR_S([Base Calculo IPI  ],13)
   Print File ARQ VALOR2STR_S([Aliquota de ICMS  ],4)
   Print File ARQ VALOR2STR_S([ICMS Debitado     ],11)
   Print File ARQ VALOR2STR_S([IPI Debitado      ],11)
   Print File ARQ Fill("0",13)
   If [CFO]="5403"
      Then Print File ARQ VALOR2STR_S([ICMS Outros       ],13)
      Else Print File ARQ Fill("0",13)
   EndIf
   Print File ARQ Fill("0",1)
   Print File ARQ Fill("0",4)
   Print File ARQ VALOR2STR_S([ICMS Isento       ],13)
   If [CFO]<>"5403"
      Then Print File ARQ VALOR2STR_S([ICMS Outros       ],13)
      Else Print File ARQ Fill("0",13)
   EndIf
   Print File ARQ VALOR2STR_S([IPI Isento        ],13)
   Print File ARQ VALOR2STR_S([IPI Outros        ],13)
   Print File ARQ Fill(" ",15)
   Print File ARQ Fill(" ",5)
   Print File ARQ Fill("0",5)

   Print File ARQ AlinhM([Condicao de Pagamento   ], 2)

   Print File ARQ Fill("0",45)
   Print File ARQ Fill("0",24)
   Print File ARQ Fill(" ",2)
   Print File ARQ VALOR2STR_S([Totalizador Inicial  ],13)
   Print File ARQ VALOR2STR_S([Totalizador Final    ],13)
   Print File ARQ VALOR2STR_S([Cancelados           ],13)
   Print File ARQ VALOR2STR_S([Descontos            ],13)
   Print File ARQ Completa([Numero Serie Fabricacao ],15," ")
   Print File ARQ AlinhM([Contador Ordem Operacao ], 6)
   Print File ARQ AlinhM(STRVAL([Numero do ECF    ]),4)
   Print File ARQ Fill("0",5)
   Print File ARQ Fill("0",2)
   Print File ARQ AlVar([CFO                     ],4," ")
   Print File ARQ Fill("0",20)
   Print File ARQ Fill(" ",50)
   Print File ARQ Fill("0",8)
   Print File ARQ Fill(" ",4)
   Print File ARQ Fill("0",16)
   Print File ARQ AlinhM([Numero Varias Notas     ],10)

   Print FIle ARQ "\n"

EndScan

EndProc

