
; script tem que ser revisado !!


;** Rm_0200D *******************************************************************
;*  Emissao Resumo de Pedidos                                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 08/02/2010 por Cleber Alves             
;Ultima Alteracao: 06/12/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes de criterios
;Ultima Alteracao: 21/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                  
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                  
;Ultima Alteracao: 28/01/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao novo processo concetrador RM_0200, substitudo do RM_3060                 

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc RM_0200D_Seleciona()
ClearAll

{Ask} {\\Sistemas\\Vendas\\Destin}
Moveto [Codigo da Destinacao  ] Example "cd"
Moveto [Tipo Movimento Estoque] TypeIn "S"

If Not IsBlank(VSDGMARCA) or
   Not IsBlank(VSDGFAMI) or
   Not IsBlank(VSDGGRP) or
   Not IsBlank(VSDGREFERENCIA) Or
   Not IsBlank(VSDGDEPART)
   Then {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ] Example "cite"
        Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
        Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
        Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        Moveto [Referencia             ] TypeIn "~VSDGREFERENCIA.."
        Moveto [Codigo do Departamento ] TypeIn "~VSDGDEPART.."
EndIf

{Ask} TypeIn "\\Sistemas\\Vendas\\PedidoC" Enter
Moveto [Numero do Pedido      ] Example "Pedido"
Moveto [Codigo da Empresa     ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo da Destinacao  ] Example "cd"
Moveto [Situacao do Pedido    ] 
switch
  case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
  case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
  case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
  case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
endswitch

Switch
  Case VSDGOPDTPEEI="1": Moveto [Data de Entrega    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
  Case VSDGOPDTPEEI="2": Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
  Case VSDGOPDTPEEI="3": Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
EndSwitch
Moveto [Cidade                 ] TypeIn CIDADE
Moveto [UF                     ] TypeIn "~VSDGESTADO.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."

{Ask} TypeIn "\\Sistemas\\Vendas\\PedidoI" Enter
Moveto [Numero do Pedido       ] CheckPLus Example "Pedido"

If Not IsBlank(VSDGMARCA) Or
   Not IsBlank(VSDGFAMI) Or
   Not IsBlank(VSDGGRP) Or
   Not IsBlank(VSDGREFERENCIA) Or
   Not IsBlank(VSDGDEPART)
   Then Moveto [Codigo do Item ] CheckPLus Example "cite" TypeIn ",~VSDGITEM.."
   else Moveto [Codigo do Item ] CheckPLus                TypeIn "~VSDGITEM.." 
EndIf

Moveto [Quantidade             ] CheckPLus TypeIn ">" Example "qf"
Moveto [Quantidade Faturada    ] CheckPLus Example "qf"
Moveto [Preco Total            ] CheckPLus
Moveto [Valor Desconto Total   ] CheckPLus
Moveto [Preco Unitario         ] CheckPLus

Do_It!
ClearAll

RM_0200D_Adiciona_Dados()

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc RM_0200D_Adiciona_Dados()

{Ask} {Answer} typein "Fast"
Moveto [Quantidade             ]       TypeIn "_qtd"
Moveto [Preco Total            ]       TypeIn "_prt"
Moveto [Valor Desconto Total   ]       TypeIn "_vdt"
Moveto [Preco Unitario         ]       TypeIn "changeto (_prt-_vdt)/_qtd"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Vendas_Quantidade      ] Example "qtde"
Moveto [Vendas_Preco Total     ] Example "ptot" 

Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc RM_0200D_Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Check  TypeIn "~VSDGITEM.." 

Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Tipo do Item           ] Check
Moveto [Descricao Tipo do Item ] Check

Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
Moveto [Referencia             ] TypeIn "~VSDGREFERENCIA.."

Do_It!
ClearAll
TabelaItens=Adiciona_Indice_Temp("Codigo do Item")


{Ask} TypeIn TabelaItens Enter 
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Descricao Tipo do Item ] Example "dtite"
Moveto [Unidade Fiscal         ] Example "unf"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Descricao Tipo do Item ] TypeIn "changeto _dtite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Do_It!
ClearAll

Delete TabelaItens

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as \"Vendas_Quantidade\""
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as \"Vendas_Preco Total\""
Do_It!
ClearAll

Delete Tabela
Rename "Answer" Tabela
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Tipo do Item *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Tipo do Item           ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Tipo do Item           ] Example "tpi"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Tipo do Item           ] Example "tpi"
Moveto [Total_Vendas_TipoItem  ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_0200D_Principal()

AGUARDE("Aguarde, Gerando o RelatĒrio")
Tabela=Cria_Temp(PrivDir())
Copy "\\Base\\Sistemas\\Producao\\RM_3100" Tabela
Empty(Tabela)

RM_0200D_Seleciona()

If not IsEmpty(Tabela)
   then
        RM_0200D_Processa()

        switch
          case VSDGCODMODELO="10"  : CopyReport "\\Base\\Sistemas\\Producao\\Rm_3100" "R" Tabela "R"  

        endswitch

        ;switch
        ;  case VSDGOPRELCODALFRANK2="2"  : Seta_Ordem_Report(Tabela,"2","Codigo do Item","Descricao do Item"  ,"")
        ;  case VSDGOPRELCODALFRANK2="3"  : Seta_Ordem_Report(Tabela,"2","Codigo do Item","Compras_Quantidade" ,"D")
        ;  case VSDGOPRELCODALFRANK2="4"  : Seta_Ordem_Report(Tabela,"2","Codigo do Item","Compras_Preco Total","D")
        ;endswitch

        IMPRIREL(Tabela,"R")
   else 
        MENSAGEM("No existem registros a processar")
EndIf

If IsTable(Tabela)   Then Delete Tabela   EndIf
If IsTable("Answer") Then Delete "Answer" EndIf

EndProc

;-- Chamada principal ----------------------------------------------------------
RM_0200D_Principal()

Release Vars Tabela
Release Procs RM_0200D_Principal, RM_0200D_Seleciona, RM_0200D_Adiciona_Dados, RM_0200D_Processa
