;** Rm_0100 ********************************************************************
;*  Emissao das programacoes por destinatario                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 28/03/2007 por Anivel Augusto Rodrigues
;Ultima Alteracao: 11/04/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Estamparia
;Ultima Alteracao: 24/03/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Bordado
;Ultima Alteracao: 11/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Lavanderia/Outros
;Ultima Alteracao: 25/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Todos itens ou apenas os pendentes
;Ultima Alteracao: 24/11/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Tg_NPROG, Ajuste de T¡tulo            
;Ultima Alteracao: 21/03/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes para empresa "0171"
;Ultima Alteracao: 26/03/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo no Filtro
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW
;Ultima Alteracao: 15/06/2011 por Bruno Carvalho
;Motivo Alteracao: Inclusao TG_MARCA
;Ultima Alteracao: 09/08/2011 por Karina Andrade
;Motivo Alteracao: Ajustes para exibir por Marca
;Ultima Alteracao: 24/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Ask conform VSDGNPROG

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Marca       ] TypeIn "~VSDGMARCA.."
{Ask} {Pfacc}
Moveto [Numero_Programacao    ] Example "num" TypeIn ", ~VSDGNPROG.."
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
If IsBlank(VSDGNPROG)
   Then Moveto [Data_Programacao      ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo                ] TypeIn "~VSDGDESTINAT.."
        Moveto [Destino_Producao      ]
        Switch
          Case VSDGOPDEST="1": TypeIn "INTERNO Or FACCAO"
          Case VSDGOPDEST="2": TypeIn "INTERNO"
          Case VSDGOPDEST="3": TypeIn "FACCAO"
          Case VSDGOPDEST="4": TypeIn "ESTAMPARIA"
          Case VSDGOPDEST="5": TypeIn "BORDARIA"
          Case VSDGOPDEST="6": TypeIn "LAVANDERIA"
          Case VSDGOPDEST="7": TypeIn "OUTROS"
        EndSwitch
        If VSDGSITUACAO<>"TODOS" And VSDGSITUACAO<>""
           Then Moveto [Situacao_Programacao] TypeIn "~VSDGSITUACAO"    
        EndIf
EndIf

{Ask} {PfacRI} Check
Moveto [Numero_Programacao    ] Example "num"
Moveto [Codigo do Item        ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Do_It!
ClearAll

{Ask} {Answer} Check
Moveto [Codigo do Item        ] Example "ITEM"
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEM"
Moveto [Codigo da Marca       ] Check
Moveto [Descricao da Marca    ] Check
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Quantidade Produzida  ] TypeIn "Changeto Blank"
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
{Ask} TypeIn Tabela Enter
Moveto [Numero_Programacao    ] Example "num"
{Ask} {Rfacc}
Moveto [Numero_Producao       ] Example "numprod"
Moveto [Numero_Programacao    ] Check Example "num"
{Ask} {RfacRI} Check
Moveto [Numero_Producao       ] Example "numprod"
Moveto [Codigo do Item        ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Do_It!
ClearAll

CoEdit Tabela,"Answer"
Scan

  Moveto Tabela
  Moveto [Numero_Programacao]
  Locate [Answer->Numero_Programacao],[Answer->Codigo do Item]
  If RetVal
     Then [Quantidade Produzida  ]=[Quantidade Produzida  ]+[Answer->Quantidade Produzida  ]
  EndIf
  Moveto "Answer"

EndScan
Do_It!
ClearAll

If VSDGOPIT="P"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast Delete"
        Moveto [Quantidade Programada] Example "qtd"
        Moveto [Quantidade Produzida ] TypeIn ">=" Example "qtd"
        Do_It!
        ClearAll

EndIf

{Ask} {Pfacc}
Moveto [Numero_Programacao    ] Check Example "num"
Moveto [Codigo da Empresa     ] Check
Moveto [Nome Fantasia Empresa ] Check
Moveto [Data_Programacao      ] Check
Moveto [Destino_Producao      ] Check
Moveto [Codigo                ] Check
Moveto [Nome Fantasia EmitDest] Check
Moveto [Razao Social          ] Check
Moveto [Situacao_Programacao  ] Check
{Ask} TypeIn Tabela Enter Check
Moveto [Numero_Programacao    ] Example "num"
Do_It!
ClearAll

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()

           If Campo="TG_OPDEST"
              Then ShowPopup " Op‡”es " @ 05,11
                        "~1~= Todas Confec‡”es ": " " : "1",
                        "~2~= Confec‡„o Interna": " " : "2",
                        "~3~= Confec‡„o Fac‡„o ": " " : "3",
                        Separator,
                        "~4~= Estamparias      ": " " : "4",
                        "~5~= Bordarias        ": " " : "5",
                        "~6~= Lavanderias      ": " " : "6",
                        "~7~= Outros           ": " " : "7"
                   EndMenu
                    To MenuVar
                       If MenuVar<>"Esc"
                          Then VSDGOPDEST=MenuVar
                               Switch
                                 Case VSDGOPDEST="1": VSDGNOMOPDEST="Todas Confec‡”es  "
                                 Case VSDGOPDEST="2": VSDGNOMOPDEST="Confec‡„o Interna "
                                 Case VSDGOPDEST="3": VSDGNOMOPDEST="Confec‡„o Fac‡„o  "
                                 Case VSDGOPDEST="4": VSDGNOMOPDEST="Estamparias       "
                                 Case VSDGOPDEST="5": VSDGNOMOPDEST="Bordarias         "
                                 Case VSDGOPDEST="6": VSDGNOMOPDEST="Lavanderias       "
                                 Case VSDGOPDEST="7": VSDGNOMOPDEST="Outros            "
                               EndSwitch
                       EndIf
           EndIf

     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_NPROG"         : Campo="TG_EMPRESA"
            Case Campo="TG_OPDEST"        : Campo="TG_NPROG"
            Case Campo="TG_DESTINAT"      : Campo="TG_OPDEST"
            Case Campo="TG_MARCA"         : Campo="TG_DESTINAT"
            Case Campo="TG_SITUACAO"      : Campo="TG_MARCA"
            Case Campo="TG_REFERENCIA"    : Campo="TG_SITUACAO"
            Case Campo="TG_ITEM"          : Campo="TG_REFERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_ITEM"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPIT"          :
                 If Not ISBlank(VSDGNPROG)
                    Then Campo="TG_NPROG"
                    Else Campo="TG_SITUACAO"
                 EndIf   
            Case Campo="TG_OPMODEL"       : Campo="TG_OPIT"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_NPROG"
                    Case Campo="TG_NPROG"      :
                         If Not ISBlank(VSDGNPROG)
                            Then VSDGOPDEST    =""
                                 VSDGNOMOPDEST =""
                                 VSDGDESTINAT  =""
                                 VSDGNOMDEST   =""
                                 VSDGMARCA     =""
                                 VSDGNOMMARCA  =""
                                 VSDGSITUACAO  ="" 
                                 VSDGREFERENCIA=""
                                 VSDGITEM      =""
                                 VSDGNOMITEM   =""
                                 VSDGDTINI     =BlankDate()
                                 VSDGDTFIM     =BlankDate()
                                 Campo="TG_OPIT"
                            Else Campo="TG_OPDEST"
                         EndIf
                    Case Campo="TG_OPDEST"     :
                         VSDGOPDEST=ControlValue("TG_OPDEST")
                         If Not IsBlank(VSDGOPDEST)
                            Then Switch
                                   Case VSDGOPDEST="1": VSDGNOMOPDEST="Todas Confec‡”es  "
                                   Case VSDGOPDEST="2": VSDGNOMOPDEST="Confec‡„o Interna "
                                   Case VSDGOPDEST="3": VSDGNOMOPDEST="Confec‡„o Fac‡„o  "
                                   Case VSDGOPDEST="4": VSDGNOMOPDEST="Estamparias       "
                                   Case VSDGOPDEST="5": VSDGNOMOPDEST="Bordarias         "
                                   Case VSDGOPDEST="6": VSDGNOMOPDEST="Lavanderias       "
                                   Case VSDGOPDEST="7": VSDGNOMOPDEST="Outros            "
                                 EndSwitch
                                 Campo="TG_DESTINAT"
                         EndIf
                    Case Campo="TG_DESTINAT"    : Campo="TG_MARCA" 
                    Case Campo="TG_MARCA"       : Campo="TG_SITUACAO"
                    Case Campo="TG_SITUACAO"    :
                                VSDGSITUACAO=ControlValue("TG_SITUACAO")
                                If IsBlank(VSDGSITUACAO)
                                   Then VSDGSITUACAO="TODOS"
                                EndIf
                                Campo="TG_REFERENCIA"
                    Case Campo = "TG_REFERENCIA": Campo = "TG_ITEM"            
                    Case Campo = "TG_ITEM"      : Campo = "TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_OPIT"
                    Case Campo="TG_OPIT"        :
                         VSDGOPIT=ControlValue("TG_OPIT")
                         If IsBlank(VSDGOPIT)
                            Then VSDGOPIT="T"
                         EndIf
                         Switch
                           Case VSDGOPIT="T": VSDGDESCOPIT="TODOS"
                           Case VSDGOPIT="P": VSDGDESCOPIT="PENDENTES"
                         EndSwitch
                         Campo="TG_OPMODEL"
                    Case Campo="TG_OPMODEL"    :
                         VSDGOPMODEL=ControlValue("TG_OPMODEL")
                         If Not IsBlank(VSDGOPMODEL)
                            Then Switch
                                   Case VSDGOPMODEL="1": VSDGNOMOPMODEL="Anal¡tico"
                                   Case VSDGOPMODEL="2": VSDGNOMOPMODEL="Sintetico I"
                                   Case VSDGOPMODEL="3": VSDGNOMOPMODEL="Sintetico II"
                                 EndSwitch
                                 Campo="YES"
                         EndIf
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_OPIT":
     MSG_CAMPO="Op‡„o: T=Todos  P=Pendentes"
  Case Campo="TG_OPMODEL":
     MSG_CAMPO="Op‡„o: 1=Anal¡tico  2=Sintetico I  3=Sintetico II"
  Case Campo="TG_SITUACAO":
     MSG_CAMPO="P=PROGRAMADA  E=EM PRODUCAO  S=SUSPENSA  F=FINALIZADA  Branco=Todos"
  Case Campo="TG_OPDEST":
     TECLA="F1=Op‡”es  "
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

VSDGEMPRESA     = ""
VSDGDESTINAT    = ""
VSDGDTINI       = BlankDate()
VSDGDTFIM       = BlankDate()
VSDGOPDT        = "T"
VSDGNPROG       = ""
VSDGTPITEM      = ""
VSDGMARCA       = ""
VSDGREFERENCIA  = ""

While True
  ShowDialog "Posi‡Æo da Produ‡„o/Interna/Externa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 21 Width 70

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 26 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Programa‡„o"  For "TG_NPROG"
    Accept @ 03,01 Width 09 "A6"  Picture "#*#" Tag "TG_NPROG" To VSDGNPROG
    Accept @ 03,11 Width 24 "A20" Picture "!*!" Tag "TG_NOMNPROG" To VSDGNOMNPROG

    Label  @ 04,00 "Op‡”es Destinat rio" For "TG_OPDEST"
    Accept @ 05,01 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPDEST" To VSDGOPDEST
    Accept @ 05,06 Width 29 "A25"  Picture "!*!" Tag "TG_NOMOPDEST" To VSDGNOMOPDEST

    Label  @ 04,36 "Destinat rio"  For "TG_DESTINAT"
    Accept @ 05,37 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,45 Width 22 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST
 
    Label  @ 06,00 "Marca"  For "TG_MARCA"
    Accept @ 07,01 Width 07 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 07,09 Width 26 "A22" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 06,36 "Situa‡„o"  For "TG_SITUACAO"
    Accept @ 07,37 Width 14 "A11"  Picture "PROGRAMADA,EM PRODUCAO,SUSPENSA,FINALIZADA,TODOS" Tag "TG_SITUACAO"  To VSDGSITUACAO
    
    Label  @ 06,52 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 07,53 Width 14 "A10" Picture "#*#" Tag "TG_REFERENCIA"     To VSDGREFERENCIA  
    
    Label  @ 08,00 "Item"  For "TG_ITEM"
    Accept @ 09,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 09,15 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM"  To VSDGNOMITEM

    Label  @ 10,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 11,00 "de" For "TG_DTINI"
    Accept @ 11,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,17 "at‚" For "TG_DTFIM"
    Accept @ 11,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 12,00 "Op‡„o para Itens" For "TG_OPIT"
    Accept @ 13,01 Width 04 "A1"  Picture "T,P" Tag "TG_OPIT" To VSDGOPIT
    Accept @ 13,06 Width 29 "A25"  Picture "!*!" Tag "TG_DESCOPIT" To VSDGDESCOPIT

    Label  @ 14,00 "Modelos de Relat¢rio" For "TG_OPMODEL"
    Accept @ 15,01 Width 04 "A1"  Picture "1,2,3,4,5,6,7" Tag "TG_OPMODEL" To VSDGOPMODEL
    Accept @ 15,06 Width 29 "A25"  Picture "!*!" Tag "TG_NOMOPMODEL" To VSDGNOMOPMODEL

    Pushbutton @ 17,20 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 17,34 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If VSDGOPDT="D" And VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")

  Seleciona()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Delete "Answer"
          Delete Tabela
          Loop
  EndIf

  Switch
    Case VSDGOPMODEL="1": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100" "R" "Answer" "R"
    Case VSDGOPMODEL="2": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100" "1" "Answer" "R"
    Case VSDGOPMODEL="3": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100" "2" "Answer" "R"
  EndSwitch

  IMPRIREL("Answer","R")

  Delete Tabela
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
