;** VN_0507 ********************************************************************
;*  Grafico de Ped.Vendas por Condicao de Pagamento                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 14/06/2019 por Anivel Augusto Rodrigues
;Ultima Alteracao: 12/09/2019 por Anivel Augusto Rodrigues      
;Motivo Alteracao: Ajustes filewrite inicial
;Ultima Alteracao: 23/10/2019 por Anivel Augusto Rodrigues  
;Motivo Alteracao: Ajustes mensagem

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc VN_0507_SelecionaDados()
ClearAll

{Ask} TypeIn "\\Sistemas\\Vendas\\PedidoC" Enter
Moveto [Codigo da Empresa      ]       TypeIn "~VSDGEMPRESA.."
Moveto [Data de Emissao        ]       TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Descricao da Destinacao]       TypeIn "..VEND.. Or ..SAIDA.. Or ..SERV.."
Moveto [Situacao do Pedido     ]       TypeIn ".."
Moveto [Condicao de Pagamento  ] check
Moveto [Valor Nota Fiscal      ]       TypeIn "Calc Sum as Valor Total"
Do_It!
ClearAll
VN_0507_AdicionaDados()

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc VN_0507_AdicionaDados()
private regcondpgto
ClearAll

View "\\sistemas\\vendas\\condpgto"
View tabeladados
CoEdit "Answer"
Scan
   Moveto tabeladados
   Moveto [Condicao de Pagamento]
   Locate [Answer->Condicao de Pagamento]
   If Not RetVal
      Then End Down
           [Condicao de Pagamento  ]=[Answer->Condicao de Pagamento   ]
           [Extenso                ]="["+[Condicao de Pagamento   ]+"] "
           getrecord "\\sistemas\\vendas\\condpgto" [Answer->Condicao de Pagamento ] to regcondpgto
           if retval
              then [Extenso  ]=[Extenso  ]+regcondpgto["Descricao CondPagto"]
           endif   
   EndIf
   [Valor  ]=[Valor  ] +  [Answer->Valor Total]

   Moveto "Answer"
EndScan
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc VN_0507_GravaCsv()
private s, arquivo, arqnew, inicio, NR, vartemp

Aguarde("Aguarde, Exportando Ped.Vendas Condicao Pagamento")

ClearAll

arquivo=VSDGPASTA+"tmp0000.txt"
arqnew =VSDGPASTA+"VN_0507.csv"

Sort tabeladados on "Valor" D
ClearAll

NR=NRecords(tabeladados)
inicio=true

FileWrite        arquivo from "label,value\n"    

View tabeladados 
Scan
  Barra(NR, RecNo())
  AGUARDE(BARRA_STRING)

  s=  monta_string([Extenso ])+","
  s=s+strval([Valor         ])+"\n"

  FileWrite append arquivo from s    
  
EndScan
Do_It!
ClearAll

FileRead  arquivo to   vartemp
FileWrite arqnew  from vartemp    

LimpAguarde()

EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************

tabeladados=Cria_Temp(PrivDir())
cria_tabela(tabeladados,"Condicao de Pagamento(A2),Extenso(A25),Valor(N)")

VN_0507_SelecionaDados()
VN_0507_GravaCsv()

Delete tabeladados

ClearAll
Release Vars tabeladados
Release Procs VN_0507_SelecionaDados, VN_0507_AdicionaDados, VN_0507_GravaCsv
