;** Rm_0100 ********************************************************************
;*  Posi‡Æo das programacoes                                                   *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 28/03/2007 por Anivel Augusto Rodrigues
;Ultima Alteracao: 11/04/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Estamparia
;Ultima Alteracao: 24/03/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Bordado
;Ultima Alteracao: 11/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Lavanderia/Outros
;Ultima Alteracao: 25/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Todos itens ou apenas os pendentes
;Ultima Alteracao: 24/11/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Tg_NPROG, Ajuste de T¡tulo            
;Ultima Alteracao: 21/03/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes para empresa "0171"
;Ultima Alteracao: 26/03/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo no Filtro
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW
;Ultima Alteracao: 15/06/2011 por Bruno Carvalho
;Motivo Alteracao: Inclusao TG_MARCA
;Ultima Alteracao: 09/08/2011 por Karina Andrade
;Motivo Alteracao: Ajustes para exibir por Marca
;Ultima Alteracao: 24/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Ask conform VSDGNPROG
;Ultima Alteracao: 11/10/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes no filtro "Op‡”es Destinat rio"
;Ultima Alteracao: 23/10/2013 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo do filtro "Destinat rio" 
;Ultima Alteracao: 21/01/2014 por Andrey Fillipe
;Motivo Alteracao: Inclusao TG_FAMI
;Ultima Alteracao: 27/10/2014 por Andrey Fillipe
;Motivo Alteracao: Ajustes Opcoes Destinatario deixar passar com "TODOS"
;Ultima Alteracao: 17/11/2014 por Luis Gustavo
;Motivo Alteracao: Implementado CheckBox. "Apenas Produ‡äes do Per¡odo"
;Ultima Alteracao: 11/12/2014 por Luis Gustavo
;Motivo Alteracao: Retirado implementa‡Æo CheckBox. "Apenas Produ‡äes do Per¡odo"
;Ultima Alteracao: 16/12/2014 por Luis Gustavo
;Motivo Alteracao: Implementado para pegar toda a produ‡Æo da confec‡Æo, assim como a programa‡Æo da confec‡Æo
;Ultima Alteracao: 24/02/2015 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Novo ShowDialog/Ask/Report
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog 
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                  
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA
;Ultima Alteracao: 20/02/2017 por Rafael Matos
;Motivo Alteracao: Incluso colunas PERDA, LD e RECICLAGEM
;Ultima Alteracao: 02/05/2017 por Bruno Carvalho 
;Motivo Alteracao: Adicionado [Destino_Producao] ao fazer o link p/ verificar as produ‡äes. Usu rio altera o destino da programa‡Æo,  
;                  e ao linkar, isto era desprezado totalizando uma numero de produ‡Æo de dois ou mais destinos desta mesmo programa‡Æo  
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 28/06/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes data produ‡Æo nÆo usar          
;Ultima Alteracao: 28/06/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes opcao de datas                  
;Ultima Alteracao: 03/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtros                         
;Ultima Alteracao: 06/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes data entrega e previsao         
;Ultima Alteracao: 10/08/2018 por Bruno Carvalho
;Motivo Alteracao: Ajustes o nome do campo -> [Data Fim_Processo] p/ [Data_Fim_Processo]
;Ultima Alteracao: 15/08/2018 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes nova logica,filtro, report
;Ultima Alteracao: 18/09/2018 por Bruno Carvalho 
;Motivo Alteracao: Ajustes nos modelos  "02B", "03B" e "04B" p/ fazer uma ASK da MARCA antes de utilizar o PegaCodigoRaiz()
;Ultima Alteracao: 21/09/2018 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes ask numero_Corte              
;Ultima Alteracao: 21/11/2018 por Bruno Carvalho 
;Motivo Alteracao: Ajustes ao realizar uma ASK com a tabela itens e outra tabela, sendo que p/ itens, foi realizado uma ASK separadamente 
;Ultima Alteracao: 25/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

Tabela2=Cria_Temp(PrivDir())

;-- Filtro programa‡Æo -------------------------------------------------------
Switch
  Case VSDGNPRODCORTE<>"": 
       {Ask} {Pfacri}
       Moveto [Numero_Programacao      ] Check 
       Moveto [Numero_Producao_Corte   ] TypeIn "~VSDGNPRODCORTE"
       Do_It!
       ClearAll

  Case VSDGNPROG<>"": 
       {Ask} {Pfacc}
       Moveto [Numero_Programacao      ] Check TypeIn "~VSDGNPROG.."
       Do_It!
       ClearAll

  Case VSDGCORTE<>"": 
       {Ask} {Pfacc}
       Moveto [Numero_Programacao      ] Check
       Moveto [Numero_Corte            ] TypeIn "~VSDGCORTE"
       Do_It!
       ClearAll

  OtherWise: 
       {Ask} {Pfacc}  
       Moveto [Numero_Programacao      ] Check
       Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA.."

       if VSDGOPDTPPE="1" Then Moveto [Data_Programacao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" endif
       If VSDGOPDTPPE="2" Then Moveto [Data PrevisaoEntrega] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" endif
       if VSDGOPDTPPE="3" Then Moveto [Data_Fim_Processo   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" endif

       If VSDGOPDEST<>"TODOS" 
         Then Moveto [Destino_Producao      ]
              If VSDGOPDEST="INTERNO + FACCAO"
                 Then TypeIn "INTERNO Or FACCAO"
                 Else TypeIn "~VSDGOPDEST" 
              EndIf
       EndIf
       Moveto [Codigo                  ] TypeIn "~VSDGDESTINAT.."
       If VSDGSITUACAO<>"TODOS" And VSDGSITUACAO<>""
         Then Moveto [Situacao_Programacao] TypeIn "~VSDGSITUACAO"    
       EndIf
       Do_It!
       ClearAll

EndSwitch
Copy "Answer" Tabela2
ClearAll

;-- Filtro Produ‡Æo ----------------------------------------------------------
Switch
  Case VSDGCORTE<>"": 
       {Ask} {Rfacc}
       Moveto [Numero_Programacao      ] Check
       Moveto [Numero_Corte            ] TypeIn "~VSDGCORTE"
       Do_It!
       ClearAll

EndSwitch
Subtract "Answer" Tabela2
Add "Answer" Tabela2

Adiciona_Indice(Tabela2,"Numero_Programacao")

ClearAll


;-- Programacao ----------------------------------------------------------------
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ]       TypeIn "_citem"
Moveto [Referencia            ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ]       TypeIn "~VSDGMARCA.."
{Ask} TypeIn Tabela2 Enter
Moveto [Numero_Programacao    ]      Example "num"
{Ask} {PfacRI}
Moveto [Numero_Programacao    ] Check Example "num" 
Moveto [Codigo do Item        ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade Programada ]       TypeIn "Calc Sum as \"Quantidade Programada\""
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

Adiciona_Campo(Tabela,"Quantidade Produzida(N),Quantidade Perda(N),Quantidade LD(N),Quantidade Reciclagem(N)")

{Ask} TypeIn Tabela Enter
Moveto [Numero_Programacao     ] Check
Do_it!
ClearAll

TabelaRP=Adiciona_Indice_Temp("Numero_Programacao")

Delete Tabela2

;-- Producao -------------------------------------------------------------------
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ]       TypeIn "_citem"
Moveto [Referencia            ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ]       TypeIn "~VSDGMARCA.."
{Ask} TypeIn TabelaRP Enter
Moveto [Numero_Programacao    ]       Example "num"
{Ask} {Pfacc}
Moveto [Numero_Programacao    ]       Example "num"
{Ask} {Rfacc}
Moveto [Numero_Producao       ] Example "numprod"
Moveto [Numero_Programacao    ] Check Example "num"
{Ask} {RfacRI}
Moveto [Numero_Producao       ] Example "numprod"
Moveto [Codigo do Item        ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero_Programacao      ] Example "num"
Moveto [Codigo do Item          ] Example "item"
Moveto [Quantidade Produzida    ] Example "qtde"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero_Programacao      ] Example "num"
Moveto [Codigo do Item          ] Example "item"
Moveto [Quantidade Produzida    ] Example "qtde"
Do_It! 
ClearAll

;-- Problemas ------------------------------------------------------------------
{Ask} TypeIn TabelaRP Enter
Moveto [Numero_Programacao  ] Example "num"
{Ask} {Rfacc}
Moveto [Numero_Producao     ] Example "nprod"
Moveto [Numero_Programacao  ] Check Example "num"
{Ask} {Cprobc}
Moveto [Numero do Lancamento] Check
Moveto [Numero_ProducaoIE   ] Example "nprod"
Do_It!
ClearAll

Adiciona_Indice("Answer","Numero do Lancamento")

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ]       TypeIn "_citem"
Moveto [Referencia            ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ]       TypeIn "~VSDGMARCA.."
{Ask} {Answer}
Moveto [Numero do Lancamento  ] Example "nlanc"
Moveto [Numero_Programacao    ] Check
{Ask} {Cprobi}
Moveto [Numero do Lancamento  ] Example "nlanc"
Moveto [Codigo do Item        ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade            ] TypeIn "Calc Sum as Quantidade" 
Moveto [Tipo_Ocorrencia       ] Check
Do_It!
ClearAll

For i from 1 to 3
  {Ask} {Answer}
  Moveto [Numero_Programacao     ] Example "num"
  Moveto [Codigo do Item         ] Example "coditem"
  Moveto [Quantidade             ] Example "qtde"
  Moveto [Tipo_Ocorrencia        ] 
  Switch
      Case i=1  :  []="LD"
      Case i=2  :  []="PERDA"
      Otherwise :  []="RECICLAGEM"
  EndSwitch
  
  {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
  Moveto [Numero_Programacao     ] Example "num"
  Moveto [Codigo do Item         ] Example "coditem"
  Switch
      Case i=1  :  Moveto [Quantidade LD        ] Example "qtde"
      Case i=2  :  Moveto [Quantidade Perda     ] Example "qtde"
      OtherWise :  Moveto [Quantidade Reciclagem] Example "qtde"
  EndSwitch 
  Do_It!
  ClearAll
EndFor

Delete TabelaRP

;-- Totalizando ----------------------------------------------------------------
AGUARDE("Aguarde, Totalizando dados")

Switch
  Case VSDGCODMODELO="02B" or VSDGCODMODELO="03B" or VSDGCODMODELO="04B":

    LimpaRodape(0)

    NR=NRecords(Tabela)

    {Ask} TypeIn Tabela Enter Check
    Moveto [Codigo do Item         ]       TypeIn "_citem!"
    {Ask} {\\Sistemas\\Estoque\\Itens}
    Moveto [Codigo do Item         ]       TypeIn "_citem!"
    Moveto [Codigo da Marca        ] Check
    Moveto [Descricao da Marca     ] Check
    Do_it!
    ClearAll
    Rename "Answer" Tabela
    
    View NoWindow Tabela
    EditKey
    Scan  
      Barra(NR, RecNo())
      Aguarde("Aguarde, agrupando itens "+BARRA_STRING)
      
      [Codigo do Item]=PegaCodigoRaiz([Codigo do Item])
    EndScan
    Do_It!
    ClearAll
    
    LimpaRodape(0)

endSwitch

Switch
  Case VSDGCODMODELO="01":
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Programacao    ] Check
    Moveto [Codigo do Item        ] Check
    Moveto [Quantidade Programada ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Moveto [Quantidade LD         ]       TypeIn "Calc Sum as \"Quantidade LD\""
    Moveto [Quantidade Reciclagem ]       TypeIn "Calc Sum as \"Quantidade Reciclagem\""
    Do_It!
    ClearAll

    AGUARDE("Aguarde, Ajustando dados")
    
    {Ask} {Pfacc}
    Moveto [Numero_Programacao    ] Example "num"
    Moveto [Numero_Corte          ] Check
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Data_Programacao      ] Check
    Moveto [Destino_Producao      ] Check
    Moveto [Codigo                ] Check
    Moveto [Nome Fantasia EmitDest] Check
    Moveto [Situacao_Programacao  ] Check
    Moveto [Data_Fim_Processo     ] Check typeIn "As \"Data Entrega\""
    Moveto [Data PrevisaoEntrega  ] Check
    Moveto [Observacoes           ] Check
    {Ask} {Answer} Check
    Moveto [Numero_Programacao    ] Example "num"
    Do_It!
    ClearAll
    

  Case VSDGCODMODELO="02" or VSDGCODMODELO="02B" :
    {Ask} {Pfacc}
    Moveto [Numero_Programacao    ] Example "num"
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Destino_Producao      ] Check
    Moveto [Codigo                ] Check
    Moveto [Nome Fantasia EmitDest] Check
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Programacao    ] Example "num"
    Moveto [Codigo do Item        ] Check
    If VSDGCODMODELO="02B" 
       Then Moveto [Codigo da Marca   ] Check
            Moveto [Descricao da Marca] Check
    EndIf        
    Moveto [Quantidade Programada ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Moveto [Quantidade LD         ]       TypeIn "Calc Sum as \"Quantidade LD\""
    Moveto [Quantidade Reciclagem ]       TypeIn "Calc Sum as \"Quantidade Reciclagem\""
    Do_It!
    ClearAll

  Case VSDGCODMODELO="03" or VSDGCODMODELO="03B" or
       VSDGCODMODELO="04" or VSDGCODMODELO="04B" :
    {Ask} {Pfacc}
    Moveto [Numero_Programacao    ] Example "num"
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Destino_Producao      ] Check
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Programacao    ] Example "num"
    Moveto [Codigo do Item        ] Check
    If VSDGCODMODELO="03B" or VSDGCODMODELO="04B"
       Then Moveto [Codigo da Marca   ] Check
            Moveto [Descricao da Marca] Check
    EndIf        
    Moveto [Quantidade Programada ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Moveto [Quantidade LD         ]       TypeIn "Calc Sum as \"Quantidade LD\""
    Moveto [Quantidade Reciclagem ]       TypeIn "Calc Sum as \"Quantidade Reciclagem\""
    Do_It!
    ClearAll

EndSwitch

Delete Tabela

Tabela=Cria_Temp(PrivDir())
Copy "Answer" Tabela 

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Check
Moveto [Referencia             ] Check
Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Tipo do Item           ] Check
Moveto [Codigo da Cor_Tecido   ] Check
Moveto [Descricao da Cor_Tecido] Check
If VSDGCODMODELO<>"02B" And VSDGCODMODELO<>"03B" And VSDGCODMODELO<>"04B"
   Then Moveto [Codigo da Marca   ] Check
        Moveto [Descricao da Marca] Check
EndIf        
Moveto [Codigo da Familia      ] Check
Moveto [Descricao da Familia   ] Check
Do_It!
ClearAll

Adiciona_Indice("Answer","Codigo do Item")

{Ask} {Answer}
Moveto [Codigo do Item         ]       TypeIn "_citem"
Moveto [Referencia             ] Check
Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Tipo do Item           ] Check
Moveto [Codigo da Cor_Tecido   ] Check
Moveto [Descricao da Cor_Tecido] Check
If VSDGCODMODELO<>"02B" And VSDGCODMODELO<>"03B" And VSDGCODMODELO<>"04B"
   Then Moveto [Codigo da Marca        ] Check
        Moveto [Descricao da Marca     ] Check
EndIf        
Moveto [Codigo da Familia      ] Check
Moveto [Descricao da Familia   ] Check
{Ask} TypeIn Tabela Enter Check
Moveto [Codigo do Item         ]       TypeIn "_citem!"
Do_It!
ClearAll

Delete Tabela     
Adiciona_Campo("Answer","Saldo(N),%Concluido(N),Alerta(A20)")

;-- Calculos -------------------------------------------------------------------

AGUARDE("Aguarde, Processando Saldo")

If VSDGOPIT="P"
   Then 
        {Ask} {Answer} TypeIn "Fast Delete"
        Moveto [Quantidade Programada] Example "qtd"
        Moveto [Quantidade Produzida ] TypeIn ">=" Example "qtd"
        Do_It!
        ClearAll
EndIf

If VSDGOPIT="D"
   Then 
        {Ask} {Answer} TypeIn "Fast Delete"
        Moveto [Quantidade Programada] Example "qtd"
        Moveto [Quantidade Produzida ] TypeIn "= " Example "qtd"
        Do_It!
        ClearAll
EndIf


{Ask} {Answer} typein "Fast"
Moveto [Quantidade Programada] TypeIn "_qprog"
Moveto [Quantidade Produzida ] TypeIn "_qprod"
Moveto [Quantidade Perda     ] TypeIn "_qperd"
Moveto [Quantidade LD        ] TypeIn "_qld"
Moveto [Saldo                ] TypeIn "changeto (_qprog - (_qprod + _qperd + _qld ))"
Do_It!
ClearAll

{Ask} {Answer} typein "Fast"
Moveto [Quantidade Programada] TypeIn "_qprog"
Moveto [Quantidade Produzida ] TypeIn ">_qprog"
Moveto [Alerta               ] TypeIn "changeto \"<-** ATENCAO **\""
Do_It!
ClearAll

{Ask} {Answer} typein "Fast"
Moveto [Quantidade Programada] TypeIn "_qprog"
Moveto [Quantidade Produzida ] TypeIn "_qprod"
Moveto [Quantidade Perda     ] TypeIn "_qperd"
Moveto [Quantidade LD        ] TypeIn "_qld"
Moveto [%Concluido           ] TypeIn "changeto ( (_qprod - ( _qperd + _qld ) ) / _qprog) * 100"
Do_It!
ClearAll

MudaEstruturaDaTabelaPara("Answer","\\Base\\Sistemas\\Faccao\\Rm_0100B")

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp      = True
TECLA     = ""
MSG_CAMPO = ""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
          If Campo="TG_OPDEST"
             Then Seleciona_Opcoes("Op‡”es de Desinat rio","7,7")
          EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"    : Campo="NO"
            Case Campo="TG_CORTE"      : Campo="TG_EMPRESA"
            Case Campo="TG_NPRODCORTE" : Campo="TG_CORTE"
            Case Campo="TG_NPROG"      : Campo="TG_NPRODCORTE" 
            Case Campo="TG_SITUACAO"   : Campo="TG_NPROG"
            Case Campo="TG_OPDEST"     : Campo="TG_SITUACAO"
            Case Campo="TG_DESTINAT"   : Campo="TG_OPDEST"
            Case Campo="TG_FAMI"       : Campo="TG_EMPRESA"
            Case Campo="TG_MARCA"      : Campo="TG_FAMI"
            Case Campo="TG_ITEM"       : Campo="TG_MARCA"
            Case Campo="TG_REFERENCIA" : Campo="TG_ITEM"
            Case Campo="TG_OPDTPPE"    : Campo="TG_REFERENCIA"
            Case Campo="TG_DTINI"      : Campo="TG_OPDTPPE"
            Case Campo="TG_DTFIM"      : Campo="TG_DTINI"
            Case Campo="TG_OPIT"       : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"  : Campo="TG_OPIT"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"      : Campo="TG_CORTE"
                    Case Campo="TG_CORTE"        : 
                         VSDGCORTE = ControlValue("TG_CORTE")
                         If Not ISBlank(VSDGCORTE)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_DESTINAT"      
                            Else Campo="TG_NPRODCORTE"    
                         EndIf
                    Case Campo="TG_NPRODCORTE"   :   
                         If Not ISBlank(VSDGNPRODCORTE)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_FAMI"      
                            Else Campo="TG_NPROG"    
                         EndIf
                    Case Campo="TG_NPROG"        :
                         If Not ISBlank(VSDGNPROG)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_FAMI"      
                            Else Campo="TG_SITUACAO"    
                         EndIf
                    Case Campo="TG_SITUACAO"    :
                         VSDGSITUACAO=ControlValue("TG_SITUACAO")
                         If IsBlank(VSDGSITUACAO)
                            Then VSDGSITUACAO="TODOS"
                         EndIf
                         Campo="TG_OPDEST"
                    Case Campo="TG_OPDEST"     : 
                         VSDGOPDEST=ControlValue("TG_OPDEST")
                         If IsBlank(VSDGOPDEST) Then VSDGOPDEST="TODOS" EndIf
                         If Not Checa_Opcoes("Op‡”es de Desinat rio",VSDGOPDEST) And VSDGOPDEST<>"TODOS"
                           Then Mensagem("Destino inv lido !")
                                Campo="TG_OPDEST"
                           Else Campo="TG_DESTINAT"
                        EndIf
                    Case Campo="TG_DESTINAT"    : Campo="TG_FAMI" 
                    Case Campo="TG_FAMI"        : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"        : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA"  : Campo="TG_OPDTPPE"
                    Case Campo="TG_OPDTPPE"     : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_OPIT"
                    Case Campo="TG_OPIT"        : Campo="TG_CODMODELO"
                         VSDGOPIT=ControlValue("TG_OPIT")
                         Switch
                           Case VSDGOPIT="P": VSDGDESCOPIT="PENDENTES"
                           Case VSDGOPIT="D": VSDGDESCOPIT="COM DIFEREN€A"
                           OtherWise        : VSDGOPIT    ="T"
                                              VSDGDESCOPIT="TODOS"
                         EndSwitch
                    Case Campo="TG_CODMODELO"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_OPDEST":
     TECLA="F1=Op‡”es  "  
     MSG_CAMPO="Em Branco=Todos, [F1]Consultar tabela"
  Case Campo="TG_OPIT":
     MSG_CAMPO="Op‡„o: T=Todos  P=Pendentes  D=Com Diferen‡a"
  Case Campo="TG_SITUACAO":
     MSG_CAMPO="P=PROGRAMADA  E=EM PRODUCAO  S=SUSPENSA  F=FINALIZADA  Branco=Todos"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

Proc LimpaCamposTag(Tipo)

Switch
    Case Tipo="Todos":
    VSDGEMPRESA    = ""
    VSDGNOMEMP     = ""     
    VSDGCORTE      = ""
    VSDGNPRODCORTE = ""
    VSDGNPROG      = ""
    VSDGSITUACAO   = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""
    VSDGOPDTPPE    = ""    
    VSDGDTINI      = BlankDate()
    VSDGDTFIM      = BlankDate()
    VSDGFAMI       = ""
    VSDGNOMFAMI    = ""
    VSDGMARCA      = ""
    VSDGNOMMARCA   = ""
    VSDGREFERENCIA = ""
    VSDGOPIT       = "T"
  Case Tipo="TG_CORTE":
    VSDGNPRODCORTE = ""
    VSDGNPROG      = ""
    VSDGNOMNPROG   = ""
    VSDGSITUACAO   = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
  Case Tipo="TG_NPROG":
    VSDGCORTE      = ""
    VSDGNPRODCORTE = ""
    VSDGSITUACAO   = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
  Case Tipo="TG_NPRODCORTE":
    VSDGCORTE      = ""
    VSDGNPROG      = ""
    VSDGNOMNPROG   = ""
    VSDGSITUACAO   = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
EndSwitch

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Anal¡tico por Programa‡Æo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Sint‚tico por Destino/Destinat rio/Marca")
ModeloRelatoriosAdd("02B Sint‚tico por Destino/Destinat rio/Marca/Referˆncia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("03  Sint‚tico por Destino/Familia/Marca")
ModeloRelatoriosAdd("03B Sint‚tico por Destino/Familia/Marca/Referˆncia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("04  Sint‚tico por Destino/Marca/Familia")
ModeloRelatoriosAdd("04B Sint‚tico por Destino/Marca/Familia/Referˆncia")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

sys_valor()

LimpaCamposTag("Todos")

Coedit "P_DESTI"
Monta_Opcoes("Op‡”es de Desinat rio","INTERNO + FACCAO") 
Do_It!
ClearAll   

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Posi‡Æo da Programa‡Æo - Interna/Externa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 01,00   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Corte"  For "TG_CORTE"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_CORTE" To VSDGCORTE
    Accept @ 03,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMCORTE" To VSDGNOMCORTE

    Label  @ 04,00 "Corte/Produ‡Æo"  For "TG_NPRODCORTE"
    Accept @ 05,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_NPRODCORTE" To VSDGNPRODCORTE
    Accept @ 05,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMNPRODCORTE" To VSDGNOMNPRODCORTE

    Label  @ 06,00 "Prog.Interno/Externo"  For "TG_NPROG"
    Accept @ 07,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_NPROG"    To VSDGNPROG
    Accept @ 07,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMNPROG" To VSDGNOMNPROG

    Label  @ 08,00 "Situa‡„o"  For "TG_SITUACAO"
    Accept @ 09,01 Width 33 "A11"  Picture "PROGRAMADA,EM PRODUCAO,SUSPENSA,FINALIZADA,TODOS" Tag "TG_SITUACAO"  To VSDGSITUACAO

    Label  @ 10,00 "Op‡”es Destinat rio" For "TG_OPDEST"
    Accept @ 11,01 Width 33 "A31"  Picture "!*!" Tag "TG_OPDEST" To VSDGOPDEST

    Label  @ 12,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 13,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 13,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 00,35 "Familia"  For "TG_FAMI"
    Accept @ 01,37 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI" To VSDGFAMI
    Accept @ 01,44 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI
 
    Label  @ 02,35 "Marca"  For "TG_MARCA"
    Accept @ 03,37 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 03,44 Width 25 "A22" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 04,36 "Item"  For "TG_ITEM"
    Accept @ 05,36 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 06,36 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 04,48 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 05,48 Width 21 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 08,36 "Op‡äes de Datas" For "TG_OPDTPPE"
    Accept @ 09,39 Width 04 "A1"  Picture "1,2,3,4,5"  Tag "TG_OPDTPPE"  To VSDGOPDTPPE
    Accept @ 09,44 Width 25 "A20" Picture "!*!"      Tag "TG_NOMOPDTPPE" To VSDGNOMOPDTPPE
 
    Label  @ 10,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 11,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,51 "at‚" For "TG_DTFIM"
    Accept @ 11,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 12,36 "Op‡„o para Itens" For "TG_OPIT"
    Accept @ 13,39 Width 04 "A1"  Picture "T,P,D" Tag "TG_OPIT" To VSDGOPIT
    Accept @ 13,44 Width 25 "A22"  Picture "!*!" Tag "TG_DESCOPIT" To VSDGDESCOPIT

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  
  Seleciona()

  If Not IsEmpty(Tabela)
     Then
          Switch
            Case VSDGCODMODELO="01"    :   CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100B" "R" Tabela "R"

            Case VSDGCODMODELO="02" or  
                 VSDGCODMODELO="02B"   :
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100B" "1" Tabela "R"

            Case VSDGCODMODELO="03" or     
                 VSDGCODMODELO="03B"   :   
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100B" "2" Tabela "R"

            Case VSDGCODMODELO="04" or     
                 VSDGCODMODELO="04B"   :   
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100B" "3" Tabela "R"
          EndSwitch
          IMPRIREL(Tabela,"R")

     Else MENSAGEM("N„o existem registros a processar")
  EndIf

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All

