;** TransfCF  ******************************************************************
;*  Transferencia P/ Drives (ECF's)                                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/06/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 27/06/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo Arj para c:\Arj
;Ultima Alteracao: 05/09/2011 por Bruno Carvalho
;Motivo Alteracao: Ajuste "ExecVise.exe"
;Ultima Alteracao: 30/11/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo de "ExecVise -> Vexe","Arj -> Varj"
;Ultima Alteracao: 08/12/2011 por Karina Andrade
;Motivo Alteracao: Nova nomeclatura para pacote gerado
;Ultima Alteracao: 07/05/2012 por Bruno Carvalho
;Motivo Alteracao: Add Sleep na rotina onde ‚ processado o ARJ
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Substitui‡Æo Editor novo arquivo por FileWrite

;*******************************************************************************
;* ROTINA PROCESSA  -> realiza o processamento da Transferencia                *
;*******************************************************************************
Proc PROCESSA()

AGUARDE("Aguarde, Transferindo Cupons Fiscais")
ClearAll
Array Arquivo[3]
Arquivo[1]="NotaC"
Arquivo[2]="NotaI"
Arquivo[3]="NotaV"

Cont     = 1

SetDir "\\Sistemas\\Vendas"
For Cont From 1 To 3
    AGUARDE("Aguarde, Transferindo "+Arquivo[Cont]+" [ "+StrVal(Cont)+"/3 ]")
    If IsTable(Arquivo[Cont])
       Then If Arquivo[Cont]<>"NotaC"
               Then {Ask} {NotaC}
                    Moveto [Codigo da Empresa  ] Example "cemp" TypeIn ", ~VSDGEMPRESA.."
                    Moveto [Numero do Documento] Example "ndoc"
                    Moveto [Serie do Documento ] Example "sdoc"
                    Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                    Moveto [Tipo do Documento  ] TypeIn "CUP.."
                    {Ask} TypeIn Arquivo[Cont] Enter Check
                    Moveto [Codigo da Empresa  ] Example "cemp"
                    Moveto [Numero do Documento] Example "ndoc"
                    Moveto [Serie do Documento ] Example "sdoc"
               Else {Ask} {NotaC} Check
                    Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
                    Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                    Moveto [Tipo do Documento  ] TypeIn "CUP.."
            Endif
            Do_It!
            ClearAll

            If IsTable("C:\\"+Arquivo[Cont])
               Then Delete "C:\\"+Arquivo[Cont]
            Endif
            Create "C:\\"+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" "C:\\"+Arquivo[Cont]
            ClearAll

            If Arquivo[Cont]="NotaC" And Not IsEmpty("Answer")
               Then Gerou_Dados=True
            EndIf   
    EndIf
EndFor

AGUARDE("Aguarde, Transferindo Tipos de Documentos")
{Ask} {\\Sistemas\\Cadastro\\TpDoctos} Check
Moveto [Codigo do Documento] TypeIn "X.."
Do_It!
ClearAll
If IsTable("C:\\Tpdoctos")
   Then Delete "C:\\Tpdoctos"
Endif
Create "C:\\TpDoctos" Like "\\Sistemas\\Cadastro\\Tpdoctos"
Add "Answer" "C:\\TpDoctos"
ClearAll

AGUARDE("Aguarde, Transferindo Mapa Resumo")
ClearAll
Arquivo[1]="ECF_C"
Arquivo[2]="ECF_T"
Cont     = 1
For Cont From 1 To 2
    AGUARDE("Aguarde, Transferindo "+Arquivo[Cont]+" [ "+StrVal(Cont)+"/2 ]")
    If IsTable(Arquivo[Cont])
       Then {Ask} TypeIn Arquivo[Cont] Enter Check
            Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
            Moveto [Data               ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
            Do_It!
            ClearAll

            If IsTable("C:\\"+Arquivo[Cont])
               Then Delete "C:\\"+Arquivo[Cont]
            Endif
            Create "C:\\"+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" "C:\\"+Arquivo[Cont]
            ClearAll

            If Cont=1 And Not IsEmpty("Answer")
               Then Gerou_Dados=True
            EndIf   
    EndIf
EndFor


;****************** Posto **************************
AGUARDE("Aguarde, Transferindo Placas de Veiculos")
If DirExists("\\Sistemas\\Posto\\")>0
   Then 
        If IsTable("\\Sistemas\\Posto\\Abast_C")
           Then If IsTable("C:\\Abast_C")
                   Then Delete "C:\\Abast_C"
                Endif
                Create "C:\\Abast_C" Like "\\Sistemas\\Posto\\Abast_C"
                Add "\\Sistemas\\Posto\\Abast_C" "C:\\Abast_C"
                ClearAll
        EndIf        

        If IsTable("\\Sistemas\\Posto\\Abast_P")
           Then If IsTable("C:\\Abast_P")
                   Then Delete "C:\\Abast_P"
                Endif
                Create "C:\\Abast_P" Like "\\Sistemas\\Posto\\Abast_P"
                Add "\\Sistemas\\Posto\\Abast_P" "C:\\Abast_P"
                ClearAll
        EndIf        
EndIf        


ClearAll
Limpaguarde()
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTREF"         : Campo="TG_EMPRESA"
            Case Campo="TG_DTINI"         : Campo="TG_DTREF"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DRIVES"         : Campo="TG_DTFIM"
          ;;Case Campo="TG_FORMATA"       : Campo="TG_DRIVE"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_DTREF"
                    Case Campo="TG_DTREF"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="TG_DRIVES"
                    Case Campo="TG_DRIVES"   :
                         VSDGDRIVE=ControlValue("TG_DRIVES")
                         Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf

Switch
  Case Campo="TG_DTREF" :
       MSG_CAMPO="Informe a data da Transa‡„o"
  Case Campo="TG_DRIVES":
       MSG_CAMPO="Selecione o drive desejado !"
       TECLA=Chr(27)+""+Chr(26)+"=Selecionar  "
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

MSG="NÆo esque‡a de: // //"
MSG=MSG+" - Importar os dados da Redu‡ao 'Z' no ECF,//"
MSG=MSG+" - Emitir o Mapa Resumo no ECF.            // //"
MSG=MSG+"Isso se for necess rio para seu controle !"
Mensagem(MSG)

VSDGEMPRESA=""
VSDGDTREF  =BlankDate()
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()
VSDGFORMATA=True

DynArray Array_Drives[]
SysInfo Drives To Array_Drives
If IsFile("OEXPECF.sc")
    Then Play "OEXPECF"
    Else ;VSDGDRIVE=SubStr(Directory(),1,2)
         VSDGDRIVE="C:" 
EndIf

While True
  ShowDialog "Exporta‡„o Cupom Fiscal" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  

   @ 05,12   Height 11 Width 47

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 1,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Data Transa‡„o" For "TG_DTREF"
    Accept @ 03,01 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Label  @ 04,00 "Periodo Referente" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "ate" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,37 "Drives:" For "TG_DRIVES"
    PickDynArrayIndex @ 01,38 Height 5 width 05
     Columns 1
      Array_Drives
       Tag "TG_DRIVES"
        To VSDGDRIVE

    Pushbutton @ 07,10 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,22 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGEMPRESA) Or
     IsBlank(VSDGDTREF)
     Then Mensagem("Informe os dados corretamente !")
          Loop
  EndIf

  DATAREF=AlinhM(StrVal(Day(VSDGDTREF)),2)+AlinhM(StrVal(Month(VSDGDTREF)),2)+SubStr(AlinhM(StrVal(Year(VSDGDTREF)),4),3,2)

  ARQ   =VSDGDRIVE+"\\XX"+DATAREF+".ARJ"
  ARQNEW=VSDGDRIVE+"\\PT_ECF"+"_"+VSDGEMPRESA+"_"+
         AlinhM(StrVal(Year(VSDGDTREF)),4) +
         AlinhM(StrVal(Month(VSDGDTREF)),2)+
         AlinhM(StrVal(Day(VSDGDTREF)),2)  +
         ".ARJ"
  
  Deleta_Arquivo("C:\\NOTA*.DB")
  Deleta_Arquivo("C:\\NOTA*.PX")
  Deleta_Arquivo("C:\\NOTA*.MB")
  Deleta_Arquivo("C:\\ECF_C.*")
  Deleta_Arquivo("C:\\ECF_T.*")
  Deleta_Arquivo("C:\\TPDOCTOS.*")
  Deleta_Arquivo("C:\\ABAST_*.*")
  Deleta_Arquivo(ARQ)
  Sleep(1000)
  ExecVise("REN "+ARQNEW+" \""+ARQ+"\"")
  Sleep(1000)
  Deleta_Arquivo(ARQ)
  Sleep(1000)

  Gerou_Dados=False
  Processa()

  Sleep(1000)

  If Not Gerou_Dados
     Then Mensagem("NÆo existe(m) cupom(s) conforme sele‡Æo !// //Verificar Empresa, Data Referente !"+
                   "//Pacote nÆo foi gerado !")
     Else Aguarde("Aguarde, Compactando pacote de transa‡„o p/ "+ARQNEW)
          Executa_Programa("c:\\vise\\Varj.exe a "+ARQ+" C:\\NOTA*.* C:\\ECF_*.* C:\\TPDOCTOS.* C:\\ABAST_*.*")
          Sleep 1000
          
          ExecVise("REN "+ARQ+" \""+ARQNEW+"\"")
          Sleep 1000
          
          Deleta_Arquivo("C:\\NOTA*.DB")
          Deleta_Arquivo("C:\\NOTA*.PX")
          Deleta_Arquivo("C:\\NOTA*.MB")
          Deleta_Arquivo("C:\\ECF_C.*")
          Deleta_Arquivo("C:\\ECF_T.*")
          Deleta_Arquivo("C:\\TPDOCTOS.*")
          Deleta_Arquivo("C:\\ABAST_*.*")
          Sleep 1000
          
          MSG="Pacote de transa‡„o gerado !// //"
          MSG=MSG+"Arquivo em "+ARQNEW+"// //"
          MSG=MSG+"Verifique !"
          Mensagem(MSG)
  EndIf

  FileWrite        "OEXPECF.sc" From ";****** Variaveis de Configura‡„o Drive Padrao Vise Informatica"+"\n"
  FileWrite Append "OEXPECF.sc" From "VSDGDRIVE="+CHR(34)+VSDGDRIVE+Chr(34)+"\n"

EndWhile
ClearAll
Release Vars All
Release Procs All
