;** Et_0102 ********************************************************************************
;* Monta Etiqueta p/ Impressora Jato de Tinha - Folha A4 -> NÆo utiliza  papel de Etiqueta *
;*******************************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 12/07/2016 por Bruno Carvalho
;Ultima Alteracao: 21/07/2016 por Bruno Carvalho 
;Motivo Alteracao: Ajustes conforme solicita‡Æo do cliente #0102# 
;Ultima Alteracao: 21/09/2016 por Kamila Gomes 
;Motivo Alteracao: Ajustes tamanho do alinhamento do ITEM[CONTADOR] de 3 para 4
;Ultima Alteracao: 15/08/2017 por Bruno Carvalho 
;Motivo Alteracao: Ajustes 

;*******************************************************************************************
;* Rotina para Impressao da Etiqueta                                                       *
;*******************************************************************************************
Proc IMPETIQUETA()

QUANTIDADE = 0
QTD        = 0
CONTADOR   = 0

DynArray ITEM[]

Print File ARQIMP CI_10CPP
;Print File ARQIMP "\n\n\n"
Print File ARQIMP "\014" 
Print File ARQIMP "\027E"    

View "Answer"
Home
Scan
  CONTADOR = CONTADOR + 1
  QUANTIDADE=QUANTIDADE+[Quantidade]
  ITEM[CONTADOR] = AlinhM(Strval(CONTADOR),4)+Format("W30",[Descricao do Item])+
                   Format("W10",[Codigo do Item])+Format("W20",[Descricao da Marca])+
                   Format("W15",[Localizacao])+Format("W10",[Peso Liquido])
EndScan

COLUNA = 38
QTD = Int(QUANTIDADE/2)
If (QUANTIDADE-(QTD*2))>0
   Then QTD=QTD+1
EndIf 

CONT_QUEBRA = 0
For Cont From 1 To DynArraySize(ITEM)
   Print File ARQIMP "\n"
   ITEM_DESC  = Ltrim(Rtrim(SubStr(ITEM[Cont],05,30)))
   ITEM_COD   = Ltrim(Rtrim(SubStr(ITEM[Cont],35,10)))
   ITEM_MARCA = Ltrim(Rtrim(SubStr(ITEM[Cont],45,20)))
   ITEM_LOCAL = Ltrim(Rtrim(SubStr(ITEM[Cont],65,15)))
   ITEM_PR    = Rtrim(Ltrim(SubStr(ITEM[Cont],80,10)))

   CONT_QUEBRA = CONT_QUEBRA + 1
   If IsAssigned(ITEM[Cont+1])
      Then ITEM_DESC2  = Ltrim(Rtrim(SubStr(ITEM[Cont+1],05,30)))
           ITEM_COD2   = Ltrim(Rtrim(SubStr(ITEM[Cont+1],35,10)))
           ITEM_MARCA2 = Ltrim(Rtrim(SubStr(ITEM[Cont+1],45,20)))
           ITEM_LOCAL2 = Ltrim(Rtrim(SubStr(ITEM[Cont+1],65,15)))
           ITEM_PR2    = Rtrim(Ltrim(SubStr(ITEM[Cont+1],80,10))) 
           Print File ARQIMP Spaces(2)+Completa(Format("W30",ITEM_DESC),COLUNA," ")+Spaces(2)+Completa(Format("W30",ITEM_DESC2),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Completa("Codigo: "+Format("W10",ITEM_COD),COLUNA," ")+Spaces(2)+Completa("Codigo: "+Format("W10",ITEM_COD2),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Completa(" Marca: "+Format("W20",ITEM_MARCA),COLUNA," ")+Spaces(2)+Completa(" Marca: "+Format("W20",ITEM_MARCA2),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Completa(" Local: "+Format("W15",ITEM_LOCAL)+"  PR: "+Format("W10,AL",ITEM_PR),COLUNA," ")+Spaces(2)+
                             Completa(" Local: "+Format("W15",ITEM_LOCAL2)+"  PR: "+Format("W10,AL",ITEM_PR2),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Fill("-",COLUNA)+Spaces(2)+Fill("-",COLUNA)
           Cont=Cont+1
           CONT_QUEBRA = CONT_QUEBRA + 1                  
      Else Print File ARQIMP Spaces(2)+Completa(Format("W30",ITEM_DESC),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Completa("Codigo: "+Format("W10",ITEM_COD),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Completa(" Marca: "+Format("W20",ITEM_MARCA),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Completa(" Local: "+Format("W10",ITEM_LOCAL)+"  PR: "+Format("W10,AL",ITEM_PR),COLUNA," ")+"\n"
           Print File ARQIMP Spaces(2)+Fill("-",COLUNA)
   EndIf        
   
   If CONT_QUEBRA >= 26
      Then Print File ARQIMP "\f"
           CONT_QUEBRA = 0
   EndIf   
EndFor

EndProc ;(IMPETIQUETA)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
ARQIMP=PrivDir()+"ET_0102.Txt"
If IsFile(ARQIMP)
   Then Deleta_Arquivo(ARQIMP)
EndIf
AGUARDE("Imprimindo Etiqueta ...")

IMPETIQUETA()

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)

Release Vars VALOR
Release Procs IMPETIQUETA

LIMPAGUARDE()
