;** PS_FPG *********************************************************************
;*  PlugSales - formas de pagamento                                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 21/05/2019 por Bruno Carvalho               
;Ultima Alteracao: 10/07/2019 por Anivel Augusto Rodrigues    
;Motivo Alteracao: Novo layout

;*******************************************************************************
;* Rotina para Localizar Registro                                              *
;*******************************************************************************
Proc CHAVE()

While True
  SetaCorRegistro("Editar")
  Moveto [FPG_ID]
  End
  SEQ = [FPG_ID]
  Down

  While True
    TECLA=""
    AguardaTeclasPadrao()
  
    Switch
    Case RetVal=-33 : SemFuncoes()
    Case RetVal="F3": SemFicha()
    Case RetVal=-94 : MsgTeclasPadrao()
    Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
         While True
           PAGINA("PS_FPG","MR")
           If EDITAR="S"
              Then CHAVE=0
                   FPG_ID=[FPG_ID]
                   Controla_EdicaoC()
              Else If EXCLUIR="S"
                      Then If QuerExcluir("")
                              Then Grava_LogEx("PS_FPG")
                                   Del
                              Else UnLockRecord
                                   Return False
                           EndIf
                      Else QuitLoop
                   EndIf
           EndIf
           SetaPosForm()
         EndWhile
         QuitLoop
    Case RetVal="ESC":
         CHAVE=9
         Del
         Return         
    Case RetVal="ENTER":
         If Not Seta_Sequencia(SEQ,True)
            Then Del
                 QuitLoop
         EndIf
         FPG_ID=[]
         Del
         Moveto [FPG_ID]
         Locate FPG_ID
         If RetVal
            Then CHAVE=0
            Else CHAVE=1
                 End Down
                 [FPG_ID]=FPG_ID
         EndIf
         If IsLockRecord()
            Then If CHAVE=1 Then Del EndIf
                 QuitLoop
         EndIf
         Return  
    EndSwitch
  EndWhile
EndWhile

EndProc ;CHAVE()

;*******************************************************************************
;* Rotina para digitacao das informacoes                                       *
;*******************************************************************************
Proc DIGITA()

if CHAVE=1
  then moveto [Tipo do Pagamento]
  else moveto [FPG_NOME         ]
endif
While True
      TECLA=" Esc=Retornar  "
      If CHAVE=0
         Then TECLA=TECLA+"Alt+F=Fun‡Æo  "
      EndIf
      If Field()="Tipo do Pagamento"    
         Then TECLA=TECLA+"F1=Tabela  "
      EndIf
      
      MSGCAMPO=""
      Prompt TECLA

      Switch
        Case Field()="Tipo do Pagamento"        : MSGCAMPO="Forma de Pagamento"
        Case Field()="FPG_NOME"                     : MSGCAMPO="Descri‡Æo no APP"
      EndSwitch   

      Wait Field
           MESSAGE MSGCAMPO
           Until "ESC","ENTER","DEL","FIELDVIEW","F35","F3","F4","F1","PGDN",-33

      Switch    
      Case RetVal=-33 :   
           ShowPopup " Fun‡Æo " CENTERED
            "[~F3~] Ativa/Inativa" : " Ativa/Inativa a opera‡Æo"         : "F3",
            Separator,
            "~C~ancelar          " : " Cancelar"                         : "CANCELAR"
           EndMenu
           To MenuVar
           Echo Off
      
           If MenuVar="CANCELAR" or MenuVar="Esc"
               Then Retval=""    
           EndIf
           
           Switch
             Case MenuVar="F3" : Ativa_Inativa()
                                 If CHAVE=9 Then QuitLoop EnDIf                    
           EndSwitch
           
      Case RetVal="F1":
           If Field()="Tipo do Pagamento"
              Then ConsultaF1()
           EndIf           
      Case RetVal="F3":
           Ativa_Inativa()
           If CHAVE=9 Then QuitLoop EnDIf           
      Case RetVal="ESC":   
           Switch
               Case Field()="Tipo do Pagamento" :
                    If QuerDesfazer("")
                       Then If CHAVE=1
                              Then Del
                              Else Undo
                            EndIf
                            CHAVE=9
                            QuitLoop
                    EndIf  
               Case Field()="FPG_NOME" : 
                 if CHAVE=1
                    then moveto [Tipo do Pagamento]
                    else
                          If QuerDesfazer("")
                             Then Undo
                                  CHAVE=9
                                  QuitLoop
                          EndIf  
                 endif   
            OtherWise : Left
           EndSwitch
      Case Retval="FIELDVIEW" or Retval="F35":
           EDITFIELD()
      Case RetVal="ENTER":
           Switch  
              Case Field()="Tipo do Pagamento"        :
                   If Not IsBlank([]) 
                      Then Moveto [FPG_NOME]
                   EndIf
              Case Field()="FPG_NOME"                     :
                   If Not IsBlank([]) 
                      Then CHAVE=9
                           QuitLoop
                   EndIf      
           EndSwitch
      EndSwitch
EndWhile

EndProc ;DIGITA()

;*******************************************************************************
;* Rotina para Ativar/Inativar a Opera‡Æo                                     *
;*******************************************************************************
Proc Ativa_Inativa()
Private INATIVO,MSG

Switch
  Case IsBlank([FPG_Inativo]) Or [FPG_Inativo]="N" : INATIVO = "S"
  Case [FPG_Inativo]="S"                           : INATIVO = "N"
EndSwitch

If INATIVO="S"
   Then MSG = "Deseja INATIVAR a opera‡Æo referente a forma de pagamento "+[FPG_NOME]+"?"
   Else MSG = "Deseja ATIVAR a opera‡Æo referente a forma de pagamento "+[FPG_NOME]+"?"
EndIf
    
If ConfGeral(MSG)
   Then [FPG_Inativo] = INATIVO
EndIf

Switch
  Case IsBlank([Tipo do Pagamento])        : Moveto [Tipo do Pagamento       ]
  Case IsBlank([FPG_NOME         ])        : Moveto [FPG_NOME                ]
  OtherWise                                : CHAVE=9
EndSwitch                                         

EndProc ;Ativa_Inativa()

;*******************************************************************************
;* Rotina para controlar Edicao do registro                                    *
;*******************************************************************************
Proc Controla_EdicaoC()

DIGITA()

If RecordStatus("Locked") Then UnLockRecord EndIf         
Endproc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"
                     
CoEdit "PS_FPG"
PickForm "F"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
  Controla_EdicaoC()
EndWhile
Do_It!
ClearAll

Release Vars All
Release Procs All
