;** Rm_0300  *******************************************************************
;*  Extrato de Conta                                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 15/04/2003 por Anivel Augusto Rodrigues
;Ultima Alteracao: 01/03/2005 por Davi Pereira Carrano
;Motivo Alteracao: Corre‡Æo das Ask para liberar tabelas quando se usa Fast Insert
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Substitui‡Æo Editor novo arquivo por FileWrite
;Ultima Alteracao: 09/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Ctacor\\Conta}
Moveto [Codigo da Conta          ] CheckPlus Example "CONTA"
Moveto [NDias Compensacao ChqDesc] CheckPlus Example "ndd"
{Ask} {BordCHC} Enter
Moveto [Numero do Lote        ] CheckPlus Example "LANCTO"
Moveto [Codigo da Empresa     ] CheckPlus
Moveto [Nome Fantasia Empresa ] CheckPlus
Moveto [Data do Lote          ] CheckPlus
Moveto [Tipo de Destino       ] TypeIn "DESCONTADO"
Moveto [Codigo da Conta       ] Example "CONTA" TypeIn ",~VSDGCONTA"
Moveto [Descricao da Conta    ] CheckPlus
{Ask} {BordCHI} Enter
Moveto [Numero do Lote        ] Example "LANCTO"
Moveto [Codigo_Banco          ] CheckPlus
Moveto [Numero_Cheque         ] CheckPlus
Moveto [Titular_Cheque        ] CheckPlus
Moveto [Valor                 ] CheckPlus
Moveto [Data Vencimento       ] CheckPlus TypeIn ">=~VSDGDTREF-_ndd"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Conta          ] Example "CONTA"
Moveto [NDias Compensacao ChqDesc] Example "ndd"
Moveto [Numero do Lote           ] Example "LANCTO"
Moveto [Codigo da Empresa        ] Example "EMPRES"
Moveto [Nome Fantasia Empresa    ] Example "NEMPRES"
Moveto [Data do Lote             ] Example "DTLOTE"
Moveto [Descricao da Conta       ] Example "DCONTA"
Moveto [Codigo_Banco             ] Example "BANCO"
Moveto [Numero_Cheque            ] Example "CHEQUE"
Moveto [Titular_Cheque           ] Example "TITULAR"
Moveto [Valor                    ] Example "VALOR"
Moveto [Data Vencimento          ] Example "DATA"

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero do Lote        ] Example "LANCTO"
Moveto [Codigo da Empresa     ] Example "EMPRES"
Moveto [Nome Fantasia Empresa ] Example "NEMPRES"
Moveto [Data do Lote          ] Example "DTLOTE"
Moveto [Codigo da Conta       ] Example "CONTA"
Moveto [Descricao da Conta    ] Example "DCONTA"
Moveto [Codigo_Banco          ] Example "BANCO"
Moveto [Numero_Cheque         ] Example "CHEQUE"
Moveto [Titular_Cheque        ] Example "TITULAR"
Moveto [Valor                 ] Example "VALOR"
Moveto [Data Vencimento       ] Example "DATA"
Moveto [Data Compensacao      ] TypeIn "_DATA+_ndd"
Do_It!
ClearAll

If VSDGCODMODELO="02"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Titular_Cheque] TypeIn "Changeto Blank"
        Do_It!
        ClearAll
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa()

Coedit Tabela
Home
Ins
[Codigo da Empresa     ]=VSDGEMPRESA
[Nome Fantasia Empresa ]=VSDGNOMEMP
[Codigo da Conta       ]=VSDGCONTA
[Descricao da Conta    ]=VSDGNOMCONTA
[Titular_Cheque        ]="LIMITE DE CREDITO"
[Saldo                 ]=LIMITE_CREDITO
Do_It!
ClearAll

EndProc    ; (Processa)

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Extrato  I")
ModeloRelatoriosAdd("02  Extrato II")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_CONTA"         : Campo="NO"
            Case Campo="TG_DTREF"         : Campo="TG_CONTA"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTREF"
            Case Campo="YES" Or Campo="NO": Campo="TG_CONTA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_CONTA"    : Campo="TG_DTREF"
                    Case Campo="TG_DTREF"    : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO": Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CONTA":
     MSG_CAMPO="Somente uma Conta disponivel"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

Proc ConfOpcoes(Opcao)
Private Opcao

Switch
  Case Opcao="Ler":
  
       ModeloRelatoriosCarregaLista()

       If IsFile("OE_0300.sc")
           Then Play "OE_0300"
           Else VSDGOPEXTRATO       =1
       EndIf
  Case Opcao="Gravar":
       FileWrite        "OE_0300.sc" From ";****** Variaveis de Configura‡„o Modelo EXTRATO Vise Informatica"+"\n"
       FileWrite Append "OE_0300.sc" From "VSDGCODMODELO=\""+VSDGCODMODELO+"\"\n"
EndSwitch
EndProc ;

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGTPCONTA=""
VSDGCONTA  =""
VSDGDTREF  =Today()

ConfOpcoes("Ler")

While True
  ShowDialog "Extrato de Cheques/Descontados" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 26,00   Height 12 Width 72

    Label  @ 00,00 "Conta"  For "TG_CONTA"
    Accept @ 01,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 01,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA

    Label  @ 02,00 "Data Referente" For "TG_DTREF"
    Accept @ 03,01 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Label  @ 05,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 06,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 06,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 08,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 08,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGCONTA=""
     Then Mensagem("Conta Invalida !")
          Loop
  EndIf
  If VSDGDTREF=BlankDate()
     Then Mensagem("Data Referencia Invalida !")
          Loop
  EndIf
  If VSDGTPCONTA="X"
     Then Mensagem("Extrato somente p/ Conta Corrente !")
          Loop
  EndIf

  View "\\Sistemas\\Ctacor\\Conta"
  Moveto [Codigo da Conta]
  Locate VSDGCONTA
  LIMITE_CREDITO=[Limite Cheque Descontado]
  VSDGEMPRESA=[Codigo da Empresa    ]
  VSDGNOMEMP =[Nome Fantasia Empresa]

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, preparando o extrato")
  Tabela=Cria_Temp(PrivDir())
  Switch
    Case VSDGCODMODELO="01" or
         VSDGCODMODELO="02":
         Copy "\\Base\\Sistemas\\CheqRec\\RM_0300" Tabela
  EndSwitch

  Seleciona()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  Switch
    Case VSDGCODMODELO="01" : IMPRIREL(Tabela,"R")
    Case VSDGCODMODELO="02" : IMPRIREL(Tabela,"1")
  EndSwitch

  Delete Tabela
  ConfOpcoes("Gravar")

EndWhile
ClearAll
Release Vars All
Release Procs All
