;** RM_0501 ********************************************************************
;*  Posicao de Pedidos                                                         *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 13/04/2011 por Anivel Augusto Rodrigues
;Ultima Alteracao:   /  /     por 
;Motivo Alteracao:         

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SELECIONA_PEDIDOS()
AGUARDE("Aguarde, selecionando pedidos de venda")
ClearAll

{Ask} {\\Sistemas\\Vendas\\PedidoC}
Moveto [Numero do Pedido       ] Example "Pedido" TypeIn ", ~VSDGPEDIDO.."
Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Data de Emissao        ] Check
Moveto [Data de Entrega        ] Check 
If IsBlank(VSDGPEDIDO) And
   IsBlank(VSDGNCARREG)
   Then Moveto [Data de Entrega] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
EndIf   
Moveto [Codigo                 ] Check
Moveto [Razao Social           ] Check
Moveto [UF                     ] Check
Moveto [Cidade                 ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Numero_Carregamento    ] Check
Moveto [Observacao do Pedido   ] Check
Moveto [Numero_Carregamento    ] TypeIn "~VSDGNCARREG.."
{Ask} {\\Sistemas\\Vendas\\PedidoI}
Moveto [Numero do Pedido       ] Check Example "Pedido"
Moveto [Item do Pedido         ] Check
Moveto [Codigo do Item         ] Check
Moveto [Descricao do Item      ] Check
Moveto [Tipo do Item           ] Check
Moveto [Codigo da Cor_Tecido   ] Check
Moveto [Descricao da Cor_Tecido] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Quantidade             ] Check
Moveto [Quantidade Faturada    ] Check
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Processa Dados                                                              *
;*******************************************************************************
Proc Processa()

If IsEmpty("Answer")
	 Then Return
EndIf

ClearAll
AGUARDE("Aguarde, processando Pedidos")

View TabelaP
Coedit "Answer"
NR = NRecords("Answer")
Scan
  Barra(NR, RecNo())
  Aguarde("Aguarde, Processando Pedidos "+BARRA_STRING)

  qtdaf=[Answer->Quantidade]-[Answer->Quantidade Faturada]

  If VSDGOPCAO[1] and qtdaf=0
     Then Loop
  EndIf

  Moveto TabelaP
  End
  Down

  [Numero do Pedido       ]=[Answer->Numero do Pedido       ]
  [Codigo da Empresa      ]=[Answer->Codigo da Empresa      ]
  [Nome Fantasia Empresa  ]=[Answer->Nome Fantasia Empresa  ]
  [Data de Emissao        ]=[Answer->Data de Emissao        ]
  [Data de Entrega        ]=[Answer->Data de Entrega        ]
  [Codigo                 ]=[Answer->Codigo                 ]
  [Razao Social           ]=[Answer->Razao Social           ]
  [UF                     ]=[Answer->UF                     ]
  [Cidade                 ]=[Answer->Cidade                 ]
  [Codigo do Representante]=[Answer->Codigo do Representante]
  [Nome Fantasia Represent]=[Answer->Nome Fantasia Represent]
  [Numero_Carregamento    ]=[Answer->Numero_Carregamento    ]
  [Item do Pedido         ]=[Answer->Item do Pedido         ]
  [Codigo do Item         ]=[Answer->Codigo do Item         ]
  [Descricao do Item      ]=[Answer->Descricao do Item      ]
  [Tipo do Item           ]=[Answer->Tipo do Item           ]
  [Qtde_Pedida            ]=[Answer->Quantidade             ]
  [Qtde_Faturada          ]=[Answer->Quantidade Faturada    ]
  [Observacao do Pedido   ]=[Answer->Observacao do Pedido   ]
  [Qtde_AFaturar          ]=qtdaf

  Moveto "Answer"
EndScan
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""

If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_NCARREG"        : Campo="TG_EMPRESA"
            Case Campo="TG_PEDIDO"         : Campo="TG_NCARREG"
            Case Campo="TG_DTINI"          : Campo="TG_PEDIDO"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_OPCOES"         : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     : Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG"     :
                      If Not IsBlank(VSDGNCARREG)
                         Then Campo="TG_OPCOES"
                              VSDGPEDIDO=""
                              VSDGDTINI  =BlankDate()
                              VSDGDTFIM  =BlankDate()
                         Else Campo="TG_PEDIDO"
                      EndIf   
                    Case Campo="TG_PEDIDO"      : 
                      If Not IsBlank(VSDGPEDIDO)
                         Then Campo="TG_OPCOES"
                              VSDGDTINI  =BlankDate()
                              VSDGDTFIM  =BlankDate()
                         Else Campo="TG_DTINI"
                      EndIf   
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_OPCOES"
                    Case Campo="TG_OPCOES"      : Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPCOES":
       MSG_CAMPO="Selecione uma ou mais op‡oes se desejar !"
       TECLA    ="=Mover  Barra de espa‡o=Marca/Desmarca  "
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

VSDGEMPRESA=""
VSDGNCARREG=""
VSDGPEDIDO =""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

Array VSDGOPCAO[1]

While True

  ShowDialog "EmissÆo da Posi‡Æo de Pedidos II" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140,-68
    @ 01,07 Height 16 Width 68

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "N§ Carregamento" For "TG_NCARREG"
    Accept @ 03,01 Width 9  "A6"  Picture "#*#" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 03,11 Width 23 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG

    Label  @ 04,00 "N§ Pedido" For "TG_PEDIDO"
    Accept @ 05,01 Width 09 "A6"  Picture "#*#" Tag "TG_PEDIDO" To VSDGPEDIDO
    Accept @ 05,11 Width 23 "A20" Picture "!*!" Tag "TG_PEDIDO" To VSDGNOMPEDIDO

    Label  @ 06,00 "Per¡odo de Entrega Referente" For "TG_DTINI"
    Label  @ 07,00 "de" For "TG_DTINI"
    Accept @ 07,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,17 "at‚" For "TG_DTFIM"
    Accept @ 07,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 08,00 "Op‡”es" For "TG_OPCOES"
    CheckBoxes @09,00 Height 2 Width 50 Tag "TG_OPCOES"
    "Imprimir apenas itens a Faturar" to VSDGOPCAO[1]

    Pushbutton @ 12,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog

  If Not RetVal Then QuitLoop EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  ;*** Pedidos ***
  TabelaP=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0501" TabelaP
  Empty TabelaP

  Seleciona_Pedidos()

	Processa()

	If IsEmpty(TabelaP)
		 Then MENSAGEM("N„o Existem Registros a Processar (Pedidos)")
     Else IMPRIREL(TabelaP,"R")
  EndIf

  LimpAguarde()
  Delete "Answer"
  Delete TabelaP

EndWhile
ClearAll
Release Vars All
Release Procs All
