;** RO_0019   ******************************************************************
;** Imprime a Digitacao do Romaneio                        ** Sintonia **      *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 20/02/2001 por Anivel Augusto Rodrigues
;Alterado em     : 24/12/2003 por Karen Lauar Nery
;Motivo Alteracao: ITEM DA OF
;Alterado em     : 16/06/2006 por Antonio Marcelo Alves
;Motivo Alteracao: Inclusao ImpriArq()
;Ultima Alteracao: 14/08/2007 por Antonio Marcelo Alves
;Motivo Alteracao: Ajustes Deleta_Arquivo

;*******************************************************************************
;* Rotina para Impressao do Relatorio                                          *
;*******************************************************************************
Proc IMPFAT()

;************************* IMPRESSAO DO CABECALHO *****************************
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf
MOveto "FaturaC"
Print File ARQIMP "\n"
Print File ARQIMP CI_15CPP

Print File ARQIMP "========================================================================================================================================"+"\n"
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP
Print File ARQIMP "\014"
Print File ARQIMP "\027E"
Print File ARQIMP Spaces(03)+"PEDIDO N§ "+Format("W06.3,AL",NOTAFISC)+" Sem Valor Fiscal"+"\n"
Print File ARQIMP "\020"
Print File ARQIMP "\027F"
Print File ARQIMP Spaces(06)+"Data: "+Format("D10",Today())+" Hora: "+Time()+" Vendedor: "
Print File ARQIMP Format("W05,AL",[Codigo do Representante])+" "+Format("W25,AL",[Nome Fantasia Represent])+"\n"
Print File ARQIMP CI_15CPP
Print File ARQIMP "========================================================================================================================================"+"\n"

Print File ARQIMP "Cliente: "+Format("W05,AL",[Codigo])+Format("W40,AL",[Razao Social])+Spaces(09)+"CGC/CPF: " +Format("W18,AL",[CGC])+" Insc./ID:"+Format("W25,AL",[IE])+"\n"

Print File ARQIMP Spaces(09)+Format("W40,AL",[Endereco])
Print File ARQIMP Spaces(03)+Format("W20,AL",[Bairro])
Print File ARQIMP Format("W12,AL",[CEP])
Print File ARQIMP Spaces(03)+Format("W20,AL",[Cidade])
Print File ARQIMP Format("W02,AL",[UF])
Print File ARQIMP Format("W25,AL",[Telefone])+"\n"

Print File ARQIMP "ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ"+"\n"
;********************* IMPRESSAO DOS ITENS ********************************
Print File ARQIMP "Pedido  Sq Codigo     Familia          Item                              Marca               M         Qtde Un        PrUni      PrTotal"+"\n"
Print File ARQIMP "------ --- ---------- ---------------- --------------------------------- ------------------ --- ----------- -- ------------ ------------"+"\n"

Moveto "FaturaI"
Moveto [Numero da OF]
CONTADOR=1
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
   Moveto [Codigo do Item]
   Ativa_Lookup()
   Locate [Faturai->Codigo do Item]
     If RetVal
        Then FAMILIA=[Descricao da Familia]
             MARCA  =[Descricao da Marca  ]
        Else Mensagem("Item n„o cadastrado !")
             FAMILIA=""
             MARCA  =""
     EndIf
   Keypress "Esc"

   Print File ARQIMP Format("W07,AL",[Numero Pedido_Orcamento])
   Print File ARQIMP Format("W03,AR",StrVal([Item da OF]))+" "
   Print File ARQIMP Format("W10,AR",NumVal([Codigo do Item]))+" "
   Print File ARQIMP Format("W17,AL",FAMILIA)
   Print File ARQIMP Format("W32,AL",[Descricao do Item])+"  "
   Print File ARQIMP Format("W17,AL",MARCA)
   Print File ARQIMP "   "+Format("W01,AL",[Faturac->Tipo Movimento Estoque])
   Print File ARQIMP Format("W13.2,EIC",[Quantidade])
   Print File ARQIMP Format("W03,AR",[Unidade Fiscal])
   Print File ARQIMP Format("W13.2,EIC",[Preco Unitario])
   Print File ARQIMP Format("W13.2,EIC",[Preco Total])+"\n"
   Skip
   CONTADOR=CONTADOR+1
   If EOT() Then QuitLoop EndIf

EndWhile
While CONTADOR < 23
  Print File ARQIMP "\n"
  CONTADOR=CONTADOR+1
EndWhile

Print File ARQIMP "ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ"+"\n"
;********************* IMPRESSAO DOS VENCIMENTOS **************************
Array DATA[9]
Array VALOR[9]
K=0
Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
  K=K+1
  DATA[K]  = Format("D13",[Data])
  VALOR[K] = Format("W10.2,AR,EIC",[Valor])
  If K=6
     Then VENC()
          K=0
  EndIf
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile
If K>0
   Then VENC()
EndIf

Moveto"Faturac"
;************************* IMPRESSAO DO RODAPE ********************************
Print File ARQIMP "\n"
Print File ARQIMP "Cond. Pagto: "+[Descricao CondPagto]
Print File ARQIMP "   NP: "+StrVal([Numero de Parcelas])
Print File ARQIMP "   CD: "+[Composicao de Dias]+[Forma de Pagamento]+" DATA: __/__/____  Ass.:_______________________________________________________________"+"\n"

Print File ARQIMP "========================================================================================================================================"+"\n"

EndProc
;*******************************************************************************
;* Rotina de Impressao dos Vencimentos                                         *
;*******************************************************************************
Proc VENC()
Moveto "FaturaC"

For I From 1 to K
  Print File ARQIMP StrVal(I)+" Parc. Venc.: "+DATA[I]+" "+"Vr:"+VALOR[I]+Spaces(06)

  If K = 1
     Then Print File ARQIMP Spaces(69)+"Total...:"+Format("W12.2,EIC",[Valor Mercadoria])+"\n"
          If [Valor Do Desconto] > 0
             Then Print File ARQIMP Spaces(114)+"Desconto:"+Format("W12.2,EIC",[Valor do Desconto])+"\n"
             Else Print File ARQIMP Spaces(114)+"Desconto:"+Format("W06.2,EIC",[Taxa de Desconto])+"%..."+"\n"
          EndIf
          Print File ARQIMP Spaces(114)+"Liquido.:"+Format("W12.2,EIC",[Valor Mercadoria Liquido])+"\n"
  EndIf

  If I=2 and k > 2
     Then Print File ARQIMP Spaces(24)+"Total...:"+Format("W12.2,EIC",[Valor Mercadoria])+"\n"
  EndIf

  If I=4 and k > 4
     Then Print File ARQIMP Spaces(24)+"Desconto:"
          If [Valor Do Desconto] > 0
             Then Print File ARQIMP Format("W12.2,EIC",[Valor do Desconto])+"\n"
             Else Print File ARQIMP Format("W06.2,EIC",[Taxa de Desconto])+"%..."+"\n"
          EndIf
  EndIf

  If I=2 and K=2
     Then Print File ARQIMP Spaces(24)+"Total...:"+Format("W12.2,EIC",[Valor Mercadoria])+"\n"
          Print File ARQIMP Spaces(114)+"Desconto:"
          If [Valor Do Desconto] > 0
             Then Print File ARQIMP Format("W12.2,EIC",[Valor do Desconto])+"\n"
             Else Print File ARQIMP Format("W06.2,EIC",[Taxa de Desconto])+"%..."+"\n"
          EndIf
          Print File ARQIMP Spaces(114)+"Liquido.:"+Format("W12.2,EIC",[Valor Mercadoria Liquido])+"\n"
  EndIf

  If I=3 and K=3
     Then Print File ARQIMP Spaces(69)+"Desconto:"
          If [Valor Do Desconto] > 0
             Then Print File ARQIMP Format("W12.2,EIC",[Valor do Desconto])+"\n"
             Else Print File ARQIMP Format("W06.2,EIC",[Taxa de Desconto])+"%..."+"\n"
          EndIf
          Print File ARQIMP Spaces(114)+"Liquido.:"+Format("W12.2,EIC",[Valor Mercadoria Liquido])+"\n"
  EndIf

  If I=4 and K=4
     Then Print File ARQIMP Spaces(24)+"Desconto:"
          If [Valor Do Desconto] > 0
             Then Print File ARQIMP Format("W12.2,EIC",[Valor do Desconto])+"\n"
             Else Print File ARQIMP Format("W06.2,EIC",[Taxa de Desconto])+"%..."+"\n"
          EndIf
          Print File ARQIMP Spaces(114)+"Liquido.:"+Format("W12.2,EIC",[Valor Mercadoria Liquido])+"\n"
  EndIf

  If I=5 and K=5
     Then Print File ARQIMP Spaces(69)+"Liquido.:"+Format("W12.2,EIC",[Valor Mercadoria Liquido])+"\n"
  EndIf

  If I=6
     Then Print File ARQIMP Spaces(24)+"Liquido.:"+Format("W12.2,EIC",[Valor Mercadoria Liquido])+"\n"
  EndIf

EndFor
Moveto "FaturaV"

EndProc
;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************

ArqImp=PrivDir()+"Ro_0019.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)
IMPFAT()
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_6LPP

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)

Release Vars VALOR,DATA
Release Procs IMPFAT,VENC
LIMPAGUARDE()


