;** Rm_0102 ********************************************************************
;*  Emissao do Inventario Terceirizados                                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 31/05/2010 por Bruno Carvalho
;Ultima Alteracao: 16/07/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado Pre‡o de Custo
;Ultima Alteracao: 16/08/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes para itens semi-acabados
;Ultima Alteracao: 14/09/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes para valores de itens semi-acabados
;Ultima Alteracao: 23/10/2013 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo do filtro "Destinat rio"
;Ultima Alteracao: 07/07/2014 por Bruno Carvalho
;Motivo Alteracao: Ajustes ao buscar o custo na Ficha de Estoque
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT 
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {Pfacc}
Moveto [Numero_Programacao    ] Example "num"
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo                ] TypeIn "~VSDGDESTINAT.."
Moveto [Situacao_Programacao  ] TypeIn "Not FINALIZADA"
Moveto [Destino_Producao      ]  
Switch
  Case VSDGOPDEST="TODOS" : TypeIn "Not INTERNO"
  OtherWise               : TypeIn "~VSDGOPDEST"
EndSwitch
{Ask} {PfacRI} Check
Moveto [Numero_Programacao    ] Example "num"
Do_It!
ClearAll

{Ask} {Answer}                        
Moveto [Quantidade Produzida] TypeIn "Changeto Blank"
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

{Ask} TypeIn Tabela Enter
Moveto [Numero_Programacao    ] Example "num"
{Ask} {Rfacc}
Moveto [Numero_Producao       ] Example "numprod"
Moveto [Numero_Programacao    ] Check Example "num"
{Ask} {RfacRI} Check
Moveto [Numero_Producao       ] Example "numprod"
Do_It!
ClearAll

CoEdit Tabela,"Answer"
Scan

  Moveto Tabela
  Moveto [Numero_Programacao]
  Locate [Answer->Numero_Programacao],[Answer->Codigo do Item]
  If RetVal
     Then [Quantidade Produzida  ]=[Quantidade Produzida  ]+[Answer->Quantidade Produzida  ]
  EndIf
  [Preco Unitario]=BlankNum()
  [Preco Total   ]=BlankNum()
  Moveto "Answer"

EndScan
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast Delete"
Moveto [Quantidade Programada] Example "qtd"
Moveto [Quantidade Produzida ] TypeIn ">=" Example "qtd"
Do_It!
ClearAll

{Ask} {Pfacc}
Moveto [Numero_Programacao    ] Check Example "num"
Moveto [Codigo da Empresa     ] Check
Moveto [Nome Fantasia Empresa ] Check
Moveto [Data_Programacao      ] Check
Moveto [Destino_Producao      ] Check
Moveto [Codigo                ] Check
Moveto [Nome Fantasia EmitDest] Check
Moveto [Razao Social          ] Check
Moveto [Situacao_Programacao  ] Check
{Ask} TypeIn Tabela Enter Check
Moveto [Numero_Programacao    ] Example "num"
Do_It!
ClearAll

Custo_Pecas()

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Processar Dados                                                   *
;*******************************************************************************
Proc Custo_Pecas()

If IsTable("\\FechAno\\"+VSDGANO+"\\Estoque\\Sdestq") 
   Then TAB_TEMP = "\\FechAno\\"+VSDGANO+"\\Estoque\\Sdestq"
   Else TAB_TEMP = "\\Sistemas\\Estoque\\SdEstq"
EndIf       

Semi_Acabados()

{Ask} TypeIn TAB_TEMP Enter
Moveto [Codigo da Empresa     ] Example "CodEmp"
Moveto [Codigo do Item        ] Example "ITEM"
Moveto [Saldo Atual           ] Example "SaldoAtual"
Moveto [Custo Total Atual     ] Example "CustoTotal"
Moveto [Mes Referencia        ] TypeIn "~VSDGMES"
Moveto [Ano Referencia        ] TypeIn "~VSDGANO"
{Ask} {Answer} TypeIn "Fast"    
Moveto [Codigo da Empresa     ] Example "CodEmp"
Moveto [Codigo do Item        ] Example "ITEM"
Moveto [Preco Unitario        ] TypeIn "Changeto _CustoTotal/_SaldoAtual"
Do_It!
ClearAll

CoEdit "Answer"
Scan
  [Preco Unitario]=NDecimal(([Preco Unitario]),5)
  [Preco Total   ]=NDecimal([Preco Unitario]*([Quantidade Programada]-[Quantidade Produzida]),2)
EndScan
Do_It!
ClearAll


EndProc ; Custo_Pecas()

;*******************************************************************************
;* Rotina p/ transformar em produtos semi-acabados                             *
;*******************************************************************************
Proc Semi_Acabados()

CoEdit "Answer"
Scan
 CODNOVO=[Codigo do Item]
 Switch
   Case SYS_CODIGO_CLIENTE="0185" Or
        SYS_CODIGO_CLIENTE="0195" Or
        SYS_CODIGO_CLIENTE="0196" Or
        SYS_CODIGO_CLIENTE="0003" Or
        SYS_CODIGO_CLIENTE="0222" Or
        SYS_CODIGO_CLIENTE="0200" Or
        SYS_CODIGO_CLIENTE="0204":
        CODNOVO="03"+SubStr(CODNOVO,3,8)
        [Codigo do Item]=CODNOVO
   Case SYS_CODIGO_CLIENTE="0171":
        CODNOVO="2"+SubStr(CODNOVO,2,9)
        [Codigo do Item]=CODNOVO
  OtherWise: QuitLoop
EndSwitch
EndScan
Do_It!
ClearAll

EndProc ;Semi_Acabados()

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Sint‚tico I")
ModeloRelatoriosAdd("02  Sint‚tico II")
ModeloRelatoriosAdd("03  Anal¡tico")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
           If Campo="TG_OPDEST"
              Then Seleciona_Opcoes("Op‡”es de Desinat rio","9,9")
           EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_OPDEST"        : Campo="TG_EMPRESA"
            Case Campo="TG_DESTINAT"      : Campo="TG_OPDEST"
            Case Campo="TG_CODMODELO"     : Campo="TG_DESTINAT"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
          Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
          SYS_TECLA_ACIONADA=Evento["KeyCode"]
          Seta_Tecla_Acionada()
          CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_OPDEST"
                    Case Campo="TG_OPDEST"     :
                         VSDGOPDEST=ControlValue("TG_OPDEST")
                         If IsBlank(VSDGOPDEST) 
                            Then Campo="TG_OPDEST" 
                            Else If Not Checa_Opcoes("Op‡”es de Desinat rio",VSDGOPDEST)
                                   Then Mensagem("Destino inv lido !")
                                        Campo="TG_OPDEST"
                                   Else If Not Isblank(VSDGOPDEST) 
                                           Then If Not IsBlank(VSDGOPDEST)
                                                   Then Campo="TG_DESTINAT"
                                                EndIf           
                                        EndIf
                                EndIf
                         EndIf
                    Case Campo="TG_DESTINAT"   : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"    : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_OPDEST":
     MSG_CAMPO="Informe a op‡Æo, [F1]Consultar tabela"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

  COR_MENSAGEM="1"
  MSG=    "Para a exibi‡„o correta deste relat¢rio ‚ necess rio que//"
  MSG=MSG+"vocˆ tenha executado o reprocessamento do estoque do mˆs//"
  MSG=MSG+"atual,  caso  esteja  em d£vida sobre a realiza‡„o deste//"
  MSG=MSG+" procedimento, execute ent„o o reprocessamento.            "
        Mensagem(MSG)
        Release Vars COR_MENSAGEM

ClearAll

VSDGEMPRESA =""
VSDGOPDEST  =""
VSDGDESTINAT=""
  
DTHOJE =Format("D13",Today())
VSDGMES=AlinhM(StrVal(Month(Today())),2)
VSDGANO=AlinhM(StrVal(Year(Today())),4)

Coedit "P_DESTI"
Monta_Opcoes("Op‡”es de Desinat rio","TODOS") 
Do_It!
ClearAll   

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Invent rio de Terceirizados de "+DTHOJE Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
      @ 05,12   Height 14 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Op‡”es Destinat rio" For "TG_OPDEST"
    Accept @ 03,01 Width 33 "A12"  Picture "!*!" Tag "TG_OPDEST" To VSDGOPDEST

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 07,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 08,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 08,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 10,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")

  Seleciona()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Delete "Answer"
          Delete Tabela
          Loop
  EndIf

  Switch
    Case VSDGCODMODELO="01": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0102" "R" "Answer" "R"
    Case VSDGCODMODELO="02": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0102" "1" "Answer" "R"
    Case VSDGCODMODELO="03": CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0102" "2" "Answer" "R"
  EndSwitch
  
  IMPRIREL("Answer","R")

  Delete Tabela
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
