;** Rm_0101 ********************************************************************
;*  Emissao das programacoes de Corte                                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/09/2010 por Karina
;Ultima Alteracao: 24/11/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajuste de T¡tulo            
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
{Ask} {Cfacc}
Moveto [Numero_Corte          ] Example "num" TypeIn ", ~VSDGCORTE.."
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
Moveto [Data_Programacao      ]
   If IsBlank(VSDGCORTE)
      Then TypeIn " >=~VSDGDTINI,<=~VSDGDTFIM"
   EndIf
If VSDGSITUACAO<>"TODOS" And VSDGSITUACAO<>""
   Then Moveto [Situacao_Programacao] TypeIn "~VSDGSITUACAO"
EndIf

{Ask} {CfacRI} Check
Moveto [Numero_Corte         ] Example "num"
Moveto [Codigo do Item       ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Quantidade Produzida] TypeIn "Changeto Blank"
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
{Ask} TypeIn Tabela Enter
Moveto [Numero_Corte          ] Example "num"
{Ask} {PcfaCC}
Moveto [Numero_Producao_Corte   ] Example "numprod"
Moveto [Numero_Programacao_Corte] Check Example "num"
{Ask} {PcfacRI} Check
Moveto [Numero_Producao_Corte   ] Example "numprod"
Moveto [Codigo do Item          ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Do_It!
ClearAll

CoEdit Tabela,"Answer"
Scan
  
  Moveto Tabela
  Moveto [Numero_Corte]
  Locate [Answer->Numero_Programacao_Corte],[Answer->Codigo do Item]
  If RetVal
     Then [Quantidade Produzida  ]=[Quantidade Produzida  ]+[Answer->Quantidade Produzida  ]
  EndIf
  Moveto "Answer"

EndScan
Do_It!
ClearAll

If VSDGOPIT="P"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast Delete"
        Moveto [Quantidade Programada] Example "qtd"
        Moveto [Quantidade Produzida ] TypeIn ">=" Example "qtd"
        Do_It!
        ClearAll

EndIf

{Ask} {Cfacc}
Moveto [Numero_Corte          ] Check Example "num"
Moveto [Codigo da Empresa     ] Check
Moveto [Nome Fantasia Empresa ] Check
Moveto [Data_Programacao      ] Check
Moveto [Situacao_Programacao  ] Check
{Ask} TypeIn Tabela Enter Check
Moveto [Numero_Corte          ] Example "num"
Do_It!
ClearAll

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_CORTE"         : Campo="TG_EMPRESA"
            Case Campo="TG_SITUACAO"      : Campo="TG_CORTE"
            Case Campo = "TG_ITEM"           : Campo = "TG_SITUACAO"
            Case Campo = "TG_REFERENCIA"     : Campo = "TG_ITEM"
            Case Campo="TG_DTINI"         : Campo="TG_REFERENCIA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPIT"          : Campo="TG_CORTE"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_CORTE"
                    Case Campo="TG_CORTE"      :
                         If Not ISBlank(VSDGCORTE)
                            Then VSDGDSITUACAO=""
                                 VSDGDTINI  =BlankDate()
                                 VSDGDTFIM  =BlankDate()
                                 Campo="TG_OPIT"
                            Else Campo="TG_SITUACAO"
                         EndIf
                    Case Campo="TG_SITUACAO"   :
                                VSDGSITUACAO=ControlValue("TG_SITUACAO")
                                If IsBlank(VSDGSITUACAO)
                                   Then VSDGSITUACAO="TODOS"
                                EndIf
                                Campo="TG_ITEM"
                    Case Campo = "TG_ITEM"     : Campo = "TG_REFERENCIA"
                    Case Campo = "TG_REFERENCIA" : Campo = "TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_OPIT"
                    Case Campo="TG_OPIT"       :
                         VSDGOPIT=ControlValue("TG_OPIT")
                         If IsBlank(VSDGOPIT)
                            Then VSDGOPIT="T"
                         EndIf
                         Switch
                           Case VSDGOPIT="T": VSDGDESCOPIT="TODOS"
                           Case VSDGOPIT="P": VSDGDESCOPIT="PENDENTES"
                         EndSwitch
                         Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CORTE"      :
     MSG_CAMPO="Em Branco = Todas" 
  Case Campo="TG_SITUACAO":
     MSG_CAMPO="P=PROGRAMADA  E=EM PRODUCAO  S=SUSPENSA  F=FINALIZADA  Branco=Todos"
  Case Campo="TG_OPIT":
     MSG_CAMPO="Op‡„o: T=Todos  P=Pendentes"
  Case Campo="":
     MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  =""
VSDGCORTE    =""
VSDGSITUACAO =""
VSDGDTINI    =BlankDate()
VSDGDTFIM    =BlankDate()
VSDGOPDT    ="T"
VSDGTPITEM  =""
VSDGREFERENCIA  = ""

While True
  ShowDialog "Posi‡Æo da Programa‡„o de Corte" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 17 Width 65

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 26 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Corte"  For "TG_CORTE"
    Accept @ 03,01 Width 09 "A6"  Picture "#*#" Tag "TG_CORTE" To VSDGCORTE
   
    Label  @ 04,00 "Situa‡„o"  For "TG_SITUACAO"
    Accept @ 05,01 Width 14 "A11"  Picture "PROGRAMADA,EM PRODUCAO,SUSPENSA,FINALIZADA,TODOS" Tag "TG_SITUACAO"  To VSDGSITUACAO
    
    Label  @ 06,00 "Item"  For "TG_ITEM"
    Accept @ 07,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 07,15 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM"  To VSDGNOMITEM

    Label  @ 06,48 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 07,49 Width 13 "A10" Picture "#*#" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 08,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 09,00 "de" For "TG_DTINI"
    Accept @ 09,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,17 "at‚" For "TG_DTFIM"
    Accept @ 09,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 10,00 "Op‡„o para Itens" For "TG_OPIT"
    Accept @ 11,01 Width 04 "A1"  Picture "T,P" Tag "TG_OPIT" To VSDGOPIT
    Accept @ 11,06 Width 29 "A25"  Picture "!*!" Tag "TG_DESCOPIT" To VSDGDESCOPIT
    
    Pushbutton @ 13,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 13,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
 If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGCORTE) And VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")

  Seleciona()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Delete "Answer"
          Delete Tabela
          Loop
  EndIf

    CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0100" "8" "Answer" "R"
    IMPRIREL("Answer","R")

  Delete Tabela
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
