;** Consulta *******************************************************************
;*  Programa para consulta na tela Caixa/Banco                                 *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 23/07/95 por Anivel Augusto Rodrigues
;Ultima Alteracao: 16/11/2000 por Anivel Augusto Rodrigues
;Motivo Alteracao: ShowDialog Novas Variaveis
;Ultima Alteracao: 15/08/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Run
;Ultima Alteracao: 10/09/2010 por Bruno Carvalho
;Motivo Alteracao: Rotina Copia Familia e Ajustes
;Ultima Alteracao: 19/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 16/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes copia familia so fechames, naä excluir pasta no fechames   
;Ultima Alteracao: 17/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   

;*******************************************************************************
;*Consulta a Movimentacao e Conta                                              *
;*******************************************************************************
Proc CONSULTA()
If IsTable("MovCont")
   Then If Not IsEmpty("MovCont")
           Then
                View "MovCont"
                PickForm "2"
                While True

                  Prompt " Esc=Sair  Ctrl+Z=Procurar  Alt+Z=Pr¢ximo  "

                  Wait Table Until "ESC", "ZOOM", "ZOOMNEXT"

                  If RetVal = "ZOOM"
                     Then PESQUISA()
                          Loop

                  EndIf
                  If RetVal = "ZOOMNEXT"
                     Then PESQUISACON()
                          Loop
                  EndIf
                  If Retval = "ESC"
                     Then QuitLoop
                  EndIf

                EndWhile
                ClearAll
           Else LimpAguarde()
                Mensagem("Tabela sem registros !")
        EndIf
   Else LimpAguarde()
        Mensagem("Tabela [MovCont] n„o encontrada !")
EndIf
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_DIRETORIOS"    : Campo="NO"
            Case Campo="YES" Or Campo="NO": Campo="TG_DIRETORIOS"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_DIRETORIOS" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="":
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* Copia Familia                                                          *
;*******************************************************************************
Proc Copia_Familia(caminho,tabela)
Private caminho,tabela

{Tools} {Copy} {JustFamily} TypeIn "\\BASE"+caminho+"\\"+tabela Enter TypeIn tabela Enter
If MenuChoice()="Cancel"
   Then Down
        If MenuChoice()="Replace"
           Then {Replace}
           Else {Cancel}
                Esc Esc Esc Esc
                MSG="Tabela [ "+tabela+" ] em [ "+caminho+" ], //"
                MSG=MSG+"com estrutura diferente !// //"
                MSG=MSG+"Anote o nome da tabela e pasta !//"
                MSG=MSG+"Depois entre em contato com o suporte Ok !"
                Mensagem(MSG)
        Endif
EndIf
Esc Esc Esc Esc
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

Diretorio="\\Sistemas\\CtaCor\\"
Diretorios_Fechames_C(Diretorio)

While True
  ShowDialog "Consulta Caixa/Banco" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 04,17   Height 19 Width 75

    Label @ 00,00 "Ano_Mes Fechado"  For "TG_DIRETORIOS"
    PickDynArray @1,00 Height 13 width 69
     Columns 7
      Array_Diretorios
       Tag "TG_DIRETORIOS"
        To ArrayElement

    Pushbutton @ 15,24 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,38 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  ANO_MES=Array_Diretorios[ArrayElement]
  If ANO_MES<>" Atual"
     Then Diretorio="\\Sistemas\\CtaCor\\Fechames\\"+ANO_MES
     Else Diretorio="\\Sistemas\\CtaCor"
  EndIf
  If DirExists(Diretorio)=0
     Then Mensagem("N„o existe a pasta do "+ANO_MES+" selecionado !")
          Loop
  EndIf
  SetDir Diretorio

  if search("FECHAMES",upper(Diretorio))>0
     then 
          Copia_Familia("\\Sistemas\\CtaCor","MovCont")  
  endif
  
  CONSULTA()
  Echo Normal
  Echo Off
  
  SetDir "\\Sistemas\\CtaCor"

;;If Not Tem_Tabelas(Diretorio)
;;   Then Deleta_Arvore(SubStr(Directory(),1,2)+Diretorio)
;;EndIf

  LimpAguarde()

EndWhile
ClearAll
Release Vars All
Release Procs All
