;** RO_0215 ********************************************************************
;** Imprime a Digitacao do Romaneio                        ** ART MOVEIS **    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 11/11/2008 por Humberto Felipe Santos.
;Alterado em     : 02/08/2009 por Humberto Felipe Santos. 
;Motivo Alteracao:
;Ultima Alteracao: 07/03/2014 por Kamila Gomes
;Motivo Alteracao: Aumento dos campos Observa‡Æo e impressÆo FP
;Ultima Alteracao: 07/11/2018 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes formata‡Æo peso EIC com 3 casas decimais

;*******************************************************************************
;* Rotina para Impressao do Relatorio                                          *
;*******************************************************************************
Proc IMPFAT()

;************************** IMPRESSAO DO CABECALHO *****************************
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf
Moveto "Faturac"
Print File ARQIMP chr(27)+chr(67)+chr(33) ;Imprime 33 Linhas por pagina
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_6LPP

;Print File ARQIMP "\n"
Print File ARQIMP Format("W50,AL","EMITENTE - ART MOVEIS - 37 3381-3354")+"Impressao: "+Format("D10",Today())+"-"+Time()+ "\n"
;Print File ARQIMP Spaces(50)+"Emissao: "+Format("D13",[Data de Emissao])+ "\n"

Print File ARQIMP "\014"
Print File ARQIMP "\027E"
Print File ARQIMP Spaces(10)+"Orcamento N§ "+Format("W06.3,AL",NOTAFISC)+"\n\n"
Print File ARQIMP "\020"

Print File ARQIMP Spaces(05)+"Cliente : "+Format("W05,AL",[Codigo])+Format("W46,AL",[Razao Social])+"\n"
Print File ARQIMP "\027F"

Print File ARQIMP CI_8LPP
Print File ARQIMP "\027P"         ;Imprime 10 Caracteres por polegada

Print File ARQIMP Spaces(15)+Format("W40,AL",[Endereco])
Print File ARQIMP Format("W18,AL",[CGC])+"\n"

Print File ARQIMP Spaces(15)+Format("W20,AL",[Bairro])
Print File ARQIMP Format("W20,AL",[CEP])
Print File ARQIMP Format("W25,AL",[IE])+"\n"

Print File ARQIMP Spaces(15)+Format("W20,AL",[Cidade])
Print File ARQIMP Format("W20,AL",[UF])
Print File ARQIMP Format("W25,AL",[Telefone])+"\n"

Print File ARQIMP Spaces(05)+"Operacao: "
Print File ARQIMP Chr(27)+Chr(71)
Print File ARQIMP ""+[Codigo da Destinacao]+" "+Format("W36",[Descricao da Destinacao])""

Print File ARQIMP Chr(27)+Chr(72)
Print File ARQIMP "Emissao: "+Format("W20,AL,D13",[Data de Emissao])+ "\n"

Print File ARQIMP Spaces(05)+"Vendedor: "+Format("W05,AL",[Codigo do Representante])
Print File ARQIMP Format("W25,AL",[Nome Fantasia Represent])+"\n"

Print File ARQIMP Spaces(05)+"Pedido  : "+Format("W06,AR",[Numero do Pedido])+Spaces(26)
Moveto [Numero do Pedido]
If Busca_Lookup("Numero do Pedido",[FaturaC->Numero do Pedido],"SM")
   Then Print File ARQIMP "Pedido Original: "+Format("W15,AL",REG_BUSCA_LOOKUP["Numero Pedido Origem"])+"\n"
   Else Print File ARQIMP "\n"
EndIf
UnLockRecord

Print File ARQIMP "\015"         ;Imprime 17 Caracteres por polegada

;********************* IMPRESSAO DOS ITENS ********************************
Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------"+"\n"
Print File ARQIMP Spaces(02)+"Item                                                                 Peso Liq  Un  Quantidade  Unitario        Total"+"\n"
Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------"+"\n"
Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
QUANT    = 0
TOT      = 0
CONTADOR = 0
QTEVOL   = 0
TOTPESO  = 0

While [Numero da OF]=[FaturaC->Numero da OF]
  Print File ARQIMP Spaces(02)+Format("W03,AR",StrVal([Item da OF]))
  Print File ARQIMP Spaces(01)+Format("W11,AL",[Codigo do Item])
  Print File ARQIMP Spaces(01)+Format("W49,AL",[Descricao do Item])
  Print File ARQIMP Spaces(01)+Format("W11.2,AR",[Peso Liquido])
  Print File ARQIMP Spaces(02)+Format("W03,Al",[Unidade Fiscal])
  Print File ARQIMP Format("W11,EIC",[Quantidade])
  Print File ARQIMP Format("W10.2,EIC",[Preco Unitario])
  Print File ARQIMP Format("W13.2,EIC",[Preco Total])+"\n"
  TOT   = TOT + [Preco Total]
  Skip
  If EOT() Then QuitLoop EndIf
  CONTADOR = CONTADOR + 1
EndWhile

For ITEM From CONTADOR To 11
    Print File ARQIMP "\n"
EndFor
Print File ARQIMP "---------------------------------------------------------------------------------------------------------------------"+"\n"

;********************* IMPRESSAO DOS TOTAIS **************************
Moveto "FaturaC"

Print File ARQIMP "Qtde.de Volumes."+Format("W4,EIC",[Numero de Volumes])
Print File ARQIMP Spaces(68)+"Total.............."+Format("W11.2,EIC",TOT)+"\n"
Print File ARQIMP "Peso L¡quido...."+Format("W013.3,EIC,AL",[Peso Liquido])
Print File ARQIMP Spaces(59)+"Desconto"+Format("W06.2,EIC",[Taxa de Desconto]) + "%..."
Print File ARQIMP Format("W12.2,EIC",[Valor Desconto])+"\n"
Print File ARQIMP Spaces(88)+"Frete............."+Format("W12.2,EIC",[Valor do Frete])+"\n"
Print File ARQIMP "Observa‡„o......"+Format("W70,CU,AL",[Observacao na Nota Fiscal])
Print File ARQIMP "  Total Liquido......"+Format("W11.2,EIC",[Valor Mercadoria Liquido]+[Valor do Frete])+"\n"

If SubStr([Observacao na Nota Fiscal],71,70)<>""
   Then Print File ARQIMP "                "+Format("W70,CU,AL",SubStr([Observacao na Nota Fiscal],71,70))+"\n"
EndIf   
If SubStr([Observacao na Nota Fiscal],141,70)<>""
   Then Print File ARQIMP "                "+Format("W70,CU,AL",SubStr([Observacao na Nota Fiscal],141,70))+"\n"
EndIf 
If SubStr([Observacao na Nota Fiscal],211,70)<>""
   Then Print File ARQIMP "                "+Format("W70,CU,AL",SubStr([Observacao na Nota Fiscal],211,70))+"\n"
EndIf  
If SubStr([Observacao na Nota Fiscal],281,70)<>""
   Then Print File ARQIMP "                "+Format("W70,CU,AL",SubStr([Observacao na Nota Fiscal],281,70))+"\n"
EndIf  
Print File ARQIMP "\n"

Print File ARQIMP "Cond. Pagto: "+[Descricao CondPagto]
Print File ARQIMP "   NP: "+StrVal([Numero de Parcelas])
Print File ARQIMP "   CD: "+[Composicao de Dias]
Print File ARQIMP "   FP: "+[Forma de Pagamento]+"\n"

;********************* IMPRESSAO DOS VENCIMENTOS **************************
;Print File ARQIMP "\018"
;Print File ARQIMP "\027E"
Print File ARQIMP "Vencimentos: "

Array DATA[9]
Array VALOR[9]
K=0
KV=0
Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
  K=K+1
  DATA[K]  = Format("D13",[Data])
  VALOR[K] = Format("W10.2,AR,EIC",[Valor])
  If K=9
     Then VENC()
          K=0
  EndIf
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile
If K>0
   Then VENC()
EndIf
Print File ARQIMP "\n"
Print File ARQIMP "\027F"

;************************* IMPRESSAO DO RODAPE *********************************
Print File ARQIMP Spaces(12)+"   /   /     -                                   " + "\n"
Print File ARQIMP Spaces(12)+"-------------------------------------------------" + "\n"
Print File ARQIMP Spaces(12)+"              Data e Assinatura"+"\n"
Print File ARQIMP CI_6LPP
Print File ARQIMP CI_10CPP
Print File ARQIMP "\f"
EndProc

;*******************************************************************************
;* Rotina de Impressao dos Vencimentos                                         *
;*******************************************************************************
Proc VENC()
If KV>0
   Then Print File ARQIMP Spaces(13)
EndIf
For I From 1 to K
  Print File ARQIMP DATA[I]+Spaces(02)
EndFor
Print File ARQIMP "\n"
Print File ARQIMP Spaces(13)
For I From 1 to K
  Print File ARQIMP VALOR[I]+Spaces(02)
EndFor
Print File ARQIMP "\n\n"

KV=KV+1
EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
ArqImp=PrivDir()+"Ro_0126.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)
IMPFAT()

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)

Release Vars VALOR,DATA
Release Procs IMPFAT,VENC
LIMPAGUARDE()


