;** EV_0003  *******************************************************************
;* Monta Etiqueta p/ Impressora Termica - Zebra - Interno Ecologica            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/05/2010 por Bruno Carvalho
;Ultima Alteracao: 04/02/2015 por Bruno Carvalho
;Motivo Alteracao: Adicionado ajustes p/ #0227#
;Ultima Alteracao: 03/05/2016 por Bruno Carvalho
;Motivo Alteracao: Ajustes ** Etiqueta Saltando
;Ultima Alteracao: 15/06/2016 por Bruno Carvalho 
;Motivo Alteracao: Adicionado Pega_Endereco() e ajustado dados do endere‡o

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc Pega_Endereco(PARAM)
Private PARAM

VSD_E_Endereco=""
VSD_E_Bairro  =""
VSD_E_CEP     =""
VSD_E_Cidade  =""
VSD_E_UF      =""

VSD_C_Endereco=""
VSD_C_Bairro  =""
VSD_C_CEP     =""
VSD_C_Cidade  =""
VSD_C_UF      =""    

GetRecord "\\Sistemas\\Vendas\\FaturaCC" PARAM To REG_ENTCOB
If RetVal
   Then VSD_E_Endereco=REG_ENTCOB["Endereco de Entrega"]
        VSD_E_Bairro  =REG_ENTCOB["Bairro de Entrega"]
        VSD_E_CEP     =REG_ENTCOB["CEP de Entrega"]
        VSD_E_Cidade  =REG_ENTCOB["Cidade de Entrega"]
        VSD_E_UF      =REG_ENTCOB["UF de Entrega"]

        VSD_C_Endereco=REG_ENTCOB["Endereco de Cobranca"]
        VSD_C_Bairro  =REG_ENTCOB["Bairro de Cobranca"]
        VSD_C_CEP     =REG_ENTCOB["CEP de Cobranca"]
        VSD_C_Cidade  =REG_ENTCOB["Cidade de Cobranca"]
        VSD_C_UF      =REG_ENTCOB["UF de Cobranca"] 
EndIf   
 
EndProc ;Pega_Endereco()
 
;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc Monta_Etiqueta()

Print File Arquivo "O\n"
Print File Arquivo "N\n"
Print File Arquivo "q792\n"
Print File Arquivo "Q1160\n"
Print File Arquivo "S2\n"
Print File Arquivo "D8\n"
Print File Arquivo "ZT\n"

Print File Arquivo "A750,50,1,5,1,1,N,\""+ SubStr(RazaoSocial,01,29) +"\"\n"
Print File Arquivo "A690,50,1,5,1,1,N,\""+ SubStr(RazaoSocial,30,20) +"\"\n"
Print File Arquivo "A620,50,1,4,3,1,N,\""+ SubStr(ENDERECO,01,40) + " / " + SubStr(BAIRRO,01,20)+"\"\n"
Print File Arquivo "A520,50,1,5,1,1,N,\""+ SubStr(CIDADE,01,25) + " - " + ESTADO + "\"\n"
Print File Arquivo "A460,50,1,4,3,1,N,\""+ "CEP: "+CEP+"\"\n\n"

Print File Arquivo "LO370,10,5,1110\n" ; horizonte
Print File Arquivo "LO050,10,330,5\n" ; Vertical de Baixo pra cima
Print File Arquivo "LO050,10,5,1110\n" ; horizonte
Print File Arquivo "LO050,1120,330,5\n" ; Vertical de Baixo pra cima

If SYS_CODIGO_CLIENTE="0227"
   Then Print File Arquivo "A350,050,1,4,2,1,N,\""+ "Nota Fiscal: "+"\"\n"
        ;Print File Arquivo "A350,305,1,4,2,2,N,\""+ NUMNOT +"\"\n"
        Print File Arquivo "A210,050,1,4,2,1,N,\""+ "Pedido: "+"\"\n"  
        Print File Arquivo "A210,305,1,4,2,2,N,\""+ NUMPED +"\"\n"
   Else Print File Arquivo "A350,050,1,4,2,1,N,\""+ "Transportadora: "+"\"\n"
        Print File Arquivo "A350,305,1,4,2,2,N,\""+ SubStr(RAZTRA,01,24) + "\"\n"
        Print File Arquivo "A300,305,1,4,2,2,N,\""+ SubStr(RAZTRA,25,40) + "\"\n"
        Print File Arquivo "A210,050,1,4,2,1,N,\""+ "Nota Fiscal: "+"\"\n"  
        Print File Arquivo "A210,305,1,4,2,2,N,\""+ NUMNOT +"\"\n"  
EndIf
Print File Arquivo "A120,050,1,4,2,1,N,\""+ "Volume: "+"\"\n"  
Print File Arquivo "A120,305,1,4,2,2,N,\""+ INI + "/" + FIM + "\"\n"  

Print File Arquivo "LO230,10,5,1110\n" ; horizonte
Print File Arquivo "LO140,10,5,1110\n" ; horizonte

Print File Arquivo "P1\n"

EndProc                                         

;*******************************************************************************
;* Monta Comandos p/ Impressora Termica                                        *
;*******************************************************************************
Proc Monta_Comandos()

Verifica=False
RAZTRA = ""

Arquivo="ECOLOG.EJF"
Deleta_Arquivo(Arquivo)

Fim=False
CoEdit "Answer"
Moveto [Sequencia]
Scan
    Moveto [Codigo]
    Ativa_Lookup()                  
    Moveto [Codigo]
    Locate [Answer->Codigo]
    If RetVal
       Then RazaoSocial =[Razao Social]
            ENDERECO    =[Endereco    ]
            BAIRRO      =[Bairro      ]
            CIDADE      =[Cidade      ]
            ESTADO      =[UF          ]
            CEP         =[CEP         ]

       Else RazaoSocial="1234567890123456789012345678901234567890"
            ENDERECO   ="1234567890123456789012345678901234567890"
            BAIRRO     ="12345678901234567890"
            CIDADE     ="12345678901234567890"
            ESTADO     ="12"
            CEP        ="1234567890"
     EndIf

     KeyPress "ESC"

     Moveto [Numero da OF]
     Ativa_Lookup()
     Locate [Answer->Numero da OF]
     If RetVal
       Then Pega_Endereco([Answer->Numero da OF]) 
            Verifica=True
            ENDENT  =VSD_E_Endereco
            BAIENT  =VSD_E_Bairro
            CIDENT  =VSD_E_Cidade
            ESTENT  =VSD_E_UF  
            CEPENT  =VSD_E_CEP
            RAZTRA  =[Razao Social Transport]
     EndIf

     KeyPress "ESC"
     Moveto [Codigo]

    If Verifica=True And ENDENT <> "O MESMO" And ENDENT <> "" 
       Then ENDERECO   = ENDENT
            BAIRRO     = BAIENT
            CIDADE     = CIDENT
            ESTADO     = ESTENT
            CEP        = CEPENT
    EndIF     
    
    NUMPED = [Numero do Pedido]
    NUMNOT = [Numero do Documento]
    NCOP   = [NCopias]    
    FIM    = ALINHM(StrVal(NCOP),3)

  For wi From 1 To [NCopias]
   INI = ALINHM(StrVal(wi),3)
   Monta_Etiqueta()  
  EndFor
  
EndScan
Do_It!
ClearAll

ImpriArq(Arquivo)

Sleep 1000
Deleta_Arquivo(Arquivo)

EndProc

Monta_Comandos()
Release Procs Monta_Etiqueta,Monta_Comandos
