;** TpLanc *********************************************************************
;*  PROGRAMA DE EDICAO DE TIPOS DE LANCAMENTOS                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 31/03/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 23/05/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Controla_Edicao
;Ultima Alteracao: 29/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Novo Layout de Teclas
;Ultima Alteracao: 01/01/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes SetaCorRegistro("Editando") 

;*******************************************************************************
;* Rotina para Localizar Registro                                              *
;*******************************************************************************
Proc CHAVE()
While True
  SetaCorRegistro("Editar")
  End
  Down

  Moveto [Tipo de Lancamento]

  TECLA=""
  AguardaTeclasPadrao()

  Switch
  Case RetVal=-33 : SemFuncoes()
  Case RetVal="F3": SemFicha()
  Case RetVal=-94 : MsgTeclasPadrao()
  Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
       While True
         PAGINA("TPLANC","MR")
         If EDITAR="S"
            Then CHAVE=0
                 Controla_EdicaoC()
            Else If EXCLUIR="S"
                   Then Mensagem("Exclusao de tipo n„o permitida !")
                        UnLockRecord
                   Else QuitLoop
                 EndIf
         EndIf
         SetaPosForm()
       EndWhile
  Case Retval="ESC":
       CHAVE=9
       Del
       QuitLoop

  Case RetVal="ENTER":
       CODIGO=[]
       Del
       Locate CODIGO

       If Retval
          Then CHAVE=0
          Else Mensagem(" N„o ‚ poss¡vel criar novo  Tipo de Item ! ")
               Loop
       EndIf
       If IsLockRecord()
          Then Loop
       EndIf
       Quitloop
  EndSwitch
EndWhile
EndProc

;*******************************************************************************
;* Rotina para Digitacao das Informacoes                                       *
;*******************************************************************************
Proc DIGITA()
Moveto [Conta Contabil]
While True

  TECLA=" Esc=Retornar  "

  Prompt TECLA
  SetaCorRegistro("Editando")
  Wait Field
       Until "ESC","ENTER","FIELDVIEW","F35"

  Switch
  Case Retval="ESC":
       If Field()="Conta Contabil"
         Then If QuerDesfazer("")
                 Then Undo
                      CHAVE=9
                      QuitLoop
              EndIf
       EndIf
  Case Retval="ENTER":
       If Field() = "Conta Contabil"
          Then QuitLoop
          Else Right
       EndIf

  Case Retval="FIELDVIEW" or Retval="F35":
       EDITFIELD()

  EndSwitch
EndWhile
EndProc  ; (Digita)

;*******************************************************************************
;* Rotina para controlar Edicao do registro                                    *
;*******************************************************************************
Proc Controla_EdicaoC()
DIGITA()
If RecordStatus("Locked") Then UnLockRecord EndIf         
Endproc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"
CoEdit "TPLANC"
PickForm "F"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
  Controla_EdicaoC()
EndWhile
Do_It!
ClearAll
Release Vars All
Release Procs All
