;** TransfBL  ******************************************************************
;*  Transferencia P/ Drive (Balan‡os estoque)                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 26/08/2016 por Anivel Augusto Rodrigues
;Ultima Alteracao: 18/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 05/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 24/02/2017 por Bruno Carvalho
;Motivo Alteracao: Vari vel ~VSDGNBL na ASK estava sendo passado como EXAMPLE
;Ultima Alteracao: 08/08/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado Gera_Log()    
;Ultima Alteracao: 07/06/2018 por Bruno Carvalho
;Motivo Alteracao: Adicionado/ajustado Grava_LogEx()            
;Ultima Alteracao: 03/06/2019 por Bruno Carvalho
;Motivo Alteracao: Adicionado UNIDADE_ORIGEM no nome do pacote compactado PT_TRD_XXXX_XXXXXXXX -> PT_?BL_????_???????? (De EBL p/ XBL ou VBL)

;*******************************************************************************
;* ROTINA PROCESSA  -> realiza o processamento da Transferencia                *
;*******************************************************************************
Proc PROCESSA()

AGUARDE("Aguarde, Transferindo Balan‡os")
ClearAll
Array Arquivo[6]
Arquivo[1]="Tab_InvC"
Arquivo[2]="Tab_InvI"

Cont     = 1
SetDir "\\Sistemas\\Estoque"
For Cont From 1 To 2
    AGUARDE("Aguarde, Transferindo "+Upper(Arquivo[Cont]))
    If IsTable(Arquivo[Cont])
       Then If Arquivo[Cont]<>"Tab_InvC"
               Then {Ask} {Tab_InvC}
                    Moveto [Numero do Lancamento] Example "nlanc, ~VSDGNBL.."
                    Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA.."
                    If VSDGNBL=""
                       Then Moveto [Data_Inclusao       ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                    EndIf   
                    {Ask} TypeIn Arquivo[Cont] Enter Check
                    Moveto [Numero do Lancamento] Example "nlanc"
               Else {Ask} {Tab_InvC} Check
                    Moveto [Numero do Lancamento] TypeIn "~VSDGNBL.."
                    Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA.."
                    If VSDGNBL=""
                       Then Moveto [Data_Inclusao       ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                    EndIf   
            Endif
            Do_It!
            ClearAll
            If IsTable(PASTA+Arquivo[Cont])
               Then Delete PASTA+Arquivo[Cont]
            Endif
            Create PASTA+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" PASTA+Arquivo[Cont]
            ClearAll
            
            If Arquivo[Cont]="Tab_InvC" And Not IsEmpty("Answer")
               Then Gerou_Dados=True
            EndIf     
    EndIf
EndFor

ClearAll
Limpaguarde()
EndProc

;*******************************************************************************
;* ROTINA PARA DELETAR ARQUIVOS                                                *
;*******************************************************************************
Proc Deleta_Arquivos()

Deleta_Arquivo(PASTA+"Tab_InvC.*")
Deleta_Arquivo(PASTA+"Tab_InvI.*")
Sleep 1000

Deleta_Arquivo(VSDGDRIVE+"\\Tab_InvC.*")
Deleta_Arquivo(VSDGDRIVE+"\\Tab_InvI.*")
Sleep 1000 

EndProc

;*******************************************************************************
;* Rotina para gerar o log de registro por usu rio                             *
;*******************************************************************************
Proc Gera_Log()          
;---- Gravando LOG ---------------------------------------------------
If VSDGDTINI<>BlankDate()
   Then AUX_DATA = ", periodo de "+StrVal(VSDGDTINI)+" ate "+StrVal(VSDGDTFIM)
   Else AUX_DATA = ", periodo ate "+StrVal(VSDGDTFIM)
EndIf   

If VSDGDTREF<>BlankDate()
   Then AUX_DTREF = ", data de transa‡„o em "+StrVal(VSDGDTREF)
   Else AUX_DTREF = ""
EndIf

AUX_OPCAO = "" 
If VSDGNBL<>"" Then AUX_OPCAO = AUX_OPCAO + ", Balan‡o: "+VSDGNBL EndIf

Grava_LogEx("Estoque TransfBL")  

EndProc ;Gera_Log()    

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA    =""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_NBL"           : Campo="TG_EMPRESA"   
            Case Campo="TG_DTINI"         : Campo="TG_NBL"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DTREF"         : Campo="TG_NBL"
            Case Campo="TG_DRIVES"        : Campo="TG_DTREF"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :
                         If Isblank(VSDGEMPRESA)
                            Then VSDGNOMEMP=""
                                 Campo="TG_EMPRESA"
                            Else Campo="TG_NBL"
                         EndIf

                    Case Campo="TG_NBL"     : Campo="TG_DTINI"
                         If Not Isblank(VSDGNBL)
                            Then Campo="TG_DTREF"
                            
                                 VSDGDTINI     =BlankDate()
                                 VSDGDTFIM     =BlankDate()
                         EndIf        
                    
                    Case Campo="TG_DTINI"   :
                         If Isblank(VSDGDTINI)
                            Then Mensagem("Data inicial invalida !")
                                 Campo="TG_DTINI"
                            Else Campo="TG_DTFIM"
                                 VSDGDTFIM=VSDGDTINI
                         EndIf
                    Case Campo="TG_DTFIM"   :
                         If VSDGDTFIM<VSDGDTINI
                            Then Mensagem("Data final invalida !")
                            Else Campo="TG_DTREF"
                         EndIf
                    Case Campo="TG_DTREF"   : Campo="TG_DRIVES"
                    Case Campo="TG_DRIVES"   :
                         VSDGDRIVE=ControlValue("TG_DRIVES")
                         Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTREF" :
       MSG_CAMPO="Informe a data da Transa‡„o"
  Case Campo="TG_DRIVES":
       MSG_CAMPO="Selecione o drive desejado !"
       TECLA=Chr(27)+""+Chr(26)+"=Selecionar  "
  Case Campo="TG_EMPRESA":
       MSG_CAMPO="Informe uma empresa"
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a data inicial"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

UNIDADE_ORIGEM  = SubStr(Upper(Directory()),1,1)
VSDGEMPRESA     = ""
VSDGNBL         = ""
VSDGDTREF       = BlankDate()
VSDGDTINI       = BlankDate()
VSDGDTFIM       = Today()-1

DynArray Array_Drives[]
SysInfo Drives To Array_Drives
VSDGDRIVE=SubStr(Directory(),1,2)

While True
  ShowDialog "Exporta‡„o de Balan‡os [Estoque]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 13 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
                                                                                                                    
    Label  @ 02,00 "Balan‡o"  For "TG_NBL"          
    Accept @ 03,01 Width 09 "A6"  Picture "!*!" Tag "TG_NBL" To VSDGNBL
    Accept @ 03,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMNBL" To VSDGNOMNBL

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 06,00 "Data Transa‡„o" For "TG_DTREF"         
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Label  @ 00,35 "Drives:" For "TG_DRIVES"
    PickDynArrayIndex @ 01,36 Height 4 width 33
     Columns 7
      Array_Drives
       Tag "TG_DRIVES"
        To VSDGDRIVE

    Pushbutton @ 09,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  
  If IsBlank(VSDGEMPRESA) Or
     IsBlank(VSDGDTREF)
     Then Mensagem("Informe os dados corretamente !")
          Loop
  EndIf

  Gera_Log()
  DATAREF=AlinhM(StrVal(Day(VSDGDTREF)),2)+AlinhM(StrVal(Month(VSDGDTREF)),2)+SubStr(AlinhM(StrVal(Year(VSDGDTREF)),4),3,2)
  
  Aguarde("Aguarde, verificando diret¢rio")
  PASTA = PrivDir()+"TMP"
  If DirExists(PASTA)=0
     Then Cria_pasta(PASTA)
  EndIf
  PASTA = PASTA + "\\"
         
  If VSDGEMPRESA="" 
     Then CODEMP="0000" 
     Else CODEMP=VSDGEMPRESA
  EndIf
  
  ARQ_ARJ="PT_"+UNIDADE_ORIGEM+"BL"+"_"+CODEMP+"_"+
          AlinhM(StrVal(Year(VSDGDTREF)),4) +
          AlinhM(StrVal(Month(VSDGDTREF)),2)+
          AlinhM(StrVal(Day(VSDGDTREF)),2)  +
          ".ARJ"

  Aguarde("Aguarde, excluindo arquivos temporarios")
  Deleta_Arquivos()
  
  FileWrite PrivDir()+"fundel.txt"  From  "DELT|"+VSDGDRIVE+"\\"+ARQ_ARJ+"\n"
  ExecVisecf(PrivDir()+"fundel.txt","")
  Sleep 2000
  
  Gerou_Dados=False  
  Processa()           

  If Not Gerou_Dados
     Then Deleta_Arquivos()
          Mensagem("NÆo existe(m) balan‡o(s) conforme sele‡Æo !// //Verificar Empresa, Data Referente !//Pacote nÆo foi gerado !")
     Else Aguarde("Aguarde, compactando pacote de transa‡„o p/ "+ARQ_ARJ)
           
          FileWrite PrivDir()+"funcmd.txt" From "CMD|"+"c:\\vise\\Varj.exe a "+PASTA+ARQ_ARJ+" "+PASTA+"TAB_INV*.*"+"\n"
          ExecVisecf(PrivDir()+"funcmd.txt","")
          Sleep 1000
          
          Aguarde("Aguarde, copiando arquivo para a unidade "+VSDGDRIVE)
          FileWrite PrivDir()+"funcop.txt" From "COP|"+PASTA+ARQ_ARJ+"|"+VSDGDRIVE+"\\"+ARQ_ARJ+"\n" 
          ExecVisecf(PrivDir()+"funcop.txt","")
          Sleep 1000
              
          ;---- Excluindo Arquivo Temporario -----------------------------------
          Aguarde("Aguarde, excluindo arquivos temporarios")
          FileWrite PrivDir()+"fundel.txt" From "DELT|"+PASTA+ARQ_ARJ+"\n"
          ExecVisecf(PrivDir()+"fundel.txt","")
          Sleep 1000
          
          Deleta_Arquivos()
          
          ;---- Excluindo Arquivo de Retorno -----------------------------------
          Aguarde("Aguarde, finalizando o processo")
          FileWrite        PrivDir()+"funcao.txt"  From  "DELT|"+PrivDir()+"fundel.ret"+"\n"
          FileWrite Append PrivDir()+"funcao.txt"  From  "DELT|"+PrivDir()+"funcmd.ret"+"\n"
          FileWrite Append PrivDir()+"funcao.txt"  From  "DELT|"+PrivDir()+"funcop.ret"+"\n"
          FileWrite Append PrivDir()+"funcao.txt"  From  "DELT|"+PrivDir()+"funren.ret"+"\n"
          ExecVisecf(PrivDir()+"funcao.txt","")
          
          MSG="Pacote de transa‡„o gerado !// //"
          MSG=MSG+"Arquivo em "+VSDGDRIVE+"\\"+ARQ_ARJ+"// //"
          MSG=MSG+"Verifique !"
          Mensagem(MSG)
  EndIf
 EndWhile
ClearAll
Release Vars All
Release Procs All
