;** PAISES *********************************************************************
;*  PROGRAMA DE CADASTRO DE PAISES                                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 29/12/2003 por Karen Lauar Nery
;Ultima Alteracao: 27/05/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 02/12/2009 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo no Script
;Ultima Alteracao: 29/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Novo Layout de Teclas
;Ultima Alteracao: 01/01/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes SetaCorRegistro("Editando") 

;*******************************************************************************
;* Rotina para Localizar Registro                                              *
;*******************************************************************************
Proc CHAVE()

While True
  SetaCorRegistro("Editar")

  End
  Down
  Moveto [Pais]
  
  TECLA=""
  AguardaTeclasPadrao()

  Switch
  Case RetVal=-33 : SemFuncoes()
  Case RetVal="F3": SemFicha()
  Case RetVal=-94 : MsgTeclasPadrao()
  Case RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
       While True
         PAGINA("PAISES","MR")
         If EDITAR="S"
            Then CHAVE=0
                 Controla_EdicaoC()
            Else If EXCLUIR="S"
                    Then If QuerExcluir("")
                            Then DEL
                            Else UnLockRecord
                         EndIf
                    Else QuitLoop
                 EndIf
         EndIf
         SetaPosForm()
       EndWhile
  Case Retval="ESC":
       CHAVE=9
       Del
       QuitLoop
  Case RetVal="ENTER":
       If IsBlank([])
          Then Loop
       EndIf
       CODIGO=[]
       Del
       Locate CODIGO
       If Retval
          Then CHAVE=0
          Else CHAVE=1
               End Down
               [Pais]=CODIGO
       EndIf
       If IsLockRecord()
          Then If CHAVE=1 Then Del EndIf
               Loop
       EndIf
       Quitloop
  EndSwitch
EndWhile
EndProc

;*******************************************************************************
;* Rotina para Digitacao das Informacoes                                       *
;*******************************************************************************
Proc DIGITA()
Moveto [Sigla_Pais]
While True

  TECLA=" Esc=Retornar  "

  If CHAVE=0
     Then TECLA=TECLA+"Del=Excluir  "
  EndIf

  MSGCAMPO=""
  Switch
     Case Field()="Codigo_Pais"       : MSGCAMPO="C¢digo SISCOMEX"
  EndSwitch

  Prompt TECLA
  SetaCorRegistro("Editando")
  Wait Field
       Message MSGCAMPO
       Until "ESC","ENTER","DEL","FIELDVIEW","F35"

  Switch
  Case Retval="ESC":
       Switch
       Case Field()="Pais" :
            If QuerDesfazer("")
                   Then If CHAVE=1
                          Then Del
                          Else If RecordStatus("Modified")
                                  Then Undo
                               EndIf
                       EndIf
                       CHAVE=9
                       QuitLoop
               EndIf
       Case Field()="Sigla_Pais" : Moveto[Pais]
       Case Field()="Codigo_Pais": Moveto[Sigla_Pais]
       Otherwise : Left           
       EndSwitch             
                  
  Case Retval="ENTER":
        If IsBlank([Pais])
          Then Loop
        EndIf
       Switch
        Case Field() = "Sigla_Pais" : Right
        Case Field() = "Codigo_Pais": Quitloop
        Otherwise : Right
       EndSwitch
  Case Retval="FIELDVIEW" or Retval="F35":
       EDITFIELD()
  Case Retval="DEL":
       If CHAVE=0
          Then If QuerExcluir("")
                  Then DEL
                       QuitLoop
               EndIf
       EndIf
  EndSwitch
EndWhile
EndProc  ; (Digita)

;*******************************************************************************
;* Rotina para controlar Edicao do registro                                    *
;*******************************************************************************
Proc Controla_EdicaoC()
DIGITA()
If RecordStatus("Locked") Then UnLockRecord EndIf         
EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"

CoEdit "PAISES"
PickForm "F"

While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
  Controla_EdicaoC()
EndWhile
Do_It!
ClearAll
Release Vars All
Release Procs All
