;** Rm_0100 ********************************************************************
;*  Emissao do Extrato/Programacoes de Corte                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/09/2010 por Karina

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

Empty("Rm_0201")

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
{Ask} {Cfacc}
Moveto [Numero_Corte          ] Example "num" TypeIn ", ~VSDGCORTE.."
Moveto [Codigo da Empresa     ] Example "cemp" TypeIn ", ~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa ] Example "nemp"
Moveto [Situacao_Programacao  ] Example "sp"
Moveto [Data_Programacao      ] Example "dp"
If IsBlank(VSDGCORTE)
   Then TypeIn ", >=~VSDGDTINI,<=~VSDGDTFIM"
EndIf
{Ask} {CfacRI}
Moveto [Numero_Corte           ] Example "num"
Moveto [Codigo do Item         ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Moveto [Tipo do Item           ] Example "tite"
Moveto [Referencia             ] Example "ref"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Quantidade Programada  ] Example "qtd"
Moveto [Unidade Fiscal         ] Example "un"
{Ask} {Rm_0201} TypeIn "Fast Insert"
Moveto [Numero_Programacao_Corte ] Example "num"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Nome Fantasia Empresa    ] Example "nemp"
Moveto [Situacao_Programacao     ] Example "sp"
Moveto [Data_Programacao         ] Example "dp"
Moveto [Numero_Producao_Corte    ] Example "num"
Moveto [Data_Producao            ] Example "dp"
Moveto [Tipo Movimento           ] TypeIn "P"
Moveto [Codigo do Item           ] Example "ITEN"
Moveto [Tipo do Item             ] Example "tite"
Moveto [Referencia               ] Example "ref"
Moveto [Descricao do Item        ] Example "dite"
Moveto [Quantidade               ] Example "qtd"
Moveto [Unidade Fiscal           ] Example "un"
Do_It!
ClearAll

{Ask} {Rm_0201}
Moveto [Numero_Programacao_Corte ] Check
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
{Ask} {Answer}
Moveto [Numero_Programacao_Corte ] Example "nprog"
{Ask} {Cfacc}
Moveto [Numero_Corte          ] Example "nprog"
Moveto [Codigo da Empresa     ] Example "cemp"
Moveto [Nome Fantasia Empresa ] Example "nemp"
Moveto [Situacao_Programacao  ] Example "sp"
Moveto [Data_Programacao      ] Example "dprog"
{Ask} {Pcfacc}
Moveto [Numero_Producao_Corte    ] Example "num"
Moveto [Numero_Programacao_Corte ] Example "nprog"
Moveto [Data_Producao            ] Example "dp"
{Ask} {PcfacRI}
Moveto [Numero_Producao_Corte  ] Example "num"
Moveto [Codigo do Item         ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Moveto [Tipo do Item           ] Example "tite"
Moveto [Referencia             ] Example "ref"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Quantidade Produzida   ] Example "qtd"
Moveto [Unidade Fiscal         ] Example "un"
{Ask} {Rm_0201} TypeIn "Fast Insert"
Moveto [Numero_Programacao_Corte ] Example "nprog"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Nome Fantasia Empresa    ] Example "nemp"
Moveto [Situacao_Programacao     ] Example "sp"
Moveto [Data_Programacao         ] Example "dprog"
Moveto [Numero_Producao_Corte    ] Example "num"
Moveto [Data_Producao            ] Example "dp"
Moveto [Tipo Movimento           ] TypeIn "R"
Moveto [Codigo do Item           ] Example "ITEN"
Moveto [Tipo do Item             ] Example "tite"
Moveto [Referencia               ] Example "ref"
Moveto [Descricao do Item        ] Example "dite"
Moveto [Quantidade               ] TypeIn "_qtd*-1"
Moveto [Unidade Fiscal           ] Example "un"
Do_It!
ClearAll

{Ask} {Rm_0201} Check
Do_It!
ClearAll


EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_CORTE"         : Campo="TG_EMPRESA"
            Case Campo = "TG_ITEM"           : Campo = "TG_CORTE"
            Case Campo = "TG_REFERENCIA"     : Campo = "TG_ITEM"
            Case Campo="TG_DTINI"         : Campo="TG_REFERENCIA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_CORTE"
                    Case Campo="TG_CORTE"      :
                         If Not ISBlank(VSDGCORTE)
                            Then VSDGDTINI  =BlankDate()
                                 VSDGDTFIM  =BlankDate()
                                 Campo="YES"
                            Else Campo="TG_ITEM"
                         EndIf
                    Case Campo = "TG_ITEM"     : Campo = "TG_REFERENCIA"
                    Case Campo = "TG_REFERENCIA" : Campo = "TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CORTE"      :
     MSG_CAMPO="Em Branco = Todas" 
  Case Campo="":
     MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  =""
VSDGCORTE    =""
VSDGDTINI    =BlankDate()
VSDGDTFIM    =BlankDate()
VSDGTPITEM  =""
VSDGREFERENCIA  = ""

While True
  ShowDialog "Extrato das Programa‡”es de Corte" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 13 Width 65

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Corte"  For "TG_CORTE"
    Accept @ 03,01 Width 09 "A6"  Picture "#*#" Tag "TG_CORTE" To VSDGCORTE
    
    Label  @ 04,00 "Item"  For "TG_ITEM"
    Accept @ 05,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 05,15 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM"  To VSDGNOMITEM

    Label  @ 04,48 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 05,49 Width 13 "A10" Picture "#*#" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 06,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 07,00 "de" For "TG_DTINI"
    Accept @ 07,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,17 "at‚" For "TG_DTFIM"
    Accept @ 07,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 09,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGCORTE) And VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")

  Seleciona()

  If IsEmpty("Rm_0201")
     Then MENSAGEM("N„o existem registros a processar")
          Delete "Answer"
          Loop
  EndIf

  CopyReport "\\Sistemas\\Faccao\\Rm_0201" "R" "Answer" "R"

  IMPRIREL("Answer","R")

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All

