;** RM_0500 ********************************************************************
;*  ImpressÆo de Recibos de Recebimento                                        *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 13/12/2013 por Andrey Fillipe
;Ultima Alteracao: 17/12/2013 por Andrey Fillipe 
;Motivo Alteracao: InclusÆo de op‡Æo de data
;Ultima Alteracao: 22/06/2016 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes recibo sys_Codigo_Cliente floren‡a tecidos
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog    
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT
;Ultima Alteracao: 29/05/2017 por Rafael Matos
;Motivo Alteracao: Ajustes SYS_CODIGO_CLIENTE"0377"
;Ultima Alteracao: 02/09/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado PARAM_IMPRESSAO ao chamar script de recibo #0377# (Ajustado tamb‚m p/ processo individual)
;Ultima Alteracao: 06/09/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado processo nos recibos de impressÆo -> "RP_000B" Ou "RP_0329C"
;Ultima Alteracao: 01/10/2018 por Kamila Gomes
;Motivo Alteracao: Ajustes campos que nÆo existem na tabela RM_0020
;Ultima Alteracao: 14/05/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes usar conta da baixa
;Ultima Alteracao: 15/05/2019 por Bruno Carvalho
;Motivo Alteracao: Ajustes Processa() -> "Answer" recebendo [Codigo da Conta] e [Descricao da Conta]
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento 
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 03/06/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes #0092 Imprime()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll
 
{Ask} {Duplic} Check
Moveto [Numero do Lancamento  ] Example "NLanc"
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo do Destinatario] TypeIn "~VSDGDESTINAT.."
If VSDGTPDATA="2"
   Then Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
EndIf
Switch
  Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
  Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
EndSwitch 

;;Campos adicionados depois na Duplic, para nÆo dar erro de estrutura com RM_0020
Moveto [Tem Rateio             ] Check
Moveto [Comissao_Estornada     ] Check
Moveto [Data_Comissao_Estornada] Check
Moveto [TaxaComissao           ] Check

{Ask} {Dupbaixa}
Moveto [Numero do Lancamento] Example "NLanc"
Moveto [Sequencia da Baixa  ] Check
Moveto [Codigo da Conta     ] TypeIn "~VSDGCONTA.."
If VSDGTPDATA="1"
   Then Moveto [Data do Pagamento   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
EndIf
Do_It!
ClearAll

Adiciona_campo("Answer","Data do Pagamento(D),"+
                        "Valor do Recebimento($),"+
                        "Valor do Juros($),"+
                        "Valor do Desconto($)")
ClearAll

EndProc ;SELECIONA()

;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************************************
If VSDGEMPRESA="0000"
   Then {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

{Ask} {Answer} TypeIn "Fast"
Moveto [Data de Vencimento] TypeIn "ChangeTo Blank"
Down
Moveto [Saldo do Documento] TypeIn "ChangeTo Blank"
Do_It!
ClearAll

View "DupBaixa"
Coedit "Answer"
Scan
  Moveto "DupBaixa"
  Moveto [Numero do Lancamento]
  Locate [Answer->Numero do Lancamento],[Answer->Sequencia da Baixa]
  If RetVal
     Then Moveto "Answer"
          [Data do Pagamento   ] = [DupBaixa->Data do Pagamento   ]
          [Valor do Recebimento] = [DupBaixa->Valor do Recebimento]
          [Valor do Juros      ] = [DupBaixa->Valor do Juros      ]
          [Valor do Desconto   ] = [DupBaixa->Valor do Desconto   ]
          [Codigo da Conta     ] = [DupBaixa->Codigo da Conta     ]
          [Descricao da Conta  ] = [DupBaixa->Descricao da Conta  ]
  EndIf
  Moveto "Answer"
EndScan
Do_It!
ClearAll

{Tools} {Copy} {JustFamily} {\\Base\\Sistemas\\Ctarec\\RM_0020} {Answer} {Replace}
Sort "Answer" On "Nome Fantasia EmitDest","Data de Vencimento","Tipo do Documento","Numero do Documento"

EndProc ;Processa()

;*******************************************************************************
;* Seleciona Registros para Carta de Cobranca                                  *
;*******************************************************************************
Proc SELECIONAI()

Edit "Answer"
SetHighLight Current Record 23 Field 31
{Image} {KeepSet}
Do_It!

CoEdit "Answer"
PickForm "F"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
EndWhile
Do_It!
ClearAll

EndProc ;SELECIONAI()

;*******************************************************************************
;* Seleciona Titulos para Baixa
;*******************************************************************************
Proc CHAVE()
While True
  End
  Down
  Moveto [Numero do Lancamento]
  While True

    Prompt " Esc=Sair  F6=Imprimir  F7=Paginar  "

    Wait Field
         Until "ESC","ENTER","F7","HOME","UP","PGUP","F6"
    Switch
    Case RetVal="F6":
         Del
         If PARAM_RELAT="RP_0000B" Or PARAM_RELAT="RP_0329C" 
            Then IMPRIME(PARAM_RELAT)
            Else ;PARAM_RELAT = Nem todos os scripts estÆo ajustado p/ BxCxAuto/RM_0500
                 IMPRIME("")
         EndIf 
    Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
         CHAVE=0
         While True
           PAGINA("Answer","MR")
           If EDITAR="S"
              Then Mensagem("Altera‡„o n„o permitida !")
                   UnLockRecord
              Else If EXCLUIR="S"
                      Then CONFIRMA()
                           If OK="S"
                              Then DEL
                              Else UnLockRecord
                           EndIf
                      Else QuitLoop
                   EndIf
           EndIf
         EndWhile
         QuitLoop
    Case Retval="ESC":
         CHAVE=9
         Return
    EndSwitch
  EndWhile
EndWhile        

EndProc ;CHAVE()

;*******************************************************************************
;* Rotina De Impressao                                                         *
;*******************************************************************************
Proc IMPRIME(PARAM)
Private MODCARTA,PARAM

VSDGNPARCELAS=""
VSDGNDIAS=""

MSGDISPOSITIVO="Recibo"
DispositivoI("RCB")

If OK="" 
   Then Return
EndIf

LimpaRodape(0)
Do_It!
ClearAll                      

ArqImp=PrivDir()+"Recibo.txt"
Deleta_Arquivo(Arqimp)
Sleep 700                                                                  
                 
Switch
  Case PARAM <>"" : PARAM_IMPRESSAO = "RM_0500"
                    Play PARAM_RELAT                  ;Mostra titulos em aberto e as baixas realizadas  
  OtherWise       :                                                 
        CodCli    = "***"
        CONTBAIXA = 0
        CodEmp    = "***"
        
        View "\\Sistemas\\Cadastro\\Destinat"
        View "Duplic"
        View "DupBaixa"
        View "Answer"
        Scan
         Moveto "DupBaixa"
         Moveto [Numero do Lancamento]
         Locate [Answer->Numero do Lancamento]
         If RetVal
            Then While [Numero do Lancamento]=[Answer->Numero do Lancamento]
                   RECB_AUT = True
                   Moveto "Duplic"
                   Moveto [Numero do Lancamento]
                   Locate [Answer->Numero do Lancamento]
                   If RetVal 
                      Then ULTIMA_BAIXA=True
                           cliant="****"
                           
                           If CodEmp<>[Duplic->Codigo da Empresa]
                              Then CodEmp =[Duplic->Codigo da Empresa]
                                   CODIGOEMP     =""
                                   RAZAOSOCIALEMP=""
                                   ENDERECOEMP   =""
                                   CNPJEMP       =""
                                        
                                   GetRecord "\\Sistemas\\Cadastro\\Destinat" CodEmp to REGEMP
                                   If Retval
                                      Then CODIGOEMP     =CodEmp
                                           RAZAOSOCIALEMP=REGEMP["Razao Social"]
                                           ENDERECOEMP   =REGEMP["Endereco"]+ ","+Spaces(1)+
                                                          REGEMP["Bairro"]
                                           CIDADEEMP     =REGEMP["Cidade"] +"/"+
                                                          REGEMP["UF"]
                                           CNPJEMP       =REGEMP["CGC"]               
                                   EndIF                         
                           EndIF         
                           If CodCli<>[Answer->Codigo do Destinatario]
                              Then CodCli=[Answer->Codigo do Destinatario]
                                   
                                   ENDERECO=""
                                   BAIRRO  =""
                                   CIDADE  =""
                                   TELEFONE=""
                                   RG      =""
                                   CGC     =""
        
                                   Moveto "\\Sistemas\\Cadastro\\Destinat"
                                   Moveto [Codigo]
                                   Locate [Duplic->Codigo do Destinatario]
                                   If RetVal
                                     Then ENDERECO = [Endereco ]                
                                          BAIRRO   = [Bairro   ]
                                          CIDADE   = [Cidade   ]
                                          TELEFONE = [Telefone ]
                                          RG       = [RG       ]
                                          CGC      = [CGC      ]
                                   EndIf
                           EndIf    
                           Moveto "DupBaixa"   
                           CONTBAIXA = CONTBAIXA + 1
                           If CONTBAIXA = 3 
                              Then CONTBAIXA = 0
                                   SALTA_PAGINA = True
                              Else SALTA_PAGINA = False
                           EndIf    
                           switch
                             case SYS_CODIGO_CLIENTE="0000" : Play "RP_0000"
                             case SYS_CODIGO_CLIENTE="0373" : Play "RP_0373"
                             case SYS_CODIGO_CLIENTE="0092" or
                                  SYS_CODIGO_CLIENTE="0377" : PARAM_IMPRESSAO = "RM_0500"
                                                              Play "RP_0377"
                             otherwise                      : Play "RP_0310" 
                           endswitch                                                          
                           
                   EndIf
                   Moveto "DupBaixa"
                   Skip
                   If Eot() Then QuitLoop EndIf
                 EndWhile
          EndIf            
          Moveto "Answer"
        EndScan
EndSwitch
ClearAll

ImpriArq(ArqImp)

CoEdit "Answer"
PickForm "F"     
End Down
LIMPAGUARDE()

EndProc ;IMPRIME()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DESTINAT"      : Campo="TG_CONTA"
            Case Campo="TG_TPPAGTO"       : Campo="TG_DESTINAT"
            Case Campo="TG_TPDATA"        : Campo="TG_TPPAGTO"
            Case Campo="TG_DTINI"         : Campo="TG_TPDATA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"            
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"  : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="TG_TPDATA"
                    Case Campo="TG_TPDATA"     : Campo="TG_DTINI"
                         VSDGTPDATA=ControlValue("TG_TPDATA")
                         Switch
                           Case VSDGTPDATA="2" : VSDGNOMTPDATA="DATA DE VENCIMENTO"
                           otherwise           : VSDGTPDATA="1"
                                                 VSDGNOMTPDATA="DATA DO RECEBIMENTO"
                         EndSwitch
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CONTA":
     MSG_CAMPO="Informe uma conta tipo CAIXA !"
  Case Campo="TG_TPDATA" :
       MSG_CAMPO="1=Data do Recebimento  2=Data de Vencimento"
  Case Campo="":            
       MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
If Not IsAssigned(SYS_CHAPA_USUARIO)   Then SYS_CHAPA_USUARIO=""   EndIf

VSDGEMPRESA =""
VSDGCONTA   =""
VSDGTPPAGTO =""
VSDGDESTINAT=""   
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
SYS_VALOR()

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPPAGTO]") 

While True
  ShowDialog "Recibo de Recebimento" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"   
   @ 05,12   Height 17 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
                               
    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 06,00 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO
                                                                                                          
    Label  @ 08,00 "Op‡äes de Datas" For "TG_TPDATA"
    Accept @ 09,04 Width 04 "A1"  Picture "1,2"  Tag "TG_TPDATA"     To VSDGTPDATA
    Accept @ 09,09 Width 25 "A20" Picture "!*!"  Tag "TG_NOMTPDATA" To VSDGNOMTPDATA
                                                                                                          
    Label  @ 10,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Pushbutton @ 13,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 13,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  PARAM_RELAT=""  
  If VSDGEMPRESA2<>""
     Then GetRecord "\\Sistemas\\CtaRec\\P_Duplic" VSDGEMPRESA2 to REGP_DUPLIC
          If Retval
             Then PARAM_RELAT = REGP_DUPLIC["Impressao_Recibo"]
          EndIf
  EndIf         

  AGUARDE("Aguarde, Selecionando registros")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf

  Processa()
  SELECIONAI()
  
  Echo Normal
  Echo Off

  ClearAll
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
