;** Voltames *******************************************************************
;*  Programa p/ Restauracao de Meses Fechados                                  *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 14/11/1997 por Anivel Augusto Rodrigues
;Ultima Alteracao: 21/10/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: SaveTables
;Ultima Alteracao: 15/08/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Run
;Ultima Alteracao: 17/12/2009 por Cleber Alves
;Motivo Alteracao: Volta mes "TITRAT"
;Ultima Alteracao: 03/03/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Layout                   
;Ultima Alteracao: 13/08/2019 por Kamila Gomes
;Motivo Alteracao: Adicionado BXAUTC()

;*******************************************************************************
; Titulos/TitBaixa/TitNota/TitCheq                                             *
;*******************************************************************************
Proc TITULOS()
ClearAll
MSG_AGUARDE="Aguarde, restaurando titulos "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(6,1))
If IsTable("Titulos")
   Then {Ask} TypeIn "\\Sistemas\\CtaPag\\Titulos" Enter
        Moveto [Numero do Lancamento] Example "lanc"
        {Ask} {Titulos} Check
        Moveto [Numero do Lancamento] Example "lanc"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        Do_It!
        ClearAll

        If Not IsEmpty("Answer")
           Then MSG_LANCDUP()
                Return
        EndIf

        {Ask} {Titulos} Check
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        Do_It!
        ClearAll
        If IsEmpty("Answer")
           Then Mensagem("Mˆs sem movimenta‡„o p/ contas a pagar !")
                Return
           Else Rename "Answer" "TitTemp"
                ClearAll
        EndIf
   Else Mensagem("Tabela [Titulos] n„o encontrada !")
        Return
EndIf

Aguarde(MSG_AGUARDE+Barra(6,2))
If IsTable("Titulos") And
   IsTable("TitBaixa")
   Then {Ask} {Titulos}
        Moveto [Numero do Lancamento] Example "LANCTO"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        {Ask} {TitBaixa} Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","TitBaixa")
EndIf

Aguarde(MSG_AGUARDE+Barra(6,3))
If IsTable("Titulos") And
   IsTable("TitCheq")
   Then {Ask} {Titulos}
        Moveto [Numero do Lancamento] Example "LANCTO"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        {Ask} {TitCheq} Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","TitCheq")
EndIf

Aguarde(MSG_AGUARDE+Barra(6,4))
If IsTable("Titulos") And
   IsTable("TitNota")
   Then {Ask} {Titulos}
        Moveto [Numero do Lancamento] Example "LANCTO"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        {Ask} {TitNota} Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","TitNota")
EndIf
Aguarde(MSG_AGUARDE+Barra(6,5))
If IsTable("Titulos") And
   IsTable("TitRat")
   Then {Ask} {Titulos}
        Moveto [Numero do Lancamento] Example "LANCTO"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        {Ask} {TitRat} Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","TitRat")
EndIf
Aguarde(MSG_AGUARDE+Barra(6,6))
Add_Sub_Rest_Tabela("TitTemp","Titulos")

EndProc

;*******************************************************************************
; AltContC/AltContI                                                            *
;*******************************************************************************
Proc ALTCONT()
ClearAll
MSG_AGUARDE="Aguarde, restaurando alt. contas "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(3,1))
If IsTable("AltContC")
   Then {Ask} TypeIn "\\Sistemas\\CtaPag\\AltContC" Enter
        Moveto [Numero do Lote      ] Example "lanc"
        {Ask} {AltContC} Check
        Moveto [Numero do Lote      ] Example "lanc"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        Do_It!
        ClearAll

        If Not IsEmpty("Answer")
           Then MSG_LANCDUP()
                Return
        EndIf

        {Ask} {AltContC} Check
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        Do_It!
        ClearAll
        If IsEmpty("Answer")
           Then Return
           Else Rename "Answer" "ContCTmp"
                ClearAll
        EndIf
   Else Return
EndIf

Aguarde(MSG_AGUARDE+Barra(3,2))
If IsTable("AltContC") And
   IsTable("AltContI")
   Then {Ask} {AltContC}
        Moveto [Numero do Lote] Example "LANCTO"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        {Ask} {AltContI} Check
        Moveto [Numero do Lote] Example "LANCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","AltContI")
EndIf

Aguarde(MSG_AGUARDE+Barra(3,3))
Add_Sub_Rest_Tabela("ContCTmp","AltContC")

EndProc

;*******************************************************************************
; BxAutc/BxAuti/BxAutT                                                         *
;*******************************************************************************
Proc BXAUTC()
ClearAll
MSG_AGUARDE="Aguarde, Baixa aut. contas "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(3,1))
If IsTable("BxAutC")
   Then {Ask} TypeIn "\\Sistemas\\CtaPag\\BxAutC" Enter
        Moveto [Numero do Lote      ] Example "lanc"
        {Ask} {BxAutC} Check
        Moveto [Numero do Lote      ] Example "lanc"
        Do_It!
        ClearAll

        If Not IsEmpty("Answer")
           Then MSG_LANCDUP()
                Return
        EndIf

        {Ask} {BxAutC} Check
        Do_It!
        ClearAll
        If IsEmpty("Answer")
           Then Return
           Else Rename "Answer" "BxAcTmp"
                ClearAll
        EndIf
   Else Return
EndIf

Aguarde(MSG_AGUARDE+Barra(3,2))
If IsTable("BxAutC") And
   IsTable("BxAutI")
   Then {Ask} {BxAutC}
        Moveto [Numero do Lote] Example "LANCTO"
        {Ask} {BxAutI} Check
        Moveto [Numero do Lote] Example "LANCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","BxAutI")
EndIf

Aguarde(MSG_AGUARDE+Barra(3,2))
If IsTable("BxAutC") And
   IsTable("BxAutT")
   Then {Ask} {BxAutC}
        Moveto [Numero do Lote] Example "LANCTO"
        {Ask} {BxAutT} Check
        Moveto [Numero do Lote] Example "LANCTO"
        Do_It!
        ClearAll
        Add_Sub_Rest_Tabela("Answer","BxAutT")
EndIf

Aguarde(MSG_AGUARDE+Barra(3,3))
Add_Sub_Rest_Tabela("BxAcTmp","BxAutC")

EndProc

;*******************************************************************************
;* Rotina Add/Subtract/Reestruct                                               *
;*******************************************************************************
Proc Add_Sub_Rest_Tabela(TABORIG,TABDEST)
Private TABORIG,TABDEST

Add TABORIG Diretorio+TABDEST ClearImage
SaveTables

Subtract TABORIG TABDEST ClearImage
SaveTables

{Modify} {Restructure} TypeIn TABDEST Enter Do_It! ClearImage
Delete TABORIG
SAVETABLES
EndProc

;*******************************************************************************
;* Rotina Mensagem Lancamentos Duplicados                                      *
;*******************************************************************************
Proc MSG_LANCDUP()
MSG=    "Os lan‡amentos do mˆs selecionado n„o ser„o restaurados !//"
MSG=MSG+"Existem lan‡amentos em aberto com a mesma numera‡„o a restaurar !//"
MSG=MSG+"Verificar quais os lan‡amentos duplicados Ok !//"
MSG=MSG+"A restaura‡„o dos lan‡amentos ser  cancelada !// //"
MSG=MSG+" Observe abaixo em que rotina ocorreu esta duplica‡Æo !"
Mensagem(MSG)
EndProc

;*******************************************************************************
;* Rotina Bloqueia Tabelas da Pasta                                            *
;*******************************************************************************
Proc BloqueiaTabelas(Pasta)
Private MSG, Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then Lock Pasta+Array_Tabelas[i] FL
          If Not RetVal
             Then MSG="O usu rio "+Upper(ErrorUser())+" esta usando o Sistema !// //"
                  MSG=MSG+Completa("- Contact -lo para liberar o Sistema;",40," ")+"//"
                  MSG=MSG+Completa("- Esta rotina ser  abortado.",40," ")+"// //"
                  MSG=MSG+"Execute esta rotina novamente para que//"
                  MSG=MSG+"a mesma seja concluida corretamente !"
                  Mensagem(MSG)
                  Return False
          EndIf
  EndIf
EndFor

Return True
EndProc

;*******************************************************************************
;* Rotina Desbloqueia Tabelas da Pasta                                         *
;*******************************************************************************
Proc DesbloqueiaTabelas(Pasta)
Private Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then UnLock Pasta+Array_Tabelas[i] FL
  EndIf
EndFor

EndProc

;*******************************************************************************
;* Rotina Monta Lista de Tabelas a Processar                                   *
;*******************************************************************************
Proc ListadeTabelas()
If IsAssigned(Array_Tabelas)
   Then Release Vars Array_Tabelas
EndIf
DynArray Array_Tabelas[]

Array_Tabelas[01]="Titulos"
Array_Tabelas[02]="TitBaixa"
Array_Tabelas[03]="TitNota"
Array_Tabelas[04]="TitCheq"
Array_Tabelas[05]="AltContC"
Array_Tabelas[06]="AltContI"
Array_Tabelas[07]="TitRat"
Array_Tabelas[08]="BxAutC"
Array_Tabelas[09]="BxAutI"
Array_Tabelas[10]="BxAutT"
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DIRETORIOS"    : Campo="TG_EMPRESA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_DIRETORIOS"
                    Case Campo="TG_DIRETORIOS" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="":
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""

While True
  Diretorio="\\Sistemas\\CtaPag\\"
  Diretorios_Fechames(Diretorio)

  ShowDialog "Restaura‡Æo mensal [ Contas a pagar ]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 04,17   Height 19 Width 75

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 0,09 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 0,16 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    PickDynArray @2,01 Height 12 width 69
     Columns 7
      Array_Diretorios
       Tag "TG_DIRETORIOS"
        To ArrayElement
    Label @ 01,00 "Ano_Mes em aberto"  For "TG_DIRETORIOS"

    Pushbutton @ 15,24 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,38 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If DynArraySize(Array_Diretorios)<1
     Then Mensagem("Sem Pasta fechames !")
          Loop
  EndIf

  ANO_MES=Array_Diretorios[ArrayElement]

  Diretorio="\\Sistemas\\CtaPag\\"
  DiretorioFechames=Diretorio+"Fechames\\"+ANO_MES+"\\"
  If DirExists(DiretorioFechames)=0
     Then Mensagem("N„o existe a pasta do "+ANO_MES+" selecionado !")
          Loop
  EndIf

  If Not Verifica_Usuario() Then Loop EndIf
  ListadeTabelas()
  If (BloqueiaTabelas(Diretorio)) And
     (BloqueiaTabelas(DiretorioFechaMes))
     Then SetDir DiretorioFechaMes
          TITULOS()
          ALTCONT()
          BXAUTC()
          SetDir Diretorio
  EndIf

  DesbloqueiaTabelas(Diretorio)
  DesbloqueiaTabelas(DiretorioFechaMes)
  If Not Tem_Tabelas(Diretorio+"Fechames\\"+ANO_MES)
     Then Deleta_Arvore(SubStr(Directory(),1,2)+Diretorio+"Fechames\\"+ANO_MES)
  EndIf

  LimpAguarde()
  MENSAGEM("Fim de Opera‡„o !")

EndWhile
ClearAll
Release Vars All
Release Procs All
