;** Rm_1100 ********************************************************************
;* Ordem de Carregamento                                                       *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 18/02/2004 por Anivel Augusto Rodrigues
;Ultima Alteracao: 06/02/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Novo Modelo
;Ultima Alteracao: 25/07/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes Diret¢rio Mˆs Fechado
;Ultima Alteracao: 19/04/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes exclusao delete answer dava erro
;Ultima Alteracao: 23/06/2016 por Bruno Carvalho
;Motivo Alteracao: Removido Link nos Report "RM_1101" e utilizado fun‡Æo Ajusta_Answer() e Adiciona_Dados_Tabela()
;Ultima Alteracao: 18/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Seleciona(), Seleciona2()
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 14/07/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modelo 01A                   

;*******************************************************************************
;* Ajusta Dados na Answer                                                      *  
;*******************************************************************************
Proc Ajusta_Answer(PARAM)
Private PARAM

;Processo p/ ajustar tabela conforme remo‡Æo do link da tabela "ITENS" nos reports

If IsAssigned(TABELA) And IsTable(TABELA) Then Delete TABELA EndIf
TABELA = Cria_Temp(PrivDir())
Copy "\\Base\\Sistemas\\Vendas\\"+PARAM TABELA

{Ask} {Answer} Check
Moveto [Codigo do Item        ] Example "_Ite"
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "_Ite"
Moveto [Codigo do Grupo       ] Check
Moveto [Descricao do Grupo    ] Check
Do_It!
ClearAll

Adiciona_Dados_Tabela(TABELA)    
                               
EndProc ;Ajusta_Answer()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI")
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Numero do Pedido   ] Example "Pedido"
        Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
        if isblank(VSDGNCARREG)
           then 
                If VSDGOPDT="E"
                   Then Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                   Else Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                EndIf
        EndIf
        Moveto [Numero_Carregamento] Check TypeIn "~VSDGNCARREG.."
        Moveto [Data_Inclusao      ] Check
        Moveto [Hora_Inclusao      ] Check
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter Check
        Moveto [Numero do Pedido   ] Example "Pedido"
        Do_It!
        ClearAll

        If VSDGOPDT="E" or not isblank(VSDGNCARREG)
           Then Return
        EndIf

        For i From 1 To 2
          {Ask} {Answer} TypeIn "Fast Delete"
          If i=1
             Then Moveto [Data_Inclusao          ] TypeIn "~VSDGDTINI"
                  Moveto [Hora_Inclusao          ] TypeIn "<~VSDGHRINI"
             Else Moveto [Data_Inclusao          ] TypeIn "~VSDGDTFIM"
                  Moveto [Hora_Inclusao          ] TypeIn ">~VSDGHRFIM"
          EndIf
          Do_It!
          ClearAll
        EndFor
EndIf

EndProc    ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona2()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI")
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter Check
        Moveto [Numero do Pedido   ] Example "Pedido"
        Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
        if isblank(VSDGNCARREG)
           then 
                If VSDGOPDT="E"
                   Then Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                   Else Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                EndIf
        EndIf
        Moveto [Numero_Carregamento] Example "Carreg" TypeIn ",~VSDGNCARREG.."
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter 
        Moveto [Numero do Pedido   ] Example "Pedido"
        Moveto [Quantidade         ] TypeIn "Calc Sum as QuantidadeTotal"
      ;;{Ask} {Accarrgc}
      ;;Moveto [Numero_Carregamento] Example "Carreg" Check
      ;;Moveto [Codigo Motorista] Check
      ;;Moveto [Nome Fantasia EmitDest] Check
        Do_It!
        ClearAll

        If VSDGOPDT="E" or not isblank(VSDGNCARREG)
           Then Return
        EndIf

        For i From 1 To 2
          {Ask} {Answer} TypeIn "Fast Delete"
          If i=1
             Then Moveto [Data_Inclusao          ] TypeIn "~VSDGDTINI"
                  Moveto [Hora_Inclusao          ] TypeIn "<~VSDGHRINI"
             Else Moveto [Data_Inclusao          ] TypeIn "~VSDGDTFIM"
                  Moveto [Hora_Inclusao          ] TypeIn ">~VSDGHRFIM"
          EndIf
          Do_It!
          ClearAll
        EndFor
EndIf

EndProc    ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9    : Temp=False
     Case Evento["KeyCode"] =  -59 : Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_NCARREG"       : Campo="TG_EMPRESA"
            Case Campo="TG_OPDT"          : Campo="TG_NCARREG"
            Case Campo="TG_DTINI"         : Campo="TG_OPDT"
            Case Campo="TG_HRINI"         : Campo="TG_DTINI"
            Case Campo="TG_DTFIM"         : Campo="TG_HRINI"
            Case Campo="TG_HRFIM"         : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"     : If Not IsBlank(VSDGNCARREG)
                                               Then Campo="TG_NCARREG"
                                               Else Campo="TG_HRFIM"
                                            EndIf
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG" : If Not isblank(VSDGNCARREG)
                                                 Then Campo="TG_CODMODELO"
                            
                                                      VSDGDTINI   =Today()
                                                      VSDGDTFIM   =Today()
                                                      VSDGHRINI  =""
                                                      VSDGHRFIM  =""
                                                
                                                 Else Campo="TG_OPDT"
                                              EndIf   
                    Case Campo="TG_OPDT"    : Campo="TG_DTINI"
                         VSDGOPDT=ControlValue("TG_OPDT")
                         Switch
                           Case VSDGOPDT="E": VSDGDESCOPDT="DATA DE EMISSAO"
                           Case VSDGOPDT="I": VSDGDESCOPDT="DATA DE INCLUSAO"
                           OtherWise: Campo="TG_OPDT"
                         EndSwitch
                    Case Campo="TG_DTINI"     : Campo="TG_HRINI"
                    Case Campo="TG_HRINI"     : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"     : Campo="TG_HRFIM"
                    Case Campo="TG_HRFIM"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPDT":
     MSG_CAMPO="Op‡„o: E=Data Emiss„o  I=Data Inclus„o "
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

ModeloRelatoriosAdd("Criar") 
ModeloRelatoriosAdd("01  Resumo Itens - Ordem C¢digo")
ModeloRelatoriosAdd("01A Resumo Itens - Ordem Descri‡Æo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Rela‡Æo de Pedidos/Cliente")
ModeloRelatoriosAdd("02A Rela‡Æo de Pedidos/Cliente *SEM VALOR")
ModeloRelatoriosAdd("03  Rela‡Æo de Carregamento")
ModeloRelatoriosAdd("04  Rela‡Æo de Pedidos/N£mero")
ModeloRelatoriosAdd("05  Rela‡Æo de Pedidos + OBS")

ModeloRelatoriosAdd("Fim")
                                     
EndProc ;ModeloRelatoriosCarregaLista()
                         
;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGNCARREG =""
VSDGOPDT    =""
VSDGDTINI   =Today()
VSDGDTFIM   =Today()
VSDGHRINI  =""
VSDGHRFIM  =""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Rela‡Æo/Resumo de Pedidos/Carregamento" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140
   @ 05,12   Height 17 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Carregamento" For "TG_NCARREG"
    Accept @ 03,01 Width 9  "A6"  Picture "[&,#][#*#]" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG

    Label  @ 04,00 "Op‡äes de Datas" For "TG_OPDT"
    Accept @ 05,04 Width 04 "A1"  Picture "E,I" Tag "TG_OPDT" To VSDGOPDT
    Accept @ 05,09 Width 25 "A20"  Picture "!*!" Tag "TG_DESCOPDT" To VSDGDESCOPDT

    Label  @ 06,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 07,04 " de" For "TG_DTINI"
    Accept @ 07,09 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,22 "as" For "TG_DTINI"
    Accept @ 07,26 Width 08 "A5"  Picture "##:##" Tag "TG_HRINI" To VSDGHRINI
    Label  @ 08,04 "at‚" For "TG_DTFIM"
    Accept @ 08,09 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    Label  @ 08,22 "as" For "TG_DTFIM"
    Accept @ 08,26 Width 08 "A5"  Picture "##:##" Tag "TG_HRFIM" To VSDGHRFIM
    
    Label  @ 10,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 11,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 11,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO    

    Pushbutton @ 13,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 13,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
   If IsTable("Answer") Then Delete "Answer" EndIf
   Switch
     Case VSDGCODMODELO="01" Or VSDGCODMODELO="01A" Or VSDGCODMODELO="03"                       : Seleciona()
     Case VSDGCODMODELO="02" Or VSDGCODMODELO="02A" Or VSDGCODMODELO="04" Or VSDGCODMODELO="05" : Seleciona2()
   EndSwitch
   If Not IsTable("Answer") Then Loop EndIf

   If IsTable(Tabela)
      Then Add "Answer" Tabela
      Else Rename "Answer" Tabela
   EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  Switch
    Case VSDGCODMODELO="01"  : Copy Tabela "Answer" 
                               Ajusta_Answer("RM_1101")
                               CopyReport  "\\Base\\Sistemas\\Vendas\\RM_1101" "R" Tabela "R"

    Case VSDGCODMODELO="01A" : Copy Tabela "Answer" 
                               Ajusta_Answer("RM_1101")
                               CopyReport  "\\Base\\Sistemas\\Vendas\\RM_1101" "1" Tabela "R"


    Case VSDGCODMODELO="02"  : CopyReport  "\\Base\\Sistemas\\Vendas\\RM_1100" "R" Tabela "R"
    Case VSDGCODMODELO="02A" : CopyReport  "\\Base\\Sistemas\\Vendas\\RM_1100" "4" Tabela "R"
    Case VSDGCODMODELO="03"  : Sort Tabela On "Numero_Carregamento","Descricao do Item","Codigo do Item"
                               ClearAll
    Case VSDGCODMODELO="04"  : CopyReport  "\\Base\\Sistemas\\Vendas\\RM_1100" "1" Tabela "R"
    Case VSDGCODMODELO="05"  : CopyReport  "\\Base\\Sistemas\\Vendas\\RM_1100" "2" Tabela "R"
    
  EndSwitch

  If VSDGCODMODELO<>"03"
     Then IMPRIREL(Tabela,"R")
          Delete Tabela

     Else Rename Tabela "Answer"
          Play "OC_0117C"
  EndIf

  if istable(Tabela) then Delete Tabela endif

EndWhile
ClearAll
Release Vars All
Release Procs All
