;** Rm_3010 ********************************************************************
;* Resumo de Vendas por Marca/Familia/Grupo/Produto                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/09/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 08/09/2004 por Jos‚ Lu¡s Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 15/12/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 28/07/2014 por Luis Gustavo
;Motivo Alteracao: Implementado op‡Æo para sair o codigo do item ou o codigo do Fornecedor
;Ultima Alteracao: 14/08/2014 por Andrey Fillipe
;Motivo Alteracao: Adicionado Codigo do Cliente no report RM_3100a "9" e "10"
;Ultima Alteracao: 15/09/2014 por Andrey Fillipe
;Motivo Alteracao: Retirado quebra por Codigo do Cliente no report RM_3100a "9" e "10"
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT                 
;Ultima Alteracao: 30/05/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modelo relatorio 02
;Ultima Alteracao: 30/07/2019 por Bruno Carvalho
;Motivo Alteracao: Adicionado proc Processa_0227() p/ #0227# onde tem algumas particularidades conforme grupo 024
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
Private ii
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then For ii From 1 To PROCESSO_0227_TM
          If Not IsBlank(VSDGMARCA) or
             Not IsBlank(VSDGFAMI) or
             Not IsBlank(VSDGGRP)
             Then {Ask} {\\Sistemas\\Estoque\\Itens}
                  Moveto [Codigo do Item         ] Example "cite"
                  Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                  Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                  Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."      
          EndIf
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
          Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
          If ii=1
             Then Moveto [Numero do Documento    ] Example "ndoc"
             Else Moveto [Numero do Documento    ] Check Example "ndoc"
          EndIf   
          Moveto [Serie do Documento     ] Example "sdoc"
          Moveto [Codigo                 ] TypeIn "~VSDGDESTINAT.."
          Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
          Moveto [Tipo Movimento Estoque ] TypeIn "S"
          Moveto [Situacao               ] TypeIn "Not C"
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
          Moveto [Codigo da Empresa      ] Example "cemp"
          Moveto [Numero do Documento    ] Example "ndoc"
          Moveto [Serie do Documento     ] Example "sdoc"
          If ii=1
             Then Moveto [Codigo do Item ] Check
          EndIf   
          If Not IsBlank(VSDGMARCA) Or
             Not IsBlank(VSDGFAMI) Or
             Not IsBlank(VSDGGRP)
             Then Moveto [Codigo do Item ] Example "cite"
          EndIf
          If ii=1
             Then Moveto [Descricao do Item      ] Check
                  Moveto [Unidade Fiscal         ] Check
                  Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
                  If PROCESSO_0227
                     Then Moveto [Preco Unitario ] Check
                          Moveto [Valor do ICMS  ] TypeIn "Calc Sum as Valor do ICMS"
                          Moveto [COFINS_Valor   ] TypeIn "Calc Sum as Valor do COFINS"
                          Moveto [PIS_Valor      ] TypeIn "Calc Sum as Valor do PIS"
                  EndIf
                  Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
                  Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
          EndIf  
          Moveto [Situacao_Item          ] TypeIn "Not C"
          Do_It!
          ClearAll

          Switch
            Case ii = 1 : Adiciona_Dados("VENDAS")
            Case ii = 2 : Adiciona_Dados("NOTAS")
          EndSwitch  
        Endfor
EndIf

;****** Devolucoes - Estoque ***************************************************
If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then For ii From 1 To PROCESSO_0227_TM 
          If Not IsBlank(VSDGMARCA) or
             Not IsBlank(VSDGFAMI) or
             Not IsBlank(VSDGGRP)
             Then {Ask} {\\Sistemas\\Estoque\\Itens}
                  Moveto [Codigo do Item         ] Example "cite"
                  Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                  Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                  Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
          EndIf
          {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
          Moveto [Numero do Lancamento   ] Example "nlan"
          Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
          If ii=2
             Then Moveto [Numero do Documento] Check
          EndIf   
          Moveto [Codigo                 ] TypeIn "~VSDGDESTINAT.."
          Moveto [Data de Entrada        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Moveto [Tipo de Operacao       ] TypeIn "D"
          {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
          Moveto [Numero do Lancamento   ] Example "nlan"
          If ii=1
             Then Moveto [Codigo do Item ] Check
          EndIf   
          If Not IsBlank(VSDGMARCA) Or
             Not IsBlank(VSDGFAMI) Or
             Not IsBlank(VSDGGRP)
             Then Moveto [Codigo do Item ] Example "cite"
          EndIf
          If ii=1
             Then Moveto [Descricao do Item      ] Check
                  Moveto [Unidade Fiscal         ] Check
                  Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
                  If PROCESSO_0227
                     Then Moveto [Preco Unitario ] Check
                          Moveto [Valor do ICMS  ] TypeIn "Calc Sum as Valor do ICMS"
                          Moveto [COFINS_Valor   ] TypeIn "Calc Sum as Valor do COFINS"
                          Moveto [PIS_Valor      ] TypeIn "Calc Sum as Valor do PIS"
                  EndIf
                  Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
                  Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
          EndIf
          Do_It!
          ClearAll
  
          Switch
            Case ii = 1 : Adiciona_Dados("DEVOLUCOES")
            Case ii = 2 : Adiciona_Dados("NOTAS")
          EndSwitch
        EndFor
EndIf

;****** Devolucoes - Vendas ****************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then For ii From 1 To PROCESSO_0227_TM
          If Not IsBlank(VSDGMARCA) or
             Not IsBlank(VSDGFAMI) or
             Not IsBlank(VSDGGRP)
             Then {Ask} {\\Sistemas\\Estoque\\Itens}
                  Moveto [Codigo do Item         ] Example "cite"
                  Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                  Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                  Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
          EndIf
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
          Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
          If ii=1
             Then Moveto [Numero do Documento    ] Example "ndoc"
             Else Moveto [Numero do Documento    ] Check Example "ndoc"
          EndIf
          Moveto [Serie do Documento     ] Example "sdoc"
          Moveto [Codigo                 ] TypeIn "~VSDGDESTINAT.."
          Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
          Moveto [Tipo Movimento Estoque ] TypeIn "E"
          Moveto [Situacao               ] TypeIn "Not C"
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
          Moveto [Codigo da Empresa      ] Example "cemp"
          Moveto [Numero do Documento    ] Example "ndoc"
          Moveto [Serie do Documento     ] Example "sdoc"
          If ii=1
             Then Moveto [Codigo do Item ] Check
          EndIf
          If Not IsBlank(VSDGMARCA) Or
             Not IsBlank(VSDGFAMI) Or
             Not IsBlank(VSDGGRP)
             Then Moveto [Codigo do Item ] Example "cite"
          EndIf
          If ii=1
             Then Moveto [Descricao do Item      ] Check
                  Moveto [Unidade Fiscal         ] Check
                  Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
                  If PROCESSO_0227
                     Then Moveto [Preco Unitario ] Check
                          Moveto [Valor do ICMS  ] TypeIn "Calc Sum as Valor do ICMS"
                          Moveto [COFINS_Valor   ] TypeIn "Calc Sum as Valor do COFINS"
                          Moveto [PIS_Valor      ] TypeIn "Calc Sum as Valor do PIS"
                  EndIf
                  Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
                  Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
          EndIf        
          Moveto [Situacao_Item          ] TypeIn "Not C"
          Do_It!
          ClearAll
  
          Switch
            Case ii = 1 : Adiciona_Dados("DEVOLUCOES")
            Case ii = 2 : Adiciona_Dados("NOTAS")
          EndSwitch
        Endfor
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

Switch
  Case Tipo="NOTAS" : 
  {Ask} {Answer}
  Moveto [Numero do Documento    ] TypeIn "_Doc"
  {Ask} TypeIn TabelaNota Enter TypeIn "Fast Insert"
  Moveto [Documento              ] TypeIn "_Doc"
  
  OtherWise         :
  {Ask} {Answer}
  Moveto [Codigo da Empresa      ] Example "cemp"
  Moveto [Codigo do Item         ] Example "cite"
  Moveto [Descricao do Item      ] Example "dite"
  Moveto [Unidade Fiscal         ] Example "unf"
  Moveto [Quantidade             ] Example "qtde"
  If PROCESSO_0227
     Then Moveto [Preco Unitario      ] Example "prunit" 
          Moveto [Valor do ICMS       ] Example "icms"
          Moveto [Valor do COFINS     ] Example "cof" 
          Moveto [Valor do PIS        ] Example "pis" 
  EndIf
  Moveto [Preco Total            ] Example "ptot"
  Moveto [Valor Desconto Total   ] Example "vdes"
  {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
  Moveto [Codigo da Empresa      ] Example "cemp"
  Moveto [Codigo do Item         ] Example "cite"
  Moveto [Descricao do Item      ] Example "dite"
  Moveto [Unidade Fiscal         ] Example "unf"
  Switch
    Case Tipo="VENDAS":
         Moveto [Vendas_Quantidade      ] Example "qtde"
         Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
         If PROCESSO_0227
            Then Moveto [Vendas_PrUnitario   ] Example "prunit"
                 Moveto [Desconto_Total      ] Example "vdes"
                 Moveto [Valor do ICMS       ] Example "icms"
                 Moveto [Valor do COFINS     ] Example "cof" 
                 Moveto [Valor do PIS        ] Example "pis" 
         EndIf
    Case Tipo="DEVOLUCOES":
         Moveto [Devolucoes_Quantidade  ] Example "qtde"
         Moveto [Devolucoes_Preco Total ] Example "ptot" TypeIn"-" Example "vdes"
         If PROCESSO_0227
            Then Moveto [Vendas_PrUnitario   ] Example "prunit"
                 Moveto [Desconto_Total      ] Example "vdes"
                 Moveto [Valor do ICMS       ] Example "icms"
                 Moveto [Valor do COFINS     ] Example "cof" 
                 Moveto [Valor do PIS        ] Example "pis"
         EndIf
  EndSwitch
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Unidade Embalagem      ] Example "une"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Descricao da Familia   ] Example "dfam"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [Descricao do Grupo     ] Example "dgru"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Descricao da Marca     ] Example "dmar"
Moveto [Codigo Fornecedor      ] Example "codfor"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Moveto [Unidade Embalagem      ] TypeIn "changeto _une"
Moveto [Codigo da Familia      ] TypeIn "changeto _cfam"
Moveto [Descricao da Familia   ] TypeIn "changeto _dfam"
Moveto [Codigo do Grupo        ] TypeIn "changeto _cgru"
Moveto [Descricao do Grupo     ] TypeIn "changeto _dgru"
Moveto [Codigo da Marca        ] TypeIn "changeto _cmar"
Moveto [Descricao da Marca     ] TypeIn "changeto _dmar"
Moveto [Codigo Fornecedor      ] typeIn "changeto _codfor"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item            ] Example "cite"
Moveto [Fator Conversao Embalagem ] Example "fce"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item            ] Example "cite"
Moveto [Unidade Fiscal            ] Example "unf"
Moveto [Unidade Embalagem         ] TypeIn "not = " Example "unf"
Moveto [Vendas_Quantidade         ] Example "qtd"
Moveto [Vendas_Embalagem          ] TypeIn "changeto _qtd*_fce"
Do_It!
ClearAll

switch
  case VSDGCODMODELO="02":
    {Ask} TypeIn Tabela Enter TypeIn "Fast"
    Moveto [Codigo da Familia      ] TypeIn "changeto blank"
    Moveto [Descricao da Familia   ] TypeIn "changeto blank"
    Moveto [Codigo do Grupo        ] TypeIn "changeto blank"
    Moveto [Descricao do Grupo     ] TypeIn "changeto blank"
    Do_It!
    ClearAll
endswitch

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Embalagem       ] Check TypeIn "Calc Sum as VendasEmbalagem"
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as VendasPreco"
Moveto [Devolucoes_Quantidade  ] Check TypeIn "Calc Sum as DevolucoesQuantidade"
Moveto [Devolucoes_Preco Total ] Check TypeIn "Calc Sum as DevolucoesPreco"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Vendas_Embalagem          ] TypeIn "<=0, changeto blank"
Moveto [Unidade Embalagem         ] TypeIn "changeto Blank"
Do_It!
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Marca *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Marca        ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Total_Vendas_Marca     ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Familia *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Marca        ] Check
Moveto [Codigo da Familia      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Total_Vendas_Familia   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Grupo *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Marca        ] Check
Moveto [Codigo da Familia      ] Check
Moveto [Codigo do Grupo        ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [Total_Vendas_Grupo     ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina p/ processar Db temporaria *Particularidade                          *
;*******************************************************************************
Proc Processa_0227()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Unidade Embalagem      ] Example "une"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [Descricao do Grupo     ] Example "dgru"
Moveto [Referencia             ] Example "Ref"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Moveto [Unidade Embalagem      ] TypeIn "changeto _une"
Moveto [Codigo do Grupo        ] TypeIn "changeto _cgru"
Moveto [Descricao do Grupo     ] TypeIn "changeto _dgru"
Moveto [Referencia             ] typeIn "changeto _Ref"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Iten_Com}
Moveto [Codigo do Item     ] Example "cite"
Moveto [Codigo Concentrador] Example "Codc"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item     ] Example "cite"
Moveto [Codigo Concentrador] typeIn "changeto _Codc"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] TypeIn "changeto blank"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Referencia                ] Example "ref"
Moveto [Descricao do Item         ] Example "descr"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Referencia                ] Example "ref"
Moveto [Descricao do Item         ] TypeIn "changeto _descr"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo Concentrador       ] TypeIn "_conc" 
Moveto [Codigo do Item            ] TypeIn "changeto _conc"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Referencia                ] TypeIn "_ref"
Moveto [Codigo do Item            ] TypeIn "Blank, changeto _ref"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter Check
Moveto [Valor do ICMS          ] Check TypeIn "Calc Sum as ValorICMS" 
Moveto [Valor do COFINS        ] Check TypeIn "Calc Sum as ValorCOFINS"
Moveto [Valor do PIS           ] Check TypeIn "Calc Sum as ValorPIS"
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as VendasPreco"
Moveto [Devolucoes_Quantidade  ] Check TypeIn "Calc Sum as DevolucoesQuantidade"
Moveto [Devolucoes_Preco Total ] Check TypeIn "Calc Sum as DevolucoesPreco"
Moveto [Desconto_Total         ] Check TypeIn "Calc Sum as VendasDescTotal"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

{Ask} TypeIn Tabela Enter 
Moveto [Valor do ICMS             ] Example "icms" 
Moveto [Valor do COFINS           ] Example "cofins" 
Moveto [Valor do PIS              ] Example "pis"
Moveto [Valor ICMS+PIS+COFINS     ] TypeIn "Changeto _icms+_cofins+_pis"
Do_It!
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Grupo *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Grupo        ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [Total_Vendas_Grupo     ] TypeIn "changeto _vp"
Do_It!
ClearAll

If Not IsEmpty(TabelaNota)
   Then NOTAS = ""
        View TabelaNota
        Scan
          If NOTAS <>"" 
             Then NOTAS = NOTAS + ", "
          EndIf   
          NOTAS = NOTAS + [Documento]
        EndScan
        CleaRAll
        
        CoEdit Tabela 
        Scan
          [Notas]=NOTAS
        EndScan
        Do_It!
        ClearAll
EndIf

EndProc    ;Processa_0227()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""

If Disparo="OPEN" Or Disparo="UPDATE" 
   Then If Campo="TG_GRP" 
            Then If VSDGGRP="024"
                    Then WCol1 = 35
                    Else WCol1 = 80
                 EndIf
                 CampoAnterior="TG_OPCAO"               
                 refazershowdialog=true
                 AcceptDialog
       Endif
EndIf

If Disparo="OPEN"  
   Then AoCriarShowDialog()
        If refazershowdialog 
           Then Campo=CampoAnterior 
                refazershowdialog=false 
        EndIf  
EndIf       

If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESATE"
            Case Campo="TG_MARCA"         : Campo="TG_DESTINAT"
            Case Campo="TG_FAMI"          : Campo="TG_MARCA"
            Case Campo="TG_GRP"           : Campo="TG_FAMI"
            Case Campo="TG_DTINI"         : Campo="TG_GRP"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_DTFIM"
            Case Campo="TG_OPCOES"        : Campo="TG_OPRELCODALF"
            Case Campo="TG_CODMODELO"     : If WCol1 = 35
                                               Then Campo="TG_OPCOES"
                                               Else Campo="TG_OPRELCODALF"
                                            EndIf   
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     :Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"    :Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       :Campo="TG_FAMI"
                    Case Campo="TG_FAMI"        :Campo="TG_GRP"
                    Case Campo="TG_GRP"         :Campo="TG_DTINI"
                         If VSDGGRP="024" And SYS_CODIGO_CLIENTE="0227"
                            Then VSDGOPCAO[1]=True
                                 WCol1 = 35  
                            Else WCol1 = 80
                         EndIf
                         CampoAnterior="TG_DTINI"
                         refazershowdialog=true
                         AcceptDialog
                    Case Campo="TG_DTINI"       :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       :Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF" : 
                         If WCol1 = 35
                            Then Campo="TG_OPCOES"
                            Else Campo="TG_CODMODELO"
                         EndIf   
                    Case Campo="TG_OPCOES"      : Campo="TG_CODMODELO"
                         If VSDGOPCAO[1]
                            Then VSDGCODMODELO = "03"
                         EndIf         
                    Case Campo="TG_CODMODELO"   : Campo="YES" 
                                                      
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPCOES"    :
       MensagemRadioButtons()
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Marca/Familia/Grupo/Item")
ModeloRelatoriosAdd("01B Marca/Familia/Grupo/Item - com c¢digo do item do fornecedor")
ModeloRelatoriosAdd("02  Marca/Item")
ModeloRelatoriosAdd("03  Grupo/Item *Codigo Concentrador")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
SYS_VALOR()

VSDGEMPRESA =""
VSDGDESTINAT=""
VSDGMARCA   =""
VSDGFAMI    =""
VSDGGRUP    =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
VSDGOPRELCODALF=""

Array VSDGOPCAO[1]
refazershowdialog=false

VSDGOPCAO[1]=False
WCol1 = 80

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Vendas por Marca/Familia/Grupo/Produto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 20 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST
    
    Label  @ 04,00 "Marca"  For "TG_MARCA"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 06,00 "Familia"  For "TG_FAMI"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 08,00 "Grupo"  For "TG_GRP"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"    To VSDGGRP
    Accept @ 09,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP

    Label  @ 10,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡„o de Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF
    
    CheckBoxes @03,WCol1 Height 3 Width 35 Tag "TG_OPCOES"
    "Por Codigo Concentrador" to VSDGOPCAO[1]
    
    Label  @ 13,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 14,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 14,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        
    
    Pushbutton @ 16,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 16,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf

  if refazershowdialog then loop endif

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGOPCAO[1] And VSDGCODMODELO <> "03"
     Then Mensagem("H  particularidades para relat¢rio ser filtrado por codigo concentrador//Modelo de Relat¢rio 03")
          Loop
  EndIf                       

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  
  PROCESSO_0227=False
  Tabela=Cria_Temp(PrivDir())
  If VSDGOPCAO[1] And VSDGCODMODELO="03"
     Then PROCESSO_0227_TM = 2
          PROCESSO_0227    = True
          ;Referencia e Codigo Concentrador
          Empty "\\Base\\Sistemas\\Vendas\\RM_3011"
          Copy "\\Base\\Sistemas\\Vendas\\RM_3011" Tabela
     Else PROCESSO_0227_TM = 1
          Empty "\\Base\\Sistemas\\Vendas\\RM_3100"
          Copy "\\Base\\Sistemas\\Vendas\\RM_3100" Tabela
  EndIf        

  ;---- Criando tabela p/ armazenar o numero do documento das notas envolvidas ---
  CRIAR_TABELA = True
  CRIAR_TABELA2=FAlse
  TabelaNota=Cria_Temp(PrivDir())
  Adiciona_Campo(TabelaNota,"Documento(A20)")
  
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  
  ;Particularidades da Empresa #0227# -> Processo especial apenas para um determinado grupo
  If VSDGOPCAO[1] And VSDGCODMODELO="03"
     Then Processa_0227()
     Else Processa()     
  EndIf
   
  Switch
    Case VSDGCODMODELO="01" : 
      CopyReport "\\Base\\Sistemas\\Vendas\\RM_3100" "6" Tabela "R"
      If VSDGOPRELCODALF="1"
         Then Seta_Ordem_Report(Tabela,"R","Codigo do Item","Codigo do Item"   ,"")
         Else Seta_Ordem_Report(Tabela,"R","Codigo do Item","Descricao do Item","")
      EndIf
    Case VSDGCODMODELO="01B": 
      CopyReport "\\Base\\Sistemas\\Vendas\\RM_3100a" "9" Tabela "R"
      If VSDGOPRELCODALF="1"
         Then Seta_Ordem_Report(Tabela,"R","Codigo Fornecedor","Codigo Fornecedor","")
         Else Seta_Ordem_Report(Tabela,"R","Codigo Fornecedor","Descricao do Item","")
      EndIf
    Case VSDGCODMODELO="02" : 
      CopyReport "\\Base\\Sistemas\\Vendas\\RM_3100" "7" Tabela "R"
      If VSDGOPRELCODALF="1"
         Then Seta_Ordem_Report(Tabela,"R","Codigo do Item","Codigo do Item"   ,"")
         Else Seta_Ordem_Report(Tabela,"R","Codigo do Item","Descricao do Item","")
      EndIf
    Case VSDGCODMODELO="03" :
      If VSDGOPCAO[1]
         Then CopyReport "\\Base\\Sistemas\\Vendas\\RM_3011" "R" Tabela "R"
         Else CopyReport "\\Base\\Sistemas\\Vendas\\RM_3100" "6" Tabela "R"
      EndIf
      If VSDGOPRELCODALF="1"
         Then Seta_Ordem_Report(Tabela,"R","Codigo do Item","Codigo do Item"   ,"")
         Else Seta_Ordem_Report(Tabela,"R","Codigo do Item","Descricao do Item","")
      EndIf
  EndSwitch
  IMPRIREL(Tabela,"R")
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
