;** Rm_0210 ********************************************************************
;*  Emissao da Posicao de Vendas por Cliente(Curva ABC)                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 06/11/96 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")
   Then {Ask} {NotaC}
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
        Moveto [Codigo                 ] Check
        Moveto [Nome Fantasia EmitDest ] Check
        Moveto [Descricao da Destinacao] TypeIn "..DEVOL"
        ;;Moveto [Descricao da Destinacao] TypeIn "..VEND.. OR ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        Moveto [Valor Nota Fiscal      ] TypeIn "Calc Sum as Valor"
        Do_It!
        ClearAll
EndIf
Add "Answer" TabelaI
ClearAll

If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC")
   Then {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEc" Enter
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
        Moveto [Data de Entrada        ] TypeIn " >=~VSDGDTINI,<=~VSDGDTFIM  "
        Moveto [Codigo                 ] Check
        Moveto [Nome Fantasia EmitDest ] Check
        Moveto [Tipo de Operacao       ] TypeIn "C"
        Moveto [Valor Nota Fiscal      ] TypeIn "Calc Sum as Valor"
        Do_It!
        ClearAll

        {Ask} {Answer} TypeIn "Fast"
        Moveto [Valor] Example "VrE" TypeIn " , Changeto " Example "VrE" TypeIn "*-1"
        Do_It!
        ClearAll

        Add "Answer" TabelaI
        ClearAll
EndIf

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")
   Then {Ask} {NotaC}
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
        Moveto [Data de Emissao        ] TypeIn " >=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo                 ] Check
        Moveto [Nome Fantasia EmitDest ] Check
        Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
        Moveto [Tipo Movimento Estoque ] TypeIn "E"
        Moveto [Situacao               ] TypeIn "Not C"
        Moveto [Valor Nota Fiscal      ] TypeIn "Calc Sum as Valor"
        Do_It!
        ClearAll
EndIf
{Ask} {Answer} TypeIn "Fast"
Moveto [Valor] Example "VrE" TypeIn " , Changeto " Example "VrE" TypeIn "*-1"
Do_It!
ClearAll

Add "Answer" TabelaI
ClearAll
EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

{Ask} TypeIn TabelaI Enter
Moveto [Codigo                ] Check
Moveto [Nome Fantasia EmitDest] Check
Moveto [Valor                 ] TypeIn "Calc Sum as Valor"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo                ] Example "CODIGO"
Moveto [Nome Fantasia EmitDest] Example "NOME"
Moveto [Valor                 ] Example "VALOR"
{Ask} TypeIn TabelaC Enter TypeIn "Fast Insert"
Moveto [Codigo                ] Example "CODIGO"
Moveto [Nome Fantasia EmitDest] Example "NOME"
Moveto [Valor                 ] Example "VALOR"
Do_It!
ClearAll

{Ask} TypeIn TabelaC Enter TypeIn "Fast"
Moveto [Valor ] TypeIn ">=~VSDGVALORA"
Moveto [Grupo ] TypeIn "Changeto A"
CtrlHome Down
TypeIn "Fast"
Moveto [Valor ] TypeIn ">=~VSDGVALORB, <~VSDGVALORA"
Moveto [Grupo ] TypeIn "Changeto B"
Ctrlhome Down
TypeIn "Fast"
Moveto [Valor ] TypeIn "<~VSDGVALORB"
Moveto [Grupo ] TypeIn "Changeto C"
Do_It!
ClearAll

{Ask} TypeIn TabelaC enter
Moveto [Valor] TypeIn "Calc Sum As VALORTOT"
Do_It!
If Not IsEmpty("Answer")
   Then VALORTOT=[VALORTOT]
   Else VALORTOT=0
EndIf
ClearAll

Sort TabelaC On "Grupo", "Valor" D

CoEdit TabelaC
VRA=0
Scan
   VRA=VRA+[Valor]
   [Indice          ]=NumVal((([Valor]*100)/VALORTOT))
   [Indice Acumulado]=NumVal(((VRA*100)/VALORTOT))
EndScan
Do_It!
ClearAll

EndProc ;(Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTINI"        : Campo="TG_EMPRESA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_VALORA"        : Campo="TG_DTFIM"
            Case Campo="TG_VALORB"        : Campo="TG_VALORA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   :Campo="TG_VALORA"
                    Case Campo="TG_VALORA":
                         VSDGVALORA=ControlValue("TG_VALORA")
                         If Not Isblank(VSDGVALORA)
                            Then Campo="TG_VALORB"
                         EndIf
                    Case Campo="TG_VALORB":
                         VSDGVALORB=ControlValue("TG_VALORB")
                         If Not Isblank(VSDGVALORB)
                            Then If VSDGVALORB > VSDGVALORA
                                    Then Mensagem("Valor B maior que Valor A !")
                                    Else Campo="YES"
                                 EndIf
                         EndIf
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_VALORA" or Campo="TG_VALORB":
     MSG_CAMPO="Informe um Valor Inicial"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGVALORA  =BlankNum()
VSDGVALORB  =BlankNum()
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Resumo de Compras por Cliente(Curva ABC)" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 12 Width 56

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Perˇodo Referente" For "TG_DTINI"
    Label  @ 03,00 "de" For "TG_DTINI"
    Accept @ 03,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,17 "at‚" For "TG_DTFIM"
    Accept @ 03,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM


    Label  @ 05,00 "Valor Inicial Grupo A"  For "TG_VALORA"
    Accept @ 05,23 Width 07 "$" Tag "TG_VALORA"  To VSDGVALORA

    Label  @ 06,00 "Valor Inicial Grupo B"  For "TG_VALORB"
    Accept @ 06,23 Width 07 "$" Tag "TG_VALORB" To VSDGVALORB

    Pushbutton @ 08,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 08,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If Isblank(VSDGVALORA)
     Then Mensagem("Valor Grupo A Invalido !")
          Loop
  EndIf

  If Isblank(VSDGVALORB)
     Then Mensagem("Valor Grupo B Invalido !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat˘rio")
  TabelaC=Cria_Temp(PrivDir())
  Copy "Rm_0210" TabelaC
  TabelaI=Cria_Temp(PrivDir())
  Copy "Rm_0210a" TabelaI

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    SetDir "\\Sistemas\\Vendas\\"+Dir_Trab
    Seleciona()
  EndWhile

  If IsEmpty(TabelaI)
     Then MENSAGEM("N„o existem registros a processar")
          Delete TabelaC
          Delete TabelaI
          Loop
  EndIf
  Processa()

  IMPRIREL(TabelaC,"R")

  Delete TabelaC
  Delete TabelaI

EndWhile

SetDir "\\Sistemas\\Estoque\\"
ClearAll
Release Vars All
Release Procs All
