;** NP_0013N *******************************************************************
;** Impressao de Nota Promissoria                     ** Divilack **           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 01/01/1998 por Anivel Augusto Rodrigues
;Alterado em     : 22/09/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 14/08/2007 por Antonio Marcelo Alves
;Motivo Alteracao: Ajustes Deleta_Arquivo
;Ultima Alteracao: 03/02/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes NUMCOPIA=1     
;Ultima Alteracao: 13/09/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modo ordem da duplicata numero/letra

;*******************************************************************************
;
;**** Teste da Impressora ****
Moveto "FaturaC"
AGUARDE("Imprimindo Vencimentos")

;********* Imprime Vencimentos*********
If CODFISC="NF1" Then TPDOCTO="NF"  EndIf
If CODFISC="ROM" Then TPDOCTO="ROM" EndIf

Array dia[12]
Array mes[12]
Array ano[12]
Array DtVencto[12]
Array ValorVen[12]

For I From 1 To 12
    dtvencto[i]=BlankDate()
    valorven[i]=BlankNum()
    dia[i] =""
    mes[i] =""
    ano[i] =""
EndFor

Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
If RetVal
   Then i=0
        While [Numero da OF] = [FaturaC->Numero da OF]
          i=i+1
          dtvencto[i] = [Data ]
          valorven[i] = [Valor]
          dia[i]      = Day([Data])
          mes[i]      = MESEXT(Month([Data]))
          ano[i]      = Year([Data])
          Skip
          If EOT()
             Then QuitLoop
          Endif
        EndWhile
Endif
Moveto "FaturaC"
inp=1

getsys_modo_ordemdup()

While valorven[inp] <> BlankNum()

  MSG="Confirma Impress„o ?//"
  MSG=MSG+"Vencimento "+Format("D13",dtvencto[inp])
  ConfGeral(MSG)
  If OK<>"S"
     Then inp=inp+1
          Loop
  EndIf

  ;---- Inicia Arquivo Impressao -------------------------------------------------
  ArqImp=PrivDir()+"NP_0013N.Txt"
  If IsFile(ArqImp)
     Then Deleta_Arquivo(ARQIMP)
  EndIf

  Print File ARQIMP  Chr(27)+Chr(18)       ; 18 Caracteres por Polegada
  Print File ARQIMP  Chr(27)+Chr(48)       ; 8 Linhas por Polegada

  Print File ARQIMP "\n"
  Print File ARQIMP Format("W47,AC",[Codigo da Empresa])+Format("W08,AL",(dia[inp]))+Format("W15,AL",(mes[inp]))+Format("W6,AL",(ano[inp]))+"\n"
  Print File ARQIMP "\n"

  switch
    case sys_modo_ordemdup="N":
      If Not IsBlank(dtvencto[2])
         Then Print File ARQIMP Spaces(23)+Format("W20,AL",(TPDOCTO+" "+NOTAFISC+"/"+strval(inp)))+Spaces(24)+Format("W11.2,AL,EIC",valorven[inp])+"\n"
         Else Print File ARQIMP Spaces(23)+Format("W22,AL",(TPDOCTO+" "+NOTAFISC+"  "))+Spaces(24)+Format("W11.2,AL,EIC",valorven[inp])+"\n"
      EndIf
    
    otherwise                 :
      If Not IsBlank(dtvencto[2])
         Then Print File ARQIMP Spaces(23)+Format("W20,AL",(TPDOCTO+" "+NOTAFISC+"/"+CHR(65+inp-1)))+Spaces(24)+Format("W11.2,AL,EIC",valorven[inp])+"\n"
         Else Print File ARQIMP Spaces(23)+Format("W22,AL",(TPDOCTO+" "+NOTAFISC+"  "))+Spaces(24)+Format("W11.2,AL,EIC",valorven[inp])+"\n"
      EndIf
  
  endswitch

  ;***** Extenso p/ Data ********************************************************
  Print File ARQIMP "\n"

  dtextenso=""
  EscExt(NumVal(Dia[inp]))
  dtextenso=SubStr(Extenso,1,SearchFrom(" CENT",extenso,1))
  Print File ARQIMP Spaces(18)+Format("W20,AL",dtextenso)
  Print File ARQIMP Format("W21,AL",Mes[inp])
  dtextenso=""
  EscExt(NumVal(SubStr(StrVal(NumVal(ano[inp])),1,1))*1000000)
  dtextenso=SubStr(Extenso,1,SearchFrom(" REA",extenso,1))

  If NumVal(SubStr(StrVal(NumVal(ano[inp])),2,3))>0
     Then dtextenso=dtextenso+"E"
          EscExt(NumVal(SubStr(StrVal(NumVal(ano[inp])),2,3))*1000)
          dtextenso=dtextenso+SubStr(Extenso,1,SearchFrom(" REA",extenso,1))
  EndIf
  Print File ARQIMP Format("W20,AL",dtextenso)+"\n\n"
  Print File ARQIMP "\n"

  Print File ARQIMP Spaces(49)+"EI\n\n"
  Print File ARQIMP Spaces(15)+Format("W45,AL","MINASLACK COMERCIAL LTDA")
  Print File ARQIMP "25.584.665/0001-10"+"\n\n"

  ;******************************************************************************

  ESCEXT(valorven[inp])
  Print File ARQIMP Spaces(22)+SubStr(EXTENSO,001,54)+"\n\n\n"
  Print File ARQIMP Spaces(14)+SubStr(EXTENSO,055,53)+"\n"
  Print File ARQIMP "\n"

  Print File ARQIMP Spaces(24)+Format("W40,AL",[Cidade])
  Print File ARQIMP Format("W4,AL",Day([Data de Emissao]))
  Print File ARQIMP Format("W4,AL",Month([Data de Emissao]))
  Print File ARQIMP Format("W6,AL",Year([Data de Emissao]))+"\n\n"

  Print File ARQIMP Spaces(24)+Format("W42,AL",[Razao Social])+"\n\n"

  Print File ARQIMP Spaces(18)+Format("W18,AL",[CGC])
  Print File ARQIMP Spaces(07)+[Endereco]+"-"+[Bairro]+"\n"

  inp=inp+1

  Print File ARQIMP  Chr(27)+Chr(18)       ; 10 Caracteres por Polegada
  Print File ARQIMP  Chr(27)+Chr(50)       ; 6 Linhas por Polegada

  ;---- Imprime Arquivo Impressao ------------------------------------------------
  NUMCOPIA=1
  ImpriArq(ARQIMP)

EndWhile

inp=1

While valorven[inp] <> BlankNum()
      CONFGERAL("Imprime Itens ?")
      If Ok="S"
         Then Play "NP_0013i"
      EndIf
      inp=inp+1
EndWhile

LIMPAGUARDE()
Release Vars Dia, Mes, Ano, dtvencto, valorven, inp

