;** EV_0343A *******************************************************************
;** Impressao de Etiquetas de volumes A4 Formul rio Pimaco                     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 18/01/2019 por Rafael Matos
;Ultima Alteracao:   /  /     por Bruno Carvalho                        
;Motivo Alteracao: 

;*******************************************************************************
Proc Imprime_Etiqueta()

If netiq>0
   Then If QUEBRA_PAGINA=0
           Then Print File ARQIMP CI_INEG+CI_10CPP+CI_6LPP
                Print File ARQIMP "\n\n\n\n\n"
        EndIf    
        ;Print File ARQIMP chr(27)+"k0"
        Print File ARQIMP LINHA1+"\n"
        Print File ARQIMP LINHA2+"\n"
        Print File ARQIMP LINHA3+"\n"
        Print File ARQIMP LINHA4+"\n"
        Print File ARQIMP LINHA5+"\n"
        Print File ARQIMP "\n\n\n\n"
 
        QUEBRA_PAGINA=QUEBRA_PAGINA+2
EndIf

netiq =0
LINHA1=""
LINHA2=""
LINHA3=""
LINHA4=""
LINHA5=""
LINHA6=""

If QUEBRA_PAGINA=14
   Then QUEBRA_PAGINA = 0
        Print File ARQIMP "\f"
EndIf

EndProc                                         

;*******************************************************************************
;* Monta Comandos p/ Impressora Termica                                        *
;*******************************************************************************
Verifica=False

;********* Imprime Certificados *******
ArqImp=PrivDir()+"EV_0343A.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

QUEBRA_PAGINA=0
netiq=0
Imprime_Etiqueta()

CoEdit "Answer"
Scan
  NUMNOT      = [Numero do Documento]
  NCOP        = [NCopias]
  RAZAOSOCIAL = [Razao Social]
  CIDADE      = [Cidade      ]
  ESTADO      = [UF          ]
  RAZTRA      = ""
  VOLUME      = 0
  TPDOCTO     = ""
  
  GetRecord "\\Sistemas\\Vendas\\FaturaC" [Numero da OF] To REG_FATURAC
  If RetVal
    Then RAZTRA  = REG_FATURAC["Razao Social Transport"]
         VOLUME  = StrVal(REG_FATURAC["Numero de Volumes"])
         TPDOCTO = REG_FATURAC["Docto Nota Gerada"]
  EndIf
  
  ;---- Formata‡Æo da Etiqueta -------------------------------------------------
  
  RAZTRA  = Spaces(1)+Format("W39"," "+RAZTRA)
  CLIENTE = Spaces(1)+Format("W39"," CLIENTE: "+RAZAOSOCIAL)
  CIDADE  = Spaces(1)+Format("39","  CIDADE: "+Rtrim(CIDADE)+"/"+ESTADO)
  TM = NumVal(VOLUME)
  If IsBlank(TM) Or TM<=0 Or Type(TM)<>"N"
     Then TM = 1
  EndIf
  FIM    = ALINHM(StrVal(TM),3)
  VOLUME = Spaces(1)+Format("W15"," VOLUMES: "+VOLUME)+" "
  For wi From 1 To TM
    AGUARDE("Imprimindo Etiquetas")
    INI = ALINHM(StrVal(wi),3)
    ETQ   = Format("W17","ETIQUETA: "+INI+"/"+FIM)   
    If Rtrim(TPDOCTO)<>""
       Then NOTAFISC = Format("39","     "+TPDOCTO+": "+NUMNOT)
       Else NOTAFISC = Format("39",NUMNOT)
    EndIf    
    
    LINHA1=LINHA1+CLIENTE
    LINHA2=LINHA2+CIDADE
    LINHA3=LINHA3+VOLUME+ETQ
    LINHA4=LINHA4+NOTAFISC
    LINHA5=LINHA5+RAZTRA

    netiq=netiq+1
    If netiq=2
       Then Imprime_Etiqueta()
       Else LINHA1=Completa(LINHA1,40," ")
            LINHA2=Completa(LINHA2,40," ")
            LINHA3=Completa(LINHA3,40," ")
            LINHA4=Completa(LINHA4,40," ")
            LINHA5=Completa(LINHA5,40," ")
    EndIf
  EndFor
EndScan
Imprime_Etiqueta()
Do_It!
ClearAll

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)
LIMPAGUARDE()

Release Procs Imprime_Etiqueta
