;** RO_0258 ********************************************************************
;** Imprime a Digitacao do Romaneio                    ** DJ CONSTRUCOES **    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 31/05/2010 por Bruno Carvalho
;Ultima Alteracao: 02/07/2010 por Bruno Carvalho
;Motivo Alteracao: Desconto Alterado - Calcular Desc. Unitarios de Cada Item
;Ultima Alteracao: 12/07/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes pro Campo TOTAL
;Ultima Alteracao: 15/06/2016 por Bruno Carvalho 
;Motivo Alteracao: Adicionado Pega_Endereco_Fatura() e ajustado dados do endere‡o
;Ultima Alteracao: 31/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desconto item

;*******************************************************************************
;* Rotina para Impressao do Relatorio                                          *
;*******************************************************************************
Proc IMPFAT()

;************************** IMPRESSAO DO CABECALHO *****************************
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf
Print File ARQIMP chr(27)+chr(67)+chr(33) ;Imprime 33 Linhas por pagina
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP

Moveto "FaturaC"
Pega_Endereco_Fatura([Numero da OF])

Moveto [Codigo]
Ativa_Lookup()
Moveto [Codigo]
Locate [FaturaC->Codigo]
If RetVal
   Then ROTA="  "+[Codigo da Area]+" "+[Descricao da Area]
   Else ROTA="???"
EndIf
KeyPress "ESC"

Moveto "FaturaC"
Print File ARQIMP "\n"
Print File ARQIMP Format("W50,AL","CONTROLE INTERNO")+"Impressao: "+Format("D10",[Data de Emissao])+"-"+Time()+ "\n\n"

Print File ARQIMP "\014"
Print File ARQIMP "\027E"
Print File ARQIMP Spaces(20)+"Orcamento N§ "+Format("W06.3,AL",NOTAFISC)+"\n\n"
Print File ARQIMP "\020"

Print File ARQIMP "Cliente : "+Format("W05,AL",[Codigo])+Format("W46,AL",[Razao Social])+"\n"
Print File ARQIMP "\027F"

Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP

Print File ARQIMP Spaces(10)+Format("W40,AL",[Endereco])
Print File ARQIMP Format("W18,AL",[CGC])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Bairro])
Print File ARQIMP Format("W20,AL",[CEP])
Print File ARQIMP Format("W25,AL",[IE])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Cidade])
Print File ARQIMP Format("W20,AL",[UF])
Print File ARQIMP Format("W25,AL",[Telefone])+"\n"

Print File ARQIMP "\027E"
Print File ARQIMP "Entrega : "+Format("W39,AL",VSD_E_Endereco)+" Bairro :" +Format("W15,AL",VSD_E_Bairro)+"\n" 
Print File ARQIMP "\027F"

Print File ARQIMP "Vendedor: "+Format("W05,AL",[Codigo do Representante])
Print File ARQIMP Format("W25,AL",[Nome Fantasia Represent])+"\n"
Print File ARQIMP CI_15CPP

;********************* IMPRESSAO DOS ITENS ********************************
Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------------------------"+"\n"
Print File ARQIMP Spaces(02)+"Item                                              Marca                       Un.Emb  Quant.Emb  Un  Quantidade  Unitario        Total"+"\n"
Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------------------------"+"\n"

CONTADOR=0
DESCONTO=0

Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]

  Moveto [Codigo do Item]
  Ativa_Lookup()
  Moveto [Codigo do Item]
  Locate [FaturaI->Codigo do Item]
  If RetVal
     Then UNEMB=[Unidade Embalagem]
          MARCA=[Descricao da Marca]
          If IsBlank([Fator Conversao Embalagem])
             Then FATCON=1
             Else FATCON=[Fator Conversao Embalagem]
          EndIf
     Else UNEMB=""
          MARCA=""
  EndIf
  KeyPress "ESC"
  UnlockRecord

  Print File ARQIMP Spaces(02)+Format("W02,AL",[Item da OF])
  Print File ARQIMP Spaces(01)+Format("W11,AL",[Codigo do Item])
  Print File ARQIMP Spaces(01)+Format("W34,AL",[Descricao do Item])
  Print File ARQIMP Spaces(01)+Format("W27,AL",MARCA)  
  If Not IsBlank(UNEMB)
     Then Print File ARQIMP Spaces(05)+Format("W03,Al",UNEMB)
          Print File ARQIMP Format("W10.2,EIC",([Quantidade]/FATCON))
  EndIf
  Print File ARQIMP Spaces(02)+Format("W03,Al",[Unidade Fiscal])
  Print File ARQIMP Format("W11.2,EIC",[Quantidade])
  Print File ARQIMP Format("W10.2,EIC",[Preco Unitario])
  Print File ARQIMP Format("W13.2,EIC",[Quantidade]*[Preco Unitario])+"\n"
  
  DESCONTO = DESCONTO+[Valor Desconto Item]              ;Total Desconto Unit rio
  
  Skip
  If EOT() Then QuitLoop EndIf
  CONTADOR = CONTADOR + 1
EndWhile

For ITEM From CONTADOR To 10
    Print File ARQIMP "\n"
EndFor

Print File ARQIMP "\027E"
Print File ARQIMP "Observacao: "+Format("W120,AL",[FaturaC->Observacao na Nota Fiscal])+"\n"
Print File ARQIMP "\027F"
Print File ARQIMP "----------------------------------------------------------------------------------------------------------------------------------------"+"\n"

;********************* IMPRESSAO DOS TOTAIS **************************
Moveto "FaturaC"
TOTD=(([Valor Desconto]+DESCONTO)*100)/([Valor Mercadoria]+DESCONTO)

Print File ARQIMP Spaces(104)+"Total................"+Format("W11.2,EIC",[Valor Mercadoria]+DESCONTO)+"\n"

Print File ARQIMP "Transportadora: "+ Format("W04,AL",[Codigo da Transportadora])+ " " +Format("W20,AL",[Nome Fantasia Transport])
Print File ARQIMP Spaces(63)+"Desconto............."+Format("W11.2,EIC",[Valor Desconto]+DESCONTO)+"\n"

If [Frete Incluso na Nota]="+"
   Then Print File ARQIMP Spaces(104)+"Valor Frete.........."+Format("W11.2,EIC",[Valor do Frete])+"\n"
EndIf

Print File ARQIMP Spaces(104)+"Valor Total.........."+Format("W11.2,EIC",[Valor Nota Fiscal])+"\n"

Print File ARQIMP "Cond. Pagto: "+[Descricao CondPagto]
Print File ARQIMP "   NP: "+StrVal([Numero de Parcelas])
Print File ARQIMP "   CD: "+[Composicao de Dias]+"\n"
;********************* IMPRESSAO DOS VENCIMENTOS **************************

Print File ARQIMP "\027E"
Print File ARQIMP "Vencimentos: "

Array DATA[9]
Array VALOR[9]
K=0
KV=0
Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
  K=K+1
  DATA[K]  = Format("D13",[Data])
  VALOR[K] = Format("W10.2,AR,EIC",[Valor])
  If K=9
     Then VENC()
          K=0
  EndIf
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile
If K>0
   Then VENC()
EndIf
Print File ARQIMP "\n"

;************************* IMPRESSAO DO RODAPE *********************************
Print File ARQIMP "\027F"
Print File ARQIMP Spaces(12)+"   /   /     -                                   " + "\n"
Print File ARQIMP Spaces(12)+"-------------------------------------------------" + "\n"
Print File ARQIMP Spaces(12)+"              Data e Assinatura"+"\n"
Print File ARQIMP CI_6LPP
Print File ARQIMP CI_10CPP
Print File ARQIMP "\f"
EndProc

;*******************************************************************************
;* Rotina de Impressao dos Vencimentos                                         *
;*******************************************************************************
Proc VENC()
If KV>0
   Then Print File ARQIMP Spaces(13)
EndIf
For I From 1 to K
  Print File ARQIMP DATA[I]+Spaces(02)
EndFor
Print File ARQIMP "\n"
Print File ARQIMP Spaces(13)
For I From 1 to K
  Print File ARQIMP VALOR[I]+Spaces(02)
EndFor
Print File ARQIMP "\n\n"

KV=KV+1
EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************

ArqImp=PrivDir()+"Ro_0025.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)
IMPFAT()

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_6LPP

Release Vars   VALOR,DATA,ROTA
Release Procs  IMPFAT,VENC
LIMPAGUARDE()


