;** Historic *******************************************************************
;*  Manutencao Cadastro de Historico Contabil p/ Conta Corrente                *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 29/08/2001 por Douglas Rodrigues
;Motivo Alteracao: Reajuste Sequencia
;Ultima Alteracao: 23/05/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Controla_Edicao
;Ultima Alteracao: 29/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Novo Layout de Teclas
;Ultima Alteracao: 01/01/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes SetaCorRegistro("Editando") 

;*******************************************************************************
;* Rotina para Localizar Registro                                              *
;*******************************************************************************
Proc CHAVE()

While True
  SetaCorRegistro("Editar")
  End
  SEQ = [Codigo do Historico]
  Down
  Moveto [Codigo do Historico]

  TECLA=""
  AguardaTeclasPadrao()

  Switch
  Case RetVal=-33 : SemFuncoes()
  Case RetVal="F3": SemFicha()
  Case RetVal=-94 : MsgTeclasPadrao()
  Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
       While True
         PAGINA("Historic","MR")
         If EDITAR="S"
            Then CHAVE=0
                 Controla_EdicaoC()
            Else If EXCLUIR="S"
                    Then If QuerExcluir("")
                            Then DEL
                            Else UnLockRecord
                         EndIf
                    Else QuitLoop
                 EndIf
         EndIf
         SetaPosForm()
       EndWhile
  Case Retval="ESC":
       CHAVE=9
       Del
       QuitLoop
  Case Retval="ENTER":
       If IsBlank([])
          Then If IsBlank(SEQ)
                  Then []="1"
                  Else []=StrVal(NumVal(SEQ)+1)
               EndIf
       EndIf
       []=Alinh()
       CODIGO=[]
       Del
       Moveto [Codigo do Historico]
       Locate CODIGO
       If Retval
          Then CHAVE=0
          Else CHAVE=1
               End Down
               [Codigo do Historico]=CODIGO
               CHAVE=1
       EndIf
       If IsLockRecord() Then Loop EndIf
       QuitLoop
  EndSwitch
EndWhile
EndProc

;*******************************************************************************
;* Rotina para Digitacao das Informacoes                                       *
;*******************************************************************************
Proc DIGITA()

Moveto [Descricao do Historico]
While True
      TECLA= " Esc=Retornar  F5=Parametros  "
      If CHAVE=0
         Then TECLA=TECLA + "Del=Excluir  "
      EndIf
      Prompt TECLA
      SetaCorRegistro("Editando")
      Wait Field
           Until "ESC","ENTER","DEL","FIELDVIEW","F35","F5"

      Switch
      Case RetVal="F5":
           PARAMETRO()
      Case Retval="ESC":
           If Field()="Descricao do Historico"
              Then If QuerDesfazer("")
                      Then If CHAVE=1
                              Then Del
                              Else Undo
                           EndIf
                           CHAVE=9
                           QuitLoop
                   EndIf
              Else Left
           EndIf
      Case Retval="ENTER":
           If IsBlank([]) Then Loop EndIf
           If Field() = "Descricao do Historico"
              Then QuitLoop
              Else Right
           EndIf
      Case Retval="FIELDVIEW" or Retval="F35":
           EDITFIELD()
      Case Retval="DEL":
           If CHAVE=0
              Then If QuerExcluir("")
                      Then DEL
                           QuitLoop
                   EndIf
           EndIf
      EndSwitch
EndWhile
EndProc


;*******************************************************************************
;* Rotina p/ Visualizar tipos de parametros                                    *
;*******************************************************************************
Proc PARAMETRO()
ShowDialog "Parƒmetros do Hist¢rico" @ 08,30 height 12 width 45
  @ 00,00 ?? " Texto      Descri‡„o                    "
  @ 01,00 ?? " ---------- -----------------------------"
  @ 02,00 ?? " *CHEQUE*   N£mero do Cheque             "
  @ 03,00 ?? " *CONTDEST* Descri‡„o da Conta Destino   "
  @ 04,00 ?? " *CONTORIG* Descri‡„o da Conta Origem    "
  @ 05,00 ?? " *DATALCTO* Data do Lan‡amento           "
  @ 06,00 ?? " *DOCTO*    N£mero do Documento          "
  @ 07,00 ?? " *TPDOCTO*  Tipo do Documento            "
  @ 08,00 ?? " *MESANO*   Mˆs/Ano da Data do Lan‡amento"
  @ 09,00 ?? " *LIVRE*    Digita‡„o Livre              "

  Pushbutton @ 01,50 width 10 "OK" OK default Value "Say Yes" Tag "YES"  to BottonValue
  Pushbutton @ 01,55 width 10 "CANCEL" CANCEL Tag "NO"  to BottonValue

Enddialog
EndProc

;*******************************************************************************
;* Rotina para controlar Edicao do registro                                    *
;*******************************************************************************
Proc Controla_EdicaoC()
DIGITA()
If RecordStatus("Locked") Then UnLockRecord EndIf         
EndProc

;*******************************************************************************
;* Rotina Princiap                                                             *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"
CoEdit "Historic"
PickForm "F"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
  Controla_EdicaoC()
EndWhile
Do_It!
ClearAll
Release Vars All
Release Procs All
