;** CB_0003 ********************************************************************
;* Carta de Cobranca IV                                                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 22/06/2009 por Cleber Alves
;Alterado em     : 26/06/2009 por Cleber Alves
;Motivo Alteracao: Ajustes
;Alterado em     : 23/02/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes SYS_CODIGO_CLIENTE (Linha 116)

;*******************************************************************************
;* Rotina para Impressao do Cabecalho da Carta                                 *
;*******************************************************************************
Proc IMPCAB_CARTA()

NFOLHA=NFOLHA+1

Print File ARQIMP "\n"  
Print File ARQIMP Spaces(65)+"Folha: "+StrVAl(NFOLHA)+"\n\n"
Print File ARQIMP Spaces(03)+EMP_CID+", "+
                  StrVal(Day(Today()))+" DE "+
                  RTrim(MesExt(Month(Today())))+" DE "+
                  StrVal(Year(Today()))+"\n\n"

Print File ARQIMP Spaces(03)+" "+"\n\n\n\n\n\n"
Print File ARQIMP Spaces(10)+CLI_RAZ +" - "+CODCLIANT+"\n"
Print File ARQIMP Spaces(10)+CLI_END +"\n"
Print File ARQIMP Spaces(10)+CLI_BAIR+" - "+CLI_CEP+"\n"
Print File ARQIMP Spaces(10)+CLI_CID +"/"+CLI_UF+"\n\n\n\n"


Print File ARQIMP Spaces(03)+"    Constando na rela‡Æo de  nossos  bons  clientes,  tomamos  a  liberdade"+"\n"
Print File ARQIMP Spaces(03)+"de comunicar-lhe que nÆo foram enviados os  cheques referente ao seu pedido "+"\n"
Print File ARQIMP Spaces(03)+"com valores e vencimentos abaixo, que deve ter ocorrido  por  esquecimento."+"\n\n"

Print File ARQIMP Spaces(03)+"    Devido ao fato de  nÆo  estarmos  conseguindo  comunica‡Æo  atrav‚s  do "+"\n"
Print File ARQIMP Spaces(03)+"telefone existente  em nosso cadastro, pedimos que envie os cheques e entre "+"\n"
Print File ARQIMP Spaces(03)+"em  contato com a nossa empresa atrav‚s do telefone "+CI_INEG+Format("w14,AC",EMP_FONE)+CI_FNEG+" para que "+"\n"
Print File ARQIMP Spaces(03)+"seja regularizada sua(s) pendˆncia(s), evitando despesas de juros, pois nos "+"\n"
Print File ARQIMP Spaces(03)+"dias de hoje a pontualidade sÆo suas melhores recomenda‡äes. "+"\n\n"

Print File ARQIMP Spaces(03)+"    Os valores em atraso serÆo  reajustados  ap¢s  a  data  do  vencimento. "+"\n\n"

Print File ARQIMP Spaces(03)+"    Tendo em vista que a emissÆo deste aviso ‚ autom tica, por  computador, "+"\n"
Print File ARQIMP Spaces(03)+"caso V.S¦ j  tenha  pago  at‚  a  data  da  entrega  do  mesmo, solicitamos "+"\n"
Print File ARQIMP Spaces(03)+"inutiliz -lo."+"\n\n"

LINHA1="     Data   Numero       Data      Valor     Valor     Valor  Dias   "
LINHA2="   Emissao  Documento   Vencto     Total  Original     Juros  Atraso "
         ;99/99/99 1234567890 99/99/99 99.999,99 99.999,99 99.999,99 99.999 1234567890


Print File ARQIMP LINHA1+"\n"
Print File ARQIMP LINHA2+"\n"

Nl=36
EndProc

;*******************************************************************************
;* Rotina para Impressao dos Titulos da Carta                                  *
;*******************************************************************************
Proc IMPTIT_CARTA()

If (Today()-[Data de Vencimento])<= 0
   Then DAtraso = "  EM ABERTO"
   Else DAtraso = Format("W8,EIC",Today()-[Data de Vencimento]) 
EndIF
Print File ARQIMP Spaces(2)+Format("D10",[Data de Emissao])+" "
Print File ARQIMP Format("W11,AL",[Numero do Documento])
Print File ARQIMP Format("D10",[Data de Vencimento])
Print File ARQIMP Format("W10.2,EIC",[Valor do Documento])
Print File ARQIMP Format("W10.2,EIC",[Saldo do Documento])
Print File ARQIMP Format("W10.2,EIC",[Valor do Desconto])
Print File ARQIMP DAtraso

Print File ARQIMP "\n"

nl=nl+1

EndProc

;*******************************************************************************
;* Rotina para Impressao nova Folha                                            *
;*******************************************************************************
Proc IMPNOVA_FOLHA()

NFOLHA=NFOLHA+1
Print File ARQIMP CI_INEG+" * Continua Pr¢xima Folha -> "+StrVAl(NFOLHA)+CI_FNEG+"\f"

Print File ARQIMP "\n"  
Print File ARQIMP Spaces(65)+"Folha: "+StrVAl(NFOLHA)+"\n\n"
nl=3
EndProc

;*******************************************************************************
;* Rotina para Impressao do Rodape da Carta                                    *
;*******************************************************************************
Proc IMPROD_CARTA()

Print File ARQIMP SPACES(21)+" TOTAL ->"+CI_INEG+
                             Format("W10.2,EIC",TOTVR)+
                             Format("W10.2,EIC",ORIVR)+Format("W10.2,EIC",JURVR)+
                             Format("W7,AR",NTIT)+" Titulos"+CI_FNEG+"\n\n\n"
nl=nl+3

if nl>53
   Then IMPNOVA_FOLHA()
EndIF

Print File ARQIMP "     Sem mais para o momento"+"\n\n\n\n"
Print File ARQIMP "     Atenciosamente,"+"\n\n\n\n"
                  
Print File ARQIMP Spaces(05)+"----------------------------------------------------"+"\n"

Switch
    Case SYS_CODIGO_CLIENTE="0051" : 
        Print File ARQIMP "     Setor de Cobran‡a - ModaMil Com‚rcio de Tecidos LTDA"+"\n\n\n"
    Otherwise :
        Print File ARQIMP Spaces(05)+Format("W40,AL",EMP_RAZ)+"\n"
        Print File ARQIMP Spaces(05)+Format("W40,AL",EMP_CONT)+"\n"
        Print File ARQIMP Spaces(05)+Format("W30,AL",EMP_FONE)+"\n"
EndSwitch

Print File ARQIMP "\f"

EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Seta_FilePrint("CB_0003")

AGUARDE("Imprimindo Carta de Cobran‡a")

CODEMPANT="***"
CODCLIANT="***"
CoEdit "Answer"
Scan

  If [Codigo da Empresa]<>CODEMPANT
     Then CODEMPANT=[Codigo da Empresa]

          Moveto [Codigo da Empresa]
          If Busca_Lookup("Codigo da Empresa",[Codigo da Empresa],"SM")
             Then EMP_NOMF=REG_BUSCA_LOOKUP["Nome Fantasia Empresa"]
                  EMP_RAZ =REG_BUSCA_LOOKUP["Razao Social Empresa" ]
                  EMP_END =REG_BUSCA_LOOKUP["Endereco Empresa"     ]
                  EMP_BAIR=REG_BUSCA_LOOKUP["Bairro Empresa"       ]
                  EMP_CID =REG_BUSCA_LOOKUP["Cidade Empresa"       ]
                  EMP_UF  =REG_BUSCA_LOOKUP["UF Empresa"           ]
                  EMP_CEP =REG_BUSCA_LOOKUP["CEP Empresa"          ]
                  EMP_FONE=REG_BUSCA_LOOKUP["Telefone Empresa"     ]
                  EMP_CONT=REG_BUSCA_LOOKUP["Contato Empresa"      ]
                  
          EndIf
  EndIf

  If [Codigo do Destinatario]<>CODCLIANT
     Then
          If CODCLIANT<>"***"
             Then IMPROD_CARTA()
          EndIf

          CODCLIANT=[Codigo do Destinatario]
          NFOLHA   =0
          TOTVR    =0
          ORIVR    =0
          JURVR    =0
          NTIT     =0
          Moveto [Codigo do Destinatario]
          If Busca_Lookup("Codigo",[Codigo do Destinatario],"SM")
             Then CLI_RAZ =REG_BUSCA_LOOKUP["Razao Social"]
                  CLI_END =REG_BUSCA_LOOKUP["Endereco"]
                  CLI_BAIR=REG_BUSCA_LOOKUP["Bairro"]
                  CLI_CID =REG_BUSCA_LOOKUP["Cidade"]
                  CLI_UF  =REG_BUSCA_LOOKUP["UF"]
                  CLI_CEP =REG_BUSCA_LOOKUP["CEP"]
                  CLI_FONE=REG_BUSCA_LOOKUP["Telefone"]
             Else CLI_RAZ ="????"
                  CLI_END =""
                  CLI_BAIR=""
                  CLI_CID =""
                  CLI_UF  =""
                  CLI_CEP =""
                  CLI_FONE=""
          EndIf
          IMPCAB_CARTA()
  EndIf

  If nl>60
     Then IMPNOVA_FOLHA()
  EndIf
 
  ImpTit_Carta()

  NTIT=NTIT+1
  ORIVR=ORIVR+[Saldo do Documento]
  TOTVR=TOTVR+[Valor do Documento]
  JURVR=JURVR+[Valor do Desconto]

EndScan
IMPROD_CARTA()
Do_It!
ClearAll

ImpriArq(ARQIMP)

LIMPAGUARDE()
Release Vars NL,NTIT,TOTVR,ORIVR,JURVR
Release Procs IMPCAB_Carta,IMPTit_Carta, ImpRod_Carta, IMPNOVA_FOLHA
