;** ALTCOMIS *******************************************************************
;*  Altera‡Æo de ComissÆo  (Lupus/YVN/Siri)                                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 21/01/2011 por Bruno Carvalho             
;Ultima Alteracao: 15/02/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Data referente a entrada de Pedidos
;Ultima Alteracao: 03/03/2011 por Bruno Carvalho   
;Motivo Alteracao: Adicionado rotina parar alterar a comissao do Faturamento
;Ultima Alteracao: 19/07/2011 por Karina Andrade   
;Motivo Alteracao: Liberado rotina para Siri
;Ultima Alteracao: 09/07/2014 por Kamila Gomes
;Motivo Alteracao: Adicionado Filtro por Marca solicitado pela Lupus
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajsutes na ASK Comissao_Nota() ao montar os dados do pedido
;Ultima Alteracao: 13/09/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modo ordem da duplicata numero/letra
;Ultima Alteracao: 27/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes bib_parm                                

;*******************************************************************************
; Script para alterar a % da comissÆo do Faturamento, e assim alterar os valores
; do comissionamento em cada parcela, se esta estiver Numero de Parcelas > 1 e o
; mesmo com a duplic, em que ir  alterar de acordo com a nota, se tiver comissÆo
; e o valor da baixa esta rateado, a comissÆo sera ajustada de acordo com o valr 
;*******************************************************************************
;Rotina                                                                        *
;*******************************************************************************
Proc Comissao_Nota()
Private CHV_NUMERO_ORDEM, CONT
ClearAll
{Ask} {\\Sistemas\\Vendas\\PedidoC} 
Moveto [Numero do Pedido       ] Check 
If VSDGMARCA<>""
   Then Example "nped"
EndIf                      
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Descricao da Destinacao] TypeIn "..VEND.."
If VSDGMARCA<>""
   Then {Ask} {\\Sistemas\\Vendas\\PedidoI} 
        Moveto [Numero do Pedido       ] Example "nped"
        Moveto [Codigo do Item         ] Example "Ite"
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ] Example "Ite"
        Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        Do_It!
        ClearAll
Endif

CoEdit "PedidoC", "Answer"
Scan
 Moveto "PedidoC"
 Moveto [Numero do Pedido]
 Locate [Answer->Numero do Pedido]
 If Not RetVal
    Then Moveto "Answer"
         Loop
    Else [Comissao do Representante]=VSDGTAXAC
         UnLockRecord
 EndIf    

 Moveto "Answer"
EndScan     
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

{Ask} TypeIn Tabela Enter
Moveto [Numero do Pedido       ] Example "nped"                  
{Ask} {\\Sistemas\\Vendas\\FaturaC} Check 
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Descricao da Destinacao] TypeIn "..VEND.."
Moveto [Tipo Movimento Estoque ] TypeIn "S"
Moveto [Numero do Pedido       ] Example "nped"                  
Do_It!
ClearAll

CoEdit "FaturaC", "Answer"
Scan
 Moveto "FaturaC"
 Moveto [Numero do Pedido]
 Locate [Answer->Numero do Pedido]
 If Not RetVal
    Then Moveto "Answer"
         Loop
    Else [Comissao do Representante]=VSDGTAXAC
         UnLockRecord
 EndIf   
 Moveto "Answer"
EndScan     
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Numero do Pedido       ] Example "nped"                  
{Ask} {\\Sistemas\\Vendas\\NotaC} Check 
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Descricao da Destinacao] TypeIn "..VEND.."
Moveto [Tipo Movimento Estoque ] TypeIn "S"
Moveto [Situacao               ] TypeIn "Not C"
Moveto [Numero do Pedido       ] Example "nped"                  
Do_It!
ClearAll


getsys_modo_ordemdup()
        
CoEdit "\\Sistemas\\Ctarec\\Duplic","\\Sistemas\\Ctarec\\Dupbaixa","NotaV","NotaC","Answer"

Scan

 Moveto "NotaC"
 Moveto [Codigo da Empresa]
 Locate [Answer->Codigo da Empresa],
        [Answer->Numero do Documento],
        [Answer->Serie do Documento]
 If Not RetVal
    Then Moveto "Answer"
         Loop
    Else [Comissao do Representante]=VSDGTAXAC
         UnLockRecord
 EndIf    

 Moveto "NotaV"
 Moveto [Codigo da Empresa]
 Locate [Answer->Codigo da Empresa],
        [Answer->Numero do Documento],
        [Answer->Serie do Documento]
 If Not RetVal
    Then Moveto "Answer"
         Loop
 EndIf               

 NPARC=0
 While [Codigo da Empresa  ]=[Answer->Codigo da Empresa  ] And
       [Numero do Documento]=[Answer->Numero do Documento] And
       [Serie do Documento ]=[Answer->Serie do Documento ]
   NPARC=NPARC+1
   Skip
   IF EOT() Then QuitLoop EndIf
 EndWhile

 i=1
 DP_CONTDP=0
 Moveto [Codigo da Empresa]
 Locate [Answer->Codigo da Empresa],
        [Answer->Numero do Documento],
        [Answer->Serie do Documento]
 
 While [Codigo da Empresa  ]=[Answer->Codigo da Empresa  ] And
       [Numero do Documento]=[Answer->Numero do Documento] And
       [Serie do Documento ]=[Answer->Serie do Documento ]

 DP_CONTDP=DP_CONTDP+1

 CHV_EMPRESA=[Answer->Codigo da Empresa  ]
 CHV_TPDOCTO=[Answer->Codigo do Documento]

  switch
    case sys_modo_ordemdup="N":
       CHV_NUMERO_ORDEM=[Answer->Numero do Documento]+"/"+strval(DP_CONTDP)
    
    otherwise                 :
       If NPARC=1
        Then CHV_NUMERO_ORDEM=[Answer->Numero do Documento]
        Else CHV_NUMERO_ORDEM=[Answer->Numero do Documento]+"/"+CHR(65+(DP_CONTDP-1))
       EndIf
  
  endswitch

 VRVENCTO=NDecimal((([Answer->Valor Nota Fiscal]-[Answer->Valor do Frete])/NPARC),2)
 VRDIFERE=[Answer->Valor Nota Fiscal]-(VRVENCTO*NPARC)
  
 If [Answer->Frete Incluso na Nota]="+"
    Then VREF=NDecimal((([Answer->Valor Nota Fiscal]-[Answer->Valor do Frete])*[Answer->Comissao do Representante])/100,2)
    Else VREF=NDecimal(([Answer->Valor Nota Fiscal]*[Answer->Comissao do Representante])/100,2)
 EndIf
 VCVENCTO=NDecimal((VREF/NPARC),2)
 VCDIFERE=VREF-(VCVENCTO*NPARC)
  
 If [Answer->Frete Incluso na Nota]="+"
    Then If i=1
            Then [Valor            ]=VRVENCTO+VRDIFERE
                 [Valor da Comissao]=VCVENCTO+VCDIFERE
            Else [Valor            ]=VRVENCTO
                 [Valor da Comissao]=VCVENCTO
         EndIf
    Else If i<>NPARC
            Then [Valor            ]=VRVENCTO
                 [Valor da Comissao]=VCVENCTO
            Else [Valor            ]=VRVENCTO+VRDIFERE
                 [Valor da Comissao]=VCVENCTO+VCDIFERE
         EndIf
 EndIf
 UnLockRecord
  
 i=i+1
 
 Moveto "\\Sistemas\\CtaRec\\Duplic"
 Moveto [Codigo da Empresa]
 Locate IndexOrder by "IndDup1" CHV_EMPRESA,CHV_TPDOCTO,CHV_NUMERO_ORDEM
 If RetVal
    Then tx_comis=[Answer->Comissao do Representante]
         [Valor da Comissao]=Round(([Valor do Documento]*tx_Comis)/100,2)
         [Saldo da Comissao]=[Valor da Comissao]
         UnLockRecord

         Moveto "\\Sistemas\\CtaRec\\DupBaixa"
         Moveto [Numero do Lancamento]
         Locate [\Sistemas\Ctarec\Duplic->Numero do Lancamento]
         If RetVal
            Then While [Numero do Lancamento]=[\Sistemas\Ctarec\Duplic->Numero do Lancamento]
                    Vr=([Valor do Recebimento]+[Valor do Desconto])-[Valor do Juros]  
                    Vr=Round((Vr*tx_Comis)/100,2)
                    [Valor da Comissao]=Vr
                    UnLockRecord
        
                    Moveto "\\Sistemas\\CtaRec\\Duplic"
                    [Saldo da Comissao]=[Saldo da Comissao]-Vr
                    UnLockRecord
         
                    Moveto "\\Sistemas\\CtaRec\\DupBaixa"
                  Skip
                  IF EOT() Then QuitLoop EndIf
                 EndWhile
         EndIf
 
 EndIf   

  Moveto "NotaV"
  Skip
  IF EOT() Then QuitLoop EndIf    
 EndWhile

 Moveto "Answer"
EndScan     
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESA"
            Case Campo="TG_MARCA"         : Campo="TG_REPRESEN"
            Case Campo="TG_TAXAC"         : Campo="TG_MARCA"
            Case Campo="TG_DTINI"         : Campo="TG_TAXAC"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN" : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"    : Campo="TG_TAXAC"
                    Case Campo="TG_TAXAC"    :
                         VSDGTAXAC=ControlValue("TG_TAXAC")
                         If Not IsBlank(VSDGTAXAC) Or VSDGTAXAC >= 0
                            Then Campo="TG_DTINI"
                         EndIf
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_TAXAC":
     MSG_CAMPO="Informe a Taxa de Comiss„o"
  Case Campo="TG_MARCA":
     MSG_CAMPO="Informe a Marca"   
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Parm"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE="" EndIf
LimpAguarde()

VSDGEMPRESA =""
VSDGREPRESEN=""
VSDGTAXAC 	=BlankNum()
VSDGDTINI 	=BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Altera‡„o de Comiss„o por Representante" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

		Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR
    
    Label  @ 04,00 "Marca"  For "TG_MARCA"
    Accept @ 05,02 Width 06 "A4"  Picture "[&,#][#*#]" Tag "TG_MARCA" To VSDGMARCA
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMMARCA"  To VSDGNOMMARCA

    Label  @ 06,00 "% Comiss„o"  For "TG_TAXAC"
    Accept @ 07,01 Width 10 "N" Tag "TG_TAXAC" To VSDGTAXAC

    Label  @ 08,00 "Per¡odo EmissÆo dos Pedidos de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If SYS_CODIGO_CLIENTE="0222" Or
     SYS_CODIGO_CLIENTE="0186" Or
     SYS_CODIGO_CLIENTE="0227"
     Then AGUARDE("Aguarde, alterando dados!")
          Comissao_Nota()
          Mensagem("Opera‡„o realizada com sucesso!")
     Else MSG=    " Rotina n„o liberada !//"
          MSG=MSG+"Verificar com o Suporte!"
          Mensagem(MSG)
          Release Vars COR_MENSAGEM
          Loop
  EndIf     
   
EndWhile
ClearAll
Release Vars All
Release Procs All
