;** Et_Z001F *******************************************************************
;* Monta Etiqueta p/ Impressora Termica - Zebra - EAN13                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 18/05/2012 por Bruno Carvalho
;Ultima Alteracao: 06/11/2018 por Bruno Carvalho
;Motivo Alteracao: Ajustes padrĈo p/ codigo de barras EAN8, EAN13 ou COD128 

;*******************************************************************************
Proc Monta_Etiqueta()

Moveto "Answer"
Print File Arquivo "O\n"
Print File Arquivo "N\n"
Print File Arquivo "q768\n"
Print File Arquivo "Q167,17+\n"
Print File Arquivo "S2\n"
Print File Arquivo "D8\n"
Print File Arquivo "ZT\n"

If Not IsBlank(CITEM[1])
   Then Print File Arquivo "A00,10,0,1,2,1,N,\""+CITEM[1]+"\"\n"        
        Print File Arquivo "A00,28,0,2,1,1,N,\""+DITEA[1]+"\"\n"
        Print File Arquivo "A00,46,0,2,1,1,N,\""+DITEB[1]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[1])>0 : Print File Arquivo "B10,70,0,E30,2,2,60,B,\""+CDBAR[1]+"\"\n"
          Case Search("EAN8",TPBARRA[1])>0  : Print File Arquivo "B10,70,0,E80,2,2,60,B,\""+CDBAR[1]+"\"\n"
          OtherWise                         : Print File Arquivo "B10,70,0,1,2,2,60,B,\""+CDBAR[1]+"\"\n"  
        EndSwitch  
        ;Print File Arquivo "A00,150,0,3,1,1,N,\""+REFER[1]+"\"\n"                      
EndIf
If Not IsBlank(CITEM[2])
   Then Print File Arquivo "A270,10,0,1,2,1,N,\""+CITEM[2]+"\"\n"
        Print File Arquivo "A270,28,0,2,1,1,N,\""+DITEA[2]+"\"\n"
        Print File Arquivo "A270,46,0,2,1,1,N,\""+DITEB[2]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[2])>0 : Print File Arquivo "B280,70,0,E30,2,2,60,B,\""+CDBAR[2]+"\"\n" 
          Case Search("EAN8",TPBARRA[2])>0  : Print File Arquivo "B280,70,0,E80,2,2,60,B,\""+CDBAR[2]+"\"\n"
          OtherWise                         : Print File Arquivo "B280,70,0,1,2,2,60,B,\""+CDBAR[2]+"\"\n" 
        EndSwitch  
       ;Print File Arquivo "A270,150,0,3,1,1,N,\""+REFER[2]+"\"\n"
EndIf
If Not IsBlank(CITEM[3])
   Then
        Print File Arquivo "A548,10,0,1,2,1,N,\""+CITEM[3]+"\"\n"
        Print File Arquivo "A548,28,0,2,1,1,N,\""+DITEA[3]+"\"\n"
        Print File Arquivo "A548,46,0,2,1,1,N,\""+DITEB[3]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[3])>0 : Print File Arquivo "B556,70,0,E30,2,2,60,B,\""+CDBAR[3]+"\"\n" 
          Case Search("EAN8",TPBARRA[3])>0  : Print File Arquivo "B556,70,0,E80,2,2,60,B,\""+CDBAR[3]+"\"\n"
          OtherWise                         : Print File Arquivo "B556,70,0,1,2,2,60,B,\""+CDBAR[3]+"\"\n" 
        EndSwitch  
       ;Print File Arquivo "A548,150,0,3,1,1,N,\""+REFER[3]+"\"\n" 
EndIf

If CITEM[1]=CITEM[2] And CITEM[1]=CITEM[3]
   Then Print File Arquivo "P"+StrVal(CR)+"\n"
        ce=ce+((CR-1)*3)
   Else Print File Arquivo "P1\n"
EndIf
ne=3
EndProc

;*******************************************************************************
;* Monta Comandos p/ Impressora Termica                                        *
;*******************************************************************************
Proc Monta_Comandos()
If IsAssigned(DITEA)
   Then Release Vars DITEA, DITEB, CITEM, TPBARRA
EndIf
Array   DITEA[3]
Array   DITEB[3]
Array   CDBAR[3]
Array   CITEM[3]
Array TPBARRA[3]
Array   REFER[3]
Array   TAMAN[3]

Arquivo=PrivDir()+"et_Z001B.ejf"
Deleta_Arquivo(Arquivo)

ne=3
Coedit "Answer"
Scan
  te=[Quantidade]
  If (te-(3-ne))>3
     Then CR=Int((te-(3-ne))/3)
     Else CR=1
  EndIf
  ce=0
  While True
    ce=ce+1
    ne=ne+1        
    If ne=4
       Then For i From 1 To 3
              DITEA[i]=""
              DITEB[i]=""
              CDBAR[i]=""
            TPBARRA[i]=""  
              CITEM[i]=""
              TAMAN[i]=""
              ;REFER[i]=""
            EndFor
            ne=1
    EndIf     
    
    TAMAN[ne]=SubStr([Codigo da Marca],1,2)   ; Tamanho do Item (Modelo 83)
    
    CITEM[ne]=[Codigo do Item]
    DITEA[ne]=SubStr([Descricao do Item],01,18)
    DITEB[ne]=Format("W16",SubStr([Descricao do Item],19,14))+TAMAN[ne] 
    CDBAR[ne]=[Codigo de Barras]
  TPBARRA[ne]=Upper([Tipo Codigo_Barras])  
    ;REFER[ne]  ="REF "+[Referencia]
    If ne=3   Then Monta_Etiqueta() EndIf
    If ce>=te Then QuitLoop         EndIf
  EndWhile
EndScan
If ne<3 Then Monta_Etiqueta() EndIf
Do_It!
ClearAll

ImpriArq(Arquivo)

Sleep 700
Deleta_Arquivo(Arquivo)
ClearAll
EndProc

Monta_Comandos()
Release Procs Monta_Etiqueta,Monta_Comandos
