;** Ent_0102 *******************************************************************
;** Imprime o comprovante de Entrega              Concretos Vico              *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 02/01/2003 por Douglas Rodrigues
;Alterado em     : 31/07/2006 por Nikolas M. Mateus
;Motivo Alteracao: Inclusao da Marca
;Alterado em     : 29/06/2006 por Antonio Marcelo Alves
;Motivo Alteracao: Inclusao ImpriArq()
;Alterado em     : 27/03/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Marca
;Ultima Alteracao: 14/08/2007 por Antonio Marcelo Alves
;Motivo Alteracao: Ajustes Deleta_Arquivo
;Ultima Alteracao: 02/06/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado Localiza‡Æo do Item
;Ultima Alteracao: 31/05/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes para impressÆo da destina‡Æo 016 e 017
;Ultima Alteracao: 03/06/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ a palavra DEVOLUCAO ser exibida quando for Nota de DEV.
;Ultima Alteracao: 16/09/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes para tres casas decimais na impressao do campo quantidade
;Ultima Alteracao: 15/06/2016 por Bruno Carvalho 
;Motivo Alteracao: Adicionado Pega_Endereco_Fatura() e ajustado dados do endere‡o

;*******************************************************************************
;* Rotina para Impressao do Relatorio                                          *
;*******************************************************************************
Proc IMPENT()
;************************* IMPRESSAO DO CABECALHO *****************************
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf
Moveto "FaturaC"
Pega_Endereco_Fatura([Numero da OF])

Switch
  Case Search("DEVOL",[Descricao da Destinacao])>0 : If TITULO<>""
                                                        Then COMPLEMENTO=" - DEVOLUCAO"
                                                        Else COMPLEMENTO="DEVOLUCAO" 
                                                     EndIf
  Case [Codigo da Destinacao]="016"    : COMPLEMENTO=" S.R."
  Case [Codigo da Destinacao]="017"    : COMPLEMENTO=" E.F."
  OtherWise                            : COMPLEMENTO=""
EndSwitch   

Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP

Print File ARQIMP CI_IEXP
Print File ARQIMP CI_INEG
Print File ARQIMP CI_FEXP
Print File ARQIMP CI_FNEG
Print File ARQIMP CI_15CPP
Print File ARQIMP Fill("=",79)+"\n"
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_IEXP
Print File ARQIMP CI_INEG
Print File ARQIMP TITULO+COMPLEMENTO+"\n"

Print File ARQIMP CI_15CPP
Print File ARQIMP CI_FEXP
Print File ARQIMP CI_FNEG

Print File ARQIMP Spaces(33)+ "NUMERO:  "+Format("W06.3,AL",NOTAFISC)+"\n"

Print File ARQIMP Spaces(01)+"EMISSAO: "+Format("D13",Today())+"-"+Time()+Spaces(05)+
"VEND: "+Format("W21,AL",[Nome Fantasia Represent])+"\n"
Print File ARQIMP Fill("-",79)+"\n"
Print File ARQIMP Spaces(08)+"EMITIDO PARA FINS DE CONTROLE DE ENTREGA E NAO TEM VALOR FISCAL"+"\n"
Print File ARQIMP Fill("-",79)+"\n"
Print File ARQIMP Spaces(02)+"CLIENTE.: "
Print File ARQIMP Format("W05,AL",[Codigo])
Print File ARQIMP Format("W35,AL",[Razao Social])+"\n"
Print File ARQIMP Spaces(02)+"AUTORIZ.: "+Format("W42,AL",[Nome do Autorizado])+Format("W20,AL",[CPF do Autorizado])+"\n"

CLIENTE=[Razao Social]

If Not BALCAO
   Then Print File ARQIMP Spaces(02)+"ENDERE€O: "+ Format("W40,AL",[Endereco])+"\n"
        Print File ARQIMP Spaces(02)+"BAIRRO..: "+ Format("W20,AL",[Bairro])+
        "FONE: " + Format("W20,AL",[Telefone])+"\n"
        Print File ARQIMP Spaces(02)+"CIDADE..: "+Format("W20,AL",[Cidade])+Spaces(2)+"\n"

        If IsBlank(VSD_C_Endereco) Then VSD_C_Endereco=[Endereco] EndIf
        If IsBlank(VSD_C_Bairro)   Then VSD_C_Bairro=[Bairro]     EndIf
        If IsBlank(VSD_C_Cidade)   Then VSD_C_Cidade=[Cidade]     EndIf
        If IsBlank(VSD_C_CEP)      Then VSD_C_CEP=[Cep]           EndIf
        
        Print File ARQIMP Spaces(02)+"ENTREGA.: "+Format("W33,AL",VSD_C_Endereco)+Spaces(02)+"BAIRRO: "+Format("W20,AL",VSD_C_Bairro)+"\n"
        Print File ARQIMP Spaces(02)+"CIDADE DE ENTREGA: "+Format("W20,AL",VSD_C_Cidade)+Spaces(09)+"CEP: "+Format("W10,AL",VSD_C_CEP)+"\n\n"
           
EndIf
Print File ARQIMP Spaces(02)+"OBS.....: "
Moveto "FaturaC"
If SubStr([Observacao na Nota Fiscal],001,67)<>""
   Then Print File ARQIMP Format("W67,AL",SubStr([Observacao na Nota Fiscal],001,67))+"\n"
EndIf
If SubStr([Observacao na Nota Fiscal],068,67)<>""
   Then Print File ARQIMP Spaces(12)+ Format("W67,AL",SubStr([Observacao na Nota Fiscal],068,67))+"\n"
EndIf
If SubStr([Observacao na Nota Fiscal],136,67)<>""
   Then Print File ARQIMP Spaces(12)+ Format("W67,AL",SubStr([Observacao na Nota Fiscal],136,67))+"\n"
EndIf
If SubStr([Observacao na Nota Fiscal],204,67)<>""
   Then Print File ARQIMP Spaces(12)+ Format("W67,AL",SubStr([Observacao na Nota Fiscal],204,67))+"\n"
   Else Print File ARQIMP "\n"
EndIf
           
;******************************** IMPRESSAO DOS ITENS ********************************
Print File ARQIMP Fill("=",80)+"\n"

Print File ARQIMP Spaces(02)+Format("W11,AL","LOCALIZACAO")
Print File ARQIMP Spaces(02)+Format("W43,AL","PRODUTO")
Print File ARQIMP Format("W03,AL","UF")
Print File ARQIMP Format("W10,AR","QUANT")+"\n"
Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While ([Numero da OF]=[FaturaC->Numero da OF])
   ITEM=[Codigo do Item]
   Moveto [Codigo do Item]
   Ativa_Lookup()
   Moveto [Codigo do Item]
   Locate ITEM
   If RetVal
      Then LOCAL=[Localizacao]
      Else LOCAL=""
   EndIf
   Keypress "ESC"
   Moveto "FaturaI"
   If BALCAO And [Entrega]="S"
      Then Print File ARQIMP Spaces(02) + Format("W10,AL",LOCAL)
           Print File ARQIMP Spaces(03) + Format("W11,AL",[Codigo do Item])
           Print File ARQIMP Format("W32,AL",[Descricao do Item])
           Print File ARQIMP Format("W03,AL",[Unidade Fiscal])
           Print File ARQIMP Format("W10.3,EIC",[Quantidade])+"\n"
           Print File ARQIMP Spaces(26)+Format("W30,AL",[Descricao da Marca])+"\n"

   EndIf
   If PATIO And [Entrega]="N"
      Then Print File ARQIMP Spaces(02) + Format("W10,AL",LOCAL)
           Print File ARQIMP Spaces(03) + Format("W11,AL",[Codigo do Item])
           Print File ARQIMP Format("W32,AL",[Descricao do Item])
           Print File ARQIMP Format("W03,AL",[Unidade Fiscal])
           Print File ARQIMP Format("W10.3,EIC",[Quantidade])+"\n"
           Print File ARQIMP Spaces(26)+Format("W30,AL",[Descricao da Marca])+"\n"

   EndIf
   Skip
   If EOT() Then QuitLoop EndIf
EndWhile

Print File ARQIMP CI_15CPP

Print File ARQIMP CI_FEXP
Print File ARQIMP CI_FNEG

Moveto "FaturaC"
Print File ARQIMP Fill("-",79)+"\n\n\n"
Print File ARQIMP "RECEBI AS MERCADORIAS ACIMA _______/_______/__________"+"\n\n\n"
Print File ARQIMP Spaces(07)+Fill("_",60)+"\n"
Print File ARQIMP Chr(27)+Chr(98)
Print File ARQIMP Spaces(17)+Format("W40,AC",CLIENTE)+"\n\n"
Print File ARQIMP Fill("-",80)+"\n"
Print File ARQIMP Spaces(17)+"NAO VALE COMO N.F PROCURE O CUPOM NO CAIXA"+"\n"
Print File ARQIMP Spaces(17)+"         AGRADECEMOS A PREFERENCIA"+"\n"
Print File ARQIMP Fill("-",80)
If BALCAO And ENT_PATIO
   Then Print File ARQIMP Fill("\n",5)
EndIf
If BALCAO And Not ENT_PATIO
   Then Print File ARQIMP Fill("\n",20)
EndIf
If PATIO
   Then Print File ARQIMP Fill("\n",20)
EndIf
;+"\n\n\n\n\n\n\n\n\n\n\n\n"
EndProc ; (IMPENT)

;*******************************************************************************
;* Rotina p/ Checar as Entregas                                                *
;*****************+*************************************************************
Proc Entrega()
Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While ([Numero da OF]=[FaturaC->Numero da OF])
  If [Entrega]="S"
     Then ENT_BALCAO=True
     Else ENT_PATIO =True
  EndIf
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile
EndProc ; (Entrega)

;*******************************************************************************
;* Rotina Principal                                                            *
;*****************+*************************************************************
BALCAO=False
PATIO =False
ENT_BALCAO=False
ENT_PATIO =False
ArqImp=PrivDir()+"ENT_0102.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf
Entrega()

If ENT_BALCAO
   Then TITULO="ENTREGA NO BALCŽO"
        BALCAO=True
        IMPENT()
        BALCAO=False
EndIf
If ENT_PATIO
   Then TITULO="ENTREGA NO PATIO"
        PATIO=True               
        IMPENT()
EndIf

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)

Print File ARQIMP CI_10CPP
Print File ARQIMP CI_6LPP

Release Vars CLIENTE,ITEM,LOCAL,ENTREGA,ENT_BALCAO,ENT_PATIO,
        BALCAO,PATIO
Release Procs IMPENT,ENTREGA,ENT_BALCAO,ENT_PATIO,BALCAO,PATIO
LIMPAGUARDE()

