;** CB_0012 ********************************************************************
;* Carta de Cobranca XVI                                                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 22/05/2015 por Andrey Fillipe
;Alterado em     :   /  /     por 
;Motivo Alteracao: 

;*******************************************************************************
;* Rotina para Impressao do Cabecalho da Carta                                 *
;*******************************************************************************
Proc IMPCAB_CARTA()

NFOLHA=NFOLHA+1

Print File ARQIMP "\n"  
Print File ARQIMP Spaces(65)+"Folha: "+StrVAl(NFOLHA)+"\n\n"
Print File ARQIMP Spaces(05)+EMP_CID+", "+
                  StrVal(Day(Today()))+" DE "+
                  RTrim(MesExt(Month(Today())))+" DE "+
                  StrVal(Year(Today()))+"."+"\n"
Print File ARQIMP "\n\n"
Print File ARQIMP Spaces(14)+"·"+"\n"
Print File ARQIMP Spaces(14)+CLI_RAZ+"\n"
Print File ARQIMP Spaces(14)+CLI_END+"\n"
Print File ARQIMP Spaces(14)+CLI_BAIR+" - "+CLI_CEP+"\n"
Print File ARQIMP Spaces(14)+CLI_CID +"/"+CLI_UF+"\n\n\n"

Print File ARQIMP Spaces(05)+"Declaro para  os  devidos  fins que se fizerem  necess rios, que recebi"+"\n"
Print File ARQIMP Spaces(05)+"os  romaneios  abaixo  relacionados,  referentes  as compras  efetuadas"+"\n"
Print File ARQIMP Spaces(05)+"na empresa "+EMP_RAZ+"."+"\n"
Print File ARQIMP Spaces(05)+"Afirmo tamb‚m ter recebido o boleto banc rio referente a estas compras."+"\n\n\n"

Print File ARQIMP "            Documento          Vencto           Valor  "+"\n\n"
                              ;1234567890       99/99/99       99.999,99 
Nl=36
EndProc

;*******************************************************************************
;* Rotina para Impressao dos Titulos da Carta                                  *
;*******************************************************************************
Proc IMPTIT_CARTA()

Print File ARQIMP Spaces(12)
Print File ARQIMP Format("W11,AL",[Numero do Documento])
Print File ARQIMP Spaces(06)
Print File ARQIMP Format("D10",[Data de Vencimento])
Print File ARQIMP Spaces(06)
Print File ARQIMP Format("W10.2,EIC",[Valor do Documento])

Print File ARQIMP "\n"

nl=nl+1

EndProc

;*******************************************************************************
;* Rotina para Impressao nova Folha                                            *
;*******************************************************************************
Proc IMPNOVA_FOLHA()

NFOLHA=NFOLHA+1
Print File ARQIMP CI_INEG+" * Continua Pr¢xima Folha -> "+StrVAl(NFOLHA)+CI_FNEG+"\f"

Print File ARQIMP "\n"  
Print File ARQIMP Spaces(65)+"Folha: "+StrVAl(NFOLHA)+"\n\n"
nl=3
EndProc

;*******************************************************************************
;* Rotina para Impressao do Rodape da Carta                                    *
;*******************************************************************************
Proc IMPROD_CARTA()

Print File ARQIMP SPACES(34)+" TOTAL ->"+CI_INEG+
                             Format("W10.2,EIC",TOTVR)+
                             Format("W7,AR",NTIT)+" Titulos"+CI_FNEG+"\n\n\n"
nl=nl+3

if nl>53
   Then IMPNOVA_FOLHA()
EndIF

Print File ARQIMP Spaces(05)+"Por ser verdade, assumo  o  pagamento do boleto  banc rio no vencimento"+"\n"
Print File ARQIMP Spaces(05)+"estipulado no mesmo,  estando ciente das condi‡äes legais que a empresa"+"\n"
Print File ARQIMP Spaces(05)+"possa vir a tomar, caso o mesmo nÆo seja efetuado."+"\n\n\n\n"

Print File ARQIMP Spaces(05)+"Nome (extenso) ________________________________________________________"+"\n\n"

Print File ARQIMP Spaces(05)+"N§ documento   ________________________________________________________"+"\n\n"
                                               
Print File ARQIMP Spaces(05)+"Assinatura     ________________________________________________________"+"\n\n\n"

Print File ARQIMP "\f"

EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Seta_FilePrint("CB_0012")

AGUARDE("Imprimindo Carta de Cobran‡a")

CODEMPANT="***"
CODCLIANT="***"
CoEdit "Answer"
Scan

  If [Codigo da Empresa]<>CODEMPANT
     Then CODEMPANT=[Codigo da Empresa]

          Moveto [Codigo da Empresa]
          GetRecord "\\Sistemas\\Cadastro\\Empresas" [Codigo da Empresa] To REG_BUSCA_LOOKUP
          If RetVal
             Then EMP_NOMF=REG_BUSCA_LOOKUP["Nome Fantasia Empresa"]
                  EMP_RAZ =REG_BUSCA_LOOKUP["Razao Social Empresa" ]
                  EMP_END =REG_BUSCA_LOOKUP["Endereco Empresa"     ]
                  EMP_BAIR=REG_BUSCA_LOOKUP["Bairro Empresa"       ]
                  EMP_CID =REG_BUSCA_LOOKUP["Cidade Empresa"       ]
                  EMP_UF  =REG_BUSCA_LOOKUP["UF Empresa"           ]
                  EMP_CEP =REG_BUSCA_LOOKUP["CEP Empresa"          ]
                  EMP_FONE=REG_BUSCA_LOOKUP["Telefone Empresa"     ]
                  EMP_CONT=REG_BUSCA_LOOKUP["Contato Empresa"      ]
          EndIf
  EndIf

  If [Codigo do Destinatario]<>CODCLIANT
     Then
          If CODCLIANT<>"***"
             Then IMPROD_CARTA()
          EndIf

          CODCLIANT=[Codigo do Destinatario]
          NFOLHA   =0
          TOTVR    =0
          ORIVR    =0
          JURVR    =0
          NTIT     =0
          Moveto [Codigo do Destinatario]
          GetRecord "\\Sistemas\\Cadastro\\Destinat" [Codigo do Destinatario] To REG_BUSCA_LOOKUP
          If RetVal
             Then CLI_RAZ =REG_BUSCA_LOOKUP["Razao Social"]
                  CLI_END =REG_BUSCA_LOOKUP["Endereco"    ]
                  CLI_BAIR=REG_BUSCA_LOOKUP["Bairro"      ]
                  CLI_CID =REG_BUSCA_LOOKUP["Cidade"      ]
                  CLI_UF  =REG_BUSCA_LOOKUP["UF"          ]
                  CLI_CEP =REG_BUSCA_LOOKUP["CEP"         ]
                  CLI_FONE=REG_BUSCA_LOOKUP["Telefone"    ]
             Else CLI_RAZ ="????"
                  CLI_END =""
                  CLI_BAIR=""
                  CLI_CID =""
                  CLI_UF  =""
                  CLI_CEP =""
                  CLI_FONE=""
          EndIf
          IMPCAB_CARTA()
  EndIf

  If nl>60
     Then IMPNOVA_FOLHA()
  EndIf
 
  ImpTit_Carta()

  NTIT=NTIT+1
  ORIVR=ORIVR+[Saldo do Documento]
  TOTVR=TOTVR+[Valor do Documento]
  JURVR=JURVR+[Valor do Desconto]

EndScan
IMPROD_CARTA()
Do_It!
ClearAll

ImpriArq(ARQIMP)

LIMPAGUARDE()
Release Vars NL,NTIT,TOTVR,ORIVR,JURVR
Release Procs IMPCAB_Carta,IMPTit_Carta, ImpRod_Carta, IMPNOVA_FOLHA
