;** Rm_0250 *******************************************************************
;* Resumo de Vendas de produtos / Custo Medio                                 *
;******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/95 por Anivel Augusto Rodrigues
;Ultima Alteracao: 08/09/2004 por Jos‚ Lu¡s Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "empresa" TypeIn ", ~VSDGEMPRESA.."
        Moveto [Numero do Documento    ] Example "docto"
        Moveto [Serie do Documento     ] Example "serie"
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] TypeIn "..VENDA.."
        Moveto [Situacao               ] TypeIn "Not C"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "empresa"
        Moveto [Numero do Documento    ] Example "docto"
        Moveto [Serie do Documento     ] Example "serie"
        Moveto [Codigo do Item         ] Check TypeIn "~VSDGITEM.."
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Valor Total"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo da Empresa    ] Example "Empresa"
        Moveto [Nome Fantasia Empresa] Example "Fantasia"
        Moveto [Codigo do Item       ] Example "CodItem"
        Moveto [Descricao do Item    ] Example "Item"
        Moveto [Unidade Fiscal       ] Example "Unidade"
        Moveto [Quantidade           ] Example "Quant"
        Moveto [Valor Total          ] Example "Valor"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Codigo da Empresa    ] Example "Empresa"
        Moveto [Nome Fantasia Empresa] Example "Fantasia"
        Moveto [Codigo do Item       ] Example "CodItem"
        Moveto [Descricao do Item    ] Example "Item"
        Moveto [Unidade Fiscal       ] Example "Unidade"
        Moveto [Quantidade           ] Example "Quant"
        Moveto [Valor Total          ] Example "Valor"
        Do_It!
        ClearAll
EndIf
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc Processa()
If Not IsEmpty(Tabela)
   Then {Ask} {\\Sistemas\\Estoque\\SdEstq}
        Moveto [Codigo da Empresa] Example "Empresa"
        Moveto [Codigo do Item   ] Example "Item"
        Moveto [Ano Referencia   ] TypeIn "VSDGANO"
        Moveto [Mes Referencia   ] TypeIn "VSDGMES"
        Moveto [Custo Total Atual] Example "Custo"
        Moveto [Saldo Atual      ] Example "Saldo"
        {Ask} TypeIn Tabela enter TypeIn "Fast"
        Moveto [Codigo da Empresa    ] Example "Empresa"
        Moveto [Codigo do Item       ] Example "Item"
        Moveto [Quantidade           ] Example "Quant"
        Moveto [Valor Total          ] TypeIn  "Changeto _Quant*(_Custo/_Saldo)"
        Moveto [Valor Unitario       ] TypeIn  "Changeto _Custo/_Saldo"
        Do_It!
        ClearAll
EndIf

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_ITEM"          : Campo="TG_EMPRESA"
            Case Campo="TG_DTINI"         : Campo="TG_ITEM"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_MESANO"        : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :Campo="TG_ITEM"
                    Case Campo="TG_ITEM"    :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   :Campo="TG_MESANO"
                    Case Campo="TG_MESANO"  :
                         VSDGMES=SubStr(VSDGMESANO,1,2)
                         VSDGANO=SubStr(VSDGMESANO,4,4)
                         If NumVal(VSDGANO) < 2000
                            Then VSDGANO=SubStr(VSDGANO,3,2)
                            Else VSDGANO=VSDGANO
                         EndIf
                         If NumVal(VSDGMES) > 12 Or NumVal(VSDGMES) = 0
                            Then MENSAGEM("Mˆs Inv lido!")
                            Else Campo = "YES"
                         EndIf
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

If Not IsTable("\\Base\\Sistemas\\Vendas\\Rm_0250")
   Then Return
   Else Empty "\\Base\\Sistemas\\Vendas\\Rm_0250"
EndIf

VSDGEMPRESA =""
VSDGITEM    =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
VSDGMESANO   = AlinhM(StrVal(Month(Today())),2)+"."+AlinhM(StrVal(Year(Today())),4)

While True

  ShowDialog "Posi‡„o de Vendas de Produtos - Custo M‚dio" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 13 Width 56

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Item"  For "TG_ITEM"
    Accept @ 03,01 Width 13 "A10"  Picture "#*#" Tag "TG_ITEM"  To VSDGITEM
    Accept @ 03,15 Width 33 "A30" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 04,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "at‚" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 06,00 "Mˆs/Ano Ficha Estoque"  For "TG_MESANO"
    Accept @ 07,01  Width 10 "A07"  Picture "##.####" Tag "TG_MESANO" To VSDGMESANO

    Pushbutton @ 09,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0250"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0250" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
