;** ET_CB002  ******************************************************************
;** Impressao de Etiqueta c/ Pre‡o - Jato de Tinta    ** DIVINA PANELA **      *
;** Etiqueta Pimaco Com 4 Colunas e 15 Linhas de Etiqueta (4,4 x 1,7)
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido em : 28/12/2012 por Bruno Carvalho
;Ultima Alteracao: 04/02/2013 por Bruno Carvalho 
;Motivo Alteracao: Alterado de "Edit" para "Coedit" ao buscar os itens

;*******************************************************************************
;* Rotina de Impressao das Etiquetas                                           *
;*******************************************************************************
Proc MONTA_ETIQUETA()

If QUEBRA_PAGINA > 60
   Then QUEBRA_PAGINA = 0
        Print File ARQIMP "\f"
        Print File ARQIMP "\n\n\n"
EndIf

Print File ARQIMP Spaces(09)
For I From 1 to K
  Print File ARQIMP Format("W10",CODIGO_ITEM[I])+Format("W18",SYS_NOMEMP_DEFAULT)+Spaces(04)
EndFor
Print File ARQIMP "\n"

Print File ARQIMP Spaces(09)
For I From 1 to K
  Print File ARQIMP Format("W28",DESCRI_ITEM[I])+Spaces(04)
EndFor
Print File ARQIMP "\n"

Print File ARQIMP Spaces(09)
For I From 1 to K              
  Print File ARQIMP "Loc.: "+Format("W9",LOCALIZACAO[I])+"  R$ "+Format("W8.2,EIC",PRECO_UNITA[I])+Spaces(04)
EndFor
Print File ARQIMP "\n\n"

EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
If Not IsAssigned(SYS_NOMEMP_DEFAULT) Then SYS_NOMEMP_DEFAULT="" EndIf

CODITEM="***"
View "Itens"
CoEdit "Answer"
Scan
  If CODITEM<>[Codigo do Item]
     Then CODITEM=[Codigo do Item]
          Moveto "Itens"
          Moveto [Codigo do Item]
          Locate [Answer->Codigo do Item]
          If RetVal
             Then If [Localizacao]<>""
                     Then LOC=[Localizacao]
                     Else LOC=""
                  EndIf
          EndIf
          Moveto "Answer"
  EndIf
  [Localizacao]=LOC
EndScan
Do_It!
ClearAll                  

View "Answer"

ArqImp=PrivDir()+"Etiqueta.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

Array CODIGO_ITEM[4]
Array DESCRI_ITEM[4]
Array LOCALIZACAO[4]
Array PRECO_UNITA[4]

K=0
CONTADOR = 0
QUEBRA_PAGINA = 0

Print File ARQIMP CI_15CPP
Print File ARQIMP "\n\n\n"

While [Quantidade] > CONTADOR      
      CONTADOR = CONTADOR + 1  
      QUEBRA_PAGINA = QUEBRA_PAGINA + 1
      K=K+1                                                       
      CODIGO_ITEM[K] = [Codigo do Item]
      DESCRI_ITEM[K] = [Descricao do Item]
      LOCALIZACAO[K] = [Localizacao]
      PRECO_UNITA[K] = [Preco Unitario]
      
      If K=4                    
         Then MONTA_ETIQUETA()
              K=0
      EndIf
      If [Quantidade] = CONTADOR
         Then CONTADOR = 0
              Skip                      
              If EOT() Then QuitLoop EndIf
      EndIf
EndWhile
                                                                                                           
If K>0
   Then MONTA_ETIQUETA()
EndIf

Print File ARQIMP "\n"

LIMPAGUARDE()

;---- Imprime Arquivo Impressao ------------------------------------------------
ImpriArq(ARQIMP)