;** Rm_0040  *******************************************************************
;*  Conferencia de Notas de Entradas por Emitente/Per¡odo                      *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 20/01/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 28/01/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Duplicidade
;Ultima Alteracao: 28/09/2009 por Bruno Carvalho
;Motivo Alteracao: Adi‡Æo da Op‡Æo TIPO DE OPERA€ÇO
;Ultima Alteracao: 17/09/2010 por Karina Andrade
;Motivo Alteracao: Add Observa‡äes e Vencimentos - Seleciona2()
;Ultima Alteracao: 30/01/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao data de inclusao/modelo paisagem
;Ultima Alteracao: 18/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog       
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT            
;Ultima Alteracao: 03/01/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Nota Entrada Opera‡Æo para Impostos 
;Ultima Alteracao: 02/04/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes observacoes e vencimentos no report 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros Cabecalho                         *
;*******************************************************************************
Proc Seleciona()
private tabela2

ClearAll

If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC")
   Then 
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA.."
        Moveto [Tipo do Documento   ] TypeIn VSDGESPDOCTO
        If Not IsBlank(VSDGNUMDOCTO) Then Moveto [Numero do Documento] TypeIn VSDGNUMDOCTO EndIf
        Moveto [Codigo              ] TypeIn "~VSDGDESTINAT.."
        Moveto [Tipo de Operacao    ] TypeIn "~VSDGOPERACAO.."
        Switch
         Case VSDGTPDATA="1" :
           Moveto [Data de Entrada  ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
         Case VSDGTPDATA="2" :
           Moveto [Data de Emissao  ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
         Case VSDGTPDATA="3" :
           Moveto [Data_Inclusao    ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        EndSwitch
        Do_It!
        ClearAll

        Adiciona_Campo("Answer","Vencimentos(M10)")
        Tabela2=Adiciona_Indice_Temp("Numero do Lancamento")
        
        {Ask} TypeIn tabela2 Enter
        Moveto [Numero do Lancamento] Example "LANCTO"
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaECP" Enter Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Do_It!
        ClearAll
        
        CoEdit Tabela2,"Answer"
        Scan
           Moveto Tabela2
           Moveto [Numero do Lancamento]
           Locate [Answer->Numero do Lancamento]
           If RetVal
              Then 
                   [Vencimentos]= [Vencimentos]+Format("D13",[Answer->Data de Vencimento])+ " " + 
                                                LTrim(Format("W12.2,EIC",[Answer->Valor do Documento]))+"; "
           endif                                      
           
           Moveto "Answer"
        EndScan
        Do_It!
        ClearAll 

        {Ask} TypeIn tabela2 Enter Check
        Moveto [Numero do Lancamento] Example "LANCTO" 
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Do_It!
        ClearAll

        Adiciona_Campo("Answer","Referencia(A20)")

        {Ask} TypeIn "\\Sistemas\\Estoque\\Itens" Enter
        Moveto [Codigo do Item      ] typein "_item"
        Moveto [Referencia          ] typein "_ref"
        {Ask} {Answer}
        Moveto [Codigo do Item      ] typein "_item"
        Moveto [Referencia          ] typein "changeto _ref"
        Do_It!
        ClearAll
        
        delete tabela2
EndIf


EndProc   ;  

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9  : Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_OPERACAO"      : Campo="TG_EMPRESA"
            Case Campo="TG_DESTINAT"      : Campo="TG_OPERACAO"
            Case Campo="TG_ESPDOCTO"      : Campo="TG_DESTINAT"
            Case Campo="TG_NUMDOCTO"      : Campo="TG_ESPDOCTO"
            Case Campo="TG_TPDATA"        : Campo="TG_NUMDOCTO"
            Case Campo="TG_DTINI"         : Campo="TG_TPDATA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM" 
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_OPERACAO"
                    Case Campo="TG_OPERACAO" :
                         VSDGOPERACAO = ControlValue("TG_OPERACAO")
                         Switch
                            Case VSDGOPERACAO = "A":
                                 VSDGNOMOPERA = "Aplica‡Æo Direta"
                            Case VSDGOPERACAO = "C":
                                 VSDGNOMOPERA = "Compras"
                            Case VSDGOPERACAO = "D":
                                 VSDGNOMOPERA = "Devolu‡Æo"
                            Case VSDGOPERACAO = "T":
                                 VSDGNOMOPERA = "Transferencia"
                            Case VSDGOPERACAO = "O":
                                 VSDGNOMOPERA = "Outras"
                            Case VSDGOPERACAO = "I":
                                 VSDGNOMOPERA = "Impostos"
                            Otherwise           :
                                 VSDGNOMOPERA = "TODAS"
                         EndSwitch
                         Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"      : Campo="TG_ESPDOCTO"
                    Case Campo="TG_ESPDOCTO"      : Campo="TG_NUMDOCTO"
                    Case Campo="TG_NUMDOCTO"      : Campo="TG_TPDATA"
                         VSDGNUMDOCTO=ControlValue("TG_NUMDOCTO")
                    Case Campo="TG_TPDATA"   :
                       VSDGTPDATA=ControlValue("TG_TPDATA")
                       Switch
                         Case VSDGTPDATA="1": VSDGNOMTPDATA="ENTRADA"
                         Case VSDGTPDATA="2": VSDGNOMTPDATA="EMISSŽO"
                         OtherWise:
                              VSDGTPDATA="3"  VSDGNOMTPDATA="INCLUSÇO"
                       EndSwitch
                       Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_TPDATA"      : MSG_CAMPO="1=ENTRADA  2=EMISSŽO  3=INCLUSÇO"
  Case Campo="TG_OPERACAO"    : MSG_CAMPO="A=Aplica‡Æo Direta, C=Compras, D=Devolu‡Æo, T=Transferˆncia, O=Outras, I=Impostos"
  Case Campo="TG_OPRELATORIO" : MSG_CAMPO="1=Retrato  2=Paisagem"
  Case Campo="TG_NUMDOCTO"    : MSG_CAMPO="Informe o ..N£mero do Documento ou Em Branco=TODOS"  
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Retrato")
ModeloRelatoriosAdd("02  Paisagem")
;;ModeloRelatoriosAdd("03  Detalhamento de valores para custo")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  = ""
VSDGDESTINAT = ""
VSDGTPDATA   = ""
VSDGESPDOCTO = ""
VSDGNUMDOCTO = ""
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Conferˆncia de Notas de Entradas com Itens" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
  @ 05,05   Height 20 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP
    
    Label  @ 02,00 "Tipo de Opera‡Æo"  For "TG_OPERACAO"
    Accept @ 03,04 Width 04 "A1"  Picture "A,C,D,T,O,I" Tag "TG_OPERACAO"  To VSDGOPERACAO
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMOPERACAO" To VSDGNOMOPERA   

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 06,00 "EspDocto"  For "TG_ESPDOCTO"
    Accept @ 07,01 Width 08 "A5"  Picture "!*!" Tag "TG_ESPDOCTO" To VSDGESPDOCTO
    Label  @ 06,09 "N£mero Docto"  For "TG_NUMDOCTO"
    Accept @ 07,10 Width 13 "A10"  Picture "!*!" Tag "TG_NUMDOCTO" To VSDGNUMDOCTO

    Label  @ 08,00 "Op‡äes de Datas" For "TG_TPDATA"
    Accept @ 09,04 Width 04 "A1"  Picture "1,2,3"  Tag "TG_TPDATA"     To VSDGTPDATA
    Accept @ 09,09 Width 25 "A18" Picture "!*!"  Tag "TG_NOMOTPDATA" To VSDGNOMTPDATA

    Label  @ 10,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 13,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 14,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 14,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 16,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 16,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf
  
  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  
  Switch
    Case VSDGCODMODELO="01": 
      CopyReport "\\Base\\Sistemas\\Estoque\\Rm_2000" "R" Tabela "R"
      IMPRIREL(Tabela,"R")

    Case VSDGCODMODELO="02": 
      Impressao_Orientacao="Paisagem"
      CopyReport "\\Base\\Sistemas\\Estoque\\Rm_2000" "6" Tabela "R"
      IMPRIREL(Tabela,"R")
  EndSwitch

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
