;** Rm_0030  *******************************************************************
;*  Fluxo de Caixa Analitico por Conta                                         *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 01/03/2005 por Davi Pereira Carrano
;Motivo Alteracao: Corre‡Æo das Ask para liberar tabelas quando se usa Fast Insert
;Ultima Alteracao: 21/11/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cheque p/ deposito e otimiza‡äes                
;Ultima Alteracao: 15/04/2013 por Karina Andrade
;Motivo Alteracao: Ajustes desprezar SALDO
;Ultima Alteracao: 04/09/2014 por Andrey Fillipe
;Motivo Alteracao: Adicionado filtro Op‡ao de data
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()               
;Ultima Alteracao: 22/06/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÆo utilizar data de competencia no fluxo de caixa nÆo existe esta situa‡Æo, esta com interpreta‡Æo errada
;Ultima Alteracao: 14/09/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado vari vel de controle PARAM_SCRIPT -> 'Rm_FlxCx"
;Ultima Alteracao: 23/12/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes variavel opcao de saldo

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_CONTA"         : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_CONTA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPCHEQ"        : Campo="TG_DTFIM"
            Case Campo="TG_OPSALDO"       : Campo="TG_OPCHEQ"
            Case Campo="YES" Or Campo="NO": Campo="TG_CONTA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_CONTA" :
                         If IsBlank(VSDGCONTA)
                            Then VSDGNOMCONTA=""
                            Else Campo="TG_DTINI"
                         EndIf
                    Case Campo="TG_DTINI" :
                         If Not IsBlank(VSDGDTINI)
                            Then Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM"  : Campo="TG_OPCHEQ"
                    Case Campo="TG_OPCHEQ" : Campo="TG_OPSALDO"
                    Case Campo="TG_OPSALDO": Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CONTA":
     MSG_CAMPO="Informe a Conta"
  Case Campo="TG_OPCHEQ" or Campo="TG_OPSALDO":
     MensagemCheckBoxes()
  Case Campo="TG_DTINI":
     MSG_CAMPO="Informe a Data Inicial"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

PARAM_SCRIPT = "RM_0030"

VSDGCONTA  =""
VSDGDTINI  =Today()
VSDGDTFIM  =Today()+30

Array CheckTG_OPCREDITO[1]
CheckTG_OPCREDITO[1]=True

Array CheckTG_OPCARTAO[2]
CheckTG_OPCARTAO[1]=False
CheckTG_OPCARTAO[2]=False

Array TG_OPCHEQ[1]
TG_OPCHEQ[1]="Incluir Cheques de Terceiros"

Array CheckTG_OPCHEQ[ArraySize(TG_OPCHEQ)]
CheckTG_OPCHEQ[1]=True

Array TG_OPSALDO[2]
TG_OPSALDO[1]="Desprezar Saldo Inicial"
TG_OPSALDO[2]=""

Array CheckTG_OPSALDO[ArraySize(TG_OPSALDO)]
CheckTG_OPSALDO[1]=False
CheckTG_OPSALDO[2]=False

While True
  ShowDialog "Fluxo de Caixa Anal¡tico por Conta" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 09 Width 72

    Label  @ 00,00 "Conta"  For "TG_CONTA"
    Accept @ 01,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA

    Label  @ 02,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    CheckBoxes @ 01,35 Height 1 Width 33 Tag "TG_OPCHEQ"
    TG_OPCHEQ[1] to CheckTG_OPCHEQ[1]
    
    CheckBoxes @ 02,35 Height 1 Width 33 Tag "TG_OPSALDO" 
    TG_OPSALDO[1] to CheckTG_OPSALDO[1]
     
    Pushbutton @ 05,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If VSDGCONTA=""
     Then Mensagem("Conta Invalida !")
          Loop
  EndIf

  If VSDGDTINI=BlankDate()
     Then Mensagem("Data Inicial Invalida !")
          Loop
  EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  View "Conta"
  Moveto [Codigo da Conta]
  Locate VSDGCONTA
  If Not RetVal
     Then VSDGEMPRESA=""
     Else VSDGEMPRESA=[Codigo da Empresa    ]
          VSDGNOMEMP =[Nome Fantasia Empresa]
  EndIf
  ClearAll

  ANOREF=StrVal(Year(VSDGDTINI))
  MESREF=StrVal(Month(VSDGDTINI))
  ALINHM(MESREF, 2)
  MESREF=NVR
  VSDGDTREF=DateVal("01."+MESREF+"."+ANOREF)

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  TipoFluxo ="Analitico"
  TipoFiltro="Conta"
  Play "Rm_FlxCx"

  IMPRIREL(Tabela,"3")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
