;** RM_3117 ********************************************************************
;* Resumo de Vendas por Representante                                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 04/12/2017 por Bruno Carvalho            
;Ultima Alteracao: 05/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Seta_Ordem_Report()                

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas *****************************************************************
{Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
Moveto [Codigo do Representante] Example "crep"
Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
{Ask} TypeIn "\\Sistemas\\Vendas\\FaturaC" Enter
Moveto [Numero da OF           ] Example "nof"
Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo do Representante] Check TypeIn "_crep, ~VSDGREPRESEN.."
Moveto [Nome Fantasia Represent] Check
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
Moveto [Tipo Movimento Estoque ] TypeIn "S"
Moveto [Sistema Gerador        ] TypeIn "Not C"
{Ask} TypeIn "\\Sistemas\\Vendas\\FaturaI" Enter
Moveto [Numero da OF           ] Example "nof"
Moveto [Codigo do Item         ] Check
Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"   
Do_It!
ClearAll

Adiciona_Dados()
Adiciona_NVendas()
Adiciona_NItens()

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados nvendas                                              *
;*******************************************************************************
Proc Adiciona_NVendas()

{Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
Moveto [Codigo do Representante] Example "crep"
If VSDGGERENCIA<>""
   Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
   Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
EndIf
{Ask} TypeIn "\\Sistemas\\Vendas\\FaturaC" Enter
Moveto [Numero da OF           ] Check 
Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo do Representante] Check Example "crep"
Moveto [Nome Fantasia Represent] Check
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
Moveto [Tipo Movimento Estoque ] TypeIn "S"
Moveto [Sistema Gerador        ] TypeIn "Not C"     
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Check 
Moveto [Numero da OF           ] TypeIn "Calc count as nvendas"
Moveto [Codigo do Representante] Check 
Moveto [Nome Fantasia Represent] Check
Moveto [Codigo da Gerencia     ] Check 
Do_It!
ClearAll
   
{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Codigo da Gerencia     ] Example "Ger"
Moveto [nvendas                ] Example "qtde"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Nome Fantasia EmitDest ] Example "Ger"
Moveto [Total_Vendas_TipoPagto ] Example "qtde"
Do_It!
ClearAll       

EndProc

;*******************************************************************************
;* Rotina adicionar dados nitens                                               *
;*******************************************************************************
Proc Adiciona_NItens()

;-- Metodo quantidade de itens em cada venda -----------------------------------

{Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
Moveto [Codigo do Representante] Example "crep"
If VSDGGERENCIA<>""
   Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
   Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
EndIf
{Ask} TypeIn "\\Sistemas\\Vendas\\FaturaC" Enter
Moveto [Numero da OF           ] Check Example "nof"
Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo do Representante] Check Example "crep"
Moveto [Nome Fantasia Represent] Check
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
Moveto [Tipo Movimento Estoque ] TypeIn "S"
Moveto [Sistema Gerador        ] TypeIn "Not C"
{Ask} TypeIn "\\Sistemas\\Vendas\\FaturaI" Enter
Moveto [Numero da OF           ] Example "nof"
Moveto [Item da OF             ] Check    
Do_It!
ClearAll
   
If IsEmpty("Answer")
   Then Return
EndIf


{Modify} {Restructure} {Answer}
Moveto [Field Name]
Locate "Item da OF"
If RetVal
 Then Right CtrlBackSpace "A6" Enter
EndIf
Do_It! 
ClearImage

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Check
Moveto [Numero da OF           ] Example "nof"
Moveto [Item da OF             ] TypeIn "_nite ,calc _nof+_nite as nitens"
Moveto [Codigo do Representante] Check 
Moveto [Nome Fantasia Represent] Check
Moveto [Codigo da Gerencia     ] Check
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Check 
Moveto [Codigo do Representante] Check 
Moveto [Nome Fantasia Represent] Check
Moveto [nitens                 ] TypeIn "Calc count as nitens"
Moveto [Codigo da Gerencia     ] Check
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Codigo da Gerencia     ] Example "Ger"
Moveto [nitens                 ] Example "qtde"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Nome Fantasia EmitDest ] Example "Ger"
Moveto [Total_Vendas_FormaPagto] Example "qtde"
Do_It!
ClearAll       

EndProc ;Adiciona_NItens()

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados()

If IsEmpty("Answer")
   Then Return
EndIf
   
{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
Moveto [Codigo da Gerencia     ] Example "Ger" ;Gerˆncia
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Nome Fantasia EmitDest ] Example "Ger" ;Gerˆncia      
Moveto [Vendas_Quantidade      ] Example "qtde"
Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
Moveto [Total_Vendas_CondPagto ] Example "vdes"
Do_It!
ClearAll       

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ***************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Cadastro\\Represen}
Moveto [Codigo do Representante  ] Example "crep"
Moveto [Nome Fantasia Represent  ] Example "nrep"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Representante  ] Example "crep"
Moveto [Nome Fantasia Represent  ] TypeIn "changeto _nrep"
Do_It!
ClearAll

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Total_Vendas_CondPagto ] Check TypeIn "Calc Sum as \"Total_Vendas_CondPagto\""
Moveto [Total_Vendas_TipoPagto ] Check TypeIn "Calc Sum as \"Total_Vendas_TipoPagto\""
Moveto [Total_Vendas_FormaPagto] Check TypeIn "Calc Sum as \"Total_Vendas_FormaPagto\""
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as \"Vendas_Quantidade\""
;;Moveto [Vendas_Embalagem       ] Check TypeIn "Calc Sum as \"Vendas_Embalagem\""
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as \"Vendas_Preco Total\""
Do_It!
ClearAll     

Delete Tabela
Rename "Answer" Tabela
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""

If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch           
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: 
          Dialog_F1() 
          
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_REPRESEN"        : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"        : Campo="TG_REPRESEN"
            Case Campo="TG_MARCA"           : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"           : Campo="TG_MARCA"
            Case Campo="TG_DTFIM"           : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"       : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO"  : Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE" : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"  : Campo="TG_GERENCIA"
                    Case campo="TG_GERENCIA"  : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"     : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"     : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"     : Campo="TG_CODMODELO"                            
                    Case Campo="TG_CODMODELO" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_DTFIM" : MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Sem quebra por Gerˆncia")
ModeloRelatoriosAdd("02  Quebra por Gerˆncia")
ModeloRelatoriosAdd("03  Total por Gerˆncia")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA         = ""
VSDGDTINI           = BlankDate()
VSDGDTFIM           = BlankDate()
VSDGOPRELCODALF     = ""
VSDGGERENCIA        = ""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Ranking por Representante\\OF" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN"  To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 06,00 "Marca"  For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO 

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Usuario_Vendedor() Then Loop EndIf  

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_3101"
  Copy "\\Base\\Sistemas\\Vendas\\RM_3101" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  Switch
    Case VSDGCODMODELO = "01" : CopyReport "\\Base\\Sistemas\\Vendas\\RM_3117" "R" Tabela "R" 
    Case VSDGCODMODELO = "02" : CopyReport "\\Base\\Sistemas\\Vendas\\RM_3117" "1" Tabela "R"
    Case VSDGCODMODELO = "03" : CopyReport "\\Base\\Sistemas\\Vendas\\RM_3117" "2" Tabela "R" 
  EndSwitch
  Seta_Ordem_Report(Tabela,"R","Codigo do Representante","Vendas_Preco Total","D")
  IMPRIREL(Tabela,"R") 
  
  Delete Tabela
EndWhile
ClearAll
Release Vars All
Release Procs All
