;** TransfOE  ******************************************************************
;*  Transferencia P/ Drive   (Ordem de Expedi‡„o)                              *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 06/10/2010 por Bruno Carvalho
;Ultima Alteracao: 16/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Layout
;Ultima Alteracao: 12/05/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novas fun‡äes para confec‡äes  
;Ultima Alteracao: 30/05/2011 por Karina Andrade
;Motivo Alteracao: Add Exporta‡Ćo de Pedidos  
;Ultima Alteracao: 27/06/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Ćo Arj para c:\Arj
;Ultima Alteracao: 13/10/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 01/12/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Ćo de "Arj -> Varj"                                  
;Ultima Alteracao: 08/12/2011 por Karina Andrade
;Motivo Alteracao: Nova nomeclatura para pacote gerado
;Ultima Alteracao: 07/05/2012 por Bruno Carvalho
;Motivo Alteracao: Add Sleep na rotina onde ‚ processado o ARJ
;Ultima Alteracao: 03/03/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Layout
;Ultima Alteracao: 19/10/2016 por Bruno Carvalho
;Motivo Alteracao: Adicionado "Iten_Tec"                   
;Ultima Alteracao: 06/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog    
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()
;Ultima Alteracao: 23/05/2017 por Rafael Matos
;Motivo Alteracao: Adicionado "Iten_Bar", ajustes ARQ_TAB
;Ultima Alteracao: 09/08/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado Gera_Log()                
;Ultima Alteracao: 02/03/2018 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes SIRI nĆo agrupar Itens                     
;Ultima Alteracao: 14/03/2018 por Bruno Carvalho
;Motivo Alteracao: Adicionado "Iten_eco"

;*******************************************************************************
;* ROTINA PROCESSA  -> realiza o processamento da Transferencia                *
;*******************************************************************************
Proc PROCESSA()

AGUARDE("Aguarde, Transferindo Ordem de Expedi‡„o!")
ClearAll
Array Arquivo[3]
Arquivo[1]="ExpedC"
Arquivo[2]="ExpedI"
Arquivo[3]="ExpedIE"

Cont     = 1

SetDir "\\Sistemas\\Vendas"
For Cont From 1 To 2
    AGUARDE("Aguarde, Transferindo "+Arquivo[Cont])
    If IsTable(Arquivo[Cont])
       Then If Arquivo[Cont]<>"ExpedC"                                       
               Then {Ask} {ExpedC}
                    Moveto [Numero da OE       ] Example "ndoc" TypeIn ", ~VSDGEXPEDICAO.."
                    Moveto [Codigo da Empresa  ] Example "cemp" TypeIn ", ~VSDGEMPRESA.."
                    Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                    Moveto [Numero_Carregamento] TypeIn "~VSDGNCARREG.."
                    {Ask} TypeIn Arquivo[Cont] Enter Check
                    Moveto [Numero da OE       ] Example "ndoc"
               Else {Ask} {ExpedC} Check
                    Moveto [Numero da OE       ] TypeIn "~VSDGEXPEDICAO.."
                    Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
                    Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                    Moveto [Numero_Carregamento] TypeIn "~VSDGNCARREG.."
            EndIf
            Do_It!
            ClearAll
            If IsTable(VSDGDRIVE+"\\"+Arquivo[Cont])
               Then Delete VSDGDRIVE+"\\"+Arquivo[Cont]
            Endif
            Create VSDGDRIVE+"\\"+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" VSDGDRIVE+"\\"+Arquivo[Cont]
            
            If Arquivo[Cont]="ExpedC" And Not IsEmpty("Answer")
               Then Gerou_Dados=True
            EndIf   
    EndIf
EndFor
                            
AGUARDE("Aguarde, Transferindo Carregamentos")
ClearAll
Arquivo[1]="AccarrgC"
Arquivo[2]="AccarrgI"
Arquivo[3]="AccarrgV"

Cont     = 1

SetDir "\\Sistemas\\Vendas"
For Cont From 1 To 3
    AGUARDE("Aguarde, Transferindo "+Arquivo[Cont])
    If IsTable(Arquivo[Cont])
       Then If Arquivo[Cont]<>"AccarrgC"
               Then {Ask} {Accarrgc}
                    Moveto [Numero_Carregamento] Example "ndoc"
                    Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                    {Ask} TypeIn Arquivo[Cont] Enter Check
                    Moveto [Numero_Carregamento] Example "ndoc"
               Else {Ask} {Accarrgc} Check
                    Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
            Endif
            Do_It!
            ClearAll
            If IsTable(VSDGDRIVE+"\\"+Arquivo[Cont])
               Then Delete VSDGDRIVE+"\\"+Arquivo[Cont]
            Endif
            Create VSDGDRIVE+"\\"+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" VSDGDRIVE+"\\"+Arquivo[Cont]
    EndIf
EndFor

AGUARDE("Aguarde, Transferindo Destinat")
ClearAll
If IsTable("\\Sistemas\\Cadastro\\Destinat")
   Then

        {Ask} {ExpedC}
        Moveto [Numero da OE       ] TypeIn "~VSDGEXPEDICAO.."
        Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
        Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Numero_Carregamento] TypeIn "~VSDGNCARREG.."
        Moveto [Codigo             ] Check
        Do_It!
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo       ] Example "clie"
        {Ask} {\\Sistemas\\Cadastro\\Destinat} Check
        Moveto [Codigo       ] Example "clie"
        Do_It!
        ClearAll
        If IsTable(VSDGDRIVE+"\\Destinat")
           Then Delete VSDGDRIVE+"\\Destinat"
        Endif
        Create VSDGDRIVE+"\\Destinat" Like "\\sistemas\\cadastro\\Destinat"
        Add "Answer" VSDGDRIVE+"\\Destinat"

EndIf

Transf_Itens=True
switch
  case sys_Codigo_Cliente="0227" : Transf_Itens=True
  case SYS_CLIENTE_CONFEC<>""    : Transf_Itens=False
endswitch

AGUARDE("Aguarde, Transferindo Itens")
ClearAll
If IsTable("\\Sistemas\\Estoque\\Itens") And Transf_Itens
   Then
        {Ask} {ExpedC}
        Moveto [Numero da OE       ] Example "ndoc" TypeIn ", ~VSDGEXPEDICAO.."
        Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."
        Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Numero_Carregamento] TypeIn "~VSDGNCARREG.."
        {Ask} {ExpedI}
        Moveto [Numero da OE       ] Example "ndoc"
        Moveto [Codigo do Item     ] Check
        Do_It!
        ClearAll

        Tabela=Cria_Temp(PrivDir())
        Rename "Answer" Tabela

        {Ask} typeIn Tabela Enter
        Moveto [Codigo do Item] Example "ite"
        {Ask} {\\Sistemas\\Estoque\\Itens} Check
        Moveto [Codigo do Item] Example "ite"
        Do_It!
        ClearAll
        
        If IsTable(VSDGDRIVE+"\\Itens")
           Then Delete VSDGDRIVE+"\\Itens"
        Endif
        Create VSDGDRIVE+"\\Itens" Like "\\sistemas\\estoque\\itens"
        Add "Answer" VSDGDRIVE+"\\itens"
        ClearAll

        ;---- Complementos dos Itens -------------------------------------------
        {Ask} typeIn Tabela Enter
        Moveto [Codigo do Item] Example "ite"
        {Ask} {\\Sistemas\\Estoque\\Iten_com} Check
        Moveto [Codigo do Item] Example "ite"
        Do_It!
        ClearAll
        
        If IsTable(VSDGDRIVE+"\\Iten_com")
           Then Delete VSDGDRIVE+"\\Iten_com"
        Endif
        Create VSDGDRIVE+"\\Iten_com" Like "\\sistemas\\estoque\\Iten_com"
        Add "Answer" VSDGDRIVE+"\\Iten_com"
        ClearAll
        
        ;---- Informa‡äes de Tecidos -------------------------------------------
        {Ask} typeIn Tabela Enter
        Moveto [Codigo do Item] Example "ite"
        {Ask} {\\Sistemas\\Estoque\\Iten_tec} Check
        Moveto [Codigo do Item] Example "ite"
        Do_It!
        ClearAll
        
        If IsTable(VSDGDRIVE+"\\Iten_tec")
           Then Delete VSDGDRIVE+"\\Iten_tec"
        Endif
        Create VSDGDRIVE+"\\Iten_tec" Like "\\sistemas\\estoque\\Iten_tec"
        Add "Answer" VSDGDRIVE+"\\Iten_tec"
        ClearAll
        
        ;---- Informa‡äes de e-Commerce ----------------------------------------
        {Ask} typeIn Tabela Enter
        Moveto [Codigo do Item] Example "ite"
        {Ask} {\\Sistemas\\Estoque\\Iten_eco} Check
        Moveto [Codigo do Item] Example "ite"
        Do_It!
        ClearAll
        
        If IsTable(VSDGDRIVE+"\\Iten_eco")
           Then Delete VSDGDRIVE+"\\Iten_eco"
        Endif
        Create VSDGDRIVE+"\\Iten_eco" Like "\\sistemas\\estoque\\Iten_eco"
        Add "Answer" VSDGDRIVE+"\\Iten_eco"
        ClearAll        
        
        ;---- Informa‡äes de C˘digos de Barras ---------------------------------
        {Ask} typeIn Tabela Enter
        Moveto [Codigo do Item] Example "ite"
        {Ask} {\\Sistemas\\Estoque\\Iten_bar} Check
        Moveto [Codigo do Item] Example "ite"
        Do_It!
        ClearAll
        
        If IsTable(VSDGDRIVE+"\\Iten_bar")
           Then Delete VSDGDRIVE+"\\Iten_bar"
        Endif
        Create VSDGDRIVE+"\\Iten_bar" Like "\\sistemas\\estoque\\Iten_bar"
        Add "Answer" VSDGDRIVE+"\\Iten_bar"
        ClearAll         
        
        Delete Tabela
        
        
        
EndIf

If CheckTG_OPCAO[1]
  Then Pedidos() 
  Else Gera_Pedido=True        
EndIf 

ClearAll

EndProc

;*******************************************************************************
;* ROTINA p/ exportar Pedidos                                                  *
;*******************************************************************************
Proc Pedidos()

AGUARDE("Aguarde, Transferindo Pedidos")

Array Arquivo[3]
Arquivo[1]="PedidoC"
Arquivo[2]="PedidoI"
Arquivo[3]="PedidoV"

Cont     = 1

SetDir "\\Sistemas\\Vendas"
For Cont From 1 To 3
    AGUARDE("Aguarde, Transferindo "+Arquivo[Cont])
    If IsTable(Arquivo[Cont])
       Then {Ask} TypeIn VSDGDRIVE+"\\EXPEDC" Enter
;            Moveto [Numero da OE       ] TypeIn "~VSDGEXPEDICAO.."
            Moveto [Numero do Pedido   ] Example "nped"
            If Arquivo[Cont]<>"PedidoC"
               Then {Ask} TypeIn Arquivo[Cont] Enter Check
                    Moveto [Numero do Pedido ] Example "nped"
               Else {Ask} {PedidoC} Check
                    Moveto [Numero do Pedido ] Example "nped"
            EndIf
            Do_It!
            ClearAll
            
            If Arquivo[Cont]="PedidoC" 
              Then If Not IsEmpty("Answer")
                    Then Gera_Pedido=True  
                    Else Gera_Pedido=False 
                         Return
                   EndIf      
            EndIf               
            If IsTable(VSDGDRIVE+"\\"+Arquivo[Cont])
               Then Delete VSDGDRIVE+"\\"+Arquivo[Cont]
            Endif
            Create VSDGDRIVE+"\\"+Arquivo[Cont] Like Arquivo[Cont]
            Add "Answer" VSDGDRIVE+"\\"+Arquivo[Cont]
    EndIf
EndFor

EndProc

;*******************************************************************************
;* Rotina para gerar o log de registro por usu rio                             *
;*******************************************************************************
Proc Gera_Log()          
;---- Gravando LOG ---------------------------------------------------
If VSDGDTINI<>BlankDate()
   Then AUX_DATA = ", periodo de "+StrVal(VSDGDTINI)+" ate "+StrVal(VSDGDTFIM)
   Else AUX_DATA = ", periodo ate "+StrVal(VSDGDTFIM)
EndIf   

AUX_OPCAO=""
If VSDGEXPEDICAO<>"" Then AUX_OPCAO = AUX_OPCAO + "Expedicao "+VSDGEXPEDICAO+", "  EndIf
If VSDGNCARREG<>""   Then AUX_OPCAO = AUX_OPCAO + "Carregamento "+VSDGNCARREG+", " EndIf
If CheckTG_OPCAO[1]
   Then AUX_OPCAO = AUX_OPCAO + "marcado a opcao de exportar pedidos da selecao"+", "
EndIf
AUX_OPCAO = Rtrim(AUX_OPCAO)
If SubStr(AUX_OPCAO,Len(AUX_OPCAO),1)="," Then AUX_OPCAO = Substr(AUX_OPCAO,1,Len(AUX_OPCAO)-1) EndIf
If AUX_OPCAO<>"" Then AUX_OPCAO = ", "+AUX_OPCAO EndIf   

MSG =  "Empresa "+VSDGEMPRESA + AUX_DATA + AUX_OPCAO + ", Drive "+VSDGDRIVE
Grava_Logt("#","TransfOE",MSG)  

EndProc ;Gera_Log()        

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_EXPEDICAO"     : Campo="TG_EMPRESA"
            Case Campo="TG_NCARREG"       : Campo="TG_EXPEDICAO"
            Case Campo="TG_DTINI"         : Campo="TG_NCARREG"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DRIVES"        : Campo="TG_DTFIM"
            Case Campo="TG_OPCAO"         : Campo="TG_DRIVES"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_EXPEDICAO"
                    Case Campo="TG_EXPEDICAO": Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG"  : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"    : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="TG_DRIVES"
                    Case Campo="TG_DRIVES"  : Campo="TG_OPCAO"
                      VSDGDRIVE=ControlValue("TG_DRIVES")
                    Case Campo="TG_OPCAO"    : Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf

If Campo="TG_OPCAO"
  Then MensagemCheckBoxes()
EndIf        

;Monta_Prompt()
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

Proc Deleta_Arquivos()

  Deleta_Arquivo(VSDGDRIVE+"\\Exped*.DB")
  Deleta_Arquivo(VSDGDRIVE+"\\Exped*.MB")
  Deleta_Arquivo(VSDGDRIVE+"\\Exped*.PX")

  Deleta_Arquivo(VSDGDRIVE+"\\Accarrg*.DB")
  Deleta_Arquivo(VSDGDRIVE+"\\Accarrg*.MB")
  Deleta_Arquivo(VSDGDRIVE+"\\Accarrg*.PX")

  Deleta_Arquivo(VSDGDRIVE+"\\Destinat*.DB")
  Deleta_Arquivo(VSDGDRIVE+"\\Destinat*.MB")
  Deleta_Arquivo(VSDGDRIVE+"\\Destinat*.PX")

  Deleta_Arquivo(VSDGDRIVE+"\\Itens*.DB")
  Deleta_Arquivo(VSDGDRIVE+"\\Itens*.MB")
  Deleta_Arquivo(VSDGDRIVE+"\\Itens*.PX")
  
  Deleta_Arquivo(VSDGDRIVE+"\\Iten_*.DB")
  Deleta_Arquivo(VSDGDRIVE+"\\Iten_*.MB")
  Deleta_Arquivo(VSDGDRIVE+"\\Iten_*.PX")
  
  If Gera_Pedido
    Then Deleta_Arquivo(VSDGDRIVE+"\\Pedido*.DB")
         Deleta_Arquivo(VSDGDRIVE+"\\Pedido*.MB")
         Deleta_Arquivo(VSDGDRIVE+"\\Pedido*.PX")
  EndIf  

EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
If Not IsAssigned(SYS_CLIENTE_CONFEC)  Then SYS_CLIENTE_CONFEC=""  EndIf
LimpAguarde()

VSDGEMPRESA   = ""
VSDGNCARREG   = ""
VSDGEXPEDICAO = ""
VSDGDTINI     = BlankDate()
VSDGDTFIM     = Today()-1
Gera_Pedido=False

DynArray Array_Drives[]
SysInfo Drives To Array_Drives
VSDGDRIVE="C:"

Array TG_OPCAO[1]
TG_OPCAO[1]="Exportar pedido(s) referente a sele‡Ćo."

Array CheckTG_OPCAO[ArraySize(TG_OPCAO)]
CheckTG_OPCAO[1]=False

While True
  ShowDialog "Exporta‡„o de ordem de expedi‡„o" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP"  To VSDGNOMEMP

    Label  @ 02,00 "Expedi‡„o" For "TG_EXPEDICAO"
    Accept @ 03,01 Width 9  "A6"  Picture "[&,#][#*#]" Tag "TG_EXPEDICAO" To VSDGEXPEDICAO
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEXPEDICAO" To VSDGNOMEXPEDICAO

    Label  @ 04,00 "Carregamento" For "TG_NCARREG"
    Accept @ 05,01 Width 9  "A6"  Picture "[&,#][#*#]" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG

    Label  @ 06,00 "Perˇodo EmissĆo de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    CheckBoxes @ 09,00 Height 1 Width 45 Tag "TG_OPCAO"
    TG_OPCAO[1] to CheckTG_OPCAO[1]

    Label  @ 00,35 "Drives:" For "TG_DRIVES"
    PickDynArrayIndex @ 01,36 Height 4 width 33
     Columns 7
      Array_Drives
       Tag "TG_DRIVES"
        To VSDGDRIVE

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,35 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

	Deleta_Arquivos()
  Gerou_Dados=False
 
  Processa()
  
  If Not Gera_Pedido
    Then Mensagem("NĆo existe(m) pedido(s) conforme sele‡Ćo ! // //Pedido(s) nĆo foi gerado no Pacote !") 
  EndIf  

  If Not Gerou_Dados
     Then Mensagem("NĆo existe(m) Ordem de Expedi‡„o conforme sele‡Ćo !// //Verificar Empresa, Na Expedi‡„o, Data de Inclus„o e No Carregamento !"+
                   "//Pacote nĆo foi gerado !")
     Else Gera_Log()
          If VSDGEMPRESA="" 
            Then CODEMP="0000" 
            Else CODEMP=VSDGEMPRESA
          EndIf
          ARQ_ARJ=VSDGDRIVE+"\\PT_EXP_"+CODEMP+"_"+
                  AlinhM(StrVal(Year(Today())),4) +
                  AlinhM(StrVal(Month(Today())),2)+
                  AlinhM(StrVal(Day(Today())),2)  +
                  ".ARJ"
          
          Aguarde("Aguarde, Compactando pacote de transa‡„o p/ "+ARQ_ARJ)
          Deleta_Arquivo(ARQ_ARJ)
          Sleep 2000
          
          ARQ_TAB=VSDGDRIVE+"\\Exped*.* "+
                  VSDGDRIVE+"\\Accarrg*.* "+
                  VSDGDRIVE+"\\Destinat*.* "+
                  VSDGDRIVE+"\\Ite*.* "
          If Gera_Pedido
            Then ARQ_TAB=ARQ_TAB+VSDGDRIVE+"\\Pedido*.*"     
          EndIf
          Executa_Programa("c:\\vise\\Varj.exe a "+ARQ_ARJ+" "+ARQ_TAB)
          Sleep 2000       
          
          Limpaguarde()
        
          MSG="Pacote de transa‡„o gerado !// //"
          MSG=MSG+"Arquivo em "+ARQ_ARJ+"// //"
          MSG=MSG+"Verifique !"
          Mensagem(MSG)
  EndIf

	Deleta_Arquivos()

EndWhile
ClearAll
Release Vars All
Release Procs All
