;** ALTY ***********************************************************************
;* Teclas de Atalho                                                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 04/02/2016 por Bruno Carvalho                     
;Ultima Alteracao: 07/02/2017 por Kamila Gomes             
;Motivo Alteracao: InclusÆo Vari vel SYS_NOME_USUARIO           

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_CODIGO_CLIENTE"    : Campo="NO"
            Case Campo="TG_CLIENTE_CONFEC"    : Campo="TG_CODIGO_CLIENTE"
            Case Campo="TG_USUARIO"           : Campo="TG_CLIENTE_CONFEC"
            Case Campo="TG_NIVEL_ACESSO"      : Campo="TG_USUARIO"
            Case Campo="YES" Or Campo="NO"    : Campo="TG_CODIGO_CLIENTE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13: 
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_CODIGO_CLIENTE"  : Campo="TG_CLIENTE_CONFEC"
                         SYS_CODIGO_CLIENTE = ControlValue("TG_CODIGO_CLIENTE")
                         If Not IsBlank(SYS_CODIGO_CLIENTE)
                            Then SYS_CODIGO_CLIENTE=AlinhM(SYS_CODIGO_CLIENTE,4)
                         EndIf   
                    Case Campo="TG_CLIENTE_CONFEC"  : Campo="TG_USUARIO"
                         SYS_CLIENTE_CONFEC = ControlValue("TG_CLIENTE_CONFEC")
                         If Not IsBlank(SYS_CLIENTE_CONFEC)
                            Then SYS_CLIENTE_CONFEC=AlinhM(SYS_CLIENTE_CONFEC,4)
                         EndIf   
                    Case Campo="TG_USUARIO"  : Campo="TG_NIVEL_ACESSO"
                         SYS_CHAPA_USUARIO = ControlValue("TG_USUARIO")
                         If Not IsBlank(SYS_CHAPA_USUARIO)
                            Then SYS_CHAPA_USUARIO=AlinhM(SYS_CHAPA_USUARIO,4)
                                 GetRecord "\\Sistemas\\Cadastro\\Usuarios" SYS_CHAPA_USUARIO To REG_USUARIO
                                 If Retval
                                    Then SYS_NIVEL_USUARIO = REG_USUARIO["Nivel de Acesso"]
                                         SYS_NOME_USUARIO  = REG_USUARIO["Nome"]
                                    Else Mensagem("Usu rio "+SYS_CHAPA_USUARIO+" n„o localizado")
                                         SYS_NIVEL_USUARIO=""
                                         SYS_NOME_USUARIO =""
                                         Campo="TG_USUARIO"
                                 EndIf   
                            Else SYS_CHAPA_USUARIO="9999"
                                 SYS_NIVEL_USUARIO="S"
                                 SYS_NOME_USUARIO ="VISE"
                         EnDIf                    
                    Case Campo="TG_NIVEL_ACESSO"  : Campo="YES"     
                         SYS_NIVEL_USUARIO = ControlValue("TG_NIVEL_ACESSO")
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_NIVEL_ACESSO":
     MSG_CAMPO="Nivel de Acesso"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
If SysMode()="Edit" Or SysMode()="CoEdit" Or SysMode()="Main"
   Then AutoLib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"
        If Not IsAssigned(SYS_CODIGO_CLIENTE) Then SYS_CODIGO_CLIENTE="" EndIf 
        If Not IsAssigned(SYS_CLIENTE_CONFEC) Then SYS_CLIENTE_CONFEC="" EndIf  

        If Not IsAssigned(SYS_CONTROLE_DIA)     Then SYS_CONTROLE_DIA=""      EndIf
        If Not IsAssigned(SYS_CONTROLE_DIA_MOD) Then SYS_CONTROLE_DIA_MOD=""  EndIf
        If Not IsAssigned(SYS_NIVEL_USUARIO)    Then SYS_NIVEL_USUARIO=""     EndIf

        If SYS_CODIGO_CLIENTE="" Or SYS_CODIGO_CLIENTE=""
           Then SYS_Valor() 
        EndIf   

        ShowDialog "" Proc "SD_Dialog"
        Trigger "OPEN","ARRIVE"
        Key "F1","ENTER","ESC","TAB",
            -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
         @ 05,12   Height 11 Width 40
      
          Label  @ 00,00 "Codigo do Cliente" For "TG_CODIGO_CLIENTE"
          Accept @ 01,01 Width 07 "A4"  Picture "!*!" Tag "TG_CODIGO_CLIENTE" To SYS_CODIGO_CLIENTE
      
          Label  @ 02,00 "Codigo Cliente Confec" For "TG_CLIENTE_CONFEC"
          Accept @ 03,01 Width 07 "A4"  Picture "!*!" Tag "TG_CLIENTE_CONFEC" To SYS_CLIENTE_CONFEC
      
          Label  @ 04,00 "Usu rio" For "TG_USUARIO"
          Accept @ 05,01 Width 07 "A4"  Picture "!*!" Tag "TG_USUARIO" To SYS_CHAPA_USUARIO
      
          Label  @ 04,08 "NA" For "TG_NIVEL_ACESSO"
          Accept @ 05,09 Width 04 "A1"  Picture "S,C,P,E,I" Tag "TG_NIVEL_ACESSO" To SYS_NIVEL_USUARIO
      
          Pushbutton @ 07,07 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
          Pushbutton @ 07,21 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue
      
        EndDialog
        If Not RetVal 
           Then Release Vars SYS_CODIGO_CLIENTE,SYS_CLIENTE_CONFEC
           Else If IsBlank(SYS_CHAPA_USUARIO)
                   Then SYS_CHAPA_USUARIO="9999"
                        SYS_NIVEL_USUARIO="S"
                        SYS_NOME_USUARIO ="VISE"
                EndIf        
        EndIf
        ClearAll
EndIf        
