;** RM_0089B *******************************************************************
;*  posicao de Titulos a receber por pessoa                                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 16/02/2017 por Bruno Carvalho
;Ultima Alteracao: 25/09/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: ajustes contas a receber
;Ultima Alteracao: 12/03/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: ajustes filtro tipo, modelorelatorio 
;Ultima Alteracao: 13/03/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: ajustes plano de conta 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll
 
If IsTable("\\Sistemas\\ctarec\\"+Dir_Trab+"Duplic") 
   Then {Ask} TypeIn "\\Sistemas\\ctarec\\"+Dir_Trab+"Duplic" Enter
        Moveto [Numero do Lancamento    ] Check
        Moveto [Codigo da Empresa       ] Check TypeIn "~VSDGEMPRESA.."
        Moveto [Nome Fantasia Empresa   ] Check
        Moveto [Codigo do Destinatario  ] Check TypeIn "~VSDGDESTINAT.., as Codigo"
        Moveto [Razao Social            ] Check
        Moveto [Codigo do Documento     ] Check
        Moveto [Tipo do Documento       ] Check
        Moveto [Serie do Documento      ] Check
        Moveto [Numero do Documento     ] Check
        Moveto [Data de Emissao         ] Check TypeIn "<=~VSDGDTINI"
        Moveto [Data de Vencimento      ] Check
        Moveto [Tipo do Lancamento      ] TypeIn "~VSDGTPLANC.."
        Moveto [Valor do Documento      ] Check
        Moveto [Saldo do Documento      ] Check
        Moveto [Codigo Plano_Conta      ] typeIn PLCONTAS
        Do_It!
        ClearAll

        {Ask} "\\Sistemas\\Cadastro\\Destinat" Enter
        Moveto [Codigo                 ] Example "ccli"
        Moveto [Tipo                   ] TypeIn "~VSDGTIPO.."
        {Ask} {Answer} Check
        Moveto [Codigo                 ] Example "ccli"
        Do_It!
        ClearAll
        
        Adiciona_Indice("Answer","Numero do Lancamento")
        
        Tabela=Cria_Temp(PrivDir())
        Copy "Answer" Tabela

        If IsTable("\\Sistemas\\ctarec\\"+Dir_Trab+"Dupbaixa")
           Then {Ask} {Answer}
                Moveto [Numero do Lancamento    ] Example "nlanc"
                {Ask} TypeIn "\\Sistemas\\ctarec\\"+Dir_Trab+"Dupbaixa" Enter
                Moveto [Numero do Lancamento    ] Check Example "nlanc"
                Moveto [Sequencia da Baixa      ] Check 
                Moveto [Data do Pagamento       ] Check TypeIn ">~VSDGDTINI, as Data"
                Moveto [Valor do Recebimento    ] Check
                Moveto [Valor do Juros          ] Check
                Moveto [Valor do Desconto       ] Check
                Moveto [Tipo da Baixa           ] Check
                Do_It!                                                             
                ClearAll 

                Adiciona_Indice("Answer","Numero do Lancamento,Sequencia da Baixa")
                ClearAll
                
                If Not IsEmpty("Answer")
                   Then View Tabela
                        CoEdit "Answer"
                        Scan
                          DOC_VR = ([Valor do Recebimento]+[Valor do Desconto])-[Valor do Juros]
                          
                          Moveto Tabela
                          Moveto [Numero do Lancamento]
                          Locate [Answer->Numero do Lancamento]
                          If Retval
                             Then [Saldo do Documento] = [Saldo do Documento] + DOC_VR
                          EndIf
                          
                          Moveto "Answer"
                        EndScan  
                        Do_It!
                        ClearAll
                EnDIf
        EndIf
                
        If VSDGCODMODELO = "02"
           Then {Ask} Typein Tabela Enter
                Moveto [Codigo da Empresa       ] Check
                Moveto [Codigo                  ] Check
                Moveto [Saldo do Documento      ] TypeIn ">0, Calc Sum as Saldo do Documento"
                Do_It!
                ClearAll
           Else {Ask} Typein Tabela Enter Check
                Moveto [Saldo do Documento      ] TypeIn ">0"
                Do_It!
                ClearAll
        EndIf
        
        If Not IsEmpty("Answer")
           Then {Ask} {Answer}
                Moveto [Codigo da Empresa       ] Example "a"
                Moveto [Codigo                  ] Example "b"
                Moveto [Saldo do Documento      ] Example "c"
                If VSDGCODMODELO = "01"
                   Then Moveto [Valor do Documento ] Example "vrdoc"
                        Moveto [Tipo do Documento  ] Example "tpdoc"
                        Moveto [Numero do Documento] Example "numdoc"
                        Moveto [Data de Emissao    ] Example "dte"
                        Moveto [Data de Vencimento ] Example "dtv"
                EndIf        
                {Ask} TypeIn TabelaRef Enter TypeIn "Fast Insert"
                Moveto [Codigo da Empresa       ] Example "a"
                Moveto [Codigo                  ] Example "b"
                Moveto [Saldo                   ] Example "c"
                If VSDGCODMODELO = "01"
                   Then Moveto [Valor Original     ] Example "vrdoc"
                        Moveto [Tipo do Documento  ] Example "tpdoc"
                        Moveto [Numero do Documento] Example "numdoc"
                        Moveto [Data de Emissao    ] Example "dte"
                        Moveto [Data de Vencimento ] Example "dtv"
                EndIf
                Do_It!
                ClearAll
        EndIf
EndIf         
   
EndProc ;Seleciona()

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa2()

;********** Pegar nome fantasia empresa **********
{Ask} TypeIn TabelaRef Enter TypeIn "Fast"
Moveto [Codigo da Empresa       ] Example "cemp"
Moveto [Nome Fantasia Empresa   ] TypeIn "changeto _nemp"
{Ask} "\\Sistemas\\Cadastro\\Empresas" Enter
Moveto [Codigo da Empresa       ] Example "cemp"
Moveto [Nome Fantasia Empresa   ] TypeIn "_nemp"
Do_It!
ClearAll

;********** Pegar razao social/cgc **********
{Ask} TypeIn TabelaRef Enter TypeIn "Fast"
Moveto [Codigo                  ] Example "ccli"
Moveto [Razao Social            ] TypeIn "changeto _ncli"
Moveto [CGC                     ] TypeIn "changeto _cgc"
{Ask} "\\Sistemas\\Cadastro\\Destinat" Enter
Moveto [Codigo                  ] Example "ccli"
Moveto [Razao Social            ] TypeIn "_ncli"
Moveto [CGC                     ] TypeIn "_cgc"
Do_It!
ClearAll                                                            

EndProc     ; (Processa2) 

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_DESTINAT"       : Campo="TG_EMPRESA"
            Case Campo="TG_TPLANC"         : Campo="TG_DESTINAT"
            Case Campo="TG_TIPO"           : Campo="TG_TPLANC"
            Case Campo="TG_PLCONTAS"       : Campo="TG_TIPO"
            Case Campo="TG_DTREF"          : Campo="TG_PLCONTAS"
            Case Campo="TG_CODMODELO"      : Campo="TG_DTREF"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_TPLANC"   
                    Case Campo="TG_TPLANC"     : Campo="TG_TIPO"
                    Case Campo="TG_TIPO"       : Campo="TG_PLCONTAS"
                         VSDGTIPO=ControlValue("TG_TIPO")
                         Switch
                           Case VSDGTIPO="C": VSDGNOMTIPO="CLIENTES"
                           Case VSDGTIPO="F": VSDGNOMTIPO="FORNECEDORES"
                           OtherWise        : VSDGNOMTIPO="TODOS"
                         EndSwitch                                  
                    Case Campo="TG_PLCONTAS"   : Campo="TG_DTREF"
                    Case Campo="TG_DTREF"      : Campo="TG_CODMODELO" 
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_TIPO":
     MSG_CAMPO="Informe (C=Clientes  F=Fornecedores  Em Branco=Todos)"
Endswitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Analˇtico")
ModeloRelatoriosAdd("02  Sint‚tico")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  = ""  
VSDGNOMEMP   = ""
VSDGDESTINAT = ""
VSDGNOMDEST  = ""
VSDGTPLANC   = ""
VSDGNOMLANC  = ""
VSDGDTREF    = BlankDate() 

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Posi‡„o de Titulos … Receber por Pessoa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 19 Width 72                                                                          
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
    
    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST
    
    Label  @ 04,00 "Tipo de Lan‡amento"  For "TG_TPLANC"
    Accept @ 05,04 Width 04 "A1"  Picture "!*!" Tag "TG_TPLANC" To VSDGTPLANC
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMLANC"  To VSDGNOMLANC
    
    Label  @ 06,00 "Tipo" For "TG_TIPO"
    Accept @ 07,04 Width 04 "A1"  Picture "C,F" Tag "TG_TIPO" To VSDGTIPO
    Accept @ 07,09 Width 25 "A13" Picture "!*!" Tag "TG_NOMTIPO" To VSDGNOMTIPO

    Label  @ 08,00 "Plano de Contas" For "TG_PLCONTAS"
    Accept @ 09,01 Width 33 "A13"  Picture "!*!" Tag "TG_PLCONTAS" To VSDGPLCONTAS
    Accept @ 10,01 Width 33 "A40" Picture "!*!" Tag "TG_NOMPLCONTAS"  To VSDGNOMPLCONTAS

    Label  @ 00,35 "Data Referente" For "TG_DTREF"
    Accept @ 01,36 Width 14 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF
                                                                                            
    Label  @ 12,00  "Modelo de ~R~elat˘rio"  For "TG_CODMODELO"
    Accept @ 13,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 13,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 15,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If VSDGDTREF=BlankDate() or VSDGDTREF>Today() 
     Then Mensagem("Data Referente Inv lida !")   
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf
  
  AGUARDE("Aguarde, Processando Dados")
  TabelaRef=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\ctarec\\Rm_0089b" TabelaRef
  Empty(TabelaRef)
  
  VSDGDTINI = VSDGDTREF
  VSDGDTFIM = Today()
  
  If Len(VSDGPLCONTAS)<13
     Then PLCONTAS=VSDGPLCONTAS + ".."
     Else PLCONTAS=VSDGPLCONTAS
  EndIf
  
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona() 
  EndWhile
  
  If IsEmpty(TabelaRef)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Delete TabelaRef
          Loop
  EndIf
  Processa2()
    
  switch
   case VSDGCODMODELO="01": IMPRIREL(TabelaRef,"1")
   case VSDGCODMODELO="02": IMPRIREL(TabelaRef,"R")
  endswitch
  
  Delete Tabela
  Delete TabelaRef
EndWhile
ClearAll
Release Vars All
Release Procs All
