;** RO_0291 ********************************************************************
;** Imprime a Digitacao do Romaneio                            ** Lassal **    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 14/03/2011 por Bruno Carvalho
;Alterado      em: 31/05/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes para controle de linha e config. p/ imp. em JATO DE TINTA . Folha A4          
;Ultima Alteracao: 02/08/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Loop Impressao NP
;Alterado      em: 17/12/2011 por Bruno Carvalho
;Motivo Alteracao: Adicionado Informacoes_Adicionais nos itens  
;Alterado      em: 09/01/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes para imprimir duas vias na mesma folha com 14 itens, e ajustado os vencimentos 
;Ultima Alteracao: 31/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desconto item

;*******************************************************************************
;* ImpressÆo do Cabe‡alho                                                      *
;*******************************************************************************
Proc Cabecalho();
If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf
Moveto "Faturac"
Print File ARQIMP chr(27)+chr(67)+chr(33) ;Imprime 33 Linhas por pagina
Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP

;Print File ARQIMP "\n"
Print File ARQIMP Format("W50,AL","    ")+"Impressao: "+Format("D10",Today())+"-"+Time()+ "\n\n"

Print File ARQIMP "\014"
Print File ARQIMP "\027E"
Print File ARQIMP Spaces(20)+"Orcamento N§ "+Format("W06.3,AL",NOTAFISC)+"\n\n"
Print File ARQIMP "\020"

Print File ARQIMP "\027F"+"Emissao : "+Format("D10",[Data de Emissao])+"\n"
Print File ARQIMP "\027E"+"Cliente : "+Format("W05,AL",[Codigo])+Format("W46,AL",[Razao Social])+"\n"
Print File ARQIMP "\027F"

Print File ARQIMP CI_10CPP
Print File ARQIMP CI_8LPP

Print File ARQIMP Spaces(10)+Format("W40,AL",[Endereco])
Print File ARQIMP Format("W18,AL",[CGC])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Bairro])
Print File ARQIMP Format("W20,AL",[CEP])
Print File ARQIMP Format("W25,AL",[IE])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Cidade])
Print File ARQIMP Format("W20,AL",[UF])
Print File ARQIMP Format("W25,AL",[Telefone])+"\n"

Print File ARQIMP "Operacao: "
Print File ARQIMP Chr(27)+Chr(71)
Print File ARQIMP ""+[Codigo da Destinacao]+" "+[Descricao da Destinacao]+"\n"
Print File ARQIMP Chr(27)+Chr(72)

Print File ARQIMP "Vendedor: "+Format("W05,AL",[Codigo do Representante])
Print File ARQIMP Format("W25,AL",[Nome Fantasia Represent])+"\n"
Print File ARQIMP "\015"         ;Imprime 17 Caracteres por polegada

;********************* IMPRESSAO DOS ITENS ********************************
Print File ARQIMP "------------------------------------------------------------------------------------------------------------------------"+"\n"
Print File ARQIMP Spaces(02)+"Item                                                                           Un  Quantidade  Unitario        Total"+"\n"
Print File ARQIMP "------------------------------------------------------------------------------------------------------------------------"+"\n"

EndProc ;(Cabecalho)

;*******************************************************************************
;* Checa linha na area de impressao dos itens                                  *
;*******************************************************************************
Proc Checa_Linha(Nl)
private nl

If (CONTADOR+nl)>(CONTA_ITENS)
   Then RodaPe(True)
        Print File ARQIMP "\f"
        Cabecalho()
        CONTADOR=nl
        Moveto "FaturaI"
   Else CONTADOR=CONTADOR+nl
EndIf
EndProc

;*******************************************************************************
;* ImpressÆo dos Itens                                                         *
;*******************************************************************************
Proc Itens()
       
Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]

CONTA_ITENS = 0

While [Numero da OF]=[FaturaC->Numero da OF]
  CONTA_ITENS = CONTA_ITENS+1
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile

Switch
 ;Case CONTA_ITENS <= 2 : CONTA_ITENS  = 2
  Case CONTA_ITENS <=14 : CONTA_ITENS  = 14
  Case CONTA_ITENS > 14 : CONTA_ITENS  = 55 
EndSwitch

CONTADOR = 0

Home
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
  Checa_Linha(1)
  Print File ARQIMP Spaces(02)+Format("W03,AR",StrVal([Item da OF]))
  Print File ARQIMP Spaces(01)+Format("W11,AL",[Codigo do Item])
  Print File ARQIMP Spaces(01)+Format("W30,AL",[Descricao do Item]) ;62
  Print File ARQIMP Spaces(01)+Format("W31,AL",[Informacoes_Adicionais])
  Print File ARQIMP Spaces(01)+Format("W03,Al",[Unidade Fiscal])
  Print File ARQIMP Format("W09.3,EIC",[Quantidade])
  Print File ARQIMP Format("W10.2,EIC",[Preco Unitario])
  Print File ARQIMP Spaces(02)+Format("W13.2,EIC",[Preco Total])+"\n"

  Skip
  If EOT() Then QuitLoop EndIf
EndWhile

For ITEM From CONTADOR To CONTA_ITENS
    If CONTADOR = CONTA_ITENS 
       Then QuitLoop
    EndIf
    Print File ARQIMP "\n"
EndFor 

Print File ARQIMP CI_8LPP
EndProc ;(Itens)

;*******************************************************************************
;* ImpressÆo do Rodap‚                                                         *
;*******************************************************************************
Proc Rodape(QUEBRAFORM)
Private QUEBRAFORM

Print File ARQIMP "-----------------------------------------------------------------------------------------------------------------------"+"\n"

;********************* IMPRESSAO DOS TOTAIS **************************
Moveto "FaturaC"

If QUEBRAFORM
   Then Print File ARQIMP Spaces(87)+"Total.............."+"    *******  "+"\n"
   Else Print File ARQIMP Spaces(87)+"Total.............."+Format("W11.2,EIC",[Valor Mercadoria])+"\n" 
EndIf

If QUEBRAFORM
   Then Print File ARQIMP Spaces(87)+"Desconto  **  %...."
        Print File ARQIMP "    *******  "+"\n"
        Print File ARQIMP Spaces(87)+"Total Liquido......"+"    *******  "+"\n\n"
   Else Print File ARQIMP Spaces(87)+"Desconto"+Format("W06.2,EIC",[Taxa de Desconto]) + "%...."
        Print File ARQIMP Format("W08.2,EIC",[Valor Desconto])+"\n"
        Print File ARQIMP Spaces(87)+"Total Liquido......"+Format("W11.2,EIC",[Valor Mercadoria Liquido]+[Valor Servico])+"\n"
EndIf

Print File ARQIMP Spaces(00)+"OBS.: "
Print File ARQIMP Format("W110,AL",SubStr([Observacao na Nota Fiscal],001,110))+"\n"

Print File ARQIMP "Cond. Pagto: "+[Descricao CondPagto]
Print File ARQIMP "   NP: "+StrVal([Numero de Parcelas])
Print File ARQIMP "   CD: "+[Composicao de Dias]+"\n"

;********************* IMPRESSAO DOS VENCIMENTOS **************************
Print File ARQIMP "\018"
Print File ARQIMP "\027E"
Print File ARQIMP "Vencimentos: "

Array DATA[5]
Array VALOR[5]
K=0
KV=0
Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
  K=K+1
  DATA[K]  = Format("D13",[Data])
  VALOR[K] = Format("W10.2,AR,EIC",[Valor])
  If K=5
     Then VENC()
          K=0
  EndIf
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile
If K>0
   Then VENC()
EndIf
Print File ARQIMP "\n"
Print File ARQIMP "\027F"

If QUEBRAFORM
   Then Print File ARQIMP "\n\n\n\n\n"
   Else Print File ARQIMP Spaces(12)+"   /   /     -                                   " + "\n"
        Print File ARQIMP Spaces(12)+"-------------------------------------------------" + "\n"
        Print File ARQIMP Spaces(12)+"              Data e Assinatura"+"\n"
        If CONTA_ITENS <=14
          Then Print File ARQIMP "\n\n"
          Else Print File ARQIMP "\n\n\n\n\n\n"
        EndIf  
        Print File ARQIMP CI_6LPP
        Print File ARQIMP CI_10CPP
EndIf   

EndProc ;Rodape

;*******************************************************************************
;* Rotina de Impressao dos Vencimentos                                         *
;*******************************************************************************
Proc VENC()
If KV>0
   Then Print File ARQIMP Spaces(13)
EndIf

If IMPRIMINDO_PARCELAS
   Then Print File ARQIMP DATA[NP]+Spaces(02)+"\n"
        Print File ARQIMP Spaces(13)+VALOR[NP]+Spaces(02)+"\n\n"
        return
EndIF

For I From 1 to K
  Print File ARQIMP DATA[I]+Spaces(02)
EndFor
Print File ARQIMP "\n"
Print File ARQIMP Spaces(13)
For I From 1 to K
  Print File ARQIMP VALOR[I]+Spaces(02)
EndFor
Print File ARQIMP "\n\n"

KV=KV+1
EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
ArqImp=PrivDir()+"Ro_0291.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)

For Wc From 1 To 3 

  IMPRIMINDO_PARCELAS=FALSE
  NParc=[FaturaC->Numero de Parcelas]
  If NParc<1 Then NParc=1 EndIf

  For NP From 1 to NParc
    If [FaturaV->Forma de Pagamento]="NP"
       Then IMPRIMINDO_PARCELAS=TRUE
    EndIf
    Cabecalho()
    Itens()
    Rodape(False) 
    If IMPRIMINDO_PARCELAS=False Then QuitLoop EndIf
  EndFor

  If CONTA_ITENS = 14 And Wc = 2
     Then Print File ARQIMP "\f"
     Else If CONTA_ITENS = 55 And Wc = 1
             Then Print File ARQIMP "\f"
          EndIf
  EndIf
  
EndFor
NUMCOPIA=1
ImpriArq(ARQIMP)

Release Vars VALOR,DATA
Release Procs IMPFAT,VENC
LIMPAGUARDE()
