;** Rm_0023  *******************************************************************
;* Relacao de Notas Fiscais com ST                                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 04/04/2012 por Karina Andrade
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 18/06/2014 por Luis Gustavo
;Motivo Alteracao: Adicionado Modelo SIMPLES e por POR ESTADO
;Ultima Alteracao: 10/07/2014 por Andrey Fillipe
;Motivo Alteracao: Adicionado Seleciona2() e coluna Vlr Itens c/ST
;Ultima Alteracao: 03/09/2014 por Kamila Gomes
;Motivo Alteracao: Ajustes Seleciona() Ask no NotaI
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 05/08/2017 por Bruno Carvalho
;Motivo Alteracao: Substituido [Valor IR] -> [Valor DebitoCredito]   
;Ultima Alteracao: 01/03/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes zerar valores e deixar um por nota

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check
         Moveto [Codigo da Empresa          ] Example "Empresa" TypeIn ", ~VSDGEMPRESA.."
         Moveto [Numero do Documento        ] Example "Docto"
         Moveto [Serie do Documento         ] Example "Serie"
         Moveto [Data de Emissao            ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
         Moveto [Descricao da Destinacao    ] TypeIn "VENDA.."
         Moveto [Situacao                   ] Typein "Not C"
         Moveto [Valor BCSubstituicao ICMS  ] TypeIn ">0"
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"Notai" Enter Check
         Moveto [Codigo da Empresa          ] Example "Empresa"
         Moveto [Numero do Documento        ] Example "Docto"
         Moveto [Serie do Documento         ] Example "Serie"
         Moveto [Situacao_Item              ] TypeIn "Not C"
         Do_It!
         ClearAll
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona2()
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Valor DebitoCredito] TypeIn "changeto 0.00"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa          ] Check
Moveto [Numero do Documento        ] Check
Moveto [Serie do Documento         ] Check
Moveto [ICMS_ST_BC                 ] TypeIn ">0" 
Moveto [Preco Total                ] TypeIn "Calc Sum as Preco Total" 
Do_It!
ClearAll

View Tabela
Coedit "Answer"

Scan
 Moveto Tabela
 Locate [Answer->Codigo da Empresa],[Answer->Numero do Documento],[Answer->Serie do Documento]
 If RetVal
    Then [Valor DebitoCredito] = [Answer->Preco Total]
 EndIf          
 Moveto "Answer"
EndScan
Do_It!
ClearAll
EndProc   ; (Seleciona2)

;*******************************************************************************
;* Rotina Ajusta Dados                                                         *
;*******************************************************************************
Proc Ajusta_Dados()
ClearAll

Sort Tabela On "Codigo da Empresa", "Numero do Documento", "Serie do Documento","Item do Documento"

CDEMPR="****"
NDOCTO="****"
SDOCTO="****"

CoEdit Tabela
Scan
 If [Codigo da Empresa  ]<>CDEMPR Or
    [Numero do Documento]<>NDOCTO Or
    [Serie do Documento ]<>SDOCTO
    Then CDEMPR=[Codigo da Empresa  ]
         NDOCTO=[Numero do Documento]
         SDOCTO=[Serie do Documento ]
    Else 
         [Valor Nota Fiscal        ]=BlankNum()
         [Valor Mercadoria         ]=BlankNum()
         [Valor Mercadoria Liquido ]=BlankNum()

         ;Ultima Alteracao: 01/03/2018 por Anivel Augusto Rodrigues
         [Valor IPI                ]=BlankNum()
         [Valor do Frete           ]=BlankNum()
         [Valor Despesas Acessorias]=BlankNum()
         [Valor BCSubstituicao ICMS]=BlankNum()
         [Valor Substituicao ICMS  ]=BlankNum()
         [Valor DebitoCredito      ]=BlankNum()
 EndIf
EndScan
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CSITENS"       : Campo="TG_DTFIM"
            Case Campo="TG_OPRELATORIO"   : Campo="TG_CSITENS"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_CSITENS"
                    Case Campo="TG_CSITENS"     : Campo="TG_OPRELATORIO"
                    Case Campo="TG_OPRELATORIO" : Campo="YES"
                         VSDGOPRELATORIO=ControlValue("TG_OPRELATORIO")
                         Switch
                            Case VSDGOPRELATORIO="1": VSDGNOMOPRELATORIO="SIMPLES"
                            Case VSDGOPRELATORIO="2": VSDGNOMOPRELATORIO="POR ESTADO"
                            OtherWise:                VSDGOPRELATORIO="1"
                                                      VSDGNOMOPRELATORIO="SIMPLES"
                         EndSwitch
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPRELATORIO":
     MSG_CAMPO="1= Simples, 2= Por Estado "
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGCSITENS =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Rela‡„o Notas Fiscais com ST" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 13 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 04,00 "Op‡„o p/ Itens" For "TG_CSITENS"
    Accept @ 05,04 Width 04 "A1"  Picture "S,C" Tag "TG_CSITENS" To VSDGCSITENS
    Accept @ 05,09 Width 25 "A20"  Picture "!*!" Tag "TG_NOMCSITENS" To VSDGNOMCSITENS
    
    Label  @ 06,00 "Op‡„o do Relat˘rio" For "TG_OPRELATORIO"
    Accept @ 07,04 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELATORIO" To VSDGOPRELATORIO
    Accept @ 07,09 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELANASINT2" To VSDGNOMOPRELATORIO

    Pushbutton @ 09,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf
  
  AGUARDE("Aguarde, gerando o relat˘rio")
  Tabela =Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile
  
  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
   
  Ajusta_Dados()
  
  If VSDGOPRELATORIO="2" Then Seleciona2() EndIf
  
  Impressao_Orientacao="Paisagem"
  Switch 
     Case VSDGCSITENS="C" And VSDGOPRELATORIO="1" :
          CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2004" "R" Tabela "R"
     Case VSDGCSITENS="S" And VSDGOPRELATORIO="1" :
          CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2004" "1" Tabela "R"
     Case VSDGCSITENS="C" And VSDGOPRELATORIO="2" :
          CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2004" "2" Tabela "R"
     Case VSDGCSITENS="S" And VSDGOPRELATORIO="2" :
          CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2004" "3" Tabela "R"   
  EndSwitch
     
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
