;** Rm_0200A ******************************************************************
;*  Analitico  p/ Plano de Contas                                             *
;******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 08/11/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 06/12/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 27/06/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Modelo Relatorio
;Ultima Alteracao: 05/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 15/12/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Report 5 (Tipo de Despesa)
;Ultima Alteracao: 02/12/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes CopyReport
;Ultima Alteracao: 03/09/2014 por Luis Gustavo
;Motivo Alteracao: Adicionado filtro Opao de data
;Ultima Alteracao: 03/02/2015 por Luis Gustavo
;Motivo Alteracao: Implementado Filtro Despesas, filtra pelo Campo Tipo_Custo da tabela PLCONTAS
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                   
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes cącigos modelo de relatorios
;Ultima Alteracao: 19/01/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo de Operacao 03, 12           
;Ultima Alteracao: 30/04/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao novo processo concetrador RM_0200, RM_0240

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaRM_0200A()
ClearAll

If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont")
  Then {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter Check
       Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo da Conta    ] TypeIn "~VSDGCONTA.."
       Moveto [Tipo de Operacao   ] TypeIn "05 or 06 or 07 or 13 or 14 or 03 or 12"
       If VSDGOPDTEMISCOMP="1"
          Then Moveto [Data Competencia] Check
               Moveto [Data            ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Else Moveto [Data            ] Check
               Moveto [Data Competencia] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM, as Data"
       EndIf
       Moveto [Codigo do EmitDest ] TypeIn "~VSDGDESTINAT.."
       Moveto [Codigo Plano_Conta ] TypeIn PLCONTAS
       Moveto [Cheque Pre-Datado  ] TypeIn "Not S"
       Do_It!
       ClearAll
       
       If Not IsBlank(VSDGDESP)
          Then {Ask} "Answer" Enter Check
               Moveto [Codigo Plano_Conta ] Example "plcont"
               {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"Plcontas" Enter
               Moveto [Codigo Plano_Conta ] Example "plcont"
               Moveto [Tipo_Custo         ] Check TypeIn "~VSDGDESP.."
               Do_It!
               ClearAll
       EndIf
EndIf
EndProc     ;  (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaRM_0200A2()
ClearAll

If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont")
  Then {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter Check
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo da Conta       ] TypeIn "~VSDGCONTA.."
       Moveto [Tipo de Operacao      ] TypeIn "05"
       Moveto [Codigo do EmitDest    ] TypeIn "~VSDGDESTINAT.."
       Moveto [Codigo Plano_Conta    ] TypeIn PLCONTAS
       Moveto [Cheque Pre-Datado     ] TypeIn "S"
       Moveto [Data Cheque Pre-Datado] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       If VSDGOPDTEMISCOMP = "2"
          Then Moveto [Data                  ] Check
               Moveto [Data Competencia      ] TypeIn "as Data"
          Else Moveto [Data Competencia      ] Check
       EndIf
       Do_It!
       ClearAll
       
       If Not IsBlank(VSDGDESP)
          Then {Ask} "Answer" Enter Check
               Moveto [Codigo Plano_Conta ] Example "plcont"
               {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"Plcontas" Enter
               Moveto [Codigo Plano_Conta ] Example "plcont"
               Moveto [Tipo_Custo         ] Check TypeIn "~VSDGDESP.."
               Do_It!
               ClearAll
       EndIf
EndIf
EndProc     ;  (Seleciona)

;*******************************************************************************
;* Rotina p/ Processar Registros                                               *
;*******************************************************************************
Proc ProcessaRM_0200A()
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Tipo de Operacao       ] TypeIn "05"
Moveto [Cheque Pre-Datado      ] TypeIn "S"
Moveto [Data Cheque Pre-Datado ] TypeIn "_dchp"
Moveto [Data                   ] TypeIn "Changeto _dchp"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
TypeIn "Fast"
Moveto [Lancamento Gerador     ] TypeIn "_nlan, Not Blank"
Moveto [Numero do Lancamento   ] TypeIn "Changeto _nlan"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
TypeIn "Fast"
Moveto [Sistema Gerador        ] TypeIn "Blank, Changeto CB"
Do_It!
ClearAll

EndProc     ;  (Seleciona)

;*******************************************************************************
;* ROTINA Ajusta Dados Empresa                                                 *
;*******************************************************************************
Proc ProcessaRM_0200A2()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

EndProc

;*******************************************************************************
;* Rotina p/ Ajustar tipocusto                                                 *
;*******************************************************************************
Proc AjustaRM_0200A()
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Tipo da Conta Trf ] TypeIn "Changeto X"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Ctacor\\Plcontas}
Moveto [Codigo Plano_Conta] example "plc"
Moveto [Tipo_Custo        ] example "tc"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo Plano_Conta] example "plc"
Moveto [Tipo da Conta Trf ] TypeIn "Changeto _tc"
Do_It!
ClearAll
EndProc  ; (Seleciona)


;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc PrincipalRM_0200A()

Tabela=Cria_Temp(PrivDir())

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  For ii From 1 to 2
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Switch
      Case ii=1: SelecionaRM_0200A()
      Case ii=2: SelecionaRM_0200A2()
    EndSwitch
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndFor
EndWhile

If IsEmpty(Tabela)
   Then 
        MENSAGEM("No existem registros a processar")
   else
        ProcessaRM_0200A()
        ProcessaRM_0200A2()
        
        If VSDGCODMODELO="01" Then AjustaRM_0200A() 
                                   CopyReport "\\Base\\Sistemas\\Ctacor\\RM_0120" "5" Tabela "R"   EndIf
        If VSDGCODMODELO="02" Then CopyReport "\\Base\\Sistemas\\Ctacor\\RM_0120" "6" Tabela "R"   EndIf
        If VSDGCODMODELO="03" Then CopyReport "\\Base\\Sistemas\\Ctacor\\RM_0120" "4" Tabela "R"   EndIf
        If VSDGCODMODELO="04" Then CopyReport "\\Base\\Sistemas\\Ctacor\\RM_0120" "8" Tabela "R"   EndIf
        
        IMPRIREL(Tabela,"R") 
EndIf

Delete Tabela

EndProc

;-- Chamada principal ----------------------------------------------------------
PrincipalRM_0200A()

Release Vars Tabela
Release Procs PrincipalRM_0200A, ProcessaRM_0200A, ProcessaRM_0200A2,
              ProcessaRM_0200A, ProcessaRM_0200A2, AjustaRM_0200A
