;** Rm_0260B ******************************************************************
;*  Relatorio Sintetico/ Plano de Contas - DRE                                *
;******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 17/09/2014 por Kamila Gomes            
;Ultima Alteracao: 07/11/2014 por Kamila Gomes    
;Motivo Alteracao: Ajuste Ask [Sistema Gerador] diferente de CP e CR 
;Ultima Alteracao: 27/11/2014 por Kamila Gomes    
;Motivo Alteracao: Ajuste Para subtrair baixas <> Normal   
;Ultima Alteracao: 18/12/2014 por Kamila Gomes    
;Motivo Alteracao: Ajuste Proc Ajusta_Dados(s) selecionar origem  
;Ultima Alteracao: 20/01/2015 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes de procedimento e erros                
;Ultima Alteracao: 11/07/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes rateio contas a pagar
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 19/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes titulos a receber - cancelado/devolucao
;Ultima Alteracao: 03/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes a pagar/a receber - cancelado/devolucao
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 19/06/2017 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ plano de conta apenas ativos                   
;Ultima Alteracao: 25/07/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo de Conta                
;Ultima Alteracao: 19/01/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo de Operacao 03, 12   
;Ultima Alteracao: 26/04/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao novo processo concetrador RM_0260, RM_0250

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaRM_0260B()
ClearAll

If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont")
  Then {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter Check
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Tipo de Operacao      ] TypeIn "05 or 06 or 07 or 13 or 14 or 03 or 12"
       Moveto [Tipo Movimento        ] TypeIn "~VSDGOPERACAO.."
       If VSDGOPDTEMISCOMP="1"
          Then 
               ;Operacao
               Moveto [Data            ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Else 
               ;Competencia
               Moveto [Data Competencia] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
               Moveto [Sistema Gerador ] TypeIn "Not CP, Not CR"  
       EndIf 
       Moveto [Cheque Pre-Datado     ] TypeIn "Not S"
       Moveto [Codigo Plano_Conta    ] TypeIn PLCONTAS
       Do_It!
       ClearAll
       
       If VSDGOPDTEMISCOMP="2" And Not IsEmpty("Answer")
          Then {Ask}{Answer} TypeIn "Fast"
               Moveto [Data Competencia] TypeIn "_dtc"
               Moveto [Data            ] TypeIn "changeto _dtc"
               Do_It!
               ClearAll
       EndIf
       
       Add "Answer" Tabela
       ClearAll
EndIf
EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaRM_0260B2()
ClearAll

If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont")
  Then {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter Check
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Tipo de Operacao      ] TypeIn "05"
       Moveto [Cheque Pre-Datado     ] TypeIn "S"
       Moveto [Codigo Plano_Conta    ] TypeIn PLCONTAS
       Moveto [Tipo Movimento        ] TypeIn "~VSDGOPERACAO.."
       If VSDGOPDTEMISCOMP="1"
          Then 
               ;Operacao
               Moveto [Data Cheque Pre-Datado] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Else 
               ;Competencia
               Moveto [Data Competencia] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
               Moveto [Sistema Gerador ] TypeIn "Not CP, Not CR"  
       EndIf 
       Do_It!
       ClearAll
       
       If VSDGOPDTEMISCOMP="1" And Not IsEmpty("Answer")
          Then {Ask}{Answer} TypeIn "Fast"
               Moveto [Data Cheque Pre-Datado] TypeIn "_dtchp"
               Moveto [Data                  ] TypeIn "changeto _dtchp"
               Do_It!
               ClearAll
       EndIf
       
       If VSDGOPDTEMISCOMP="2" And Not IsEmpty("Answer")
          Then {Ask}{Answer} TypeIn "Fast"
               Moveto [Data Competencia] TypeIn "_dtc"
               Moveto [Data            ] TypeIn "changeto _dtc"
               Do_It!
               ClearAll
       EndIf

       Add "Answer" Tabela
       ClearAll
EndIf
EndProc     

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaRM_0260B3()
ClearAll

If VSDGOPDTEMISCOMP="1"
   Then Return
EndIf   

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then 
      {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic" Enter Check 
       Moveto [Numero do Lancamento  ] TypeIn "_nlanc!"
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Data de Emissao       ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       Moveto [Codigo Plano_Conta    ] TypeIn PLCONTAS
       {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter 
       Moveto [Numero do Lancamento  ] TypeIn "_nlanc"
       moveto [Tipo da Baixa         ] TypeIn "CANCELADO or DEVOLUCAO"
       Moveto [Valor do Recebimento  ] TypeIn "Calc Sum as ValorBaixa"
       Moveto [Valor do Juros        ] TypeIn "Calc Sum as ValorJuros"
       Moveto [Valor do Desconto     ] TypeIn "Calc Sum as ValorDesconto"
       Do_It!
       ClearAll

       Edit "Answer"
       Scan
         [Valor do Documento]=[Valor do Documento]-(([ValorBaixa]+[ValorDesconto])-[ValorJuros])
       EndScan
       Do_It!
       ClearAll
  
       Ajusta_DadosRM_0260B(1)
EndIf

EndProc     

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaRM_0260B4()
ClearAll

If VSDGOPDTEMISCOMP="1"
   Then Return
EndIf   

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Numero do Lancamento  ] TypeIn "_nlanc!"
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Data Competencia      ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM" 
       Moveto [Codigo Plano_Conta    ] TypeIn PLCONTAS
       {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa" Enter 
       Moveto [Numero do Lancamento  ] TypeIn "_nlanc"
       moveto [Tipo da Baixa         ] TypeIn "CANCELADO or DEVOLUCAO"
       Moveto [Valor do Pagamento    ] TypeIn "Calc Sum as ValorBaixa"
       Moveto [Valor do Juros        ] TypeIn "Calc Sum as ValorJuros"
       Moveto [Valor do Desconto     ] TypeIn "Calc Sum as ValorDesconto"
       Do_It!
       ClearAll
       
       Edit "Answer"
       Scan
         [Valor do Documento]=[Valor do Documento]-(([ValorBaixa]+[ValorDesconto])-[ValorJuros])
       EndScan
       Do_It!
       ClearAll

       {Ask} {Answer} Check
       Moveto [Numero do Lancamento  ] TypeIn "_nlanc!"
       {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitRat" Enter  Check
       Moveto [Numero do Lancamento  ] TypeIn "_nlanc"
       Do_It!
       ClearAll
       
       Ajusta_DadosRM_0260B(2)
EndIf

EndProc     

;*******************************************************************************
;* Rotina p/ Ajustar dados na tabela temp                                      *
;*******************************************************************************
Proc Ajusta_DadosRM_0260B(s)
private s

ClearAll

If IsEmpty("Answer")
   Then Return
EndIf    

Switch
  Case s=1 :  ;Duplic
    {Ask} {Answer} 
    Moveto [Numero do Lancamento   ] Example "nLanc"
    Moveto [Codigo da Empresa      ] Example "cEmp"
    Moveto [Nome Fantasia Empresa  ] Example "nEmp"
    Moveto [Codigo do Documento    ] Example "cDoc"
    Moveto [Tipo do Documento      ] Example "tDoc"
    Moveto [Serie do Documento     ] Example "sDoc"
    Moveto [Numero do Documento    ] Example "nDoc"
    Moveto [Tipo do Lancamento     ] Example "tLanc"
    Moveto [Descricao do Lancamento] Example "dLanc"
    Moveto [Tipo                   ] Example "tipo"
    Moveto [Codigo do Destinatario ] Example "cDest"
    Moveto [Nome Fantasia EmitDest ] Example "ndest"
    Moveto [Razao Social           ] Example "rsoc"
    Moveto [Data de Emissao        ] Example "data"
    Moveto [Valor do Documento     ] Example "vrDoc"
    Moveto [Codigo da Conta        ] Example "cCont"
    Moveto [Descricao da Conta     ] Example "dCont"
    Moveto [Codigo Plano_Conta     ] Example "plCont"
    Moveto [Descricao Plano_Conta  ] Example "dPlCt"
    Moveto [Codigo_Usuario         ] Example "usu"
    Moveto [Data_Inclusao          ] Example "dtInc"
    Moveto [Hora_Inclusao          ] Example "hInc"
    Moveto [Numero_Controle_Dia    ] Example "nCtDia"

  Case s=2 :  ;Titulos
    Edit "Answer"
    Scan
      if not isblank([Codigo Plano_Conta-1]) and [Valor]>0
         then [Codigo Plano_Conta     ]=[Codigo Plano_Conta-1    ]
              [Descricao Plano_Conta  ]=[Descricao Plano_Conta-1 ]
              [Valor do Documento     ]=[Valor                   ]
      endif   
    EndScan
    Do_It!
    ClearAll
  
    {Ask} {Answer} 
    Moveto [Numero do Lancamento    ] Example "nLanc"
    Moveto [Codigo da Empresa       ] Example "cEmp" 
    Moveto [Nome Fantasia Empresa   ] Example "nEmp" 
    Moveto [Codigo do Documento     ] Example "cDoc" 
    Moveto [Tipo do Documento       ] Example "tDoc" 
    Moveto [Serie do Documento      ] Example "sDoc" 
    Moveto [Numero do Documento     ] Example "nDoc" 
    Moveto [Tipo do Lancamento      ] Example "tLanc"
    Moveto [Descricao do Lancamento ] Example "dLanc"
    Moveto [Tipo                    ] Example "tipo"  
    Moveto [Codigo do Emitente      ] Example "cDest" 
    Moveto [Nome Fantasia EmitDest  ] Example "ndest" 
    Moveto [Razao Social            ] Example "rsoc"
    Moveto [Data Competencia        ] Example "data"  
    Moveto [Valor do Documento      ] Example "vrDoc" 
    Moveto [Codigo da Conta         ] Example "cCont" 
    Moveto [Descricao da Conta      ] Example "dCont" 
    Moveto [Codigo Plano_Conta      ] Example "plCont"
    Moveto [Descricao Plano_Conta   ] Example "dPlCt" 
    Moveto [Codigo_Usuario          ] Example "usu"   
    Moveto [Data_Inclusao           ] Example "dtInc" 
    Moveto [Hora_Inclusao           ] Example "hInc"  
    Moveto [Numero_Controle_Dia     ] Example "nCtDia"
EndSwitch

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"               
Moveto [Numero do Lancamento    ] Example "nLanc"      
Moveto [Codigo da Conta         ] Example "cCont"      
Moveto [Descricao da Conta      ] Example "dCont"      
Moveto [Codigo da Empresa       ] Example "cEmp"       
Moveto [Nome Fantasia Empresa   ] Example "nEmp"       
Moveto [Data                    ] Example "data"       
Moveto [Valor                   ] Example "vrDoc"      
Moveto [Codigo do Documento     ] Example "cDoc"       
Moveto [Tipo do Documento       ] Example "tDoc"       
Moveto [Serie do Documento      ] Example "sDoc"       
Moveto [Numero do Documento     ] Example "nDoc"       
Moveto [Tipo                    ] Example "tipo"       
Moveto [Codigo do EmitDest      ] Example "cDest"      
Moveto [Nome Fantasia EmitDest  ] Example "ndest"      
Moveto [Razao Social            ] Example "rsoc"
Moveto [Tipo do Lancamento      ] Example "tLanc"      
Moveto [Descricao do Lancamento ] Example "dLanc"      
Moveto [Codigo Plano_Conta      ] Example "plCont"     
Moveto [Descricao Plano_Conta   ] Example "dPlCt"      
Moveto [Codigo_Usuario          ] Example "usu"        
Moveto [Data_Inclusao           ] Example "dtInc"      
Moveto [Hora_Inclusao           ] Example "hInc"       
Moveto [Numero_Controle_Dia     ] Example "nCtDia" 
Moveto [Descricao do Historico  ] TypeIn "\"* \"+_tDoc+\"/\"+_nDoc"
Switch
  Case s=1 :  ;Duplic
    Moveto [Sistema Gerador         ] TypeIn "CR"      
    Moveto [Tipo Movimento          ] TypeIn "E"      
  Case s=2 :  ;Titulos
    Moveto [Sistema Gerador         ] TypeIn "CP"      
    Moveto [Tipo Movimento          ] TypeIn "S"      
EndSwitch
Do_It!                                                 
ClearAll                                               

EndProc 

;*******************************************************************************
;* Rotina p/ Processar Registros                                               *
;*******************************************************************************
Proc ProcessaRM_0260B()
ClearAll

Adiciona_campo(Tabela,"Tipo de Conta(A1)")

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo CCusto   ] TypeIn "Changeto Blank"
Moveto [Descricao CCusto] TypeIn "Changeto Blank"
Do_It!
ClearAll

{Ask} {PlContas}
Moveto [Codigo Plano_Conta    ] Example "cpl"
Moveto [Descricao Plano_Conta ] Example "dpl"
Moveto [Tipo de Conta         ] Example "tpc"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo Plano_Conta    ] Example "cpl"
Moveto [Descricao Plano_Conta ] TypeIn "Changeto " Example "dpl"
Moveto [Tipo de Conta         ] typein "changeto " Example "tpc"
Do_It!
ClearAll

 If VSDGPLCONTAS=""
    Then 
         {Ask} {PlContas}
         Moveto [Codigo Plano_Conta    ] Example "cpl"
         Moveto [Descricao Plano_Conta ] Example "dpl"
         Moveto [Tipo de Conta         ] Example "tpc"
         Moveto [Inativo               ] TypeIn "Not S"
         {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
         Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2"
         Moveto [Codigo Plano_Conta    ] Example "cpl"
         Moveto [Descricao Plano_Conta ] Example "dpl"
         Moveto [Tipo de Conta         ] Example "tpc"
         Do_It!
         ClearAll
        
         {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
         Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2"
         Moveto [Codigo Plano_Conta    ] TypeIn "00"
         Moveto [Descricao Plano_Conta ] TypeIn "LANCAMENTOS NŽO INFORMADO PLANO DE CONTA ="
         Do_It!
         ClearAll
EndIf

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo Plano_Conta     ] TypeIn "Blank, Changeto 00"
Moveto [Descricao Plano_Conta  ] TypeIn "Changeto \"LANCAMENTOS NŽO INFORMADO PLANO DE CONTA =\""
Do_It!
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Empresas}
Moveto [Codigo da Empresa     ] Example "cde"
Moveto [Nome Fantasia Empresa ] Example "nfe"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa     ] Example "cde"
Moveto [Nome Fantasia Empresa ] TypeIn "changeto _nfe"
Do_It!
ClearAll

ProcessaRM_0260B2()

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa     ] Check
Moveto [Nome Fantasia Empresa ] Check
Moveto [Codigo Plano_Conta    ] Check
Moveto [Descricao Plano_Conta ] Check
Moveto [Tipo de Conta         ] Check
Moveto [Codigo CCusto         ] Check
Moveto [Descricao CCusto      ] Check
Moveto [Valor                 ] TypeIn "Calc Sum As Valor"
Do_It!
ClearAll

{Modify} {Restructure} {Answer}
Down Down Ins Right  "Codigo Plano_Conta" Enter
Down Left Left Ins Right  "Descricao Plano_Conta" Enter
Up Backspace Backspace  "21" Down Do_It! ClearImage

Sort "Answer" On "Codigo da Empresa", "Codigo Plano_Conta"

g1=0     c1=""  t1=0
g2=0     c2=""  t2=0
g3=0     c3=""
g4=0     c4=""

CoEdit "Answer"
SetHighLight Current Record 23 Field 31
CtrlEnd Left Left
c1=SubStr([Codigo Plano_Conta],01,01)
c2=SubStr([Codigo Plano_Conta],01,03)
c3=SubStr([Codigo Plano_Conta],01,06)
c4=SubStr([Codigo Plano_Conta],01,09)
While True

  nr=recno()
  If SubStr([Codigo Plano_Conta],01,01)<>c1 Then TotalizaRM_0260B(1) EndIf
  If SubStr([Codigo Plano_Conta],01,03)<>c2 Then TotalizaRM_0260B(2) EndIf
  If SubStr([Codigo Plano_Conta],01,06)<>c3 Then TotalizaRM_0260B(3) EndIf
  If SubStr([Codigo Plano_Conta],01,09)<>c4 Then TotalizaRM_0260B(4) EndIf

  g1=g1+[Valor]
  g2=g2+[Valor]
  g3=g3+[Valor]
  g4=g4+[Valor]

  Switch
    Case SubStr([Codigo Plano_Conta],01,01)="1": t1=t1+[Valor]
    Case SubStr([Codigo Plano_Conta],01,01)="2": t2=t2+[Valor]
  EndSwitch

  Down
  If RecordStatus("New")
     Then TotalizaRM_0260B(1)

          If VSDGPLCONTAS=""
             Then 
                  End
                  Down
                  If VSDGEMPRESA="0000"
                     Then [Codigo da Empresa     ]="0000"
                     Else [Codigo da Empresa     ]=VSDGEMPRESA2
                  Endif
                  [Nome Fantasia Empresa ]=VSDGNOMEMP
                  [Codigo Plano_Conta    ]="9"
                  [Descricao Plano_Conta ]="[1.. ENTRADAS] - [2.. SAIDAS]..."
                  [Valor                 ]=t1-t2
                  [Tipo de Conta         ]="S"
             Else 
                  End
                  Down
                  If VSDGEMPRESA="0000"
                     Then [Codigo da Empresa     ]="0000"
                     Else [Codigo da Empresa     ]=VSDGEMPRESA2
                  Endif
                  [Nome Fantasia Empresa ]=VSDGNOMEMP
                  [Codigo Plano_Conta    ]="9"
                  [Descricao Plano_Conta ]="Total..."
                  [Valor                 ]=t1+t2
                  [Tipo de Conta         ]="S"
          EndIf
          
          End
          Down
          If VSDGEMPRESA="0000"
             Then [Codigo da Empresa     ]="0000"
             Else [Codigo da Empresa     ]=VSDGEMPRESA2
          Endif
          [Nome Fantasia Empresa ]=VSDGNOMEMP
          [Codigo Plano_Conta    ]="0"
          [Descricao Plano_Conta ]="* RELATORIO POR "+VSDGNOMOPDTEMISCOMP+" *"
          QuitLoop
  EndIf
EndWhile
Do_It!
ClearAll

{Ask} {Answer} TypeIn "Fast"
Moveto [Valor                  ] TypeIn "0, Changeto Blank"
Do_It!
ClearAll

EndProc     

;*******************************************************************************
;* Totaliza                                                                    *
;*******************************************************************************
Proc TotalizaRM_0260B(Tipo)
Moveto [Codigo Plano_Conta]
For i From Tipo To 4
  Switch
    Case i=1:
         If Not IsBlank(SubStr(c1,01,01))
            Then Locate c1
                 If RetVal
                    Then [Valor]=g1
                 EndIf
         EndIf
         g1=0
    Case i=2:
         If Not IsBlank(SubStr(c2,03,01))
            Then Locate c2
                 If RetVal
                    Then [Valor]=g2
                 EndIf
         EndIf
         g2=0
    Case i=3:
         If Not IsBlank(SubStr(c3,05,02))
            Then Locate c3
                 If RetVal
                    Then [Valor]=g3
                 EndIf
         EndIf
         g3=0
    Case i=4:
         If Not IsBlank(SubStr(c4,08,02))
            Then Locate c4
                 If RetVal
                    Then [Valor]=g4
                 EndIf
         EndIf
         g4=0
  EndSwitch
EndFor
Moveto Record nr
c1=SubStr([Codigo Plano_Conta],01,01)
c2=SubStr([Codigo Plano_Conta],01,03)
c3=SubStr([Codigo Plano_Conta],01,06)
c4=SubStr([Codigo Plano_Conta],01,09)
EndProc

;*******************************************************************************
;* ROTINA Ajusta Dados Empresa                                                 *
;*******************************************************************************
Proc ProcessaRM_0260B2()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc PrincipalRM_0260B()

;-- Criando tabela espelho estrutura MovCont ---------------------------------
{Ask} TypeIn "\\Base\\Sistemas\\Ctacor\\Movcont" Enter Check
Do_It!
ClearAll
Empty "Answer"

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela
;-----------------------------------------------------------------------------

SetDir "\\Sistemas\\CtaCor"
Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  SelecionaRM_0260B()
  SelecionaRM_0260B2()
EndWhile

If (VSDGOPERACAO = "E" Or VSDGOPERACAO = "")
   then
        SetDir "\\Sistemas\\CtaRec"
        Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
        While Novo_Dir_Trab()
          SelecionaRM_0260B3()
        EndWhile
endif

If (VSDGOPERACAO = "S" Or VSDGOPERACAO = "")
   then 
        SetDir "\\Sistemas\\CtaPag"
        Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
        While Novo_Dir_Trab()
          SelecionaRM_0260B4()
        EndWhile
endif

SetDir "\\Sistemas\\CtaCor"

If Not IsEmpty(Tabela)
   Then
        ProcessaRM_0260B()
        
        CopyReport "\\Base\\Sistemas\\Ctacor\\RM_0210" "R" "Answer" "R"
        IMPRIREL("Answer","R")
        
   Else MENSAGEM("N„o existem registros a processar")
EndIf

If IsTable(Tabela)   Then Delete Tabela   EndIf
If IsTable("Answer") Then Delete "Answer" EndIf


EndProc

;-- Chamada principal ----------------------------------------------------------
PrincipalRM_0260B()

Release Vars Tabela
Release Procs PrincipalRM_0260B, SelecionaRM_0260B, SelecionaRM_0260B2, SelecionaRM_0260B3, SelecionaRM_0260B4,
              Ajusta_DadosRM_0260B, TotalizaRM_0260B, ProcessaRM_0260B, ProcessaRM_0260B2
