;** Rm_0040  *******************************************************************
;*  Fluxo de Caixa Analitico por Empresa                                       *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 01/03/2005 por Davi Pereira Carrano
;Motivo Alteracao: Corre‡Æo das Ask para liberar tabelas quando se usa Fast Insert
;Ultima Alteracao: 07/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cheques em Cobranca
;Ultima Alteracao: 05/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 21/11/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cheque p/ deposito e otimiza‡äes                
;Ultima Alteracao: 15/04/2013 por Karina Andrade
;Motivo Alteracao: Ajustes desprezar SALDO
;Ultima Alteracao: 04/09/2014 por Andrey Fillipe
;Motivo Alteracao: Adicionado filtro Op‡ao de data
;Ultima Alteracao: 20/04/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado opcao de escolher mais de uma empresa, quando for empresa "0000"
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()               
;Ultima Alteracao: 22/06/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÆo utilizar data de competencia no fluxo de caixa nÆo existe esta situa‡Æo, esta com interpreta‡Æo errada
;Ultima Alteracao: 14/09/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado vari vel de controle PARAM_SCRIPT -> 'Rm_FlxCx"
;Ultima Alteracao: 23/12/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes variavel opcao de saldo

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog_Emp(Disparo,Campo,Evento,Elemento)

Temp=True
MSG_CAMPO=""
                                    
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
          Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
          SYS_TECLA_ACIONADA=Evento["KeyCode"]
          Seta_Tecla_Acionada()
          CancelDialog
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_Registro"      : Campo="NO"
            Case Campo="YES" Or Campo="NO": Campo="TG_Registro"
          EndSwitch
     Case Evento["KeyCode"] = 32 And Campo="TG_Registro":
          Temp=False
          If SubStr(Array_Empresa[ControlValue("TG_Registro")],41,1)=" "
             Then Array_Empresa[ControlValue("TG_Registro")]=SubStr(Array_Empresa[ControlValue("TG_Registro")],1,40)+"X"
             Else Array_Empresa[ControlValue("TG_Registro")]=SubStr(Array_Empresa[ControlValue("TG_Registro")],1,40)+" "
          EndIf 
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_Registro": Campo="YES"
                  EndSwitch
          EndIf                     
   EndSwitch 
EndIf

Switch  
  Case Campo="TG_Registro":
       MSG_CAMPO="Selecione o arquivo"
       TECLA="Barra de Espa‡o=Marca/Desmarca"
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc Seleciona_Empresa()
Private wc,wcc,Empresa

If Not IsAssigned(Array_Empresa)
   Then DynArray Array_Empresa[]

        {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa    ] Check 
        Moveto [Nome Fantasia Empresa] Check
        Do_It!
        ClearAll
        
        CoEdit "Answer"
        Moveto [Codigo da Empresa]
        wc=1
        Scan
          Empresa           = [Codigo da Empresa]+" "+[Nome Fantasia Empresa]
          Array_Empresa[wc] = Completa(SubStr(Empresa,1,Len(Empresa)),40," ")+"X"
          wc=wc+1
        EndScan
        Do_It!
        ClearAll
EndIf
VOLTA=True

While True

  ShowDialog "Empresas" Proc "SD_Dialog_Emp"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",32,
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 02,12   Height 14 Width 56

  @ 00,02 ?? "Empresas"
  PickDynArray @1,01 Height 08 width 53
   Columns 1
    Array_Empresa
     Tag "TG_Registro"
      To ArrayElement

    Pushbutton @ 10,17 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,29 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  
  If Not RetVal Then Return False EndIf
  
  VOLTA=False
  For wc From 1 To DynArraySize(Array_Empresa)
      If SubStr(Array_Empresa[wc],41,1) = "X"
         Then QuitLoop
         Else If wc = DynArraySize(Array_Empresa) 
                 Then Mensagem("Nenhuma empresa selecionada !") 
                      VOLTA=True
              EndIf
      EndIf
  EndFor
  If VOLTA Then Loop EndIf
  
  wcc=0
  DynArray Array_Cod_Empresa[]
  For wc From 1 To DynArraySize(Array_Empresa)
      If SubStr(Array_Empresa[wc],41,1) = "X"
         Then wcc=wcc+1
              Array_Cod_Empresa[wcc] = LTrim(SubStr(Array_Empresa[wc],1,4))
              TipoFiltroEmp = "1" 
      EndIf
  EndFor 
  QuitLoop
EndWhile

Return True

EndProc
;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPCREDITO"     : Campo="TG_DTFIM"
            Case Campo="TG_OPSALDO"       : Campo="TG_OPCREDITO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE" :    
                         If IsBlank(VSDGEMPRESA)
                            Then VSDGNOMEMP=""
                            Else If VSDGEMPRESA="0000"
                                    Then If Seleciona_Empresa()
                                            Then Campo="TG_DTINI"
                                         EndIf
                                         Temp=False   
                                    Else Campo="TG_DTINI"
                                 EndIf 
                         EndIf
                    Case Campo="TG_DTINI" :
                         If Not IsBlank(VSDGDTINI)
                            Then Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM"     : Campo="TG_OPCREDITO"
                    Case Campo="TG_OPCREDITO" : Campo="TG_OPSALDO" 
                    Case Campo="TG_OPSALDO"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_EMPRESATE":
     MSG_CAMPO="Informe uma Empresa"
  Case Campo="TG_DTINI":
     MSG_CAMPO="Informe a Data Inicial"
  Case Campo="TG_OPCREDITO" or Campo="TG_OPSALDO":
     MensagemCheckBoxes()
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGCONTA     = ""
VSDGDTINI     = Today()
VSDGDTFIM     = Today()+30

PARAM_SCRIPT = "RM_0040"

Array TG_OPCREDITO[1]
TG_OPCREDITO[1]="Incluir Crˆdito Cta Corrente"

Array CheckTG_OPCREDITO[ArraySize(TG_OPCREDITO)]
CheckTG_OPCREDITO[1]=True 

Array TG_OPSALDO[2]
TG_OPSALDO[1]="Desprezar Saldo Inicial"
TG_OPSALDO[2]=""

Array CheckTG_OPSALDO[ArraySize(TG_OPSALDO)]
CheckTG_OPSALDO[1]=False
CheckTG_OPSALDO[2]=False


Array CheckTG_OPCARTAO[2]
CheckTG_OPCARTAO[1]=False
CheckTG_OPCARTAO[2]=False

Array CheckTG_OPCHEQ[1]
CheckTG_OPCHEQ[1]=True 

While True
  ShowDialog "Fluxo de Caixa Anal¡tico/Empresa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 09 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    CheckBoxes @ 01,35 Height 1 Width 33 Tag "TG_OPCREDITO"
    TG_OPCREDITO[1] to CheckTG_OPCREDITO[1]
    
    CheckBoxes @ 02,35 Height 1 Width 33 Tag "TG_OPSALDO" 
    TG_OPSALDO[1] to CheckTG_OPSALDO[1]

    Pushbutton @ 05,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsAssigned(VOLTA) And VOLTA 
     Then Mensagem("Nenhuma empresa selecionada !") 
          Loop
  EndIf        
                      
  If VSDGEMPRESA=""
     Then Mensagem("Empresa Invalida !")
          Loop
  EndIf

  If VSDGDTINI=BlankDate()
     Then Mensagem("Data Inicial Invalida !")
          Loop
  EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf        
  
  ANOREF=StrVal(Year(VSDGDTINI))
  MESREF=StrVal(Month(VSDGDTINI))
  ALINHM(MESREF, 2)
  MESREF=NVR
  VSDGDTREF=DateVal("01."+MESREF+"."+ANOREF)

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  TipoFluxo ="Analitico"
  TipoFiltro="Empresa"
  Play "Rm_FlxCx"

  IMPRIREL(Tabela,"8")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
