;** Encerra ********************************************************************
;*  Programa p/ Fechamento de Meses Selecionados                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 07/10/1997 por Anivel Augusto Rodrigues
;Ultima Alteracao: 10/11/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mensagem advertencia
;Ultima Alteracao: 14/08/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Run
;Ultima Alteracao: 13/04/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tamanho Tabela Grande
;Ultima Alteracao: 16/11/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes notas referenciadas Inclusao FaturaR/NotaR                             
;Ultima Alteracao: 07/07/2011 por Karina Andrade
;Motivo Alteracao: Ajustes diversos
;Ultima Alteracao: 01/08/2011 por Bruno Carvalho
;Motivo Alteracao: InclusÆo das tabelas NotaIDD e NotaIAD   
;Ultima Alteracao: 03/08/2011 por Karina Andrade
;Motivo Alteracao: InclusÆo das tabelas NotaCTR
;Ultima Alteracao: 25/10/2011 por Bruno Carvalho
;Motivo Alteracao: Add Tabela "NotaOCP"
;Ultima Alteracao: 30/01/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes % da barra executada                             
;Ultima Alteracao: 18/01/2013 por Bruno Carvalho
;Motivo Alteracao: Adicionado ¡ndice na tabela "NFCTemp" p/ maior eficiˆncia nos processos
;Ultima Alteracao: 03/03/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Layout                   
;Ultima Alteracao: 05/04/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes mensagem                 
;Ultima Alteracao: 03/07/2014 por Bruno Carvalho
;Motivo Alteracao: Add rotina quando existir fechamento de ficha de estoque 
;Ultima Alteracao: 05/09/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado rotina de exclusÆo de tabela "xc_Reg_Tabela()"                
;Ultima Alteracao: 06/09/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes "NotaIG"
;Ultima Alteracao: 06/09/2013 por Bruno Carvalho
;Motivo Alteracao: Sleep p/ quando realizar fechamento das notas
;Ultima Alteracao: 18/11/2015 por Kamila Gomes
;Motivo Alteracao: Adicionada tabela NotaICom
;Ultima Alteracao: 20/04/2016 por Kamila Gomes
;Motivo Alteracao: Alterada Faticom e Notaicom para FaturICM e  NotaICM
;Ultima Alteracao: 04/08/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes NotaICM                  
;Ultima Alteracao: 14/11/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao tabela AcCarrgF                 
;Ultima Alteracao: 04/05/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao tabela Contfrtc,Contfrtn                
;Ultima Alteracao: 14/07/2017 por Bruno Carvalho
;Motivo Alteracao: Removido "NotaCF" e inclu¡do "NotaCC" 
;Ultima Alteracao: 14/07/2017 por Bruno Carvalho
;Motivo Alteracao: Removido "Notactr" e "Notaocp" 
;Ultima Alteracao: 03/08/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes familia Nota??
;Ultima Alteracao: 13/09/2017 por Bruno Carvalho
;Motivo Alteracao: Inclusao tabela EXPEDC, EXPEDI, EXPEDIE, EXPEDIQ, EXPEDTG , EXPEDOFC, EXPEDOFI
;Ultima Alteracao: 07/02/2018 por Bruno Carvalho
;Motivo Alteracao: Ajustes na proc NotasFiscais() p/ verificar a se a tabela existe antes de realizar o processo             
;Ultima Alteracao: 15/05/2018 por Bruno Carvalho
;Motivo Alteracao: Adicionado PARAM_FECHA_VENDAS (p/ Estoque) e movido o processo do fechamento p/ uma proc Encerra_Vendas() 
 
;*******************************************************************************
; NotaC/NotaI/NotaV/NotaIDV/NotaIC/NotaCC/NotaR/***                            *
;*******************************************************************************
Proc NOTASFISCAIS()
Private Arquivo,wi
ClearAll

MSG_AGUARDE="Aguarde, fechando notas emitidas "+ANO_MES+" "

Array Arquivo[10]
Arquivo[1] ="Notac"
Arquivo[2] ="Notacc"
Arquivo[3] ="Notai"
Arquivo[4] ="Notaiad"
Arquivo[5] ="Notaic"
Arquivo[6] ="Notaicm"
Arquivo[7] ="Notaidd"
Arquivo[8] ="Notaidv"
Arquivo[9] ="Notar"
Arquivo[10]="Notav"

for wi from 1 to 10

  AGUARDE(MSG_AGUARDE+Barra(10,wi-1))
  
  switch
    case wi=1 :
      {Ask} {NotaC}
      Moveto [Codigo da Empresa   ] Check TypeIn "~VSDGEMPRESA.."
      Moveto [Numero do Documento ] Check
      Moveto [Serie do Documento  ] Check
      Moveto [Data de Emissao     ]       TypeIn "...~MESANO"
      Moveto [Entrega             ]       TypeIn "Not N"
      Do_It!
      ClearAll
      
      If IsEmpTy("Answer")
         Then Fastmsg("Mˆs sem movimenta‡„o p/ notas fiscais !")
              Return
      EndIf

      TabelaRNotas=Adiciona_Indice_Temp("Codigo da Empresa,Numero do Documento,Serie do Documento") 
      ClearAll
    
    otherwise :
      If Not IsTable(Arquivo[wi])
         Then Loop
      EndIf
      {Ask} typeIn TabelaRNotas Enter
      Moveto [Codigo da Empresa   ] Example "EMPRE"
      Moveto [Numero do Documento ] Example "DOCTO"
      Moveto [Serie do Documento  ] Example "SERIE"
      {Ask} TypeIn Arquivo[wi] Enter Check
      Moveto [Codigo da Empresa   ] Example "EMPRE"
      Moveto [Numero do Documento ] Example "DOCTO"
      Moveto [Serie do Documento  ] Example "SERIE"
      Do_It!
      ClearAll
      Crea_Add_Sub_Tabela("Answer",Arquivo[wi])
    
  endswitch
        
endfor

Aguarde(MSG_AGUARDE+Barra(10,10))
{Ask} typeIn TabelaRNotas Enter
Moveto [Codigo da Empresa   ] Example "EMPRE"
Moveto [Numero do Documento ] Example "DOCTO"
Moveto [Serie do Documento  ] Example "SERIE"
{Ask} {NotaC} Check
Moveto [Codigo da Empresa   ] Example "EMPRE"
Moveto [Numero do Documento ] Example "DOCTO"
Moveto [Serie do Documento  ] Example "SERIE"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","NotaC")

Delete TabelaRNotas
EndProc

;*******************************************************************************
; DupC/DupI/DupNF                                                              *
;*******************************************************************************
Proc DUPLICATAS()
ClearAll
MSG_AGUARDE="Aguarde, fechando duplicatas geradas "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(4,1))
{Ask} {DupC} Check
Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
Moveto [Data de Emissao  ] TypeIn "...~MESANO"
Do_It!
ClearAll
If IsEmpTy("Answer")
   Then Fastmsg("Mˆs sem movimenta‡„o p/ duplicatas !")
        Return
EndIf

Rename "Answer" "DupCTemp"
ClearAll

Aguarde(MSG_AGUARDE+Barra(4,2))
{Ask} {DupC}
Moveto [Codigo da Empresa   ] Example "EMPRE" TypeIn ", ~VSDGEMPRESA.."
Moveto [Numero do Documento ] Example "DOCTO"
Moveto [Serie do Documento  ] Example "SERIE"
Moveto [Data de Emissao     ] TypeIn "...~MESANO"
{Ask} {DupI} Check
Moveto [Codigo da Empresa   ] Example "EMPRE"
Moveto [Numero do Documento ] Example "DOCTO"
Moveto [Serie do Documento  ] Example "SERIE"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","DupI")

Aguarde(MSG_AGUARDE+Barra(4,3))
{Ask} {DupC}
Moveto [Codigo da Empresa   ] Example "EMPRE" TypeIn ", ~VSDGEMPRESA.."
Moveto [Numero do Documento ] Example "DOCTO"
Moveto [Serie do Documento  ] Example "SERIE"
Moveto [Data de Emissao     ] TypeIn "...~MESANO"
{Ask} {DupNF} Check
Moveto [Codigo da Empresa   ] Example "EMPRE"
Moveto [Numero do Documento ] Example "DOCTO"
Moveto [Serie do Documento  ] Example "SERIE"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","DupNF")

Aguarde(MSG_AGUARDE+Barra(4,4))
Crea_Add_Sub_Tabela("DupCTemp","DupC")

EndProc

;*******************************************************************************
; ECF_C/ECF_T                                                                  *
;*******************************************************************************
Proc ECFS()
ClearAll
MSG_AGUARDE="Aguarde, fechando mapa resumo ecf "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(4,1))
{Ask} {ECF_C} Check
Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
Moveto [Data             ] TypeIn "...~MESANO"
Do_It!
ClearAll
If IsEmpTy("Answer")
   Then Fastmsg("Mˆs sem movimenta‡„o p/ mapa resumo ecf !")
        Return
EndIf

Rename "Answer" "ECFCTemp"
ClearAll

Aguarde(MSG_AGUARDE+Barra(4,2))
{Ask} {ECF_C}
Moveto [Codigo da Empresa   ] Example "EMPRE" TypeIn ", ~VSDGEMPRESA.."
Moveto [Serie do Documento  ] Example "SERIE"
Moveto [Data                ] Example "DATA" TypeIn ", ...~MESANO"
{Ask} {ECF_T} Check
Moveto [Codigo da Empresa   ] Example "EMPRE"
Moveto [Serie do Documento  ] Example "SERIE"
Moveto [Data                ] Example "DATA"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","ECF_T")

Aguarde(MSG_AGUARDE+Barra(4,3))
{Ask} {ECF_C}
Moveto [Codigo da Empresa   ] Example "EMPRE" TypeIn ", ~VSDGEMPRESA.."
Moveto [Serie do Documento  ] Example "SERIE"
Moveto [Data                ] Example "DATA" TypeIn ", ...~MESANO"
{Ask} {ECF_S} Check
Moveto [Codigo da Empresa   ] Example "EMPRE"
Moveto [Serie do Documento  ] Example "SERIE"
Moveto [Data                ] Example "DATA"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","ECF_S")

Aguarde(MSG_AGUARDE+Barra(4,4))
Crea_Add_Sub_Tabela("ECFCTemp","ECF_C")

EndProc

;*******************************************************************************
; AcCarrgC/AcCarrgI/AcCarrgV                                                   *
;*******************************************************************************
Proc CARREGAMENTOS()
ClearAll
MSG_AGUARDE="Aguarde, fechando carregamentos "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(5,1))
{Ask} {AcCarrgC} Check
;Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
Moveto [Data de Emissao  ] TypeIn "...~MESANO"
Moveto [Situacao         ] TypeIn "ACERTADO"

Do_It!
ClearAll

If IsEmpTy("Answer")
   Then Fastmsg("Mˆs sem movimenta‡„o p/ carregamentos !")
        Return
EndIf

Rename "Answer" "CarTemp"
ClearAll

Aguarde(MSG_AGUARDE+Barra(5,2))
{Ask} {AcCarrgC}
Moveto [Numero_Carregamento ] Example "ncarg"
;Moveto [Codigo da Empresa   ] Example "EMPRE" TypeIn ", ~VSDGEMPRESA.."
Moveto [Data de Emissao     ] TypeIn "...~MESANO"
Moveto [Situacao            ] TypeIn "ACERTADO"
{Ask} {AcCarrgI} Check
Moveto [Numero_Carregamento ] Example "ncarg"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","AcCarrgI")

Aguarde(MSG_AGUARDE+Barra(5,3))
{Ask} {AcCarrgC}
Moveto [Numero_Carregamento ] Example "ncarg"
;Moveto [Codigo da Empresa   ] Example "EMPRE" TypeIn ", ~VSDGEMPRESA.."
Moveto [Data de Emissao     ] TypeIn "...~MESANO"
Moveto [Situacao            ] TypeIn "ACERTADO"
{Ask} {AcCarrgV} Check
Moveto [Numero_Carregamento ] Example "ncarg"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","AcCarrgV")

Aguarde(MSG_AGUARDE+Barra(5,4))
{Ask} {AcCarrgC}
Moveto [Numero_Carregamento ] Example "ncarg"
;Moveto [Codigo da Empresa   ] Example "EMPRE" TypeIn ", ~VSDGEMPRESA.."
Moveto [Data de Emissao     ] TypeIn "...~MESANO"
Moveto [Situacao            ] TypeIn "ACERTADO"
{Ask} {AcCarrgF} Check
Moveto [Numero_Carregamento ] Example "ncarg"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","AcCarrgF")

Aguarde(MSG_AGUARDE+Barra(5,5))
Crea_Add_Sub_Tabela("CarTemp","AcCarrgC")

EndProc

;*******************************************************************************
; Contfrtc/ContfrtN                                                            *
;*******************************************************************************
Proc ControleFretes()
ClearAll
MSG_AGUARDE="Aguarde, fechando controle fretes "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(3,1))
{Ask} {Contfrtc} Check
Moveto [Numero do Lancamento  ] Example "lanc"
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
Moveto [Data de Emissao       ] TypeIn "...~MESANO"
Moveto [CT_Numero do Documento] typeIn "Not blank"
Do_It!
ClearAll

If IsEmpTy("Answer")
   Then Fastmsg("Mˆs sem movimenta‡„o p/ controle fretes !")
        Return
EndIf

Rename "Answer" "FretTemp"
ClearAll

Aguarde(MSG_AGUARDE+Barra(2,1))
{Ask} {Contfrtc}
Moveto [Numero do Lancamento  ] Example "LANCTO"
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
Moveto [Data de Emissao       ] TypeIn "...~MESANO"
Moveto [CT_Numero do Documento] typeIn "Not blank"
{Ask} {Contfrtn} Check
Moveto [Numero do Lancamento] Example "LANCTO"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","Contfrtn")

Aguarde(MSG_AGUARDE+Barra(3,1))
Crea_Add_Sub_Tabela("FretTemp","Contfrtc")

EndProc   ; (ControleFretes)

;*******************************************************************************
; EXPEDC/EXPEDI/EXPEDIE/EXPEDIQ/EXPEDTG                                        *
;*******************************************************************************
Proc Expedicao()
ClearAll
MSG_AGUARDE="Aguarde, fechando expedi‡”es "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(6,1))
{Ask} {ExpedC} Check
Moveto [Data_Inclusao    ] TypeIn "...~MESANO"
Moveto [Situacao da OE   ] TypeIn "FATURADO"
Do_It!
ClearAll

If IsEmpTy("Answer")
   Then Fastmsg("Mˆs sem movimenta‡„o p/ expedi‡”es!")
        Return
EndIf

Rename "Answer" "ExpTemp"
ClearAll

Aguarde(MSG_AGUARDE+Barra(6,2))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedI} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","ExpedI")

Aguarde(MSG_AGUARDE+Barra(6,3))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedIE} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","ExpedIE")

Aguarde(MSG_AGUARDE+Barra(6,4))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedIQ} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","ExpedIQ")

Aguarde(MSG_AGUARDE+Barra(6,5))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedTG} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","ExpedTG")

Aguarde(MSG_AGUARDE+Barra(6,6))
Crea_Add_Sub_Tabela("ExpTemp","ExpedC")

EndProc ;Expedicao()

;*******************************************************************************
; EXPEDOFC/EXPEDOFI                                                            *
;*******************************************************************************
Proc Expedicao_OF()
ClearAll
MSG_AGUARDE="Aguarde, fechando expedi‡”es de OF "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(7,1))

{Ask} {ExpedOFC} Check
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
Do_It!
ClearAll

If IsEmpTy("Answer")
   Then Fastmsg("Mˆs sem movimenta‡„o p/ expedi‡”es de OF !")
        Return
EndIf

Rename "Answer" "ExpOfTmp"
ClearAll

Aguarde(MSG_AGUARDE+Barra(7,2))
{Ask} {ExpedOFC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedOFI} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Crea_Add_Sub_Tabela("Answer","ExpedOFI")

Aguarde(MSG_AGUARDE+Barra(7,3))
Crea_Add_Sub_Tabela("ExpOfTmp","ExpedOFC")

EndProc ;Expedicao_OF()

;*******************************************************************************
;* Rotina Create/Add/Subtract                                                  *
;*******************************************************************************
Proc Crea_Add_Sub_Tabela(TABORIG,TABDEST)
Private TABORIG,TABDEST,TABDESTINO

TABDESTINO = DiretorioFechames+TABDEST
If Not IsTable(TABDESTINO)
   Then Create TABDESTINO Like TABDEST
        {Tools} {Copy} {JustFamily} TypeIn TABDEST Enter TypeIn TABDESTINO Enter {Replace}
        Delete "Struct"
EndIf
Add TABORIG TABDESTINO ClearImage
If Search("NOTA",Upper(TABDESTINO)) > 0
   Then Sleep 1000
EndIf   
SaveTables

SubTract TABORIG TABDEST ClearImage
If Search("NOTA",Upper(TABDESTINO)) > 0
   Then Sleep 1000
EndIf
SaveTables

{Modify} {Restructure} TypeIn TABDEST Enter Do_It! ClearImage
Delete TABORIG
SAVETABLES
EndProc

;*******************************************************************************
;* Rotina Bloqueia Tabelas da Pasta                                            *
;*******************************************************************************
Proc BloqueiaTabelas(Pasta)
Private MSG, Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then Lock Pasta+Array_Tabelas[i] FL
          If Not RetVal
             Then MSG="O usu rio "+Upper(ErrorUser())+" esta usando o Sistema !// //"
                  MSG=MSG+Completa("- Contact -lo para liberar o Sistema;",40," ")+"//"
                  MSG=MSG+Completa("- Esta rotina ser  abortado.",40," ")+"// //"
                  MSG=MSG+"Execute esta rotina novamente para que//"
                  MSG=MSG+"a mesma seja concluida corretamente !"
                  Mensagem(MSG)
                  Return False
          EndIf
  EndIf
EndFor

Return True
EndProc

;*******************************************************************************
;* Rotina Subtract APENAS                                                      *
;*******************************************************************************
Proc Exc_Reg_Tabela(TABORIG,TABDEST)
Private TABORIG,TABDEST
                 
SubTract TABORIG TABDEST ClearImage
SaveTables

{Modify} {Restructure} TypeIn TABDEST Enter Do_It! ClearImage
Delete TABORIG
SAVETABLES
EndProc

;*******************************************************************************
;* Rotina Desbloqueia Tabelas da Pasta                                         *
;*******************************************************************************
Proc DesbloqueiaTabelas(Pasta)
Private Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then UnLock Pasta+Array_Tabelas[i] FL
  EndIf
EndFor

EndProc

;*******************************************************************************
;* Rotina Monta Lista de Tabelas a Processar                                   *
;*******************************************************************************
Proc ListadeTabelas()
If IsAssigned(Array_Tabelas)
   Then Release Vars Array_Tabelas
EndIf
DynArray Array_Tabelas[]

Array_Tabelas[01]="NotaC"
Array_Tabelas[02]="NotaI"
Array_Tabelas[03]="NotaIG"
Array_Tabelas[04]="NotaIC"
Array_Tabelas[05]="NotaIDD"
Array_Tabelas[06]="NotaIAD"
Array_Tabelas[07]="NotaIDV"
Array_Tabelas[08]="NotaR"
Array_Tabelas[09]="NotaV"
Array_Tabelas[10]="NotaCC"
Array_Tabelas[11]="NotaICM"

Array_Tabelas[12]="DupC"
Array_Tabelas[13]="DupI"
Array_Tabelas[14]="DupNF"

Array_Tabelas[15]="ECF_C"
Array_Tabelas[16]="ECF_T"
Array_Tabelas[17]="ECF_S"

Array_Tabelas[18]="AcCarrgC"
Array_Tabelas[19]="AcCarrgF"
Array_Tabelas[20]="AcCarrgI"
Array_Tabelas[21]="AcCarrgV"

Array_Tabelas[22]="Contfrtc"
Array_Tabelas[23]="Contfrtn"

Array_Tabelas[24]="EXPEDC"
Array_Tabelas[25]="EXPEDI"
Array_Tabelas[26]="EXPEDIE"
Array_Tabelas[27]="EXPEDIQ"
Array_Tabelas[28]="EXPEDTG"

Array_Tabelas[29]="EXPEDOFC"
Array_Tabelas[30]="EXPEDOFI"

EndProc

;*******************************************************************************
;* Rotina Lista de Mes/Ano em Aberto                                           *
;*******************************************************************************
Proc Lista_MesAno()
ClearAll
Aguarde("Aguarde, Verificando Mes/Ano em Aberto")

If IsAssigned(Array_ListaMesAno)
   Then Release Vars Array_ListaMesAno
EndIf
DynArray Array_ListaMesAno[]

{Ask} {Notac}
Moveto [Data de Emissao] Check
Do_It!
ClearAll

Rename "Answer" PrivDir()+"Temp000"

{Ask} {DupC}
Moveto [Data de Emissao] Check
Do_It!
ClearAll

Add "Answer" PrivDir()+"Temp000"
ClearAll

{Ask} {ECF_C}
Moveto [Data] Check
Do_It!
ClearAll

Add "Answer" PrivDir()+"Temp000"
ClearAll

{Ask} {AcCarrgC}
Moveto [Data de Emissao] Check
Moveto [Situacao       ] TypeIn "ACERTADO"
Do_It!
ClearAll

Add "Answer" PrivDir()+"Temp000"
ClearAll

{Ask} {Contfrtc}
Moveto [Data de Emissao] Check
Moveto [CT_Numero do Documento] typeIn "Not blank"
Do_It!
ClearAll

Add "Answer" PrivDir()+"Temp000"
ClearAll

{Ask} {ExpedC}
Moveto [Data_Inclusao ] Check TypeIn "as Data de Emissao"
Moveto [Situacao da OE] TypeIn "FATURADO"
Do_It!
ClearAll

Add "Answer" PrivDir()+"Temp000"
ClearAll

{Ask} {ExpedOFC}
Moveto [Data_Inclusao ] Check TypeIn "as Data de Emissao"
Moveto [Situacao da OE] TypeIn "FATURADO"
Do_It!
ClearAll

Add "Answer" PrivDir()+"Temp000"
ClearAll

If IsEmpty(PrivDir()+"Temp000")
   Then LimpAguarde()
        Return
EndIf

{Modify} {Restructure} TypeIn PrivDir()+"Temp000" Enter
Right CtrlBackspace  "Data"
Down  "Mes" Enter  "a2" Enter  "Ano" Enter  "a4"
Do_It!

EditKey
Scan
  If Not IsBlank([Data])
     Then [Mes]=AlinhM(StrVal(Month([Data])),2)
          [Ano]=AlinhM(StrVal(Year([Data])),4)
  EndIf
EndScan
Do_It!
ClearAll

{Ask} TypeIn PrivDir()+"Temp000" Enter
Moveto [Mes] Check
Moveto [Ano] Check
Do_It!
ClearAll

Sort "Answer" on "Ano","Mes"

wcs=0
Scan
  wcs=wcs+1
  Array_ListaMesAno[wcs]=[Ano]+"_"+[Mes]
EndScan
ClearAll

LimpAguarde()
EndProc    ;  (Lista_MesAno)

;*******************************************************************************
;* Rotina para encerramento das tabelas do Faturamento                         *
;*******************************************************************************
Proc Encerra_Vendas()  
  
Diretorio="\\Sistemas\\Vendas\\"
DiretorioFechames=Diretorio+"Fechames\\"+ANO+"_"+MES+"\\"
If DirExists(Diretorio+"Fechames")=0
  Then Cria_Pasta(Diretorio+"FechaMes")
EndIf
If DirExists(Diretorio+"Fechames\\"+ANO+"_"+MES)=0
   Then Cria_Pasta(Diretorio+"Fechames\\"+ANO+"_"+MES)
EndIf

ListadeTabelas()
If (BloqueiaTabelas(Diretorio)) And
   (BloqueiaTabelas(DiretorioFechames))
   Then NOTASFISCAIS()
        DUPLICATAS()
        ECFS()
        CARREGAMENTOS()
        ControleFretes()
        Expedicao()
        Expedicao_OF()
EndIf
DesbloqueiaTabelas(Diretorio)
DesbloqueiaTabelas(DiretorioFechames)
  
EndProc ;Proc Encerra_Vendas()  

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DIRETORIOS"    : Campo="TG_EMPRESA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
          SYS_TECLA_ACIONADA=Evento["KeyCode"]
          Seta_Tecla_Acionada()
          CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_DIRETORIOS"
                    Case Campo="TG_DIRETORIOS" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="":
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

If Not IsAssigned(PARAM_FECHA_VENDAS) Then PARAM_FECHA_VENDAS = False EndIf

If PARAM_FECHA_VENDAS
   Then Encerra_Vendas()
        Return
EndIf        

VSDGEMPRESA   =""

COR_MENSAGEM="1"
MSG=    "Antes de fechar um mˆs, observe se j //"
MSG=MSG+"existem lan‡amentos existentes no mˆs seguinte !// //"
MSG=MSG+"Fique atento a ordem crescente dos lan‡amentos//"
MSG=MSG+"pra que os mesmos n„o retrocedam !"
Mensagem(MSG)
Release Vars COR_MENSAGEM

primeiravez = True

While True
  Lista_MesAno()

  ShowDialog "Fechamento mensal [ Faturamento ]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 04,17   Height 19 Width 75

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 0,09 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 0,16 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    PickDynArray @2,01 Height 12 width 69
     Columns 7
      Array_ListaMesAno
       Tag "TG_DIRETORIOS"                                           
        To ArrayElement
    Label @ 01,00 "Ano_Mes em aberto"  For "TG_DIRETORIOS"

    Pushbutton @ 15,24 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,38 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If DynArraySize(Array_ListaMesAno)<1
     Then Mensagem("Sem Mes/Ano p/ Fechar !")
          Loop
  EndIf

  ANO_MES=Array_ListaMesAno[ArrayElement]

  MES=Substr(ANO_MES,6,2)
  ANO=Substr(ANO_MES,1,4)
  If NumVal(ANO) < 2000
     Then MESANO=MES+"."+SubStr(ANO,3,2)
     Else MESANO=MES+"."+ANO
  EndIf

  If DirExists("\\Fechano\\"+ANO)<>0 And Not IsFile("\\Fechano\\"+ANO+"\\ESTOQUE\\SDESTQ.DB")
     Then MSG="No fechamento Anual de "+ANO+" j  existem lan‡amentos arquivados !// //"
          MSG=MSG+Completa("Para poder fechar este mˆs, siga os passos:",70," ")+"// //"
          MSG=MSG+Completa("1) Restaure o ano de "+ANO+";",70," ")+"//"
          MSG=MSG+Completa("2) Aproveite e feche os mˆses de todos m¢dulos referente a "+ANO+";",70," ")+"//"
          MSG=MSG+Completa("   * Assim estes novos lan‡amentos ser„o agrupados aos",70," ")+"//"
          MSG=MSG+Completa("     lan‡amentos anteriores",70," ")+"//"
          MSG=MSG+Completa("3) Se necess rio feche novamente o ano de "+ANO+" !",70," ")
          Mensagem(MSG)
          Loop
  Endif

  If ANO <> Year(Today()) And primeiravez
     Then COR_MENSAGEM="1"
          MSG=    "Identificamos  que o mˆs a ser fechado ‚ do ano de "+ANO+",//"
          MSG=MSG+"portanto   para  um  melhor  desempenho  do  sistema  ‚//" 
          MSG=MSG+"aconselh vel  ap¢s  executar todos os fechamentos deste//" 
          MSG=MSG+"ano executar a rotina de fechamento da Ficha de Estoque.////"
          MSG=MSG+"Utilitarios > Fechamento > Anual - Ficha Estoque        "
          Mensagem(MSG)
          Release Vars COR_MENSAGEM
  EndIf  

  If Not Verifica_Usuario() Then Loop EndIf
  Encerra_Vendas()
  
  LimpAguarde()
  Fastmsg("Fim de Opera‡„o !")
  
  primeiravez  = False

EndWhile
ClearAll
Release Vars All
Release Procs All
