;** Rm_0060  *******************************************************************
;*  Fluxo de Caixa                                                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 03/05/2018 por Anivel Augusto Rodrigues
;Ultima Alteracao: 03/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao novo processo concetrador RM_0030, RM_0040, RM_0050, RM_0060             
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog_Emp(Disparo,Campo,Evento,Elemento)
private Disparo,Campo,Evento,Elemento, Temp

Temp=True
MSG_CAMPO=""
                                    
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
          Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
          SYS_TECLA_ACIONADA=Evento["KeyCode"]
          Seta_Tecla_Acionada()
          CancelDialog
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_Registro"      : Campo="NO"
            Case Campo="YES" Or Campo="NO": Campo="TG_Registro"
          EndSwitch
     Case Evento["KeyCode"] = 32 And Campo="TG_Registro":
          Temp=False
          If SubStr(Array_Empresa[ControlValue("TG_Registro")],41,1)=" "
             Then Array_Empresa[ControlValue("TG_Registro")]=SubStr(Array_Empresa[ControlValue("TG_Registro")],1,40)+"X"
             Else Array_Empresa[ControlValue("TG_Registro")]=SubStr(Array_Empresa[ControlValue("TG_Registro")],1,40)+" "
          EndIf 
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_Registro": Campo="YES"
                  EndSwitch
          EndIf                     
   EndSwitch 
EndIf

Switch  
  Case Campo="TG_Registro":
       MSG_CAMPO="Selecione o arquivo"
       TECLA="Barra de Espa‡o=Marca/Desmarca"
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc Seleciona_Empresa()
Private wc,wcc,Empresa

If Not IsAssigned(Array_Empresa)
   Then DynArray Array_Empresa[]

        {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa    ] Check 
        Moveto [Nome Fantasia Empresa] Check
        Do_It!
        ClearAll
        
        CoEdit "Answer"
        Moveto [Codigo da Empresa]
        wc=1
        Scan
          Empresa           = [Codigo da Empresa]+" "+[Nome Fantasia Empresa]
          Array_Empresa[wc] = Completa(SubStr(Empresa,1,Len(Empresa)),40," ")+"X"
          wc=wc+1
        EndScan
        Do_It!
        ClearAll
EndIf
VOLTA=True

While True

  ShowDialog "Empresas" Proc "SD_Dialog_Emp"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",32
   @ 02,12   Height 14 Width 56

  @ 00,02 ?? "Empresas"
  PickDynArray @1,01 Height 08 width 53
   Columns 1
    Array_Empresa
     Tag "TG_Registro"
      To ArrayElement

    Pushbutton @ 10,17 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,29 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  
  If Not RetVal Then Return False EndIf
  
  VOLTA=False
  For wc From 1 To DynArraySize(Array_Empresa)
      If SubStr(Array_Empresa[wc],41,1) = "X"
         Then QuitLoop
         Else If wc = DynArraySize(Array_Empresa) 
                 Then Mensagem("Nenhuma empresa selecionada !") 
                      VOLTA=True
              EndIf
      EndIf
  EndFor
  If VOLTA Then Loop EndIf
  
  wcc=0
  DynArray Array_Cod_Empresa[]
  For wc From 1 To DynArraySize(Array_Empresa)
      If SubStr(Array_Empresa[wc],41,1) = "X"
         Then wcc=wcc+1
              Array_Cod_Empresa[wcc] = LTrim(SubStr(Array_Empresa[wc],1,4))
      EndIf
  EndFor 
  QuitLoop
EndWhile

Return True

EndProc


;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc ValidarRelatorio(tipo)
private tipo, result

result=true

switch
  case VSDGCODMODELO="01" Or
       VSDGCODMODELO="02" Or
       VSDGCODMODELO="03" Or
       VSDGCODMODELO="10" :

    If VSDGEMPRESA=""
       Then result=false
            if tipo="SD"
               then  FastMsg("Empresa Inv lida !")
               else Mensagem("Empresa Inv lida !")
            endif
            return result   
       else
            VSDGCONTA   =""
            VSDGNOMCONTA="TODAS"
    EndIf

  case VSDGCODMODELO="09" Or
       VSDGCODMODELO="11" : 

    If VSDGCONTA  =""
       Then result=false
            if tipo="SD"
               then  FastMsg("Conta Inv lida !")
               else Mensagem("Conta Inv lida !")
            endif   
            return result   
       else
            VSDGEMPRESA =""
            VSDGNOMEMP  ="TODAS"
            
            VSDGEMPRESA2=VSDGEMPRESA
    EndIf

endswitch

return result
endproc 

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
private Disparo,Campo,Evento,Elemento, Temp

Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESAS"      : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESAS"
            Case Campo="TG_DTINI"         : Campo="TG_CONTA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPFLUXOCX"     : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPFLUXOCX"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESAS"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESAS" :    
                         If IsBlank(VSDGEMPRESA)
                            Then VSDGNOMEMP=""
                            
                            Else 
                                 If VSDGEMPRESA="0000"
                                    Then If Seleciona_Empresa()
                                            Then Campo="TG_CONTA"
                                            else Campo="TG_EMPRESAS"
                                         EndIf
                                    Else Campo="TG_CONTA"
                                 EndIf 
                         EndIf
                    Case Campo="TG_CONTA"      : Campo="TG_DTINI"
                    Case Campo="TG_DTINI" :
                         If Not IsBlank(VSDGDTINI)
                            Then Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM"      : Campo="TG_OPFLUXOCX"
                    Case Campo="TG_OPFLUXOCX"  : Campo="TG_CODMODELO"

                    Case Campo="TG_CODMODELO"  :
                      if ValidarRelatorio("SD")
                         then Campo="YES"
                      endif   
                     
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_DTINI":
     MSG_CAMPO="Informe a Data Inicial"
  Case Campo="TG_OPFLUXOCX":
     MensagemCheckBoxes()
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Sint‚tico Empresa/Di rio")
ModeloRelatoriosAdd("02  Sint‚tico Empresa/Mensal I")
ModeloRelatoriosAdd("03  Sint‚tico Empresa/Mensal II")
ModeloRelatoriosAdd("11  Sint‚tico Conta")

ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("09  Anal¡tico Conta")
ModeloRelatoriosAdd("10  Anal¡tico Empresa")

ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   = ""
VSDGCONTA     =""
VSDGDTINI     = Today()
VSDGDTFIM     = Today()+30

Array TG_OPFLUXOCX[8]
TG_OPFLUXOCX[1]="~1~ T¡lulos a receber referente a Cart„o de Crˆdito/D‚bito"
TG_OPFLUXOCX[2]="~2~ T¡lulos a receber todos"
TG_OPFLUXOCX[3]="~3~ Entradas/Saida realizadas"
TG_OPFLUXOCX[4]="~4~ Saldo Inicial"
TG_OPFLUXOCX[5]="~5~ Conta tipo Aplica‡Æo"
TG_OPFLUXOCX[6]="~6~ Transferˆncias entre Contas"
TG_OPFLUXOCX[7]="~7~ Crˆdito Conta Corrente"
TG_OPFLUXOCX[8]="~8~ Cheques de Terceiros"

Array CheckTG_OPFLUXOCX[8]
CheckTG_OPFLUXOCX[1]=False
CheckTG_OPFLUXOCX[2]=False
CheckTG_OPFLUXOCX[3]=False
CheckTG_OPFLUXOCX[4]=False
CheckTG_OPFLUXOCX[5]=False
CheckTG_OPFLUXOCX[6]=False
CheckTG_OPFLUXOCX[7]=False
CheckTG_OPFLUXOCX[8]=False

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Fluxo de Caixa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
    @ 01,00 Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESAS"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESAS"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    

    Label  @ 07,00 "Desprezar op‡äes:" For "TG_OPFLUXOCX"
    CheckBoxes @ 08,00 Height 8 Width 66 Tag "TG_OPFLUXOCX" 
    TG_OPFLUXOCX[1] to CheckTG_OPFLUXOCX[1],
    TG_OPFLUXOCX[2] to CheckTG_OPFLUXOCX[2],
    TG_OPFLUXOCX[3] to CheckTG_OPFLUXOCX[3],
    TG_OPFLUXOCX[4] to CheckTG_OPFLUXOCX[4],
    TG_OPFLUXOCX[5] to CheckTG_OPFLUXOCX[5],
    TG_OPFLUXOCX[6] to CheckTG_OPFLUXOCX[6],
    TG_OPFLUXOCX[7] to CheckTG_OPFLUXOCX[7],
    TG_OPFLUXOCX[8] to CheckTG_OPFLUXOCX[8] 

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         
       
  If VSDGDTINI=BlankDate()
     Then Mensagem("Data Inicial Invalida !")
          Loop
  EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  if not ValidarRelatorio("")
     then Loop
  endif   

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  ANOREF=StrVal(Year(VSDGDTINI))
  MESREF=StrVal(Month(VSDGDTINI))
  ALINHM(MESREF, 2)
  MESREF=NVR
  VSDGDTREF=DateVal("01."+MESREF+"."+ANOREF)

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  Release Vars TipoFluxo,TipoFiltro

  switch
    case VSDGCODMODELO="01" Or
         VSDGCODMODELO="02" Or
         VSDGCODMODELO="03" :
      TipoFluxo ="Sintetico"
      TipoFiltro="Empresa"
      Impressao_Orientacao="Paisagem"

    case VSDGCODMODELO="11" :
      TipoFluxo ="Sintetico"
      TipoFiltro="Conta"
      Impressao_Orientacao="Paisagem"
          
    case VSDGCODMODELO="09" :
      TipoFluxo ="Analitico"
      TipoFiltro="Conta"
      Impressao_Orientacao="Retrato"
          
    case VSDGCODMODELO="10" :
      TipoFluxo ="Analitico"
      TipoFiltro="Empresa"
      Impressao_Orientacao="Retrato"

  endswitch

  Play "RM_FlxCx"
  
  switch
    case VSDGCODMODELO="01" : IMPRIREL(Tabela,"R")
    case VSDGCODMODELO="02" : IMPRIREL(Tabela,"3")
    case VSDGCODMODELO="03" : IMPRIREL(Tabela,"4")

    case VSDGCODMODELO="09" : IMPRIREL(Tabela,"3")

    case VSDGCODMODELO="10" : IMPRIREL(Tabela,"8")

    case VSDGCODMODELO="11" : IMPRIREL(Tabela,"1")

  endswitch

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
