;** Rc_0090 *******************************************************************
;*  Relatorio de Representantes                                                *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/95 por Anivel Augusto Rodrigues
;Ultima Alteracao: 02/04/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 23/03/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado Op‡Æo 3 (Ficha Cadastral mais Detalhada)
;Ultima Alteracao: 14/04/2011 por Bruno Carvalho
;Motivo Alteracao: Adicionado Op‡Æo para Status do Representante
;Ultima Alteracao: 24/05/2011 por Nikolas
;Motivo Alteracao: Status do Representante estava invertido
;Ultima Alteracao: 07/05/2012 por Karina Andrade
;Motivo Alteracao: Adicionado Gerencia e ajuste de Status ao ShowDialog
;Ultima Alteracao: 21/06/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes na op‡Æo da impressÆo, ]ao estava sendo impresso em ordem alf.
;Ultima Alteracao: 13/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 09/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 25/11/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_CODMODELO
;Ultima Alteracao: 23/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 05/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Seta_Ordem_Report()                
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()

If VSDGOPRELCODALF = "2"
   Then {Modify} {Sort} {Represen} {Answer} Down  "1" Do_It!
        DORDEM="Alfabetica"
   Else {Modify} {Sort} {Represen} {Answer}       "1" Do_It!
        DORDEM="de Codigo"
EndIf

{Ask} {Answer} Check
Switch
  Case VSDGSTATUS="1": Moveto [Inativo Represent]  TypeIn "N"
  Case VSDGSTATUS="2": Moveto [Inativo Represent]  TypeIn "S"
EndSwitch

If VSDGGERENCIA<>""
  Then Moveto [Codigo do Representante] TypeIn "_crep"
       {Ask} {Represen}
       Moveto [Codigo do Representante] TypeIn "_crep"
       Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
  
  Else Moveto [Codigo do Representante] TypeIn "_crep!"
       {Ask} {Represen}
       Moveto [Codigo do Representante] TypeIn "_crep"  
       Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
EndIf 
Do_It!
ClearAll

If VSDGCODMODELO = "01" Then CopyReport "\\Base\\Sistemas\\Cadastro\\Represen" "1" "Answer" "R" EndIf
If VSDGCODMODELO = "02" Then CopyReport "\\Base\\Sistemas\\Cadastro\\Represen" "2" "Answer" "R" EndIf
If VSDGCODMODELO = "03" Then CopyReport "\\Base\\Sistemas\\Cadastro\\Represen" "3" "Answer" "R" EndIf
ClearAll

If VSDGOPRELCODALF="2"
   Then Seta_Ordem_Report("Answer","R","Codigo do Representante","Nome Fantasia Represent","")
EndIf   
 
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog1(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9  : Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_GERENCIA"       : Campo="NO"
            Case Campo="TG_STATUS"         : Campo="TG_GERENCIA"
            Case Campo="TG_OPRELCODALF"    : Campo="TG_STATUS"  
            Case Campo="TG_CODMODELO"      : Campo="TG_OPRELCODALF"
            Case Campo="YES" Or Campo="NO" : Campo="TG_GERENCIA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_GERENCIA"     : Campo="TG_STATUS"
                    Case Campo="TG_STATUS"       : Campo="TG_OPRELCODALF"      
                    Case Campo="TG_OPRELCODALF"  : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"    : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Listagem")
ModeloRelatoriosAdd("02  Ficha cadastral I")
ModeloRelatoriosAdd("03  Ficha cadastral II")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGOPRELCODALF  =""
VSDGGERENCIA     =""
VSDGSTATUS       =""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Relat¢rio de Representantes" Proc "SD_Dialog1"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12 Height 12 Width 72

    Label  @ 00,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 01,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 02,00 "Status" For "TG_STATUS"
    Accept @ 03,04 Width 04 "A1"  Picture "1,2,3" Tag "TG_STATUS" To VSDGSTATUS
    Accept @ 03,09 Width 25 "A12" Picture "!*!" Tag "TG_NOMSTATUS" To VSDGNOMSTATUS

    Label  @ 00,35 "Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 05,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 06,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 06,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 08,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 08,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  DISPOSITIVO()
  If OK="" Then Loop EndIf
  
  If IsTable("Answer")
     Then Delete "Answer"
  EndIf
  
  AGUARDE("Aguarde, Gerando Relat¢rio")
  Seleciona()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o Existem Registros a Processar")
          Loop
  EndIf

  IMPRIREL("Answer","R")

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All

