;** Rm_0030  *******************************************************************
;* Relacao de Notas Fiscais por Clientes                                       *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 06/04/2004 por Anivel Augusto Rodrigues
;Ultima Alteracao: 10/08/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;ultima Alteracao: 21/01/2010 por Humberto F. sAntos.
;Motivo Alteracao: Inclusao Pedido de origem.
;ultima Alteracao: 25/11/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Layout Relatorio   
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;ultima Alteracao: 26/07/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes inclusao filtro condi‡Æo de pagto 
;ultima Alteracao: 13/12/2013 por Andrey Fillipe
;Motivo Alteracao: Inclusao de data de vencimento na opcao c/itens
;ultima Alteracao: 21/05/2014 por Kamila Gomes
;Motivo Alteracao: Inclusao de op‡Æo c/itens/cor
;Ultima Alteracao: 27/10/2016 por Rafael Matos
;Motivo Alteracao: Ajustes Layout para padroniza‡Æo
;Ultima Alteracao: 10/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog       
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT            
;Ultima Alteracao: 23/02/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes foram de pagamento nos vencimentos
;Ultima Alteracao: 03/05/2018 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro de data -> EmissÆo ou Saida  

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check
         Moveto [Codigo da Empresa      ] Example "Empresa" TypeIn ", ~VSDGEMPRESA.."
         Moveto [Numero do Documento    ] Example "Docto"
         Moveto [Serie do Documento     ] Example "Serie"
         If IsBlank(VSDGNCARREG)
            Then If VSDGOPDTES="1"
                    Then Moveto [Data de Emissao] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                    Else Moveto [Data de Saida  ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                 EndIf     
         EndIf
         Moveto [Codigo                 ] TypeIn "~VSDGDESTINAT.."
         Moveto [Condicao de Pagamento  ] TypeIn "~VSDGCONDPGTO.."
         Moveto [Forma de Pagamento     ] TypeIn "~VSDGTPPAGTO.."
         Moveto [Codigo da Destinacao   ] TypeIn "~VSDGDESTIN.."
         Moveto [Numero_Carregamento    ] TypeIn "~VSDGNCARREG.."
         Moveto [Situacao               ] TypeIn "Not C"
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"Notai" Enter Check
         Moveto [Codigo da Empresa      ] Example "Empresa"
         Moveto [Numero do Documento    ] Example "Docto"
         Moveto [Serie do Documento     ] Example "Serie"
         Moveto [Situacao_Item          ] TypeIn "Not C"
         Do_It!
         ClearAll
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar os Vencimentos                                         *
;*******************************************************************************
Proc Selecionav()

Copy Tabela Tabela1

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa  ] Example "codemp"
Moveto [Numero do Documento] Example "numdoc"
Moveto [Serie do Documento ] Example "serdoc"

{Ask} {NotaV} Check
Moveto [Codigo da Empresa  ] Example "codemp"
Moveto [Numero do Documento] Example "numdoc"
Moveto [Serie do Documento ] Example "serdoc"
Do_It!
ClearAll

View "Answer"
Coedit Tabela1
Scan

  [Observacao na Nota Fiscal]=""

  CODEMP = [Codigo da Empresa]
  NUMDOC = [Numero do Documento]
  SERDOC = [Serie do Documento]
  
  Moveto "Answer"
  Moveto [Codigo da Empresa]
  Locate CODEMP,NUMDOC,SERDOC
  If RetVal
     Then  AUXILIAR = ""
           NCHAR = 0
           While CODEMP=[Codigo da Empresa  ] And
                 NUMDOC=[Numero do Documento] And
                 SERDOC=[Serie do Documento ] 
                 If AUXILIAR<>""
                    Then AUXILIAR = AUXILIAR + " | "
                         NCHAR=NCHAR+2
                 EndIf   
                 AUXILIAR = AUXILIAR + Format("D13",[Data])+" "+[Forma de Pagamento]+" "+LTrim(Format("W10.2,EIC",[Valor])) ;22 Caracteres
                 NCHAR=NCHAR+22
                 Skip
                 If Eot() Then QuitLoop EndIf
           EndWhile

           Moveto Tabela1
           Moveto [Observacao na Nota Fiscal]
           []=""
           []=AUXILIAR
           UnLockRecord

  EndIf

  Moveto Tabela1
EndScan
Do_It!
ClearAll

EndProc   ; (Selecionav)

;*******************************************************************************
;* Rotina Ajusta Dados                                                         *
;*******************************************************************************
Proc Ajusta_Dados()
ClearAll
         
Sort Tabela On "Codigo da Empresa", "Numero do Documento", "Serie do Documento","Item do Documento"

CDEMPR="****"
NDOCTO="****"
SDOCTO="****"

CoEdit Tabela
Scan
 If [Codigo da Empresa  ]<>CDEMPR Or
    [Numero do Documento]<>NDOCTO Or
    [Serie do Documento ]<>SDOCTO
    Then CDEMPR=[Codigo da Empresa  ]
         NDOCTO=[Numero do Documento]
         SDOCTO=[Serie do Documento ]
    Else [Valor Nota Fiscal]=BlankNum()
         [Valor Mercadoria ]=BlankNum()
         [Peso Liquido     ]=BlankNum()
 EndIf
 [Nome do Autorizado]=""
EndScan
Do_It!
ClearAll

{Ask} {PedidoC}
Moveto [Numero do Pedido    ] Example "nped"
Moveto [Numero Pedido Origem] Example "pedori"
{Ask} Typein tabela enter  
Moveto [Numero do Pedido    ] Example "nped"
Moveto [Nome do Autorizado  ] Typein "changeto " Example "pedori"   
do_it!
ClearAll 

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""      
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESA"
            Case Campo="TG_DESTIN"        : Campo="TG_DESTINAT"
            Case Campo="TG_CONDPGTO"      : Campo="TG_DESTIN"
            Case Campo="TG_NCARREG"       : Campo="TG_CONDPGTO"            
            Case Campo="TG_TPPAGTO"       : Campo="TG_NCARREG"
            Case Campo="TG_CSITENS"       : Campo="TG_TPPAGTO"
            Case Campo="TG_OPDTES"        : Campo="TG_CSITENS"
            Case Campo="TG_DTINI"         : Campo="TG_OPDTES" 
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT": Campo="TG_DESTIN"
                    Case Campo="TG_DESTIN"  : Campo="TG_CONDPGTO"
                    Case Campo="TG_CONDPGTO": Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG" : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO" : Campo="TG_CSITENS"
                    Case Campo="TG_CSITENS" : 
                         VSDGCSITENS=ControlValue("TG_CSITENS")
                         Switch
                           Case VSDGCSITENS="C": VSDGNOMCSITENS="COM ITENS"
                           Case VSDGCSITENS="I": VSDGNOMCSITENS="COM ITENS/COR"
                           OtherWise:
                                VSDGCSITENS="S"
                                VSDGNOMCSITENS="SEM ITENS"
                         EndSwitch
                         Campo="TG_OPDTES" 
                    Case Campo="TG_OPDTES"  : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="YES"                         
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_CSITENS":
     MSG_CAMPO="Impress„o das Notas: C=Com Itens,I=Com Itens/Cor,S=Sem Itens"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGDESTINAT=""
VSDGDESTIN  =""
VSDGCONDPGTO=""
VSDGTPPAGTO =""
VSDGCSITENS =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
VSDGNCARREG =""

While True

  ShowDialog "Rela‡„o Notas Fiscais - Clientes" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 19 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 04,00 "Destinacao"  For "TG_DESTIN"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_DESTIN"    To VSDGDESTIN
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMDESTIN" To VSDGNOMDESTIN

    Label  @ 06,00 "Condi‡„o de Pagamento"  For "TG_CONDPGTO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_CONDPGTO"    To VSDGCONDPGTO
    Accept @ 07,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMCONDPGTO" To VSDGNOMCONDPGTO

    Label  @ 10,00 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 11,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 11,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 08,00 "Carregamento" For "TG_NCARREG"
    Accept @ 09,01 Width 09  "A6"  Picture "#*#" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG

    Label  @ 12,00 "Op‡„o p/ Itens" For "TG_CSITENS"
    Accept @ 13,03 Width 05 "A1"  Picture "S,C,I" Tag "TG_CSITENS" To VSDGCSITENS
    Accept @ 13,09 Width 25 "A20"  Picture "!*!" Tag "TG_NOMCSITENS" To VSDGNOMCSITENS

    Label  @ 00,35 "Op‡äes de Datas" For "TG_OPDTES"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2"  Tag "TG_OPDTES" To VSDGOPDTES
    Accept @ 01,44 Width 25 "A18" Picture "!*!"  Tag "TG_NOMOPDTES" To VSDGNOMOPDTES

    Label  @ 02,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 15,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGNCARREG) And IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Ajusta_Dados()
  Tabela1=Cria_Temp(PrivDir())
  Selecionav()
  If VSDGCSITENS="C"
     Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2001" "R" Tabela1 "R"
     Else If VSDGCSITENS="I" 
             Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2001b" "R" Tabela1 "R"
             Else If VSDGOPDTES="1"
                     Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2001" "1" Tabela1 "R"
                     Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2001b" "4" Tabela1 "R"                          
                  EndIf   
          EndIf
  EndIf

  IMPRIREL(Tabela1,"R")
  
  Delete Tabela
  Delete Tabela1

EndWhile
ClearAll
Release Vars All
Release Procs All
