;** Rm_0201 ********************************************************************
;*  Emissao do Extrato/Programacoes de Corte                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/09/2010 por Karina
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW
;Ultima Alteracao: 20/06/2014 por Luis Gustavo
;Motivo Alteracao: InclusÆo da op‡ao de Relatorio  (Analitico e Sintetico)
;Ultima Alteracao: 13/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes l¢gica e reports           
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

Empty(Tabela)

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ] TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ] TypeIn "~VSDGMARCA.."
{Ask} {Cfacc}
Moveto [Numero_Corte          ] Example "num" TypeIn ", ~VSDGCORTE.."
Moveto [Codigo da Empresa     ] Example "cemp" TypeIn ", ~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa ] Example "nemp"
Moveto [Situacao_Programacao  ] Example "sp"
Moveto [Data_Programacao      ] Example "dp"
If IsBlank(VSDGCORTE)
   Then TypeIn ", >=~VSDGDTINI,<=~VSDGDTFIM"
EndIf
{Ask} {CfacRI}
Moveto [Numero_Corte           ] Example "num"
Moveto [Codigo do Item         ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Moveto [Tipo do Item           ] Example "tite"
Moveto [Referencia             ] Example "ref"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Quantidade Programada  ] Example "qtd"
Moveto [Unidade Fiscal         ] Example "un"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero_Programacao_Corte ] Example "num"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Nome Fantasia Empresa    ] Example "nemp"
Moveto [Situacao_Programacao     ] Example "sp"
Moveto [Data_Programacao         ] Example "dp"
Moveto [Numero_Producao_Corte    ] Example "num"
Moveto [Data_Producao            ] Example "dp"
Moveto [Tipo Movimento           ] TypeIn "P"
Moveto [Codigo do Item           ] Example "ITEN"
Moveto [Tipo do Item             ] Example "tite"
Moveto [Referencia               ] Example "ref"
Moveto [Descricao do Item        ] Example "dite"
Moveto [Quantidade Programada    ] Example "qtd"
Moveto [Unidade Fiscal           ] Example "un"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Numero_Programacao_Corte ] Check
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ] TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ] TypeIn "~VSDGMARCA.."
{Ask} {Answer}
Moveto [Numero_Programacao_Corte ] Example "nprog"
{Ask} {Cfacc}
Moveto [Numero_Corte          ] Example "nprog"
Moveto [Codigo da Empresa     ] Example "cemp"
Moveto [Nome Fantasia Empresa ] Example "nemp"
Moveto [Situacao_Programacao  ] Example "sp"
Moveto [Data_Programacao      ] Example "dprog"
{Ask} {Pcfacc}
Moveto [Numero_Producao_Corte    ] Example "num"
Moveto [Numero_Programacao_Corte ] Example "nprog"
Moveto [Data_Producao            ] Example "dp"
{Ask} {PcfacRI}
Moveto [Numero_Producao_Corte  ] Example "num"
Moveto [Codigo do Item         ] Example "ITEN" TypeIn ", ~VSDGITEM.."
Moveto [Tipo do Item           ] Example "tite"
Moveto [Referencia             ] Example "ref"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Quantidade Produzida   ] Example "qtd"
Moveto [Unidade Fiscal         ] Example "un"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero_Programacao_Corte ] Example "nprog"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Nome Fantasia Empresa    ] Example "nemp"
Moveto [Situacao_Programacao     ] Example "sp"
Moveto [Data_Programacao         ] Example "dprog"
Moveto [Numero_Producao_Corte    ] Example "num"
Moveto [Data_Producao            ] Example "dp"
Moveto [Tipo Movimento           ] TypeIn "R"
Moveto [Codigo do Item           ] Example "ITEN"
Moveto [Tipo do Item             ] Example "tite"
Moveto [Referencia               ] Example "ref"
Moveto [Descricao do Item        ] Example "dite"
Moveto [Quantidade Produzida     ] TypeIn "_qtd"
Moveto [Unidade Fiscal           ] Example "un"
Do_It!  
ClearAll

if VSDGCODMODELO="1" or
   VSDGCODMODELO="2" 
  then return 
endif

if VSDGCODMODELO="4"        
   then 
        Edit Tabela
        Scan
          [Codigo do Item]=PegaCodigoRaiz([Codigo do Item])
        EndScan
        Do_It!
        ClearAll
        
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ] Example "item"
        Moveto [Descricao do Item      ] TypeIn "_desc"
        Moveto [Referencia             ] TypeIn "_ref"
        
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo do Item         ] Example "item"
        Moveto [Descricao do Item      ] TypeIn "Changeto _desc"
        Moveto [Referencia             ] TypeIn "Changeto _ref"
        Do_It!
        ClearAll
        
endif

{Ask} TypeIn Tabela Enter 
Moveto [Codigo da Empresa      ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Codigo do Item         ] Check
Moveto [Descricao do Item      ] Check
Moveto [Referencia             ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Data_Producao          ] Check
Moveto [Tipo Movimento         ] Check
Moveto [Numero_Producao_Corte  ] Check
Moveto [Quantidade Programada  ] TypeIn "Calc Sum As \"Quantidade Programada\""
Moveto [Quantidade Produzida   ] TypeIn "Calc Sum As \"Quantidade Produzida\""
Moveto [Saldo                  ] TypeIn "Calc Sum As \"Saldo\""
Do_It!
ClearAll

EndProc   ; (Seleciona)

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Normal")
ModeloRelatoriosAdd("02  Mensal")
ModeloRelatoriosAdd("03  Por Item")
ModeloRelatoriosAdd("04  Por Referˆncia")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"    : Campo="NO"
            Case Campo="TG_CORTE"      : Campo="TG_EMPRESA"
            Case Campo="TG_FAMI"       : Campo="TG_CORTE"
            Case Campo="TG_MARCA"      : Campo="TG_FAMI"
            Case Campo="TG_ITEM"       : Campo="TG_MARCA"
            Case Campo="TG_REFERENCIA" : Campo="TG_ITEM"
            Case Campo="TG_DTINI"      : Campo="TG_REFERENCIA"
            Case Campo="TG_DTFIM"      : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"  : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_CORTE"
                    Case Campo="TG_CORTE"      :
                         If Not ISBlank(VSDGCORTE)
                            Then VSDGDTINI  =BlankDate()
                                 VSDGDTFIM  =BlankDate()
                                 Campo="TG_CODMODELO"
                            Else Campo="TG_FAMI"
                         EndIf
                    Case Campo="TG_FAMI"        : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"        : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA"  : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   : Campo = "YES" 
                         
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO="" 
  Case Campo="":
     MSG_CAMPO="" 
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

Proc LimpaCamposTag(Tipo)

Switch
    Case Tipo="Todos":
    VSDGEMPRESA    = ""
    VSDGNOMEMP     = ""     
    VSDGCORTE      = ""
    VSDGDTINI      = BlankDate()
    VSDGDTFIM      = BlankDate()
    VSDGFAMI       = ""
    VSDGNOMFAMI    = ""
    VSDGMARCA      = ""
    VSDGNOMMARCA   = ""
    VSDGREFERENCIA = ""
EndSwitch

EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

sys_Valor()

LimpaCamposTag("Todos")

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Extrato das Programa‡”es - Corte" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 19 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Corte"  For "TG_CORTE"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_CORTE" To VSDGCORTE
    Accept @ 03,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMCORTE" To VSDGNOMCORTE
    
    Label  @ 04,00 "Familia"  For "TG_FAMI"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI" To VSDGFAMI
    Accept @ 05,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI
 
    Label  @ 06,00 "Marca"  For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 07,09 Width 25 "A22" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 08,00 "Item"  For "TG_ITEM"
    Accept @ 09,01 Width 33 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 10,01 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM"  To VSDGNOMITEM

    Label  @ 00,35 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 01,36 Width 33 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 02,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 12,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 13,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 13,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 15,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGCORTE) And VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")

  Tabela = Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Faccao\\Rm_0201" Tabela
  
  Seleciona()

  If Not IsEmpty(Tabela)
     Then
          Switch
            Case VSDGCODMODELO="01": 
              Sort Tabela On "Codigo da Empresa","Numero_Programacao_Corte","Referencia","Codigo do Item","Data_Producao",
                             "Tipo Movimento","Numero_Producao_Corte"
              IMPRIREL(Tabela,"R")
                                  
            Case VSDGCODMODELO="02": 
              Sort Tabela On "Codigo da Empresa","Data_Programacao","Numero_Programacao_Corte","Referencia","Codigo do Item","Data_Producao",
                             "Tipo Movimento","Numero_Producao_Corte"
              IMPRIREL(Tabela,"1")
                                  
            Case VSDGCODMODELO="03" or
                 VSDGCODMODELO="04":
                 
              Delete Tabela
              Sort "Answer" On "Codigo da Empresa","Referencia","Codigo do Item","Data_Producao","Tipo Movimento","Numero_Producao_Corte" to Tabela
              CopyReport "\\Base\\Sistemas\\Faccao\\RM_0201" "2" Tabela "2"
              IMPRIREL(Tabela,"2")
              
          EndSwitch
     Else MENSAGEM("N„o existem registros a processar")
  EndIf

  if isTable(Tabela)   then Delete Tabela   EndIf
  if isTable("Answer") then Delete "Answer" EndIf

EndWhile
ClearAll
Release Vars All
Release Procs All

