;** Rm_0080 ********************************************************************
;*  Emissao dos Titulos a Receber por Cliente                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 28/11/2011 por Karina Andrade
;Motivo Alteracao: Add op‡Æo ordem de impressÆo
;Ultima Alteracao: 18/12/2013 por Andrey Fillipe
;Motivo Alteracao: Inclusao de data media
;Ultima Alteracao: 21/01/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado Modelo Com Saldo anterior Report RM_1000a "2"
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT
;Ultima Alteracao: 16/05/2017 por Rafael Matos
;Motivo Alteracao: Ajustes Modelos de Relat¢rio e InclusÆo Modelo Ranking/Sint‚tico
;Ultima Alteracao: 17/05/2017 por Rafael Matos
;Motivo Alteracao: Ajustes Modelos de Relat¢rio e InclusÆo Modelo Ranking/Sint‚tico/Valor Original
;Ultima Alteracao: 19/05/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: inclusao filtro representante                   
;Ultima Alteracao: 07/07/2017 por Bruno Carvalho
;Motivo Alteracao: Ajustes se VSDGREPRESEN="" e/ou VSDGGERENCIA="", Sol. 30710
;                  Registros com representante em branco nÆo estavam sendo exibidos
;Ultima Alteracao: 04/01/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modelo analitico             
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
 
;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona(PARAM)
Private PARAM
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then If VSDGGERENCIA<>""
          Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
               Moveto [Codigo do Representante] Example "crep"
               Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
       EndIf
       {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       If VSDGOPSIT = "2" 
          Then Moveto [Codigo do Destinatario] Example "cod" TypeIn " ,~VSDGDESTINAT.."
          Else Moveto [Codigo do Destinatario] TypeIn "~VSDGDESTINAT.."
       EndIf                      
       Switch
         Case VSDGGERENCIA<>"" : Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
         Case VSDGREPRESEN<>"" : Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
       Endswitch  
       If PARAM = 2
          Then If Not IsBlank(VSDGDTINI)
                  Then Moveto [Data de Vencimento    ] TypeIn "<~VSDGDTINI"
               EndIf
          Else Moveto [Data de Vencimento    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       EndIf
       Moveto [Saldo do Documento    ] TypeIn "> 0.01"
       Moveto [Tipo do Lancamento    ] TypeIn "~VSDGTPCART.."
       If VSDGOPSIT="2"
          Then If IsTable("\\Sistemas\\Cadastro\\"+Dir_Trab+"Destinat")
                  Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
                       Moveto [Codigo             ] Example "cod"
                       Moveto [Situacao do Cliente] TypeIn "PESSIMO"
               EndIf
       EndIf
       Do_It!
       ClearAll
EndIf

If VSDGOPSIT="3"
   Then If IsTable("\\Sistemas\\Cadastro\\"+Dir_Trab+"Destinat")
          Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
               Moveto [Codigo             ] Example "cod"
               Moveto [Situacao do Cliente] TypeIn "PESSIMO"
               {Ask} {Answer} TypeIn "Fast Delete"
               Moveto [Codigo do Destinatario] Example "cod"
               Do_It!
               ClearAll
        EndIf
EndIf

If PARAM = 2 And Not IsEmpty("Answer") and VSDGCODMODELO="05" 
   Then {Ask} TypeIn Tabela Enter
        Moveto [Valor da Comissao] TypeIn "Changeto 0.00"
        Do_It!
        ClearAll
   
        If Not IsBlank(VSDGDTINI)
           Then Processa("Answer")
   
                {Ask} {Answer}
                Moveto [Codigo do Destinatario] Check
                Moveto [Valor do Documento    ] TypeIn "Calc Sum as Valor do Documento"
                Do_It!
                ClearAll
                
                {Ask} {Answer}
                Moveto [Codigo do Destinatario] Check Example "a"
                Moveto [Valor do Documento    ] Check
                {Ask} TypeIn Tabela Enter
                Moveto [Codigo do Destinatario] Example "a"
                Do_It!
                ClearAll
                
                
                View Tabela
                Coedit "Answer"
                Scan
                  COD = [Codigo do Destinatario]
                  
                  Moveto Tabela
                  Moveto [Codigo do Destinatario]
                  Locate COD
                  If RetVal
                     Then [Valor da Comissao] = [Answer->Valor do Documento]
                  EndIf    
                
                  Moveto "Answer"
                EndScan
                Do_It!
                ClearAll
        EndIf             
EndIf   

Release Vars PARAM
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar os Vencimentos                                         *
;*******************************************************************************
Proc Selecionav()

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa     ] Check
Moveto [Codigo do Destinatario] Check
Moveto [Data de Vencimento    ] TypeIn "Calc Average as Data de Vencimento"

Do_It!
ClearAll

View "Answer"
Coedit Tabela
Scan
  CODEMP = [Codigo da Empresa]
  CODDES = [Codigo do Destinatario]
  
  Moveto "Answer"
  Moveto [Codigo da Empresa]
  Locate CODEMP,CODDES
  If RetVal
     Then  Moveto Tabela 
           Moveto [Data Limite Desconto]
           []=[Answer->Data de Vencimento]
           UnLockRecord
  EndIf
EndScan
Do_It!
ClearAll

EndProc   ; (Selecionav)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa(TabelaRef)
Private TabelaRef

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn TabelaRef Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit TabelaRef
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=Round((([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100),2)
      Else VRJUROS=Round((([Valor de Juros]/[NDias Taxa de Juros])*NDA),2)
           VRJUROS=VRJUROS+Round((([Saldo do Documento]*TXM)/100),2)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll

Release Vars TabelaRef
EndProc     ; (Processa)

;*******************************************************************************
;* Rotina p/ Somar os Valores                                                  *
;*******************************************************************************
Proc SelecionaTot()

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check Example "codemp"
Moveto [Codigo do Destinatario ] Check
Moveto [Valor do Documento     ] TypeIn "Calc Sum as Valor do Documento"
Moveto [Saldo do Documento     ] TypeIn "Calc Sum as Saldo do Documento"
Moveto [Valor do Desconto      ] TypeIn "Calc Sum as Valor do Desconto"
{Ask} {\\sistemas\\cadastro\\destinat}
Moveto [Codigo                 ] Example "codemp"
Moveto [Razao Social           ] Check TypeIn "as Nome Fantasia Empresa"
Do_It!
ClearAll

{Ask} {Answer} Check
Moveto [Codigo do Destinatario] Example "cod"
{Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
Moveto [Codigo                 ] Example "cod"
Moveto [Razao Social           ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Cidade                 ] Check
Moveto [UF                     ] Check
Do_It!
ClearAll
    
Delete Tabela

Rename "Answer" Tabela

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Anal¡tico")
ModeloRelatoriosAdd("02  Sint‚tico")
ModeloRelatoriosAdd("03  Ranking/Sint‚tico")
ModeloRelatoriosAdd("04  Ranking/Sint‚tico/Valor Original")
ModeloRelatoriosAdd("05  Com Saldo Anterior")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_DESTINAT"      : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_OPSIT"         : Campo="TG_DDPROTESTO"
            Case Campo="TG_TPCART"        : Campo="TG_OPSIT"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_TPCART"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPRELCODALF"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"      : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"      : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"      : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO"    : Campo="TG_OPSIT"
                    Case Campo="TG_OPSIT"         : Campo="TG_TPCART"
                         VSDGOPSIT=ControlValue("TG_OPSIT")
                         Switch
                           Case VSDGOPSIT="2": VSDGNOMOPSIT="PESSIMA"
                           Case VSDGOPSIT="3": VSDGNOMOPSIT="BOA/REGULAR"
                           otherwise         : VSDGNOMOPSIT="TODAS" 
                                               VSDGOPSIT="1"
                         EndSwitch
                    Case Campo="TG_TPCART"        : Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF"   : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
     MSG_CAMPO="Informe o Numero de Dias"
  Case Campo="TG_OPSIT":
       MSG_CAMPO="1- Todas  2- Pessima  3- Boa/Regular"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA      = ""
VSDGDESTINAT     = ""
VSDGTPCART       = ""
VSDGDDPROTESTO   = ""
VSDGDTINI        = BlankDate()
VSDGDTFIM        = BlankDate()
VSDGOPSIT        = ""
VSDGNOMOPSIT     = ""
VSDGMODELOREL    = ""
VSDGNOMMODELOREL = ""
VSDGREPRESEN     = ""
VSDGGERENCIA     = ""

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Titulos a Receber por Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 06,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
               
    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Op‡„o Cliente" For "TG_OPSIT"
    Accept @ 03,39 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPSIT" To VSDGOPSIT
    Accept @ 03,44 Width 25 "A11"  Picture "!*!" Tag "TG_NOMOPSIT" To VSDGNOMOPSIT

    Label  @ 04,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 05,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 05,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART
    
    Label  @ 06,35 "Ordem" For "TG_OPRELCODALF"
    Accept @ 07,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 07,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona(1)
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa(Tabela)
  Selecionav()
  
  If VSDGCODMODELO="03" or  VSDGCODMODELO="04"
     Then SelecionaTot()
  EndIf   

  If VSDGCODMODELO="05"
     then Seleciona(2)
  EndIf
  
  Switch
    Case VSDGCODMODELO="01":
         CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "12" Tabela "R"
         If VSDGOPRELCODALF="1"
            Then Seta_Ordem_Report(Tabela,"R","Codigo do Destinatario","Codigo do Destinatario","") 
            Else Seta_Ordem_Report(Tabela,"R","Codigo do Destinatario","Razao Social","") 
         EndIf
    Case VSDGCODMODELO="02":
         If VSDGOPRELCODALF="1"
            Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001" "5"  Tabela "R"
            Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001" "14" Tabela "R"
         EndIf 
    Case VSDGCODMODELO="03": CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1004" "1"  Tabela "R" 
                             Sort Tabela On "Valor do Documento" D
    Case VSDGCODMODELO="04": CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1004" "2"  Tabela "R" 
                             Sort Tabela On "Saldo do Documento" D                      
    Case VSDGCODMODELO="05": CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000a" "2" Tabela "R" 
    
  EndSwitch
  
  IMPRIREL(Tabela,"R")

  Delete Tabela
  
EndWhile
ClearAll
Release Vars All
Release Procs All
