;** Rm_0040  *******************************************************************
;* Relacao de Notas Fiscais - Produto                                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 06/09/2004 por Jos‚ Lu¡s Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 23/06/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Opcao Item+Cor
;Ultima Alteracao: 01/12/2010 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo no Relat¢rio para Inbec (00193)
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 07/10/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado Coluna Vended. no report RM_2000 "3" e RM_2000 "10"
;Ultima Alteracao: 18/08/2016 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo de REPORT, de RM_2000 "3" e "10" -> RM_1999 "R" e "1"
;Ultima Alteracao: 27/10/2016 por Rafael Matos
;Motivo Alteracao: Ajustes Layout para padroniza‡Æo  
;Ultima Alteracao: 10/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT              
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustado ASK p/ check apenas nos campos utilizados no REPORT e criado um REPORT com a estutura utilizada
;Ultima Alteracao: 08/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes logica         
;Ultima Alteracao: 14/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novo report e altera‡Æo estrutura tabela report
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Seleciona Registros                                                         *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
         Moveto [Codigo da Empresa         ] Check Example "Empresa" TypeIn ", ~VSDGEMPRESA.."
         Moveto [Numero do Documento       ] Check Example "Docto"
         Moveto [Serie do Documento        ] Check Example "Serie"
         Moveto [Nome Fantasia Empresa     ] Check
         Moveto [Codigo                    ] Check TypeIn "~VSDGDESTINAT.." 
         Moveto [Razao Social              ] Check
         Moveto [Data de Emissao           ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
         Moveto [Codigo da Destinacao      ] TypeIn "~VSDGDESTIN.."  
         Moveto [Descricao da Destinacao   ] Check
         Moveto [Descricao CondPagto       ] Check
         Moveto [Composicao de Dias        ] Check
         Moveto [Codigo do Representante   ] Check
         Moveto [Situacao                  ] TypeIn "Not C"
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"Notai" Enter 
         Moveto [Codigo da Empresa      ] Example "Empresa"
         Moveto [Numero do Documento    ] Example "Docto"
         Moveto [Serie do Documento     ] Example "Serie"
         Moveto [Codigo do Item         ] Check TypeIn "~VSDGITEM.."
         Moveto [Descricao do Item      ] Check
         Moveto [Unidade Fiscal         ] Check
         Moveto [Quantidade             ] Check
         Moveto [Preco Unitario         ] Check
         Moveto [Preco Total            ] Check
         Moveto [Valor Desconto Total   ] Check
         Moveto [Codigo da Cor_Tecido   ] Check
         Moveto [Descricao da Cor_Tecido] Check
         Moveto [Informacoes_Adicionais ] Check
         Moveto [Situacao_Item          ] TypeIn "Not C"
         If SYS_CODIGO_CLIENTE = "0193"
            Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV" Enter 
                 Moveto [Codigo da Empresa      ] Example "Empresa"
                 Moveto [Numero do Documento    ] Example "Docto"
                 Moveto [Serie do Documento     ] Example "Serie"
                 Moveto [Forma de Pagamento     ] TypeIn  "Not OU"
                 Moveto [Sequencia              ] TypeIn  "01" 
         EndIf
         Do_It!
         ClearAll

         {Ask} {Answer} Check
         Moveto [Codigo do Item ] Example "CodI"
         {Ask} {\\Sistemas\\Estoque\\Itens} 
         Moveto [Codigo do Item ] Example "CodI"
         Moveto [Codigo da Grade] Check
         Do_It!
         ClearAll

         If IsTable("Answer") 
            Then {Modify} {Restructure} {Answer}
                 Moveto [Field Name]
                 Locate "Informacoes_Adicionais"
                 If RetVal
                    Then Right CtrlBackSpace "A255" Enter
                 EndIf
                 Do_it!
                 
                 if MenuChoice()="Trimming" then {Trimming} endif
 
                 ClearAll 
                 Adiciona_Dados_Tabela(Tabela)
         EndIf      

EndIf

EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESA"
            Case Campo="TG_DESTIN"        : Campo="TG_DESTINAT"
            Case Campo="TG_ITEM"          : Campo="TG_DESTIN"
            Case Campo="TG_DTINI"         : Campo="TG_ITEM"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"   :Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"  :Campo="TG_DESTIN"
                    Case Campo="TG_DESTIN"    :Campo="TG_ITEM"
                    Case Campo="TG_ITEM"      :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"     :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"     :Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
       MSG_CAMPO=""
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Destinatario,Codigo do Item")
ModeloRelatoriosAdd("02  Por Destinatario,Codigo do Item,Cor")
ModeloRelatoriosAdd("03  Por Destinatario,Codigo do Item,Descri‡Æo,Inf.Adicionais")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
SYS_VALOR()

VSDGEMPRESA =""
VSDGDESTINAT=""
VSDGDESTIN  =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Rela‡„o Notas Fiscais por Produto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 19 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 04,00 "Destinacao"  For "TG_DESTIN"
    Accept @ 05,01 Width 07 "A3"  Picture "#*#" Tag "TG_DESTIN"    To VSDGDESTIN
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMDESTIN" To VSDGNOMDESTIN

    Label  @ 06,00 "Item"  For "TG_ITEM"
    Accept @ 07,01 Width 33 "A10"  Picture "#*#" Tag "TG_ITEM"    To VSDGITEM
    Accept @ 08,01 Width 33 "A30" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 09,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 10,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 10,16 "at‚" For "TG_DTFIM"
    Accept @ 10,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 12,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 13,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 13,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 15,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Vendas\\Rm_1999" Tabela
  Empty(Tabela)

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  Switch
    case VSDGCODMODELO="01"  : IMPRIREL(Tabela,"R")
    case VSDGCODMODELO="02"  : IMPRIREL(Tabela,"1")
    case VSDGCODMODELO="03"  : IMPRIREL(Tabela,"2")
  endSwitch
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
