;** Rm_0025  *******************************************************************
;*  Emissao dos Titulos a Pagar por Data de Entrada                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 07/08/2003 por Karen Lauar Nery
;Ultima Alteracao: 01/03/2005 por Davi Pereira Carrano
;Motivo Alteracao: Corre‡Æo das Ask para liberar tabelas quando se usa Fast Insert
;Ultima Alteracao: 08/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 14/12/2009 por Cleber Alves
;Motivo Alteracao: Alteracao Data_Inclusao
;Ultima Alteracao: 23/03/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 23/08/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro "Tipo de Pagamento","Emitente" e adicionado novo modelo
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog 
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT   
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()                 
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 15/08/2017 por Bruno Carvalho
;Motivo Alteracao: Alterado OPCHEQ="S" p/ CheckTG_OPCHEQ[1]  *OPCHEQ nÆo estava sendo setada
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
       Moveto [Codigo            ] Example "CodE"
       {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo do Emitente] Example "CodE" TypeIn ", ~VSDGDESTINAT.."
       Moveto [Tipo do Pagamento ] TypeIn "~VSDGTPPAGTO.."
       Moveto [Data_Inclusao     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       Do_it!
       ClearAll
EndIf
EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc Seleciona2()
If not CheckTG_OPCHEQ[1]
   Then Return
EndIf

{Ask} {\\sistemas\\ctacor\\MovCont}
Moveto [Numero do Lancamento  ] CheckPlus
Moveto [Codigo da Conta       ] CheckPlus
Moveto [Descricao da Conta    ] CheckPlus
Moveto [Codigo da Empresa     ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Nome Fantasia Empresa ] CheckPlus
Moveto [Tipo Movimento        ] TypeIn "S"
Moveto [Tipo de Operacao      ] TypeIn "05"
Moveto [Valor                 ] CheckPlus
Moveto [Codigo do EmitDest    ] CheckPlus
Moveto [Nome Fantasia EmitDest] CheckPlus
Moveto [Razao Social          ] CheckPlus
Moveto [Codigo do Documento   ] CheckPlus
Moveto [Tipo do Documento     ] CheckPlus
Moveto [Serie do Documento    ] CheckPlus
Moveto [Numero do Documento   ] CheckPlus
Moveto [Numero do Cheque      ] CheckPlus
Moveto [Serie do Cheque       ] CheckPlus
Moveto [Cheque Pre-Datado     ] TypeIn "S"
Moveto [Data Cheque Descontado] TypeIn "Blank"
Moveto [Data                  ] CheckPlus
Moveto [Data Cheque Pre-Datado] CheckPlus TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero do Lancamento  ] Example "lanc"
Moveto [Codigo da Conta       ] Example "cont"
Moveto [Descricao da Conta    ] Example "dcont"
Moveto [Codigo da Empresa     ] Example "cod"
Moveto [Nome Fantasia Empresa ] Example "ncod"
Moveto [Valor                 ] Example "vr"
Moveto [Codigo do EmitDest    ] Example "cemi"
Moveto [Nome Fantasia EmitDest] Example "nemi"
Moveto [Razao Social          ] Example "emit"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tpdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Numero do Cheque      ] Example "numc"
Moveto [Serie do Cheque       ] Example "serc"
Moveto [Data                  ] Example "data"
Moveto [Data Cheque Pre-Datado] Example "dat"

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero do Lancamento  ] Example "lanc"
Moveto [Codigo da Conta       ] Example "cont"
Moveto [Descricao da Conta    ] Example "dcont"
Moveto [Codigo da Empresa     ] Example "cod"
Moveto [Nome Fantasia Empresa ] Example "ncod"
Moveto [Codigo do Emitente    ] Example "cemi"
Moveto [Nome Fantasia EmitDest] Example "nemi"
Moveto [Razao Social          ] Example "emit"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tpdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Valor do Documento    ] Example "vr"
Moveto [Saldo do Documento    ] Example "vr"
Moveto [Data_Inclusao         ] Example "dat"
Moveto [Data de Emissao       ] Example "data"
Moveto [Data a Pagar          ] Example "dat"
Moveto [Tipo do Lancamento    ] TypeIn "0"
Moveto [Descricao do Lancamento] TypeIn "_numc+"+"\" - \"+"+"_serc"
Do_It!
ClearAll

CoEdit Tabela
Scan
  If [Tipo do Lancamento     ]="0"
     Then [Observacoes       ]=[Descricao do Lancamento]
     Else [Tipo do Lancamento]=""
  EndIf
EndScan
Do_It!

ClearAll

EndProc  ; (Seleciona2)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
   If [Data a Pagar]<Today() And Not IsBlank([Data a Pagar])
      Then NDA=Today()-[Data a Pagar]
           TXM=[Multa]
      Else NDA=0
           TXM=0
   EndIf
   If [Data Limite Desconto] >= Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)
   [Data de Vencimento]=[Data a Pagar]
EndScan
Do_It!
ClearAll
EndProc   ; (Processa)

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Modelo A")
ModeloRelatoriosAdd("02  Modelo B")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT" 
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_TPPAGTO"       : Campo="TG_DTFIM"
            Case Campo="TG_OPCHEQ"        : Campo="TG_TPPAGTO"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPCHEQ"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"   : Campo="TG_DESTINAT" 
                    Case Campo="TG_DESTINAT"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"     : Campo="TG_OPCHEQ"
                    Case Campo="TG_OPCHEQ"      : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog                             
   EndSwitch
EndIf
Switch
  Case Campo="" :
       MSG_CAMPO="" 
  Case Campo="TG_OPCHEQ":
       MensagemCheckBoxes()
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGDESTINAT=""
VSDGTPPAGTO =""
VSDGOPRELCODALF=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

Array TG_OPCHEQ[1]
TG_OPCHEQ[1]="Incluir os nÆo apresentados"

Array CheckTG_OPCHEQ[ArraySize(TG_OPCHEQ)]
CheckTG_OPCHEQ[1]=False

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos … Pagar por Data Entrada" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 09,12   Height 14 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP               
                                                                                              
    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 01,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 01,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO
    
    Label  @ 02,35 "Cheques Emitidos como Pr‚-Datados" For "TG_OPCHEQ"
    CheckBoxes @ 03,35 Height 1 Width 33 Tag "TG_OPCHEQ"
    TG_OPCHEQ[1] to CheckTG_OPCHEQ[1]

    Label  @ 07,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 08,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 08,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 10,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  Seleciona2()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  Switch 
    Case VSDGCODMODELO="01" : 
         If CheckTG_OPCHEQ[1]
            Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1010" "5" Tabela "R"
            Else CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1010" "6" Tabela "R"
         EndIf
    Case VSDGCODMODELO="02" :
         If CheckTG_OPCHEQ[1]
            Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1011" "R" Tabela "R"
            Else CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1011" "1" Tabela "R"
         EndIf
  EndSwitch   
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
