;** Rm_0080 ********************************************************************
;*  Sintetico II p/ Centro de Custo                                            *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 05/11/96 por Anivel Augusto Rodrigues
;Ultima Alteracao: 01/03/2005 por Davi Pereira Carrano
;Motivo Alteracao: Corre‡Æo das Ask para liberar tabelas quando se usa Fast Insert
;Ultima Alteracao: 08/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 12/01/2010 por Cleber Alves
;Motivo Alteracao: Alteracao da Ask p/ Rateio
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()
;Ultima Alteracao: 10/05/2017 por Rafael Matos
;Motivo Alteracao: Incluso TG_OPCCUSTO                  
;Ultima Alteracao: 02/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Sequencia da Baixa TitRat        

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."   
       Moveto [Data a Pagar          ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       Moveto [Saldo do Documento    ] TypeIn "> 0.01"
       Do_It!
       ClearAll
       
       {Ask} "TitRat" Enter
       Moveto [Numero do Lancamento] example "NumLan"        
       {Ask} "Answer" Enter TypeIn "Delete"
       Moveto [Numero do Lancamento] example "NumLan" 
       Moveto [Sequencia da Baixa  ] TypeIn "0"
       Do_It!
       ClearAll
       
       Primeirav="******"
       Coedit "Answer","TitRat","Deleted"
       Scan
         If [Numero do Lancamento]<>Primeirav 
            then Primeirav = [Numero do Lancamento] 
                 CopyToArray Array_Del      
                 Moveto "TitRat"
                 Moveto [Numero do Lancamento]
                 Locate [deleted->Numero do Lancamento],"0"
                 If RetVal             
                    Then While [Numero do Lancamento]=[Deleted->Numero do Lancamento] and
                               [Sequencia da Baixa  ]="0"
                           Moveto "Answer"
                           End Down
                           CopyFromArray Array_del
                           [Codigo Plano_Conta   ]=[TitRat->Codigo Plano_Conta   ]
                           [Descricao Plano_Conta]=[TitRat->Descricao Plano_Conta] 
                           [Codigo CCusto        ]=[TitRat->Codigo CCusto        ]
                           [Descricao CCusto     ]=[TitRat->Descricao CCusto     ]
                         
                           If [Valor do Documento]<>[Saldo do Documento]
                              Then [Saldo do Documento]=(([TitRat->Valor]*[Saldo do Documento])/[Valor do Documento]) 
                                   [Valor do Documento]=[Saldo do Documento ]                            
                              Else [Saldo do Documento]=[TitRat->Valor]
                           EndIf   
                           [Valor do Documento]=[Saldo do Documento ]                            
                           UnLockRecord                           
                           Moveto "TitRat"      
                           Skip
                           If EOT() Then QuitLoop EndIf
                         EndWhile
                 EndIf  
                 Moveto "Deleted"  
         EndIf       
       EndScan
       Do_It!
       ClearAll
       
       {Ask} {Answer} check
       If CheckTG_OPCCUSTO[1]
          Then Moveto [Codigo CCusto          ] TypeIn "Not Blank, ~VSDGCCUSTO.."
          Else Moveto [Codigo CCusto          ] TypeIn "~VSDGCCUSTO.."
       Endif     
       Do_It!
       ClearAll

       {Ask} {Answer}
       Moveto [Codigo da Empresa     ] Example "CE"
       Moveto [Nome Fantasia Empresa ] Example "NFE"
       Moveto [Data a Pagar          ] Example "DT"
       Moveto [Saldo do Documento    ] Example "VR"
       Moveto [Codigo CCusto         ] Example "CC"
       Moveto [Descricao CCusto      ] Example "DC"
       Moveto [Codigo do Emitente    ] Example "CED"
       Moveto [Nome Fantasia EmitDest] Example "NFED"
       Moveto [Tipo do Documento     ] Example "TIPO"
       Moveto [Numero do Documento   ] Example "NUMERO"

       {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
       Moveto [Codigo da Empresa     ] Example "CE"
       Moveto [Nome Fantasia Empresa ] Example "NFE"
       Moveto [Data                  ] Example "DT"
       Moveto [Valor                 ] Example "VR"
       Moveto [Codigo CCusto         ] Example "CC"
       Moveto [Descricao CCusto      ] Example "DC"
       Moveto [Codigo do EmitDest    ] Example "CED"
       Moveto [Nome Fantasia EmitDest] Example "NFED"
       Moveto [Descricao do Historico] TypeIn "\"PG \"+" Example "TIPO" TypeIn "+\"/\"+" Example "NUMERO"
       Do_It!
       ClearAll
EndIf
EndProc ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

CoEdit Tabela
Scan For Not IsBlank([Codigo CCusto])
   [Codigo CCusto1]=SubStr([Codigo CCusto],1,4)+"000"
EndScan
Do_It!
ClearAll
EndProc   ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_CCUSTO"        : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"         : Campo="TG_CCUSTO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPCCUSTO"        : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     :Campo="TG_CCUSTO"
                    Case Campo="TG_CCUSTO"      :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_OPCCUSTO"
                    Case Campo="TG_OPCCUSTO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_OPCCUSTO":
     MensagemCheckBoxes()
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGCCUSTO  =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
Array TG_OPCCUSTO[1]
TG_OPCCUSTO[1]="Ignorar em Branco"

Array CheckTG_OPCCUSTO[ArraySize(TG_OPCCUSTO)]
CheckTG_OPCCUSTO[1]=False

While True
  ShowDialog "T¡tulos   Pagar Sint‚tico II por Centro de Custo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 12 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Centro de Custo" For "TG_CCUSTO"
    Accept @ 03,01 Width 33 "A7"  Picture "###.###" Tag "TG_CCUSTO" To VSDGCCUSTO
    Accept @ 04,01 Width 33 "A20" Picture "!*!" Tag "TG_NOMCUST"  To VSDGNOMCUST
    
    Label  @ 05,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 06,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 06,16 "at‚" For "TG_DTFIM"
    Accept @ 06,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Centro de Custo"  For "TG_OPCCUSTO"
    CheckBoxes @ 01,35 Height 1 Width 35 Tag "TG_OPCCUSTO"
    TG_OPCCUSTO[1] to CheckTG_OPCCUSTO[1]
                   
    Pushbutton @ 08,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 08,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\CtaPag\\Rm_0060" Tabela
  Empty Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  CCUSTO=""
  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  IMPRIREL(Tabela,"2")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
