;** Rm_0200 ********************************************************************
;*  Emissao do Extrato/Programacoes                                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 28/03/2007 por Anivel Augusto Rodrigues
;Ultima Alteracao: 28/01/2011 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo por C¢digo do Cliente "Situa‡Æo da Programa‡Æo"
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW
;Ultima Alteracao: 13/05/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro por Numero do Corte
;Ultima Alteracao: 17/11/2014 por Luis Gustavo
;Motivo Alteracao: Implementado CheckBox. "Apenas Produ‡äes do Per¡odo"
;Ultima Alteracao: 11/12/2014 por Luis Gustavo
;Motivo Alteracao: Retirado implementa‡Æo CheckBox. "Apenas Produ‡äes do Per¡odo"
;Ultima Alteracao: 16/12/2014 por Luis Gustavo
;Motivo Alteracao: Implementado para pegar toda a produ‡Æo da confec‡Æo, assim como a programa‡Æo da confec‡Æo
;Ultima Alteracao: 31/12/2014 por Andrey Fillipe
;Motivo Alteracao: Corrigido navegacao com Enter nos campos
;Ultima Alteracao: 13/01/2015 por Anivel/Kamila/Andrey
;Motivo Alteracao: Adicionado Filtro Producao do Corte
;Ultima Alteracao: 24/02/2015 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Novo ShowDialog/Ask/Report
;Ultima Alteracao: 12/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Ask quantidade programada e quantidade produzida, relatorio por item
;Ultima Alteracao: 13/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes l¢gica e reports           
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog    
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT               
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 31/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nova logica e ajustes reports 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

;-- Filtro Programa‡Æo evolvidas ------------------------------------------------
Switch
  Case VSDGNPRODCORTE<>"": 
       {Ask} {Pfacri}
       Moveto [Numero_Programacao      ] Check 
       Moveto [Data_Programacao        ] Check
       Moveto [Numero_Producao_Corte   ] TypeIn "~VSDGNPRODCORTE.."
       Do_It!
       ClearAll
        
  Case VSDGNPROG<>"": 
       {Ask} {Pfacc}
       Moveto [Numero_Programacao      ] Check TypeIn "~VSDGNPROG.."
       Moveto [Data_Programacao        ] Check
       Do_It!
       ClearAll

  Case VSDGCORTE<>"": 
       {Ask} {Pfacc}
       Moveto [Numero_Programacao      ] Check
       Moveto [Data_Programacao        ] Check
       Moveto [Numero_Corte            ] TypeIn "~VSDGCORTE.."
       Do_It!
       ClearAll

  OtherWise:
       {Ask} {Pfacc} 
       Moveto [Numero_Programacao      ] Check
       Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA.."
       Moveto [Data_Programacao        ] check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       If VSDGOPDEST<>"TODOS" 
         Then Moveto [Destino_Producao      ]
              If VSDGOPDEST="INTERNO + FACCAO"
                 Then TypeIn "INTERNO Or FACCAO"
                 Else TypeIn "~VSDGOPDEST" 
              EndIf
       EndIf
       Moveto [Codigo                  ] TypeIn "~VSDGDESTINAT.."
       Moveto [Situacao_Programacao  ]
       switch
         case VSDGSITUACAOFAC<>"TODAS"                     : TypeIn "~VSDGSITUACAOFAC.."
       endswitch
       Do_It!
       ClearAll

EndSwitch
TabelaRC=Adiciona_Indice_Temp("Numero_Programacao")

;-- Programa‡Æo ----------------------------------------------------------------
AGUARDE("Aguarde, Processando Programa‡Æo Corte")
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEN"
Moveto [Referencia            ] TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ] TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ] TypeIn "~VSDGMARCA.."
{Ask} TypeIn TabelaRC Enter
Moveto [Numero_Programacao    ]       Example "nprog"
{Ask} {Pfacc} 
Moveto [Numero_Programacao    ]       Example "nprog"  
Moveto [Data_Programacao      ] Check
{Ask} {PfacRI}
Moveto [Numero_Programacao    ] check Example "nprog"  
Moveto [Codigo do Item        ] check Example "ITEN" TypeIn ", ~VSDGITEM.."
Moveto [Quantidade Programada ]                      TypeIn "Calc Sum as \"Quantidade Programada\""
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

Adiciona_Campo(Tabela,"Tipo Movimento(A1),Numero_Producao(A6),Data_Producao(D),Quantidade Produzida(N),Saldo(N)")

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Tipo Movimento          ] typein "changeto 0"
Moveto [Data_Programacao        ] typein "_dtprog"
Moveto [Data_Producao           ] typein "changeto _dtprog"
Moveto [Numero_Programacao      ] typein "_numprg"
Moveto [Numero_Producao         ] typein "changeto _numprg"
Do_It! 
ClearAll

;-- Produ‡Æo -------------------------------------------------------------------
AGUARDE("Aguarde, Processando Produ‡Æo Corte")
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item          ] Example "ITEN"
Moveto [Referencia              ] TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia       ] TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca         ] TypeIn "~VSDGMARCA.."
{Ask} TypeIn TabelaRC Enter
Moveto [Numero_Programacao      ] Check Example "nprog"
Moveto [Data_Programacao        ] Check
{Ask} {Rfacc}
Moveto [Numero_Producao         ] check Example "num"
Moveto [Numero_Programacao      ]       Example "nprog"
Moveto [Data_Producao           ] check
{Ask} {RfacRI}
Moveto [Numero_Producao         ]       Example "num"
Moveto [Codigo do Item          ] check Example "ITEN" TypeIn ", ~VSDGITEM.."
Moveto [Quantidade Produzida    ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero_Programacao      ] Example "numprg"
Moveto [Numero_Producao         ] Example "numprd"
Moveto [Data_Programacao        ] example"_dtprog"
Moveto [Data_Producao           ] Example "dtprod"
Moveto [Codigo do Item          ] Example "item"
Moveto [Quantidade Produzida    ] Example "qtde"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero_Programacao      ] Example "numprg"
Moveto [Tipo Movimento          ] typein "1"
Moveto [Numero_Producao         ] Example "numprd"
Moveto [Data_Programacao        ] example"_dtprog"
Moveto [Data_Producao           ] Example "dtprod"
Moveto [Codigo do Item          ] Example "item"
Moveto [Quantidade Produzida    ] Example "qtde"
Do_It! 
ClearAll

Delete TabelaRC

;-- Ajustando Dados ------------------------------------------------------------
AGUARDE("Aguarde, Ajustando dados")

Switch
  Case VSDGCODMODELO="04" or
       VSDGCODMODELO="06":

    LimpaRodape(0)
    
    NR=NRecords(Tabela)
    
    View NoWindow Tabela
    EditKey
    Scan  
      Barra(NR, RecNo())
      Aguarde("Aguarde, agrupando itens "+BARRA_STRING)
      
      [Codigo do Item]=PegaCodigoRaiz([Codigo do Item])
    EndScan
    Do_It!
    ClearAll
    
    LimpaRodape(0)

endSwitch

;-- Totalizando ----------------------------------------------------------------
AGUARDE("Aguarde, Totalizando dados")

Switch
  Case VSDGCODMODELO="01":
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Programacao      ] check 
    Moveto [Data_Programacao        ] check
    Moveto [Tipo Movimento          ] check
    Moveto [Numero_Producao         ] check 
    Moveto [Data_Producao           ] check
    Moveto [Codigo do Item          ] Check
    Moveto [Quantidade Programada   ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida    ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Saldo                   ]       TypeIn "Calc Sum as \"Saldo\""
    Do_It!
    ClearAll
    
    {Ask} {Pfacc}
    Moveto [Numero_Programacao      ] Example "num"
    Moveto [Codigo da Empresa       ] Check
    Moveto [Nome Fantasia Empresa   ] Check
    Moveto [Destino_Producao        ] Check
    Moveto [Codigo                  ] Check
    Moveto [Razao Social            ] Check
    Moveto [Numero_Corte            ] Check
    Moveto [Situacao_Programacao    ] Check
    Moveto [Observacoes             ] Check
    {Ask} {Answer} Check
    Moveto [Numero_Programacao      ] Example "num"
    Do_It!
    ClearAll

  Case VSDGCODMODELO="03" or VSDGCODMODELO="04" : 
    {Ask} {Pfacc}
    Moveto [Numero_Programacao      ] Example "num"
    Moveto [Codigo da Empresa       ] Checkplus
    Moveto [Nome Fantasia Empresa   ] Checkplus
    Moveto [Destino_Producao        ] Checkplus
    Moveto [Codigo                  ] Checkplus
    Moveto [Razao Social            ] Checkplus
    {Ask} TypeIn Tabela Enter Checkplus     
    Moveto [Numero_Programacao      ] Example "num"
    Do_It!
    ClearAll

    {Ask} {Answer}               
    Moveto [Codigo da Empresa       ] Check
    Moveto [Nome Fantasia Empresa   ] Check
    Moveto [Destino_Producao        ] Check
    Moveto [Codigo                  ] Check
    Moveto [Razao Social            ] Check
    Moveto [Codigo do Item          ] Check
    Moveto [Tipo Movimento          ] check
    Moveto [Data_Producao           ] check
    Moveto [Numero_Producao         ] check 
    Moveto [Quantidade Programada   ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida    ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Saldo                   ]       TypeIn "Calc Sum as \"Saldo\""
    Do_It!
    ClearAll
    
  Case VSDGCODMODELO="05" or VSDGCODMODELO="06" : 
    {Ask} {Pfacc}
    Moveto [Numero_Programacao      ] Example "num"
    Moveto [Codigo da Empresa       ] Checkplus
    Moveto [Nome Fantasia Empresa   ] Checkplus
    Moveto [Destino_Producao        ] Checkplus
    {Ask} TypeIn Tabela Enter Checkplus     
    Moveto [Numero_Programacao      ] Example "num"
    Do_It!
    ClearAll

    {Ask} {Answer}               
    Moveto [Codigo da Empresa       ] Check
    Moveto [Nome Fantasia Empresa   ] Check
    Moveto [Destino_Producao        ] Check
    Moveto [Codigo do Item          ] Check
    Moveto [Tipo Movimento          ] check
    Moveto [Data_Producao           ] check
    Moveto [Numero_Producao         ] check 
    Moveto [Quantidade Programada   ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida    ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Saldo                   ]       TypeIn "Calc Sum as \"Saldo\""
    Do_It!
    ClearAll
    
EndSwitch

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ]       TypeIn "_citem"
Moveto [Referencia             ] Check
Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Tipo do Item           ] Check
Moveto [Codigo da Cor_Tecido   ] Check
Moveto [Descricao da Cor_Tecido] Check
{Ask} {Answer} Check
Moveto [Codigo do Item         ]       TypeIn "_citem!"
Do_It!
ClearAll
     
MudaEstruturaDaTabelaPara("Answer","\\Base\\Sistemas\\Faccao\\Rm_0200")

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

EndProc   ; (Seleciona)

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Programa‡Æo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("03  Por Destino/Pessoa/Item")
ModeloRelatoriosAdd("04  Por Destino/Pessoa/Referˆncia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("05  Por Destino/Item")
ModeloRelatoriosAdd("06  Por Destino/Referˆncia")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp      = True
TECLA     = ""
MSG_CAMPO = ""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
          If Campo="TG_OPDEST"
             Then Seleciona_Opcoes("Op‡”es de Desinat rio","7,7")
          EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"    : Campo="NO"
            Case Campo="TG_CORTE"      : Campo="TG_EMPRESA"
            Case Campo="TG_NPRODCORTE" : Campo="TG_CORTE"
            Case Campo="TG_NPROG"      : Campo="TG_NPRODCORTE" 
            Case Campo="TG_OPDEST"     : Campo="TG_NPROG"
            Case Campo="TG_DESTINAT"   : Campo="TG_OPDEST"
            Case Campo="TG_FAMI"       : Campo="TG_EMPRESA"
            Case Campo="TG_MARCA"      : Campo="TG_FAMI"
            Case Campo="TG_ITEM"       : Campo="TG_MARCA"
            Case Campo="TG_REFERENCIA" : Campo="TG_ITEM"
            Case Campo="TG_DTINI"      : Campo="TG_REFERENCIA"
            Case Campo="TG_DTFIM"      : Campo="TG_DTINI"
            Case Campo="TG_SITUACAOFAC": Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"  : Campo="TG_SITUACAOFAC"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"      : Campo="TG_CORTE"
                    Case Campo="TG_CORTE"        : 
                         VSDGCORTE = ControlValue("TG_CORTE")
                         If Not ISBlank(VSDGCORTE)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_FAMI"      
                            Else Campo="TG_NPRODCORTE"    
                         EndIf
                    Case Campo="TG_NPRODCORTE"   :
                         If Not ISBlank(VSDGNPRODCORTE)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_FAMI"      
                            Else Campo="TG_NPROG"    
                         EndIf
                    Case Campo="TG_NPROG"        :
                         If Not ISBlank(VSDGNPROG)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_FAMI"      
                            Else Campo="TG_OPDEST"    
                         EndIf
                    Case Campo="TG_OPDEST"     : 
                         VSDGOPDEST=ControlValue("TG_OPDEST")
                         If IsBlank(VSDGOPDEST) Then VSDGOPDEST="TODOS" EndIf
                         If Not Checa_Opcoes("Op‡”es de Desinat rio",VSDGOPDEST) And VSDGOPDEST<>"TODOS"
                           Then Mensagem("Destino inv lido !")
                                Campo="TG_OPDEST"
                           Else Campo="TG_DESTINAT"
                        EndIf
                    Case Campo="TG_DESTINAT"    : Campo="TG_FAMI" 
                    Case Campo="TG_FAMI"        : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"        : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA"  : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_SITUACAOFAC"
                    Case Campo="TG_SITUACAOFAC" : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   : Campo = "YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_OPDEST":
     MSG_CAMPO="Em Branco=Todos, [F1]Consultar tabela"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

Proc LimpaCamposTag(Tipo)

Switch
    Case Tipo="Todos":
    VSDGEMPRESA    = ""
    VSDGNOMEMP     = ""     
    VSDGCORTE      = ""
    VSDGNPRODCORTE = ""
    VSDGNPROG      = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
    VSDGDTINI      = BlankDate()
    VSDGDTFIM      = BlankDate()
    VSDGFAMI       = ""
    VSDGNOMFAMI    = ""
    VSDGMARCA      = ""
    VSDGNOMMARCA   = ""
    VSDGREFERENCIA = ""
    VSDGOPIT       = "T"
  Case Tipo="TG_CORTE":
    VSDGNPRODCORTE = ""
    VSDGNPROG      = ""
    VSDGNOMNPROG   = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
  Case Tipo="TG_NPROG":
    VSDGCORTE      = ""
    VSDGNPRODCORTE = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
  Case Tipo="TG_NPRODCORTE":
    VSDGCORTE      = ""
    VSDGNPROG      = ""
    VSDGNOMNPROG   = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
EndSwitch

EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

sys_Valor()

LimpaCamposTag("Todos")

Coedit "P_DESTI"
Monta_Opcoes("Op‡”es de Desinat rio","INTERNO + FACCAO") 
Do_It!
ClearAll   

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Extrato da Programa‡äes/Produc‡äes - Interna/Externa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Corte"  For "TG_CORTE"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_CORTE" To VSDGCORTE
    Accept @ 03,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMCORTE" To VSDGNOMCORTE

    Label  @ 04,00 "Corte/Produ‡Æo"  For "TG_NPRODCORTE"
    Accept @ 05,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_NPRODCORTE" To VSDGNPRODCORTE
    Accept @ 05,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMNPRODCORTE" To VSDGNOMNPRODCORTE

    Label  @ 06,00 "Prog.Interno/Externo"  For "TG_NPROG"
    Accept @ 07,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_NPROG"    To VSDGNPROG
    Accept @ 07,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMNPROG" To VSDGNOMNPROG

    Label  @ 08,00 "Op‡”es Destinat rio" For "TG_OPDEST"
    Accept @ 09,01 Width 33 "A31"  Picture "!*!" Tag "TG_OPDEST" To VSDGOPDEST

    Label  @ 10,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 11,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 11,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 12,00 "Familia"  For "TG_FAMI"
    Accept @ 13,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI" To VSDGFAMI
    Accept @ 13,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI
 
    Label  @ 14,00 "Marca"  For "TG_MARCA"
    Accept @ 15,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 15,09 Width 25 "A22" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 00,35 "Item"  For "TG_ITEM"
    Accept @ 01,36 Width 33 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 02,36 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM"  To VSDGNOMITEM

    Label  @ 03,35 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 04,36 Width 33 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 05,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 06,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 06,51 "at‚" For "TG_DTFIM"
    Accept @ 06,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 07,35 "Situacao da Programa‡Æo"  For "TG_SITUACAOFAC"
    Accept @ 08,36 Width 33 "A30"  Picture "PROGRAMADA,EM PRODUCAO,SUSPENSA,FINALIZADA,TODAS,!*!" Tag "TG_SITUACAOFAC"  To VSDGSITUACAOFAC

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")

  Seleciona()
  
  If Not IsEmpty(Tabela)
     Then
          Switch
            Case VSDGCODMODELO="01": 
              Sort Tabela On "Codigo da Empresa","Data_Programacao","Numero_Programacao","Referencia","Codigo do Item",
                             "Data_Producao","Tipo Movimento","Numero_Producao"

              CopyReport "\\Base\\Sistemas\\Faccao\\RM_0200" "R" Tabela "R"
                                  
            Case VSDGCODMODELO="03" or
                 VSDGCODMODELO="04":
              Sort Tabela On "Codigo da Empresa","Destino_Producao","Codigo","Referencia","Codigo do Item","Data_Producao","Tipo Movimento","Numero_Producao"

              CopyReport "\\Base\\Sistemas\\Faccao\\RM_0200" "2" Tabela "R"
              
            Case VSDGCODMODELO="05" or
                 VSDGCODMODELO="06":
              Sort Tabela On "Codigo da Empresa","Destino_Producao","Referencia","Codigo do Item","Data_Producao","Tipo Movimento","Numero_Producao"

              CopyReport "\\Base\\Sistemas\\Faccao\\RM_0200" "3" Tabela "R"
              
          EndSwitch

          IMPRIREL(Tabela,"R")
          
     Else MENSAGEM("N„o existem registros a processar")
  EndIf

  if isTable(Tabela)   then Delete Tabela   EndIf
  if isTable("Answer") then Delete "Answer" EndIf

EndWhile
ClearAll
Release Vars All
Release Procs All
