;** Rm_0011  *******************************************************************
;*  Emissao dos Titulos a Pagar por Plano de Contas                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 12/03/2007 por Humberto F. Santos
;Ultima Alteracao: 10/10/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Tipo_Custo Fixo/Variavel
;Ultima Alteracao: 08/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 11/09/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Novo Modelo Relatorio
;Ultima Alteracao: 17/12/2009 por Cleber Alves
;Motivo Alteracao: Ask Rateio Plano_Contas
;Ultima Alteracao: 12/01/2010 por Cleber Alves
;Motivo Alteracao: Ajustes da Ask
;Ultima Alteracao: 12/05/2010 por Bruno Carvalho
;Motivo Alteracao: Op‡Æo 3 . Filtrando por data de competˆncia
;Ultima Alteracao: 08/01/2014 por Kamila Gomes
;Motivo Alteracao: Op‡Æo 4 . Filtrando por Ano e Mes Anal¡tico
;                  Op‡Æo 5 . Filtrando por Ano e Mes Sint‚tico
;                  Op‡Æo de ver titulos a pagar ou todos do periodo
;Ultima Alteracao: 24/04/2014 por Luis Gustavo
;Motivo Alteracao: Inclusao op‡Æo de incluir cheques nÆo apresentados/pre datados
;Ultima Alteracao: 26/05/2015 por Kamila Gomes
;Motivo Alteracao: Inclusao Op‡Æo 6. por Data Competencia /Ano e Mes Sint‚tico
;Ultima Alteracao: 28/10/2015 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Modelo 7 de Relatorio   
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog 
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()                  
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 15/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes CheckTG_OPTIT incluir ou nÆo 
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 02/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Sequencia da Baixa TitRat        
;Ultima Alteracao: 17/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: [Sequencia da Baixa] estava posicionado na "Answer" e nÆo no "TitRat"

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       If VSDGCODMODELO="03" Or VSDGCODMODELO="06"
          Then Moveto [Data Competencia  ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Else Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       EndIf
       If not CheckTG_OPTIT[1]
          Then Moveto [Saldo do Documento] TypeIn ">=0.01"
       EndIf
       Moveto [Codigo Plano_Conta] TypeIn PLCONTAS
       Do_It!
       ClearAll
       
       {Ask} "TitRat" Enter
       Moveto [Numero do Lancamento] example "NumLan"        
       Moveto [Sequencia da Baixa  ] TypeIn "0"
       {Ask} "Answer" Enter TypeIn "Delete"
       Moveto [Numero do Lancamento] example "NumLan"
       Do_It!
       ClearAll
       
       Primeirav="******"
       Coedit "Answer","TitRat","Deleted"
       Scan
         If [Numero do Lancamento]<>Primeirav 
            then Primeirav = [Numero do Lancamento] 
                 CopyToArray Array_Del      
                 Moveto "TitRat"
                 Moveto [Numero do Lancamento]
                 Locate [deleted->Numero do Lancamento],"0"
                 If RetVal             
                    Then While [Numero do Lancamento]=[Deleted->Numero do Lancamento] and
                               [Sequencia da Baixa  ]="0"
                           If Not IsBlank([Codigo Plano_Conta]) Then
                           Moveto "Answer"
                           End Down
                           CopyFromArray Array_del
                           [Codigo Plano_Conta   ]=[TitRat->Codigo Plano_Conta   ]
                           [Descricao Plano_Conta]=[TitRat->Descricao Plano_Conta] 
                           [Codigo CCusto        ]=[TitRat->Codigo CCusto        ]
                           [Descricao CCusto     ]=[TitRat->Descricao CCusto     ]
                         
                           If [Valor do Documento]<>[Saldo do Documento]
                              Then [Saldo do Documento]=(([TitRat->Valor]*[Saldo do Documento])/[Valor do Documento]) 
                                   [Valor do Documento]=[Saldo do Documento ]                            
                              Else [Saldo do Documento]=[TitRat->Valor]
                           EndIf   
                           [Valor do Documento]=[Saldo do Documento ]                            
                           
                           UnLockRecord
                           EndIf
                           Moveto "TitRat"      
                           Skip
                           If EOT() Then QuitLoop EndIf
                         EndWhile
                 EndIf 
                 Moveto "Deleted"  
         EndIf       
       EndScan
       Do_It!
       ClearAll     
EndIf
EndProc  ; (Seleciona)
;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc Seleciona2()
If not CheckTG_OPCHEQ[1]
   Then Return
EndIf

{Ask} {\\sistemas\\ctacor\\MovCont}
Moveto [Numero do Lancamento  ] CheckPlus
Moveto [Codigo da Conta       ] CheckPlus
Moveto [Descricao da Conta    ] CheckPlus
Moveto [Codigo da Empresa     ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Nome Fantasia Empresa ] CheckPlus
Moveto [Tipo Movimento        ] TypeIn "S"
Moveto [Tipo de Operacao      ] TypeIn "05"
Moveto [Valor                 ] CheckPlus
Moveto [Codigo do EmitDest    ] CheckPlus
Moveto [Nome Fantasia EmitDest] CheckPlus
Moveto [Razao Social          ] CheckPlus
Moveto [Codigo do Documento   ] CheckPlus
Moveto [Tipo do Documento     ] CheckPlus
Moveto [Serie do Documento    ] CheckPlus
Moveto [Numero do Documento   ] CheckPlus
Moveto [Numero do Cheque      ] CheckPlus
Moveto [Serie do Cheque       ] CheckPlus
Moveto [Cheque Pre-Datado     ] TypeIn "S"
Moveto [Data Cheque Descontado] TypeIn "Blank"
Moveto [Data                  ] CheckPlus
Moveto [Data Cheque Pre-Datado] CheckPlus TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero do Lancamento  ] Example "lanc"
Moveto [Codigo da Conta       ] Example "cont"
Moveto [Descricao da Conta    ] Example "dcont"
Moveto [Codigo da Empresa     ] Example "cod"
Moveto [Nome Fantasia Empresa ] Example "ncod"
Moveto [Valor                 ] Example "vr"
Moveto [Codigo do EmitDest    ] Example "cemi"
Moveto [Nome Fantasia EmitDest] Example "nemi"
Moveto [Razao Social          ] Example "emit"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tpdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Numero do Cheque      ] Example "numc"
Moveto [Serie do Cheque       ] Example "serc"
Moveto [Data                  ] Example "data"
Moveto [Data Cheque Pre-Datado] Example "dat"

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero do Lancamento  ] Example "lanc"
Moveto [Codigo da Conta       ] Example "cont"
Moveto [Descricao da Conta    ] Example "dcont"
Moveto [Codigo da Empresa     ] Example "cod"
Moveto [Nome Fantasia Empresa ] Example "ncod"
Moveto [Codigo do Emitente    ] Example "cemi"
Moveto [Nome Fantasia EmitDest] Example "nemi"
Moveto [Razao Social          ] Example "emit"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tpdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Valor do Documento    ] Example "vr"
Moveto [Saldo do Documento    ] Example "vr"
Moveto [Data_Inclusao         ] Example "dat"
Moveto [Data de Emissao       ] Example "data"
Moveto [Data a Pagar          ] Example "dat"
Moveto [Tipo do Lancamento    ] TypeIn "0"
Moveto [Descricao do Lancamento] TypeIn "_numc+"+"\" - \"+"+"_serc"
Do_It!
ClearAll

CoEdit Tabela
Scan
  If [Tipo do Lancamento     ]="0"
     Then [Observacoes       ]=[Descricao do Lancamento]
     Else [Tipo do Lancamento]=""
  EndIf
EndScan
Do_It!

ClearAll

EndProc  ; (Seleciona2)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()
;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
   VALORDOC=0
   If [Data a Pagar]<Today()
      Then NDA=Today()-[Data a Pagar]
           TXM=[Multa]
      Else NDA=0
           TXM=0
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf
   VALORDOC=[Valor do Documento] 
   
   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)
   [Data de Vencimento]=[Data a Pagar]
   
   If CheckTG_OPTIT[1] And [Saldo do Documento] < 0.01
      Then [Saldo do Documento]= VALORDOC
   EndIf

EndScan
Do_It!
ClearAll
EndProc   ;  (Processa)

;*******************************************************************************
;* Rotina p/ Ajustar tipocusto                                                   *
;*******************************************************************************
Proc Ajusta()
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Pag_1             ] TypeIn "Changeto X"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Ctacor\\Plcontas}
Moveto [Codigo Plano_Conta] example "plc"
Moveto [Tipo_Custo        ] example "tc"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo Plano_Conta] example "plc"
Moveto [Pag_1             ] TypeIn "Changeto _tc"
Do_It!
ClearAll
EndProc  ; (Seleciona)

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Data Vencimento - Anal¡tico")
ModeloRelatoriosAdd("02  Data Vencimento - Anal¡tico II")
ModeloRelatoriosAdd("04  Data Vencimento - Ano/Mˆs Anal¡tico")
ModeloRelatoriosAdd("05  Data Vencimento - Ano/Mˆs Sint‚tico")
ModeloRelatoriosAdd("07  Data Vencimento - Ano/Mˆs Sint‚tico II")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("03  Data Competˆncia- Anal¡tico")
ModeloRelatoriosAdd("06  Data Competˆncia- Ano/Mˆs Sint‚tico")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9  : Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1() 
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_PLCONTAS"      : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"         : Campo="TG_PLCONTAS"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPTIT"         : Campo="TG_DTFIM"
            Case Campo="TG_OPCHEQ"        : Campo="TG_OPTIT"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPCHEQ"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"  : Campo="TG_PLCONTAS"
                    Case Campo="TG_PLCONTAS"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_OPTIT"
                    Case Campo="TG_OPTIT"      : Campo="TG_OPCHEQ"  
                    Case Campo="TG_OPCHEQ"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"  
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo=""     :
       MSG_CAMPO=""
       TECLA=TECLA+"F1=Consulta  "
  Case Campo="TG_OPCHEQ" or Campo="TG_OPTIT":
       MensagemCheckBoxes()
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA=""
VSDGPLCONTAS=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()
VSDGMODELOREL=""

Array TG_OPTIT[1]
TG_OPTIT[1]="Incluir os T¡tulos Pagos"

Array CheckTG_OPTIT[ArraySize(TG_OPTIT)]
CheckTG_OPTIT[1]=False

Array TG_OPCHEQ[1]
TG_OPCHEQ[1]="Incluir os nÆo apresentados"

Array CheckTG_OPCHEQ[ArraySize(TG_OPCHEQ)]
CheckTG_OPCHEQ[1]=False

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos … Pagar por Plano de Conta" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC", "TAB","ReverseTab",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Plano de Contas" For "TG_PLCONTAS"
    Accept @ 03,01 Width 33 "A13"  Picture "!*!" Tag "TG_PLCONTAS" To VSDGPLCONTAS
    Accept @ 04,01 Width 33 "A40" Picture "!*!" Tag "TG_NOMPLCONTAS"  To VSDGNOMPLCONTAS
    
    Label  @ 05,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 06,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 06,16 "at‚" For "TG_DTFIM"
    Accept @ 06,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡Æo de T¡tulos" For "TG_OPTIT"
    CheckBoxes @ 01,35 Height 1 Width 33 Tag "TG_OPTIT"
    TG_OPTIT[1] to CheckTG_OPTIT[1]
    
    Label  @ 02,35 "Cheques Emitidos como Pr‚-Datados" For "TG_OPCHEQ"
    CheckBoxes @ 03,35 Height 1 Width 33 Tag "TG_OPCHEQ"
    TG_OPCHEQ[1] to CheckTG_OPCHEQ[1]
    
    Label  @ 08,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 09,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 09,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        
    
    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If Len(VSDGPLCONTAS)<13
     Then PLCONTAS=VSDGPLCONTAS + ".."
     Else PLCONTAS=VSDGPLCONTAS
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile
  
  Seleciona2()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  Ajusta()

  If VSDGCODMODELO="01" Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "R"  Tabela "R" EndIf
  If VSDGCODMODELO="02" Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "2"  Tabela "R" EndIf
  If VSDGCODMODELO="03" Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "6"  Tabela "R" EndIf
  If VSDGCODMODELO="04" Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "10" Tabela "R" EndIf
  If VSDGCODMODELO="05" Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "11" Tabela "R" EndIf
  If VSDGCODMODELO="06" Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "12" Tabela "R" EndIf
  If VSDGCODMODELO="07" Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "13" Tabela "R" EndIf
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
