;** Consulta *******************************************************************
;*  Consulta geral do contas a pagar                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 30/10/2017 por Bruno Carvalho
;Ultima Alteracao: 16/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes copia familia so fechames, naä excluir pasta no fechames   

;*******************************************************************************
;* Rotina para prepar a consulta                                               *
;*******************************************************************************
Proc CONTAS_APAGAR()

If IsTable("Titulos") And IsTable("TitBaixa")
   Then usandoconsultammaa=true
        Play "\\Sistemas\\CtaPag\\TitCons"
        ClearAll
   Else LimpAguarde()
        Mensagem("Tabela [Titulos] ou [TitBaixa] n„o encontrada !")
EndIf    

EndProc ;CONTAS_APAGAR()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_DIRETORIOS"    : Campo="NO"
            Case Campo="YES" Or Campo="NO": Campo="TG_DIRETORIOS"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_DIRETORIOS" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_OPCOES":
       MensagemRadioButtons()
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc   ; (SD_Dialog)

;*******************************************************************************
;* Copia Familia                                                           *
;*******************************************************************************
Proc Copia_Familia(caminho,tabela)
Private caminho,tabela

If Not IsTable(tabela)
   Then Return False
EndIf   

{Tools} {Copy} {JustFamily} TypeIn "\\BASE"+caminho+"\\"+tabela Enter TypeIn tabela Enter
If MenuChoice()="Cancel"
   Then Down
        If MenuChoice()="Replace"
           Then {Replace}
           Else {Cancel}
                Esc Esc Esc Esc
                MSG="Tabela [ "+tabela+" ] em [ "+caminho+" ], //"
                MSG=MSG+"com estrutura diferente !// //"
                MSG=MSG+"Anote o nome da tabela e pasta !//"
                MSG=MSG+"Depois entre em contato com o suporte Ok !"
                Mensagem(MSG)
        Endif
EndIf
Esc Esc Esc Esc

Return True

EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

Diretorio_Padrao="\\Sistemas\\CtaPag\\"
Diretorios_Fechames_C(Diretorio_Padrao)

While True
  ShowDialog "Consulta" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 06,12   Height 12 Width 54

    Label @ 00,00 "Ano_Mes Fechado"  For "TG_DIRETORIOS"

    PickDynArray @01,01 Height 6 width 49
     Columns 5
      Array_Diretorios
       Tag "TG_DIRETORIOS"
        To ArrayElement

    Pushbutton @ 08,12 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 08,26 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  Aguarde("Carregando consulta")

  ANO_MES=Array_Diretorios[ArrayElement]
  If ANO_MES<>" Atual"
     Then Diretorio=Diretorio_Padrao+"Fechames\\"+ANO_MES
     Else Diretorio=Diretorio_Padrao
  EndIf
  If DirExists(Diretorio)=0
     Then Mensagem("N„o existe a pasta de "+ANO_MES+" selecionado !")
          Loop
  EndIf
  SetDir Diretorio

  if search("FECHAMES",upper(Diretorio))>0
     then 
          Array Nom_Tab[5]
          Nom_Tab[1]="Titulos"
          Nom_Tab[2]="TitBaixa"
          Nom_Tab[3]="TitNota"
          Nom_Tab[4]="TitCheq"
          Nom_Tab[5]="TitRat"  
          
          For i From 1 To ArraySize(Nom_Tab) 
              If IsTable(Nom_Tab[i])
                  Then If Not Copia_Familia(Diretorio_Padrao,Nom_Tab[i])
                          Then Mensagem("Tabela "+Nom_Tab[i]+" n„o localizada no diret¢rio "+Diretorio+"!")
                               QuitLoop
                       Endif   
              EndIf
          EndFor
  endif
  
  CONTAS_APAGAR()  
  
  Echo Normal
  Echo Off
  LimpaRodape(0)

  Aguarde("Verificando Tabelas")
  SetDir Diretorio_Padrao
;;If Not Tem_Tabelas(Diretorio)
;;   Then Deleta_Arvore(SubStr(Directory(),1,2)+Diretorio)
;;EndIf
  LimpAguarde()
EndWhile
ClearAll
Release Vars All
Release Procs All
