;** TbprNew  *******************************************************************
;*  Altera Precos de Itens para Nova Tabela                                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 22/11/1999 por Douglas Rodrigues
;Ultima Alteracao: 01/07/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 27/07/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÆo usar condi‡Æo pagamento por item
;Ultima Alteracao: 25/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desativar tecla alt+O (-24) ir ao prompt do DOS
;Ultima Alteracao: 03/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes altera empresa e nova logica

;*******************************************************************************
;* Rotina de Digitacao Dados do Item                                           *
;*******************************************************************************
Proc TbPrNew_Item_DialogP(Disparo,Campo,Evento,Elemento)
private Disparo,Campo,Evento,Elemento,WinArray5,JANELA

Temp=True
MSG_CAMPO=""
TECLA=""

If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: 
          If Campo="I_Codigo_Empresa" Or
             Campo="I_Codigo_Tabela"  Or
             Campo="I_Condicao_Pagto"
             Then 
                  Dynarray WinArray5[]
                  Window Handle Dialog to JANELA
                  Window GetAttributes JANELA To WinArray5
                  WinArray5["FLOATING"]=False
                  Window SetAttributes JANELA From WinArray5
        
                  If Campo="I_Codigo_Empresa" Then Moveto [Codigo da Empresa    ] endif
                  If Campo="I_Codigo_Tabela"  Then Moveto [Codigo da Tabela     ] endif
                  if Campo="I_Condicao_Pagto" Then Moveto [Condicao de Pagamento] EndIf
                  If ConsultaF1()
                     then
                          If Campo="I_Codigo_Empresa"
                             Then VSD_I_Codigo_Empresa     =Reg_ConsultaF1["Codigo da Empresa"     ]
                                  VSDGNOMEMP               =Reg_ConsultaF1["Nome Fantasia Empresa" ]
                                  [Codigo da Empresa       ]=empold 
                          endif
                          If Campo="I_Codigo_Tabela"
                             Then VSD_I_Codigo_Tabela      =Reg_ConsultaF1["Codigo da Tabela"      ]
                                  VSDGNOMTAB               =Reg_ConsultaF1["Descricao da Tabela"   ]
                                  [Codigo da Tabela       ]=tabold 
                          endif
                          if Campo="I_Condicao_Pagto"
                             Then VSD_I_Condicao_Pagto     =Reg_ConsultaF1["Condicao de Pagamento" ]
                                  VSDGNOMCONDPGTO          =Reg_ConsultaF1["Descricao CondPagto"   ]
                                  [Condicao de Pagamento  ]=cpgold
                          EndIf
                  endif   

                  Window Select JANELA
                  WinArray5["FLOATING"]=True
                  Window SetAttributes JANELA From WinArray5
       
                  echo Normal
                  echo off
                  
                  
          EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
            Switch
             Case Campo="I_Codigo_Empresa" : campo="NO"
             Case Campo="I_Codigo_Tabela"  : campo="I_Codigo_Empresa"
             Case Campo="I_Condicao_Pagto" : campo="I_Codigo_Tabela"
             Case Campo="YES" Or Campo="NO": Campo="I_Codigo_Empresa"
           EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                   Case Campo="I_Codigo_Empresa":  Campo="I_Codigo_Tabela"
                        VSD_I_Codigo_Empresa=ControlValue("I_Codigo_Empresa")
                        if isblank(VSD_I_Codigo_Empresa)
                           then VSDGNOMEMP          ="N¶O ALTERAR"
                           else
                                VSD_I_Codigo_Empresa=AlinhM(VSD_I_Codigo_Empresa,4)
                                getrecord "\\sistemas\\cadastro\\empresas" VSD_I_Codigo_Empresa to Reg_Busca_Lookup
                                If RetVal
                                   Then VSDGNOMEMP          = Reg_Busca_Lookup["Nome Fantasia Empresa"]
                                    
                                   Else fastmsg("Empresa n„o cadastrada !")
                                        Campo="I_Codigo_Empresa"
                                EndIf
                        endif
                   Case Campo="I_Codigo_Tabela":  Campo="I_Condicao_Pagto"
                        VSD_I_Codigo_Tabela=ControlValue("I_Codigo_Tabela")
                        if isblank(VSD_I_Codigo_Tabela)
                           then VSDGNOMTAB          ="N¶O ALTERAR"
                           else 
                                VSD_I_Codigo_Tabela=AlinhM(VSD_I_Codigo_Tabela,5)
                                getrecord "\\sistemas\\Vendas\\Tbprcab" VSD_I_Codigo_Tabela to Reg_Busca_Lookup
                                If RetVal
                                   Then VSDGNOMTAB          = Reg_Busca_Lookup["Descricao da Tabela"] 
                                   Else fastmsg("Tabela n„o cadastrada !")
                                        Campo="I_Codigo_Tabela"
                                EndIf
                        endif
                   Case Campo="I_Condicao_Pagto":  Campo="YES"
                        VSD_I_Condicao_Pagto=ControlValue("I_Condicao_Pagto")
                        if isblank(VSD_I_Condicao_Pagto)
                           then VSDGNOMCONDPGTO          ="N¶O ALTERAR"
                           else 
                                VSD_I_Condicao_Pagto=AlinhM(VSD_I_Condicao_Pagto,2)
                                getrecord "\\sistemas\\Vendas\\Condpgto" VSD_I_Condicao_Pagto to Reg_Busca_Lookup
                                If RetVal
                                   Then VSDGNOMCONDPGTO     = Reg_Busca_Lookup["Descricao CondPagto"] 
                                   Else fastmsg("Condi‡Æo n„o cadastrada !")
                                        Campo="I_Condicao_Pagto"
                                EndIf
                        endif
                 EndSwitch
          EndIf
   EndSwitch
EndIf
Switch
  Case Campo="I_Codigo_Empresa"         : MSG_CAMPO="Em Branco=nƒo altera a Empresa, [F1]Consulta Tabela"
  Case Campo="I_Codigo_Tabela"          : MSG_CAMPO="Em Branco=nƒo altera a Tabela, [F1]Consulta Tabela"
  Case Campo="I_Condicao_Pagto"         : MSG_CAMPO="Em Branco=nƒo altera a Condi‡Æo de Pagamento, [F1]Consulta Tabela"
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* Rotina para Digitacao Item                                                  *
;*******************************************************************************
proc TbPrNew_Principal()
private empold,tabold,cpgold

empold=[Codigo da Empresa    ]
tabold=[Codigo da Tabela     ]
cpgold=[Condicao de Pagamento]

VSD_I_Codigo_Empresa =""    VSDGNOMEMP     =""
VSD_I_Codigo_Tabela  =""    VSDGNOMTAB     =""
VSD_I_Condicao_Pagto =""    VSDGNOMCONDPGTO=""

Ok_TbprNew=False

Showdialog "Novos dados para alterar !" Proc "TbPrNew_Item_DialogP" 
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB" 
    @ 04,00 Height 11 Width 38

   Label  @ 00,00 "Empresa"  For "I_Codigo_Empresa"
   Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "I_Codigo_Empresa"    To VSD_I_Codigo_Empresa
   Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

   Label  @ 02,00 "Tabela"  For "I_Codigo_Tabela"
   Accept @ 03,01 Width 08 "A5"  Picture "#*#" Tag "I_Codigo_Tabela" To VSD_I_Codigo_Tabela
   Accept @ 03,09 Width 25 "A70" Picture "!*!" Tag "TG_NOMTAB" To VSDGNOMTAB

   Label  @ 04,00 "Condi‡Æo de Pagamento" For "I_Condicao_Pagto"
   Accept @ 05,03 Width 05 "A2" picture "!*!" Tag "I_Condicao_Pagto" to VSD_I_Condicao_Pagto
   Accept @ 05,09 Width 25 "A20" picture "!*!" Tag "TG_NOMCONDPGTO" to VSDGNOMCONDPGTO

   Pushbutton @ 07,05 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
   Pushbutton @ 07,19 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

Enddialog
if retval
   then 
        if not isblank(VSD_I_Codigo_Empresa) 
           then [Codigo da Empresa    ]=VSD_I_Codigo_Empresa
                if not Carrega_Parametros() 
                   then [Codigo da Empresa       ]=empold 
                        return
                endif     
        endif
        if not isblank(VSD_I_Codigo_Tabela)  then [Codigo da Tabela     ]=VSD_I_Codigo_Tabela   endif
        if not isblank(VSD_I_Condicao_Pagto) then [Condicao de Pagamento]=VSD_I_Condicao_Pagto  endif
        
        if not isblank(VSD_I_Codigo_Tabela) or not isblank(VSD_I_Condicao_Pagto) 
           then Ok_TbprNew=True 
        endif
endif

endproc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
TbPrNew_Principal()

Release procs TbPrNew_Item_DialogP, TbPrNew_Principal
