;** Rm_0210A ******************************************************************
;*  Emissao dos Titulos a Programados por Plano de Contas/CCusto Sintetico I  *
;******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 02/06/2010 por Bruno Carvalho
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 02/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Sequencia da Baixa TitRat        
;Ultima Alteracao: 05/10/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Sequencia da Baixa TitRat        

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Data Competencia  ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       Do_It!
       ClearAll
           
       {Ask} "TitRat" Enter
       Moveto [Numero do Lancamento] example "NumLan"       
       Moveto [Sequencia da Baixa  ] TypeIn "0"
       {Ask} "Answer" Enter TypeIn "Delete"
       Moveto [Numero do Lancamento] example "NumLan" 
       Do_It!
       ClearAll
       
       Primeirav="******"
       Coedit "Answer","TitRat","Deleted"
       Scan
         If [Numero do Lancamento]<>Primeirav 
            then Primeirav = [Numero do Lancamento] 
                 CopyToArray Array_Del      
                 Moveto "TitRat"
                 Moveto [Numero do Lancamento]
                 Locate [deleted->Numero do Lancamento],"0"
                 If RetVal             
                    Then While [Numero do Lancamento]=[Deleted->Numero do Lancamento] and
                               [Sequencia da Baixa  ]="0"
                           If Not IsBlank([Codigo Plano_Conta]) Then
                           Moveto "Answer"
                           End Down
                           CopyFromArray Array_del
                           [Codigo Plano_Conta   ]=[TitRat->Codigo Plano_Conta   ]
                           [Descricao Plano_Conta]=[TitRat->Descricao Plano_Conta] 
                           [Codigo CCusto        ]=[TitRat->Codigo CCusto        ]
                           [Descricao CCusto     ]=[TitRat->Descricao CCusto     ]
                           [Valor do Documento   ]=[TitRat->Valor                ]                  
                           UnLockRecord
                           EndIf
                           Moveto "TitRat"      
                           Skip
                           If EOT() Then QuitLoop EndIf
                         EndWhile
                 EndIf 
                 Moveto "Deleted"  
         EndIf       
       EndScan
       Do_It!
       ClearAll     
EndIf
EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Processar Registros                                               *
;*******************************************************************************
Proc Processa()
ClearAll

;{Ask} TypeIn Tabela Enter TypeIn "Fast"
;Moveto [Codigo CCusto   ] TypeIn "Changeto Blank"
;Moveto [Descricao CCusto] TypeIn "Changeto Blank"
;Do_It!
;ClearAll

;{Ask} {\\Sistemas\\Ctacor\\CCusto}
;Moveto [Codigo CCusto    ] Example "ccl"
;Moveto [Descricao CCusto ] Example "dcl"
;{Ask} TypeIn Tabela Enter TypeIn "Fast"
;Moveto [Codigo CCusto         ] Example "ccl"
;Moveto [Descricao CCusto      ] TypeIn "Changeto " Example "dcl"
;Do_It!
;ClearAll

{Ask} {\\Sistemas\\Ctacor\\PlContas}
Moveto [Codigo Plano_Conta    ] Example "cpl"
Moveto [Descricao Plano_Conta ] Example "dpl"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo Plano_Conta    ] Example "cpl"
Moveto [Descricao Plano_Conta ] TypeIn "Changeto " Example "dpl"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Ctacor\\PlContas}
Moveto [Codigo Plano_Conta    ] Example "cpl" TypeIn ", Not 1.."
Moveto [Descricao Plano_Conta ] Example "dpl"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa     ] TypeIn VSDGEMPRESA
Moveto [Codigo Plano_Conta    ] Example "cpl"
Moveto [Descricao Plano_Conta ] Example "dpl"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Empresas}
Moveto [Codigo da Empresa     ] Example "cde"
Moveto [Nome Fantasia Empresa ] Example "nfe"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa     ] Example "cde"
Moveto [Nome Fantasia Empresa ] TypeIn "changeto _nfe"
Do_It!
ClearAll

Processa2()

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa     ] Check
Moveto [Nome Fantasia Empresa ] Check
Moveto [Codigo Plano_Conta    ] Check
Moveto [Descricao Plano_Conta ] Check
Moveto [Codigo CCusto         ] Check
Moveto [Descricao CCusto      ] Check
Moveto [Valor do Documento    ] TypeIn "Calc Sum As Valor"
Do_It!
ClearAll

{Modify} {Restructure} {Answer}
Down Down Ins Right  "Codigo Plano_Conta" Enter
Down Left Left Ins Right  "Descricao Plano_Conta" Enter
Up Backspace Backspace  "21" Down Do_It! ClearImage

CoEdit "Answer"
Scan For Not IsBlank([Codigo CCusto])
  [Codigo Plano_Conta   ]=Completa([Codigo Plano_Conta],14," ")+[Codigo CCusto]
  [Descricao Plano_Conta]="          "+LTrim([Descricao CCusto])
EndScan
Do_It!
ClearAll

Sort "Answer" On "Codigo da Empresa", "Nome Fantasia Empresa",
                 "Codigo Plano_Conta", "Descricao Plano_Conta",
                 "Codigo CCusto", "Descricao CCusto"

g1=0     c1=""  t1=0
g2=0     c2=""  t2=0
g3=0     c3=""
g4=0     c4=""
g5=0     c5=""

CoEdit "Answer"
SetHighLight Current Record 23 Field 31
CtrlEnd Left Left
c1=SubStr([Codigo Plano_Conta],01,01)
c2=SubStr([Codigo Plano_Conta],01,03)
c3=SubStr([Codigo Plano_Conta],01,06)
c4=SubStr([Codigo Plano_Conta],01,09)
c5=SubStr([Codigo Plano_Conta],01,13)
While True

  nr=recno()
  If SubStr([Codigo Plano_Conta],01,01)<>c1 Then Totaliza(1) EndIf
  If SubStr([Codigo Plano_Conta],01,03)<>c2 Then Totaliza(2) EndIf
  If SubStr([Codigo Plano_Conta],01,06)<>c3 Then Totaliza(3) EndIf
  If SubStr([Codigo Plano_Conta],01,09)<>c4 Then Totaliza(4) EndIf
  If SubStr([Codigo Plano_Conta],01,13)<>c5 Then Totaliza(5) EndIf

  g1=g1+[Valor]
  g2=g2+[Valor]
  g3=g3+[Valor]
  g4=g4+[Valor]
  g5=g5+[Valor]
  
  t1=t1+[Valor]

  Down
  If RecordStatus("New")
     Then Totaliza(1)
          If VSDGEMPRESA="0000"
             Then [Codigo da Empresa     ]=VSDGEMPRESA
             Else [Codigo da Empresa     ]=VSDGEMPRESA2
          EndIf
          [Nome Fantasia Empresa ]=VSDGNOMEMP
          [Codigo Plano_Conta    ]="T"
          [Descricao Plano_Conta ]="[SAIDAS]..."
          [Valor                 ]=t1           
          QuitLoop
  EndIf

EndWhile
Do_It!
ClearAll

{Ask} {Answer}
TypeIn "Fast"
Moveto [Valor                  ] TypeIn "0, Changeto Blank"
Do_It!
ClearAll

CopyReport  "\\Base\\Sistemas\\Ctapag\\RM_0210" "1" "Answer" "R"

EndProc     ;  (Seleciona)

;*******************************************************************************
;* Totaliza                                                                    *
;*******************************************************************************
Proc Totaliza(Tipo)
Moveto [Codigo Plano_Conta]
For i From Tipo To 5
  Switch
    Case i=1:
         If Not IsBlank(SubStr(c1,01,01))
            Then Locate c1
                 If RetVal
                    Then [Valor]=g1
                 EndIf
         EndIf
         g1=0
    Case i=2:
         If Not IsBlank(SubStr(c2,03,01))
            Then Locate c2
                 If RetVal
                    Then [Valor]=g2
                 EndIf
         EndIf
         g2=0
    Case i=3:
         If Not IsBlank(SubStr(c3,05,02))
            Then Locate c3
                 If RetVal
                    Then [Valor]=g3
                 EndIf
         EndIf
         g3=0
    Case i=4:
         If Not IsBlank(SubStr(c4,08,02))
            Then Locate c4
                 If RetVal
                    Then [Valor]=g4
                 EndIf
         EndIf
         g4=0
    Case i=5:
         If Not IsBlank(SubStr(c5,11,03))
            Then Locate c5
                 If RetVal
                    Then [Valor]=g5
                 EndIf
         EndIf
         g5=0         
  EndSwitch
EndFor
Moveto Record nr
c1=SubStr([Codigo Plano_Conta],01,01)
c2=SubStr([Codigo Plano_Conta],01,03)
c3=SubStr([Codigo Plano_Conta],01,06)
c4=SubStr([Codigo Plano_Conta],01,09)
c5=SubStr([Codigo Plano_Conta],01,13)
EndProc

;*******************************************************************************
;* ROTINA Ajusta Dados Empresa                                                 *
;*******************************************************************************
Proc Processa2()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
    Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    :
                         If IsBlank(VSDGEMPRESA)
                            Then Mensagem("Informe uma Empresa !")
                            Else Campo="TG_DTINI"
                         EndIf
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_EMPRESATE":
       MSG_CAMPO="Informe uma Empresa"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  =""
VSDGDTINI    =BlankDate()
VSDGDTFIM    =BlankDate()

While True
  ShowDialog "Sint‚tico/Programado por Plano de Conta/Centro de Custo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 09 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Per¡odo Competˆncia de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 05,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGEMPRESA)
     Then Mensagem("Informe uma Empresa !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
      If IsTable("Answer")     Then Delete "Answer" EndIf
      Seleciona()
      If Not IsTable("Answer") Then Loop EndIf
      If IsTable(Tabela)
         Then Add "Answer" Tabela
         Else Rename "Answer" Tabela
      EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  IMPRIREL("Answer","R")
  Delete Tabela
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
