;** Et_Z002D *******************************************************************
;* Monta Etiqueta p/ Imp. T‚rmica - Zebra - Interno    ** PODIUM ** *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 20/08/2010 por Davi Pereira Carrano
;Ultima Alteracao: 03/09/2010 por Nikolas
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 06/09/2010 por Nikolas
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 13/06/2011 por Bruno Carvalho
;Motivo Alteracao: Alterado de 4 para 6 Digitos o campo "Codigo Concentrador"
;Ultima Alteracao: 07/11/2018 por Bruno Carvalho
;Motivo Alteracao: Ajustes padrÆo p/ codigo de barras EAN8, EAN13 ou COD128

;*******************************************************************************
Proc Monta_Etiqueta()
Moveto "Answer"
Print File Arquivo "O\n"
Print File Arquivo "N\n"
Print File Arquivo "q768\n"
Print File Arquivo "Q181,17+\n"
Print File Arquivo "S2\n"
Print File Arquivo "D8\n"
Print File Arquivo "ZT\n"

If Not IsBlank(CITEM[1])
   Then Print File Arquivo "A00,7,0,1,1,1,N,\""+DITEA[1]+"\"\n"
        Print File Arquivo "A00,23,0,2,1,1,N,\""+DITEB[1]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[1])>0 : Print File Arquivo "B12,48,0,E30,2,2,45,B,\""+CITEM[1]+"\"\n" 
          Case Search("EAN8",TPBARRA[1])>0  : Print File Arquivo "B12,48,0,E80,2,2,45,B,\""+CITEM[1]+"\"\n"
          OtherWise                         : Print File Arquivo "B12,48,0,1,2,2,45,B,\""+CITEM[1]+"\"\n"  
        EndSwitch     
        Print File Arquivo "A00,141,0,4,1,1,N,\""+CODCT[1]+"\"\n"
EndIf
If Not IsBlank(CITEM[2])
   Then Print File Arquivo "A270,7,0,1,1,1,N,\""+DITEA[2]+"\"\n"      ; A270
        Print File Arquivo "A260,23,0,2,1,1,N,\""+DITEB[2]+"\"\n"     
        Switch
          Case Search("EAN13",TPBARRA[2])>0 : Print File Arquivo "B288,48,0,E30,2,2,45,B,\""+CITEM[2]+"\"\n"  ; B288 
          Case Search("EAN8",TPBARRA[2])>0  : Print File Arquivo "B288,48,0,E80,2,2,45,B,\""+CITEM[2]+"\"\n"  ; B288
          OtherWise                         : Print File Arquivo "B288,48,0,1,2,2,45,B,\""+CITEM[2]+"\"\n"  ; B288 
        EndSwitch     
        Print File Arquivo "A261,141,0,4,1,1,N,\""+CODCT[2]+"\"\n"
EndIf                      
If Not IsBlank(CITEM[3])
   Then Print File Arquivo "A548,7,0,1,1,1,N,\""+DITEA[3]+"\"\n"      ; A548
        Print File Arquivo "A546,23,0,2,1,1,N,\""+DITEB[3]+"\"\n"
        Switch
          Case Search("EAN13",TPBARRA[3])>0 : Print File Arquivo "B564,48,0,E30,2,2,45,B,\""+CITEM[3]+"\"\n"  ; A564
          Case Search("EAN8",TPBARRA[3])>0  : Print File Arquivo "B564,48,0,E80,2,2,45,B,\""+CITEM[3]+"\"\n"  ; A564 
          OtherWise                         : Print File Arquivo "B564,48,0,1,2,2,45,B,\""+CITEM[3]+"\"\n"  ; A564 
        EndSwitch     
        Print File Arquivo "A547,141,0,4,1,1,N,\""+CODCT[3]+"\"\n"
EndIf

If CITEM[1]=CITEM[2] And CITEM[1]=CITEM[3]
   Then Print File Arquivo "P"+StrVal(CR)+"\n"
        ce=ce+((CR-1)*3)
   Else Print File Arquivo "P1\n"
EndIf
ne=3
EndProc

;*******************************************************************************
;* Monta Comandos p/ Impressora Termica                                        *
;*******************************************************************************
Proc Monta_Comandos()
If IsAssigned(DITEA)
   Then Release Vars DITEA, DITEB, CITEM, CODCT, TPBARRA
EndIf
Array   DITEA[3]
Array   DITEB[3]
Array   CITEM[3]
Array TPBARRA[3]
Array   CODCT[3]

Arquivo=PrivDir()+"CR.ejf"
Deleta_Arquivo(Arquivo)

ne=3
Coedit "Answer"
Scan
  te=[Quantidade]
  If (te-(3-ne))>3
     Then CR=Int((te-(3-ne))/3)
     Else CR=1
  EndIf
  ce=0
  While True
    ce=ce+1
    ne=ne+1
    If ne=4
       Then For i From 1 To 3
              DITEA[i]=""
              DITEB[i]=""
              CITEM[i]=""
            TPBARRA[i]="" 
              CODCT[i]=""
            EndFor
            ne=1
    EndIf
    DITEA[ne]=SubStr([Descricao do Item],01,22)
    DITEB[ne]="Ref "+RTrim([Referencia])
  TPBARRA[ne]=Upper([Tipo Codigo_Barras])
    Switch
      Case Search("EAN13",TPBARRA[ne])>0 Or 
           Search("EAN8",TPBARRA[ne])>0   : CITEM[ne]=[Codigo de Barras]
      OtherWise                           : CITEM[ne]=[Codigo do Item]
    EndSwitch 
    CODCT[ne]=SubStr([Codigo Concentrador],01,06)+" "+SubStr([Descricao do Item],24,07)
    If ne=3   Then Monta_Etiqueta() EndIf
    If ce>=te Then QuitLoop         EndIf
  EndWhile
EndScan
If ne<3 Then Monta_Etiqueta() EndIf
Do_It!
ClearAll

ImpriArq(Arquivo)

Sleep 700
Deleta_Arquivo(Arquivo)
ClearAll
EndProc

Monta_Comandos()
Release Procs Monta_Etiqueta,Monta_Comandos
