;** Encerra ********************************************************************
;*  Programa p/ Fechamento de Meses Selecionados                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 07/10/97   por Anivel Augusto Rodrigues
;Ultima Alteracao: 10/11/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mensagem advertencia
;Ultima Alteracao: 14/08/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Run
;Ultima Alteracao: 08/05/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes BordChTx
;Ultima Alteracao: 03/03/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Layout                   
;Ultima Alteracao: 05/04/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes mensagem                 
;Ultima Alteracao: 05/12/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes deletar keyviol   

;*******************************************************************************
; ChequeC/ChequeI                                                              *
;*******************************************************************************
Proc CHEQUES()
ClearAll
MSG_AGUARDE="Aguarde, fechando cheques liquidados "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(4,1))
If IsTable("ChequeC")
   Then If Not IsTable("ChequeI")
           Then Mensagem("Tabela [ChequeI] n„o encontrada !")
                Return
        EndIf
        
        {Ask} {ChequeC} Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        {Ask} {ChequeI} 
        Moveto [Numero do Lancamento] Example "LANCTO"
        Moveto [Data Vencimento  ] TypeIn "...~MESANO"
        Moveto [Situacao         ] TypeIn "LIQUIDADO"
        Do_It!
        ClearAll
        
        If IsEmpty("Answer")
           Then Fastmsg("Mˆs sem movimenta‡„o p/ cheques liquidados !")
                Return
        EndIf

        Rename "Answer" "ChqCTemp"
        ClearAll
        
        {Modify} {Restructure} {ChqCTemp}
        Moveto [Field Type] TypeIn "*"
        Do_It!
        ClearAll       
                
        Aguarde(MSG_AGUARDE+Barra(4,2))
        If IsTable("ChequeI")
           Then {Ask} {ChqCTemp}
                Moveto [Numero do Lancamento] Example "LANCTO"
                {Ask} {ChequeI} Check
                Moveto [Numero do Lancamento] Example "LANCTO"
                Do_It!
                ClearAll
                Crea_Add_Sub_Tabela("Answer","ChequeI")
        EndIf
        
        Aguarde(MSG_AGUARDE+Barra(4,3))
        {Ask} {ChqCTemp}
        Moveto [Numero do Lancamento] Example "LANCTO"
        {Ask} {ChequeC} Check
        Moveto [Numero do Lancamento] Example "LANCTO"
        Do_It!
        ClearAll        
        Crea_Add_Sub_Tabela("Answer","ChequeC")
        
        Aguarde(MSG_AGUARDE+Barra(4,4))
        Coedit "Chequec"
        PickForm "F"
        Scan
          While True
            Moveto "Chequei"
            If RecordStatus("New")
               Then Deletar=True
               Else Deletar=False
            EndIf
            Moveto "Chequec"
            If Deletar
               Then Del
               Else QuitLoop
            EndIf
            If [Numero do Lancamento]=""
               Then QuitLoop
            EndIf
          EndWhile
        EndScan
        Do_It!
        ClearAll       
        
   Else Fastmsg("Tabela [ChequeC] n„o encontrada !")
EndIf

Endproc

;*******************************************************************************
; BordCHC/BordCHI                                                              *
;*******************************************************************************
Proc BORDEROS()
ClearAll
MSG_AGUARDE="Aguarde, fechando borderos "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(4,1))
If IsTable("BordCHC")
   Then {Ask} {BordCHC} Check
        Moveto [Codigo da Empresa] TypeIn "~VSDGEMPRESA.."
        Moveto [Data do Lote     ] TypeIn "...~MESANO"
        Do_It!
        ClearAll
        
        If IsEmpty("Answer")
           Then Fastmsg("Mˆs sem movimenta‡„o p/ borderos !")
                Return
        EndIf
        
        Rename "Answer" "BordCTmp"
        ClearAll
        
        {Modify} {Restructure} {BordCTmp}
        Moveto [Field Type] TypeIn "*"
        Do_It!
        ClearAll               
                
        Aguarde(MSG_AGUARDE+Barra(4,2))
        If IsTable("BordCHI")
           Then {Ask} {BordCTmp}
                Moveto [Numero do Lote] Example "LANCTO"
                {Ask} {BordCHI} Check
                Moveto [Numero do Lote] Example "LANCTO"
                Do_It!
                ClearAll
                Crea_Add_Sub_Tabela("Answer","BordCHI")
        EndIf
        
        Aguarde(MSG_AGUARDE+Barra(4,3))
        If IsTable("Bordchtx")
           Then {Ask} {BordCTmp}
                Moveto [Numero do Lote] Example "LANCTO"
                {Ask} {Bordchtx} Check
                Moveto [Numero do Lote] Example "LANCTO"
                Do_It!
                ClearAll
                Crea_Add_Sub_Tabela("Answer","Bordchtx")
        EndIf
        
        Aguarde(MSG_AGUARDE+Barra(4,4))
        {Ask} {BordCTmp}
        Moveto [Numero do Lote] Example "LANCTO"
        {Ask} {BordCHC} Check
        Moveto [Numero do Lote] Example "LANCTO"
        Do_It!
        ClearAll
        Crea_Add_Sub_Tabela("Answer","BordCHC")
        
   Else Fastmsg("Tabela [BordCHC] n„o encontrada !")              
EndIf

EndProc

;*******************************************************************************
;* Rotina Create/Add/Subtract                                                  *
;*******************************************************************************
Proc Crea_Add_Sub_Tabela(TABORIG,TABDEST)
Private TABORIG,TABDEST,TABDESTINO

TABDESTINO = DiretorioFechames+TABDEST
If Not IsTable(TABDESTINO)
   Then Create TABDESTINO Like TABDEST
        {Tools} {Copy} {JustFamily} TypeIn TABDEST Enter TypeIn TABDESTINO Enter {Replace}
        Delete "Struct"
EndIf
Add TABORIG TABDESTINO ClearImage
SaveTables

;************************ Especial ****************************
;**************************************************************
If TABORIG<>"ChqCTemp"
   Then SubTract TABORIG TABDEST ClearImage
        SaveTables
EndIf
;**************************************************************
;**************************************************************

{Modify} {Restructure} TypeIn TABDEST Enter Do_It! ClearImage
Delete TABORIG
SAVETABLES
EndProc

;*******************************************************************************
;* Rotina Bloqueia Tabelas da Pasta                                            *
;*******************************************************************************
Proc BloqueiaTabelas(Pasta)
Private MSG, Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then Lock Pasta+Array_Tabelas[i] FL
          If Not RetVal
             Then MSG="O usu rio "+Upper(ErrorUser())+" esta usando o Sistema !// //"
                  MSG=MSG+Completa("- Contact -lo para liberar o Sistema;",40," ")+"//"
                  MSG=MSG+Completa("- Esta rotina ser  abortado.",40," ")+"// //"
                  MSG=MSG+"Execute esta rotina novamente para que//"
                  MSG=MSG+"a mesma seja concluida corretamente !"
                  Mensagem(MSG)
                  Return False
          EndIf
  EndIf
EndFor

Return True
EndProc

;*******************************************************************************
;* Rotina Desbloqueia Tabelas da Pasta                                         *
;*******************************************************************************
Proc DesbloqueiaTabelas(Pasta)
Private Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)
  If IsTable(Pasta+Array_Tabelas[i])
     Then UnLock Pasta+Array_Tabelas[i] FL
  EndIf
EndFor

EndProc

;*******************************************************************************
;* Rotina Monta Lista de Tabelas a Processar                                   *
;*******************************************************************************
Proc ListadeTabelas()
If IsAssigned(Array_Tabelas)
   Then Release Vars Array_Tabelas
EndIf
DynArray Array_Tabelas[]

Array_Tabelas[01]="ChequeC"
Array_Tabelas[02]="ChequeI"
Array_Tabelas[03]="BordCHC"
Array_Tabelas[04]="BordCHI"
Array_Tabelas[05]="BordCHTX"

EndProc

;*******************************************************************************
;* Rotina Lista de Mes/Ano em Aberto                                           *
;*******************************************************************************
Proc Lista_MesAno()
ClearAll
Aguarde("Aguarde, Verificando Mes/Ano em Aberto")

If IsAssigned(Array_ListaMesAno)
   Then Release Vars Array_ListaMesAno
EndIf
DynArray Array_ListaMesAno[]

{Ask} {ChequeI}
Moveto [Data Vencimento  ] Check
Moveto [Situacao         ] TypeIn "LIQUIDADO"
Do_It!
ClearAll

Rename "Answer" PrivDir()+"Temp000"

{Ask} {BordCHC}
Moveto [Data do Lote     ] Check
Do_It!
ClearAll

Add "Answer" PrivDir()+"Temp000"

If IsEmpty(PrivDir()+"Temp000")
   Then LimpAguarde()
        Return
EndIf

if istable("Keyviol") then delete "Keyviol" endif

{Modify} {Restructure} TypeIn PrivDir()+"Temp000" Enter
Right CtrlBackspace  "Data"
Down  "Mes" Enter  "a2" Enter  "Ano" Enter  "a4"
Do_It!

EditKey
Scan
  If Not IsBlank([Data])
     Then [Mes]=AlinhM(StrVal(Month([Data])),2)
          [Ano]=AlinhM(StrVal(Year([Data])),4)
  EndIf
EndScan
Do_It!
ClearAll

{Ask} TypeIn PrivDir()+"Temp000" Enter
Moveto [Mes] Check
Moveto [Ano] Check
Do_It!
ClearAll

Sort "Answer" on "Ano","Mes"

wcs=0
Scan
  wcs=wcs+1
  Array_ListaMesAno[wcs]=[Ano]+"_"+[Mes]
EndScan
ClearAll

LimpAguarde()
EndProc    ;  (Lista_MesAno)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DIRETORIOS"    : Campo="TG_EMPRESA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_DIRETORIOS"
                    Case Campo="TG_DIRETORIOS" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="":
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""

COR_MENSAGEM="1"
MSG=    "Antes de fechar um mˆs, observe se j //"
MSG=MSG+"existem lan‡amentos existentes no mˆs seguinte !// //"
MSG=MSG+"Fique atento a ordem crescente dos lan‡amentos//"
MSG=MSG+"pra que os mesmos n„o retrocedam !"
Mensagem(MSG)
Release Vars COR_MENSAGEM

While True
  Lista_MesAno()

  ShowDialog "Fechamento mensal [ Cheques/Terceiros ]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 04,17   Height 19 Width 75

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 0,09 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 0,16 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    PickDynArray @2,01 Height 12 width 69
     Columns 7
      Array_ListaMesAno
       Tag "TG_DIRETORIOS"                                           
        To ArrayElement
    Label @ 01,00 "Ano_Mes em aberto"  For "TG_DIRETORIOS"

    Pushbutton @ 15,24 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,38 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If DynArraySize(Array_ListaMesAno)<1
     Then Mensagem("Sem Mes/Ano p/ Fechar !")
          Loop
  EndIf

  ANO_MES=Array_ListaMesAno[ArrayElement]

  MES=Substr(ANO_MES,6,2)
  ANO=Substr(ANO_MES,1,4)
  If NumVal(ANO) < 2000
     Then MESANO=MES+"."+SubStr(ANO,3,2)
     Else MESANO=MES+"."+ANO
  EndIf

  If DirExists("\\Fechano\\"+ANO)<>0
     Then MSG="No fechamento Anual de "+ANO+" j  existem lan‡amentos arquivados !// //"
          MSG=MSG+Completa("Para poder fechar este mˆs, siga os passos:",70," ")+"// //"
          MSG=MSG+Completa("1) Restaure o ano de "+ANO+";",70," ")+"//"
          MSG=MSG+Completa("2) Aproveite e feche os mˆses de todos m¢dulos referente a "+ANO+";",70," ")+"//"
          MSG=MSG+Completa("   * Assim estes novos lan‡amentos ser„o agrupados aos",70," ")+"//"
          MSG=MSG+Completa("     lan‡amentos anteriores",70," ")+"//"
          MSG=MSG+Completa("3) Se necess rio feche novamente o ano de "+ANO+" !",70," ")
          Mensagem(MSG)
          Loop
  Endif

  If Not Verifica_Usuario() Then Loop EndIf
  Diretorio="\\Sistemas\\CheqRec\\"
  DiretorioFechames=Diretorio+"Fechames\\"+ANO+"_"+MES+"\\"
  If DirExists(Diretorio+"Fechames")=0
    Then Cria_Pasta(Diretorio+"FechaMes")
  EndIf
  If DirExists(Diretorio+"Fechames\\"+ANO+"_"+MES)=0
     Then Cria_pasta(Diretorio+"Fechames\\"+ANO+"_"+MES)
  EndIf

  ListadeTabelas()
  If (BloqueiaTabelas(Diretorio)) And
     (BloqueiaTabelas(DiretorioFechames))
     Then CHEQUES()
          BORDEROS()
  EndIf
  DesbloqueiaTabelas(Diretorio)
  DesbloqueiaTabelas(DiretorioFechames)

  LimpAguarde()
  Fastmsg("Fim de Opera‡„o !")

EndWhile
ClearAll
Release Vars All
Release Procs All
