;** Rm_0080 *******************************************************************
;*  Relatorio de Honorarios por Indice                                         *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 02/05/2007 por Anivel Augusto Rodrigues
;Ultima Alteracao: 21/03/2012 por Bruno Carvalho
;Motivo Alteracao: InlusÆo de um novo Modelo "RazÆo Social" (Anal¡tico)
;Ultima Alteracao: 01/11/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novos layout relatorios e tabela               
;Ultima Alteracao: 16/11/2015 por Bruno Carvalho
;Motivo Alteracao: Adicionado Modelo por CODIGO #0092# 
;Ultima Alteracao: 03/01/2017 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog MensagemRadioButtons()
;Ultima Alteracao: 04/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novos modelos e ordem               
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 10/07/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novos modelos e ordem               
;Ultima Alteracao: 07/01/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novo modelo 08                     

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc ORDEM()
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Empresas}
Moveto [Codigo da Empresa     ] TypeIn "_ce"
Moveto [Nome Fantasia Empresa ] Check
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                ] TypeIn "_cc"
Moveto [Nome Fantasia EmitDest] Check
Moveto [Razao Social          ] Check          
Moveto [Cidade                ] Check          
Moveto [UF                    ] Check          
Moveto [Telefone              ] Check          
Moveto [Contato               ] Check          
Moveto [Codigo Atividade      ] Check      
Moveto [Descricao Atividade   ] Check      
Moveto [Data_Cadastro         ] Check      
Moveto [Codigo do Cobrador    ] Check      
Moveto [Descricao do Cobrador ] Check      
{Ask} {Indice}
Moveto [Codigo do Indice      ] TypeIn "_ci"
Moveto [Valor do Indice       ] Check TypeIn "_vi"
{Ask} {CobClie} 
Moveto [Codigo do Cliente     ] Check TypeIn "_cc"
Moveto [Codigo da Empresa     ] Check TypeIn "_ce"
Moveto [Codigo do Indice      ] Check TypeIn "_ci"
Moveto [Formulario            ] Check
Moveto [Observacoes           ] Check
Moveto [Dia do Vencimento     ] Check
Switch
  Case VSDGSTATUS="1": TypeIn "Not Blank"
  Case VSDGSTATUS="2": TypeIn "Blank"
EndSwitch
Moveto [Indice do Salario     ] Check TypeIn "_is, calc (_is*_vi) as Valor Honorario"
Do_It!
ClearAll

MudaEstruturaDaTabelaPara("Answer","\\Base\\Sistemas\\Cobranca\\Rm_0020")


EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog1(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_STATUS"          : Campo="NO"
            Case Campo="TG_OPRELCODALFRANK" : Campo="TG_STATUS"
            Case Campo="TG_CODMODELO"       : Campo="TG_OPRELCODALFRANK"
            Case Campo="YES" Or Campo="NO"  : Campo="TG_STATUS"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_STATUS"          : Campo="TG_OPRELCODALFRANK"
                    Case Campo="TG_OPRELCODALFRANK" : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"       :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por %Indice")
ModeloRelatoriosAdd("02  Por UF/Cidade")
ModeloRelatoriosAdd("03  Por Data de cadastro")
ModeloRelatoriosAdd("05  Por Cobrador")
ModeloRelatoriosAdd("06  Por Atividade")
ModeloRelatoriosAdd("07  Por Dia Vencimento")
ModeloRelatoriosAdd("08  Por C¢digo de Indice")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("04  Simples")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
Sys_Valor()

If Not IsAssigned(SYS_CODIGO_CLIENTE) Then SYS_CODIGO_CLIENTE = "" EndIf
   
VSDGSTATUS          =""
VSDGOPRELCODALFRANK = ""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Relat¢rio de honor rios" Proc "SD_Dialog1"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 12 Width 72

    Label  @ 00,00 "Status do Cliente" For "TG_STATUS"
    Accept @ 01,04 Width 04 "A1"  Picture "1,2,3" Tag "TG_STATUS" To VSDGSTATUS
    Accept @ 01,09 Width 25 "A12" Picture "!*!" Tag "TG_NOMSTATUS" To VSDGNOMSTATUS

    Label  @ 02,00 "Op‡„o de Ordem" For "TG_OPRELCODALFRANK"
    Accept @ 03,04 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPRELCODALFRANK" To VSDGOPRELCODALFRANK
    Accept @ 03,09 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALFRANK" To VSDGNOMOPRELCODALFRANK

    Label  @ 05,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 06,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 06,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO  

    Pushbutton @ 08,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 08,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         
                       
  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando Relat¢rio")
  ORDEM()
  If IsEmpty("Answer")
     Then MENSAGEM("N„o Existem Registros a Processar")
          Loop
  EndIf

  Impressao_Orientacao="Paisagem"
  Switch
      Case VSDGCODMODELO="01"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "3" "Answer" "R"
                                                                    
      Case VSDGCODMODELO="02"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "1" "Answer" "R"
        
      Case VSDGCODMODELO="03"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "4" "Answer" "R" 

      Case VSDGCODMODELO="04"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "5" "Answer" "R"
        
      Case VSDGCODMODELO="05"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "6" "Answer" "R"

      Case VSDGCODMODELO="06"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "7" "Answer" "R"
        
      Case VSDGCODMODELO="07"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "8" "Answer" "R"
        
      Case VSDGCODMODELO="08"     :    
        CopyReport "\\Base\\Sistemas\\Cobranca\\Rm_0020" "9" "Answer" "R"
                                                                    
  EndSwitch    
  Switch
    Case VSDGOPRELCODALFRANK="2" : Seta_Ordem_Report("Answer","R","Codigo do Cliente","Nome Fantasia EmitDest","")
    Case VSDGOPRELCODALFRANK="3" : Seta_Ordem_Report("Answer","R","Codigo do Cliente","Valor Honorario"       ,"D")
    OtherWise                    : Seta_Ordem_Report("Answer","R","Codigo do Cliente","Codigo do Cliente"     ,"")
  EndSwitch

  IMPRIREL("Answer","R")

  Delete "Answer"
EndWhile
ClearAll
Release Vars All
Release Procs All
