;** Categoria ******************************************************************
;*  Manutencao Cadastro de Categoria                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 11/01/2019 por Bruno Carvalho               
;Ultima Alteracao:   /  /     por                          
;Motivo Alteracao: 

;*******************************************************************************
;* Rotina para Localizar Registro                                              *
;*******************************************************************************
Proc CHAVE()
While true
  Moveto [Codigo da Categoria]
  End
  SEQ = [Codigo da Categoria]
  Down
  
  While true
    SetaCorRegistro("Editar")
  
    TECLA=""
    AguardaTeclasPadrao()
  
    If Retval=-33
       Then
         ShowPopup " Fun‡”es " CENTERED
          "1-Descri‡Æo da Categoria" : " Aplicar altera‡„o da Descri‡„o para todos os itens" : "F5",
          "~C~ancelar              " : " Cancelar a Opera‡„o                               " : "CANCELAR"
         EndMenu
          To MenuVar
         echo off
  
         If MenuVar="CANCELAR" or MenuVar="Esc"
             Then Loop
         EndIf
         RetVal=MenuVar
    EndIf
  
    Switch
    Case RetVal="F3": SemFicha()
    Case RetVal="F5":
         ConfGeral("Aplicar as altera‡”es das descri‡äes no cadastro de Itens ?")
         If Ok="S"
          Then Atualiza_Itens()
               Quitloop
         EndIf
    Case RetVal=-94 : MsgTeclasPadrao()
    Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
         While True
           PAGINA("Categor","MR")
           If EDITAR="S"
              Then CHAVE=0
                   Controla_EdicaoC()
              Else If EXCLUIR="S"
                      then If QuerExcluir("")
                              Then Del
                              Else UnLockRecord
                           EndIf
                      Else QuitLoop
                   EndIf
           EndIf
           SetaPosForm()
         EndWhile
         QuitLoop
    Case Retval="ESC":
         CHAVE=9
         Del
         Return  
    Case Retval="ENTER":
         If IsBlank([])
            Then If IsBlank(SEQ)
                    Then SEQ="1"
                    Else SEQ=StrVal(NumVal(SEQ)+1)
                  EndIf
                  []=SEQ
         EndIf
         []=ALINH()
         CODIGO=[]
         Del
         Locate CODIGO
         If Retval
            Then CHAVE=0
            Else CHAVE=1
                 End Down
                 [Codigo da Categoria]=CODIGO
         EndIf
         If IsLockRecord()
            Then QuitLoop
         EndIf
         Return  
    EndSwitch
  EndWhile
EndWhile
EndProc

;*******************************************************************************
;* Rotina para Digitacao das Informacoes                                       *
;*******************************************************************************
Proc DIGITA()

Moveto [Descricao da Categoria]
While True

      TECLA=" Esc=Retornar  "

      If CHAVE=0
         Then TECLA=TECLA+"Del=Excluir  "
      EndIf

      Prompt TECLA
      SetaCorRegistro("Editando")
      
      Wait Field
           Message Field()
           Until "ESC","ENTER","DEL","FIELDVIEW","F35"

      Switch

      Case Retval="ESC":
           Switch
                 Case Field()="Descricao da Categoria":
                      If QuerDesfazer("")
                         Then If CHAVE=1
                                 Then DEL
                                 Else Undo
                              Endif
                              CHAVE=9
                              QuitLoop
                      EndIf
                 OtherWise:
                      Left
           EndSwitch
      Case Retval="ENTER":
           Switch
                 Case Field()="Descricao da Categoria"   :
                      If IsBlank([])Then Loop EndIf
                      QuitLoop     
                 OtherWise:
                      Right
           EndSwitch
      Case Retval="FIELDVIEW" or Retval="F35":
           EDITFIELD()
      Case Retval="DEL":
           If CHAVE=0
              Then If QuerExcluir("")
                      Then Del
                           QuitLoop
                   EndIf
           EndIf
      EndSwitch
EndWhile
EndProc

;*******************************************************************************
;* Rotina para Atualizar Itens                                                 *
;*******************************************************************************
Proc Atualiza_Itens()
Private codant, codok, cod

Do_It!
ClearAll

codant="****"

NR = NRecords("Iten_Com")
CoEdit "Iten_Com"
Moveto [Codigo da Categoria]
Scan
  Barra(NR, RecNo())
  Aguarde("Aguarde, atualizando itens "+BARRA_STRING)

  If [Codigo da Categoria]<>codant
     Then codant=[Codigo da Categoria]
          If Busca_Lookup("Codigo da Categoria",[Codigo da Categoria],"SM")
             Then codok=true
             Else codok=false
          EndIf
  EndIf
  If codok
     Then cod=[Codigo da Categoria]
          [Codigo da Categoria]=""
          [Codigo da Categoria]=cod
  EndIf        

EndScan
Do_It!
ClearAll

CoEdit "Categoria"
PickForm "F"

FastMsg("Fim do processo")
EndProc

;*******************************************************************************
;* Rotina para Atualizar Itens                                                 *
;*******************************************************************************
Proc Atualiza_Itens2()
Private codant, codok, cod

Do_It!
ClearAll

codant="****"

NR = NRecords("Iten_Com")
CoEdit "Iten_Com"
Moveto [Codigo da Categoria]
Scan
  Barra(NR, RecNo())
  Aguarde("Aguarde, atualizando itens "+BARRA_STRING)

  If [Codigo da Categoria]<>codant
     Then codant=[Codigo da Categoria]
          If Busca_Lookup("Codigo da Categoria",[Codigo da Categoria],"SM")
             Then codok=true
             Else codok=false
          EndIf
  EndIf
EndScan
Do_It!
ClearAll

CoEdit "Categor"
PickForm "F"

FastMsg("Fim do processo")
EndProc

;*******************************************************************************
;* Rotina para controlar Edicao do registro                                    *
;*******************************************************************************
Proc Controla_EdicaoC()
DIGITA()
If RecordStatus("Locked") Then UnLockRecord EndIf         
EndProc

;*************************************************
;* Rotina Principal                              *
;*************************************************
AutoLib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"

CoEdit "Categor"
PickForm "F"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
  Controla_EdicaoC()
EndWhile
Do_It!
ClearAll

Release Vars All
Release Procs All
