;** Rm_0050b *******************************************************************
;*  Emissao da Apuracao da Comissao Mod. II                                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 16/07/2009 por Nikolas
;Ultima Alteracao: 12/01/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes estrutura rm_0050 descricao/unidade
;Ultima Alteracao: 29/04/2010 por Cleber Alves            
;Motivo Alteracao: ".." VSDGGERENCIA
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 11/04/2014 por Bruno/Gustavo
;Motivo Alteracao: Ajustes p/ Inclusao de Rateio de Comissao de Representante
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado op‡Æo para filtrar por rateio de comissao de representante
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado CHECK "Item do Documento" no processo dos itens (Codigo e Qtd Iguais)
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 31/07/2014 por Bruno Carvalho
;Motivo Alteracao: Comentado op‡Æo para incluir PEDIDO na comissÆo, pois duplicava lan‡amento 
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes gerar comissao 

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas/Devolu‡äes/Pedido *******
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC") 
   Then ;---- Pedido -----------------------------------------------------------
        ;If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC")
        ;   Then OPCAO = 3
        ;   Else OPCAO = 2
        ;EndIf
        
        ;---- Se Cliente desejar incluir PEDIDO, informar por SYS_CODIGO_CLIENTE
        OPCAO = 2
        
        For wi2 From 1 To OPCAO 
         For wi From INICIO_RATEIO To FIM_RATEIO 
          {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
          Moveto [Codigo do Representante] Example "crep"
          If Not IsBlank(VSDGGERENCIA)
              Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
              Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           EndIf
                  
           If wi = 2 
              Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC" Enter
                    Moveto [Codigo da Empresa        ] Example "a"
                    Moveto [Numero do Documento      ] Example "b"
                    Moveto [Serie do Documento       ] Example "c"
                    Moveto [Item do Documento        ] TypeIn "0"
                    Moveto [Codigo do Representante  ] Check TypeIn "_crep, ~VSDGREPRESEN.."
                    Moveto [Nome Fantasia Represent  ] Check
                    Moveto [Comissao do Representante] Check
           EndIf
            
            {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
            Moveto [Codigo da Empresa      ] Check Example "a" TypeIn ", ~VSDGEMPRESA.."
            Moveto [Numero do Documento    ] Check Example "b"
            Moveto [Serie do Documento     ] Check Example "c"
            Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
            Moveto [Situacao               ] TypeIn "Not C"
            Moveto [Nome Fantasia Empresa  ] Check
            Moveto [Codigo                 ] Check
            Moveto [Nome Fantasia EmitDest ] Check
            Moveto [Razao Social           ] Check
            Moveto [Numero da OF           ] Check
            Moveto [Numero do Pedido       ] Check

            Switch
              Case wi2 = 1 :
                   Moveto [Descricao da Destinacao  ] TypeIn "..VEND.." 
                   Moveto [Tipo Movimento Estoque   ] TypeIn "S"
              Case wi2 = 2 :
                   Moveto [Descricao da Destinacao  ] TypeIn "..DEVOL.."
                   Moveto [Tipo Movimento Estoque   ] TypeIn "E"
              Case wi2 = 3 :                           
                   ;---- Pedido ------------------------------------------------
                   Moveto [Descricao da Destinacao  ] TypeIn "..VEND.." 
                   Moveto [Tipo Movimento Estoque   ] TypeIn "S"
                   Moveto [Numero do Pedido         ] Example "np"
            EndSwitch     
                   
            If wi = 1
               Then Moveto [Codigo do Representante  ] Check TypeIn "_crep, ~VSDGREPRESEN.."
                    Moveto [Nome Fantasia Represent  ] Check
                    Moveto [Comissao do Representante] Check
            EndIf      

            {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
            Moveto [Codigo da Empresa      ] Example "a"
            Moveto [Numero do Documento    ] Example "b"
            Moveto [Serie do Documento     ] Example "c"
            Moveto [Item do Documento      ] Check
            Moveto [Codigo do Item         ] Check
            Moveto [Descricao do Item      ] Check
            Moveto [Quantidade             ] Check
            Moveto [Unidade Fiscal         ] Check
            Moveto [Preco Total            ] Check
            Moveto [Valor Desconto Total   ] Check
            Moveto [Situacao_Item          ] TypeIn "Not C"
            If wi2 = 3 
               Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
                    Moveto [Codigo da Empresa      ] Example "a"
                    Moveto [Numero do Pedido       ] Example "np"
                    Moveto [Numero Pedido Origem   ] Check
            EndIf 
            Do_It!
            ClearAll
            
            {Ask} {Answer}
            Moveto [Codigo da Empresa      ] Example "a"
            Moveto [Numero do Documento    ] Example "b"
            Moveto [Serie do Documento     ] Example "c"
            Moveto [Codigo do Representante] Example "d"
            Moveto [Data de Emissao        ] Example "e"
            Moveto [Nome Fantasia Empresa  ] Example "ne"
            Moveto [Nome Fantasia Represent] Example "nr"
            Moveto [Codigo                 ] Example "cc"
            Moveto [Nome Fantasia EmitDest ] Example "nc"
            Moveto [Razao Social           ] Example "rz"
            Moveto [Numero da OF           ] Example "no"
            Moveto [Codigo do Item         ] Example "f"
            Moveto [Descricao do Item      ] Example "descr"
            Moveto [Quantidade             ] Example "g"
            Moveto [Unidade Fiscal         ] Example "uf"
            Moveto [Preco Total            ] Example "h"
            Moveto [Valor Desconto Total   ] Example "i"
            If wi2 = 3
               Then Moveto [Numero do Pedido    ] Example "np"
                    Moveto [Numero Pedido Origem] Example "op"            
            EndIf        

            {Ask} TypeIn Tabela Enter  TypeIn "Fast Insert"
            Switch
              Case wi2 = 1 Or  wi2 = 3 : Moveto [Operacao] TypeIn "\"Vendas\"" 
              Case wi2 = 2             : Moveto [Operacao] TypeIn "\"Devolucoes\""
            EndSwitch  
            Moveto [Codigo da Empresa      ] Example "a"
            Moveto [Numero do Documento    ] Example "b"
            Moveto [Serie do Documento     ] Example "c"
            Moveto [Codigo do Representante] Example "d"
            Moveto [Data de Emissao        ] Example "e"
            Moveto [Nome Fantasia Empresa  ] Example "ne"
            Moveto [Nome Fantasia Represent] Example "nr"
            Moveto [Codigo                 ] Example "cc"
            Moveto [Nome Fantasia EmitDest ] Example "nc"
            Moveto [Razao Social           ] Example "rz"
            Moveto [Numero da OF           ] Example "no"
            Moveto [Codigo do Item         ] Example "f"
            Moveto [Descricao do Item      ] Example "descr"
            Moveto [Unidade Fiscal         ] Example "uf"
            Moveto [Aliquota Comissao      ] TypeIn "~VSDGTAXAC"
            Switch
              Case wi2 = 1 Or
                   wi2 = 3  : If wi2 = 3 
                                 Then Moveto [Numero do Pedido    ] Example "np"
                                      Moveto [Numero Pedido Origem] Example "op"
                              EndIf
                              Moveto [Quantidade          ] Example "g"
                              Moveto [Preco Total         ] Example "h" TypeIn "-" Example "i"
                              Moveto [Comissao            ] TypeIn "(("Example "h" TypeIn "-" Example "i" TypeIn ")*~VSDGTAXAC)/100"
              Case wi2 = 2  : Moveto [Quantidade          ] Example "g" TypeIn "*-1"
                              Moveto [Preco Total         ] TypeIn "(" Example "h" TypeIn "-" Example "i" TypeIn ")*-1"
                              Moveto [Comissao            ] TypeIn "((("Example "h" TypeIn "-" Example "i" TypeIn ")*~VSDGTAXAC)/100)*-1"
            EndSwitch  
            Do_It!
            ClearAll
          EndFor    
        Endfor
EndIf

;****** Devolu‡”es *******
If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
        Moveto [Numero do Lancamento   ] Example "x"
        Moveto [Codigo da Empresa      ] CheckPlus TypeIn "~VSDGEMPRESA.."
        Moveto [Numero do Documento    ] CheckPlus
        Moveto [Serie do Documento     ] CheckPlus
        Moveto [Codigo do Representante] CheckPlus Example "crep" TypeIn ", ~VSDGREPRESEN.."
        Moveto [Data de Entrada        ] CheckPlus TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo de Operacao       ] TypeIn "D"
        Moveto [Nome Fantasia Empresa  ] CheckPlus
        Moveto [Nome Fantasia Represent] CheckPlus
        Moveto [Codigo                 ] CheckPlus
        Moveto [Nome Fantasia EmitDest ] CheckPlus
        Moveto [Razao Social           ] CheckPlus
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
        Moveto [Numero do Lancamento   ] Example "x"
        Moveto [Codigo do Item         ] CheckPlus
        Moveto [Descricao do Item      ] CheckPlus
        Moveto [Quantidade             ] CheckPlus
        Moveto [Unidade Fiscal         ] CheckPlus
        Moveto [Preco Total            ] CheckPlus
        Moveto [Valor Desconto Total   ] CheckPlus
        Do_It!
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo da Empresa      ] Example "a"
        Moveto [Numero do Documento    ] Example "b"
        Moveto [Serie do Documento     ] Example "c"
        Moveto [Codigo do Representante] Example "d"
        Moveto [Data de Entrada        ] Example "e"
        Moveto [Nome Fantasia Empresa  ] Example "ne"
        Moveto [Nome Fantasia Represent] Example "nr"
        Moveto [Codigo                 ] Example "cc"
        Moveto [Nome Fantasia EmitDest ] Example "nc"
        Moveto [Razao Social           ] Example "rz"
        Moveto [Codigo do Item         ] Example "f"
        Moveto [Descricao do Item      ] Example "descr"
        Moveto [Quantidade             ] Example "g"
        Moveto [Unidade Fiscal         ] Example "uf"
        Moveto [Preco Total            ] Example "h"
        Moveto [Valor Desconto Total   ] Example "i"

        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Operacao               ] TypeIn "\"Devolucoes\""
        Moveto [Codigo da Empresa      ] Example "a"
        Moveto [Numero do Documento    ] Example "b"
        Moveto [Serie do Documento     ] Example "c"
        Moveto [Codigo do Representante] Example "d"
        Moveto [Data de Emissao        ] Example "e"
        Moveto [Nome Fantasia Empresa  ] Example "ne"
        Moveto [Nome Fantasia Represent] Example "nr"
        Moveto [Codigo                 ] Example "cc"
        Moveto [Nome Fantasia EmitDest ] Example "nc"
        Moveto [Razao Social           ] Example "rz"
        Moveto [Codigo do Item         ] Example "f"
        Moveto [Descricao do Item      ] Example "descr"
        Moveto [Quantidade             ] Example "g" TypeIn "*-1"
        Moveto [Unidade Fiscal         ] Example "uf"
        Moveto [Preco Total            ] TypeIn "(" Example "h" TypeIn "-" Example "i" TypeIn ")*-1"
        Moveto [Comissao               ] TypeIn "((("Example "h" TypeIn "-" Example "i" TypeIn ")*~VSDGTAXAC)/100)*-1"
        Moveto [Aliquota Comissao      ] TypeIn "~VSDGTAXAC"
        Do_It!
        ClearAll
EndIf

EndProc   ;  (Seleciona)

;*******************************************************************************
;* Rotina para processar Db temporaria                                         *
;*******************************************************************************
Proc Processa()

;****** Taxa Administrativa sobre Devolucoes *******
If Not VSDGTAXAD>0
   Then Return
EndIf

{Ask} TypeIn Tabela Enter
Moveto [Operacao               ] Check TypeIn "Devolucoes"
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Preco Total            ] Example "h"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Operacao               ] TypeIn "\"Administr.\""
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Nome Fantasia EmitDest ] TypeIn "\"SOBRE DEVOLUCOES\""
Moveto [Razao Social           ] TypeIn "\"SOBRE DEVOLUCOES\""
Moveto [Comissao               ] TypeIn "(" Example "h" TypeIn "*~VSDGTAXAD)/100"
Moveto [Aliquota Comissao      ] TypeIn "~VSDGTAXAD"
Do_It!
ClearAll

EndProc   ; (Processa)

;*******************************************************************************
;* Rotina p/                                                                   *
;*******************************************************************************
Proc GeraComissao()
ClearAll


;-------------

PC_0000_AquivoDeParametrosGeraComissao="PC_0050B" ; informar o Rm_XXXX como PC_XXXX nÆo esquecer 
Play "PC_0000"

;-------------

EndProc     

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESA"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_TAXAC"         : Campo="TG_GERENCIA"
            Case Campo="TG_TAXAD"         : Campo="TG_TAXAC"
            Case Campo="TG_DTINI"         : Campo="TG_TAXAD"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPCAO"         : Campo="TG_DTFIM"
            Case Campo="TG_COMISSAO"      : Campo="TG_OPCAO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN":Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA":Campo="TG_TAXAC"
                    Case Campo="TG_TAXAC":
                         VSDGTAXAC=ControlValue("TG_TAXAC")
                         If Not IsBlank(VSDGTAXAC) Or VSDGTAXAC >= 0
                            Then Campo="TG_TAXAD"
                         EndIf
                    Case Campo="TG_TAXAD"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="TG_OPCAO"
                    Case Campo="TG_OPCAO"   : Campo="TG_COMISSAO"
                         VSDGOPCAO = ControlValue("TG_OPCAO")
                         Switch
                           Case VSDGOPCAO = "2" : VSDGNOMOPCAO = "COM RATEIO"
                           Case VSDGOPCAO = "3" : VSDGNOMOPCAO = "APENAS RATEIO"
                           OtherWise            : VSDGOPCAO = "1" 
                                                  VSDGNOMOPCAO = "SEM RATEIO"
                         EndSwitch                  
                    Case Campo="TG_COMISSAO" : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPCAO":
     MSG_CAMPO="1=SEM RATEIO  2=COM RATEIO  3=APENAS RATEIO"
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_TAXAC":
     MSG_CAMPO="Informe a Taxa de Comiss„o"
  Case Campo="TG_OPBONIF":
     MSG_CAMPO="Defina a op‡„o"
     TECLA="Barra de Espa‡o=Marca/Desmarca  "
  Case Campo="TG_COMISSAO":
       MSG_CAMPO="Defina a op‡„o"
       TECLA="Barra de Espa‡o=Marca/Desmarca  "
     
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

sys_valor()

VSDGEMPRESA  = ""
VSDGREPRESEN = ""
VSDGGERENCIA = ""
VSDGOPCAO    = ""
VSDGNOMOPCAO = ""
VSDGTAXAC    = BlankNum()
VSDGTAXAD  	 = BlankNum()
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()

Array TG_OPBONIF[1]
TG_OPBONIF[1]="Deduz Bonfica‡”es das Vendas"

Array TG_COMISSAO[1]
TG_COMISSAO[1]="Gera comiss„o Contas a Pagar"

Array CheckTG_COMISSAO[ArraySize(TG_COMISSAO)]
CheckTG_COMISSAO[1]=False

While True

  ShowDialog "Apura‡„o de Comiss„o p/ Repres.- % Fixa II" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

		Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 06,08 "% Comiss„o"  For "TG_TAXAC"
    Accept @ 07,09 Width 12 "N" Tag "TG_TAXAC" To VSDGTAXAC

    Label  @ 06,21 "% Devoluc„o"  For "TG_TAXAD"
    Accept @ 07,22 Width 12 "N" Tag "TG_TAXAD" To VSDGTAXAD

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Rateio de Comiss„o" For "TG_OPCAO"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPCAO" To VSDGOPCAO
    Accept @ 01,44 Width 25 "A30" Picture "!*!" Tag "TG_NOMOPCAO" To VSDGNOMOPCAO

    CheckBoxes @ 03,35 Height 1 Width 35 Tag "TG_COMISSAO"
    TG_COMISSAO[1] to CheckTG_COMISSAO[1]        

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue


  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Usuario_Vendedor() Then Loop EndIf  

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  Switch
    Case VSDGOPCAO = "1" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 1
    Case VSDGOPCAO = "2" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 2
    Case VSDGOPCAO = "3" : INICIO_RATEIO = 2
                           FIM_RATEIO    = 2
  EndSwitch   

	DISPOSITIVO()
	If OK="" Then Loop EndIf

	AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0050b"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0050b" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()    
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  if CheckTG_COMISSAO[1]
     then
          GeraComissao()
     else
          IMPRIREL(Tabela,"R")
  endif        

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
