;** ZeraEstoq ******************************************************************
;*  Gera requisi‡Æo para zeramamento de estoque                                *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 15/02/2010 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/12/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao:  Ajustes 
;Ultima Alteracao: 20/09/2011 por Karina Andrade
;Motivo Alteracao:  Add filtro por Marca ShowDialog
;Ultima Alteracao: 01/02/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes descricao do movimento/operacao
;Ultima Alteracao: 30/05/2016 por Bruno Carvalho 
;Motivo Alteracao: Adaptado processo para gera‡Æo do [Numero do Lancamento] "Interno"                       
;Ultima Alteracao: 14/03/2019 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes Numero_Lancamento("Interno","Locked_Down")

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] TypeIn "_ite"
Moveto [Codigo da Marca       ] Check TypeIn "~VSDGMARCA.."
Moveto [Tipo do Item          ]
Switch
   Case VSDGTIPOEST = "1"       : TypeIn "E or M or O or A or S"
   Case VSDGTIPOEST = "2"       : TypeIn "P or T"
   Case Not IsBlank(VSDGTIPOEST): TypeIn "~VSDGTIPOEST"
   OtherWise                    : TypeIn "Not C, Not D, Not F, Not G, Not H, Not I"
EndSwitch
{Ask} {\\Sistemas\\Estoque\\SdEstq}
Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Item        ] Check TypeIn "_ite"
Moveto [Ano Referencia        ] Check TypeIn "~ANO"
Moveto [Mes Referencia        ] Check TypeIn "~MES"
Moveto [Saldo Atual           ] Check
Moveto [Custo Total Atual     ] Check
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

NR = NRecords("Answer")
ReqOK=False

For wi From 1 to 2
  ini   =true
  QTDTOT=0
  VRTOT =0
  SEQ   =0

  Coedit "RqCabeca","RqItem","Answer"   
  Scan 

    Barra(NR, RecNo())
    Switch
      Case wi=1: Aguarde("Processando 1/2 Saidas "+BARRA_STRING)
      Case wi=2: Aguarde("Processando 2/2 Entradas "+BARRA_STRING)
    EndSwitch

    If ([Saldo Atual       ]=0 Or IsBlank([Saldo Atual       ])) And
       ([Custo Total Atual ]=0 Or IsBlank([Custo Total Atual ]))
       Then Loop
    EndIf   

    Switch
      Case wi=1:
        If [Saldo Atual]<0
           Then Loop
        EndIf
      Case wi=2:
        If [Saldo Atual]>=0
           Then Loop
        EndIf
    EndSwitch
  
    If ini
       then ini=false
       
            Moveto "RqCabeca"
            While True
              End
              Moveto [Numero do Lancamento]
              If Numero_Lancamento("Interno","Locked_Down")
                 Then NUMEROL = PROXLANCTO_NLANC
                      Release Vars PROXLANCTO_NLANC
                      quitloop
              EndIf    
            EndWhile
       
           ;While True
           ; Moveto "RqCabeca"
           ; End
           ; Moveto [Numero do Lancamento]
           ; If Numero_Lancamento("Interno","")
           ;    Then NUMEROL = PROXLANCTO_NLANC
           ;         Release Vars PROXLANCTO_NLANC
           ; EndIf
           ; Down
           ; [Numero do Lancamento  ]=NUMEROL
           ; If IsLockRecord()
           ;    Then Del
           ;         Loop
           ; EndIf
           ; QuitLoop
           ;EndWhile
           
            [Codigo da Empresa     ]=VSDGEMPRESA                 
            [Tipo de Operacao      ]="O"
            [Descricao da Operacao ]="OUTRAS"
            [Codigo do Documento   ]="REQ"
            [Numero do Documento   ]="ZERAMENTO"
            [Data de Ocorrencia    ]=VSDGDTREF                   
            Switch
              Case wi=1: [Tipo de Movimento     ]="S"
                         [Descricao do Movimento]="SAIDA"
                         [Descricao Requisitante]="ZERA ESTOQUE SAIDAS"
              Case wi=2: [Tipo de Movimento     ]="E"
                         [Descricao do Movimento]="ENTRADA"
                         [Descricao Requisitante]="ZERA ESTOQUE ENTRADAS"
            EndSwitch 
            Controle_Dia()
            [Codigo_Usuario        ]="9999"
            UnLockrecord
    Endif
  
    Moveto "\\Sistemas\\Estoque\\RqItem"

    End
    Down
    SEQ=SEQ+1
    [Numero do Lancamento       ]=NUMEROL
    [Sequencia do Lancamento    ]=SEQ
    [Codigo da Empresa          ]=VSDGEMPRESA
    [Codigo do Item             ]=[Answer->Codigo do Item]
    Switch
      Case wi=1: 
        [Quantidade         ]=[Answer->Saldo Atual       ]
        [Custo Total        ]=[Answer->Custo Total Atual ]
      Case wi=2: 
        [Quantidade         ]=[Answer->Saldo Atual       ]*-1
        [Custo Total        ]=[Answer->Custo Total Atual ]*-1
    EndSwitch
    
    If [Quantidade]>0
       Then [Custo Unitario             ]=NDecimal([Custo Total]/[Quantidade],5)
       Else [Custo Unitario             ]=[Custo Total]
    EndIf
  
    QTDTOT=QTDTOT+[Quantidade ]
    VRTOT =VRTOT +[Custo Total]
    UnLockrecord
  
    Moveto "Answer"
  
  EndScan
  
  If SEQ>0
     Then 
          ReqOK=True
          
          Moveto "\\Sistemas\\Estoque\\RqCabeca"
          Moveto [Numero do Lancamento]
          Locate NUMEROL
          If RetVal
             Then [Quantidade Total         ]=QTDTOT
                  [Valor Total              ]=VRTOT
                  UnLockRecord
          EndIf
  EndIf
  Do_It!
  ClearAll
EndFor

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_TIPOEST"       : Campo="TG_EMPRESA"
            Case Campo="TG_MARCA"         : Campo="TG_TIPOEST"
            Case Campo="TG_MESANO"        : Campo="TG_MARCA"
            Case Campo="TG_DTREF"         : Campo="TG_MESANO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :
                         If Not IsBlank(VSDGEMPRESA)
                            Then  Campo="TG_TIPOEST"
                            Else VSDGNOMEMP=""
                         Endif
                    Case Campo="TG_TIPOEST": Campo="TG_MARCA"
                    Case Campo="TG_MARCA"  : Campo="TG_MESANO"
                    Case Campo="TG_MESANO" : Campo="TG_DTREF"
                    Case Campo="TG_DTREF"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_EMPRESA":
     MSG_CAMPO="Informe uma Empresa"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA     =""
VSDGTIPOEST     = ""
VSDGDESCTIPOEST = ""
VSDGMARCA       =""
VSDGMESANO      =""
VSDGDTREF       =BlankDate()

MENSAGEM("Antes de executar esta rotina,// reprocessar estoque da Empresa/Ano/Mˆs desejado !")

While True
  ShowDialog "Gera requisi‡äes para zeramento do Estoque" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 13 Width 56

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Tipo do Estoque"  For "TG_TIPOEST"
    Accept @ 03,04 Width 04 "A1"  Picture "!" Tag "TG_TIPOEST" To VSDGTIPOEST
    Accept @ 03,09 Width 25 "A30"  Picture "!*!" Tag "TG_DESCTIPOEST" To VSDGDESCTIPOEST

    Label  @ 04,00 "Marca"  For "TG_MARCA"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 05,09 Width 33 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 06,00 "Mes/Ano" For "TG_MESANO"
    Accept @ 07,01 Width 13 "A7"  Picture "##;.####" Tag "TG_MESANO" To VSDGMESANO

    Label  @ 06,18 "Data p/ requisi‡Æo" For "TG_DTREF"
    Accept @ 07,19 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Pushbutton @ 09,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If VSDGEMPRESA="" Or
     VSDGEMPRESA="9999"
     Then Mensagem("Empresa Invalida !")
          Loop
  EndIf

  MES=Substr(VSDGMESANO,1,2)
  ANO=Substr(VSDGMESANO,4,4)
  If NumVal(MES) > 12 Or NumVal(MES) <= 0
     Then Loop
  EndIf

  If Month(VSDGDTREF)<>NumVal(MES) Or
      Year(VSDGDTREF)<>NumVal(ANO) 
     Then MENSAGEM("Data requisi‡Æo difere Mes/Ano informado !")
          Loop
  EndIf

  AGUARDE("Aguarde, Gerando requisi‡äes")
  SELECIONA()
  If IsEmpty("Answer")
     Then MENSAGEM("Nao Existe Registros a Processar !")
     Else If ReqOk
             Then MENSAGEM("Fim do processo, gerou Requisi‡Æo !// // Reprocessar estoque e verificar invent rio !")
             Else MENSAGEM("Fim do processo, nÆo gerou Requisi‡Æo !")
          Endif
  EndIf

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
