;** Et_Z014 ********************************************************************
;* Monta Etiqueta p/ Impressora Termica - Zebra - EAN13             ** GDA **  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/08/2012 por Bruno Carvalho
;Ultima Alteracao: 27/08/2012 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo de COR por Descricao Complementar "DITEA2"
;Ultima Alteracao: 29/08/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes Caracteres "Descricao Complementar" e incluido "Codigo do Item"
;Ultima Alteracao: 30/08/2012 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo do Logo (Em Letras) de "GDA" p/ "FUNDICAO GDA"  
;Ultima Alteracao: 21/09/2012 por Bruno Carvalho
;Motivo Alteracao: Ajsutes para corre‡Æo da impressÆo e add logo p/ impressÆo na etiqueta
;Ultima Alteracao: 07/11/2018 por Bruno Carvalho
;Motivo Alteracao: Adicionado Array CITEM[] p/ um melhor controle de impressÆo ao montar -> "P"+StrVal(CR) 

;*******************************************************************************
Proc Monta_Etiqueta()
Moveto "Answer"

Print File Arquivo "O\n"
Print File Arquivo "N\n"
Print File Arquivo "q831\n"
Print File Arquivo "Q631,024\n"
Print File Arquivo "S2\n"
Print File Arquivo "D8\n"
Print File Arquivo "ZT\n"     

If Not IsBlank(CITEM[1])           
   Then Print File Arquivo "A709,38,1,1,3,1,N,\""+DITEA1[1]+"\"\n"
        Print File Arquivo "B652,116,1,E30,3,6,128,B,\""+CDBAR[1]+"\"\n"
        Print File Arquivo "A482,38,1,1,3,1,N,\""+DITEA2[1]+"\"\n"   
        Print File Arquivo "GG734,192,\""+"LO_0199"+"\"\n"        
EndIf

If Not IsBlank(CITEM[2])
   Then Print File Arquivo "A293,38,1,1,3,1,N,\""+DITEA1[2]+"\"\n"
        Print File Arquivo "B236,110,1,E30,3,6,128,B,\""+CDBAR[2]+"\"\n"
        Print File Arquivo "A66,38,1,1,3,1,N,\""+DITEA2[2]+"\"\n" 
        Print File Arquivo "GG318,192,\""+"LO_0199"+"\"\n" 
EndIf

If CITEM[1]=CITEM[2]
   Then Print File Arquivo "P"+StrVal(CR)+"\n"
        ce=ce+((CR-1)*3)
   Else Print File Arquivo "P1\n"
EndIf

ne=2
EndProc

;*******************************************************************************
;* Monta Comandos p/ Impressora Termica                                        *
;*******************************************************************************
Proc Monta_Comandos()

; **** Para essa impressÆo, que ‚ USB, ‚ necess rio compartolhar a impressora, e 
;      ap¢s isso, capturar essa impressora no sistema em uma das portas LPT, como
;      a baixo estamos usando a LPT3, temos que capturar a impressora ZEBRA nessa porta.
; Se tiver problemas ao imprimir na LPT3, tente entÆo adicionar a impressora na LPT2

Comando="Copy "+Directory()+"LOGO\\LO_0199.txt"+" + "+Directory()+"LOGO\\LO_0199.pcx LPT3 /b"
@ 22,00 Run NoRefresh Comando
Sleep 1000

If IsAssigned(CITEM)
   Then Release Vars CITEM, DITEA1,DITEA2,CDBAR 
EndIf  
Array  CITEM[2]
Array DITEA1[2]
Array DITEA2[2]
Array  CDBAR[2]
       
Arquivo="et_Z014.ejf"
Deleta_Arquivo(Arquivo)
       
ne=2   
       
Coedit "Answer"
Scan   
  te=[Quantidade]
  If (te-(2-ne))>2
     Then CR=Int((te-(2-ne))/2)
     Else CR=1
  EndIf
  ce=0 
  While True
    ce=ce+1
    ne=ne+1
    If ne=3
       Then For i From 1 To 2
               CITEM[i]=""
              DITEA1[i]=""
              DITEA2[i]=""
               CDBAR[i]=""
            EndFor
            ne=1
    EndIf
     CITEM[ne]=[Codigo do Item]
    DITEA1[ne]=[Codigo do Item]+" "+SubStr([Descricao do Item],01,30)
    DITEA2[ne]=SubStr([Descricao Complementar],01,48)
     CDBAR[ne]=[Codigo de Barras]
    ;COR[ne]  =[Descricao da Cor_Tecido]
    If ne=2   Then Monta_Etiqueta() EndIf
    If ce>=te Then QuitLoop         EndIf
  EndWhile
EndScan
If ne<2 Then Monta_Etiqueta() EndIf
Do_It!
ClearAll

ImpriArq(Arquivo)

Sleep 700
Deleta_Arquivo(Arquivo)
ClearAll
EndProc

Monta_Comandos()
Release Procs Monta_Etiqueta,Monta_Comandos
