;** Rm_0066 ********************************************************************
;*  Emissao dos Pedidos por Ordem de Data de Entrega e Produto - Resumo/Grade  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/02/2010 por Anivel Augusto Rodrigues
;Ultima Alteracao: 15/09/2010 por Karina Andrade
;Motivo Alteracao: Ajustes de criterios
;Ultima Alteracao: 16/02/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro Pedidos     
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW
;Ultima Alteracao: 06/12/2011 por Karina Andrade
;Motivo Alteracao: Corre‡Æo Report
;Ultima Alteracao: 31/10/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Adicionar_dados() e Ajustar_Dados()
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()

ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "item"
Moveto [Tipo do Item           ] CheckPLus
Moveto [Codigo da Familia      ] CheckPLus TypeIn "~VSDGFAMI.."
Moveto [Descricao da Familia   ] CheckPLus
Moveto [Codigo do Grupo        ] CheckPLus TypeIn "~VSDGGRP.."
Moveto [Descricao do Grupo     ] CheckPLus
Moveto [Codigo da Marca        ] CheckPLus TypeIn "~VSDGMARCA.."
Moveto [Descricao da Marca     ] CheckPLus
Moveto [Codigo da Grade        ] CheckPLus
Moveto [Referencia             ] CheckPLus TypeIn "~VSDGREFERENCIA.."

{Ask} {\\Sistemas\\Vendas\\Destin}
Moveto [Codigo da Destinacao  ] Example "cd"
Moveto [Tipo Movimento Estoque] TypeIn "S"

{Ask} {\\Sistemas\\Vendas\\PedidoC}
Moveto [Numero do Pedido      ] Example "Pedido"
Moveto [Codigo da Empresa     ] CheckPLus TypeIn "~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa ] CheckPLus
Moveto [Nome Fantasia EmitDest] CheckPLus
Moveto [Data de Entrega       ] CheckPLus TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
Moveto [Codigo da Destinacao  ] Example "cd"
Moveto [Situacao do Pedido    ] TypeIn "ABERTO"

{Ask} {\\Sistemas\\Vendas\\PedidoI}
Moveto [Numero do Pedido       ] CheckPLus Example "Pedido"
Moveto [Codigo do Item         ] CheckPLus example "item" TypeIn ",~VSDGITEM.."
Moveto [Descricao do Item      ] CheckPLus
Moveto [Codigo da Cor_Tecido   ] CheckPLus
Moveto [Descricao da Cor_Tecido] CheckPLus
Moveto [Tamanho                ] CheckPLus
Moveto [Quantidade             ] CheckPLus TypeIn ">" Example "qf"
Moveto [Quantidade Faturada    ] CheckPLus Example "qf"
Moveto [Unidade Fiscal         ] CheckPLus
Moveto [Preco Unitario         ] CheckPLus

Do_It!
ClearAll

EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Agrupar Itens nos tamanhos respectivos                            *
;*******************************************************************************
Proc AgrupaItens()
Array Array_TM[12]

Tabela=Cria_Temp(PrivDir())
Copy "\\Base\\Sistemas\\Faccao\\PosEstqG" Tabela

Sort "Answer" On "Referencia"

View "\\Sistemas\\Estoque\\TpGrade"
Coedit Tabela,"Answer"
COMPREF = "*****"

Scan
  AGUARDE("Aguarde, Agrupando Dados")

  If [Referencia] <> COMPREF 
     Then Verifica_Array_Grade()
          Moveto "Answer"
          COMPREF = [Referencia] 
  EndIF
  
  WSEMP = [Codigo da Empresa   ]
  WSREF = [Referencia          ]
  If VSDGOPANALISE="1"
     Then WSCOR = [Codigo da Cor_Tecido]
     Else WSCOR =""
  EndIf
  
  Moveto Tabela
  Moveto [Codigo da Empresa]
  Locate WSEMP,WSREF
  If Not RetVal
     Then End
          Down
          [Codigo da Empresa    ]=[Answer->Codigo da Empresa    ]
          [Codigo do Item       ]=WSREF+WSCOR
          [Referencia           ]=WSREF
          [Nome Fantasia Empresa]=[Answer->Nome Fantasia Empresa]
          If VSDGOPANALISE="1"
             Then [Descricao do Item      ]=Substr([Answer->Descricao do Item],1,27)
             Else [Descricao do Item      ]=Substr([Answer->Descricao do Item],1,23)
          EndIf
          [Unidade Interna      ]=[Answer->Unidade Fiscal       ]
          [Codigo da Familia    ]=[Answer->Codigo da Familia    ]
          [Descricao da Familia ]=[Answer->Descricao da Familia ]
          [Codigo do Grupo      ]=[Answer->Codigo do Grupo      ]
          [Descricao do Grupo   ]=[Answer->Descricao do Grupo   ]
          [Codigo da Marca      ]=[Answer->Codigo da Marca      ]
          [Descricao da Marca   ]=[Answer->Descricao da Marca   ]
          [Codigo da Grade      ]=[Answer->Codigo da Grade      ]
  EndIf
  
  Coluna=0
  For Wi from 1 to 12
    If Len(RTrim(SubStr(Array_TM[Wi],1,2)))=1
       Then If SubStr([Answer->Codigo do Item],10,1)=SubStr(Array_TM[Wi],1,1)
               Then Coluna=Wi
                    QuitLoop
            EndIf
       Else If SubStr([Answer->Codigo do Item],9,2)=SubStr(Array_TM[Wi],1,2)
               Then Coluna=Wi
                    QuitLoop
            EndIf
    EndIf
  EndFor

  Qtd=[Answer->Quantidade]-[Answer->Quantidade Faturada]

  Switch
    Case Coluna=0 : [Qtd1  ]=[Qtd1  ]+Qtd
    Case Coluna=1 : [Qtd1  ]=[Qtd1  ]+Qtd
    Case Coluna=2 : [Qtd2  ]=[Qtd2  ]+Qtd
    Case Coluna=3 : [Qtd3  ]=[Qtd3  ]+Qtd
    Case Coluna=4 : [Qtd4  ]=[Qtd4  ]+Qtd
    Case Coluna=5 : [Qtd5  ]=[Qtd5  ]+Qtd
    Case Coluna=6 : [Qtd6  ]=[Qtd6  ]+Qtd
    Case Coluna=7 : [Qtd7  ]=[Qtd7  ]+Qtd
    Case Coluna=8 : [Qtd8  ]=[Qtd8  ]+Qtd
    Case Coluna=9 : [Qtd9  ]=[Qtd9  ]+Qtd
    Case Coluna=10: [Qtd10 ]=[Qtd10 ]+Qtd
    Case Coluna=11: [Qtd11 ]=[Qtd11 ]+Qtd
    Case Coluna=12: [Qtd12 ]=[Qtd12 ]+Qtd
  EndSwitch
  
  [Pedidos    ]=[Pedidos    ]+Qtd

Moveto "Answer"
        
EndScan
Do_It!
ClearAll

EndProc ;AgrupaItens()

;*******************************************************************************
;* Rotina Monta Array Grade                                                     *
;*******************************************************************************
Proc Verifica_Array_Grade()

For Wh From 1 To 12
  Array_TM[Wh]="" 
EndFor

Moveto "\\Sistemas\\Estoque\\TpGrade"
Moveto [Codigo da Grade]
Locate [Answer->Codigo da Grade]
If Not RetVal
   Then Mensagem("Item "+[Answer->Codigo do Item]+" sem grade definida !")
        Return
EndIf

Array_TM[1] =LTrim(RTrim([Codigo Item1]))
Array_TM[2] =LTrim(RTrim([Codigo Item2]))
Array_TM[3] =LTrim(RTrim([Codigo Item3]))
Array_TM[4] =LTrim(RTrim([Codigo Item4]))
Array_TM[5] =LTrim(RTrim([Codigo Item5]))
Array_TM[6] =LTrim(RTrim([Codigo Item6]))
Array_TM[7] =LTrim(RTrim([Codigo Item7]))
Array_TM[8] =LTrim(RTrim([Codigo Item8]))
Array_TM[9] =LTrim(RTrim([Codigo Item9]))
Array_TM[10]=LTrim(RTrim([Codigo Item10]))
Array_TM[11]=LTrim(RTrim([Codigo Item11]))
Array_TM[12]=LTrim(RTrim([Codigo Item12]))

EndProc ;Verifica_Array_Grade()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_MARCA"          : Campo="TG_EMPRESA"
            Case Campo="TG_FAMI"           : Campo="TG_MARCA"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_ITEM"           : Campo="TG_GRP"
            Case Campo="TG_REFERENCIA"     : Campo="TG_ITEM" 
            Case Campo="TG_OPANALISE"      : Campo="TG_REFERENCIA" 
            Case Campo="TG_DTINI"          : Campo="TG_OPANALISE"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO" : Campo="TG_ITEM"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"   : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"    : Campo="TG_GRP"
                    Case Campo="TG_GRP"     : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"    : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA"  : Campo="TG_OPANALISE"
                    Case Campo="TG_OPANALISE"   : Campo="TG_DTINI"
                         VSDGOPANALISE=ControlValue("TG_OPANALISE")
                         Switch
                           Case VSDGOPANALISE="2": VSDGNOMOPANALISE="SO REFERENCIA"
                           OtherWise         : VSDGNOMOPANALISE="REFERENCIA+COR"
                                               VSDGOPANALISE="1"
                         EndSwitch
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_OPANALISE":
       MSG_CAMPO="1=Referencia+Cor  2=Referencia"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA=""
VSDGMARCA  =""
VSDGFAMI   =""
VSDGGRUP   =""
VSDGTPITEM = ""
VSDGDTINI  = BlankDate()
VSDGDTFIM  = BlankDate()
VSDGOPANALISE    = ""
VSDGNOMOPANALISE = ""
While True

  ShowDialog "Resumo de Item/Entrega II" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
  @ 05,12   Height 19 Width 55

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Marca"  For "TG_MARCA"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 03,09 Width 33 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 04,00 "Familia"  For "TG_FAMI"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 05,09 Width 33 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 06,00 "Grupo"  For "TG_GRP"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"    To VSDGGRP
    Accept @ 07,09 Width 33 "A30" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP

    Label  @ 08,00 "Item"  For "TG_ITEM"
    Accept @ 09,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 09,15 Width 37 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 10,00 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 11,01 Width 13 "A20" Picture "!*!" Tag "TG_REFERENCIA" To VSDGREFERENCIA

    Label  @ 10,15 "Op‡„o de An lise" For "TG_OPANALISE"
    Accept @ 11,16 Width 04 "A1"  Picture "1,2" Tag "TG_OPANALISE" To VSDGOPANALISE
    Accept @ 11,21 Width 31 "A25"  Picture "!*!" Tag "TG_NOMOPANALISE" To VSDGNOMOPANALISE

    Label  @ 12,00 "Per¡odo de Entrega" For "TG_DTINI"
    Label  @ 13,00 "de" For "TG_DTINI"
    Accept @ 13,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 13,17 "at‚" For "TG_DTFIM"
    Accept @ 13,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 15,14 width 11 "~O~k"      OK     Default Value "Ok"  Tag "YES" To BottonValue
    Pushbutton @ 15,28 width 11 "~C~ancela" CANCEL                     Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando Relat¢rio")
  
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar!")
          Loop
  EndIf

  AgrupaItens()
  CopyReport "\\Base\\Sistemas\\Faccao\\PosEstqG" "3" Tabela "R"

  IMPRIREL(Tabela,"R")

  Delete "Answer"
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
