;** Rm_3105 ********************************************************************
;* Posi‡Æo Ranking Pedidos/Corte                                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 03/05/2011 por Bruno Carvalho 
;Ultima Alteracao: 12/05/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novas fun‡äes para confec‡äes  
;Ultima Alteracao: 07/07/2011 por Karina Andrade
;Motivo Alteracao: Ajustes Periodo Referente = Data de Entrega  
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll                  

;Pedidos
{Ask} {\\Sistemas\\Vendas\\Destin}
Moveto [Codigo da Destinacao  ] Example "cd"
Moveto [Tipo Movimento Estoque] TypeIn "S"
                                     
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "Item"
Moveto [Codigo da Marca        ] CheckPlus TypeIn "~VSDGMARCA.."
Moveto [Descricao da Marca     ] CheckPlus 
Moveto [Referencia             ] CheckPlus TypeIn "~VSDGREFERENCIA.."

{Ask} {\\Sistemas\\Vendas\\PedidoC}
Moveto [Numero do Pedido       ] Example "Pedido"
Moveto [Codigo da Empresa      ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Nome Fantasia Empresa  ] CheckPlus
Moveto [Data de Entrega        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Codigo da Destinacao   ] Example "cd"
Moveto [Situacao do Pedido     ] TypeIn "Not CANCELADO, NOT SUSPENSO"

{Ask} {\\Sistemas\\Vendas\\PedidoI}
Moveto [Numero do Pedido       ] Example "Pedido"
Moveto [Codigo do Item         ] CheckPlus Example "Item"
Moveto [Descricao do Item      ] CheckPlus
Moveto [Quantidade             ] CheckPlus    
Do_It!
ClearAll

Adiciona_Dados("Pedidos") 
  
;Programa‡Æo do Corte
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item          ] Example "Item"
Moveto [Codigo da Marca         ] CheckPlus TypeIn "~VSDGMARCA.."
Moveto [Descricao da Marca      ] CheckPlus

{Ask} {Cfacc}
Moveto [Numero_Corte            ] CheckPlus Example "NCorte"
Moveto [Codigo da Empresa       ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Nome Fantasia Empresa   ] CheckPlus
;Moveto [Data_Programacao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"

{Ask} {Cfacri}
Moveto [Numero_Corte            ] Example "NCorte"
Moveto [Codigo do Item          ] CheckPlus Example "Item"
Moveto [Referencia              ] CheckPlus TypeIn "~VSDGREFERENCIA.."
Moveto [Descricao do Item       ] CheckPlus
Moveto [Quantidade Programada   ] CheckPlus TypeIn "as Quantidade"
Do_It!
ClearAll 

Adiciona_Dados("ProgCorte")

;Produ‡Æo do Corte
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item          ] Example "Item"
Moveto [Codigo da Marca         ] CheckPlus TypeIn "~VSDGMARCA.."
Moveto [Descricao da Marca      ] CheckPlus

{Ask} {Cfacc}
Moveto [Numero_Corte            ] CheckPlus Example "NCorte"
Moveto [Codigo da Empresa       ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Nome Fantasia Empresa   ] CheckPlus
;Moveto [Data_Programacao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"

{Ask} {Pcfacc}                
Moveto [Numero_Producao_Corte   ] Example "NProd"
Moveto [Numero_Programacao_Corte] Example "NCorte"

{Ask} {Pcfacri}
Moveto [Numero_Producao_Corte   ] Example "NProd"
Moveto [Codigo do Item          ] CheckPlus Example "Item"
Moveto [Referencia              ] CheckPlus TypeIn "~VSDGREFERENCIA.."
Moveto [Descricao do Item       ] CheckPlus
Moveto [Quantidade Produzida    ] CheckPlus TypeIn "as Quantidade"
Do_It!
ClearAll

Adiciona_Dados("ProdCorte")

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"                ;Pedido
Moveto [Quantidade ProgCorte   ] TypeIn "Calc Sum as \"Quantidade ProgCorte\""  ;Programa‡Æo de Corte
Moveto [Quantidade ProdCorte   ] TypeIn "Calc Sum as \"Quantidade ProdCorte\""  ;Produ‡Æo de Corte
Moveto [Codigo do Item         ] Check
Moveto [Descricao do Item      ] Check
Moveto [Codigo da Marca        ] Check
Moveto [Descricao da Marca     ] Check         
Moveto [Referencia             ] Check
Do_IT!
ClearAll

Delete Tabela
Rename "Answer" Tabela         

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

Private Tipo

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "CodEmp"
Moveto [Nome Fantasia Empresa  ] Example "NomFan"
Moveto [Quantidade             ] Example "Qtd"
Moveto [Codigo do Item         ] Example "CodIte"
Moveto [Descricao do Item      ] Example "DesIte"
Moveto [Codigo da Marca        ] Example "CodMar"
Moveto [Descricao da Marca     ] Example "DesMar"
Moveto [Referencia             ] Example "Ref"

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "CodEmp"
Moveto [Nome Fantasia Empresa  ] Example "NomFan"
Switch
 Case Tipo="Pedidos"    : Moveto [Quantidade          ] Example "Qtd"
 Case Tipo="ProgCorte"  : Moveto [Quantidade ProgCorte] Example "Qtd"
 Case Tipo="ProdCorte"  : Moveto [Quantidade ProdCorte] Example "Qtd"
EndSwitch
Moveto [Codigo do Item         ] Example "CodIte"
Moveto [Descricao do Item      ] Example "DesIte"
Moveto [Codigo da Marca        ] Example "CodMar"
Moveto [Descricao da Marca     ] Example "DesMar"
Moveto [Referencia             ] Example "Ref"
Do_It!
ClearAll

If Tipo <>  "Pedidos"
   Then If Not IsEmpty(Tabela)
           Then Edit Tabela
                Scan
                  [Codigo do Item]=MudaCodigoPara([Codigo do Item],"P")  
                EndScan
                Do_It!
                ClearAll
        EndIf 
EndIf

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_MARCA"         : Campo="TG_EMPRESA"
            Case Campo="TG_REFERENCIA"    : Campo="TG_MARCA" 
            Case Campo="TG_DTINI"         : Campo="TG_REFERENCIA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     : Campo="TG_MARCA" 
                    Case Campo="TG_MARCA"       : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA"  : Campo="TG_DTINI" 
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

VSDGEMPRESA     =""
VSDGMARCA       =""
VSDGREFERENCIA  =""
VSDGDTINI       =BlankDate()
VSDGDTFIM       =BlankDate()

While True

  ShowDialog "Posi‡„o Ranking do Pedido/Corte" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,13   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Marca"  For "TG_MARCA"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 04,00 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 05,01 Width 33 "A20" Picture "!*!" Tag "TG_REFERENCIA" To VSDGREFERENCIA

    Label  @ 06,00 "Per¡odo de Entrega dos Pedidos de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    @ 08,01 ? "* Usando todas programa‡äes acumuladas at‚ o momento!"
    
    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok"  Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                     Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Faccao\\RM_3105"
  Copy "\\Base\\Sistemas\\Faccao\\RM_3105" Tabela

  Seleciona()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  CopyReport "\\Base\\Sistemas\\Faccao\\RM_3105" "R" Tabela "R"

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
