;** Rm_0120 ********************************************************************
;*  Relatorio de Clientes que compraram em um periodo                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/11/1997 por Anivel Augusto Rodrigues
;Ultima Alteracao: 18/06/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Periodo/Modelo Relatorio
;Ultima Alteracao: 20/10/2009 por Bruno Carvalho
;Motivo Alteracao: Inclusao do Campo VCDGESTADO
;Ultima Alteracao: 28/10/2009 por Bruno Carvalho
;Motivo Alteracao: Ajustes Seleciona()         
;Ultima Alteracao: 09/08/2011 por Bruno Carvalho
;Motivo Alteracao: Adicionado Celular no 1§ Modelo de Report
;Ultima Alteracao: 19/01/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado valores de compras e quantidade faturada conforme sele‡Æo
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 24/09/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ quando for o mesmo cliente, somar as quantidades
;Ultima Alteracao: 08/01/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro por marca
;Ultima Alteracao: 05/01/2016 por Bruno Carvalho
;Motivo Alteracao: Adicionado Gerˆncia
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()                

;*******************************************************************************
;* Rotina p/ Selecionar Vendas                                                 *
;*******************************************************************************
Proc Sel_Vendas()
ClearAll
  
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")     
   Then {Ask} {\\Sistemas\\Cadastro\\Represen}
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        If CheckTG_OPVR[1] Or VSDGMARCA<>"" ;Para Informar Quantidade de Itens Faturados
           Then Moveto [Codigo da Empresa  ] Check TypeIn "~VSDGEMPRESA.."
                Moveto [Numero do Documento] Check
                Moveto [Serie do Documento ] Check
           else Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."     
           
        EndIf                                 
        Moveto [Codigo                 ] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"        
        Moveto [Codigo do Representante] Check Example "crep" TypeIn "!, ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        Do_It!
        ClearAll
        
        If CheckTG_OPVR[1] Or VSDGMARCA<>""  
           Then If Not IsEmpty("Answer")
                    Then {Ask} {Answer} Check
                         Moveto [Codigo da Empresa  ] Example "CodE"
                         Moveto [Numero do Documento] Example "Ndoc"
                         Moveto [Serie do Documento ] Example "Sdoc"
                         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
                         Moveto [Codigo da Empresa  ] Example "CodE"
                         Moveto [Numero do Documento] Example "Ndoc"
                         Moveto [Serie do Documento ] Example "Sdoc"
                         If CheckTG_OPVR[1]
                            Then Moveto [Quantidade         ] TypeIn "Calc Sum as Quantidade"
                                 Moveto [Situacao_Item      ] TypeIn "Not C"
                         EndIf
                         If VSDGMARCA<>""  
                            Then Moveto [Codigo do Item         ] Example "CodI"
                                 {Ask} {\\Sistemas\\Estoque\\Itens}
                                 Moveto [Codigo do Item         ] Example "CodI"
                                 Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
                         EndIf  
                         Do_It!
                         ClearAll 
                EndIf
        Endif
Endif

EndProc   ; (Sel_Vendas)

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll
          
{Ask} TypeIn Tabela2 Enter
Moveto [Codigo                  ] Example "COD"           
{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                  ] Example "COD"
Moveto [Data da Primeira Compra ] Check
Moveto [Data da Ultima Compra   ] Check
If CheckTG_OPVR[1]
   Then Moveto [Valor da Primeira Compra] Check
        Moveto [Valor da Ultima Compra  ] Check
EndIf                                           
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Check Example "COD" ;TypeIn "!"
Moveto [Tipo                   ] TypeIn "C"
Moveto [Razao Social           ] Check
Moveto [Cidade                 ] Check
If UPPER(VSDGCIDADE)<>"TODAS"
   Then TypeIn VSDGCIDADE
EndIf
Moveto [UF                     ] Check TypeIn "~VSDGESTADO.."
Moveto [Telefone               ] Check
Moveto [Contato                ] Check
Moveto [Codigo do Representante] Check 
Moveto [Nome Fantasia Represent] Check
Moveto [Endereco               ] Check
Moveto [Bairro                 ] Check
Moveto [CEP                    ] Check
Moveto [Celular                ] Check 
Do_It!
ClearAll

{Ask} {Answer} 
Moveto [Codigo do Representante] TypeIn "Changeto Blank"
Do_It!
ClearAll

 {Ask} {Answer}
Moveto [Nome Fantasia Represent] TypeIn "Changeto Blank"
Do_It!
ClearAll

{Ask} TypeIn Tabela2 Enter
Moveto [Codigo                 ] Example "COD"
Moveto [Nome Fantasia Represent] Example "NomF"
Moveto [Codigo do Representante] Example "CodR"
{Ask} {Answer}
Moveto [Codigo                 ] Example "COD"
Moveto [Nome Fantasia Represent] TypeIn "Changeto _NomF"
Moveto [Codigo do Representante] TypeIn "Changeto _CodR"
Do_It!
ClearAll
                                                        
{Ask} {Answer} Check
Moveto [Codigo                  ] Example "COD"
{Ask} TypeIn Tabela2 Enter
Moveto [Codigo                  ] Example "COD"
If CheckTG_OPVR[1]
   Then Moveto [Quantidade      ] Check
EndIf   
Do_It!
ClearAll

If CheckTG_OPVR[1] ;Tava gerando duplicidade de clientes, e foi feito entÆo a soma das quantidades se cliente = mesmo !
   Then {Ask} {Answer} Check
        Moveto [Quantidade] Check TypeIn "Calc Sum as Quantidade"
        Do_It!
        ClearAll
EndIf        

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_ESTADO"         : Campo="TG_EMPRESA"  
            Case Campo="TG_CIDADE"         : Campo="TG_ESTADO"
            Case Campo="TG_REPRESEN"       : Campo="TG_CIDADE"
            Case Campo="TG_GERENCIA"       : Campo="TG_REPRESEN"
            Case Campo="TG_MARCA"          : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"          : Campo="TG_MARCA"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALF"    : Campo="TG_DTFIM"
            Case Campo="TG_MODELOREL"      : Campo="TG_OPRELCODALF"
            Case Campo="TG_OPVR"           : Campo="TG_MODELOREL"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"        :Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"         :Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"         :Campo="TG_REPRESEN"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf 
                    Case Campo="TG_REPRESEN"       :Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"      : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"          :Campo="TG_DTINI"      
                    Case Campo="TG_DTINI"          :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"          :Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF"    :Campo="TG_MODELOREL"
                    Case Campo="TG_MODELOREL"      :Campo="TG_OPVR"
                         VSDGMODELOREL=ControlValue("TG_MODELOREL")
                         Switch
                           Case VSDGMODELOREL="2": VSDGNOMMODELOREL="COM ENDERECO"
                           OtherWise:
                                VSDGMODELOREL="1"  VSDGNOMMODELOREL="SIMPLES"
                         EndSwitch
                    Case Campo="TG_OPVR"           :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a Data Inicial do Periodo"
  Case Campo="TG_DTFIM":
       MSG_CAMPO="Informe a Data Final do Periodo"
  Case Campo="TG_MODELOREL":
       MSG_CAMPO="Modelo: 1=Simples  2=Com Endere‡o"
  Case Campo="TG_OPVR":
       MensagemCheckBoxes()      
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*****************************************************************************+*
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA         = ""
VSDGDTINI       =BlankDate()
VSDGDTFIM       =BlankDate()
VSDGCIDADE      =""
VSDGESTADO      =""
VSDGMARCA       =""
VSDGNOMMARCA    =""
VSDGREPRESEN    =""
VSDGOPRELCODALF =""
VSDGMODELOREL   ="" 
VSDGGERENCIA    ="" 

Array TG_OPVR[1]
TG_OPVR[1]="Exibe valores!"

Array CheckTG_OPVR[ArraySize(TG_OPVR)]
CheckTG_OPVR[1]=False

While True

  ShowDialog "Clientes que compraram em um per¡odo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,09   Height 19 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Estado"  For "TG_ESTADO"
    Accept @ 03,03 Width 05 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMESTADO"  To VSDGNOMESTADO

    Label  @ 04,00 "Cidade"  For "TG_CIDADE"
    Accept @ 05,01 Width 33 "A20"  Picture "!*!" Tag "TG_CIDADE"   To VSDGCIDADE

    Label  @ 06,00 "Representante"  For "TG_REPRESEN"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 08,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 09,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 09,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 10,00 "Marca" For "TG_MARCA"
    Accept @ 11,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"     To VSDGMARCA
    Accept @ 11,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMMARCA"  To VSDGNOMMARCA

    Label  @ 12,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 13,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 13,16 "at‚" For "TG_DTFIM"
    Accept @ 13,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 02,35 "Modelo Relat¢rio" For "TG_MODELOREL"
    Accept @ 03,39 Width 04 "A1"   Picture "1,2" Tag "TG_MODELOREL" To VSDGMODELOREL
    Accept @ 03,44 Width 25 "A12"  Picture "!*!" Tag "TG_NOMMODELOREL" To VSDGNOMMODELOREL

    CheckBoxes @ 05,35 Height 1 Width 33 Tag "TG_OPVR"
    TG_OPVR[1] to CheckTG_OPVR[1]
    
    Pushbutton @ 15,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  If VSDGDTFIM < VSDGDTINI
     Then Mensagem("Data Final deve ser maior que Data Inicial !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela2=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Sel_Vendas()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela2)
       Then Add "Answer" Tabela2
       Else Rename "Answer" Tabela2
    EndIf
  EndWhile
                 
  Seleciona()  
                 
  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Delete "Answer"
          Loop
  EndIf
  
  If CheckTG_OPVR[1]
     Then Impressao_Orientacao="Paisagem"
  EndIf                       

  If VSDGMARCA="" Then VSDGNOMMARCA="" EndIf    

  Switch
    Case VSDGMODELOREL="1" And CheckTG_OPVR[1]: ;Op‡Æo com Quantidade Faturada e Exibi‡Æo de Valores  
         If VSDGOPRELCODALF="1"
            Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0111" "R" "Answer" "R"   
            Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0111" "1" "Answer" "R"  
         EndIf   
    Case VSDGMODELOREL="1" :
         If VSDGOPRELCODALF="1"
            Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "4" "Answer" "R"
            Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "5" "Answer" "R"
         EndIf
    Case VSDGMODELOREL="2":
      If VSDGOPRELCODALF="1"
         Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "8" "Answer" "R"
         Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "9" "Answer" "R"
      EndIf
  EndSwitch

  IMPRIREL("Answer","R")

  If IsTable("Answer")     Then Delete "Answer" EndIf
  If IsTable(Tabela2)      Then Delete Tabela2  EndIf

EndWhile
ClearAll
Release Vars All
Release Procs All
