;** Rm_0231  *******************************************************************
;*  Emissao dos Titulos a Receber por Cidade/Cliente/Vencto                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 03/12/1999 por Anivel Augusto Rodrigues
;Ultima Alteracao: 14/05/2003 por Karen Lauar Nery
;Motivo Alteracao: Mudan‡a Base
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 26/12/2013 por Andrey Fillipe
;Motivo Alteracao: Inclusao filtro de UF
;Ultima Alteracao: 20/11/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado novo modelo de relatorio Sintetico
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                
;Ultima Alteracao: 06/09/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro gerencia/representante
;Ultima Alteracao: 27/11/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask com representante nÆo cadastrado

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

If VSDGGERENCIA<>""
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
EndIf

{Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
Moveto [Codigo ] Example "cli"
Moveto [Cidade ] Check TypeIn CIDADE
Moveto [UF     ] Check TypeIn "~VSDGESTADO.."

{Ask} {Duplic} Check
Moveto [Codigo do Destinatario ] Example "cli"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
Moveto [Tipo do Pagamento      ] TypeIn "~VSDGTPPAGTO.."
If VSDGSIM_NAO="SIM"
   Then Moveto [Tipo do Lancamento] TypeIn "P"
   Else Moveto [Tipo do Lancamento] TypeIn "Not P, Not J"
EndIf
Moveto [Data de Vencimento     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Saldo do Documento     ] TypeIn "> 0.01"
Switch
  Case VSDGGERENCIA<>"" : Moveto [Codigo do Representante] Example "crep" TypeIn "!, ~VSDGREPRESEN.."
  Case VSDGREPRESEN<>"" : Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Endswitch  
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit "Answer"
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll
EndProc    ; (Processa)

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA_ANAL()
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Codigo do Destinatario ] Check
Moveto [Razao Social           ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Data de Emissao        ] Check
Moveto [Tipo do Documento      ] Check
Moveto [Serie do Documento     ] Check
Moveto [Numero Docto Gerador   ] Check
Moveto [Cidade                 ] Check
Moveto [UF                     ] Check
Moveto [Valor do Documento     ] TypeIn "Calc Sum as Valor do Documento"
Moveto [Saldo do Documento     ] TypeIn "Calc Sum as Saldo do Documento"
Moveto [Valor do Desconto      ] TypeIn "Calc Sum as Valor do Desconto"
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_ESTADO"        : Campo="TG_GERENCIA"
            Case Campo="TG_CIDADE"        : Campo="TG_ESTADO"
            Case Campo="TG_DESTINAT"      : Campo="TG_ESTADO"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_TPPAGTO"       : Campo="TG_DDPROTESTO"
            Case Campo="TG_SN_SOPENDENTES": Campo="TG_TPPAGTO"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_SN_SOPENDENTES"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"   : Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"     : 
                         If IsBlank(VSDGESTADO) Or VSDGESTADO="" 
                            Then VSDGCIDADE="TODAS"
                                 CIDADE=""
                                 Campo="TG_DESTINAT"
                            Else Campo="TG_CIDADE"
                         EndIf
                    Case Campo="TG_CIDADE"     : 
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                         GetRecord "\\Sistemas\\Cadastro\\Cidades" VSDGCIDADE to UF_CID
                         If RetVal 
                            Then UF_CID = UF_CID["UF"] 
                            Else UF_CID = ""
                         EndIf
                         CI=""
                         If VSDGCIDADE=".." Then CI="TODAS" EndIf
                         If Upper(VSDGCIDADE)="TODAS" Then CI="TODAS" EndIf
                         If  VSDGESTADO<>"" And VSDGESTADO<>"TODAS"
                            Then If VSDGESTADO<>UF_CID And CI<>"TODAS"
                                    Then Mensagem("Cidade nÆo pertence a este Estado !")
                                         Campo="TG_CIDADE"
                                         VSDGCIDADE=""
                                    Else Campo="TG_DESTINAT"
                                 EndIf   
                         EndIf
                    Case Campo="TG_DESTINAT"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="TG_SN_SOPENDENTES"
                    Case Campo="TG_SN_SOPENDENTES"  : Campo="TG_OPRELANALSINT"
                    Case Campo="TG_OPRELANALSINT" : Campo="YES"     
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
       MSG_CAMPO="Informe o Numero de Dias"
  Case Campo="TG_SN_SOPENDENTES":
       MSG_CAMPO="S¢ t¡tulos pendentes?"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
VSDGEMPRESA   =""
VSDGTPPAGTO   =""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()
VSDGCIDADE =""
VSDGESTADO =""
VSDGDDPROTESTO=""
VSDGREPRESEN=""

While True
  ShowDialog "T¡tulos a Receber por Represent/Cidade/Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 19 Width 72
    
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP   
    
    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 06,02 "Estado"  For "TG_ESTADO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMESTADO"  To VSDGNOMESTADO

    Label  @ 08,00 "Cidade"  For "TG_CIDADE"
    Accept @ 09,01 Width 33 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE

    Label  @ 10,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 11,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 11,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST 
                           
    Label  @ 12,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 13,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 13,16 "at‚" For "TG_DTFIM"
    Accept @ 13,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 03,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 04,35 "Emitir s¢ os Pendentes"  For "TG_SN_SOPENDENTES"
    Accept @ 05,36 Width 07 "A3"  Picture "SIM,NAO" Tag "TG_SN_SOPENDENTES" To VSDGSIM_NAO

    Label  @ 06,35 "Op‡„o do Relat¢rio" For "TG_OPRELANALSINT"
    Accept @ 07,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 07,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELANASINT" To VSDGNOMOPRELANALSINT

    Pushbutton @ 15,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue
  EndDialog

  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, processando")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf
  PROCESSA()

  If VSDGOPRELANALSINT="1"
     Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230" "1" "Answer" "R"
     Else SELECIONA_ANAL()
          CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230b" "6" "Answer" "R"
  EndIf        

  IMPRIREL("Answer","R")
  
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
