;** Rm_0060A ********************************************************************
;*  Emissao da Apuracao da Comissao usando % da Nota Fiscal                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/09/2015 por Andrey Fillipe
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes gerar comissao 
                                       
;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()
Private PROCESSO     

;----- H  um processo de Troca Diferenciado ------------------------------------
;----- NÆo controla estoque quando ‚ troca, e a troca deve ter a comissao ------ 
;----- subtraida ---------------------------------------------------------------
If SYS_CODIGO_CLIENTE="0112"  
   Then PROCESSO = 3 
   Else PROCESSO = 2
EndIf   

ClearAll
;****** Vendas/Devolu‡äes *******
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC")                      
   Then For wi2 From 1 To PROCESSO 
          For wi From INICIO_RATEIO To FIM_RATEIO 
           {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
            Moveto [Codigo do Representante] Example "crep"
            Moveto [Codigo da Gerencia     ] Check
            If Not IsBlank(VSDGGERENCIA)
               Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
            EndIf
            
            If wi = 2
               Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC" Enter
                    Moveto [Codigo da Empresa        ] Example "a"
                    Moveto [Numero do Documento      ] Example "b"
                    Moveto [Serie do Documento       ] Example "c"
                    Moveto [Item do Documento        ] TypeIn "0"
                    Moveto [Codigo do Representante  ] Check TypeIn "_crep!, ~VSDGREPRESEN.."
                    Moveto [Nome Fantasia Represent  ] Check
                    Moveto [Comissao do Representante] Check
            EndIf

            {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
            Moveto [Codigo da Empresa        ] Check Example "a , ~VSDGEMPRESA.."
            Moveto [Numero do Documento      ] Check Example "b"
            Moveto [Serie do Documento       ] Check Example "c"
            Moveto [Nome Fantasia Empresa    ] Check 
            Moveto [Data de Emissao          ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
            Moveto [Tipo do Documento        ] Check 
            Moveto [Codigo                   ] Check
            Moveto [Razao Social             ] Check 
            Moveto [Cidade                   ] Check 
            Moveto [UF                       ] Check 
            Moveto [Valor Mercadoria Liquido ] Check 
            Moveto [Situacao                 ] TypeIn "Not C"
            Moveto [Nome Fantasia EmitDest   ] Check
            Moveto [Numero da OF             ] Check
            Moveto [Descricao CondPagto      ] Check
            Moveto [Forma de Pagamento       ] Check
            
            Switch
              Case wi2 = 1 : Moveto [Descricao da Destinacao  ] Check TypeIn "..VEND.. Or ..SAIDA.. Or ..SERV.."
                             Moveto [Tipo Movimento Estoque   ] TypeIn "S"
              Case wi2 = 2 : Moveto [Descricao da Destinacao  ] TypeIn "..DEVOL.."
                             Moveto [Tipo Movimento Estoque   ] TypeIn "E"
              Case wi2 = 3 : Moveto [Descricao da Destinacao  ] TypeIn "..TROC.."          
            EndSwitch   

            If wi = 1
               Then Moveto [Codigo do Representante  ] Check TypeIn "_crep, ~VSDGREPRESEN.."
                    Moveto [Nome Fantasia Represent  ] Check
                    Moveto [Comissao do Representante] Check
            EndIf
            
            {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
            Moveto [Codigo da Empresa        ] Example "a"
            Moveto [Numero do Documento      ] Example "b"
            Moveto [Serie do Documento       ] Example "c"
            Moveto [Quantidade               ] TypeIn "Calc Sum as Quantidade"
            Moveto [Situacao_Item            ] TypeIn "Not C"
            Do_It!
            ClearAll  
            
            If SYS_CODIGO_CLIENTE="0112" And wi2 = 1
               Then Coedit "Answer"
                    While True
                      If Search("TROC",[Descricao da Destinacao])>0
                         Then Del
                              Home
                      EndIf   
                      Skip
                      If Eot() Then QuitLoop EndIf
                    EndWhile
                    Do_It!
                    ClearAll
            EndIf   

            {Ask} {Answer}
            Moveto [Codigo da Empresa        ] Example "a"
            Moveto [Numero do Documento      ] Example "b"
            Moveto [Serie do Documento       ] Example "c"
            Moveto [Codigo do Representante  ] Example "d"
            Moveto [Comissao do Representante] Example "TAXA"
            Moveto [Data de Emissao          ] Example "e"
            Moveto [Nome Fantasia Empresa    ] Example "ne"
            Moveto [Nome Fantasia Represent  ] Example "nr"
            Moveto [Codigo                   ] Example "cc"
            Moveto [Nome Fantasia EmitDest   ] Example "nc"
            Moveto [Razao Social             ] Example "rz"
            Moveto [Numero da OF             ] Example "no"
            Moveto [Valor Mercadoria Liquido ] Example "h"
            Moveto [Quantidade               ] Example "g"
            Moveto [Descricao CondPagto      ] Example "despag"
            Moveto [Forma de Pagamento       ] Example "fppag"
            {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
            Switch
              Case wi2 = 1 : Moveto [Operacao       ] TypeIn "\"Vendas\""
              Case wi2 = 2 : Moveto [Operacao       ] TypeIn "\"Devolucoes\""
              Case wi2 = 3 : Moveto [Operacao       ] TypeIn "\"Troca\""
            EndSwitch
            Moveto [Codigo da Empresa        ] Example "a"
            Moveto [Numero do Documento      ] Example "b"
            Moveto [Serie do Documento       ] Example "c"
            Moveto [Codigo do Representante  ] Example "d"
            Moveto [Data de Emissao          ] Example "e"
            Moveto [Nome Fantasia Empresa    ] Example "ne"
            Moveto [Nome Fantasia Represent  ] Example "nr"
            Moveto [Codigo                   ] Example "cc"
            Moveto [Nome Fantasia EmitDest   ] Example "nc"
            Moveto [Razao Social             ] Example "rz"
            Moveto [Numero da OF             ] Example "no"
            Moveto [Aliquota Comissao        ] Example "TAXA"
            Moveto [Descricao CondPagto      ] Example "despag"
            Moveto [Forma de Pagamento       ] Example "fppag"
            Switch
              Case wi2 = 1 : Moveto [Quantidade     ] Example "g"
                             Moveto [Preco Total    ] Example "h"
                             Moveto [Comissao       ] TypeIn "(_h * _TAXA )/100"
              Case wi2 = 2 : Moveto [Quantidade     ] Example "g" TypeIn "*-1"
                             Moveto [Preco Total    ] Example "h*-1"
                             Moveto [Comissao       ] TypeIn "(_h * _TAXA )/100*-1"
              Case wi2 = 3 : Moveto [Quantidade     ] Example "g" TypeIn "*-1"
                             Moveto [Preco Total    ] Example "h*-1"
                             Moveto [Comissao       ] TypeIn "(_h * _TAXA )/100*-1"
            EndSwitch        
            Do_It!
            ClearAll
          EndFor
        Endfor       
        
        ;---- Reproveitando CAMPO - Calculo da M‚dia dos Vencimentos -----------
        If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV")    
           Then {Ask} TypeIn Tabela Enter
                Moveto [Codigo da Empresa  ] Check
                Moveto [Serie do Documento ] Check 
                Moveto [Numero do Documento] Check
                Moveto [Data de Emissao    ] Check
                Do_It!
                ClearAll
                
                If Not IsEmpty("Answer")
                   Then {Ask} TypeIn Tabela Enter
                        Moveto [Aliquota Comissao       ] TypeIn "Changeto Blank"
                        Do_It!
                        ClearAll     
              
                        NR=NRecords("Answer") 
                
                        Tabela2 = Cria_Temp(PrivDir())
                        Copy "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV" Tabela2
                
                        View Tabela2
                        View Tabela
                        CoEdit "Answer"
                        Scan
                          Barra(NR, RecNo())
                          Aguarde("Aguarde, Calculando Media "+Completa(StrVal(Recno())+"/"+StrVal(NR),9," ")+BARRA_STRING)                
                        
                          COD_EMP = [Codigo da Empresa  ]
                          COD_DOC = [Serie do Documento ]
                          NUM_DOC = [Numero do Documento]
                          DATA    = [Data de Emissao    ]
                          
                          DIAS = 0
                          Moveto Tabela2
                          Moveto [Codigo da Empresa]
                          Locate COD_EMP,NUM_DOC,COD_DOC
                          If RetVal
                             Then DynArray NDIAS[]
                                  CONT_NDIAS = 0
                                  While [Codigo da Empresa  ] = COD_EMP And
                                        [Serie do Documento ] = COD_DOC And
                                        [Numero do Documento] = NUM_DOC
                                  
                                        CONT_NDIAS = CONT_NDIAS + 1
                                    
                                        If [Data] < DATA
                                           Then NDIAS[CONT_NDIAS] = 0 
                                           Else NDIAS[CONT_NDIAS] = [Data] - DATA 
                                        EndIf   
          
                                        Skip
                                        If Eot() Then QuitLoop EndIf
                                  EndWhile
        
                                  For i From 1 To CONT_NDIAS
                                    DIAS = DIAS + NDIAS[i]
                                  EndFor
                                  If DIAS > 0 
                                     Then DIAS = Int(DIAS / CONT_NDIAS)
                                  EndIf    
                          EndIf     
                          If DIAS > 0
                             Then Moveto Tabela
                                  Moveto [Codigo da Empresa]
                                  Locate COD_EMP
                                  If Retval
                                     Then While COD_EMP = [Codigo da Empresa]
                                            If [Serie do Documento ] = COD_DOC
                                               Then If [Numero do Documento] = NUM_DOC
                                                       Then [Aliquota Comissao] = DIAS
                                                            ;QuitLoop
                                                    EndIf
                                            EndIf
                                            Skip
                                            If Eot() Then QuitLoop EndIf
                                            Locate Next COD_EMP
                                            If Not RetVal
                                               Then QuitLoop 
                                            EndIf
                                          EndWhile
                                  EndIf    
                          EndIf        
                          Moveto "Answer"   
                        EndScan
                        Do_It!
                        ClearAll
                        
                        If IsTable(Tabela2)
                           Then Delete Tabela2
                        EndIf   
                        Release Vars DIAS,i,NLANCTO,DATA,NDIAS,CONT_NDIAS 
                EndIf   
        EndIf        
        ;-----------------------------------------------------------------------       
EndIf

;****** Devolucoes *******
If PROCESSO <> 3
   Then If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
           IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
           Then
                {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
                Moveto [Codigo do Representante] Example "crep"
                If VSDGGERENCIA<>""
                   Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
                   Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
                EndIf
                {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEc" Enter
                Moveto [Numero do Lancamento     ] Example "x"
                Moveto [Codigo da Empresa        ] CheckPlus TypeIn "~VSDGEMPRESA2.."
                Moveto [Numero do Documento      ] CheckPlus
                Moveto [Serie do Documento       ] CheckPlus
                Moveto [Codigo do Representante  ] CheckPlus Example "crep" TypeIn "!, ~VSDGREPRESEN.."
                Moveto [Comissao do Representante] CheckPlus
                Moveto [Data de Entrada          ] CheckPlus TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                Moveto [Tipo de Operacao         ] TypeIn "D"
                Moveto [Nome Fantasia Empresa    ] CheckPlus
                Moveto [Nome Fantasia Represent  ] CheckPlus
                Moveto [Codigo                   ] CheckPlus
                Moveto [Nome Fantasia EmitDest   ] CheckPlus
                Moveto [Razao Social             ] CheckPlus
                {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
                Moveto [Numero do Lancamento     ] Example "x"
                Moveto [Codigo do Item           ] CheckPlus
                Moveto [Descricao do Item        ] CheckPlus
                Moveto [Quantidade               ] CheckPlus
                Moveto [Unidade Fiscal           ] CheckPlus
                Moveto [Preco Total              ] CheckPlus
                Moveto [Valor Desconto Total     ] CheckPlus
                Do_It!
                ClearAll
        
                {Ask} {Answer}
                Moveto [Codigo da Empresa        ] Example "a"
                Moveto [Numero do Documento      ] Example "b"
                Moveto [Serie do Documento       ] Example "c"
                Moveto [Codigo do Representante  ] Example "d"
                Moveto [Comissao do Representante] Example "TAXA"
                Moveto [Data de Entrada          ] Example "e"
                Moveto [Nome Fantasia Empresa    ] Example "ne"
                Moveto [Nome Fantasia Represent  ] Example "nr"
                Moveto [Codigo                   ] Example "cc"
                Moveto [Nome Fantasia EmitDest   ] Example "nc"
                Moveto [Razao Social             ] Example "rz"
                Moveto [Codigo do Item           ] Example "f"
                Moveto [Descricao do Item      ] Example "descr"
                Moveto [Quantidade             ] Example "g"
                Moveto [Unidade Fiscal         ] Example "uf"
                Moveto [Preco Total              ] Example "h"
                Moveto [Valor Desconto Total     ] Example "i"
        
                {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
                Moveto [Operacao               ] TypeIn "\"Devolucoes\""
                Moveto [Codigo da Empresa      ] Example "a"
                Moveto [Numero do Documento    ] Example "b"
                Moveto [Serie do Documento     ] Example "c"
                Moveto [Codigo do Representante] Example "d"
                Moveto [Data de Emissao        ] Example "e"
                Moveto [Nome Fantasia Empresa  ] Example "ne"
                Moveto [Nome Fantasia Represent] Example "nr"
                Moveto [Codigo                 ] Example "cc"
                Moveto [Nome Fantasia EmitDest ] Example "nc"
                Moveto [Razao Social           ] Example "rz"
                Moveto [Codigo do Item         ] Example "f"
                Moveto [Descricao do Item      ] Example "descr"
                Moveto [Quantidade             ] Example "g" TypeIn "*-1"
                Moveto [Unidade Fiscal         ] Example "uf"
                Moveto [Preco Total            ] TypeIn "(" Example "h" TypeIn "-" Example "i" TypeIn ")*-1"
                Moveto [Comissao               ] TypeIn "((("Example "h" TypeIn "-" Example "i" TypeIn ")*" Example "TAXA" TypeIn ")/100)*-1"
                Moveto [Aliquota Comissao      ] Example "TAXA"
                Do_It!
                ClearAll   
        EndIf
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina para processar Db temporaria                                 !       *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

;****** Taxa Administrativa sobre Devolucoes *******
If Not VSDGTAXAD>0
   Then Return
EndIf

{Ask} TypeIn Tabela Enter
Moveto [Operacao               ] Check TypeIn "Devolucoes"
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Preco Total            ] Example "h"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Operacao               ] TypeIn "\"Administr.\""
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Nome Fantasia EmitDest ] TypeIn "\"SOBRE DEVOLUCOES\""
Moveto [Razao Social           ] TypeIn "\"SOBRE DEVOLUCOES\""
Moveto [Comissao               ] TypeIn "("Example "h" TypeIn "*~VSDGTAXAD)/100"
Moveto [Aliquota Comissao      ] TypeIn "~VSDGTAXAD"
Do_It!
ClearAll

EndProc   ;  (Processa)

;*******************************************************************************
;* Rotina para Quebrar por Cidade                                              *
;*******************************************************************************
Proc PorCidade()

{Ask} TypeIn Tabela Enter
Moveto [Descricao da Destinacao] TypeIn "Changeto Blank" Down
Moveto [Condicao de Pagamento  ] TypeIn "Changeto Blank"
Do_it!
ClearAll

COD_CLI = "***"

Sort Tabela On "Codigo"
ClearAll

View "\\Sistemas\\Cadastro\\Destinat"
Coedit Tabela
Scan
  Barra(NRecords(Tabela), RecNo())
  Aguarde("Aguarde, Verificando Cidade/UF "+BARRA_STRING)
  If COD_CLI <> [Codigo]
     Then COD_CLI = [Codigo]
          GetRecord "\\Sistemas\\Cadastro\\Destinat" COD_CLI To REG_CLI
          If RetVal
             Then CID_CLI = REG_CLI["Cidade"]
                  EST_CLI = REG_CLI["Uf"]
          EndIf   
  EndIf   
  [Descricao da Destinacao] = CID_CLI
  [Condicao de Pagamento  ] = EST_CLI
EndScan
Do_It!
ClearAll

Sort Tabela On "Descricao da Destinacao","Condicao de Pagamento","Data de Emissao"
ClearAll

EndProc ;PorCidade()

;*******************************************************************************
;* Rotina p/                                                                   *
;*******************************************************************************
Proc GeraComissao()
ClearAll


;-------------

PC_0000_AquivoDeParametrosGeraComissao="PC_0060A" ; informar o Rm_XXXX como PC_XXXX nÆo esquecer 
Play "PC_0000"

;-------------

EndProc     

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_TAXAD"         : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_TAXAD"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPCAO"         : Campo="TG_DTFIM"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_OPCAO"
            Case Campo="TG_COMISSAO"      : Campo="TG_OPRELANALSINT"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE" :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN":Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA":Campo="TG_TAXAD"
                    Case Campo="TG_TAXAD"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="TG_OPCAO"
                    Case Campo="TG_OPCAO"   : 
                         VSDGOPCAO = ControlValue("TG_OPCAO")
                         If IsBlank(VSDGOPCAO) Then VSDGOPCAO = "1" EndIf
                         Switch
                           Case VSDGOPCAO = "1" : VSDGNOMOPCAO = "SEM RATEIO"
                           Case VSDGOPCAO = "2" : VSDGNOMOPCAO = "COM RATEIO"
                           Case VSDGOPCAO = "3" : VSDGNOMOPCAO = "APENAS RATEIO"
                         EndSwitch   
                         Campo="TG_OPRELANALSINT"
                    Case Campo="TG_OPRELANALSINT" : 
                         VSDGOPRELANALSINT = ControlValue("TG_OPRELANALSINT")
                         Switch
                           Case VSDGOPRELANALSINT = "2" : VSDGNOMOPRELANALSINT = "REPRESENTANTE/CIDADE"
                           OtherWise                    : VSDGNOMOPRELANALSINT = "REPRESENTANTE"
                                                          VSDGOPRELANALSINT    = "1"
                         EndSwitch                        
                         Campo="TG_COMISSAO"
                    Case Campo="TG_COMISSAO" : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPCAO":
     MSG_CAMPO="1=SEM RATEIO  2=COM RATEIO  3=APENAS RATEIO"
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_OPRELANALSINT" :
     MSG_CAMPO="1=Representante  2=Representante/Cidade"
  Case Campo="TG_COMISSAO":
       MSG_CAMPO="Defina a op‡„o"
       TECLA="Barra de Espa‡o=Marca/Desmarca  "
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

sys_Valor()

VSDGEMPRESA          = ""
VSDGREPRESEN         = ""
VSDGGERENCIA         = ""
VSDGDESCGERENCIA     = ""
VSDGOPCAO            = ""
VSDGNOMOPCAO         = ""
VSDGOPRELANALSINT    = ""
VSDGNOMOPRELANALSINT = ""
VSDGTAXAD            = BlankNum()
VSDGDTINI            = BlankDate()
VSDGDTFIM            = BlankDate()

Array TG_COMISSAO[1]
TG_COMISSAO[1]="Gera comiss„o Contas a Pagar"

Array CheckTG_COMISSAO[ArraySize(TG_COMISSAO)]
CheckTG_COMISSAO[1]=False

While True

  ShowDialog "Apura‡„o de Comiss„o p/ Repres.- % Nota Fiscal" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

		Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 06,08 "% Devoluc„o"  For "TG_TAXAD"
    Accept @ 07,09 Width 12 "N" Tag "TG_TAXAD" To VSDGTAXAD

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Rateio de Comiss„o" For "TG_OPCAO"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPCAO" To VSDGOPCAO
    Accept @ 01,44 Width 25 "A30" Picture "!*!" Tag "TG_NOMOPCAO" To VSDGNOMOPCAO

    Label  @ 02,35 "Op‡„o do Relat¢rio" For "TG_OPRELANALSINT"
    Accept @ 03,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 03,44 Width 25 "A30"  Picture "!*!" Tag "TG_NOMOPRELANASINT" To VSDGNOMOPRELANALSINT

    CheckBoxes @ 05,35 Height 1 Width 35 Tag "TG_COMISSAO"
    TG_COMISSAO[1] to CheckTG_COMISSAO[1]        

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  Switch
    Case VSDGOPCAO = "1" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 1 
    Case VSDGOPCAO = "2" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 2
    Case VSDGOPCAO = "3" : INICIO_RATEIO = 2
                           FIM_RATEIO    = 2
  EndSwitch   
    
  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf
  
  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0050"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0050" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile
   
  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  
  if CheckTG_COMISSAO[1]
     then
          GeraComissao()
     else
          If VSDGOPRELANALSINT="2"
             Then PorCidade()
                  REL = "14"
             Else REL = "13"
          EndIf   
          IMPRIREL(Tabela,REL)
  endif

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
