;** Rm_3114 ********************************************************************
;* Resumo de Vendas por Representante/Cliente Maximo Ultimos 4 Anos            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 26/02/2015 por Anivel Augusto Rodrigues
;Ultima Alteracao: 27/02/2015 por Kamila Gomes
;Motivo Alteracao: Ajustes filtro cliente, adicionado mais uma coluna de ano
;Ultima Alteracao: 05/03/2015 por Kamila Gomes
;Motivo Alteracao: Ajustes - Ask duplicando registro - novo modelo sem total
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes ShowDialog TG_DESTINAT              
;Ultima Alteracao: 28/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes reports, Seta_Ordem_Report      

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           If VSDGGERENCIA<>""
              Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
              Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           EndIf
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo                 ] Check TypeIn "~VSDGDESTINAT.."
        Moveto [Codigo do Representante] Check Example "crep" TypeIn "!, ~VSDGREPRESEN.."
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        Adiciona_Dados("VENDAS")
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo                 ] Example "ccli"
Moveto [Codigo do Representante] Example "crep"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo                 ] Example "ccli"
Moveto [Codigo do Representante] Example "crep"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Quantidade      ] Example "qtde"
       Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
       
     Switch
       Case anoref=1:  
            Moveto [Ano1_Vendas_Quantidade      ] Example "qtde"
            Moveto [Ano1_Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
       Case anoref=2:  
            Moveto [Ano2_Vendas_Quantidade      ] Example "qtde"
            Moveto [Ano2_Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
       Case anoref=3:  
            Moveto [Ano3_Vendas_Quantidade      ] Example "qtde"
            Moveto [Ano3_Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
       Case anoref=4:  
            Moveto [Ano4_Vendas_Quantidade      ] Example "qtde"
            Moveto [Ano4_Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
     EndSwitch  
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Embalagem       ] Check TypeIn "Calc Sum as VendasEmbalagem"
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as VendasPreco"
Moveto [Devolucoes_Quantidade  ] Check TypeIn "Calc Sum as DevolucoesQuantidade"
Moveto [Devolucoes_Preco Total ] Check TypeIn "Calc Sum as DevolucoesPreco"
Moveto [Ano1_Vendas_Quantidade ] Check TypeIn "Calc Sum as Ano1VendasQuantidade"
Moveto [Ano1_Vendas_Preco Total] Check TypeIn "Calc Sum as Ano1VendasPreco"
Moveto [Ano2_Vendas_Quantidade ] Check TypeIn "Calc Sum as Ano2VendasQuantidade"
Moveto [Ano2_Vendas_Preco Total] Check TypeIn "Calc Sum as Ano2VendasPreco"
Moveto [Ano3_Vendas_Quantidade ] Check TypeIn "Calc Sum as Ano3VendasQuantidade"
Moveto [Ano3_Vendas_Preco Total] Check TypeIn "Calc Sum as Ano3VendasPreco"
Moveto [Ano4_Vendas_Quantidade ] Check TypeIn "Calc Sum as Ano4VendasQuantidade"
Moveto [Ano4_Vendas_Preco Total] Check TypeIn "Calc Sum as Ano4VendasPreco"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

;*** Totaliza Empresa ***
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [VendasPreco              ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Total_Vendas_Empresa     ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Representante ***
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Representante] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Codigo do Representante  ] Example "crep"
Moveto [VendasPreco              ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Codigo do Representante  ] Example "crep"
Moveto [Total_Vendas_Represent   ] TypeIn "changeto _vp"
Do_It!
ClearAll

If VSDGOPACVR="S"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast" Enter
        Moveto [Vendas_Preco Total     ] TypeIn "Changeto Blank"
        Moveto [Ano1_Vendas_Preco Total] TypeIn "Changeto Blank"
        Moveto [Ano2_Vendas_Preco Total] TypeIn "Changeto Blank"
        Moveto [Ano3_Vendas_Preco Total] TypeIn "Changeto Blank"
        Moveto [Ano4_Vendas_Preco Total] TypeIn "Changeto Blank"
        Moveto [Total_Vendas_Empresa   ] TypeIn "changeto Blank"
        Do_It!
        ClearAll
EndIf


{Ask} {\\Sistemas\\Cadastro\\Destinat} TypeIn "Fast" Enter
Moveto [Codigo                   ] Example "ccli"
Moveto [Nome Fantasia EmitDest   ] Example "nf"
Moveto [Cidade                   ] Example "cid"
Moveto [Uf                       ] Example "uf"
Moveto [Contato                  ] Example "cont"
Moveto [Razao Social             ] Example "ncli"
{Ask} TypeIn Tabela Enter TypeIn "Fast" Enter
Moveto [Codigo                   ] Example "ccli"
Moveto [Nome Fantasia EmitDest   ] TypeIn "Changeto " Example "nf"
Moveto [Cidade                   ] TypeIn "Changeto " Example "cid"
Moveto [Uf                       ] TypeIn "Changeto " Example "uf"
Moveto [Descricao da Destinacao  ] TypeIn "Changeto " Example "cont"
Moveto [Razao Social             ] TypeIn "Changeto " Example "ncli"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Represen} TypeIn "Fast" Enter
Moveto [Codigo do Representante  ] Example "crep"
Moveto [Nome Fantasia Represent  ] Example "nr"
{Ask} TypeIn Tabela Enter TypeIn "Fast" Enter
Moveto [Codigo do Representante  ] Example "crep"
Moveto [Nome Fantasia Represent  ] TypeIn "Changeto " Example "nr"
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_DESTINAT"      : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_DTFIM"
            Case Campo="TG_OPMODEL"       : Campo="TG_OPRELCODALF"
            Case Campo="TG_OPACVR"        : Campo="TG_OPMODEL"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"    :Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"    :Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"    :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       :Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF" :Campo="TG_OPMODEL"
                    Case Campo="TG_OPMODEL"     :Campo="TG_OPACVR"
                         VSDGOPMODEL=ControlValue("TG_OPMODEL")
                         If VSDGOPMODEL = "2"
                            Then VSDGNOMOPMODEL= "COM TOTAL"
                            Else VSDGOPMODEL = "1"
                                 VSDGNOMOPMODEL= "SEM TOTAL"
                        EndIf
                            
                    Case Campo="TG_OPACVR"      : Campo="YES"
                         VSDGOPACVR=ControlValue("TG_OPACVR")
                         If VSDGOPACVR="C"
                            Then VSDGDESCOPACVR="COM VALORES"
                            Else VSDGOPACVR    ="S"
                                 VSDGDESCOPACVR="SEM VALORES"
                         EndIf
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTINI":
     MSG_CAMPO="Informe a Data Inicial"
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_OPACVR":
     MSG_CAMPO="Imprimir: C=Com Valores  S=Sem Valores"
  Case Campo="TG_OPMODEL":
     MSG_CAMPO="Imprimir: 1=Sem Total  2=Com Total"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf

VSDGEMPRESA =""
VSDGREPRESEN=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
VSDGOPRELCODALF=""
VSDGOPACVR  =""
VSDGOPMODEL = ""
VSDGDESTINAT = ""
While True

  ShowDialog "Vendas por Representante/Cliente/Ano" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN"  To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 06,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI"  To VSDGNOMDEST
    
    Label  @ 08,00 "Per¡odo Referente (M ximo 4 Anos)" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡„o de Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 02,35 "Modelo" For "TG_OPMODEL"
    Accept @ 03,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPMODEL" To VSDGOPMODEL
    Accept @ 03,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPMODEL" To VSDGNOMOPMODEL

    Label  @ 04,35 "Op‡„o de Valores" For "TG_OPACVR"
    Accept @ 05,39 Width 04 "A1"  Picture "C,S" Tag "TG_OPACVR" To VSDGOPACVR
    Accept @ 05,44 Width 25 "A20"  Picture "!*!" Tag "TG_DESCOPACVR" To VSDGDESCOPACVR

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  If IsBlank(VSDGDTINI)
     Then Mensagem("Data Inicial Invalida !")
          Loop
  EndIf

  qanos=1+(Year(VSDGDTFIM)-Year(VSDGDTINI))
  If qanos>4
     Then Mensagem("Intervalo m ximo de 4 anos !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_3114"
  Copy "\\Base\\Sistemas\\Vendas\\RM_3114" Tabela

  ;--campos calculado report/titulos ---
   ano1="____"
   ano2="____"
   ano3="____"
   ano4="____"
  ;-------------------------------------
  VSDGDTINI2=VSDGDTINI
  VSDGDTFIM2=VSDGDTFIM

  For anoref from 1 to qanos
   
    Switch
      case anoref=1: VSDGDTINI=VSDGDTINI2
                     VSDGDTFIM=DateVal("31.12."+StrVal(Year(VSDGDTINI2)))
                     ano1=StrVal(Year(VSDGDTFIM))
                     
      case anoref=2: VSDGDTINI=DateVal("01.01."+StrVal(Year(VSDGDTINI2)+1))
                     VSDGDTFIM=DateVal("31.12."+StrVal(Year(VSDGDTINI2)+1))
                     ano2=StrVal(Year(VSDGDTFIM))
                     
      case anoref=3: VSDGDTINI=DateVal("01.01."+StrVal(Year(VSDGDTINI2)+2))
                     VSDGDTFIM=DateVal("31.12."+StrVal(Year(VSDGDTINI2)+2))
                     ano3=StrVal(Year(VSDGDTFIM))
      case anoref=4: VSDGDTINI=DateVal("01.01."+StrVal(Year(VSDGDTINI2)+3))
                     VSDGDTFIM=VSDGDTFIM2
                     ano4=StrVal(Year(VSDGDTFIM))
    EndSwitch

    Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
    While Novo_Dir_Trab()
      Seleciona()
    EndWhile
  EndFor

  VSDGDTINI=VSDGDTINI2
  VSDGDTFIM=VSDGDTFIM2

  If Not IsEmpty(Tabela)
     Then
          Processa()
        
          Impressao_Orientacao="Paisagem"
          switch
            case VSDGOPMODEL="2" :
              If VSDGOPRELCODALF="1"
                 Then Seta_Ordem_Report(Tabela,"R","Codigo","Codigo"              ,"")
                 Else Seta_Ordem_Report(Tabela,"R","Codigo do Item","Razao Social","")
              EndIf
              IMPRIREL(Tabela,"R")

            case VSDGOPMODEL="1" :
              If VSDGOPRELCODALF="1"
                 Then Seta_Ordem_Report(Tabela,"2","Codigo","Codigo"              ,"")
                 Else Seta_Ordem_Report(Tabela,"2","Codigo do Item","Razao Social","")
              EndIf
              IMPRIREL(Tabela,"2")

          endswitch
     Else MENSAGEM("N„o existem registros a processar")
  EndIf

  Delete "Answer"
  Delete Tabela
EndWhile
ClearAll
Release Vars All
Release Procs All
