;** Rm_0112 ********************************************************************
;*  Clientes sem compra no per¡odo Ranking Pedidos - Ranking Pedidos           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 14/04/2009 por Anivel Augusto Rodrigues
;Ultima Alteracao: 22/10/2009 por Bruno Carvalho
;Motivo Alteracao: Inclusao do Campo VCDGESTADO
;Ultima Alteracao: 28/10/2009 por Bruno Carvalho
;Motivo Alteracao: Script Modificado ()
;Ultima Alteracao: 06/12/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes de criterios
;Ultima Alteracao: 28/02/2012 por Karina Andrade
;Motivo Alteracao: Add filtro por "TG_GERENCIA"
;Ultima Alteracao: 24/07/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes Diret¢rio Mˆs Fechado
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                  ] Example "COD"
Moveto [Data da Primeira Compra ] Check
Moveto [Valor da Primeira Compra] Check
Moveto [Data da Ultima Compra   ] Check
Moveto [Valor da Ultima Compra  ] Check

{Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
Moveto [Codigo do Representante] Example "crep"
Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."

{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                  ] Check Example "COD" TypeIn "!"
Moveto [Tipo                    ] TypeIn "C"
Moveto [Razao Social            ] Check
Moveto [Cidade                  ] Check
If UPPER(VSDGCIDADE)<>"TODAS"
   Then TypeIn VSDGCIDADE
EndIf
Moveto [UF                      ] Check TypeIn "~VSDGESTADO.."
Moveto [Telefone                ] Check
Moveto [Contato                 ] Check
Moveto [Codigo do Representante ] Check Example "crep" TypeIn "!, ~VSDGREPRESEN.."
Moveto [Nome Fantasia Represent ] Check
Moveto [Endereco                ] Check
Moveto [Bairro                  ] Check
Moveto [CEP                     ] Check
Moveto [Inativo                 ] TypeIn "Not S"
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar Vendas                                                 *
;*******************************************************************************
Proc Sel_Vendas()
ClearAll  

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") 
   Then {Ask} {\\Sistemas\\Vendas\\Destin}
        Moveto [Codigo da Destinacao  ] Example "cd"
        Moveto [Tipo Movimento Estoque] TypeIn "S"
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
        Moveto [Codigo                 ] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo da Destinacao   ] Example "cd"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.."
        Moveto [Situacao do Pedido     ]
        switch
          case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
          case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
        endswitch
        Do_It!
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo                 ] Example "cod"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Delete"
        Moveto [Codigo                 ] Example "cod"
        Do_It!
        ClearAll        
EndIf

EndProc   ; (Sel_Vendas)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_ESTADO"        : Campo="TG_EMPRESA"
            Case Campo="TG_CIDADE"        : Campo="TG_ESTADO" 
            Case Campo="TG_REPRESEN"      : Campo="TG_CIDADE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI"         : Campo="TG_GERENCIA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_DTFIM" 
            Case Campo="TG_MODELOREL"     : Campo="TG_OPRELCODALF"
            Case Campo="TG_SITUACAOPEDIDO": Campo="TG_MODELOREL" 
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    :Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"     :Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"     :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   :Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"   :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      :Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF":Campo="TG_MODELOREL"
                    Case Campo="TG_MODELOREL"  :Campo="TG_SITUACAOPEDIDO"
                         VSDGMODELOREL=ControlValue("TG_MODELOREL")
                         Switch
                           Case VSDGMODELOREL="2": VSDGNOMMODELOREL="COM ENDERECO"
                           OtherWise:
                                VSDGMODELOREL="1"  VSDGNOMMODELOREL="SIMPLES"
                         EndSwitch
                    Case Campo="TG_SITUACAOPEDIDO"  : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a Data Inicial do Periodo"
  Case Campo="TG_DTFIM":
       MSG_CAMPO="Informe a Data Final do Periodo"
  Case Campo="TG_MODELOREL":
       MSG_CAMPO="Modelo: 1=Simples  2=Com Endere‡o"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*****************************************************************************+*
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA     =""
VSDGDTINI       =BlankDate()
VSDGDTFIM       =BlankDate()
VSDGCIDADE      =""
VSDGESTADO      =""
VSDGREPRESEN    =""
VSDGOPRELCODALF =""
VSDGMODELOREL   =""
VSDGGERENCIA    =""
VSDGSITUACAOPEDIDO  = ""

While True

  ShowDialog "Clientes sem compra no per¡odo Ranking Pedidos" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,09   Height 17 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Estado"  For "TG_ESTADO"
    Accept @ 03,03 Width 05 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMESTADO"  To VSDGNOMESTADO

    Label  @ 04,00 "Cidade"  For "TG_CIDADE"
    Accept @ 05,01 Width 33 "A20"  Picture "!*!" Tag "TG_CIDADE"   To VSDGCIDADE

    Label  @ 06,00 "Representante"  For "TG_REPRESEN"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 08,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 09,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 09,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 10,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 02,35 "Modelo Relat¢rio" For "TG_MODELOREL"
    Accept @ 03,39 Width 04 "A1"   Picture "1,2" Tag "TG_MODELOREL" To VSDGMODELOREL
    Accept @ 03,44 Width 25 "A12"  Picture "!*!" Tag "TG_NOMMODELOREL" To VSDGNOMMODELOREL

    Label  @ 04,35 "Situacao do Pedido"  For "TG_SITUACAOPEDIDO"
    Accept @ 05,36 Width 33 "A30"  Picture "ABERTO,SUSPENSO,CANCELADO,FATURADO,TODAS,!*!" Tag "TG_SITUACAOPEDIDO"  To VSDGSITUACAOPEDIDO

    Pushbutton @ 13,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 13,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  If VSDGDTFIM < VSDGDTINI
     Then Mensagem("Data Final deve ser maior que Data Inicial !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Seleciona()
  If IsEmpty(Tabela) 
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf
  
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)     
  While Novo_Dir_Trab()
    Sel_Vendas()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf 
  
  TITR   ="sem"
  TITDATA="Compra"

  Switch
    Case VSDGMODELOREL="1":
      If VSDGOPRELCODALF="1"
         Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "11" Tabela "R"
         Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "12" Tabela "R"
      EndIf
    Case VSDGMODELOREL  ="2":
      If VSDGOPRELCODALF="1"
         Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "13" Tabela "R"
         Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "14" Tabela "R"
      EndIf
  EndSwitch

  IMPRIREL(Tabela,"R")

  If IsTable("Answer")     Then Delete "Answer"  EndIf
  If IsTable(Tabela)       Then Delete Tabela    EndIf

EndWhile
ClearAll
Release Vars All
Release Procs All
