;** Rm_0930 *********************************************************************
;* Resumo de Vendas por Vendedor                                                *
;********************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 15/04/1998 por Anivel Augusto Rodrigues
;Ultima Alteracao: 06/12/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 15/12/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 03/10/2013 por Andrey Fillipe          
;Motivo Alteracao: Adicionado filtro por Gerencia
;Ultima Alteracao: 26/02/2014 por Kamila Gomes          
;Motivo Alteracao: InclusÆo novos campos na tabela RM_0930
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc SELECIONA()
ClearAll
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then  For wiw From 1 To 5
           {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           If VSDGGERENCIA<>""
              Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
              Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           EndIf
           
           {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
           Moveto [Codigo da Empresa       ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
           Moveto [Numero do Documento     ] Example "ndoc" TypeIn ", Calc Count as NumReg"
           Moveto [Serie do Documento      ] Example "sdoc"
           Moveto [Codigo do Representante ] Check Example "crep" TypeIn "!, ~VSDGREPRESEN.."
           Moveto [Nome Fantasia Represent ] Check
           Moveto [Descricao da Destinacao ]
           If wiw<5
              Then TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
              Else TypeIn "..DEVOL.."
           EndIf
           Moveto [Data de Emissao         ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
           Moveto [Tipo Movimento Estoque  ]
           If wiw<5
              Then TypeIn "S"
              Else TypeIn "E"
           EndIf
           Moveto [Situacao                ] TypeIn "Not C"
           Moveto [Origem do Pedido        ]
           if wiw=1 Then TypeIn "Blank"  EndIf       
           if wiw=2 Then TypeIn "VISITA" EndIf
           if wiw=3 Then TypeIn "FONE"   EndIf
           if wiw=4 Then TypeIn "BALCAO" EndIf
           {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
           Moveto [Codigo da Empresa      ] Example "cemp"
           Moveto [Numero do Documento    ] Example "ndoc"
           Moveto [Serie do Documento     ] Example "sdoc"
           Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
           Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
           Moveto [Situacao_Item          ] TypeIn "Not C"
           Do_It!
           ClearAll

           {Ask} {Answer}
           Moveto [Codigo da Empresa        ] Example "cemp"
           Moveto [Codigo do Representante  ] Example "crep"
           Moveto [Nome Fantasia Represent  ] Example "nemp"
           Moveto [Data de Emissao          ] Example "date"
           Moveto [NumReg                   ] Example "nreg"
           Moveto [Preco Total              ] Example "ptot"
           Moveto [Valor Desconto Total     ] Example "vdes"

           {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
           Moveto [Codigo da Empresa        ] Example "cemp"
           Moveto [Codigo do Representante  ] Example "crep"
           Moveto [Nome Fantasia Represent  ] Example "nemp"
           Moveto [Data de Emissao          ] Example "date"
           Switch
             Case wiw=1:
                  Moveto [Vendas Geral Numero      ] Example "nreg"
                  Moveto [Vendas Geral Valor       ] Example "ptot" TypeIn"-" Example "vdes"
             Case wiw=2:
                  Moveto [Vendas Visita Numero     ] Example "nreg"
                  Moveto [Vendas Visita Valor      ] Example "ptot" TypeIn"-" Example "vdes"
             Case wiw=3:
                  Moveto [Vendas Fone Numero       ] Example "nreg"
                  Moveto [Vendas Fone Valor        ] Example "ptot" TypeIn"-" Example "vdes"
             Case wiw=4:
                  Moveto [Vendas Balcao Numero     ] Example "nreg"
                  Moveto [Vendas Balcao Valor      ] Example "ptot" TypeIn"-" Example "vdes"
             Case wiw=5:
                  Moveto [Devolucoes Numero        ] Example "nreg"
                  Moveto [Devolucoes Valor         ] Example "ptot" TypeIn"-" Example "vdes"
           EndSwitch
           Do_It!
           ClearAll
         EndFor
EndIf

;****** Devolucoes - Estoque ***************************************************
If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           If VSDGGERENCIA<>""
              Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
              Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           EndIf
   
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Codigo do Representante] Check Example "crep" TypeIn "!, ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Numero do Documento    ] TypeIn "Calc Count as NumReg"
        Moveto [Data de Entrada        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo de Operacao       ] TypeIn "D"
        Moveto [Nome Fantasia Empresa  ] Check
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Do_It!
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Nome Fantasia Represent] Example "nemp"
        Moveto [Data de Entrada        ] Example "date"
        Moveto [NumReg                 ] Example "nreg"
        Moveto [Preco Total            ] Example "ptot"
        Moveto [Valor Desconto Total   ] Example "vdes"

        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Nome Fantasia Represent] Example "nemp"
        Moveto [Data de Emissao        ] Example "date"
        Moveto [Devolucoes Numero      ] Example "nreg"
        Moveto [Devolucoes Valor       ] Example "ptot" TypeIn"-" Example "vdes"
        Do_It!
        ClearAll
EndIf
EndProc   ;  (Seleciona)

;*******************************************************************************
;* Rotina p/ Processar  Registros                                              *
;*******************************************************************************
Proc PROCESSA()
ClearAll

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
				;;Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
 ;;Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
 ;; 		Moveto [Codigo da Empresa 		 ] Example "cemp"
 ;; 		Moveto [Nome Fantasia Empresa  ] Example "nemp"
 ;; 		{Ask} TypeIn Tabela Enter TypeIn "Fast"
 ;; 		Moveto [Codigo da Empresa 		 ] Example "cemp"
 ;; 		Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
 ;; 		Do_It!
 ;; 		ClearAll
EndIf

;****** Somatorio Vendedor *****************************************
If VSDGOPRELANALSINT="2"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Data de Emissao] TypeIn "Changeto Blank"
        Do_It!
        ClearAll
EndIf

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Data de Emissao        ] Check
Moveto [Vendas Geral Numero    ] TypeIn "Calc Sum as Vendas Geral Numero"
Moveto [Vendas Geral Valor     ] TypeIn "Calc Sum as Vendas Geral Valor"
Moveto [Vendas Visita Numero   ] TypeIn "Calc Sum as Vendas Visita Numero"
Moveto [Vendas Visita Valor    ] TypeIn "Calc Sum as Vendas Visita Valor"
Moveto [Vendas Fone Numero     ] TypeIn "Calc Sum as Vendas Fone Numero"
Moveto [Vendas Fone Valor      ] TypeIn "Calc Sum as Vendas Fone Valor"
Moveto [Vendas Balcao Numero   ] TypeIn "Calc Sum as Vendas Balcao Numero"
Moveto [Vendas Balcao Valor    ] TypeIn "Calc Sum as Vendas Balcao Valor"
Moveto [Devolucoes Numero      ] TypeIn "Calc Sum as Devolucoes Geral Numero"
Moveto [Devolucoes Valor       ] TypeIn "Calc Sum as Devolucoes Geral Valor"
Moveto [Vendas Empresa Numero  ] TypeIn "Calc Sum as Vendas Empresa Numero"
Moveto [Vendas Empresa Valor   ] TypeIn "Calc Sum as Vendas Empresa Valor"
Moveto [Devolucoes Empresa Numero] TypeIn "Calc Sum as Devolucoes Empresa Numero"
Moveto [Devolucoes Empresa Valor ] TypeIn "Calc Sum as Devolucoes Empresa Valor"
Moveto [Devolucoes Empresa Quant ] TypeIn "Calc Sum as Devolucoes Empresa Quant"
Moveto [Desconto Valor           ] TypeIn "Calc Sum as Desconto Valor"
Do_It!
ClearAll

;****** Somatorio Vendedor II **************************************
CoEdit "Answer"
While Not EOT()
  If IsBlank([Codigo da Empresa]) And
     IsBlank([Codigo do Representante])
     Then Del
  EndIf
  [Vendas Geral Numero]=[Vendas Geral Numero]+[Vendas Visita Numero]+[Vendas Fone Numero]+[Vendas Balcao Numero]
  [Vendas Geral Valor ]=[Vendas Geral Valor ]+[Vendas Visita Valor ]+[Vendas Fone Valor ]+[Vendas Balcao Valor ]

  Skip
EndWhile
Do_It!
ClearAll

Empty(Tabela)
Add "Answer" Tabela
ClearAll

;****** Somatorio Empresa ******************************************
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas Geral Numero    ] TypeIn "Calc Sum as Vendas Geral Numero"
Moveto [Vendas Geral Valor     ] TypeIn "Calc Sum as Vendas Geral Valor"
Moveto [Devolucoes Numero      ] TypeIn "Calc Sum as Devolucoes Numero"
Moveto [Devolucoes Valor       ] TypeIn "Calc Sum as Devolucoes Valor"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Vendas Geral Numero    ] Example "ven"
Moveto [Vendas Geral Valor     ] Example "vev"
Moveto [Devolucoes Numero      ] Example "den"
Moveto [Devolucoes Valor       ] Example "dev"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa        ] Example "cemp"
Moveto [Vendas Empresa Numero    ] TypeIn "Changeto " Example "ven"
Moveto [Vendas Empresa Valor     ] TypeIn "Changeto " Example "vev"
Moveto [Devolucoes Empresa Numero] TypeIn "Changeto " Example "den"
Moveto [Devolucoes Empresa Valor ] TypeIn "Changeto " Example "dev"
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI"         : Campo="TG_GERENCIA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"      :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"     :Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"     :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"        :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"        :Campo="TG_OPRELANALSINT"
                    Case Campo="TG_OPRELANALSINT":Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGDESTINAT=""
VSDGOPRELANALSINT=""
VSDGNOMOPRELANALSINT=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Resumo de Vendas por Representante/Origem Diaria" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 13 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN"  To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡„o do Relat¢rio" For "TG_OPRELANALSINT"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELANASINT" To VSDGNOMOPRELANALSINT

    Pushbutton @ 09,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0930"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0930" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  If VSDGOPRELANALSINT="1"
     Then IMPRIREL(Tabela,"R")
     Else IMPRIREL(Tabela,"1")
  EndIf

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
