
; antes era o menu 34
; ** nÆo usar mais, foi substituito pelo modelo 12 da posi‡Æo de pedidos. - menu 38
; relatorio com erro

;Rm_0404  **********************************************************************
;* Ranking Representante/Cliente                                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 07/12/2010 por Anivel Augusto Rodrigues
;Ultima Alteracao: 24/07/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes Diret¢rio Mˆs Fechado
;Ultima Alteracao: 19/03/2013 por Bruno Carvalho
;Motivo Alteracao: Comentado a linha "Fator Conversao" quando utilizado nos Itens 
;Ultima Alteracao: 19/03/2013 Bruno Carvalho
;Motivo Alteracao: Alterado campo [Fator Conversao] p/ [Aliquota de IR]
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 04/05/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes calculo preco unitartio com desconto
;Ultima Alteracao: 19/10/2017 por Bruno Carvalho
;Motivo Alteracao: [Aliquota de IR] substitu¡do [Volumes] na ASK "PedidoI", renomeado p/ Aliquota de IR conforme tabela de report
;Ultima Alteracao: 20/10/2017 por Bruno Carvalho
;Motivo Alteracao: Ajustes [Codigo da Marca]

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll                    

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If Not IsBlank (VSDGGERENCIA)
           Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        EndIf

        {Ask} {\\Sistemas\\Vendas\\Destin}
        Moveto [Codigo da Destinacao  ] Example "cd"
        Moveto [Tipo Movimento Estoque] TypeIn "S"

        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA2.."
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Codigo do Representante] Check
        Moveto [Nome Fantasia Represent] Check
        Moveto [Codigo                 ] Check
        Moveto [Razao Social           ] Check
        Moveto [Data de Emissao        ] Check
        Moveto [Data de Entrega        ] Check
        Moveto [Numero do Pedido       ] Check Example "Pedido" TypeIn " , as Numero do Pedido Cabeca"        
        Moveto [Situacao do Pedido     ] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo do Representante] Example "crep" TypeIn "!, ~VSDGREPRESEN.."
        Moveto [Codigo da Destinacao   ] Example "cd"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.."
        Moveto [Situacao do Pedido     ]
        switch
          case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
          case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
        endswitch
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter Check
        Moveto [Numero do Pedido] Example "Pedido"
        Moveto [Codigo do Item  ] Example "Item"
        Moveto [Volumes         ] TypeIn "as Aliquota de IR"
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item  ] Example "Item"
        Moveto [Codigo da Marca ] TypeIn "~VSDGMARCA.."        
        Do_It!
        ClearAll   

        If IsEmpty("Answer")                                                                                             
           Then Return
        EndIf   
        
        ;; *** Ajustando contador de Pedidos ****
        Sort "Answer" On "Numero do Pedido"
        ClearAll
                  
        Edit "Answer"
        NPED="***"
        Scan
        
          If [Numero do Pedido]=NPED
             Then [Aliquota de IR]=0
             Else [Aliquota de IR]=1
                  NPED=[Numero do Pedido]
          EndIf
          
          [Preco Unitario]=([Preco Total]-[Valor Desconto Total])/[Quantidade]
        
        EndScan
        
        Do_It!
        ClearAll     
    
EndIf                 

EndProc; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"         : Campo="NO"
            Case Campo="TG_MARCA"           : Campo="TG_EMPRESA"
            Case Campo="TG_REPRESEN"        : Campo="TG_MARCA"
            Case Campo="TG_GERENCIA"        : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI"           : Campo="TG_GERENCIA"
            Case Campo="TG_DTFIM"           : Campo="TG_DTINI"
            Case Campo="TG_SITUACAOPEDIDO"  : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"         : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"           : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"        : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"        : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"           : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"           : Campo="TG_SITUACAOPEDIDO"
                    Case Campo="TG_SITUACAOPEDIDO"  : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_PEDIDO":
     MSG_CAMPO="Em Branco = Todos"
  Case Campo="TG_TPDATA":
       MSG_CAMPO="1 = EMISSAO  2 = ENTREGA"
  Case Campo="TG_SITUACAO":
    MSG_CAMPO="A = Aberto  F = Faturado  C = Cancelado  Em Branco = Todos"
  Case Campo="TG_UTILIZAITENS":
    MSG_CAMPO="M = Mostra Itens  O = Oculta Itens"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA          =""
VSDGMARCA            =""
VSDGREPRESEN         =""
VSDGGERENCIA         =""
VSDGDTINI            =BlankDate()
VSDGDTFIM            =BlankDate()
VSDGSITUACAOPEDIDO  = ""

While True

  ShowDialog "Ranking Representante/Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,09   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Marca"  For "TG_MARCA"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 06,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 07,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Situacao do Pedido"  For "TG_SITUACAOPEDIDO"
    Accept @ 01,36 Width 33 "A30"  Picture "ABERTO,SUSPENSO,CANCELADO,FATURADO,TODAS,!*!" Tag "TG_SITUACAOPEDIDO"  To VSDGSITUACAOPEDIDO

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer") Then Delete "Answer" EndIf
    
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf 

  CopyReport "\\Base\\Sistemas\\Vendas\\RM_0404" "R" Tabela "R"

  IMPRIREL(Tabela,"R")
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
