;** Rm_0620  *******************************************************************
;*  Emissao da Apuracao da Comissao % da Nota - Acerto                         *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 30/06/2006 por Davi Pereira Carrano
;Motivo Alteracao: Correcao para constar devolucao
;Ultima Alteracao: 20/06/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Vales MODAMIL
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 14/04/2014 por Bruno/Gustavo
;Motivo Alteracao: Ajustes p/ Inclusao de Rateio de Comissao de Representante
;Ultima Alteracao: 04/06/2014 por Bruno Carvalho
;Motivo Alteracao: Ajustes quando campo de opera‡Æo for "Devolucao"
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado op‡Æo para filtrar por rateio de comissao de representante
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Ajustes otimizando os processos "Devolucoes", "Pendentes" e "Comissäes Pagas"
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Omitido a op‡Æo de Filtrar por rateio de comissao de representante
;Ultima Alteracao: 11/06/2014 por Luis Gustavo
;Motivo Alteracao: Adicionado Filtro por Gerˆncia
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 29/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Edit para Coedit
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes gerar comissao 
;Ultima Alteracao: 20/05/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtrar plano de contas ref valse/adiantamentos

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc SELECIONA()
ClearAll

;****** Vendas/Devolu‡äes *******
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")                 
   Then If Not IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC")
           Then FIM_RATEIO = 1
        EndIf   
   
        For wi2 From 1 To 4 
          For wi From INICIO_RATEIO To FIM_RATEIO 
           {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
            Moveto [Codigo do Representante] Example "crep"
            Moveto [Codigo da Gerencia    ] Check
            If Not IsBlank(VSDGGERENCIA)
               Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
            EndIf
             
            If wi = 2
               Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC" Enter
                    Moveto [Codigo da Empresa        ] Example "a"
                    Moveto [Numero do Documento      ] Example "b"
                    Moveto [Serie do Documento       ] Example "c"
                    Moveto [Item do Documento        ] TypeIn "0"
                    Moveto [Codigo do Representante  ] Check TypeIn "_crep!, ~VSDGREPRESEN.."
                    Moveto [Nome Fantasia Represent  ] Check
                    Moveto [Comissao do Representante] Check
            EndIf
            
            {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
            Moveto [Codigo da Empresa        ] Check Example "a" TypeIn ", ~VSDGEMPRESA.."
            Moveto [Numero do Documento      ] Check Example "b"
            Moveto [Serie do Documento       ] Check Example "c"
            Moveto [Situacao                 ] TypeIn "Not C"
            Moveto [Nome Fantasia Empresa    ] Check
            Moveto [Nome Fantasia EmitDest   ] Check
            Moveto [Numero da OF             ] Check
            Moveto [Codigo                   ] Check
            Moveto [Data de Acerto           ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
            Moveto [Forma de Pagamento       ] TypeIn "Not PE"
            
            Switch
              Case wi2 = 1 Or 
                   wi2 = 2 Or 
                   wi2 = 3  : Moveto [Descricao da Destinacao  ] Check TypeIn "..VEND.." 
                              Moveto [Tipo Movimento Estoque   ] TypeIn "S"
                              Switch
                                Case wi2 = 2 : Moveto [Forma de Pagamento] TypeIn "PE"    ;Pendentes 
                                Case wi2 = 3 : Moveto [Comissao paga     ] TypeIn "S"     ;Comissao Pagas            
                              EndSwitch
              Case wi2 = 4 : Moveto [Descricao da Destinacao   ] Check TypeIn "..DEVOL.." ;Devolucoes
                             Moveto [Tipo Movimento Estoque    ] TypeIn "E"
            EndSwitch  

            If wi = 1
               Then Moveto [Codigo do Representante  ] Check TypeIn "_crep, ~VSDGREPRESEN.."
                    Moveto [Nome Fantasia Represent  ] Check
                    Moveto [Comissao do Representante] Check
            EndIf
    
            {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
            Moveto [Codigo da Empresa      ] Example "a"
            Moveto [Numero do Documento    ] Example "b"
            Moveto [Serie do Documento     ] Example "c"
            Moveto [Item do Documento      ] Check
            Moveto [Codigo do Item         ] Check
            Moveto [Quantidade             ] Check
            Moveto [Preco Total            ] Check
            Moveto [Valor Desconto Total   ] Check
            Moveto [Situacao_Item          ] TypeIn "Not C"
            Do_It!
            ClearAll
            
            {Ask} {Answer}                
            Moveto [Codigo da Empresa        ] Example "a"
            Moveto [Numero do Documento      ] Example "b"
            Moveto [Serie do Documento       ] Example "c"
            Moveto [Codigo do Representante  ] Example "d"
            Moveto [Nome Fantasia Empresa    ] Example "ne"
            Moveto [Nome Fantasia Represent  ] Example "nr"
            Moveto [Nome Fantasia EmitDest   ] Example "nc"
            Moveto [Numero da OF             ] Example "no"
            Moveto [Codigo                   ] Example "clie"
            Moveto [Comissao do Representante] Example "VSDGTAXAD"
            Moveto [Data de Acerto           ] Example "e"
            Moveto [Codigo do Item           ] Example "f"
            Moveto [Quantidade               ] Example "g"
            Moveto [Preco Total              ] Example "h"
            Moveto [Valor Desconto Total     ] Example "i"
            
            {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"    
            Switch
              Case wi2 = 1 : Moveto [Operacao] TypeIn "\"Vendas\""
              Case wi2 = 2 : Moveto [Operacao] TypeIn "\"Pendentes\""
              Case wi2 = 3 : Moveto [Operacao] TypeIn "\"Com. Pagas\""
              Case wi2 = 4 : Moveto [Operacao] TypeIn "\"Devolucoes\""    
            EndSwitch 
            Moveto [Codigo da Empresa      ] Example "a"
            Moveto [Numero do Documento    ] Example "b"
            Moveto [Serie do Documento     ] Example "c"
            Moveto [Codigo do Representante] Example "d"
            Moveto [Data de Emissao        ] Example "e"
            Moveto [Nome Fantasia Empresa  ] Example "ne"
            Moveto [Nome Fantasia Represent] Example "nr"
            Moveto [Nome Fantasia EmitDest ] Example "nc"
            Moveto [Numero da OF           ] Example "no"
            Moveto [Codigo do Item         ] Example "f"
            Moveto [Aliquota Comissao      ] Example "VSDGTAXAD"
            Moveto [Codigo                 ] Example "clie"           
            Switch
              Case wi2 = 1 : Moveto [Quantidade ] Example "g" 
                             Moveto [Preco Total] Example "h" TypeIn "-" Example "i"
                             Moveto [Comissao   ] TypeIn "(("Example "h" TypeIn "-" Example "i" TypeIn ")*" Example "VSDGTAXAD" TypeIn ")/100"             
              Case wi2 = 2 Or 
                   wi2 = 3 Or                     
                   wi2 = 4  : Moveto [Quantidade ] Example "g" TypeIn "*-1"
                              Switch
                                Case wi2 = 2 : Moveto [Preco Total] Example "h" TypeIn "-" Example "i"
                                OtherWise    : Moveto [Preco Total] TypeIn "(" Example "h" TypeIn "-" Example "i" TypeIn ")*-1"
                                               Moveto [Comissao   ] TypeIn "((("Example "h" TypeIn "-" Example "i" TypeIn ")*" Example "VSDGTAXAD" TypeIn ")/100)*-1"
                              EndSwitch                           
            EndSwitch                      
            Do_It!
            ClearAll
            
            View "\\Sistemas\\Cadastro\\Destinat"
            CoEdit Tabela
            Scan 
              GetRecord "\\Sistemas\\Cadastro\\Destinat" [Codigo] To REG_DESTINAT
              If RetVal
                 Then [Observacoes]=[Codigo]+" "+Completa(Substr(REG_DESTINAT["Razao Social"],1,30),32," ")+REG_DESTINAT["UF"]+"/"+Substr(REG_DESTINAT["Cidade"],1,17)
              EndIf   
            EndScan
            Do_It!
            ClearAll 
                        
          EndFor
        EndFor
EndIf

;****** Devolucoes *******
If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then 
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia    ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia    ] TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEc" Enter
        Moveto [Numero do Lancamento   ] Example "x"
        Moveto [Codigo da Empresa      ] CheckPlus TypeIn "~VSDGEMPRESA.."
        Moveto [Numero do Documento    ] CheckPlus
        Moveto [Serie do Documento     ] CheckPlus
        Moveto [Codigo do Representante] CheckPlus Example "crep" TypeIn "! ,~VSDGREPRESEN.."
        Moveto [Data de Entrada        ] CheckPlus TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo de Operacao       ] TypeIn "D"
        Moveto [Nome Fantasia Empresa  ] CheckPlus
        Moveto [Nome Fantasia Represent] CheckPlus
        Moveto [Nome Fantasia EmitDest ] CheckPlus
        Moveto [Codigo                 ] CheckPlus
        Moveto [Comissao do Representante] CheckPlus

        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
        Moveto [Numero do Lancamento   ] Example "x"
        Moveto [Codigo do Item         ] CheckPlus
        Moveto [Quantidade             ] CheckPlus
        Moveto [Preco Total            ] CheckPlus
        Moveto [Valor Desconto Total   ] CheckPlus
        Do_It!
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo da Empresa        ] Example "a"
        Moveto [Numero do Documento      ] Example "b"
        Moveto [Serie do Documento       ] Example "c"
        Moveto [Codigo do Representante  ] Example "d"
        Moveto [Data de Entrada          ] Example "e"
        Moveto [Nome Fantasia Empresa    ] Example "ne"
        Moveto [Nome Fantasia Represent  ] Example "nr"
        Moveto [Nome Fantasia EmitDest   ] Example "nc"
        Moveto [Codigo                   ] Example "clie"
        Moveto [Comissao do Representante] Example "VSDGTAXAD"
        Moveto [Codigo do Item           ] Example "f"
        Moveto [Quantidade               ] Example "g"
        Moveto [Preco Total              ] Example "h"
        Moveto [Valor Desconto Total     ] Example "i"

        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Operacao               ] TypeIn "\"Devolucoes\""
        Moveto [Codigo da Empresa      ] Example "a"
        Moveto [Numero do Documento    ] Example "b"
        Moveto [Serie do Documento     ] Example "c"
        Moveto [Codigo do Representante] Example "d"
        Moveto [Data de Emissao        ] Example "e"
        Moveto [Nome Fantasia Empresa  ] Example "ne"
        Moveto [Nome Fantasia Represent] Example "nr"
        Moveto [Nome Fantasia EmitDest ] Example "nc"
        Moveto [Codigo do Item         ] Example "f"
        Moveto [Quantidade             ] Example "g" TypeIn "*-1"
        Moveto [Preco Total            ] TypeIn "(" Example "h" TypeIn "-" Example "i" TypeIn ")*-1"
        Moveto [Comissao               ] TypeIn "((("Example "h" TypeIn "-" Example "i" TypeIn ")*" Example "VSDGTAXAD" TypeIn ")/100)*-1"
        Moveto [Aliquota Comissao      ] Example "VSDGTAXAD"
        Moveto [Codigo                 ] Example "clie"
        Do_It!
        ClearAll
EndIf

EndProc  ;(Seleciona)

;*******************************************************************************
;* Rotina para processar Db temporaria                                         *
;*******************************************************************************
Proc Processa()
;****** Taxa Administrativa sobre Devolucoes *******
If Not VSDGTAXAD>0
   Then Return
EndIf

{Ask} TypeIn Tabela Enter
Moveto [Operacao               ] Check TypeIn "Devolucoes"
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Preco Total            ] Example "h"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Operacao               ] TypeIn "\"Administr.\""
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Nome Fantasia EmitDest ] TypeIn "\"SOBRE DEVOLUCOES\""
Moveto [Comissao               ] TypeIn "("Example "h" TypeIn "*~VSDGTAXAD)/100"
Moveto [Aliquota Comissao      ] TypeIn "VSDGTAXAD"
Do_It!
ClearAll
EndProc   ;  (Processa)

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaVales()
ClearAll

if isblank(VSDGPLCONTAS3)
   then return
endif   

If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont")
  Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
       Moveto [Codigo                 ] Example "codemit"
       Moveto [Codigo do Representante] Check TypeIn "~VSDGREPRESEN.."
       Moveto [Nome Fantasia Represent] Check
       {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter Check
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
       Moveto [Tipo de Operacao      ] TypeIn "05 or 06 or 07 or 13 or 14"
       Moveto [Data                  ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       Moveto [Codigo do EmitDest    ] Example "codemit"
       Moveto [Cheque Pre-Datado     ] TypeIn "Not S"
       Moveto [Codigo Plano_Conta    ] TypeIn VSDGPLCONTAS3
       Do_It!
       ClearAll

       If IsTAble(Tabela2)
          Then Add "Answer" Tabela2
          Else Rename "Answer" Tabela2
       EndIf
EndIf
EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SelecionaVales2()
ClearAll

if isblank(VSDGPLCONTAS3)
   then return
endif   

If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont")
  Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
       Moveto [Codigo                 ] Example "codemit"
       Moveto [Codigo do Representante] Check TypeIn "~VSDGREPRESEN.."
       Moveto [Nome Fantasia Represent] Check
       {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter Check
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
       Moveto [Tipo de Operacao      ] TypeIn "05"
       Moveto [Codigo do EmitDest    ] Example "codemit"
       Moveto [Cheque Pre-Datado     ] TypeIn "S"
       Moveto [Data Cheque Pre-Datado] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       Moveto [Codigo Plano_Conta    ] TypeIn VSDGPLCONTAS3
       Do_It!
       ClearAll

       If IsTable(Tabela2)
          Then Add "Answer" Tabela2
          Else Rename "Answer" Tabela2
       EndIf
EndIf
EndProc

;*******************************************************************************
;* Rotina p/ Processar Registros                                               *
;*******************************************************************************
Proc Processa2()
ClearAll

{Ask} TypeIn Tabela2 Enter TypeIn "Fast"
Moveto [Tipo de Operacao       ] TypeIn "05"
Moveto [Cheque Pre-Datado      ] TypeIn "S"
Moveto [Data Cheque Pre-Datado ] TypeIn "_dchp"
Moveto [Data                   ] TypeIn "Changeto _dchp"
Do_It!
ClearAll

{Ask} TypeIn Tabela2 Enter
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Data                   ] Example "dt"
Moveto [Valor                  ] Example "vr"
Moveto [Descricao do Historico ] Example "dh"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Operacao               ] TypeIn "\"Vales\""
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Data de Emissao        ] Example "dt"
Moveto [Nome Fantasia EmitDest ] Example "dh"
Moveto [Comissao               ] TypeIn "_vr*-1"
Do_It!
ClearAll

EndProc     ;  (Seleciona)

;*******************************************************************************
;* Rotina p/                                                                   *
;*******************************************************************************
Proc GeraComissao()
ClearAll


;-------------

PC_0000_AquivoDeParametrosGeraComissao="PC_0620" ; informar o Rm_XXXX como PC_XXXX nÆo esquecer 
Play "PC_0000"

;-------------

EndProc     

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESA"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN" 
            Case Campo="TG_TAXAD"         : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_TAXAD"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_PLCONTAS3"     : Campo="TG_DTFIM"
            Case Campo="TG_COMISSAO"      : Campo="TG_PLCONTAS3"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN" : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA" : Campo="TG_TAXAD"
                    Case Campo="TG_TAXAD"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"    : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"    : Campo="TG_PLCONTAS3"   
                    Case Campo="TG_PLCONTAS3": Campo="TG_COMISSAO"
                    Case Campo="TG_COMISSAO" : Campo="YES" 

                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPCAO":
     MSG_CAMPO="1=SEM RATEIO  2=COM RATEIO  3=APENAS RATEIO"
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_COMISSAO":
       MSG_CAMPO="Defina a op‡„o"
       TECLA="Barra de Espa‡o=Marca/Desmarca  "
     
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

sys_valor()

VSDGEMPRESA  = ""
VSDGREPRESEN = ""
VSDGOPCAO    = ""
VSDGNOMOPCAO = ""
VSDGTAXAD    = BlankNum()
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()

VSDGPLCONTAS3=""

Array TG_COMISSAO[1]
TG_COMISSAO[1]="Gera comiss„o Contas a Pagar"

Array CheckTG_COMISSAO[ArraySize(TG_COMISSAO)]
CheckTG_COMISSAO[1]=False

While True

  ShowDialog "Apura‡„o de Comiss„o - % NF [ACERTO I]" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
    @ 01,00 Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

		Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 06,08 "% Devoluc„o"  For "TG_TAXAD"
    Accept @ 07,09 Width 12 "N" Tag "TG_TAXAD" To VSDGTAXAD

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Plano de Contas ref. Vales/Adiantamentos" For "TG_PLCONTAS3"
    Accept @ 01,36 Width 33 "A13"  Picture "!*!" Tag "TG_PLCONTAS3" To VSDGPLCONTAS3
    Accept @ 02,36 Width 33 "A40" Picture "!*!" Tag "TG_NOMPLCONTAS"  To VSDGNOMPLCONTAS

    CheckBoxes @ 04,35 Height 1 Width 35 Tag "TG_COMISSAO"
    TG_COMISSAO[1] to CheckTG_COMISSAO[1]        

    @ 14,01 ?? "Regra: Vendas, Pendentes/ComissÆo Paga, Devolu‡äes, %Adm/Devolu‡äes, Vales,"
    @ 15,01 ?? "       CH emitido/pr‚-datado"

    Pushbutton @ 18,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  ;---- Processo Omitido -----------------------------------
  VSDGOPCAO = "1"

  Switch
    Case VSDGOPCAO = "1" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 1 
    Case VSDGOPCAO = "2" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 2
    Case VSDGOPCAO = "3" : INICIO_RATEIO = 2
                           FIM_RATEIO    = 2
  EndSwitch
  ;---------------------------------------------------------  

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0610"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0610"  Tabela

  Tabela2=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
    SelecionaVales()
    SelecionaVales2()
  EndWhile

  If IsEmpty(Tabela) And
     IsEmpty(Tabela2)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Delete Tabela2
          Loop
  EndIf
  Processa()
  Processa2()

  if CheckTG_COMISSAO[1]
     then
          GeraComissao()
     else
          IMPRIREL(Tabela,"4")
  endif        

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
