;** Rm_0065D *******************************************************************
;*  Emissao da Apuracao e Acerto da Comissao usando % do Item da Nota Fiscal   *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido por: 29/01/2013 por Kamila Gomes
;Ultima Alteracao: 14/04/2014 por Bruno/Gustavo
;Motivo Alteracao: Ajustes p/ Inclusao de Rateio de Comissao de Representante
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado op‡Æo para filtrar por rateio de comissao de representante
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado CHECK "Item do Documento" no processo dos itens (Codigo e Qtd Iguais)
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado op‡Æo para filtrar por rateio de comissao de representante
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado CHECK "Item do Documento" no processo dos itens (Codigo e Qtd Iguais)
;Ultima Alteracao: 10/06/2014 por Bruno Carvalho
;Motivo Alteracao: Omitido a op‡Æo de Filtrar por rateio de comissao de representante
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog 
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()   
;Ultima Alteracao: 28/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes gerar comissao 
;Ultima Alteracao: 28/06/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes erro nome procedure
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas/Devolu‡äes *******
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC")
   Then For wi2 From 1 To 2 
          For wi From INICIO_RATEIO To FIM_RATEIO 
           {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           Moveto [Codigo da Gerencia     ] Check
           If Not IsBlank (VSDGGERENCIA)
              Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           EndIf
            
           If wi = 2
              Then {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaIC" Enter
                    Moveto [Codigo da Empresa        ] Example "a"
                    Moveto [Numero do Documento      ] Example "b"
                    Moveto [Serie do Documento       ] Example "c"
                    Moveto [Item do Documento        ] TypeIn "0"
                    Moveto [Codigo do Representante  ] Check TypeIn "_crep, ~VSDGREPRESEN.."
                    Moveto [Nome Fantasia Represent  ] Check
                    Moveto [Comissao do Representante] Check
           EndIf
              
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
          Moveto [Codigo da Empresa      ] Check Example "a" TypeIn ", ~VSDGEMPRESA.."
          Moveto [Numero do Documento    ] Check Example "b"
          Moveto [Serie do Documento     ] Check Example "c"
          Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Moveto [Situacao               ] TypeIn "Not C"
          Moveto [Nome Fantasia Empresa  ] Check
          Moveto [Codigo                 ] Check
          Moveto [Nome Fantasia EmitDest ] Check
          Moveto [Razao Social           ] Check
          Moveto [Numero da OF           ] Check
          Moveto [Data de Acerto         ] Check
          
          If VSDGOPRELANALSINT="S"
             Then Moveto [Comissao Paga  ] TypeIn "S"
             Else Moveto [Comissao Paga  ] TypeIn "Not S"
          EndIf
          
          Switch 
             Case  wi2 = 1 : Moveto [Descricao da Destinacao  ] TypeIn "..VEND.." 
                             Moveto [Tipo Movimento Estoque   ] TypeIn "S"
             Case  wi2 = 2 : Moveto [Descricao da Destinacao  ] TypeIn "..DEVOL.."
                             Moveto [Tipo Movimento Estoque   ] TypeIn "E"
          EndSwitch  
                    
          If wi = 1
             Then Moveto [Codigo do Representante  ] Check TypeIn "_crep, ~VSDGREPRESEN.."
                  Moveto [Nome Fantasia Represent  ] Check
                  Moveto [Comissao do Representante] Check
          EndIf 
          
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
          Moveto [Codigo da Empresa      ] Example "a"
          Moveto [Numero do Documento    ] Example "b"
          Moveto [Serie do Documento     ] Example "c"
          Moveto [Item do Documento      ] Check 
          Moveto [Codigo do Item         ] Check
          Moveto [Descricao do Item      ] Check
          Moveto [Quantidade             ] Check
          Moveto [Unidade Fiscal         ] Check
          Moveto [Preco Total            ] Check
          Moveto [Valor Desconto Total   ] Check
          Moveto [Comissao do Item       ] Check
          Moveto [Situacao_Item          ] TypeIn "Not C"
          Do_It!                  
          ClearAll
          
          {Ask} {Answer}
          Moveto [Codigo da Empresa        ] Example "a"
          Moveto [Numero do Documento      ] Example "b"
          Moveto [Serie do Documento       ] Example "c"
          Moveto [Data de Emissao          ] Example "e"
          Moveto [Nome Fantasia Empresa    ] Example "ne"
          Moveto [Codigo                   ] Example "cc"
          Moveto [Nome Fantasia EmitDest   ] Example "nc"
          Moveto [Razao Social             ] Example "rz"
          Moveto [Numero da OF             ] Example "no"
          Moveto [Codigo do Item           ] Example "f"
          Moveto [Descricao do Item        ] Example "descr"
          Moveto [Quantidade               ] Example "g"
          Moveto [Unidade Fiscal           ] Example "uf"
          Moveto [Preco Total              ] Example "h"
          Moveto [Valor Desconto Total     ] Example "i"
          Moveto [Codigo do Representante  ] Example "d"
          Moveto [Nome Fantasia Represent  ] Example "nr"
          Moveto [Comissao do Item         ] Example "TAXA"
          Moveto [Data de Acerto           ] Example "DtAc"
  
          {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
          Switch
              Case wi2 = 1 : Moveto [Operacao] TypeIn "\"Vendas\"" 
              Case wi2 = 2 : Moveto [Operacao] TypeIn "\"Devolucoes\"" 
           EndSwitch
          Moveto [Codigo da Empresa      ] Example "a"
          Moveto [Numero do Documento    ] Example "b"
          Moveto [Serie do Documento     ] Example "c"
          Moveto [Codigo do Representante] Example "d"
          Moveto [Data de Emissao        ] Example "e"
          Moveto [Nome Fantasia Empresa  ] Example "ne"
          Moveto [Nome Fantasia Represent] Example "nr"
          Moveto [Codigo                 ] Example "cc"
          Moveto [Nome Fantasia EmitDest ] Example "nc"
          Moveto [Razao Social           ] Example "rz"
          Moveto [Numero da OF           ] Example "no"
          Moveto [Codigo do Item         ] Example "f"
          Moveto [Descricao do Item      ] Example "descr"          
          Moveto [Unidade Fiscal         ] Example "uf"
          Moveto [Aliquota Comissao      ] Example "TAXA"
          Moveto [Data de Acerto         ] Example "DtAc"
          Switch
             Case wi2 = 1 : Moveto [Quantidade          ] Example "g"
                            Moveto [Preco Total         ] Example "h" TypeIn "-" Example "i"
                            Moveto [Comissao            ] TypeIn "(("Example "h" TypeIn "-" Example "i" TypeIn ")*" Example "TAXA" TypeIn ")/100"
             Case wi2 = 2 : Moveto [Quantidade          ] Example "g" TypeIn "*-1"
                            Moveto [Preco Total         ] TypeIn "(" Example "h" TypeIn "-" Example "i" TypeIn ")*-1"
                            Moveto [Comissao            ] TypeIn "((("Example "h" TypeIn "-" Example "i" TypeIn ")*" Example "TAXA" TypeIn ")/100)*-1"        
          EndSwitch             
          Do_It! 
          ClearAll
         EndFor
       EndFor
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina para processar Db temporaria                                         *
;*******************************************************************************
Proc Processa()
;****** Taxa Administrativa sobre Devolucoes *******

If Not VSDGTAXAD>0
   Then Return
EndIf

{Ask} TypeIn Tabela Enter
Moveto [Operacao               ] Check TypeIn "Devolucoes"
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Preco Total            ] Example "h"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Operacao               ] TypeIn "\"Administr.\""
Moveto [Codigo da Empresa      ] Example "a"
Moveto [Codigo do Representante] Example "d"
Moveto [Nome Fantasia Empresa  ] Example "ne"
Moveto [Nome Fantasia Represent] Example "nr"
Moveto [Nome Fantasia EmitDest ] TypeIn "\"SOBRE DEVOLUCOES\""
Moveto [Razao Social           ] TypeIn "\"SOBRE DEVOLUCOES\""
Moveto [Comissao               ] TypeIn "("Example "h" TypeIn "*~VSDGTAXAD)/100"
Moveto [Aliquota Comissao      ] TypeIn "~VSDGTAXAD"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Operacao               ] TypeIn "Not \"Administr.\""
Moveto [Aliquota Comissao      ] TypeIn "Changeto Blank"
Do_It!
ClearAll
EndProc   ;  (Processa)

;*******************************************************************************
;* Rotina para lan‡ar status de paga em comissoes nao pagas                    *                                                                      *
;*******************************************************************************
Proc Comissoes_APagar()

Sort Tabela On "Codigo da Empresa", "Numero do Documento", "Serie do Documento"

CDEMPR="****"
NDOCTO="****"
SDOCTO="****"

CoEdit "NotaC", Tabela
Scan
  Aguarde("Aguarde, atualizando dados ")

 If [Codigo da Empresa  ]<>CDEMPR Or
    [Numero do Documento]<>NDOCTO Or
    [Serie do Documento ]<>SDOCTO
    Then CDEMPR=[Codigo da Empresa  ]
         NDOCTO=[Numero do Documento]
         SDOCTO=[Serie do Documento ]
        
         Moveto "Notac"
         Moveto [Codigo da Empresa]
         Locate CDEMPR,NDOCTO,SDOCTO
          If IsLockRecordL()
           Then Mensagem(" O documento "+[Tipo do Documento]+"/"+[Numero do Documento]+"-"+[Serie do Documento]+" est  em uso. // //"+
                         "NÆo ser  efetuado altera‡”es neste documento.// //Liberar antes de prosseguir !")
           Else [Comissao Paga  ] = "S"
                [Data de Acerto ] = VSDGDTREFERENTE
                Gerou_Comissao_APagar=True     
         EndIf     
 EndIf
 Moveto Tabela 

EndScan
Do_It!
ClearAll

EndProc ;Comissoes_APagar()

;*******************************************************************************
;* Rotina p/                                                                   *
;*******************************************************************************
Proc GeraComissao()
ClearAll


;-------------

PC_0000_AquivoDeParametrosGeraComissao="PC_0065G" ; informar o Rm_XXXX como PC_XXXX nÆo esquecer 
Play "PC_0000"

;-------------

EndProc     

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESA"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_TAXAD"         : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_TAXAD"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_DTFIM"    
            Case Campo="TG_OPGERENCIA"    : Campo="TG_OPRELANALSINT"
            Case Campo="TG_DTREFERENTE"   : Campo="TG_OPGERENCIA"
            Case Campo="TG_COMISSAO"      : Campo="TG_OPRELANALSINT"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"       : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"      : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"      : Campo="TG_TAXAD"
                    Case Campo="TG_TAXAD"         : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_OPRELANALSINT" 
                    Case Campo="TG_OPRELANALSINT" : 
                         VSDGOPRELANALSINT=ControlValue("TG_OPRELANALSINT")
                         If Not IsBlank(VSDGOPRELANALSINT)
                            Then VSDGOPRELANALSINT=Upper(VSDGOPRELANALSINT)
                            Else VSDGOPRELANALSINT="N"
                         EndIf
                         Switch
                           Case VSDGOPRELANALSINT="S" : VSDGNOMOPRELANALSINT="Comissoes Pagas"
                           Case VSDGOPRELANALSINT="N" : VSDGNOMOPRELANALSINT="Comissoes a Pagar"
                         EndSwitch
                         
                         If VSDGOPRELANALSINT="S"
                            Then CheckTG_OPGERENCIA[1]=False
                                 VSDGDTREFERENTE=BlankDate()  
                                 Campo="YES"
                            Else Campo="TG_OPGERENCIA"
                         EndIf
                    Case Campo="TG_OPGERENCIA"    :
                         If CheckTG_OPGERENCIA[1]
                            Then Campo="TG_DTREFERENTE"
                            Else Campo="TG_COMISSAO"
                         EndIf
                    Case Campo="TG_DTREFERENTE": 
                         VSDGDTREFERENTE=ControlValue("TG_DTREFERENTE")
                         If IsBlank(VSDGDTREFERENTE)
                            Then Mensagem("Informe a Data para Acerto")
                            Else If Not CheckTG_OPGERENCIA[1]
                                    Then VSDGDTREFERENTE=BlankDate()
                                         Campo="TG_COMISSAO"  
                                    Else Campo="YES"    
                                 EndIf        
                         EndIf      
                    Case Campo="TG_COMISSAO" : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch                  
EndIf
Switch        
  Case Campo="TG_DTREFERENTE":
     MSG_CAMPO="Informe a Data para Acerto"   
  Case Campo="TG_OPRELANALSINT":
     MSG_CAMPO="Op‡„o: S=Comiss”es Pagas  N=Comiss”es a Pagar"   
  Case Campo="TG_OPGERENCIA":
     MensagemCheckBoxes()
  Case Campo="TG_COMISSAO":
       MSG_CAMPO="Defina a op‡„o"
       TECLA="Barra de Espa‡o=Marca/Desmarca  "
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

sys_Valor()

VSDGEMPRESA          = ""
VSDGREPRESEN         = ""
VSDGOPRELANALSINT    = ""
VSDGOPRELANALSINT2   = "" 
VSDGNOMOPRELANALSINT = ""
VSDGNOMOPRELANALSINT2= ""
VSDGOPCAO            = ""
VSDGNOMOPCAO         = ""
VSDGTAXAD            = BlankNum()
VSDGDTINI            = BlankDate()
VSDGDTFIM            = BlankDate()
VSDGDTREFERENTE      = BlankDate() 
Gerou_Comissao_APagar = False

Array TG_OPGERENCIA[1]
TG_OPGERENCIA[1]="Atualizar comiss”es"

Array CheckTG_OPGERENCIA[ArraySize(TG_OPGERENCIA)]
CheckTG_OPGERENCIA[1]=False

Array TG_COMISSAO[1]
TG_COMISSAO[1]="Gera comiss„o Contas a Pagar"

Array CheckTG_COMISSAO[ArraySize(TG_COMISSAO)]
CheckTG_COMISSAO[1]=False

While True

  ShowDialog "Rela‡„o de Comiss”es PAGAS/A PAGAR" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

		Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 06,08 "% Devoluc„o"  For "TG_TAXAD"
    Accept @ 07,09 Width 12 "N" Tag "TG_TAXAD" To VSDGTAXAD

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Status" For "TG_OPRELANALSINT"
    Accept @ 01,39 Width 04 "A1"  Picture "S,N" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 01,44 Width 25 "A18"  Picture "!*!" Tag "TG_NOMOPRELANALSINT" To VSDGNOMOPRELANALSINT

    Label  @ 04,35 "Comissäes nÆo Pagas" For "TG_OPGERENCIA"
    CheckBoxes @ 05,35 Height 1 Width 33 Tag "TG_OPGERENCIA"
    TG_OPGERENCIA[1] to CheckTG_OPGERENCIA[1]
    
    Label  @ 06,39 "como pagas em : " For "TG_DTREFERENTE"
    Accept @ 06,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREFERENTE" To VSDGDTREFERENTE

    CheckBoxes @ 08,35 Height 1 Width 35 Tag "TG_COMISSAO"
    TG_COMISSAO[1] to CheckTG_COMISSAO[1]        

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If CheckTG_OPGERENCIA[1]
     Then If VSDGDTREFERENTE=BlankDate()
             Then Mensagem("Data para acerto n„o informado!")
                  Loop
          EndIF
  EndIf

  ;---- Processo Omitido -----------------------------------
  VSDGOPCAO = "1"

  Switch
    Case VSDGOPCAO = "1" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 1 
    Case VSDGOPCAO = "2" : INICIO_RATEIO = 1
                           FIM_RATEIO    = 2
    Case VSDGOPCAO = "3" : INICIO_RATEIO = 2
                           FIM_RATEIO    = 2
  EndSwitch
  ;---------------------------------------------------------  

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_0050"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0050" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop                  
  EndIf
  Processa()
  
  If CheckTG_OPGERENCIA[1] And VSDGOPRELANALSINT="N" And Not IsBlank(VSDGDTREFERENTE)
     Then Comissoes_APagar()
  EndIf
  
  If VSDGOPRELANALSINT="S"
     Then VSDGPAG = " PAGAS"
     Else VSDGPAG = "A PAGAR"         
  EndIF                                         
                                                    
  If Gerou_Comissao_APagar
     Then Mensagem("Processo realizado com sucesso!//Alterado status de comiss„o \"como PAGA\"!// //Data de Acerto: "+StrVal(VSDGDTREFERENTE))
     Else 
          if CheckTG_COMISSAO[1]
             then
                  GeraComissao()
             else
                  IMPRIREL(Tabela,"5")
          endif        
  EndIF

  Gerou_Comissao_APagar=False

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
