;** RM_3116 ********************************************************************
;** Relat¢rio de Metas/Pedidos                                                 *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 07/12/2016 por Rafael Matos
;Alterado em     : 14/12/2016 por Rafael Matos 
;Motivo Alteracao: Ajustes Layout Relat¢rio e InclusÆo do filtro Marca  
;Alterado em     : 28/12/2016 por Rafael Matos 
;Motivo Alteracao: InclusÆo do filtro TG_SITUACAOPEDIDO
;Alterado em     : 20/10/2017 por Bruno Carvalho 
;Motivo Alteracao: Ajustes Seleciona() -> Codigo da Marca
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll
;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI")
   Then 
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Numero do Pedido       ] Example "nped" TypeIn ", Calc Count as Nvendas"
        Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA2.."
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Codigo do Representante] Check TypeIn "~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Situacao do Pedido     ] Check
        switch
          case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
          case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
        endswitch        
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter
        Moveto [Numero do Pedido       ] Example "nped"
        Moveto [Codigo do Item         ] Example "cite"
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ] Example "cite"
        Moveto [Codigo da Marca        ] Check TypeIn "~VSDGMARCA.."
        Moveto [Descricao da Marca     ] Check
        Do_It!
        ClearAll
        
        Adiciona_Dados("Vendas")
EndIf

EndProc


;*******************************************************************************
;* Rotina p/ Selecionar Metas                                                  *
;*******************************************************************************
Proc Seleciona2()

{Ask} TypeIn "\\Sistemas\\Vendas\\Rankvc" Enter
      Moveto [Numero da Programacao  ] Example "nprog"
      Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA2.."
      Moveto [Nome Fantasia Empresa  ] Check
      Moveto [Data Inicial           ] TypeIn "~VSDGDTINI"
      Moveto [Codigo da Marca        ] Check TypeIn "~VSDGMARCA.."
      Moveto [Descricao da Marca     ] Check 
{Ask} TypeIn "\\Sistemas\\Vendas\\Rankvi" Enter 
      Moveto [Numero da Programacao  ] Example "nprog"
      Moveto [Codigo do Representante] Check TypeIn "~VSDGREPRESEN.." 
      Moveto [Nome Fantasia Represent] Check
      Moveto [Meta_Faturamento       ] Check
      Moveto [Meta_Pecas             ] Check
      Do_It!
      ClearAll
      
If Istable("Answer") and IsEmpty("Answer")
   Then Return False
   Else Adiciona_Dados("Metas")
        Return True       
EndIf                       
      
EndProc 

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If VSDGEMPRESA="0000"
   Then {Ask} TypeIn "Answer" Enter TypeIn "Fast"
         Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
         Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
         Do_It!
         ClearAll
EndIf

{Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
        Moveto [Descricao Gerencia     ] Check
{Ask} TypeIn "Answer" Enter Check
Moveto [Codigo do Representante] Example "crep" 
Do_It!
ClearAll

If IsEmpty("Answer")
   Then Return
EndIf   
     
View Tabela
Coedit "Answer"
NR = NRecords("Answer")
Scan
  Barra(NR, RecNo())
  Aguarde("Aguarde, Processando "+BARRA_STRING)
  Moveto Tabela
  Moveto [Codigo da Empresa]
  Locate [Answer->Codigo da Empresa],[Answer->Codigo do Representante],[Answer->Codigo da Marca]
  If not retval
     Then  End Down
                    [Codigo da Empresa      ] = [Answer->Codigo da Empresa]
                    [Nome Fantasia Empresa  ] = [Answer->Nome Fantasia Empresa]
                    [Codigo do Representante] = [Answer->Codigo do Representante]
                    [Nome Fantasia Represent] = [Answer->Nome Fantasia Represent]
                    [Codigo da Gerencia     ] = [Answer->Codigo da Gerencia]
                    [Descricao Gerencia     ] = [Answer->Descricao Gerencia]
                    [Codigo da Marca        ] = [Answer->Codigo da Marca   ]
                    [Descricao da Marca     ] = [Answer->Descricao da Marca]
  EndIf
  
  Switch
               Case Tipo="Vendas":
                    [Total_Vendas_TipoPagto] = [Total_Vendas_TipoPagto] + [Answer->Nvendas]
                    [Vendas_Quantidade     ] = [Vendas_Quantidade     ] + [Answer->Quantidade]
                    [Vendas_Preco Total    ] = [Vendas_Preco Total    ] + ([Answer->Preco Total] - [Answer->Valor Desconto Total])
                    
               Case Tipo="Metas":
                    [Meta_Faturamento      ] = [Meta_Faturamento      ] + [Answer->Meta_Faturamento]
                    [Meta_Pecas            ] = [Meta_Pecas            ] + [Answer->Meta_Pecas]
           EndSwitch
  
  Moveto "Answer"
EndScan
Do_It!
ClearAll                         

EndProc

;*******************************************************************************
;* Rotina para Ler/Gravacao Opcao                                              *
;*******************************************************************************
Proc ModeloRelatoriosCarregaLista()

;ModeloRelatoriosAdd("XXX  XX maximo 61 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Anal¡tico por Marca S/ Valor")
ModeloRelatoriosAdd("02  Anal¡tico por Gerencia")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: 
          Dialog_F1()                                
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"           : Campo="NO"
            Case Campo="TG_GERENCIA"          : Campo="TG_EMPRESA"
            Case Campo="TG_REPRESEN"          : Campo="TG_GERENCIA"
            Case Campo="TG_MARCA"             : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI"             : Campo="TG_MARCA"
            Case Campo="TG_DTFIM"             : Campo="TG_DTINI"
            Case Campo="TG_SITUACAOPEDIDO"    : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"         : Campo="TG_SITUACAOPEDIDO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()              
             Then Switch
                    Case Campo="TG_EMPRESA"        : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"       : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"       : Campo="TG_MARCA"    
                    Case Campo="TG_MARCA"          : Campo="TG_DTINI"                
                    Case Campo="TG_DTINI"          : Campo="TG_DTFIM"                    
                    Case Campo="TG_DTFIM"          : Campo="TG_SITUACAOPEDIDO"
                    Case Campo="TG_SITUACAOPEDIDO" : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"      : Campo="YES"
              EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO="" 
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Bloq"
LimpAguarde()

;***** Verificar se o Cliente tem acesso a esta rotina *****
If Bloqueia_Rotina("METAS")
   Then Return
EndIf   
;***********************************************************

VSDGEMPRESA         = ""
VSDGDTINI           = BlankDate()
VSDGDTFIM           = BlankDate()
VSDGGERENCIA        = ""
VSDGCODMODELO       = BlankNum()
VSDGMODELO          = ""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Comparativo Pedidos/Metas" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR
    
    Label  @ 06,00 "Marca"  For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 00,35 "Situacao do Pedido"  For "TG_SITUACAOPEDIDO"
    Accept @ 01,36 Width 33 "A30"  Picture "ABERTO,SUSPENSO,CANCELADO,FATURADO,TODAS,!*!" Tag "TG_SITUACAOPEDIDO"  To VSDGSITUACAOPEDIDO
    
    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A64"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO  

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

DISPOSITIVO()
  If OK=""  Then Loop EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf
  
  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_3116"
  Copy "\\Base\\Sistemas\\Vendas\\RM_3116" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile
  If Seleciona2() = false
     Then Mensagem("NÆo existe meta cadastrada para essa Data Inicial")
          Loop
  EndIf 

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  Switch
    Case VSDGCODMODELO="01": Impressao_Orientacao="Retrato" CopyReport "\\Base\\Sistemas\\Vendas\\Rm_3116" "1" Tabela "R"
    Case VSDGCODMODELO="02": Impressao_Orientacao="Retrato" CopyReport "\\Base\\Sistemas\\Vendas\\Rm_3116" "4" Tabela "R"
  EndSwitch

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
