;** RM_3002 ********************************************************************
;*  Resumo de Compra/Venda/Estoque                                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 25/01/2010 por Bruno Carvalho
;Ultima Alteracao: 24/03/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Itens Inativos
;Ultima Alteracao: 17/05/2010 por Bruno Carvalho
;Motivo Alteracao: Altera‡Æo p/ nÆo aparecer itens inativos mesmo com saldo
;Ultima Alteracao: 30/08/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Entradas Faturamento para custo medio DEVOL/MANIF/CONSIG/REQUIS
;Ultima Alteracao: 01/09/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes OF em aberto situa‡Æo TROCA
;Ultima Alteracao: 10/04/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado Pre‡o de Venda no Report e Ajustado no Script
;Ultima Alteracao: 03/05/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro por tabela de pre‡o "PRECO DE VENDA"
;Ultima Alteracao: 17/05/2012 por Karina Andrade
;Motivo Alteracao: Ajustes Op‡Æo de Pre‡o
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Substitui‡Æo Editor novo arquivo por FileWrite
;Ultima Alteracao: 19/05/2016 por Bruno Carvalho
;Motivo Alteracao: Ajustes GetRecord "Iten_Com" p/ o campo [Situacao]
;Ultima Alteracao: 18/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 22/03/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado TG_CODMODELO, TG_CODMODELO_COMCASASDECIMAIS
;Ultima Alteracao: 26/03/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado SetaVisualizarCasasDecimais(),ConfigOpcoes()
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 10/12/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro fornecedor             
;Ultima Alteracao: 01/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado modelo 01B
;Ultima Alteracao: 19/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes origem da tabela
;Ultima Alteracao: 24/12/2019 por Bruno Carvalho
;Motivo Alteracao: Adicionado Bib_Proc

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona_Itens()
ClearAll                                                
AGUARDE("Aguarde, selecionando Itens")

switch
  case VSDGDESTINAT<>"":
    {Ask} {\\Sistemas\\Estoque\\Iten_Com}
    Moveto [Codigo do Item         ] Example "cite"
    Moveto [Situacao               ] TypeIn VSDGSITITEM
    {Ask} {\\Sistemas\\Estoque\\Itens}
    Moveto [Codigo do Item         ] Example "cite"
    Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
    Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
    Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
    {Ask} {\\Sistemas\\Estoque\\Cotacao}
    Moveto [Codigo do Item         ] Check Example "cite" TypeIn ", ~VSDGITEM.."
    Moveto [Codigo                 ] TypeIn "~VSDGDESTINAT.." 
    Do_It!
    ClearAll

  otherwise            :   
    {Ask} {\\Sistemas\\Estoque\\Iten_Com}
    Moveto [Codigo do Item         ] Example "cite"
    Moveto [Situacao               ] TypeIn VSDGSITITEM
    {Ask} {\\Sistemas\\Estoque\\Itens}
    Moveto [Codigo do Item         ] check Example "cite"
    Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
    Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
    Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
    Do_It!
    ClearAll
    
endswitch
TabelaRelItens=Adiciona_Indice_Temp("Codigo do Item")

endproc

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona_Estoque()
ClearAll                                                
AGUARDE("Aguarde, selecionando entradas/saidas")

;*** Faturamento ***
For I From 1 To 1
  If Not IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") Or
     Not IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
     Then Loop
  EndIf
    
  {Ask} typein TabelaRelItens Enter
  Moveto [Codigo do Item           ] Example "cite"

  {Ask} {\\Sistemas\\Vendas\\Destin}
  Moveto [Codigo da Destinacao     ] Example "destin"
  Moveto [Atualiza Estoque         ] TypeIn "S"
  {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
  Moveto [Codigo da Empresa        ] Check Example "emp" TypeIn ", ~VSDGEMPRESA.."
  Moveto [Numero do Documento      ] Example "doc"
  Moveto [Serie do Documento       ] Example "ser"
  Moveto [Codigo da Destinacao     ] Example "destin"
  Moveto [Descricao da Destinacao  ] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
  Moveto [Data de Saida            ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
  Switch
    Case i=1: Moveto [Tipo Movimento Estoque   ] TypeIn "S"
    Case i=2: Moveto [Tipo Movimento Estoque   ] TypeIn "E"
  EndSwitch
  Moveto [Situacao                 ] TypeIn "Not C"
  {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
  Moveto [Codigo da Empresa        ] Example "emp"
  Moveto [Numero do Documento      ] Example "doc"
  Moveto [Serie do Documento       ] Example "ser"
  Moveto [Codigo do Item           ] Check Example "cite" TypeIn ", ~VSDGITEM.."
  Moveto [Tipo do Item             ]
  Switch
     Case VSDGTIPOEST = "1"       : TypeIn "E or M or O or A or S"
     Case VSDGTIPOEST = "2"       : TypeIn "T or P or S"
     Case Not IsBlank(VSDGTIPOEST): TypeIn "~VSDGTIPOEST"
          If VSDGTIPOEST="P" Then TypeIn " Or S" EndIf
     OtherWise                    : TypeIn "Not C, Not D, Not F, Not G, Not H, Not I"
  EndSwitch
  Moveto [Preco Total              ] Check TypeIn "Calc Sum as Preco Total"
  Moveto [Valor Desconto Total     ] Check TypeIn "Calc Sum as Valor Desconto Total"  
  Moveto [Quantidade               ] TypeIn "Calc Sum as Quantidade"
  Moveto [Situacao_Item            ] TypeIn "Not C"   
  Do_It!
  ClearAll

  Switch
    Case i=1: Adiciona_Dados("SAIDAS")
    Case i=2: Adiciona_Dados("ENTRADAS")
  EndSwitch
EndFor

If VSDGOPOF="S"  And Dir_Trab="" And IsTable("\\Sistemas\\Vendas\\FaturaC")
   Then For I From 1 To 1
          {Ask} typein TabelaRelItens Enter
          Moveto [Codigo do Item           ] Example "cite"
          
          ;*** Ordem de Faturamento ***
          {Ask} {\\Sistemas\\Vendas\\Destin}
          Moveto [Codigo da Destinacao     ] Example "destin"
          Moveto [Atualiza Estoque         ] TypeIn "S"
          {Ask} {\\Sistemas\\Vendas\\FaturaC}
          Moveto [Numero da OF             ] Example "doc"
          Moveto [Codigo da Empresa        ] Check TypeIn "~VSDGEMPRESA.."
          Moveto [Codigo da Destinacao     ] Example "destin"
          Moveto [Descricao da Destinacao  ] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
          Moveto [Data de Emissao          ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          If i=1
             Then Moveto [Tipo Movimento Estoque   ] TypeIn "S"
             Else Moveto [Tipo Movimento Estoque   ] TypeIn "E"
          EndIf
          Moveto [Numero Nota Gerada       ] TypeIn "Blank"
          {Ask} {\\Sistemas\\Vendas\\FaturaI}
          Moveto [Numero da OF             ] Example "doc"
          Moveto [Codigo do Item           ] Check Example "cite" TypeIn ", ~VSDGITEM.."

          Moveto [Tipo do Item             ]
          Switch
             Case VSDGTIPOEST = "1"       : TypeIn "E or M or O or A or S"
             Case VSDGTIPOEST = "2"       : TypeIn "T or P or S"
             Case Not IsBlank(VSDGTIPOEST): TypeIn "~VSDGTIPOEST"
                  If VSDGTIPOEST="P" Then TypeIn " Or S" EndIf
             OtherWise                    : TypeIn "Not C, Not D, Not F, Not G, Not H, Not I"
          EndSwitch
          Moveto [Preco Total              ] Check TypeIn "Calc Sum as Preco Total"
          Moveto [Valor Desconto Total     ] Check TypeIn "Calc Sum as Valor Desconto Total"          
          Moveto [Quantidade               ] TypeIn "Calc Sum as Quantidade"
          Do_It!
          ClearAll

          If i=1
             Then Adiciona_Dados("SAIDAS")
             Else Adiciona_Dados("ENTRADAS")
          EndIf
        EndFor
        
        ;*** Ordem de Faturamento de Entrada/Troca ***
        {Ask} typein TabelaRelItens Enter
        Moveto [Codigo do Item           ] Example "cite"
        
        {Ask} {\\Sistemas\\Vendas\\Destin}
        Moveto [Codigo da Destinacao     ] Example "destin"
        Moveto [Atualiza Estoque         ] TypeIn "S"
        {Ask} {\\Sistemas\\Vendas\\FaturaC}
        Moveto [Numero da OF             ] Example "doc"
        Moveto [Codigo da Empresa        ] Check TypeIn "~VSDGEMPRESA.."
        Moveto [Codigo da Destinacao     ] Example "destin"
        Moveto [Descricao da Destinacao  ] TypeIn "..TROCA.."
        Moveto [Data de Emissao          ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Tipo Movimento Estoque   ] TypeIn "S"
        Moveto [Numero Nota Gerada       ] TypeIn "Blank"
        {Ask} {\\Sistemas\\Vendas\\FaturaID}
        Moveto [Numero da OF             ] Example "doc"
        Moveto [Codigo do Item           ] Check Example "cite" TypeIn ", ~VSDGITEM.."
        Moveto [Tipo do Item             ]
        Switch
           Case VSDGTIPOEST = "1"       : TypeIn "E or M or O or A or S"
           Case VSDGTIPOEST = "2"       : TypeIn "T or P or S"
           Case Not IsBlank(VSDGTIPOEST): TypeIn "~VSDGTIPOEST"
                If VSDGTIPOEST="P" Then TypeIn " Or S" EndIf
           OtherWise                    : TypeIn "Not C, Not D, Not F, Not G, Not H, Not I"
        EndSwitch
        Moveto [Quantidade               ] TypeIn "Calc Sum as Quantidade"
        Do_It!
        ClearAll

        Adiciona_Dados("ENTRADAS")
EndIf

;*** Notas de Entrada/Estoque ***
  If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
     IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
     Then 
          {Ask} typein TabelaRelItens Enter
          Moveto [Codigo do Item           ] Example "cite"

          {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
          Moveto [Numero do Lancamento     ] Example "doc"
          Moveto [Codigo da Empresa        ] Check TypeIn "~VSDGEMPRESA.."
          Moveto [Data de Entrada          ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Moveto [Tipo de Operacao         ] TypeIn "C"
          {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
          Moveto [Numero do Lancamento     ] Check Example "doc"
          Moveto [Sequencia do Lancamento  ] Check
          Moveto [Codigo do Item           ] Check Example "cite" TypeIn ", ~VSDGITEM.."

          Moveto [Tipo do Item             ]
          Switch
             Case VSDGTIPOEST = "1"       : TypeIn "E or M or O or A or S"
             Case VSDGTIPOEST = "2"       : TypeIn "T or P or S"
             Case Not IsBlank(VSDGTIPOEST): TypeIn "~VSDGTIPOEST"
                  If VSDGTIPOEST="P" Then TypeIn " Or S" EndIf
             OtherWise                    : TypeIn "Not C, Not D, Not F, Not G, Not H, Not I"
          EndSwitch
          Moveto [Quantidade Convertida    ] Check TypeIn "As Quantidade"
          Do_It!
          ClearAll

          {Ask} {Answer}
          Moveto [Codigo da Empresa        ] Check
          Moveto [Codigo do Item           ] Check
          Moveto [Quantidade               ] TypeIn "Calc Sum As Quantidade"
          Do_It!
          ClearAll

          Adiciona_Dados("ENTRADAS")
EndIf

EndProc

;*******************************************************************************
;* Adiciona Dados                                                              *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

ClearAll
If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa        ] Example "emp"
Moveto [Codigo do Item           ] Example "ite"
Moveto [Quantidade               ] Example "qtd"
If Tipo="SAIDAS"
   Then Moveto [Preco Total         ] TypeIn "_ptot"
        Moveto [Valor Desconto Total] TypeIn "_vdes"
EndIf        

{Ask} TypeIn TabelaP Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa        ] Example "emp"
Moveto [Codigo do Item           ] Example "ite"

Switch
 Case Tipo="ENTRADAS" : Moveto [Entradas       ] Example "qtd"
 Case Tipo="SAIDAS"   : Moveto [Saidas         ] Example "qtd"                                                          
                        Moveto [Preco de Venda ] TypeIn "(_ptot - _vdes) / _qtd" 
EndSwitch

Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Ajusta Dados                                                                *
;*******************************************************************************

Proc Ajusta_Dados()
ClearAll

AGUARDE("Aguarde, processando dados")

;******** Agrupa Dados *******
{Ask} TypeIn TabelaP Enter
Moveto [Codigo da Empresa     ] Check
Moveto [Codigo do Item        ] Check
Moveto [Entradas              ] TypeIn "Calc Sum As Entradas"
Moveto [Saidas                ] TypeIn "Calc Sum As Saidas"
Moveto [Preco de Venda        ] TypeIn "Calc Sum As Preco de Venda"
Do_It!
ClearAll

Empty(TabelaP)

{Ask} {Answer}
Moveto [Codigo da Empresa     ] Example "emp"
Moveto [Codigo do Item        ] Example "ite"
Moveto [Entradas              ] Example "qtde"
Moveto [Saidas                ] Example "qtds"
Moveto [Preco de Venda        ] Example "pv"

{Ask} TypeIn TabelaP Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa     ] Example "emp"
Moveto [Codigo do Item        ] Example "ite"
Moveto [Entradas              ] Example "qtde"
Moveto [Saidas                ] Example "qtds"
Moveto [Preco de Venda        ] Example "pv"
Do_It!
ClearAll

;******** Saldo Atual *******
{Ask} typein TabelaRelItens Enter
Moveto [Codigo do Item         ] Example "cite"
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Tipo do Item           ]
Switch
   Case VSDGTIPOEST = "1"       : TypeIn "E or M or O or A or S"
   Case VSDGTIPOEST = "2"       : TypeIn "T or P or S"
   Case Not IsBlank(VSDGTIPOEST): TypeIn "~VSDGTIPOEST"
        If VSDGTIPOEST="P" Then TypeIn " Or S" EndIf
   OtherWise                    : TypeIn "Not C, Not D, Not F, Not G, Not H, Not I"
EndSwitch
{Ask} {\\Sistemas\\Estoque\\SdEstq}
Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Item        ] Check Example "cite" TypeIn ", ~VSDGITEM.."
Moveto [Mes Referencia        ] TypeIn "~VSDGMES"
Moveto [Ano Referencia        ] TypeIn "~VSDGANO"
Moveto [Saldo Atual           ] Check 
Moveto [Preco de Custo        ] Check 
Moveto [Data do Preco de Custo] Check

Do_It!
ClearAll

CoEdit TabelaP,"Answer"
Scan
  Moveto TabelaP
  Moveto [Codigo da Empresa]
  Locate [Answer->Codigo da Empresa],"",[Answer->Codigo do Item]
  If Not RetVal
     Then 
          End
          Down
          [Codigo da Empresa     ] = [Answer->Codigo da Empresa      ]
          [Codigo do Item        ] = [Answer->Codigo do Item         ]
  EndIf
  [Saldo Atual           ] = [Answer->Saldo Atual            ]
  [Preco de Custo        ] = [Answer->Preco de Custo         ]
  [Data do Preco de Custo] = [Answer->Data do Preco de Custo ]
  UnLockRecord
  
  Moveto "Answer"
EndScan
Do_It!
ClearAll

;******* Ajusta dados do cadastro de Empresas ******
{Ask} {\\Sistemas\\Cadastro\\Empresas}
Moveto [Codigo da Empresa     ] example "empr"
Moveto [Nome Fantasia Empresa ] example "nome"
{Ask} TypeIn TabelaP Enter TypeIn "Fast"
Moveto [Codigo da Empresa     ] example "empr"
Moveto [Nome Fantasia Empresa ] TypeIn "Changeto " example "nome"
Do_It!
ClearAll

;******** Ajusta dados do cadastro de Itens ********
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "item"
Moveto [Descricao do Item      ] Example "desc"
Moveto [Descricao Complementar ] Example "dcom"
Moveto [Unidade Interna        ] Example "un"
Moveto [Descricao Tipo do Item ] Example "dtp"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Descricao da Familia   ] Example "dfam"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [Descricao do Grupo     ] Example "dgru"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Descricao da Marca     ] Example "dmar"

{Ask} TypeIn TabelaP Enter TypeIn "Fast"
Moveto [Codigo do Item        ] example "item"
Moveto [Descricao do Item     ] TypeIn "Changeto " Example "desc"
Moveto [Descricao Complementar] TypeIn "Changeto " Example "dcom"
Moveto [Unidade Interna       ] TypeIn "Changeto " Example "un"
Moveto [Descricao Tipo do Item] TypeIn "Changeto " Example "dtp"
Moveto [Codigo da Familia     ] TypeIn "Changeto " Example "cfam"
Moveto [Descricao da Familia  ] TypeIn "Changeto " Example "dfam"
Moveto [Codigo do Grupo       ] TypeIn "Changeto " Example "cgru"
Moveto [Descricao do Grupo    ] TypeIn "Changeto " Example "dgru"
Moveto [Codigo da Marca       ] TypeIn "Changeto " Example "cmar"
Moveto [Descricao da Marca    ] TypeIn "Changeto " Example "dmar"

Do_It!
ClearAll

;******** Somente Tipo de itens *******
{Ask} TypeIn TabelaP Enter Check
Moveto [Tipo do Item         ]
Switch
   Case VSDGTIPOEST = "1"       : TypeIn "E or M or O or A or S"
   Case VSDGTIPOEST = "2"       : TypeIn "T or P or S"
   Case Not IsBlank(VSDGTIPOEST): TypeIn "~VSDGTIPOEST"
   OtherWise                    : TypeIn "Not C, Not D, Not F, Not G, Not H, Not I"
EndSwitch
Do_It!
ClearAll

;** Elimina os Inativos **********************

;{Ask} {\\Sistemas\\Estoque\\EstqPrm}
;Moveto [Codigo da Empresa     ] example "empr"
;Moveto [Codigo do Item        ] example "item"
;Moveto [Data de Inatividade   ] TypeIn "<~VSDGDTFIM"
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] example "item"
Moveto [Inativo               ] TypeIn "S"
{Ask} {Answer} TypeIn "Fast Delete"
;Moveto [Codigo da Empresa     ] example "empr"
Moveto [Codigo do Item        ] example "item"  
;Moveto [Saldo Atual           ] TypeIn "0 or Blank"
Do_It!
ClearAll

If VSDGOPCUSTO="V" 
   Then {Ask}  {Answer} TypeIn "Fast"
        Moveto [Preco de Venda] TypeIn "changeto Blank"
        Do_It!
        ClearAll

        {Ask} {\\Sistemas\\Vendas\\Tbprite} 
        Moveto [Codigo da Tabela         ] TypeIn "~VSDGTABELA.." 
        Moveto [Codigo do Item           ] Example "codi"
        Moveto [Preco Unitario           ] Example "prit"
        {Ask}  {Answer}
        Moveto [Codigo do Item           ] Example "codi"
        Moveto [Preco de Venda           ] TypeIn "changeto _prit"        
   Else {Ask} {Answer} TypeIn "Fast"
        Moveto [Preco de Venda        ] TypeIn "blank, changeto 0"
EndIf
Do_It!
ClearAll

EndProc    ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -68  :
            Temp=False
            Relatorios()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_TIPOEST"        : Campo="TG_EMPRESA"
            Case Campo="TG_FAMI"           : Campo="TG_TIPOEST"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_MARCA"          : Campo="TG_GRP"
            Case Campo="TG_ITEM"           : Campo="TG_MARCA"
            Case Campo="TG_DTINI"          : Campo="TG_ITEM"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_OPCUSTO"        : Campo="TG_DTFIM"
            Case Campo="TG_TABELA"         : Campo="TG_OPCUSTO"
            Case Campo="TG_OPSP"           : Campo="TG_TABELA"
            Case Campo="TG_OPRELCODALF"    : Campo="TG_OPSP"
            Case Campo="TG_DESTINAT"       : Campo="TG_OPRELCODALF"
            Case Campo="TG_CODMODELO"      : Campo="TG_DESTINAT"                   
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     : Campo="TG_TIPOEST"
                    Case Campo="TG_TIPOEST"     : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"        : Campo="TG_GRP"
                    Case Campo="TG_GRP"         : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"        : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_OPCUSTO"
                    Case Campo="TG_OPCUSTO" : 
                         VSDGOPCUSTO=ControlValue("TG_OPCUSTO") 
                         If Isblank(VSDGOPCUSTO)
                            Then VSDGOPCUSTO="V"
                         EndIf
                         Switch
                           Case VSDGOPCUSTO="M" : VSDGNOMOPCUSTO="PRECO DE VENDA MEDIO" 
                           Case VSDGOPCUSTO="V" : VSDGNOMOPCUSTO="PRECO DE VENDA" 
                                                  VSDGTABELA=""
                                                  VSDGNOMTAB=""    
                         EndSwitch   
                         Campo="TG_TABELA"
                    Case Campo="TG_TABELA"      : Campo="TG_OPSP" 
                         If IsBlank(VSDGTABELA)
                            Then VSDGNOMTAB=""  
                         EndIf                          
                    Case Campo="TG_OPSP"    : Campo="TG_OPRELCODALF"
                         VSDGOPSP=ControlValue("TG_OPSP")
                         Switch
                           Case VSDGOPSP="2": VSDGNOMOPSP="FORA DE LINHA"
                           OtherWise:
                                VSDGOPSP="1"  VSDGNOMOPSP="EM LINHA"
                         EndSwitch
                    Case Campo="TG_OPRELCODALF" : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"    :Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   : Campo="YES"                   
                  EndSwitch
          EndIf
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPSP":
       MSG_CAMPO="1=Em Linha  2=Fora de Linha"
  Case Campo="TG_OPCUSTO":
       MSG_CAMPO="M=Pre‡o de Venda M‚dio  V=Pre‡o de Venda"       
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

TG_CODMODELO_COMCASASDECIMAIS=true

VSDGCODMODELO     = ""
VSDGMODELO        = ""

ConfigOpcoes("ModeloRelatorio/CasasDecimais","Ler","PO_3002")  

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Resumo de Compra/Venda/Estoque")
ModeloRelatoriosAdd("01B Resumo de Compra/Venda/Estoque c/ Descri‡Æo Complementar")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

  COR_MENSAGEM="1"
  MSG=    "Para a exibi‡Æo correta deste relat¢rio ‚ necess rio que//"
  MSG=MSG+"vocˆ tenha executado o reprocessamento do estoque do mˆs//"
  MSG=MSG+"atual,  caso  esteja  em d£vida sobre a realiza‡Æo deste//"
  MSG=MSG+" procedimento, execute entÆo o reprocessamento.            "
        Mensagem(MSG)
        Release Vars COR_MENSAGEM

ClearAll

VSDGEMPRESA     = ""
VSDGTIPOEST     = ""
VSDGDTINI       = BlankDate()
VSDGDTFIM       = BlankDate()
VSDGFAMI        = ""
VSDGMARCA       = ""
VSDGGRP         = ""
VSDGITEM        = ""
VSDGOPRELCODALF = ""
VSDGMESANO      = AlinhM(StrVal(Month(Today())),2)+"."+AlinhM(StrVal(Year(Today())),4)
VSDGOPOF        = ""
VSDGNOMOPOF     = ""
VSDGMESES       = ""
VSDGDIAS        = BlankNum()
VSDGNOMOPPE     = ""
VSDGTABELA      = ""
VSDGOPCUSTO     = ""
VSDGDESTINAT     =""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Resumo de Compra/Venda/Estoque" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140
    @ 01,07 Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Tipo do Estoque"  For "TG_TIPOEST"
    Accept @ 03,04 Width 04 "A1"  Picture "!" Tag "TG_TIPOEST" To VSDGTIPOEST
    Accept @ 03,09 Width 25 "A30"  Picture "!*!" Tag "TG_DESCTIPOEST" To VSDGDESCTIPOEST

    Label  @ 04,00 "Familia"  For "TG_FAMI"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI" To VSDGFAMI
    Accept @ 05,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 06,00 "Grupo"  For "TG_GRP"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP" To VSDGGRP
    Accept @ 07,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP
    
    Label  @ 08,00 "Marca"  For "TG_MARCA"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 09,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 10,00 "Item"  For "TG_ITEM"
    Accept @ 11,01 Width 33 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 12,01 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 13,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 14,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 14,16 "at‚" For "TG_DTFIM"
    Accept @ 14,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡„o de Pre‡o" For "TG_OPCUSTO"
    Accept @ 01,39 Width 04 "A1"  Picture "M,V" Tag "TG_OPCUSTO" To VSDGOPCUSTO
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPCUSTO" To VSDGNOMOPCUSTO

    Label  @ 02,35 "Tabela"  For "TG_TABELA"
    Accept @ 03,36 Width 08 "A5"  Picture "#*#" Tag "TG_TABELA" To VSDGTABELA
    Accept @ 03,44 Width 25 "A18" Picture "!*!" Tag "TG_NOMTAB" To VSDGNOMTAB

    Label  @ 04,35 "Item em" For "TG_OPSP"
    Accept @ 05,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPSP" To VSDGOPSP
    Accept @ 05,44 Width 25 "A15"  Picture "!*!" Tag "TG_NOMOPSP" To VSDGNOMOPSP

    Label  @ 06,35 "Op‡Æo de Ordem" For "TG_OPRELCODALF"
    Accept @ 07,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 07,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 08,35 "Pessoa/Fornecedor"  For "TG_DESTINAT"
    Accept @ 09,36 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 09,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  VSDGMES=AlinhM(StrVal(Month(Today())),2)
  VSDGANO=AlinhM(StrVal( Year(Today())),4)

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, processando dados")
  TabelaP=Cria_Temp(PrivDir())
  Copy "\\base\\sistemas\\estoque\\RM_3002" TabelaP
  Empty TabelaP

  If VSDGOPSP="1"
     Then VSDGSITITEM="L Or Blank"
     Else VSDGSITITEM="F"
  EndIf

  Seleciona_Itens()

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona_Estoque()
  EndWhile

  Ajusta_Dados()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o Existem Registros a Processar")
          Delete TabelaP
          Delete TabelaRelItens
          Loop
  EndIf

  SetaVisualizarCasasDecimais("12")

  Impressao_Orientacao=""
  switch
    case VSDGCODMODELO="01"  :
      CopyReport "\\Base\\Sistemas\\Estoque\\Rm_3002" "R" "Answer" "R"  

      If VSDGOPRELCODALF="2"
         Then Seta_Ordem_Report("Answer","R","Codigo do Item","Descricao do Item","")
      EndIf
      IMPRIREL("Answer","R")

    case VSDGCODMODELO="01B" : 
      Impressao_Orientacao="Paisagem"
      CopyReport "\\Base\\Sistemas\\Estoque\\Rm_3002" "1" "Answer" "R"  

      If VSDGOPRELCODALF="2"
           Then Seta_Ordem_Report("Answer","R","Codigo do Item","Descricao Complementar","")
      EndIf
      IMPRIREL("Answer","R")

  endswitch

  Delete "Answer"
  Delete TabelaP
  Delete TabelaRelItens
  
  ConfigOpcoes("ModeloRelatorio/CasasDecimais","Gravar","PO_3002")  
EndWhile
ClearAll
Release Vars All
Release Procs All
              
