;** Rm_3102a *******************************************************************
;* Resumo de Vendas por Marca/Representante Ranking Pedidos                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 17/03/2011 por Bruno Carvalho
;Ultima Alteracao: 30/03/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_COMVALOR       
;Ultima Alteracao: 05/04/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes Filtro Marca/Representante
;Ultima Alteracao: 16/05/2012 por Bruno Carvalho           
;Motivo Alteracao: Altera‡Æo na impressÆo dos reports, ajustado p/ imprimir em 3 modelos
;Ultima Alteracao: 24/07/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes Diret¢rio Mˆs Fechado
;Ultima Alteracao: 16/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro de Gerencia
;Ultima Alteracao: 23/08/2016 por Kamila Gomes
;Motivo Alteracao: InclusÆo de op‡Æo Incluir Suspensos
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 26/09/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtros                      
;Ultima Alteracao: 05/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Seta_Ordem_Report()                
;Ultima Alteracao: 13/06/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtros
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        
        {Ask} {\\Sistemas\\Vendas\\Destin}
        Moveto [Codigo da Destinacao  ] Example "cd"
        Moveto [Tipo Movimento Estoque] TypeIn "S"
        Moveto [Atualiza Pedidos      ] TypeIn "S"
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Numero do Pedido       ] Example "Pedido"
        Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo da Destinacao   ] Example "cd"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.."
        Moveto [Situacao do Pedido     ]
        switch
          case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
          case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
        endswitch
                                                
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter
        Moveto [Numero do Pedido       ] Example "Pedido"
        Moveto [Codigo do Item         ] Example "Item"
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"  
                                                                
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ] Example "Item"
        Moveto [Codigo da Marca        ] Check TypeIn "~VSDGMARCA.."
        Moveto [Descricao da Marca     ] Check 
        Do_It!
        ClearAll      
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
Moveto [Codigo da Marca        ] Example "CodM"
Moveto [Descricao da Marca     ] Example "DesM"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Codigo da Marca        ] Example "CodM"
Moveto [Descricao da Marca     ] Example "DesM"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Quantidade      ] Example "qtde"
       Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
  Case Tipo="DEVOLUCOES":
       Moveto [Devolucoes_Quantidade  ] Example "qtde"
       Moveto [Devolucoes_Preco Total ] Example "ptot" TypeIn"-" Example "vdes"
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados **************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Embalagem       ] Check TypeIn "Calc Sum as VendasEmbalagem"
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as VendasPreco"
Moveto [Devolucoes_Quantidade  ] Check TypeIn "Calc Sum as DevolucoesQuantidade"
Moveto [Devolucoes_Preco Total ] Check TypeIn "Calc Sum as DevolucoesPreco"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Vendas_Embalagem          ] TypeIn "<=0, changeto blank"
Moveto [Unidade Embalagem         ] TypeIn "changeto Blank"
Do_It!
ClearAll

;***** Totaliza Empresa **********************************
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"

Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;***** Totaliza Marca ************************************
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Marca        ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"

Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Total_Vendas_Marca     ] TypeIn "changeto _vp"
Do_It!
ClearAll

;***** Totaliza Representante ****************************
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Marca        ] Check
Moveto [Codigo do Representante] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Codigo do Representante] Example "crep"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"

Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Codigo do Representante] Example "crep"
Moveto [Total_Vendas_Represent ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"         : Campo="NO"
            Case Campo="TG_GERENCIA"          : Campo="TG_EMPRESATE"
            Case Campo="TG_REPRESEN"          : Campo="TG_GERENCIA"
            Case Campo="TG_MARCA"             : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI"             : Campo="TG_MARCA"
            Case Campo="TG_DTFIM"             : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALFRANK"   : Campo="TG_DTFIM" 
            Case Campo="TG_COMVALOR"          : Campo="TG_OPRELCODALFRANK"
            Case Campo="TG_SITUACAOPEDIDO"  : Campo="TG_COMVALOR"
            Case Campo="YES" Or Campo="NO"    : Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"       : Campo="TG_GERENCIA" 
                    Case Campo="TG_GERENCIA"        : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"        : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"           : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"           : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"           : Campo="TG_OPRELCODALFRANK"
                    Case Campo="TG_OPRELCODALFRANK" : 
                         VSDGOPRELCODALFRANK=ControlValue("TG_OPRELCODALFRANK")
                         If IsBlank(VSDGOPRELCODALFRANK)
                            Then VSDGOPRELCODALFRANK="1"
                         EndIf   
                         Campo="TG_COMVALOR"                    
                    Case Campo="TG_COMVALOR"        : Campo="TG_SITUACAOPEDIDO"
                    Case Campo="TG_SITUACAOPEDIDO"  : Campo="YES" 
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   = ""
VSDGGERENCIA  = ""
VSDGREPRESEN  = ""
VSDGMARCA     = ""
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()
VSDGOPRELCODALFRANK = ""
VSDGCOMVALOR = "1"
VSDGSITUACAOPEDIDO  = ""

While True

  ShowDialog "Ranking de Pedidos Marca/Representante" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN"    To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMREPR"     To VSDGNOMREPR

    Label  @ 06,00 "Marca"  For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡„o de Ordem" For "TG_OPRELCODALFRANK"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPRELCODALFRANK" To VSDGOPRELCODALFRANK
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALFRANK" To VSDGNOMOPRELCODALFRANK

    Label  @ 02,35 "Op‡„o de Valor" For "TG_COMVALOR"
    Accept @ 03,39 Width 04 "A1"  Picture "1,2" Tag "TG_COMVALOR" To VSDGCOMVALOR
    Accept @ 03,44 Width 25 "A10"  Picture "!*!" Tag "TG_NOMCOMVALOR" To VSDGNOMCOMVALOR

    Label  @ 04,35 "Situacao do Pedido"  For "TG_SITUACAOPEDIDO"
    Accept @ 05,36 Width 33 "A30"  Picture "ABERTO,SUSPENSO,CANCELADO,FATURADO,TODAS,!*!" Tag "TG_SITUACAOPEDIDO"  To VSDGSITUACAOPEDIDO

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok"  Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                     Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer") Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Rename Tabela "Answer"
  
  Tabela =Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_3106"
  Copy "\\Base\\Sistemas\\Vendas\\RM_3106" Tabela  

  Adiciona_Dados("VENDAS")
  Processa()
  
  Switch
    Case VSDGOPRELCODALFRANK="1" : Seta_Ordem_Report(Tabela,"6","Codigo do Representante","Codigo do Representante","")
    Case VSDGOPRELCODALFRANK="2" : Seta_Ordem_Report(Tabela,"6","Codigo do Representante","Nome Fantasia Represent","")
    Case VSDGOPRELCODALFRANK="3" : Seta_Ordem_Report(Tabela,"6","Codigo do Representante","Vendas_Preco Total","D")                               
  EndSwitch
  IMPRIREL(Tabela,"6")
  
  ;If VSDGOPRELCODALFRANK="1"
  ;  Then IMPRIREL(Tabela,"6")
  ;  Else IMPRIREL(Tabela,"7")
  ;EndIf

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
