;** Rm_0350 ********************************************************************
;*  Emissao dos Titulos a Receber por Conta/TpCarteira/Cliente                 *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 26/11/2003 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 08/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0351" (59) neste script "RM_0350" (51)
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira
;Ultima Alteracao: 31/01/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes agrupado RM_0090, RM_0352    

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then
       if not isblank(CIDADE)
          then
               {Ask} {\\Sistemas\\Cadastro\\Destinat}
           	    Moveto [Codigo ] Example "cli"
          	    Moveto [Cidade ] TypeIn CIDADE
	    endif
     
      {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA.."
       Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       Moveto [Saldo do Documento] TypeIn "> 0.01"
       Moveto [Codigo da Conta   ] TypeIn "~VSDGCONTA.."
       Moveto [Tipo do Documento ] TypeIn "~VSDGTPDOCTO.."

       if not isblank(CIDADE)
          then Moveto [Codigo do Destinatario] Example "cli" TypeIn ", ~VSDGDESTINAT.."
          else Moveto [Codigo do Destinatario]               TypeIn   "~VSDGDESTINAT.."
       endif
       
       Switch                                                                           
         Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
         Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
       EndSwitch  
       Do_It!
       ClearAll
EndIf

If VSDGCODMODELO="32B"
	 Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
				Moveto [Codigo] Example "codigo"
				Moveto [Situacao do Cliente] TypeIn "PESSIMO"
        {Ask} {Answer} TypeIn "Fast Delete"
        Moveto [Codigo do Destinatario] Example "codigo"
        Do_It!
        ClearAll
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar DB temporaria                                           *
;*******************************************************************************
Proc Processa()

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf
      
   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll
EndProc   ;(Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59  : Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPCART"  
                                        Then ListaRegra_F2() 
                                     EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESA"
            Case Campo="TG_TPDOCTO"       : Campo="TG_CONTA"
            Case Campo="TG_CIDADE"        : Campo="TG_TPDOCTO"
            Case Campo="TG_DESTINAT"      : Campo="TG_CIDADE"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_TPCART"        : Campo="TG_DDPROTESTO"
            Case Campo="TG_CODMODELO"     : Campo="TG_TPCART"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : Campo="TG_TPDOCTO"
                    Case Campo="TG_TPDOCTO"    : Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"     : Campo="TG_DESTINAT"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                    Case Campo="TG_DESTINAT"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
     MSG_CAMPO="Informe o Numero de Dias"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("51  Tipo de Carteira/Cliente/Data de Vencimento")           ;RM_0350   
ModeloRelatoriosAdd("59  Tipo de Carteira/Data de Vencimento")                   ;RM_0351
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Data de Vencimento")                                    ;RM_0090
ModeloRelatoriosAdd("02B Data de Vencimento - Sint‚tico")                        ;RM_0090
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("65  Tipo de Documento/Tipo de Carteira/Data de Vencimento") ;RM_0352   
ModeloRelatoriosAdd("32  UF/Cidade/Cliente/Data de Vencimento")                        ;RM_0084   
ModeloRelatoriosAdd("32B UF/Cidade/Cliente/Data de Vencimento - SEM CLIENTE PESSIMO")  ;RM_0084   

ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""
VSDGCONTA     =""
VSDGTPDOCTO   =""
VSDGCIDADE    =""
CIDADE        =""
VSDGDESTINAT  =""

VSDGDDPROTESTO=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()
VSDGTPCART    =""

ModeloRelatoriosCarregaLista()

ListaRegra_TGAtivado="[TG_TPCART]"

While True
  ShowDialog "Titulos a Receber por Conta" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"     
   @ 05,12   Height 20 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 04,00 "Tipo do Documento"  For "TG_TPDOCTO"
    Accept @ 05,01 Width 07 "A4"  Picture "!*!" Tag "TG_TPDOCTO" To VSDGTPDOCTO
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPDOCTO"  To VSDGNOMTPDOCTO

    Label  @ 06,00 "Cidade"  For "TG_CIDADE"
    Accept @ 07,01 Width 33 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE

    Label  @ 08,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 09,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 10,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap˘s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 03,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART
    
    Label  @ 13,00  "Modelo de ~R~elat˘rio"  For "TG_CODMODELO"
    Accept @ 14,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 14,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 16,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 16,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  Switch
    Case VSDGCODMODELO="51"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001"  "2"  Tabela "R"
    Case VSDGCODMODELO="59"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001b" "7"  Tabela "R"
    
    Case VSDGCODMODELO="02"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "13"  Tabela "R"
    Case VSDGCODMODELO="02B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000a" "1"  Tabela "R"

    Case VSDGCODMODELO="65"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001" "8"   Tabela "R"


    Case VSDGCODMODELO="32"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1002" "R" Tabela "R"
    Case VSDGCODMODELO="32B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1002" "R" Tabela "R"
      
  EndSwitch
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
