;** Rm_0121 ********************************************************************
;*  Relatorio de Clientes que compram a tantos meses                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/11/1997 por Anivel Augusto Rodrigues
;Ultima Alteracao: 10/05/2007 por Davi Carrano
;Motivo Alteracao: Acrescentar Endere‡o
;Ultima Alteracao: 10/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO]

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "Codigo"
Moveto [Razao Social           ] Check
Moveto [Cidade                 ] Check
If Upper(VSDGCIDADE)<>"TODAS"
   Then TypeIn VSDGCIDADE
EndIf
Moveto [UF                     ] Check TypeIn "~VSDGESTADO.."
Moveto [Telefone               ] Check
Moveto [Contato                ] Check
Moveto [Endereco               ] Check
Moveto [Bairro                 ] Check
Moveto [CEP                    ] Check
Moveto [Tipo                   ] TypeIn "C"
{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                ] Check Example "Codigo"
Moveto [Data da Ultima Compra ] Check TypeIn ">=~DATA"
Moveto [Valor da Ultima Compra] Check
Do_It!
ClearAll
EndProc   ;  (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_MESES"         : Campo="NO"
            Case Campo="TG_CIDADE"        : Campo="TG_MESES"
            Case Campo="TG_ESTADO"        : Campo="TG_CIDADE"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_ESTADO"
            Case Campo="YES" Or Campo="NO": Campo="TG_OPRELCODALF"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_MESES":
                         VSDGMESES=ControlValue("TG_MESES")
                         If IsBlank(VSDGMESES)
                            Then Campo="TG_MESES"
                            Else Campo="TG_CIDADE"
                         EndIf
                    Case Campo="TG_CIDADE"     :Campo="TG_ESTADO"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                    Case Campo="TG_ESTADO"     : Campo="TG_OPRELCODALF"     
                    Case Campo="TG_OPRELCODALF":Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_MESES":
       MSG_CAMPO="Informe a Quantidade a Mais de Meses que n„o Compram"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*****************************************************************************+*
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGMESES       =""
VSDGCIDADE      =""
VSDGESTADO      ="" 
VSDGOPRELCODALF =""

While True

  ShowDialog "Rela‡„o de Clientes que Compram … ? Mes(es)" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,09   Height 12 Width 60

    Label  @ 01,00 "Quantidade a Mais de Mes(es)" For "TG_MESES"
    Accept @ 02,01 Width 05 "A2"  Picture "#*#" Tag "TG_MESES" To VSDGMESES

    Label  @ 03,00 "Cidade"  For "TG_CIDADE"
    Accept @ 04,01 Width 27 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE
                                   
    Label  @ 03,27 "Estado"  For "TG_ESTADO"
    Accept @ 04,28 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO

    Label  @ 05,00 "Ordem" For "TG_OPRELCODALF"
    Accept @ 06,01 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 06,06 Width 15 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Pushbutton @ 08,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 08,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog

  If Not RetVal Then QuitLoop EndIf

  DATA=Today()-(NumVal(VSDGMESES)*30)

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, Gerando Relat¢rio")
  Seleciona()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf

  If VSDGOPRELCODALF="1"
     Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "8" "Answer" "R"
     Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "9" "Answer" "R"
  EndIf

  IMPRIREL("Answer","R")

  Delete "Answer"
EndWhile
ClearAll
Release Vars All
Release Procs All
