;** RM_0050 ********************************************************************
;*  Carta de Cobranca                                                          *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 17/02/2009 por Anivel Augusto Rodrigues
;Ultima Alteracao: 06/08/2009 por Cleber Alves
;Motivo Alteracao: Adição dos modelos V e VI
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 21/09/2009 por Bruno Carvalho
;Motivo Alteracao: Adição do modelo VII
;Ultima Alteracao: 30/11/2009 por Cleber Alves
;Motivo Alteracao: Alteracao no Sort
;Ultima Alteracao: 15/01/2010 por Cleber Alves
;Motivo Alteracao: Acrescimo dos modelos VIII, IX, X           
;Ultima Alteracao: 20/03/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes para ordenar os modelos das cartas em listagem
;Ultima Alteracao: 20/03/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado modelo/op‡Æo de Carta de Reabilita‡Æo de Credito
;Alterado em     : 02/04/2012 por Karina Andrade 
;Motivo Alteracao: Add VSDGNDIAS e VSDGNPARCELAS na op‡Æo Carta de Reabilita‡Æo
;Ultima Alteracao: 24/05/2012 por Bruno Carvalho
;Motivo Alteracao: InclusÆo modelo 12 para empresa "0312"
;Ultima Alteracao: 01/06/2012 por Bruno Carvalho
;Motivo Alteracao: InclusÆo modelo 13 para empresa "0312"
;Ultima Alteracao: 15/06/2012 por Bruno Carvalho
;Motivo Alteracao: InclusÆo modelo 14 para empresa "0222"
;Ultima Alteracao: 19/09/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Substitui‡Æo Editor novo arquivo por FileWrite
;Ultima Alteracao: 04/02/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes LimpaRodape()                  
;Ultima Alteracao: 18/02/2014 por Bruno Carvalho
;Motivo Alteracao: Alterado no Sort "Nome Fantasia" -> "Razao Social"  #0227#
;Ultima Alteracao: 23/04/2014 por Luis Gustavo
;Motivo Alteracao: Inclusao modelos XIV e XV para empresa "0121" 
;Ultima Alteracao: 18/07/2014 por Luis Gustavo
;Motivo Alteracao: Inclusao do RadioButtons para escolher qual endere‡o imprimir  na carta de cobranca,
; Endere‡o do Cadastro ou Endere‡o de Cobran‡a.  Alteracao so foi implementada para o modelo XIII***
;Ultima Alteracao: 06/09/2014 por Kamila Gomes
;Motivo Alteracao: Ajustes Dispositivo() alterado para DispositivoI("COB")
;Ultima Alteracao: 22/05/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado Codigo 17 e Modelo XVI 
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE  
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT  
;Ultima Alteracao: 03/01/2017 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog MensagemRadioButtons()             
;Ultima Alteracao: 29/03/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes #0232 email  
;Ultima Alteracao: 04/04/2019 por Kamila Gomes
;Motivo Alteracao: Ajustes #0232 email  
;Ultima Alteracao: 22/11/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes #0121 email  
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

{Ask} {Duplic} Check
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo da Conta       ] TypeIn "~VSDGCONTA.."
Moveto [Codigo do Destinatario] TypeIn "~VSDGDESTINAT.."
Moveto [Data de Vencimento    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Saldo do Documento    ] TypeIn "> 0.01"
Switch
  Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
  Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
EndSwitch    
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************************************
If VSDGEMPRESA="0000"
   Then {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit "Answer"
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
 ;;If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
 ;;    Then If [Descricao do Lancamento]="PROTESTADA"
 ;;            Then [Observacoes]="Cartorio"
 ;;            Else [Observacoes]="Protestar"
 ;;         EndIf
 ;;EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll

{Tools} {Copy} {JustFamily} {Duplic} {Answer} {Replace}

Sort "Answer" On "Razao Social","Codigo da Empresa","Data de Vencimento","Tipo do Documento","Numero do Documento"

EndProc ;Processa()

;*******************************************************************************
;* Seleciona Registros para Carta de Cobranca                                  *
;*******************************************************************************
Proc SELECIONAI()

Edit "Answer"
SetHighLight Current Record 23 Field 31
{Image} {KeepSet}
Do_It!

CoEdit "Answer"
PickForm "3"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
EndWhile
Do_It!
ClearAll
EndProc

;*******************************************************************************
;* Seleciona Titulos para Baixa
;*******************************************************************************
Proc CHAVE() 

While True
  End
  Down
  Moveto [Numero do Lancamento]
  While True
    Prompt " Esc=Sair  F4=Imprimir  F5=Enviar email  F7=Paginar  "

    Wait Field
         Until "ESC","ENTER","F7","HOME","UP","PGUP","F4","F5"

    Switch
    Case RetVal="F4":
         Del
         CobrancaViaEmail=false
         IMPRIME()
         QuitLoop
         
    Case RetVal="F5":
         Del
         CobrancaViaEmail=true
         IMPRIME()
         QuitLoop
         
    Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
         CHAVE=0
         While True
           PAGINA("Answer","MR")
           If EDITAR="S"
              Then Mensagem("Altera‡„o n„o permitida !")
                   UnLockRecord
              Else If EXCLUIR="S"
                      Then CONFIRMA()
                           If OK="S"
                              Then DEL
                              Else UnLockRecord
                           EndIf
                      Else QuitLoop
                   EndIf
           EndIf
         EndWhile
         QuitLoop
    Case Retval="ESC":
         CHAVE=9
         Return
    EndSwitch
  EndWhile
EndWhile
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_ImpDialog(Disparo,Campo,Evento,Elemento) 
Temp=True
MSG_CAMPO=""
TECLA=""

If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_MontaLista"     : Campo="NO"
            Case Campo="TG_NPARCELAS"      : Campo="TG_MontaLista"
            Case Campo="TG_NDIAS"          : Campo="TG_NPARCELAS"
            Case Campo="TG_END_COB"        : Campo="TG_MontaLista"      
            Case Campo="YES" Or Campo="NO" : Campo="TG_MontaLista"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_MontaLista"     : 
                         VSDGMODLIST = controlvalue("TG_MontaLista")
                         If CARTA = "COBRANCA" 
                            Then If VSDGMODLIST = 15
                                    Then Campo="TG_END_COB"
                                    Else Campo="YES"
                                 EndIF
                            Else Campo="TG_NPARCELAS"  
                         EndIf 
                    Case Campo="TG_NPARCELAS"      : Campo="TG_NDIAS" 
                         VSDGNPARCELAS=ControlValue("TG_NPARCELAS") 
                    Case Campo="TG_NDIAS"          : Campo="YES"
                         VSDGNDIAS=ControlValue("TG_NDIAS")
                    Case Campo="TG_END_COB"        : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_MontaLista":
     MSG_CAMPO="Selecione o op‡„o desejada !"
     TECLA    ="=Selecionar  "
  Case Campo="TG_NPARCELAS":
     MSG_CAMPO="Informe o Numero de Parcelas"
  Case Campo="TG_NDIAS":
     MSG_CAMPO="Informe a Validade da Proposta"
  Case Campo="TG_END_COB":
     MensagemRadioButtons()   
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc ;SD_ImpDialog()

;*******************************************************************************
;* Rotina de Configura‡Æo para montar Lista                                    *
;*******************************************************************************
Proc ConfOpcoes(Opcao,CARTA)
Private Opcao
Switch
  Case CARTA = "COBRANCA" :   
       Switch
         Case Opcao="Ler":
              Array Array_MontaLista[18]
;                                  "Codigo  Descri‡„o                            Modelo        "                
              Array_MontaLista[1] ="01      Lista                                              "
              Array_MontaLista[2] ="-----------------------------------------------------------" 
              Array_MontaLista[3] ="02      Carta Cobran‡a                       I             "
              Array_MontaLista[4] ="03      Carta Cobran‡a                       II            "
              Array_MontaLista[5] ="04      Carta Cobran‡a                       III           "
              Array_MontaLista[6] ="05      Carta Cobran‡a                       IV            "   
              Array_MontaLista[7] ="06      Carta Cobran‡a                       V             "
              Array_MontaLista[8] ="07      Carta Cobran‡a                       VI            "
              Array_MontaLista[9] ="08      Carta Cobran‡a                       VII           "
              Array_MontaLista[10]="09      Carta Cobran‡a                       VIII          "
              Array_MontaLista[11]="10      Carta Cobran‡a                       IX            "
              Array_MontaLista[12]="11      Carta Cobran‡a                       X             "
              Array_MontaLista[13]="12      Carta Cobran‡a (p/ papel timbrado)   XI            " ;CB_0312
              Array_MontaLista[14]="13      Carta Cobran‡a (p/ papel timbrado)   XII           " ;CB_0312a
              Array_MontaLista[15]="14      Carta Cobran‡a (p/ papel timbrado)   XIII          " ;CB_0222
              Array_MontaLista[16]="15      Carta Cobran‡a                       XIV           " ;CB_0121
              Array_MontaLista[17]="16      Carta Cobran‡a                       XV            " ;CB_0121
              Array_MontaLista[18]="17      Carta Cobran‡a                       XVI           " ;CB_0012
              
              VSDGQUANTIDADE=1
              If IsFile("ML_0001.sc")
                  Then Play "ML_0001"
                  Else VSDGMontaLista       =1
                       VSDGOPRELCODALFDIG   =""
                       VSDGNOMOPRELCODALFDIG=""
              EndIf
        
              For wi From 1 to ArraySize(Array_MontaLista)
                If RTrim(SubStr(Array_MontaLista[wi],1,3))=VSDGMontaLista
                   Then VSDGMontaLista=wi
                        QuitLoop
                EndIf
              EndFor
        
         Case Opcao="Gravar":
              FileWrite        "ML_0001.sc" From ";****** Variaveis de Configura‡„o Modelo de Carta de Cobranca Vise nformatica"+"\n"
              FileWrite Append "ML_0001.sc" From "VSDGMontaLista    ="+Chr(34)+MODLISTA+Chr(34)+"\n"
              FileWrite Append "ML_0001.sc" From "VSDGOPRELCODALFDIG="+Chr(34)+VSDGOPRELCODALFDIG+Chr(34)+"\n"
       EndSwitch
       
  Case CARTA = "REABILITACAO" :
       Switch
         Case Opcao="Ler":
              Array Array_MontaLista[1]                
;                                  "Codigo  Descri‡„o                            Modelo        "   
              Array_MontaLista[1] ="01      Carta de Reabilita‡„o de Cr‚dito     I             "
              
              VSDGQUANTIDADE=1
              If IsFile("ML_0002.sc")
                  Then Play "ML_0002"
                  Else VSDGMontaLista       =1
                       VSDGOPRELCODALFDIG   =""
                       VSDGNOMOPRELCODALFDIG=""
              EndIf
        
              For wi From 1 to ArraySize(Array_MontaLista)
                If RTrim(SubStr(Array_MontaLista[wi],1,3))=VSDGMontaLista
                   Then VSDGMontaLista=wi
                        QuitLoop
                EndIf
              EndFor

         Case Opcao="Gravar":
              FileWrite        "ML_0002.sc" From ";****** Variaveis de Configura‡„o Modelo de Carta de Rabilitacao de Credito Vise nformatica"+"\n"
              FileWrite Append "ML_0002.sc" From "VSDGMontaLista    ="+Chr(34)+MODLISTA+Chr(34)+"\n"
              FileWrite Append "ML_0002.sc" From "VSDGOPRELCODALFDIG="+Chr(34)+VSDGOPRELCODALFDIG+Chr(34)+"\n"
       EndSwitch 
EndSwitch         

EndProc ;ConfOpcoes()      

;*******************************************************************************
;* Rotina De Impressao                                                         *
;*******************************************************************************
Proc IMPRIME()
Private MODCARTA

If CobrancaViaEmail
   then
        ;-- liberar com pagamento !!
        if sys_codigo_Cliente="0274" or
           sys_codigo_Cliente="0232" or
           sys_codigo_Cliente="0121" or 
           not IsRuntime()
           then 
                ;liberado !
                           
           else Mensagem("Fun‡Æo email inativa !// //Contactar Suporte Vise caso queira utilizar !")
                Return
        endif   
endif   

Echo Normal
Echo Off
ShowPopup " Modelo de Carta " CENTERED
 "Carta de ~C~obran‡a                " : " Carta de Cobran‡a                " : "COB",
 "Carta de ~R~eabilita‡„o de Cr‚dito " : " Carta de Reabilita‡„o de Cr‚dito " : "REA",
 Separator,
 "~C~ancelar                         " : " Cancelar a Opera‡„o              " : "CANCELAR"
EndMenu
To MenuVar
Echo off
If MenuVar="CANCELAR" or MenuVar="Esc"
   Then Return   
EndIf   

Switch
 Case MenuVar="COB" : CARTA="COBRANCA"
 Case MenuVar="REA" : CARTA="REABILITACAO"
EndSwitch

Release Vars Array_MontaLista
ConfOpcoes("Ler",CARTA)

Endereco_Cobranca = False
VSDGNPARCELAS=""
VSDGNDIAS=""
VSDGENDCOB = 1
VSDGMODLIST = 0

LimpaRodape(0)
Do_It!
ClearAll

Switch 
  Case CARTA="COBRANCA"     : MODCARTA = "Carta de Cobran‡a"
  Case CARTA="REABILITACAO" : MODCARTA = "Carta de Reabilita‡„o de Cr‚dito" 
EndSwitch  

While True

  OP_SHOW="I"
  ShowDialog "Selecione o Modelo da "+MODCARTA Proc "SD_ImpDialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 00,01 Height 18 Width 65

    PickArray @2,01 Height 8 width 60
     Columns 1
      Array_MontaLista
       Tag "TG_MontaLista"
        To VSDGMontaLista
    Label @ 01,01 "Codigo  Descri‡„o                            Modelo     "    For "TG_MontaLista"
    
    Label  @ 10,00 "N§ Parcelas"  For "TG_NPARCELAS"
    Accept @ 11,01 Width 05 "A2"  Picture "#*#" Tag "TG_NPARCELAS" To VSDGNPARCELAS
                  
    Label  @ 10,15 "Validade" For "TG_NDIAS"
    Accept @ 11,16 Width 06 "A3"  Picture "#*#" Tag "TG_NDIAS" To VSDGNDIAS
    Label  @ 11,22 "Dias" For "TG_NDIAS"
    
    Frame Single From 13,60 to 10,39
    @ 10,42 ?? " End. Cobran‡a "
    RadioButtons @ 11,40 Height 2 Width 18
      "End. ~C~adastro",
      "End. C~o~bran‡a"
      Tag "TG_END_COB"
      To VSDGENDCOB
    
    Pushbutton @ 14,16 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,30 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  MODLISTA=RTrim(SubStr(Array_MontaLista[VSDGMontaLista],1,3))

  If MODLISTA="---"
     Then Mensagem("Modelo Inv lido !")
          Loop
  EndIf
  
  If VSDGENDCOB = 2 And MODLISTA="14"
     Then Endereco_Cobranca = True
     Else Endereco_Cobranca = False
  EndIf   
                  
  if CobrancaViaEmail
     then
     
     else                  
          DispositivoI("COB")
          If OK="" Then Loop EndIf
  endif                 
    
  AGUARDE("Aguarde, Imprimindo")

  Switch
    Case CARTA = "REABILITACAO" : Switch
                                    Case MODLISTA="01" : Play "RC_0001"
                                  EndSwitch

    Case CARTA = "COBRANCA"     : Switch 
                                    Case MODLISTA="01" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1002" "6"  "Answer" "R"
                                                         IMPRIREL("Answer","R") 

                                    Case MODLISTA="02" : Play "CB_0000"
                                    Case MODLISTA="03" : Play "CB_0001"
                                    Case MODLISTA="04" : Play "CB_0002"
                                    Case MODLISTA="05" : Play "CB_0003"
                                    Case MODLISTA="06" : Play "CB_0004"
                                    Case MODLISTA="07" : Play "CB_0005"
                                    Case MODLISTA="08" : Play "CB_0006"
                                    Case MODLISTA="09" : Play "CB_0007"
                                    Case MODLISTA="10" : Play "CB_0008"
                                    Case MODLISTA="11" : Play "CB_0009"
                                    Case MODLISTA="12" : Play "CB_0312"  ;Casa Cruzeiro (Utiliza folha personalizada)
                                    Case MODLISTA="13" : Play "CB_0312a"
                                    Case MODLISTA="14" : Play "CB_0222"  ;Lupus
                                    Case MODLISTA="15" : Play "CB_0010"
                                    Case MODLISTA="16" : Play "CB_0011"
                                    Case MODLISTA="17" : Play "CB_0012" ;Cotran
                                  EndSwitch 
  EndSwitch
  ClearAll                                       

  ConfOpcoes("Gravar",CARTA)

  QuitLoop
EndWhile
ClearAll

CoEdit "Answer"
PickForm "3"
LIMPAGUARDE()
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc MontaArquivoImpressao(tipo, pessoa, nome)
private tipo, pessoa, nome, regdestmail, regdestinat, email

switch
  case tipo="Inicio":
    if CobrancaViaEmail
       then
            DISPOSITIVO_OPCAO="V"
            Seta_Tipo_Impressora("Matricial")

            FileWrite privdir()+"CVE0000.ini" From ""
       else
            ARQIMP=PrivDir()+"CB_0000.Txt"       
            FileWrite ARQIMP From ""
    endif   

  case tipo="PessoaInicio":
    If CobrancaViaEmail 
       then ARQIMP=privdir()+"CVE"+pessoa+".Txt"
            FileWrite ARQIMP From ""
    endif    

  case tipo="PessoaFim":
    If CobrancaViaEmail
       then
            email = "***Indefinido***"  
            GetRecord "\\Sistemas\\Cadastro\\Destmail" pessoa,"F" To regdestmail
            If not RetVal
              Then GetRecord "\\Sistemas\\Cadastro\\Destinat" pessoa To regdestinat
                   If RetVal
                      Then email = regdestinat["Endereco_Eletronico"]
                           If email = "" then email = "***Indefinido***"  endIf
                   EndIf 
              Else email = regdestmail["Email"] 
            EndIf
            
            Run NoRefresh "c:\\vise\\Vdpr.exe /DEL /PDF /FILE "+ARQIMP
            FileWrite Append privdir()+"CVE0000.ini" From  nome+"|"+email+"|"+Privdir()+"CVE"+pessoa+".txt.pdf"+"\n"
    endif    

  case tipo="Fim":
    if CobrancaViaEmail
       then ARQ_EMAIL = privdir()+"CVE0000.ini"
            FileWrite     PrivDir()+"funcao1.txt"  From  "EXEM|c:\\vise\\ViseMail.exe|"+SubStr(Directory(),1,1)+
                                                                                      " "+PrivDir()+"MAILCOB"+
                                                                                      " "+"**Lote** "+ARQ_EMAIL
            ExecVise(PrivDir()+"funcao1.txt")

       else ImpriArq(ARQIMP)
    endif   

endswitch

Endproc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DESTINAT"      : Campo="TG_CONTA"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_TPPAGTO"       : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CONTA":
     MSG_CAMPO="Informe uma conta tipo CAIXA !"
  Case Campo="":
       MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

sys_valor()

If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE="0222"  EndIf
If Not IsAssigned(SYS_CHAPA_USUARIO)   Then SYS_CHAPA_USUARIO=""       EndIf

VSDGEMPRESA =""
VSDGCONTA   =""
VSDGTPPAGTO =""
VSDGDESTINAT=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

ListaRegra_TGAtivado="[TG_TPPAGTO]"

While True
  ShowDialog "Carta de Cobran‡a" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"   
   @ 05,12   Height 13 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
                                
    Label  @ 00,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 01,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 01,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Pushbutton @ 09,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  AGUARDE("Aguarde, Selecionando registros")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf

  Processa()

  SELECIONAI()
  Echo Normal
  Echo Off

  ClearAll
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
