;** Rm_0950 ********************************************************************
;*  Relatorio Analise de Credito                                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 01/06/2001 por Anivel Augusto Rodrigues
;Ultima Alteracao: 06/05/2003 por Rodrigo Francisco Bento
;Motivo Alteracao: Mudan‡a Base
;Ultima Alteracao: 07/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cheques em Cobranca
;Ultima Alteracao: 21/08/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes "Situacao do Cliente" p/ permitir situa‡Æo como OTIMO
;Ultima Alteracao: 10/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO] 

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc SELECIONA()
ClearAll

;; Titulos a Vencer
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                ] Example "cod"
Moveto [Situacao do Cliente   ] TypeIn "~VSDGSITUACAO.."
Moveto [Cidade                ] TypeIn CIDADE
Moveto [UF                    ] TypeIn "~VSDGESTADO.."
{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                 ] Example "cod"
Moveto [Data da Primeira Compra] TypeIn ">=~VSDGDTREF"
{Ask} {\\Sistemas\\CtaRec\\Duplic}
Moveto [Codigo do Destinatario ] Check Example "cod"
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Data de Vencimento     ] TypeIn ">=Today"
Moveto [Saldo do Documento     ] TypeIn "> 0.01" TypeIn ", calc sum as Valor Total"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo do Destinatario ] Example "a"
Moveto [Valor Total            ] Example "b"
{Ask} {Rm_0950} TypeIn "Fast Insert"
Moveto [Codigo                 ] Example "a"
Moveto [Total a Vencer         ] Example "b"
Do_It!
ClearAll


;; Titulos a Vencidos
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "cod"
Moveto [Situacao do Cliente    ] TypeIn "~VSDGSITUACAO.."
Moveto [Cidade                 ] TypeIn CIDADE
Moveto [UF                     ] TypeIn "~VSDGESTADO.."
{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                 ] Example "cod"
Moveto [Data da Primeira Compra] TypeIn ">=~VSDGDTREF"
{Ask} {\\Sistemas\\CtaRec\\Duplic}
Moveto [Codigo do Destinatario ] Check Example "cod"
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Data de Vencimento     ] TypeIn "<Today"
Moveto [Saldo do Documento     ] TypeIn "> 0.01" TypeIn ", calc sum as Valor Total"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo do Destinatario ] Example "a"
Moveto [Valor Total            ] Example "b"
{Ask} {Rm_0950} TypeIn "Fast Insert"
Moveto [Codigo                 ] Example "a"
Moveto [Total Vencido          ] Example "b"
Do_It!
ClearAll


;;; Pedidos a entregar
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "cod"
Moveto [Situacao do Cliente    ] TypeIn "~VSDGSITUACAO.."
Moveto [Cidade                 ] TypeIn CIDADE
Moveto [UF                     ] TypeIn "~VSDGESTADO.."
{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                 ] Example "cod"
Moveto [Data da Primeira Compra] TypeIn ">=~VSDGDTREF"
{Ask} {\\Sistemas\\Vendas\\PedidoC}
Moveto [Numero do Pedido       ] Example "PEDIDO"
Moveto [Codigo                 ] Check Example "cod"
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Situacao do Pedido     ] TypeIn "ABERTO"
{Ask} {\\Sistemas\\Vendas\\PedidoI}
Moveto [Numero do Pedido   ] Example "PEDIDO"
Moveto [Quantidade         ] Example "QUANT" TypeIn ", >" Example "QUANTF"
Moveto [Quantidade Faturada] Example "QUANTF"
Moveto [Preco Unitario     ] Example "VALOR"
TypeIn ", Calc (" Example "QUANT" TypeIn "-" Example "QUANTF" TypeIn ")*" Example "VALOR"
TypeIn " as Valor"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo] Check
Moveto [Valor ] TypeIn "Calc Sum As Valor Total"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo                 ] Example "a"
Moveto [Valor Total            ] Example "b"
{Ask} {Rm_0950} TypeIn "Fast Insert"
Moveto [Codigo                 ] Example "a"
Moveto [Total Pedidos          ] Example "b"
Do_It!
ClearAll

;;; Cheques a Descontar
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "cod"
Moveto [Nome Fantasia EmitDest ] Check
Moveto [Situacao do Cliente    ] TypeIn "~VSDGSITUACAO.."
Moveto [Cidade                 ] TypeIn CIDADE
Moveto [UF                     ] TypeIn "~VSDGESTADO.."
{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                 ] Example "cod"
Moveto [Data da Primeira Compra] TypeIn ">=~VSDGDTREF"
{Ask} {\\Sistemas\\CheqRec\\ChequeC}
Moveto [Numero do Lancamento   ] Example "NUMERO"
Moveto [Codigo                 ] Check Example "cod"
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
{Ask} {\\Sistemas\\CheqRec\\ChequeI}
Moveto [Numero do Lancamento] Example "NUMERO"
Moveto [Valor               ] Check
Moveto [Situacao            ] TypeIn "Blank Or \"EM ABERTO\" Or \"PRORROGADO\""
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo                ] Check
Moveto [Valor                 ] TypeIn "Calc Sum As Valor Total"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo                 ] Example "a"
Moveto [Valor Total            ] Example "b"
{Ask} {Rm_0950} TypeIn "Fast Insert"
Moveto [Codigo                 ] Example "a"
Moveto [Total Cheques          ] Example "b"
Do_It!
ClearAll

{Ask} {Rm_0950}
Moveto [Codigo                 ] Check
Moveto [Nome Fantasia EmitDest ] Check
Moveto [Data da Primeira Compra] Check
Moveto [Data da Ultima Compra  ] Check
Moveto [Situacao do Cliente    ] Check
Moveto [Total Pedidos          ] TypeIn "Calc Sum as Total Pedidos"
Moveto [Total Cheques          ] TypeIn "Calc Sum as Total Cheques"
Moveto [Total a Vencer         ] TypeIn "Calc Sum as Total a Vencer"
Moveto [Total Vencido          ] TypeIn "Calc Sum as Total Vencido"
Moveto [Limite de Credito      ] Check
Moveto [Credito Disponivel     ] Check

Do_It!
ClearAll
If Not IsEmpty("ANSWER")
   Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0950" "R" "Answer" "R"
EndIf

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_REPRESEN"      : Campo="NO"
            Case Campo="TG_CIDADE"        : Campo="TG_REPRESEN"
            Case Campo="TG_ESTADO"        : Campo="TG_CIDADE"            
            Case Campo="TG_DTREF"         : Campo="TG_ESTADO"
            Case Campo="TG_SITUACAO"      : Campo="TG_DTREF"
            Case Campo="YES" Or Campo="NO": Campo="TG_REPRESEN"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_REPRESEN"   : Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"     : Campo="TG_ESTADO"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                    Case Campo="TG_ESTADO"     : Campo="TG_DTREF"                         
                    Case Campo="TG_DTREF"      : Campo="TG_SITUACAO"
                    Case Campo="TG_SITUACAO"   : Campo="YES"
                         VSDGSITUACAO=ControlValue("TG_SITUACAO")
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_SITUACAO":
       MSG_CAMPO="Em Branco = Todas ou informe Bom, Regular, P‚ssimo"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGREPRESEN=""
VSDGDTREF   =BlankDate()
VSDGCIDADE  =""
VSDGESTADO  ="" 
VSDGSITUACAO=""

While True
  ShowDialog "Analise de Cr‚dito" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 11 Width 56

    Label  @ 00,00 "Representante"  For "TG_REPRESEN"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 1,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 02,00 "Cidade"  For "TG_CIDADE"
    Accept @ 03,01 Width 27 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE

    Label  @ 02,27 "Estado"  For "TG_ESTADO"
    Accept @ 03,28 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO

    Label  @ 04,00 "Compram desde" For "TG_DTREF"
    Accept @ 05,01 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Label  @ 04,14 "Situa‡„o" For "TG_SITUACAO"
    Accept @ 05,15 Width 13 "A10"  Picture "OTIMO,BOM,REGULAR,PESSIMO" Tag "TG_SITUACAO" To VSDGSITUACAO

    Pushbutton @ 07,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf

  IMPRIREL("Answer","R")

  Empty "\\Base\\Sistemas\\Vendas\\Rm_0950"
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
