;** RM_0079C *******************************************************************
;*  Relacao de Vendas a Vista e a Prazo/Devolucao                                *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 24/07/2009 por Nikolas
;Ultima Alteracao: 18/11/2009 por Nikolas
;Motivo Alteracao: Inclusao de forma de pagamento Outros
;Ultima Alteracao: 19/12/2011 por Nikolas
;Motivo Alteracao: Ajustes Seleciona()
;Ultima Alteracao: 23/12/2011 por Karina Andrade
;Motivo Alteracao: Ajustes Seleciona()
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 06/08/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes devolu‡Æo s¢ de entrada     
;Ultima Alteracao: 10/02/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_DESTIN, TG_TPMOVDESTIN                  
;Ultima Alteracao: 17/02/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes agrupado RM_0079, substituto RM_0072C         
;Ultima Alteracao: 21/02/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_REPRESEN          

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc RM_0079C_Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV")
   Then
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check
        Moveto [Codigo da Empresa      ] Example "cemp" TypeIn "!, ~VSDGEMPRESA.."
        Moveto [Numero do Documento    ] Example "ndoc" TypeIn "!"
        Moveto [Serie do Documento     ] Example "sdoc" TypeIn "!"
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        switch
          case ListaRegra_VSDGDESTIN_Ativo  : Moveto [Codigo da Destinacao] TypeIn ListaRegra_VSDGDESTIN
          otherwise                         : Moveto [Codigo da Destinacao] TypeIn "~VSDGDESTIN.."
        endswitch
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. Or ..SAIDA.. Or ..SERV.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "not C"
        Moveto [Tipo de Pagamento      ] TypeIn "~VSDGTPPAGTOVPO.."
        Moveto [Condicao de Pagamento  ] TypeIn "~VSDGCONDPGTO.."
        Moveto [Numero_Carregamento    ] TypeIn "~VSDGNCARREG.."
        Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV" Enter Check
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Forma de Pagamento     ] TypeIn "~VSDGTPPAGTO.."
        Do_It!
        ClearAll

        If IsTable(Tabela)
           Then Add "Answer" Tabela
           Else Rename "Answer" Tabela
        EndIf

        If IsBlank(VSDGDESTIN)
           then
                {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check
                Moveto [Codigo da Empresa      ] Example "cemp" TypeIn "!, ~VSDGEMPRESA.."
                Moveto [Numero do Documento    ] Example "ndoc" TypeIn "!"
                Moveto [Serie do Documento     ] Example "sdoc" TypeIn "!"
                Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
                Moveto [Tipo Movimento Estoque ] TypeIn "E"
                Moveto [Situacao               ] TypeIn "not C"
                Moveto [Numero_Carregamento    ] TypeIn "~VSDGNCARREG.."
                Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
                {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaV" Enter Check
                Moveto [Codigo da Empresa      ] Example "cemp"
                Moveto [Numero do Documento    ] Example "ndoc"
                Moveto [Serie do Documento     ] Example "sdoc"
                Do_It!
                ClearAll
        
                If Not IsEmpty("Answer")
                    Then {Ask} {Answer} TypeIn "Fast"
                         Moveto [Data de Emissao        ] Example "dt" 
                         Moveto [Valor Nota Fiscal      ] Example "vl"
                         Moveto [Forma de Pagamento     ] Example "fp" 
                         Moveto [Sequencia              ] TypeIn "blank, changeto 01"
                         Moveto [Data                   ] TypeIn "blank, changeto _dt"
                         Moveto [Valor                  ] TypeIn "blank, changeto _vl"
                         Moveto [Forma de Pagamento-1   ] TypeIn "blank, changeto _fp"
                         Do_It!
                         ClearAll
                         
                         {Ask} {Answer} TypeIn "Fast"
                         Moveto [Valor                  ] Example "vr" TypeIn ",Changeto " Example "vr" TypeIn "*-1"
                         Do_It! 
                         ClearAll
                         
                         If IsTable(Tabela)
                            Then Add "Answer" Tabela
                            Else Rename "Answer" Tabela
                         EndIf
                EndIf
        endif   
EndIF
EndProc   ;  (Seleciona)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_0079C_Principal()

AGUARDE("Aguarde, gerando o relat¢rio")
Tabela=Cria_Temp(PrivDir())

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  RM_0079C_Seleciona()
EndWhile

If IsEmpty(Tabela)
   Then 
        MENSAGEM("N„o existem registros a processar")
   else
        Switch
          case VSDGCODMODELO="1N"  : CopyReport "\\Base\\Sistemas\\Vendas\\Rm_1020" "2" Tabela "R"
          case VSDGCODMODELO="1NA" : CopyReport "\\Base\\Sistemas\\Vendas\\Rm_1020" "R"  Tabela "R"
          case VSDGCODMODELO="1NB" : CopyReport "\\Base\\Sistemas\\Vendas\\Rm_1020" "1"  Tabela "R"
      
        endSwitch
        IMPRIREL(Tabela,"R")  
EndIf
Delete Tabela

EndProc

;-- Chamada principal ----------------------------------------------------------
RM_0079C_Principal()

Release Vars Tabela
Release Procs RM_0079C_Principal, RM_0079C_Seleciona
