;** Rm_4001 ********************************************************************
;* Resumo de Vendas por Item para reposi‡Æo                                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 15/02/2013 por Karina Andrade
;Ultima Alteracao: 05/03/2014 por Kamila Gomes
;Motivo Alteracao: InclusÆo coluna Saldo_Atual
;Ultima Alteracao: 16/05/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: InclusÆo Filtro para Hora         
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 02/08/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro marca, departamento                 
;Ultima Alteracao: 19/09/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novo modelo 02 #0294#                 
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
private i

ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Estoque\\Itens" Enter
        Moveto [Codigo do Item          ] Example "ite"
        Moveto [Codigo da Marca         ] TypeIn "~VSDGMARCA.."
        Moveto [Codigo do Departamento  ] TypeIn "~VSDGDEPART.."
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Hora de Saida          ] Check 
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Tipo do Item           ] Check 
        Moveto [Codigo do Item         ] check Example "ite"
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Moveto [Preco Unitario Tabela  ] Check
        Do_It!
        ClearAll
        
        If IsEmpty("Answer")
           Then Return
        EndIf
        
        For i From 1 To 2
          {Ask} {Answer} TypeIn "Fast Delete"
          If i=1
             Then Moveto [Data de Emissao      ] TypeIn "~VSDGDTINI"
                  Moveto [Hora de Saida        ] TypeIn "<~VSDGHRINI"
             Else Moveto [Data de Emissao      ] TypeIn "~VSDGDTFIM"
                  Moveto [Hora de Saida        ] TypeIn ">~VSDGHRFIM"
          EndIf
          Do_It!
          ClearAll
        EndFor

        {Ask} {Answer}
        Moveto [Codigo da Empresa      ] Check 
        Moveto [Tipo do Item           ] Check 
        Moveto [Codigo do Item         ] Check
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Unitario Tabela  ] Check
        Do_It!
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Codigo do Item         ] Example "cite"
        Moveto [Descricao do Item      ] Example "dite"
        Moveto [Unidade Fiscal         ] Example "unf"
        Moveto [Tipo do Item           ] Example "tite"
        Moveto [Quantidade             ] Example "qtde"
        Moveto [Preco Unitario Tabela  ] Example "ptab"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Codigo do Item         ] Example "cite"
        Moveto [Descricao do Item      ] Example "dite"
        Moveto [Unidade Fiscal         ] Example "unf"
        Moveto [Tipo do Item           ] Example "tite"
        Moveto [Vendas_Quantidade      ] Example "qtde"
        Moveto [Preco Unitario Tabela  ] Example "ptab"
        Do_It!
        ClearAll
        
EndIf


EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Descricao Tipo do Item ] Example "dtpi"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Unidade Embalagem      ] Example "une"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Descricao da Familia   ] Example "dfam"
Moveto [Codigo da Marca        ] Example "cmar"
Moveto [Descricao da Marca     ] Example "dmar"
Moveto [Codigo de Barras       ] Example "cbr"
Moveto [Codigo Fornecedor      ] Example "cfor"
Moveto [Localizacao            ] Example "loc"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Descricao Tipo do Item ] TypeIn "changeto _dtpi"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Moveto [Unidade Embalagem      ] TypeIn "changeto _une"
Moveto [Codigo da Familia      ] TypeIn "changeto _cfam"
Moveto [Descricao da Familia   ] TypeIn "changeto _dfam"
Moveto [Codigo da Marca        ] TypeIn "changeto _cmar"
Moveto [Descricao da Marca     ] TypeIn "changeto _dmar"
Moveto [Codigo de Barras       ] TypeIn "changeto _cbr"
Moveto [Codigo Fornecedor      ] TypeIn "changeto _cfor"
Moveto [Localizacao            ] TypeIn "changeto _loc"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item            ] Example "cite"
Moveto [Fator Conversao Embalagem ] Example "fce"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item            ] Example "cite"
Moveto [Unidade Fiscal            ] Example "unf"
Moveto [Unidade Embalagem         ] TypeIn "not = " Example "unf"
Moveto [Vendas_Quantidade         ] Example "qtd"
Moveto [Vendas_Embalagem          ] TypeIn "changeto _qtd*_fce"
Do_It!
ClearAll

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Embalagem       ] Check TypeIn "Calc Sum as VendasEmbalagem"
Moveto [Saldo_Atual            ] Check TypeIn "Calc Sum as SaldoAtual"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Vendas_Embalagem          ] TypeIn "<=0, changeto blank"
Moveto [Unidade Embalagem         ] TypeIn "changeto Blank"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item            ] Example "cite"
Moveto [Codigo de Barras          ] TypeIn "blank, changeto _cite"
Do_It!
ClearAll

;***** Saldo Atual ************************************
{Ask} {\\Sistemas\\Estoque\\SdEstq}
Moveto [Codigo da Empresa         ] Example "cemp"
Moveto [Codigo do Item            ] Example "cite"
Moveto [Ano Referencia            ] TypeIn "~ANO"
Moveto [Mes Referencia            ] TypeIn "~MES"
Moveto [Saldo Atual               ] Example "saldo"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa         ] Example "cemp"
Moveto [Codigo do Item            ] Example "cite"
Moveto [Saldo_Atual               ] TypeIn "changeto " Example "saldo"
Do_It!
ClearAll


EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_MARCA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DEPART"        : Campo="TG_MARCA"
            Case Campo="TG_DTINI"         : Campo="TG_DEPART"
            Case Campo="TG_HRINI"         : Campo="TG_DTINI"
            Case Campo="TG_DTFIM"         : Campo="TG_HRINI"
            Case Campo="TG_HRFIM"         : Campo="TG_DTFIM"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_HRFIM"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPRELCODALF"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"   :Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_DEPART"
                    Case Campo="TG_DEPART"      : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_HRINI"
                    Case Campo="TG_HRINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_HRFIM"
                    Case Campo="TG_HRFIM"       : Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF" :Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Familia com Saldo de Estoque")
ModeloRelatoriosAdd("02  Por Familia Sem Saldo de Estoque")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA    =""
VSDGDTINI      =Today()-1
VSDGDTFIM      =Today()-1
VSDGOPRELCODALF=""
VSDGMARCA    = ""
VSDGDEPART   = ""

ANO=AlinhM(StrVal(Year(Today())),04)
MES=AlinhM(StrVal(Month(Today())),02)

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Resumo saidas para reposi‡Æo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 17 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP
  
    Label  @ 02,00 "Marca"  For "TG_MARCA"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 03,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA
    
    Label  @ 04,00 "Departamento"  For "TG_DEPART"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_DEPART"    To VSDGDEPART
    Accept @ 05,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMDEPART" To VSDGNOMDEPART    

    Label  @ 06,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 07,04 " de" For "TG_DTINI"
    Accept @ 07,09 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,22 "as" For "TG_DTINI"
    Accept @ 07,26 Width 08 "A5"  Picture "##:##" Tag "TG_HRINI" To VSDGHRINI
    Label  @ 08,04 "at‚" For "TG_DTFIM"
    Accept @ 08,09 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    Label  @ 08,22 "as" For "TG_DTFIM"
    Accept @ 08,26 Width 08 "A5"  Picture "##:##" Tag "TG_HRFIM" To VSDGHRFIM

    Label  @ 00,35 "Op‡„o de Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 10,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 11,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 11,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 13,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 13,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Vendas\\RM_4001" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  switch
    case VSDGCODMODELO="01"  : CopyReport "\\Base\\Sistemas\\Vendas\\Rm_4001"  "R" Tabela "R" 
    case VSDGCODMODELO="02"  : CopyReport "\\Base\\Sistemas\\Vendas\\Rm_4001"  "1" Tabela "R" 
  endswitch
  If VSDGOPRELCODALF="2"         
    Then Seta_Ordem_Report(Tabela,"R","Codigo de Barras","Descricao do Item","")
  EndIf

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
