;** Rm_0105 ********************************************************************
;*  Emissao dos Titulos Recebidos por Representante/Emissao/Pagto              *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 04/12/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 10/02/2014 por Andrey Fillipe
;Motivo Alteracao: Adicionado filtro por tipo de carteira
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/01/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado no filtro a op‡Æo por Data de EmissÆo ou Data de Vencimento 
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Dupbaixa")

  Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
       Moveto [Numero do Lancamento   ] Example "lanc"
       Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
       If VSDGOPDT="1"
          Then Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Else Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       EndIf
       Switch 
         Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
         Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
       EndSwitch 
       {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
       Moveto [Numero do Lancamento] Example "lanc"
       Moveto [Tipo da Baixa       ] TypeIn "Blank or NORMAL"
       Moveto [Data do Pagamento   ] TypeIn ">=~VSDGDTINIP,<=~VSDGDTFIMP"
       Do_It!
       ClearAll
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
  [Valor do Desconto-1]=([Valor do Desconto-1]*-1)+[Valor do Juros]
  If IsBlank([Valor do Desconto-1]) Then [Valor do Desconto-1]=0 EndIf
EndScan
Do_It!
ClearAll
EndProc  ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPCART"
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_OPDT"          : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI"         : Campo="TG_OPDT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DTINIP"        : Campo="TG_DTFIM"
            Case Campo="TG_DTFIMP"        : Campo="TG_DTINIP"
            Case Campo="TG_TPCART"        : Campo="TG_DTFIMP"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"     : Campo="TG_OPDT"
                    Case Campo="TG_OPDT"         : Campo="TG_DTINI"
                         VSDGOPDT=ControlValue("TG_OPDT")
                         Switch
                           Case VSDGOPDT="2": VSDGDESCOPDT="DATA DE VENCIMENTO"
                           OtherWise        : VSDGOPDT="1"
                                              VSDGDESCOPDT="DATA DE EMISSAO"
                         EndSwitch  
                    Case Campo="TG_DTINI"        : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"        : Campo="TG_DTINIP"
                    Case Campo="TG_DTINIP"       : Campo="TG_DTFIMP"
                         VSDGDTINIP=ControlValue("TG_DTINIP")
                    Case Campo="TG_DTFIMP"       :
                         VSDGDTFIMP=ControlValue("TG_DTFIMP")
                         If Not Isblank(VSDGDTFIMP)
                            Then Campo="TG_TPCART"
                         EndIf
                    Case Campo="TG_TPCART"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
     MSG_CAMPO="Informe o Numero de Dias"
  Case Campo="TG_DTINIP":
     MSG_CAMPO="Em Branco = Data desde do Inicio"
  Case Campo="TG_DTFIMP":
     MSG_CAMPO="Informe a Data Final"
Case Campo="TG_OPDT":
       MSG_CAMPO="Op‡„o: 1= Emiss„o  2= Vencimento"     
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
                     
VSDGEMPRESA   =""
VSDGREPRESEN  =""
VSDGTPCART    =""
VSDGNOMCART   =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
VSDGDTINIP  =BlankDate()
VSDGDTFIMP  =BlankDate()

ListaRegra_TGAtivado="[TG_TPCART]"

While True
  ShowDialog "Recebidos por Representante/Emiss„o/Pagto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"   
   @ 05,12   Height 15 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR

    Label  @ 04,00 "Op‡„o de Datas" For "TG_OPDT"
    Accept @ 05,04 Width 04 "A1"  Picture "1,2" Tag "TG_OPDT" To VSDGOPDT
    Accept @ 05,09 Width 25 "A20"  Picture "!*!" Tag "TG_DESCOPDT" To VSDGDESCOPDT

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
               
    Label  @ 08,00 "Per¡odo Pagamento de" For "TG_DTINIP"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINIP" To VSDGDTINIP
    Label  @ 09,16 "at‚" For "TG_DTFIMP"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIMP" To VSDGDTFIMP
               
    Label  @ 00,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 01,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 01,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue


  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate() Or
     VSDGDTFIMP=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  If VSDGOPDT="1"
     Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010" "2" Tabela "R"
     Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010c" "2" Tabela "R" 
  EndIf    

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile         
ClearAll
Release Vars All
Release Procs All
