;** Rm_0020b *******************************************************************
;*  Emissao dos Titulos a Pagar por Data de Vencimento/Emitentes                     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 08/24/2009 por Nikolas
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE  
;Ultima Alteracao: 03/01/2017 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog MensagemRadioButtons()               
;Ultima Alteracao: 01/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de pagamento

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       Moveto [Saldo do Documento] TypeIn ">= 0.01 "
       Switch
         Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
         Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
       EndSwitch     
       Do_it!
       ClearAll
EndIf
EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                      *
;*******************************************************************************
Proc Seleciona2()
If OPCHEQ<>"S"
   Then Return
EndIf

{Ask} {\\sistemas\\ctacor\\MovCont}
Moveto [Numero do Lancamento  ] CheckPlus
Moveto [Codigo da Conta       ] CheckPlus
Moveto [Descricao da Conta    ] CheckPlus
Moveto [Codigo da Empresa     ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Nome Fantasia Empresa ] CheckPlus
Moveto [Tipo Movimento        ] TypeIn "S"
Moveto [Tipo de Operacao      ] TypeIn "05"
Moveto [Valor                 ] CheckPlus
Moveto [Codigo do EmitDest    ] CheckPlus
Moveto [Nome Fantasia EmitDest] CheckPlus
Moveto [Razao Social          ] CheckPlus
Moveto [Codigo do Documento   ] CheckPlus
Moveto [Tipo do Documento     ] CheckPlus
Moveto [Serie do Documento    ] CheckPlus
Moveto [Numero do Documento   ] CheckPlus
Moveto [Numero do Cheque      ] CheckPlus
Moveto [Serie do Cheque       ] CheckPlus
Moveto [Cheque Pre-Datado     ] TypeIn "S"
Moveto [Data Cheque Descontado] TypeIn "Blank"
Moveto [Data                  ] CheckPlus
Moveto [Data Cheque Pre-Datado] CheckPlus TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero do Lancamento  ] Example "lanc"
Moveto [Codigo da Conta       ] Example "cont"
Moveto [Descricao da Conta    ] Example "dcont"
Moveto [Codigo da Empresa     ] Example "cod"
Moveto [Nome Fantasia Empresa ] Example "ncod"
Moveto [Valor                 ] Example "vr"
Moveto [Codigo do EmitDest    ] Example "cemi"
Moveto [Nome Fantasia EmitDest] Example "nemi"
Moveto [Razao Social          ] Example "emit"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tpdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Numero do Cheque      ] Example "numc"
Moveto [Serie do Cheque       ] Example "serc"
Moveto [Data                  ] Example "data"
Moveto [Data Cheque Pre-Datado] Example "dat"

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero do Lancamento  ] Example "lanc"
Moveto [Codigo da Conta       ] Example "cont"
Moveto [Descricao da Conta    ] Example "dcont"
Moveto [Codigo da Empresa     ] Example "cod"
Moveto [Nome Fantasia Empresa ] Example "ncod"
Moveto [Codigo do Emitente    ] Example "cemi"
Moveto [Nome Fantasia EmitDest] Example "nemi"
Moveto [Razao Social          ] Example "emit"
Moveto [Codigo do Documento   ] Example "cdoc"
Moveto [Tipo do Documento     ] Example "tpdoc"
Moveto [Serie do Documento    ] Example "sdoc"
Moveto [Numero do Documento   ] Example "ndoc"
Moveto [Valor do Documento    ] Example "vr"
Moveto [Saldo do Documento    ] Example "vr"
Moveto [Data de Vencimento    ] Example "dat"
Moveto [Data de Emissao       ] Example "data"
Moveto [Data a Pagar          ] Example "dat"
Moveto [Tipo do Lancamento    ] TypeIn "0"
Moveto [Descricao do Lancamento] TypeIn "_numc+"+"\" - \"+"+"_serc"
Do_It!
ClearAll

CoEdit Tabela
Scan
  If [Tipo do Lancamento     ]="0"
     Then [Observacoes       ]="[CHQPRE] "+[Descricao do Lancamento]
     Else [Tipo do Lancamento]=""
  EndIf
EndScan
Do_It!

ClearAll

EndProc  ; (Seleciona2)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
   If ([Data a Pagar]<Today()) And (Not IsBlank([Data a Pagar]))
      Then NDA=Today()-[Data a Pagar]
           TXM=[Multa]
      Else NDA=0
           TXM=0
   EndIf
   If [Data Limite Desconto] >= Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)
   [Data de Vencimento]=[Data a Pagar]
EndScan
Do_It!
ClearAll
EndProc   ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_TPPAGTO"       : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"         : Campo="TG_TPPAGTO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPCHEQ"        : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_OPCHEQ"
                    Case Campo="TG_OPCHEQ"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
Case Campo="TG_OPCHEQ":
    MensagemRadioButtons()
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA=""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

Array TG_OPCHEQ[1]
TG_OPCHEQ[1]="Incluir Cheques n„o Apresentados/Pre-Datados"

Array CheckTG_OPCHEQ[ArraySize(TG_OPCHEQ)]
CheckTG_OPCHEQ[1]=False

ListaRegra_TGAtivado="[TG_TPPAGTO]"

While True
  ShowDialog "Pagar por Data de Vencimento/Emitente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"  
   @ 09,12   Height 16 Width 66

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 1,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 1,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,02 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 03,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 03,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 04,00 "Periodo Referente" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "at‚" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Frame Single From 06,00 to 11,60

    Label @ 07,01 "Op‡”es" For "TG_OPCHEQ"
    RadioButtons @ 08,01 Height 3 Width 55
      "~1~ Normal",
      "~2~ Incluir Cheques n„o Apresentados/Pre-Datados I",
      "~3~ Incluir Cheques n„o Apresentados/Pre-Datados II"
        Tag "TG_OPCHEQ"
        To VSDGOPCHEQ

    Pushbutton @ 12,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()

  If OK="" Then Loop EndIf
  If VSDGOPCHEQ<>1
     Then OPCHEQ="S"
     Else OPCHEQ="N"
  EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  Seleciona2()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  If VSDGOPCHEQ=1 Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "4" Tabela "R" EndIf
  If VSDGOPCHEQ=2 Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "3" Tabela "R" EndIf
  If VSDGOPCHEQ=3 Then CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1001" "4" Tabela "R" EndIf

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
