;** Rm_0085 ********************************************************************
;*  Emissao dos Titulos a Receber por Cliente/DtEmissao                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 17/05/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 19/01/2011 por Bruno Carvalho
;Motivo Alteracao: Adicionado Op‡Æo de Relatorio e Filtro por "Protestar"
;Ultima Alteracao: 16/08/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes opcao de data de vencimento  
;Ultima Alteracao: 12/11/2011 por Bruno Carvalho
;Motivo Alteracao: Adicionado Relat¢rio Op‡Æo 3 "Documentos"
;Ultima Alteracao: 06/09/2012 por kamila Gomes  
;Motivo Alteracao: Adicionado filtro por cobrador
;Ultima Alteracao: 15/08/2013 por Bruno Carvalho  
;Motivo Alteracao: Ajustes Op‡„o do Relat¢rio "3"
;Ultima Alteracao: 13/11/2013 por Andrey Fillipe  
;Motivo Alteracao: Alterado report, ordenar por ordem de data
;Ultima Alteracao: 04/07/2015 por Kamila Gomes 
;Motivo Alteracao: Incluido op‡Æo de relatorio com saldo anterior por data de Emissao
;Ultima Alteracao: 08/07/2015 por Kamila Gomes 
;Motivo Alteracao: Ajustes no saldo anterior por data de Emissao
;Ultima Alteracao: 16/07/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado filtro por Numero do Carregamento
;Ultima Alteracao: 15/03/2016 por Kamila Gomes
;Motivo Alteracao: Ajustes na Op‡„o do Relat¢rio "3" para sair valores de datas m‚dias
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT 
;Ultima Alteracao: 03/01/2017 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog MensagemRadioButtons()                
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 25/09/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modelo 03                        
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 08/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0088" (82) neste script "RM_0085" (22)
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona(PARAM)
Private PARAM
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
       Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo do Destinatario  ] TypeIn "~VSDGDESTINAT.."
       If PARAM = 2
          Then If Not IsBlank(VSDGDTINI)
                  Then Moveto [Data de Emissao] TypeIn "<~VSDGDTINI"
               EndIf
          Else Moveto [Data de Emissao ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       EndIf
       Moveto [Saldo do Documento      ] TypeIn "> 0.01"
       Switch                                                                                        
         Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
         Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
       EndSwitch      
       Moveto [Codigo do Cobrador      ] TypeIn "~VSDGCOBRADOR.."
       If VSDGOPDTV=1
          Then Moveto [Data de Vencimento] TypeIn "<=~VSDGDTREF"
       EndIf
       Moveto [Numero_Carregamento_Orig] TypeIn "~VSDGNCARREG.."   
       Do_It!
       ClearAll
EndIf

If PARAM = 2 And Not IsEmpty("Answer") 
   Then {Ask} TypeIn Tabela Enter
        Moveto [Valor da Comissao] TypeIn "Changeto 0.00"
        Do_It!
        ClearAll
   
        If Not IsBlank(VSDGDTINI)
           Then Processa("Answer")
   
                {Ask} {Answer}
                Moveto [Codigo do Destinatario] Check
                Moveto [Valor do Documento    ] TypeIn "Calc Sum as Valor do Documento"
                Do_It!
                ClearAll
                
                {Ask} {Answer}
                Moveto [Codigo do Destinatario] Check Example "a"
                Moveto [Valor do Documento    ] Check
                {Ask} TypeIn Tabela Enter
                Moveto [Codigo do Destinatario] Example "a"
                Do_It!
                ClearAll
                
                
                View Tabela
                Coedit "Answer"
                Scan
                  COD = [Codigo do Destinatario]
                  
                  Moveto Tabela
                  Moveto [Codigo do Destinatario]
                  Locate COD
                  If RetVal
                     Then [Valor da Comissao] = [Answer->Valor do Documento]
                  EndIf    
                
                  Moveto "Answer"
                EndScan
                Do_It!
                ClearAll
        EndIf 
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona_RM0088()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
       Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo do Destinatario] TypeIn "~VSDGDESTINAT.."
       Moveto [Data de Emissao       ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       Moveto [Saldo do Documento    ] TypeIn "> 0.01"
       Switch                                                                                        
         Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
         Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
       EndSwitch
       Moveto [Codigo do Cobrador     ] TypeIn "~VSDGCOBRADOR.."
       If VSDGOPDTV=1
          Then Moveto [Data de Vencimento] TypeIn "<=~VSDGDTREF"
       EndIf   
       Do_It!
       ClearAll
EndIf

EndProc ;Seleciona_RM0088()

;*******************************************************************************
;* Rotina p/ Selecionar os Vencimentos                                         *
;*******************************************************************************
Proc SelecionaE()

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa     ] Check
Moveto [Codigo do Destinatario] Check
Moveto [Data de Vencimento    ] Check
Moveto [Data de Emissao       ] TypeIn "Calc Average as Data de Emissao"

Do_It!
ClearAll

View "Answer"
Coedit Tabela
Scan
  CODEMP = [Codigo da Empresa]
  CODDES = [Codigo do Destinatario]
  
  Moveto "Answer"
  Moveto [Codigo da Empresa]
  Locate CODEMP,CODDES
  If RetVal
     Then  Moveto Tabela 
           Moveto [Data Limite Desconto]
           []=[Answer->Data de Emissao]
           UnLockRecord
  EndIf
EndScan
Do_It!
ClearAll

EndProc   ; (SelecionaE)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa_RM0088()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Codigo do Cobrador    ] TypeIn "Changeto Blank"
Down
Moveto [Descricao do Cobrador ] TypeIn "Changeto Blank"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter Check
Moveto [Codigo do Destinatario] Example "CodD"
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                ] Example "CodD"
Moveto [Codigo da Area        ] Check TypeIn "~VSDGAREA.."
Moveto [Descricao da Area     ] Check
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero do Lancamento  ] Example "NumL"
Moveto [Codigo do Destinatario] Example "CodD"
Moveto [Codigo da Area        ] Example "CodB"
Moveto [Descricao da Area     ] Example "DesB"
{Ask} TypeIn Tabela Enter
Moveto [Numero do Lancamento  ] Example "NumL"
Moveto [Codigo do Destinatario] Example "CodD"
Moveto [Codigo do Cobrador    ] TypeIn "Changeto _CodB"
Moveto [Descricao do Cobrador ] TypeIn "Changeto _DesB"
Do_It!
ClearAll

If VSDGAREA<>""
   Then {Ask} TypeIn Tabela Enter "Delete"
        Moveto [Codigo do Cobrador] TypeIn "Blank" 
        Do_It!
        ClearAll
EndIf

EndProc ;Processa_RM0088()

;*******************************************************************************
;* Rotina p/ processar Db Temporaria  2                                        *
;*******************************************************************************
Proc Processa2_RM0088()
Private CODDES,i,Array_Cod
 
CODDES="***"
DynArray Array_Cod[]
i=0

Sort Tabela On "Codigo do Destinatario"
Do_It!
ClearAll

CoEdit Tabela
Moveto [Codigo do Destinatario]
Scan
  If [Codigo do Destinatario] <> CODDES
     Then i=i+1
          CODDES       = [Codigo do Destinatario]
          Array_Cod[i] = Format("W4",CODDES)+[Numero do Documento]
    Else Array_Cod[i] = Array_Cod[i]+", "+[Numero do Documento]
  EndIf  
EndScan
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter 
Moveto [Codigo da Empresa     ] Check
Moveto [Nome Fantasia Empresa ] Check
Moveto [Codigo do Cobrador    ] Check
Moveto [Descricao do Cobrador ] Check
Moveto [Codigo do Destinatario] Check
Moveto [Razao Social          ] Check
Moveto [Observacoes           ] Check
Moveto [Valor do Documento    ] Check
Moveto [Saldo do Documento    ] Check
Moveto [Valor do Desconto     ] Check
Do_It!
ClearAll

Copy "Answer" Tabela
Empty Tabela

CODDES="***"
i=0

Sort "Answer" On "Codigo do Destinatario"
Do_It!
ClearAll

View Tabela
CoEdit "Answer"
Moveto [Codigo do Destinatario]
Scan
    If [Codigo do Destinatario] <> CODDES
       Then i=i+1
            CODDES                   = SubStr(Array_Cod[i],1,4)
            
            Moveto Tabela
            End
            Down
            [Codigo da Empresa     ] = [Answer->Codigo da Empresa     ] 
            [Nome Fantasia Empresa ] = [Answer->Nome Fantasia Empresa ]
            [Codigo do Cobrador    ] = [Answer->Codigo do Cobrador    ]
            [Descricao do Cobrador ] = [Answer->Descricao do Cobrador ] 
            [Codigo do Destinatario] = [Answer->Codigo do Destinatario] 
            [Razao Social          ] = [Answer->Razao Social          ] 
            [Valor do Documento    ] = [Answer->Valor do Documento    ] 
            [Saldo do Documento    ] = [Answer->Saldo do Documento    ] 
            [Valor do Desconto     ] = [Answer->Valor do Desconto     ] 
            [Observacoes           ] = SubStr(Array_Cod[i],5,Len(Array_Cod[i])-4)
       Else Moveto Tabela
            Moveto [Codigo do Destinatario]
            Locate CODDES
            If RetVal
               Then [Valor do Documento    ] = [Valor do Documento]+[Answer->Valor do Documento]
                    [Saldo do Documento    ] = [Saldo do Documento]+[Answer->Saldo do Documento]  
                    [Valor do Desconto     ] = [Valor do Desconto ]+[Answer->Valor do Desconto ]
            EndIf        
    EndIf  
    Moveto "Answer"
EndScan
Do_It!
ClearAll

EndProc ;Processa2_RM0088()

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa(TabelaRef)

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn TabelaRef Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit TabelaRef
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)
   UnLockRecord
EndScan
Do_It!
ClearAll

If VSDGOPRELANALSINT="2"
   Then {Ask} TypeIn TabelaRef Enter Check
        Moveto [Observacoes] TypeIn "Protestar"
        Do_It!
        ClearAll

        Rename "Answer" TabelaRef 
EndIf

EndProc     ; (Processa)

;*******************************************************************************
;* Agrupa Desdobramentos                                                       *
;*******************************************************************************
Proc Agrupa()

Coedit Tabela
Scan
  If [Tipo Docto Gerador]<>"" And [Numero Docto Gerador]<>""
     Then [Documento Referente]=[Tipo Docto Gerador]+"/"+[Numero Docto Gerador]
          UnLockRecord
  EndIf
EndScan
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter 
Moveto [Codigo da Empresa      ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Razao Social           ] Check
Moveto [Codigo do Destinatario ] Check
Moveto [Documento Referente    ] Check                        
Moveto [Data de Emissao        ] Check
Moveto [Valor do Documento     ] TypeIn "Calc Sum as Valor do Documento"
Moveto [Saldo do Documento     ] TypeIn "Calc Sum as Saldo do Documento"
Moveto [Valor do Desconto      ] TypeIn "Calc Sum as Valor do Desconto"
Moveto [Codigo da Conta        ] Check
Moveto [Codigo do Representante] Check
Moveto [Descricao do Lancamento] Check
Moveto [Tipo do Pagamento      ] Check
Do_It!
ClearAll            

Empty Tabela
{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "CodE"
Moveto [Nome Fantasia Empresa  ] Example "NomF"
Moveto [Razao Social           ] Example "RazS"
Moveto [Codigo do Destinatario ] Example "CodD"
Moveto [Documento Referente    ] Example "DocR"
Moveto [Data de Emissao        ] Example "DatE"
Moveto [Valor do Documento     ] Example "VrDo"
Moveto [Saldo do Documento     ] Example "SlDo"
Moveto [Valor do Desconto      ] Example "VrDe"
Moveto [Codigo da Conta        ] Example "CodC"
Moveto [Codigo do Representante] Example "CodP"
Moveto [Descricao do Lancamento] Example "DesL"
Moveto [Tipo do Pagamento      ] Example "TipP"

{Ask} TypeIn Tabela Enter TypeIn "Insert"
Moveto [Codigo da Empresa      ] Example "CodE"          
Moveto [Nome Fantasia Empresa  ] Example "NomF"          
Moveto [Razao Social           ] Example "RazS"          
Moveto [Codigo do Destinatario ] Example "CodD"          
Moveto [Documento Referente    ] Example "DocR"          
Moveto [Data de Emissao        ] Example "DatE"          
Moveto [Valor do Documento     ] Example "VrDo"          
Moveto [Saldo do Documento     ] Example "SlDo"          
Moveto [Valor do Desconto      ] Example "VrDe"          
Moveto [Codigo da Conta        ] Example "CodC"          
Moveto [Codigo do Representante] Example "CodP"          
Moveto [Descricao do Lancamento] Example "DesL"          
Moveto [Tipo do Pagamento      ] Example "TipP"          
Do_It!
ClearAll
   
EndProc ;Agrupa()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPCART"         
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_NCARREG"       : Campo="TG_EMPRESATE"
            Case Campo="TG_COBRADOR"      : Campo="TG_NCARREG"
            Case Campo="TG_DESTINAT"      : Campo="TG_COBRADOR"
            Case Campo="TG_DESTINAT"      : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_AREA"          : Campo="TG_DTFIM"  
            Case Campo="TG_DDPROTESTO"    : Campo="TG_AREA"
            Case Campo="TG_TPCART"        : Campo="TG_DDPROTESTO"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_TPCART"
            Case Campo="TG_OPDTV"         : Campo="TG_OPRELANALSINT"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPRELANALSINT" 
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG"       : Campo="TG_COBRADOR"
                    Case Campo="TG_COBRADOR"      : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"      : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_AREA" 
                    Case Campo="TG_AREA"          : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO"    : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"        : Campo="TG_OPRELANALSINT"
                    Case Campo="TG_OPRELANALSINT" : Campo="TG_OPDTV"
                         VSDGOPRELANALSINT=ControlValue("TG_OPRELANALSINT")
                         If IsBlank(VSDGOPRELANALSINT) Then VSDGOPRELANALSINT="1" EndIf
                         Switch
                           Case VSDGOPRELANALSINT="1" : VSDGNOMOPRELANALSINT="Completo"
                           Case VSDGOPRELANALSINT="2" : VSDGNOMOPRELANALSINT="Protestar"
                           Case VSDGOPRELANALSINT="3" : VSDGNOMOPRELANALSINT="Documento"
                         EndSwitch
                    Case Campo="TG_OPDTV"         : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES" 
                        Switch
                           Case VSDGCODMODELO="02": 
                                VSDGOPRELANALSINT    = "1"
                                VSDGNOMOPRELANALSINT = "Completo"
                       EndSwitch
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO"    :
     MSG_CAMPO="Informe o Numero de Dias"
  Case Campo="TG_OPRELANALSINT" : 
     MSG_CAMPO="1=COMPLETO  2=PROTESTAR  3=DOCUMENTO"  
  Case Campo="TG_OPDTV":
       MensagemRadioButtons()
  Case Campo="" :
       MSG_CAMPO=""   
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Data de EmissÆo/Cliente/T¡tulo")
ModeloRelatoriosAdd("03  Conta/Data de EmissÆo/T¡tulo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Cliente/Data de EmissÆo - Com Saldo Anterior")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("82A Anal¡tico por Area/Cliente/Data de EmissÆo")
ModeloRelatoriosAdd("82B Sint‚tico por Area/Cliente/Data de EmissÆo")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA    = ""
VSDGCOBRADOR   = ""
VSDGDESTINAT   = ""
VSDGTPCART     = ""
VSDGDDPROTESTO = ""
VSDGDTINI      = BlankDate()
VSDGDTFIM      = BlankDate()
VSDGDTREF      = Today()-1
VSDGNCARREG    = ""
VSDGNOMNCARREG = ""

ModeloRelatoriosCarregaLista()

ListaRegra_TGAtivado="[TG_TPCART]"   

While True
  ShowDialog "Titulos a Receber por Cliente/DtEmissao" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"
          
   @ 05,12   Height 18 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
    
    Label  @ 02,00 "Carregamento" For "TG_NCARREG"
    Accept @ 03,01 Width 9  "A6"  Picture "[&,#][#*#]" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG
    
    Label  @ 04,00 "Cobrador"  For "TG_COBRADOR"
    Accept @ 05,01 Width 07 "A2"  Picture "[&,#][#*#]" Tag "TG_COBRADOR" To VSDGCOBRADOR
    Accept @ 05,09 Width 25 "A30"  Picture "!*!" Tag "TG_NOMCOBRADOR" To VSDGNOMCOBRADOR

    Label  @ 06,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Area"  For "TG_AREA"
    Accept @ 01,38 Width 05 "A2"  Picture "#*#" Tag "TG_AREA"  To VSDGAREA
    Accept @ 01,44 Width 25 "A30" Picture "!*!" Tag "TG_NOMAREA" To VSDGNOMAREA

    Label  @ 02,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 03,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 03,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 04,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 05,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 05,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Label  @ 06,35 "Op‡„o do Relat¢rio" For "TG_OPRELANALSINT"
    Accept @ 07,39 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 07,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELANASINT" To VSDGNOMOPRELANALSINT 
    
    Label @ 08,35 "Op‡„o vencimento " For "TG_OPDTV"
    RadioButtons @ 09,35 Height 5 Width 33
      "~1~=Vencidos at‚ "+Format("D13",VSDGDTREF),
      "~2~=Todos a receber"
        Tag "TG_OPDTV"
        To VSDGOPDTV

    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    If VSDGCODMODELO="82A" Or VSDGCODMODELO="82B"
       Then Seleciona_RM0088()
       Else Seleciona(1)
    EndIf    
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
                   
  If VSDGCODMODELO="82A" Or VSDGCODMODELO="82B"
     Then Processa_RM0088()
          If IsEmpty(Tabela)
             Then MENSAGEM("N„o existem registros a processar")
                  Delete Tabela
                  Loop
          EndIf
          If VSDGCODMODELO="82B"
             Then Processa2_RM0088()
          EndIf  
     Else Processa(Tabela)
          SelecionaE()
          Seleciona(2)
          If IsEmpty(Tabela)
             Then MENSAGEM("N„o existem registros a processar")
                  Delete Tabela
                  Loop
          EndIf
  EndIf        

  switch
    case VSDGCODMODELO="01" :
                      If VSDGOPRELANALSINT="3"
                         Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001B" "5" Tabela "R"
                         Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "R"  Tabela "R"
                      EndIf
    
    case VSDGCODMODELO="02"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000a" "4"   Tabela "R"
    case VSDGCODMODELO="03"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001b" "13"  Tabela "R"
    case VSDGCODMODELO="82A" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000a" "R"  Tabela "R"
    case VSDGCODMODELO="82B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000a" "3"  Tabela "R"
  endswitch
  
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All