;** Rm_0022  *******************************************************************
;* Relacao de Of nÆo faturadas                                                 *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/08/2010 por Anivel Augusto Rodrigues
;Ultima Alteracao: 14/10/2011 por Karina Andrade
;Motivo Alteracao: Inclusao de filtro Op‡Æo de Data
;Ultima Alteracao: 01/10/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes OF sem item                
;Ultima Alteracao: 24/03/2014 por Kamila Gomes
;Motivo Alteracao: Ajustes op‡Æo com Item
;Ultima Alteracao: 08/07/2015 por Kamila Gomes
;Motivo Alteracao: InclusÆo de filtro por destina‡Æo
;Ultima Alteracao: 29/10/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado Usuario que fez a ultima alteracao
;Ultima Alteracao: 21/07/2016 por Bruno Carvalho 
;Motivo Alteracao: Adicionado op‡Æo de quebra por cliente *Op‡Æo no Filtro 
;Ultima Alteracao: 19/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao data de saida             
;Ultima Alteracao: 29/08/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro Seleciona()        
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog 
;Ultima Alteracao: 20/03/2017 por Rafael Matos
;Motivo Alteracao: Incluso campo OBSERVA€ÇO nos reports          
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 30/05/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado Relatorio 04                
;Ultima Alteracao: 10/02/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_DESTIN, TG_TPMOVDESTIN                  

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {FaturaC} Check
Moveto [Numero da OF           ] Example "Docto"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."

switch
  case VSDGTPDATA="1" : Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
  case VSDGTPDATA="2" : Moveto [Data_Inclusao          ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
  case VSDGTPDATA="3" : Moveto [Data de Saida          ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
endswitch

Moveto [Codigo                 ] TypeIn "~VSDGCLIENTE.."
Moveto [Numero_Carregamento    ] TypeIn "~VSDGNCARREG.." 
switch
 case ListaRegra_VSDGDESTIN_Ativo  : Moveto [Codigo da Destinacao] TypeIn ListaRegra_VSDGDESTIN
 otherwise                         : Moveto [Codigo da Destinacao] TypeIn "~VSDGDESTIN.."
endswitch
Moveto [Tipo Movimento Estoque ] TypeIn "~VSDGTPMOVDESTIN.."
Moveto [Numero Nota Gerada     ] TypeIn "Blank"

If VSDGCSITENS="C"
   Then {Ask} {FaturaI} Check
        Moveto [Numero da OF           ] Example "Docto"
EndIf
Do_It!
ClearAll

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina Ajusta Dados                                                         *
;*******************************************************************************
Proc Ajusta_Dados()
ClearAll

If VSDGCSITENS="C"
   Then If VSDGOPREL2="1"
           Then Sort "Answer" On "Codigo da Empresa", "Numero da OF","Item da OF"
           Else Sort "Answer" On "Codigo da Empresa", "Codigo", "Numero da OF","Item da OF"
        EndIf   
   Else If VSDGOPREL2="1"
          Then Sort "Answer" On "Codigo da Empresa", "Numero da OF"
          Else Sort "Answer" On "Codigo da Empresa", "Codigo", "Numero da OF"
        EndIf  
EndIf

NDOCTO="****"
CoEdit "Answer"
Scan
 If [Numero da OF]<>NDOCTO 
    Then NDOCTO=[Numero da OF       ]
    Else [Valor Nota Fiscal]=BlankNum()
         [Peso Bruto       ]=BlankNum()
 EndIf
EndScan
Do_It!
ClearAll

EndProc
;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60: ListaRegra_F2()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_NCARREG"       : Campo="TG_EMPRESA"
            Case Campo="TG_DESTIN"        : Campo="TG_NCARREG"
            Case Campo="TG_TPMOVDESTIN"   : Campo="TG_DESTIN"
            Case Campo="TG_CLIENTE"       : Campo="TG_TPMOVDESTIN" 
            Case Campo="TG_DTINI"         : Campo="TG_CLIENTE"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_TPDATA"        : Campo="TG_DTFIM"            
            Case Campo="TG_CSITENS"       : Campo="TG_TPDATA"
            Case Campo="TG_CODMODELO"     : Campo="TG_CSITENS"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG" : Campo="TG_DESTIN" 
                    Case Campo="TG_DESTIN"        : Campo="TG_TPMOVDESTIN"
                    Case Campo="TG_TPMOVDESTIN"   : Campo="TG_CLIENTE"
                    Case Campo="TG_CLIENTE" : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   : Campo="TG_TPDATA"
                    Case Campo="TG_TPDATA"  :
                      VSDGTPDATA=ControlValue("TG_TPDATA")
                      switch
                        case VSDGTPDATA="2" : VSDGNOMTPDATA="DATA DE INCLUSAO" 
                        case VSDGTPDATA="3" : VSDGNOMTPDATA="DATA DE SAIDA"
                        Otherwise           : VSDGNOMTPDATA="DATA DE EMISSAO"
                                              VSDGTPDATA   ="1"
                      endswitch
                      Campo="TG_CSITENS"
                      
                    Case Campo="TG_CSITENS" : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"  
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPREL2" :
       MSG_CAMPO="1 = POR DESTINACAO  2 = POR CLIENTE"
  Case Campo="TG_TPDATA" :
       MSG_CAMPO="1 = EMISSAO  2 = INCLUSAO  3 = SAIDA"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Destina‡ao")
ModeloRelatoriosAdd("02  Por Cliente")
ModeloRelatoriosAdd("03  Por Carregamento")
ModeloRelatoriosAdd("04  UF/Cidade - Dados para cota‡Æo de frete")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
SYS_VALOR()
LimpAguarde()

VSDGEMPRESA   = ""
VSDGCSITENS   = ""
VSDGDTINI     = BlankDate()
VSDGDTFIM     = BlankDate()
VSDGNCARREG   = ""
VSDGOPREL2    = ""
VSDGNOMOPREL2 = ""
VSDGDESTIN  =""
VSDGTPMOVDESTIN=""

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_DESTIN]")

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Rela‡„o Ordem de Faturamento nÆo efetuada" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60  
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Carregamento" For "TG_NCARREG"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG
    
    Label  @ 04,00 "Destinacao"  For "TG_DESTIN"
    Accept @ 05,02 Width 06 "A3"  Picture "[&,#][#*#]" Tag "TG_DESTIN"    To VSDGDESTIN
    Accept @ 05,09 Width 21 "A30" Picture "!*!" Tag "TG_NOMDESTIN" To VSDGNOMDESTIN

    Label  @ 04,28 "TpMov" For "TG_TPMOVDESTIN"
    Accept @ 05,30 Width 04 "A1"  Picture "E,S" Tag "TG_TPMOVDESTIN" To VSDGTPMOVDESTIN

    Label  @ 06,00 "Cliente"  For "TG_CLIENTE"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_CLIENTE" To VSDGCLIENTE
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLIE"  To VSDGNOMCLIE

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 00,35 "Op‡äes de Datas" For "TG_TPDATA"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3"  Tag "TG_TPDATA"     To VSDGTPDATA
    Accept @ 01,44 Width 25 "A18" Picture "!*!"  Tag "TG_NOMTPDATA" To VSDGNOMTPDATA

    Label  @ 02,35 "Op‡„o p/ Itens" For "TG_CSITENS"
    Accept @ 03,39 Width 04 "A1"  Picture "S,C" Tag "TG_CSITENS" To VSDGCSITENS
    Accept @ 03,44 Width 25 "A20"  Picture "!*!" Tag "TG_NOMCSITENS" To VSDGNOMCSITENS
    
    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO 
    
    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Seleciona()
  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Delete "Answer"
          Loop
  EndIf
  Ajusta_Dados()
  
  Switch
    case VSDGCODMODELO="01" : If VSDGCSITENS="C" Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "R" "Answer" "R"     
                                                 Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "1" "Answer" "R"
                              EndIf                   
    case VSDGCODMODELO="02" : If VSDGCSITENS="C" Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "4" "Answer" "R"
                                                 Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "5" "Answer" "R"
                              EndIf                   
    case VSDGCODMODELO="03" : If VSDGCSITENS="C" Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "6" "Answer" "R" 
                                                 Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "7" "Answer" "R"
                              EndIf                   
    case VSDGCODMODELO="04" : If VSDGCSITENS="C" Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "8" "Answer" "R" 
                                                 Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_2002" "9" "Answer" "R"
                              EndIf                   
  EndSwitch

  
  IMPRIREL("Answer","R")
  Delete "Answer"

EndWhile
ClearAll

Release Vars All
Release Procs All
