;** Rm_0232  *******************************************************************
;*  Emissao dos Titulos a Receber por Cliente/Vencto                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 03/12/1999 por Anivel Augusto Rodrigues
;Ultima Alteracao: 14/05/2003 por Karen Lauar Nery
;Motivo Alteracao: Mudan‡a Base
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 08/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0232B" (37), "RM_0232C" (46), "RM_0233B" (54) neste script "RM_0232" (36)
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "cli"
Switch 
  Case VSDGCODMODELO="46"   : Moveto [Codigo da Area         ] Check TypeIn "~VSDGAREA.."
                              Moveto [Descricao da Area      ] Check 
                              Moveto [Codigo da Rota         ]       TypeIn "~VSDGROTA.."
                              Moveto [Cidade                 ] Check
  Case VSDGCODMODELO="54A" Or 
       VSDGCODMODELO="54B" Or 
       VSDGCODMODELO="54C" Or 
       VSDGCODMODELO="54D"  : 
                              Moveto [UF                     ] Check
                              Moveto [Cidade                 ] Check
                              Moveto [Codigo da Area         ]       TypeIn "~VSDGAREA.."
                              Moveto [Codigo da Rota         ] Check TypeIn "~VSDGROTA.."
                              Moveto [Descricao da Rota      ] Check
  OtherWise                 : Moveto [Cidade                 ] Check
                              Moveto [Codigo da Area         ]       TypeIn "~VSDGAREA.."
                              Moveto [Codigo da Rota         ]       TypeIn "~VSDGROTA.."
EndSwitch

{Ask} {Duplic} Check
Moveto [Codigo do Destinatario ] Example "cli"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Data de Vencimento     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Saldo do Documento     ] TypeIn "> 0.01"
Moveto [Codigo da Conta        ] TypeIn "~VSDGCONTA.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
If (VSDGCODMODELO="54A" Or VSDGCODMODELO="54B" Or VSDGCODMODELO="54C" Or VSDGCODMODELO="54D") And VSDGTPPAGTO=""
   Then Moveto [Tipo do Pagamento] TypeIn "Not \"BO\", Not \"CO\", Not \"DP\""
   Else Switch
          Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
          Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
        EndSwitch    
EndIf
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

Coedit "Answer"
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   
   If VSDGCODMODELO<>"54A" And VSDGCODMODELO<>"54B" And VSDGCODMODELO<>"54C" And VSDGCODMODELO<>"54D"  
      Then If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
              Then If [Descricao do Lancamento]="PROTESTADA"
                      Then [Observacoes]="Cartorio"
                      Else [Observacoes]="Protestar"
                   EndIf
          EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf
   
   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll

If VSDGCODMODELO="54B"
   Then
        {Ask} {\\Sistemas\\Cadastro\\RotaCid}
        Moveto [Codigo da Rota] Example "rot"
        Moveto [Ordem         ] Example "ord"
        Moveto [UF            ] Example "uf"
        Moveto [Cidade        ] Example "cid"
        {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Rota     ] Example "rot"
        Moveto [UF                 ] Example "uf"
        Moveto [Cidade             ] Example "cid"
        Moveto [NDias Taxa de Juros] TypeIn "Changeto " Example "ord"
        Do_It!
        ClearAll
EndIf

EndProc    ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESA"
            Case Campo="TG_CONTA"         : Campo="TG_REPRESEN"
            Case Campo="TG_AREA"          : Campo="TG_CONTA"
            Case Campo="TG_ROTA"          : Campo="TG_AREA"
            Case Campo="TG_DTINI"         : Campo="TG_ROTA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_TPPAGTO"       : Campo="TG_DDPROTESTO"
            Case Campo="TG_CODMODELO"     : Campo="TG_TPPAGTO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   : Campo="TG_CONTA"   
                    Case Campo="TG_CONTA"      : Campo="TG_AREA"    
                    Case Campo="TG_AREA"       : Campo="TG_ROTA"
                    Case Campo="TG_ROTA"       : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
       MSG_CAMPO="Informe o Numero de Dias"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("36  Por Cliente/Data de Vencimento")                                ;RM_0232   
ModeloRelatoriosAdd("37  Por Cliente/Data de Vencimento II")                             ;RM_0232B
ModeloRelatoriosAdd("46  Por Area/Cliente/Data de Vencimento")                           ;RM_0232C
ModeloRelatoriosAdd("Separator")                                                  
ModeloRelatoriosAdd("54A Analˇtico por Ficha de Cobran‡a de Cliente - Pr‚-Venda")        ;RM_0233B
ModeloRelatoriosAdd("54B Sint‚tico por Ficha de Cobran‡a de Cliente - Pr‚-Venda")        ;RM_0233B
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("54C Analˇtico por Ficha de Cobran‡a de Cliente - Pronta Entrega")   ;RM_0233B
ModeloRelatoriosAdd("54D Sint‚tico por Ficha de Cobran‡a de Cliente - Pronta Entrega")   ;RM_0233B
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
VSDGEMPRESA    = ""
VSDGTPPAGTO    = ""
VSDGDDPROTESTO = ""
VSDGREPRESEN   = ""     
VSDGNOMREPR    = ""
VSDGCONTA      = ""
VSDGNOMCONTA   = ""
VSDGAREA       = ""
VSDGNOMAREA    = ""
VSDGROTA       = ""
VSDGDESCROTA   = ""
VSDGDTINI      = BlankDate()
VSDGDTFIM      = BlankDate()

ModeloRelatoriosCarregaLista()

ListaRegra_TGAtivado="[TG_TPPAGTO]"  

While True
  ShowDialog "Tˇtulos a Receber por Cliente - Cobranca" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"  
   @ 05,12   Height 20 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
                                               
    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR
    
    Label  @ 04,00 "Conta"  For "TG_CONTA"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 06,00 "Area"  For "TG_AREA"
    Accept @ 07,03 Width 05 "A2"  Picture "#*#" Tag "TG_AREA"   To VSDGAREA
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMAREA
    
    Label  @ 08,00 "Rota"  For "TG_ROTA"
    Accept @ 09,01 Width 07 "A4"  Picture "#*#" Tag "TG_ROTA" To VSDGROTA
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_DESCROTA"  To VSDGDESCROTA

    Label  @ 10,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap˘s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 03,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO
    
    Label  @ 13,00  "Modelo de ~R~elat˘rio"  For "TG_CODMODELO"
    Accept @ 14,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 14,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 16,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 16,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue
  EndDialog

  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If (VSDGCODMODELO="54A" Or VSDGCODMODELO="54B") And IsBlank(VSDGREPRESEN)
     Then Mensagem("Informe o Representante !")
          Loop
  EndIf    

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, processando")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf
  PROCESSA()
  
  Switch
    Case VSDGCODMODELO="36"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230" "2"  "Answer" "R"
    Case VSDGCODMODELO="37"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230" "3"  "Answer" "R"
    Case VSDGCODMODELO="46"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230" "8"  "Answer" "R"
    Case VSDGCODMODELO="54A" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230b" "4" "Answer" "R"
    Case VSDGCODMODELO="54B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230b" "5" "Answer" "R"
    Case VSDGCODMODELO="54C" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230b" "R" "Answer" "R"
    Case VSDGCODMODELO="54D" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230b" "1" "Answer" "R" 
  EndSwitch 
  IMPRIREL("Answer","R")  

  Delete "Answer"
EndWhile
ClearAll
Release Vars All
Release Procs All