;** Rm_0096a *******************************************************************
;*  Emissao dos Titulos a Receber por Repres/Cidade/Cliente c/ Telefone/Contato*
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 29/06/2009 por Anivel Augusto Rodrigues
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 08/10/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÇo pegar tiutlos da mesma pessoa representante
;Ultima Alteracao: 29/04/2010 por Cleber Alves            
;Motivo Alteracao: ".." VSDGGERENCIA
;Ultima Alteracao: 07/10/2011 por Karina Andrade            
;Motivo Alteracao: Add op‡Æo para ordem alfabetica
;Ultima Alteracao: 05/12/2011 por Bruno Carvalho            
;Motivo Alteracao: Add Op‡Æo: Anota‡Æo/Agendamento
;Ultima Alteracao: 07/12/2011 por Bruno Carvalho            
;Motivo Alteracao: Ajustes nos Reports
;Ultima Alteracao: 08/05/2012 por Karina Andrade            
;Motivo Alteracao: Ajustes op‡Æo dos Reports
;Ultima Alteracao: 18/05/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes para Lupus                                      
;Ultima Alteracao: 23/05/2012 por Bruno Carvalho            
;Motivo Alteracao: Add Op‡Æo para informar "Debitos dos Representantes" 
;Ultima Alteracao: 26/12/2013 por Andrey Fillipe
;Motivo Alteracao: Inclusao filtro de UF
;Ultima Alteracao: 07/05/2014 por Andrey Fillipe
;Motivo Alteracao: Adicionado Opcao de Relatorio
;Ultima Alteracao: 13/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no Filtro Gerencia
;Ultima Alteracao: 09/09/2014 por Luis Gustavo
;Motivo Alteracao: Implementado op‡ao de filtrar por Agendamento/Anota‡Æo e filtrar por data do Agendamento
;Ultima Alteracao: 07/11/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes na Proc Agendamento()
;Ultima Alteracao: 03/05/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes [Conta Contabil Represent]->[Codigo_Pessoa] relacionamento
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog 
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                  
;Ultima Alteracao: 16/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes logica no filtros e agendamentos
;Ultima Alteracao: 21/09/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                       
;Ultima Alteracao: 06/09/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro gerencia/representante
;Ultima Alteracao: 27/11/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask com representante nÆo cadastrado
;Ultima Alteracao: 05/12/2019 por Bruno Carvalho
;Motivo Alteracao: Adicionado dois novos modelos sem quebra por representante, como ‚ realizado nos outros modelos deste processo *RM_1003
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 27/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento 
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira
 
;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If VSDGGERENCIA<>""
  Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
       Moveto [Codigo do Representante] Example "crep"
       Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
EndIf

{Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
Moveto [Codigo                 ] Example "cli"
Moveto [Cidade                 ] TypeIn CIDADE
Moveto [UF                     ] TypeIn "~VSDGESTADO.."

If VSDGOPDT="3"
   Then {Ask} TypeIn "\\Sistemas\\Ctarec\\DupNotas" Enter 
        Moveto [Numero do Lancamento   ] Example "NumLan"
        Moveto [Data da Anotacao       ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
         
        {Ask} TypeIn "\\Sistemas\\Ctarec\\DupliC" Enter Check
        Moveto [Numero do Lancamento  ] Example "NumLan"
        Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Destinatario] Example "cli" TypeIn ", ~VSDGDESTINAT.." 
        
   Else {Ask} TypeIn "\\Sistemas\\Ctarec\\DupliC" Enter Check
        Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Destinatario] Example "cli" TypeIn ", ~VSDGDESTINAT.."
        If VSDGOPDT="1"
           Then Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
           Else Moveto [Data de Vencimento ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndIf
EndIf           
If SYS_CODIGO_CLIENTE<>"0380"
   Then Moveto [Saldo do Documento     ] TypeIn "> 0.01"
   Else Moveto [Saldo do Documento     ] TypeIn "> 0"
EndIF   
Switch                                                                                                                            ;Copiar e Ajsutar
  Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
  Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
EndSwitch
switch
  case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] CheckPlus Example "crep" TypeIn ","+ListaRegra_VSDGTPPAGTO
  otherwise                          : Moveto [Tipo do Pagamento] CheckPlus Example "crep" TypeIn ",~VSDGTPPAGTO.."
endswitch        
Switch
  Case VSDGGERENCIA<>"" : Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
  Case VSDGREPRESEN<>"" : Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Endswitch  
Do_It!
ClearAll

If VSDGSIM_NAO="NAO" 
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo_Pessoa         ] Example "codemit"
        {Ask} {Answer} TypeIn "Fast Delete"
        Moveto [Codigo do Destinatario] Example "codemit"
        Do_It!
        ClearAll
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Agendamento()
Private NLANC

if VSDGOPRELAG="4" 
   Then 
        Tabela=Cria_Temp(PrivDir())
        Rename "Answer" Tabela
        Return True
endif

{Ask} {Answer} Check
Moveto [Numero do Lancamento] Example "Lanc" TypeIn "!"
{Ask} {Dupnotas} Check 
Moveto [Numero do Lancamento] Example "Lanc"
Do_It!
ClearAll

Switch
   Case VSDGOPRELAG = "2" :
        {Ask} {Answer} Check
        Moveto [Situacao da Anotacao] TypeIn "AGEN.."
        Do_It!
        ClearAll

   Case VSDGOPRELAG = "3" :
        {Ask} {Answer} Check
        Moveto [Situacao da Anotacao] TypeIn "ANOT.."
        Do_It!
        ClearAll

EndSwitch

If IsEmpty("Answer")
  Then Return False
EndIf
    
Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

Sort Tabela On "Numero do Lancamento","Sequencia da Anotacao"

NLANC="***"

Coedit Tabela
Scan
If NLANC<>[Numero do Lancamento]
  Then NLANC=[Numero do Lancamento]   
  Else [Valor do Documento  ]=BlankNum()
       [Saldo do Documento  ]=BlankNum()
       [Valor do Desconto   ]=BlankNum()
EndIf  
EndScan
Do_It!
ClearAll

Return True

EndProc ;Agendamento()

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Descricao do Cobrador]="Vencida"
      Else NDA=0
           TXM=0
           [Descricao do Cobrador]=""
   EndIf                    
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Descricao do Cobrador]="Cartorio"
               Else [Descricao do Cobrador]="Protestar"
            EndIf
   EndIf
                              
   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

   Switch
     Case [Codigo do documento]="CH"       : [Descricao Tipo Pagamento]="CHEQUE DEV"
   EndSwitch

EndScan
Do_It!
ClearAll

EndProc     ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""

If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO" Or Campo="TG_TPCART"  
                                        Then ListaRegra_F2() 
                                     EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_ESTADO"        : Campo="TG_GERENCIA"
            Case Campo="TG_CIDADE"        : Campo="TG_ESTADO"        
            Case Campo="TG_DESTINAT"      : Campo="TG_ESTADO"
            Case Campo="TG_OPDT"          : Campo="TG_DESTINAT"
            Case Campo="TG_DTINI"         : Campo="TG_OPDT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_TPCART"        : Campo="TG_DDPROTESTO"
            Case Campo="TG_TPPAGTO"       : Campo="TG_TPCART"
            Case Campo="TG_OPRELAG"       : Campo="TG_TPPAGTO"
            Case Campo="TG_SN_OPRELAR"    : Campo="TG_OPRELAG"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_SN_OPRELAR"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPRELCODALF"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"   : Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"     : 
                         If IsBlank(VSDGESTADO) Or VSDGESTADO="" 
                            Then VSDGCIDADE="TODAS"
                                 CIDADE=""
                                 Campo="TG_DESTINAT"
                            Else Campo="TG_CIDADE"
                         EndIf
                    Case Campo="TG_CIDADE"     : 
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf   
                         GetRecord "\\Sistemas\\Cadastro\\Cidades" VSDGCIDADE to UF_CID
                         If RetVal 
                            Then UF_CID = UF_CID["UF"] 
                            Else UF_CID = ""
                         EndIf
                         CI=""
                         If VSDGCIDADE=".." Then CI="TODAS" EndIf
                         If Upper(VSDGCIDADE)="TODAS" Then CI="TODAS" EndIf
                         If  VSDGESTADO<>"" And VSDGESTADO<>"TODAS"
                            Then If VSDGESTADO<>UF_CID And CI<>"TODAS"
                                    Then Mensagem("Cidade nÆo pertence a este Estado !")
                                         Campo="TG_CIDADE"
                                         VSDGCIDADE=""
                                    Else Campo="TG_DESTINAT"
                                 EndIf   
                         EndIf
                    Case Campo="TG_DESTINAT"   : Campo="TG_OPDT"
                    Case Campo="TG_OPDT"       : Campo="TG_DTINI"
                         VSDGOPDT=ControlValue("TG_OPDT")
                         Switch
                           Case VSDGOPDT="2": VSDGDESCOPDT="DATA DE VENCIMENTO"
                           Case VSDGOPDT="3": VSDGDESCOPDT="DATA DE AGEND/ANOT"
                           OtherWise        : VSDGOPDT="1"
                                              VSDGDESCOPDT="DATA DE EMISSAO"
                         EndSwitch
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"     : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="TG_OPRELAG"
                    Case Campo="TG_OPRELAG"    : Campo="TG_SN_OPRELAR"
                         VSDGOPRELAG=ControlValue("TG_OPRELAG")
                             Switch
                               Case VSDGOPRELAG = "2" : VSDGNOMOPRELAG = "AGENDAMENTO"
                               Case VSDGOPRELAG = "3" : VSDGNOMOPRELAG = "ANOTACAO"
                               Case VSDGOPRELAG = "4" : VSDGNOMOPRELAG = "NAO MOSTRAR"
                               OtherWise              : VSDGOPRELAG ="1"
                                                        VSDGNOMOPRELAG = "AGEND/ANOTA"
                             EndSwitch                             
                    Case Campo="TG_SN_OPRELAR" : Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF": Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO": Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
 
Switch
  Case Campo="TG_OPRELAG" : 
       MSG_CAMPO="Op‡Æo: 1= Agend/Anota  2= Agendamento 3= Anota‡Æo  4= NÆo Mostrar"
  Case Campo="TG_SN_OPRELAR" : 
       MSG_CAMPO="Com D‚bitos dos Representantes?"
  Case Campo="TG_DDPROTESTO":
       MSG_CAMPO="Informe o Numero de Dias"
  Case Campo="TG_OPDT":
       MSG_CAMPO="Op‡„o: 1= Emiss„o  2= Vencimento  3= Agend/Anota"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Modelo I  sem Obs por Representante")
ModeloRelatoriosAdd("02  Modelo II com Obs por Representante")
If SYS_CODIGO_CLIENTE<>"0380"
   Then ModeloRelatoriosAdd("03  Modelo I  sem Obs")
        ModeloRelatoriosAdd("04  Modelo II com Obs")
EndIf        
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
SYS_VALOR()
LimpAguarde()

VSDGEMPRESA   =""
VSDGREPRESEN  =""
VSDGGERENCIA  =""
VSDGDESTINAT  =""
VSDGTPCART    =""
VSDGTPPAGTO   =""
VSDGDDPROTESTO=""
VSDGNOMOPRELAG=""
VSDGOPDT      =""
VSDGDTINI     =BlankDate()
VSDGDTFIM     =BlankDate()
VSDGESTADO    =""
VSDGCIDADE    =""
VSDGOPRELAG   =""
VSDGSIM_NAO   ="SIM"

ModeloRelatoriosCarregaLista()

ListaRegra_TGAtivado="[TG_TPPAGTO],[TG_TPCART]"

While True
  ShowDialog "Titulos a Receber por Representante/Cidade/Cliente II" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"                 
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"  
    @ 01,00 Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP   
    
    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 06,02 "Estado"  For "TG_ESTADO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMESTADO"  To VSDGNOMESTADO

    Label  @ 08,00 "Cidade"  For "TG_CIDADE"
    Accept @ 09,01 Width 33 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE

    Label  @ 10,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 11,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 11,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST 
                           
    Label  @ 12,00 "Op‡„o de Datas" For "TG_OPDT"
    Accept @ 13,04 Width 04 "A1"  Picture "1,2,3" Tag "TG_OPDT" To VSDGOPDT
    Accept @ 13,09 Width 25 "A20"  Picture "!*!" Tag "TG_DESCOPDT" To VSDGDESCOPDT

    Label  @ 14,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 15,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 15,16 "at‚" For "TG_DTFIM"
    Accept @ 15,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 03,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Label  @ 04,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 05,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 05,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 06,35 "Anota‡”es/Agendamento" For "TG_OPRELAG"
    Accept @ 07,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPRELAG" To VSDGOPRELAG
    Accept @ 07,44 Width 25 "A11"  Picture "!*!" Tag "TG_NOMOPRELAG" To VSDGNOMOPRELAG

    Label  @ 08,35 "D‚bitos Representantes" For "TG_SN_OPRELAR"
    Accept @ 09,36 Width 07 "A3"  Picture "SIM,NAO" Tag "TG_SN_OPRELAR" To VSDGSIM_NAO  
    
    Label  @ 10,35 "Op‡„o de Ordem" For "TG_OPRELCODALF"
    Accept @ 11,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 11,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If VSDGTPPAGTO="" 
     Then VSDGNOMTPPAGTO = "TODAS"
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf
         
  AGUARDE("Aguarde, Processando Dados")
  Seleciona()
  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf
  If Not Agendamento()
     Then Mensagem("N„o existem agendamentos/anota‡”es no per¡odo informado!")
          Loop
  EndIf        
  Processa()

  switch
    case VSDGCODMODELO="01" Or VSDGCODMODELO="03" : VSDGOPRELAT="1" ; variavel usada nos reports !!
    case VSDGCODMODELO="02" Or VSDGCODMODELO="04" : VSDGOPRELAT="2"
  endswitch
  
  Switch
    Case VSDGOPRELAG<>"4" and VSDGOPRELCODALF = "1" :
         ;CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "R"  Tabela "R" 
         If SYS_CODIGO_CLIENTE="0380"
             Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "3"  Tabela "R"    
             Else If VSDGCODMODELO="01" Or VSDGCODMODELO="02" 
                     Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "R"  Tabela "R"
                     Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "4"  Tabela "R"
                  EndIf   
         EndIF
    Case VSDGOPRELAG<>"4" and VSDGOPRELCODALF = "2" :
         ;CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "1"  Tabela "R"
         IF SYS_CODIGO_CLIENTE="0380"
             Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "3"  Tabela "R"
             Else If VSDGCODMODELO="01" Or VSDGCODMODELO="02" 
                     Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "1"  Tabela "R"
                     Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "5"  Tabela "R"
                  EndIf   
         EndIf
    Case VSDGOPRELAG="4"  and VSDGOPRELCODALF = "1" : If VSDGCODMODELO="01" Or VSDGCODMODELO="02"
                                                         Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001" "11" Tabela "R"
                                                         Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "6"  Tabela "R"
                                                      EndIf           
    Case VSDGOPRELAG="4"  and VSDGOPRELCODALF = "2" : If VSDGCODMODELO="01" Or VSDGCODMODELO="02"
                                                         Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001" "12" Tabela "R"
                                                         Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "7"  Tabela "R" 
                                                      EndIf   
  EndSwitch

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All