;** RM_0500 ********************************************************************
;*  ImpressÆo de Recibos de Pagamento                                          *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 09/11/2012 por Bruno Carvalho
;Ultima Alteracao: 12/11/2012 por Bruno Carvalho
;Motivo Alteracao: InclusÆo do filtro "Plano de Conta"
;Ultima Alteracao: 04/02/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes LimpaRodape()                  
;Ultima Alteracao: 17/12/2013 por Andrey Fillipe 
;Motivo Alteracao: InclusÆo de op‡Æo de data
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                 
;Ultima Alteracao: 01/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de pagamento

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

{Ask} {Titulos} Check
Moveto [Numero do Lancamento] Example "NLanc"
Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo da Conta     ] TypeIn "~VSDGCONTA.."
Moveto [Codigo do Emitente  ] TypeIn "~VSDGDESTINAT.."
If VSDGTPDATA="2"
   Then Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
EndIf
Switch
  Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
  Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
EndSwitch
Moveto [Codigo Plano_Conta  ] TypeIn "Not Blank, ~VSDGPLCONTAS.."
;Moveto [Saldo do Documento  ] TypeIn "> 0.01"

{Ask} {TitBaixa}
Moveto [Numero do Lancamento] Example "NLanc"
If VSDGTPDATA="1"
   Then Moveto [Data do Pagamento   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
EndIf
Do_It!
ClearAll

EndProc ;SELECIONA()

;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************************************
If VSDGEMPRESA="0000"
   Then {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

{Ask} {Answer} TypeIn "Fast"
Moveto [Data de Vencimento] TypeIn "ChangeTo Blank"
Down
Moveto [Saldo do Documento] TypeIn "ChangeTo Blank"
Do_It!
ClearAll

View "TitBaixa"
Coedit "Answer"
Scan
  Moveto "TitBaixa"
  Moveto [Numero do Lancamento]
  Locate [Answer->Numero do Lancamento]
  If RetVal
     Then Moveto "Answer"
          [Data de Vencimento]=[TitBaixa->Data do Pagamento]                              
          [Saldo do Documento]=[TitBaixa->Valor do Pagamento]
  EndIf
  Moveto "Answer"
EndScan
Do_It!
ClearAll

{Tools} {Copy} {JustFamily} {Titulos} {Answer} {Replace}

Sort "Answer" On "Nome Fantasia EmitDest","Data de Vencimento","Tipo do Documento","Numero do Documento"

EndProc ;Processa()

;*******************************************************************************
;* Seleciona Registros para Carta de Cobranca                                  *
;*******************************************************************************
Proc SELECIONAI()

Edit "Answer"
SetHighLight Current Record 23 Field 31
{Image} {KeepSet}
Do_It!

CoEdit "Answer"
PickForm "7"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
EndWhile
Do_It!
ClearAll

EndProc ;SELECIONAI()

;*******************************************************************************
;* Seleciona Titulos para Baixa
;*******************************************************************************
Proc CHAVE()
While True
  End
  Down
  Moveto [Numero do Lancamento]
  While True

    Prompt " Esc=Sair  F6=Imprimir  F7=Paginar  "

    Wait Field
         Until "ESC","ENTER","F7","HOME","UP","PGUP","F6"

    Switch
    Case RetVal="F6":
         Del
         IMPRIME()
         
    Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME":
         CHAVE=0
         While True
           PAGINA("Answer","MR")
           If EDITAR="S"
              Then Mensagem("Altera‡„o n„o permitida !")
                   UnLockRecord
              Else If EXCLUIR="S"
                      Then CONFIRMA()
                           If OK="S"
                              Then DEL
                              Else UnLockRecord
                           EndIf
                      Else QuitLoop
                   EndIf
           EndIf
         EndWhile
         QuitLoop
    Case Retval="ESC":
         CHAVE=9
         Return
    EndSwitch
  EndWhile
EndWhile        

EndProc ;CHAVE()

;*******************************************************************************
;* Rotina De Impressao                                                         *
;*******************************************************************************
Proc IMPRIME()
Private MODCARTA

VSDGNPARCELAS=""
VSDGNDIAS=""

MSGDISPOSITIVO="Recibo"
DispositivoI("RCB")

If OK="" 
   Then Return
EndIf

LimpaRodape(0)
Do_It!
ClearAll

ArqImp="Recibo.txt"
Deleta_Arquivo(Arqimp)
Sleep 700

CodCli    = "***"
CONTBAIXA = 0

View "\\Sistemas\\Cadastro\\Destinat"
View "Titulos"
View "TitBaixa"
View "Answer"
Scan
 Moveto "TitBaixa"
 Moveto [Numero do Lancamento]
 Locate [Answer->Numero do Lancamento]
 If RetVal
    Then While [Numero do Lancamento]=[Answer->Numero do Lancamento]
           RECB_AUT = True
           Moveto "Titulos"
           Moveto [Numero do Lancamento]
           Locate [Answer->Numero do Lancamento]
           If RetVal 
              Then ULTIMA_BAIXA=True
                   forant="****"
                   If CodCli<>[Answer->Codigo do Emitente]
                      Then CodCli=[Answer->Codigo do Emitente]
                           
                           ENDERECO=""
                           BAIRRO  =""
                           CIDADE  =""
                           TELEFONE=""
                           RG      =""

                           Moveto "\\Sistemas\\Cadastro\\Destinat"
                           Moveto [Codigo]
                           Locate [Titulos->Codigo do Emitente]
                           If RetVal
                             Then ENDERECO = [Endereco ]                
                                  BAIRRO   = [Bairro   ]
                                  CIDADE   = [Cidade   ]
                                  TELEFONE = [Telefone ]
                                  RG       = [RG       ]
                           EndIf
                   EndIf    
                   Moveto "TitBaixa"   
                   CONTBAIXA = CONTBAIXA + 1
                   If CONTBAIXA = 3 
                      Then CONTBAIXA = 0
                           SALTA_PAGINA = True
                      Else SALTA_PAGINA = False
                   EndIf    
                   Play "RP_0310"
           EndIf
           Moveto "TitBaixa"
           Skip
           If Eot() Then QuitLoop EndIf
         EndWhile
  EndIf            
  Moveto "Answer"
EndScan
ClearAll

ImpriArq(ArqImp)

CoEdit "Answer"
PickForm "7"     
End Down
LIMPAGUARDE()

EndProc ;IMPRIME()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DESTINAT"      : Campo="TG_CONTA"
            Case Campo="TG_PLCONTAS"      : Campo="TG_DESTINAT"
            Case Campo="TG_TPDATA"        : Campo="TG_PLCONTAS"
            Case Campo="TG_DTINI"         : Campo="TG_TPDATA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"            
            Case Campo="TG_TPPAGTO"       : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_PLCONTAS"
                    Case Campo="TG_PLCONTAS"   : Campo="TG_TPDATA"
                    Case Campo="TG_TPDATA"     : Campo="TG_DTINI"
                         VSDGTPDATA=ControlValue("TG_TPDATA")
                         If IsBlank(VSDGTPDATA)
                            Then Campo="TG_TPDATA"
                         EndIf   
                         Switch
                           Case VSDGTPDATA="1" : VSDGNOMTPDATA="DATA DO PAGAMENTO"
                           Case VSDGTPDATA="2" : VSDGNOMTPDATA="DATA DE VENCIMENTO"
                         EndSwitch
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CONTA":
     MSG_CAMPO="Informe uma conta tipo CAIXA !"
  Case Campo="TG_TPDATA" :
       MSG_CAMPO="1=Data do Pagamento  2=Data de Vencimento"
  Case Campo="":
       MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE="0222"  EndIf
If Not IsAssigned(SYS_CHAPA_USUARIO)   Then SYS_CHAPA_USUARIO=""       EndIf

VSDGEMPRESA =""
VSDGCONTA   =""
VSDGTPPAGTO =""
VSDGDESTINAT=""   
VSDGPLCONTAS=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

ListaRegra_TGAtivado="[TG_TPPAGTO]"

While True
  ShowDialog "Recibo de Pagamento" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"   
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
                               
    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST
                                                                                                          
    Label  @ 06,00 "Plano de Contas" For "TG_PLCONTAS"
    Accept @ 07,01 Width 33 "A13"  Picture "!*!" Tag "TG_PLCONTAS" To VSDGPLCONTAS
    Accept @ 08,01 Width 33 "A40" Picture "!*!" Tag "TG_NOMPLCONTAS"  To VSDGNOMPLCONTAS
    
    Label  @ 09,00 "Op‡äes de Datas" For "TG_TPDATA"
    Accept @ 10,04 Width 04 "A1"  Picture "1,2"  Tag "TG_TPDATA"     To VSDGTPDATA
    Accept @ 10,09 Width 25 "A20" Picture "!*!"  Tag "TG_NOMTPDATA" To VSDGNOMTPDATA
                                                                                                            
    Label  @ 11,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 12,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 12,16 "at‚" For "TG_DTFIM"
    Accept @ 12,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
                                
    Label  @ 00,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 01,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 01,44 Width 23 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  AGUARDE("Aguarde, Selecionando registros")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf

  Processa()
  SELECIONAI()
  
  Echo Normal
  Echo Off

  ClearAll
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
