;** Rm_0096 ********************************************************************
;*  Emissao dos Titulos a Receber por Repres/Cidade/Cliente c/ Telefone/Contato*
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 01/04/2009 por Anivel Augusto Rodrigues
;Ultima Alteracao: 10/07/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Gerencia
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 08/10/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÇo pegar tiutlos da mesma pessoa representante
;Ultima Alteracao: 29/04/2010 por Cleber Alves            
;Motivo Alteracao: ".." VSDGGERENCIA
;Ultima Alteracao: 12/07/2013 por Bruno Carvalho            
;Motivo Alteracao: Ajustes e add novo modelo com observa‡Æo
;Ultima Alteracao: 18/07/2013 por Bruno Carvalho            
;Motivo Alteracao: Ajustes #0343#
;Ultima Alteracao: 26/12/2013 por Andrey Fillipe
;Motivo Alteracao: Inclusao filtro de UF
;Ultima Alteracao: 13/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 03/05/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes [Conta Contabil Represent]->[Codigo_Pessoa] relacionamento
;Ultima Alteracao: 18/08/2016 por Heverton/Bruno
;Motivo Alteracao: Removido verifica‡Æo de Destinat Mˆs fechado
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/11/2016 por Nikolas
;Motivo Alteracao: Ajustes exclusao DP s¢ para 0343 Thardely
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 28/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                 
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 21/09/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                       
;Ultima Alteracao: 26/04/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro atividade   
;Ultima Alteracao: 08/05/2019 por Kamila Gomes
;Motivo Alteracao: NÆo fazer processo de remover cliente do representante se for #0222#               
;Ultima Alteracao: 06/09/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro gerencia/representante
;Ultima Alteracao: 27/11/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask com representante nÆo cadastrado
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
   Then
       If VSDGGERENCIA<>""
          Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
               Moveto [Codigo do Representante] Example "crep"
               Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
       EndIf

        {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
        Moveto [Codigo ] Example "cli"
        Moveto [Cidade ] TypeIn CIDADE
        Moveto [UF     ] TypeIn "~VSDGESTADO.."
        Moveto [Codigo Atividade  ] TypeIn "~VSDGATIVIDADE.."

        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Destinatario] Example "cli" TypeIn ", ~VSDGDESTINAT.."
        Switch
          Case VSDGOPDTEMISVENC="2": Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDTEMISVENC="1": Moveto [Data de Vencimento ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
        Moveto [Saldo do Documento    ] TypeIn "> 0.01"
        Switch                                          
          Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
          Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
        EndSwitch  
        switch
          case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
          otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
        endswitch
        Switch
          Case VSDGGERENCIA<>"" : Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
          Case VSDGREPRESEN<>"" : Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
        Endswitch  
        Do_It!
        ClearAll
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

If SYS_CODIGO_CLIENTE<>"0222"
   then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
        If VSDGGERENCIA<>""
           Then TypeIn VSDGGERENCIA
        EndIf
        Moveto [Codigo_Pessoa         ] Example "codemit"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Delete"
        Moveto [Codigo do Destinatario] Example "codemit"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Descricao do Cobrador]="Vencida"
      Else NDA=0
           TXM=0
           [Descricao do Cobrador]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Descricao do Cobrador]="Cartorio"
               Else [Descricao do Cobrador]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll

If SYS_CODIGO_CLIENTE="0343"
   Then NOMEEMPRESA=""
        {Ask} TypeIn Tabela Enter
        Moveto [Codigo da Empresa    ] TypeIn "Changeto Blank"
        End
        Moveto [Nome Fantasia Empresa] TypeIn "Changeto Blank"
        Do_It!
        ClearAll

        {Ask} TypeIn Tabela Enter TypeIn "Fast Delete"
        Moveto [Tipo do Pagamento] TypeIn "BO or DP"
        Do_It!
        ClearAll
EndIf

EndProc     ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO" Or Campo="TG_TPCART"  
                                        Then ListaRegra_F2() 
                                     EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_ESTADO"        : Campo="TG_GERENCIA"
            Case Campo="TG_CIDADE"        : Campo="TG_ESTADO"
            Case Campo="TG_DESTINAT"      : Campo="TG_ESTADO"
            Case Campo="TG_OPDTEMISVENC"  : Campo="TG_DESTINAT"
            Case Campo="TG_DTINI"         : Campo="TG_OPDTEMISVENC"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_TPCART"        : Campo="TG_DDPROTESTO"
            Case Campo="TG_TPPAGTO"       : Campo="TG_TPCART"
            Case Campo="TG_ATIVIDADE"     : Campo="TG_TPPAGTO"
            Case Campo="TG_CODMODELO"     : Campo="TG_ATIVIDADE"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"   : Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"     : 
                         If IsBlank(VSDGESTADO) Or VSDGESTADO="" 
                            Then VSDGCIDADE="TODAS"
                                 CIDADE=""
                                 Campo="TG_DESTINAT"
                            Else Campo="TG_CIDADE"
                         EndIf
                    Case Campo="TG_CIDADE"     : 
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                         GetRecord "\\Sistemas\\Cadastro\\Cidades" VSDGCIDADE to UF_CID
                         If RetVal 
                            Then UF_CID = UF_CID["UF"] 
                            Else UF_CID = ""
                         EndIf
                         CI=""
                         If VSDGCIDADE=".." Then CI="TODAS" EndIf
                         If Upper(VSDGCIDADE)="TODAS" Then CI="TODAS" EndIf
                         If  VSDGESTADO<>"" And VSDGESTADO<>"TODAS"
                            Then If VSDGESTADO<>UF_CID And CI<>"TODAS"
                                    Then Mensagem("Cidade nÆo pertence a este Estado !")
                                         Campo="TG_CIDADE"
                                         VSDGCIDADE=""
                                    Else Campo="TG_DESTINAT"
                                 EndIf   
                         EndIf
                    Case Campo="TG_DESTINAT"   : Campo="TG_OPDTEMISVENC"
                    Case Campo="TG_OPDTEMISVENC": Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"     : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="TG_ATIVIDADE"
                    Case Campo="TG_ATIVIDADE"  : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
     MSG_CAMPO="Informe o Numero de Dias"
  Case Campo="":
     MSG_CAMPO=""
EndSwitch                            
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Modelo I  sem Obs")
ModeloRelatoriosAdd("02  Modelo II com Obs")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

If Not Isassigned(SYS_CODIGO_CLIENTE) Then SYS_CODIGO_CLIENTE="" EndIf

VSDGEMPRESA   =""
VSDGREPRESEN  =""
VSDGGERENCIA  =""
VSDGDESTINAT  =""
VSDGTPCART    =""
VSDGDDPROTESTO=""
VSDGDTINI     =BlankDate()
VSDGDTFIM     =BlankDate()
VSDGESTADO    =""
VSDGCIDADE    =""
VSDGOPRELCODALF    = ""
VSDGNOMOPRELCODALF = "" 
VSDGOPDTEMISVENC   =""
VSDGNOMOPDTEMISVENC=""
VSDGATIVIDADE= ""

ModeloRelatoriosCarregaLista()

ListaRegra_TGAtivado="[TG_TPPAGTO],[TG_TPCART]"

While True
  ShowDialog "Titulos a Receber por Representante/Cidade/Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"     
    @ 01,00 Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP   
    
    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 06,02 "Estado"  For "TG_ESTADO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMESTADO"  To VSDGNOMESTADO

    Label  @ 08,00 "Cidade"  For "TG_CIDADE"
    Accept @ 09,01 Width 33 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE

    Label  @ 10,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 11,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 11,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST 
                           
    Label  @ 12,00 "Op‡äes de Datas" For "TG_OPDTEMISVENC"
    Accept @ 13,04 Width 04 "A1"  Picture "1,2"  Tag "TG_OPDTEMISVENC"    To VSDGOPDTEMISVENC
    Accept @ 13,09 Width 25 "A20" Picture "!*!"  Tag "TG_NOMOPDTEMISVENC" To VSDGNOMOPDTEMISVENC

    Label  @ 14,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 15,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 15,16 "at‚" For "TG_DTFIM"
    Accept @ 15,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 03,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Label  @ 04,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 05,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 05,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 06,36 "Atividade"  For "TG_ATIVIDADE"
    Accept @ 07,36 Width 07 "A4"  Picture "!*!" Tag "TG_ATIVIDADE" To VSDGATIVIDADE
    Accept @ 07,44 Width 25 "A30"  Picture "#*#" Tag "TG_NOMATIV" To VSDGNOMATIV

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile
  Processa()

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  If VSDGCODMODELO="01"
     Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001"  "10" Tabela "R"
     Else Impressao_Orientacao="Paisagem"
          CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001a" "2"  Tabela "R" 
  EndIf

  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
