;** Rm_0200E *******************************************************************
;*  Emissao Resumo de Pedidos                                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 19/04/2016 por Kamila Gomes     
;Ultima Alteracao: 21/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                  
;Ultima Alteracao: 24/11/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_SITUACAOPEDIDO  
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                  
;Ultima Alteracao: 28/01/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao novo processo concetrador RM_0200, substitudo do RM_0066              
                  
;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc RM_0200E_Seleciona()
ClearAll

{Ask} {\\Sistemas\\Vendas\\Destin}
Moveto [Codigo da Destinacao  ] Example "cd"
Moveto [Tipo Movimento Estoque] TypeIn "S"

{Ask} {\\Sistemas\\Vendas\\PedidoC}
Moveto [Numero do Pedido      ] Example "Pedido"
Moveto [Codigo da Empresa     ] CheckPlus TypeIn "~VSDGEMPRESA2.."
Moveto [Nome Fantasia Empresa ] CheckPLus
Moveto [Nome Fantasia EmitDest] CheckPLus
Moveto [Data de Entrega       ] CheckPLus 
Moveto [Codigo da Destinacao  ] Example "cd"
Moveto [Situacao do Pedido    ] 
switch
  case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
  case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
  case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
  case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
endswitch

Switch
  Case VSDGOPDTPEEI="1": Moveto [Data de Entrega    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
  Case VSDGOPDTPEEI="2": Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
  Case VSDGOPDTPEEI="3": Moveto [Data_Inclusao      ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
EndSwitch
Moveto [Cidade                 ] TypeIn CIDADE
Moveto [UF                     ] TypeIn "~VSDGESTADO.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."

switch
  case VSDGCODMODELO="14" :   
    Moveto [Codigo do Representante] CheckPLus
    Moveto [Nome Fantasia Represent] CheckPLus
 
endswitch

{Ask} {\\Sistemas\\Vendas\\PedidoI}
Moveto [Numero do Pedido       ] CheckPLus Example "Pedido"
Moveto [Codigo do Item         ] CheckPLus Example "cite" TypeIn ",~VSDGITEM.."
Moveto [Descricao do Item      ] CheckPLus
Moveto [Codigo da Cor_Tecido   ] CheckPLus
Moveto [Descricao da Cor_Tecido] CheckPLus
Moveto [Tamanho                ] CheckPLus
Moveto [Unidade Fiscal         ] CheckPLus

Moveto [Quantidade             ] CheckPLus TypeIn ">" Example "qf"
Moveto [Quantidade Faturada    ] CheckPLus Example "qf"
Moveto [Preco Total            ] CheckPLus
Moveto [Valor Desconto Total   ] CheckPLus
Moveto [Preco Unitario         ] CheckPLus

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Tipo do Item           ] CheckPLus
Moveto [Codigo da Familia      ] CheckPLus TypeIn "~VSDGFAMI.."
Moveto [Descricao da Familia   ] CheckPLus
Moveto [Codigo do Grupo        ] CheckPLus TypeIn "~VSDGGRP.."
Moveto [Descricao do Grupo     ] CheckPLus
Moveto [Codigo da Marca        ] CheckPLus TypeIn "~VSDGMARCA.."
Moveto [Descricao da Marca     ] CheckPLus
Moveto [Codigo da Grade        ] CheckPLus
Moveto [Referencia             ] CheckPLus TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo do Departamento ]           TypeIn "~VSDGDEPART.."

Do_It!
ClearAll

EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina para Processar  Registros                                            *
;*******************************************************************************
Proc RM_0200E_Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   else
        {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} {Answer} TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {Answer} typein "Fast"
Moveto [Quantidade             ]       TypeIn "_qtd"
Moveto [Preco Total            ]       TypeIn "_prt"
Moveto [Valor Desconto Total   ]       TypeIn "_vdt"
Moveto [Preco Unitario         ]       TypeIn "changeto (_prt-_vdt)/_qtd"
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ Agrupar Itens nos tamanhos respectivos                            *
;*******************************************************************************
Proc RM_0200E_AgrupaItens()
private newitem

Array Array_TM[12]


Tabela=Cria_Temp(PrivDir())
Copy "\\Base\\Sistemas\\Faccao\\PosEstqG" Tabela

Sort "Answer" On "Referencia"

View "\\Sistemas\\Estoque\\TpGrade"
Coedit Tabela,"Answer"
COMPREF = "*****"

Scan
  AGUARDE("Aguarde, Agrupando Dados")

  If [Referencia] <> COMPREF 
     Then RM_0200E_Verifica_Array_Grade()
          Moveto "Answer"
          COMPREF = [Referencia] 
  EndIF
  
  WSEMP = [Codigo da Empresa   ]
  WSREF = [Referencia          ]
  If VSDGCODMODELO="18"
     Then WSCOR = [Codigo da Cor_Tecido]
     Else WSCOR =""
  EndIf
  newitem=wsref+wscor
  
  Moveto Tabela
  Moveto [Codigo da Empresa]
  Locate WSEMP,newitem
  If Not RetVal
     Then End
          Down
          [Codigo da Empresa    ]=[Answer->Codigo da Empresa    ]
          [Codigo do Item       ]=newitem
          [Referencia           ]=WSREF
          [Nome Fantasia Empresa]=[Answer->Nome Fantasia Empresa]
          If VSDGCODMODELO="18"
             Then [Descricao do Item      ]=Substr([Answer->Descricao do Item],1,27)
             Else [Descricao do Item      ]=Substr([Answer->Descricao do Item],1,23)
          EndIf
          [Unidade Interna      ]=[Answer->Unidade Fiscal       ]
          [Codigo da Familia    ]=[Answer->Codigo da Familia    ]
          [Descricao da Familia ]=[Answer->Descricao da Familia ]
          [Codigo do Grupo      ]=[Answer->Codigo do Grupo      ]
          [Descricao do Grupo   ]=[Answer->Descricao do Grupo   ]
          [Codigo da Marca      ]=[Answer->Codigo da Marca      ]
          [Descricao da Marca   ]=[Answer->Descricao da Marca   ]
          [Codigo da Grade      ]=[Answer->Codigo da Grade      ]
  EndIf
  
  Coluna=0
  For Wi from 1 to 12
    If Len(RTrim(SubStr(Array_TM[Wi],1,2)))=1
       Then If SubStr([Answer->Codigo do Item],10,1)=SubStr(Array_TM[Wi],1,1)
               Then Coluna=Wi
                    QuitLoop
            EndIf
       Else If SubStr([Answer->Codigo do Item],9,2)=SubStr(Array_TM[Wi],1,2)
               Then Coluna=Wi
                    QuitLoop
            EndIf
    EndIf
  EndFor

  Qtd=[Answer->Quantidade]-[Answer->Quantidade Faturada]

  Switch
    Case Coluna=0 : [Qtd1  ]=[Qtd1  ]+Qtd
    Case Coluna=1 : [Qtd1  ]=[Qtd1  ]+Qtd
    Case Coluna=2 : [Qtd2  ]=[Qtd2  ]+Qtd
    Case Coluna=3 : [Qtd3  ]=[Qtd3  ]+Qtd
    Case Coluna=4 : [Qtd4  ]=[Qtd4  ]+Qtd
    Case Coluna=5 : [Qtd5  ]=[Qtd5  ]+Qtd
    Case Coluna=6 : [Qtd6  ]=[Qtd6  ]+Qtd
    Case Coluna=7 : [Qtd7  ]=[Qtd7  ]+Qtd
    Case Coluna=8 : [Qtd8  ]=[Qtd8  ]+Qtd
    Case Coluna=9 : [Qtd9  ]=[Qtd9  ]+Qtd
    Case Coluna=10: [Qtd10 ]=[Qtd10 ]+Qtd
    Case Coluna=11: [Qtd11 ]=[Qtd11 ]+Qtd
    Case Coluna=12: [Qtd12 ]=[Qtd12 ]+Qtd
  EndSwitch
  
  [Pedidos    ]=[Pedidos    ]+Qtd

Moveto "Answer"
        
EndScan
Do_It!
ClearAll

EndProc ;AgrupaItens()

;*******************************************************************************
;* Rotina Monta Array Grade                                                     *
;*******************************************************************************
Proc RM_0200E_Verifica_Array_Grade()

For Wh From 1 To 12
  Array_TM[Wh]="" 
EndFor

Moveto "\\Sistemas\\Estoque\\TpGrade"
Moveto [Codigo da Grade]
Locate [Answer->Codigo da Grade]
If Not RetVal
   Then Mensagem("Item "+[Answer->Codigo do Item]+" sem grade definida !")
        Return
EndIf

Array_TM[1] =LTrim(RTrim([Codigo Item1]))
Array_TM[2] =LTrim(RTrim([Codigo Item2]))
Array_TM[3] =LTrim(RTrim([Codigo Item3]))
Array_TM[4] =LTrim(RTrim([Codigo Item4]))
Array_TM[5] =LTrim(RTrim([Codigo Item5]))
Array_TM[6] =LTrim(RTrim([Codigo Item6]))
Array_TM[7] =LTrim(RTrim([Codigo Item7]))
Array_TM[8] =LTrim(RTrim([Codigo Item8]))
Array_TM[9] =LTrim(RTrim([Codigo Item9]))
Array_TM[10]=LTrim(RTrim([Codigo Item10]))
Array_TM[11]=LTrim(RTrim([Codigo Item11]))
Array_TM[12]=LTrim(RTrim([Codigo Item12]))

EndProc ;Verifica_Array_Grade()

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_0200E_Principal()

AGUARDE("Aguarde, Gerando o RelatĒrio")

RM_0200E_Seleciona()

If not IsEmpty("Answer")
   then
        RM_0200E_Processa()
        RM_0200E_AgrupaItens()
        
       ;switch
       ;  case VSDGOPRELCODALFRANK2="2"  : Seta_Ordem_Report(Tabela,"8","Codigo do Item","Descricao do Item"  ,"")
       ;  case VSDGOPRELCODALFRANK2="3"  : Seta_Ordem_Report(Tabela,"8","Codigo do Item","Compras_Quantidade" ,"D")
       ;  case VSDGOPRELCODALFRANK2="4"  : Seta_Ordem_Report(Tabela,"8","Codigo do Item","Compras_Preco Total","D")
       ;endswitch

        switch
          case VSDGCODMODELO="18"  or   
               VSDGCODMODELO="18B" : CopyReport "\\Base\\Sistemas\\Faccao\\PosEstqG" "3" Tabela "R"   

        endswitch
        IMPRIREL(Tabela,"R")
   else 
        MENSAGEM("No existem registros a processar")
EndIf

If IsTable(Tabela)   Then Delete Tabela   EndIf

EndProc

;-- Chamada principal ----------------------------------------------------------
RM_0200E_Principal()

Release Vars Tabela
Release Procs RM_0200E_Principal, RM_0200E_Seleciona, RM_0200E_Processa, RM_0200E_AgrupaItens, RM_0200E_Verifica_Array_Grade
