;** Rm_0070 ********************************************************************
;*  Emissao dos Titulos a Receber por Tipo de Carteira/Cliente                 *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 29/02/2016 por Kamila Gomes
;Motivo Alteracao: Adicionada op‡Æo de mostrar Agendamentos e Anota‡äes
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll
If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
  Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
			 Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
       Moveto [Saldo do Documento] TypeIn "> 0.01"
       Switch                                                                                                                            
         Case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
         Otherwise                         : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
       EndSwitch  
       Do_It!
       ClearAll
EndIf

EndProc    ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Agendamento()
Private NLANC

If IsTable("\\Sistemas\\CtaRec\\"+Dir_Trab+"Dupnotas") 
   Then {Ask} TypeIn Tabela Enter Check
        Moveto [Numero do Lancamento] Example "Lanc" TypeIn "!"
        {Ask} {Dupnotas} Check 
        Moveto [Numero do Lancamento] Example "Lanc"
        Do_It!
        ClearAll
EndIf

If IsEmpty("Answer")
   Then Return False
   Else Copy "Answer" Tabela
EndIf

Switch
  Case VSDGOPRELAG = "4" :
       Sort Tabela On "Numero do Lancamento","Sequencia da Anotacao"

        NLANC="***"
        NR=NRecords(Tabela)
        Coedit Tabela
        Moveto [Numero do Lancamento]
        While True
          If NLANC<>[Numero do Lancamento]
             Then NLANC=[Numero do Lancamento]   
                  Down
             Else del
          EndIf
          NR = NR-1
          If NR <= 0 Then QuitLoop EndIf
        EndWhile
        
        Do_It!
        ClearAll

        Return True

   Case VSDGOPRELAG = "2" :
        {Ask} TypeIn Tabela Enter Check
        Moveto [Situacao da Anotacao] TypeIn "AGEN.."
   Case VSDGOPRELAG = "3" :
        {Ask} TypeIn Tabela Enter Check 
        Moveto [Situacao da Anotacao] TypeIn "ANOT.."
EndSwitch

If  VSDGOPRELAG = "2" Or VSDGOPRELAG = "3"
  Then Do_It!
       ClearAll
       If IsEmpty("Answer")
          Then Return False
          Else Copy "Answer" Tabela
       EndIf
EndIf         
    
Sort Tabela On "Numero do Lancamento","Sequencia da Anotacao"

NLANC="***"

Coedit Tabela
Scan
If NLANC<>[Numero do Lancamento]
  Then NLANC=[Numero do Lancamento]   
  Else [Valor do Documento  ]=BlankNum()
       [Saldo do Documento  ]=BlankNum()
       [Valor do Desconto   ]=BlankNum()
EndIf  
EndScan
Do_It!
ClearAll

Return True

EndProc ;Agendamento()

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll
EndProc  ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPCART"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_TPCART"        : Campo="TG_DDPROTESTO"
            Case Campo="TG_OPRELAG"       : Campo ="TG_TPCART"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"     : Campo="TG_OPRELAG"
                    Case Campo="TG_OPRELAG"    : Campo="YES"
                         VSDGOPRELAG=ControlValue("TG_OPRELAG")
                         Switch
                           Case VSDGOPRELAG = "1" : VSDGNOMOPRELAG = "AGEND/ANOTA"
                           Case VSDGOPRELAG = "2" : VSDGNOMOPRELAG = "AGENDAMENTO"
                           Case VSDGOPRELAG = "3" : VSDGNOMOPRELAG = "ANOTACAO"
                           OtherWise              : VSDGOPRELAG ="4"
                                                    VSDGNOMOPRELAG = "NAO MOSTRAR"
                         EndSwitch   
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
     MSG_CAMPO="Informe o Numero de Dias"
  Case Campo="TG_OPRELAG" : 
     MSG_CAMPO="Op‡Æo: 1= Agend/Anota  2= Agendamento 3= Anota‡Æo  4= NÆo Mostrar"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   =""
VSDGTPCART    =""
VSDGDDPROTESTO=""
VSDGDTINI     =BlankDate()
VSDGDTFIM     =BlankDate()
VSDGOPRELAG   =""

ListaRegra_TGAtivado="[TG_TPCART]"

While True
  ShowDialog "Receber por Tipo de Carteira/Clientes" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"
    @ 05,12   Height 11 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,16 "at‚" For "TG_DTFIM"
    Accept @ 03,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 03,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Label  @ 04,35 "Anota‡”es/Agendamento" For "TG_OPRELAG"
    Accept @ 05,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPRELAG" To VSDGOPRELAG
    Accept @ 05,44 Width 25 "A11"  Picture "!*!" Tag "TG_NOMOPRELAG" To VSDGNOMOPRELAG

    Pushbutton @ 07,22 width 11 "~O~K"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  
  If Not Agendamento()
     Then Mensagem("N„o existem agendamentos/anota‡”es no per¡odo informado!")
          Loop
  EndIf
  
  If VSDGOPRELAG="4" 
     Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "10" Tabela "R"
     Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1003" "2"  Tabela "R" 
  EndIf

  IMPRIREL(Tabela,"R")

  Delete Tabela
                          
EndWhile
ClearAll
Release Vars All
Release Procs All
