;** Rm_3070 ********************************************************************
;* Resumo de Vendas por Familia/Produto                                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 17/09/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 05/09/2006 por Nikolas M. Mateus
;Motivo Alteracao: Invertido no calculo da embalagem para dividir pela quantidade
;Ultima Alteracao: 15/12/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 03/09/2013 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Inclusao opcao sintetico
;Ultima Alteracao: 16/01/2015 por Andrey Fillipe 
;Motivo Alteracao: Adicionado Coluna Localizacao RM_3100 "12" e "13" Analitico
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/07/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modelo 03 e filro tipo pessoa
;Ultima Alteracao: 22/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes erro modelo 02   
;Ultima Alteracao: 18/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_3060" (16), "RM_3063" (1Q), "RM_3062" (1A),"RM_0170" (42) neste script "RM_0370" (15)           

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then If Not IsBlank(VSDGFAMI) or
           Not IsBlank(VSDGGRP)
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
        EndIf                        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        
        if VSDGCODMODELO="15C" 
           then moveto [Tipo Pessoa    ] typein "JURIDICA"
        endif   
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo do Item         ] Check
        If Not IsBlank(VSDGFAMI)
           Then Moveto [Codigo do Item ] Example "cite"
        EndIf
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        Adiciona_Dados("VENDAS")
EndIf

;****** Devolucoes - Estoque ***************************************************
If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then If Not IsBlank(VSDGFAMI) or
           Not IsBlank(VSDGGRP)
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Data de Entrada        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo de Operacao       ] TypeIn "D"
        Moveto [Codigo do Representante] Example "crep"
        
        if VSDGCODMODELO="15C" 
           then moveto [Tipo Pessoa    ] typein "JURIDICA"
        endif   
        
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        Moveto [Codigo do Item         ] Check
        If Not IsBlank(VSDGFAMI)
           Then Moveto [Codigo do Item ] Example "cite"
        EndIf
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Do_It!
        ClearAll

        Adiciona_Dados("DEVOLUCOES")
EndIf

;****** Devolucoes - Vendas ****************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then If Not IsBlank(VSDGFAMI) or
           Not IsBlank(VSDGGRP)
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Tipo Movimento Estoque ] TypeIn "E"
        Moveto [Situacao               ] TypeIn "Not C"
        
        if VSDGCODMODELO="15C" 
           then moveto [Tipo Pessoa    ] typein "JURIDICA"
        endif   
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo do Item         ] Check
        If Not IsBlank(VSDGFAMI)
           Then Moveto [Codigo do Item ] Example "cite"
        EndIF
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        Adiciona_Dados("DEVOLUCOES")
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Quantidade      ] Example "qtde"
       Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
  Case Tipo="DEVOLUCOES":
       Moveto [Devolucoes_Quantidade  ] Example "qtde"
       Moveto [Devolucoes_Preco Total ] Example "ptot" TypeIn"-" Example "vdes"
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Unidade Embalagem      ] Example "une"
switch
  case VSDGCODMODELO="15C":
    Moveto [NCM                    ] Example "ncm"
    Moveto [Codigo de Barras       ] Example "cbar"
  
  otherwise              :
    Moveto [Codigo da Familia      ] Example "cfam"
    Moveto [Descricao da Familia   ] Example "dfam"
    Moveto [Localizacao            ] Example "loc"
     
endswitch

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Moveto [Unidade Embalagem      ] TypeIn "changeto _une"
switch
  case VSDGCODMODELO="15C":
    Moveto [Descricao do Grupo     ] TypeIn "changeto _ncm"
    Moveto [Descricao da Marca     ] TypeIn "changeto _cbar"
  
  otherwise              :
    Moveto [Codigo da Familia      ] TypeIn "changeto _cfam"
    Moveto [Descricao da Familia   ] TypeIn "changeto _dfam"
    Moveto [Codigo Fornecedor      ] TypeIn "changeto _loc"
  
endswitch

Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item            ] Example "cite"
Moveto [Fator Conversao Embalagem ] Example "fce"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item            ] Example "cite"
Moveto [Unidade Fiscal            ] Example "unf"
Moveto [Unidade Embalagem         ] TypeIn "not = " Example "unf"
Moveto [Vendas_Quantidade         ] Example "qtd"
Moveto [Vendas_Embalagem          ] TypeIn "changeto _qtd/_fce"
Do_It!
ClearAll




;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as \"Vendas_Quantidade\""
Moveto [Vendas_Embalagem       ] Check TypeIn "Calc Sum as \"Vendas_Embalagem\""
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as \"Vendas_Preco Total\""
Moveto [Devolucoes_Quantidade  ] Check TypeIn "Calc Sum as \"Devolucoes_Quantidade\""
Moveto [Devolucoes_Preco Total ] Check TypeIn "Calc Sum as \"Devolucoes_Preco\""
Do_It!
ClearAll

Empty Tabela
Adiciona_Dados_Tabela(Tabela)

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Vendas_Embalagem          ] TypeIn "<=0, changeto blank"
Moveto [Unidade Embalagem         ] TypeIn "changeto Blank"
Do_It!
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Familia *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Familia      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Total_Vendas_Familia   ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (Processa)

;*******************************************************************************
;* Organiza Registro p/ Exibir em Arquivo                                      *
;*******************************************************************************
Proc Gera_Arquivo_Rm3100()
        
Switch
  Case VSDGCODMODELO="15C" : 
        
       {Ask} TypeIn Tabela    Enter 
       Moveto [Codigo da Empresa      ] Check 
       Moveto [Nome Fantasia Empresa  ] Check
       Moveto [Codigo do Item         ] Check
       Moveto [Descricao do Item      ] Check
       Moveto [Unidade Fiscal         ] Check
       Moveto [Descricao do Grupo     ] Check typeIn "as NCM"
       Moveto [Descricao da Marca     ] check typeIn "as CodigoDeBarras"
       Moveto [Vendas_Preco Total     ]       TypeIn "Calc Sum as \"Vendas\""     
       Moveto [Devolucoes_Preco Total ]       TypeIn "Calc Sum as \"Devolucoes\""     
       Do_iT!
       ClearAll
       
       {Ask} {Answer} Check              
       Moveto [Vendas                 ] typein "_v" 
       Moveto [Devolucoes             ] typein "_d, calc _v-_d as Liquido" 
       Do_iT!
       ClearAll               

                                       
       Adiciona_Campo_EmOrdem("Answer","Codigo da Empresa(A4),"+      
                                       "Nome Fantasia Empresa(A20),"+  
                                       "Codigo do Item(A10),"+         
                                       "Descricao do Item(A30),"+
                                       "Unidade Fiscal(A4),"+         
                                       "CodigoDeBarras(A20),"+   
                                       "NCM(A20),"+   
                                       "Vendas($),"+         
                                       "Devolucoes($),"+         
                                       "Liquido($)")                       
                                       
       Delete Tabela
       Rename "Answer" Tabela                                                      
       
EndSwitch       
       
EndProc ;Gera_Arquivo_Rm3100()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_GERENCIA"      : Campo="TG_EMPRESATE" 
            Case Campo="TG_FAMI"          : Campo="TG_GERENCIA"
            Case Campo="TG_GRP"           : Campo="TG_FAMI"
            Case Campo="TG_DTINI"         : Campo="TG_GRP"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPRELCODALF"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"      : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"          : Campo="TG_GRP"
                    Case Campo="TG_GRP"           : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF"   : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("15A  Anal¡tico por Produto/Familia")                       ;RM_3070
ModeloRelatoriosAdd("15B  Sint‚tico por Produto/Familia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("15C  Analitico por Produto - S¢ Pessoa Jur¡dica")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("16A Por Grupo/Produto - Embalagem")                        ;RM_3060
ModeloRelatoriosAdd("1QA Por Grupo/Produto + Transferencias - Embalagem")       ;RM_3063
ModeloRelatoriosAdd("1AA Por Grupo/Produto + Cor - Embalagem")                  ;RM_3062
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("16B Por Grupo/Produto - Volumes")                          ;RM_3060
ModeloRelatoriosAdd("1QB Por Grupo/Produto + Transferencias - Volumes")         ;RM_3063
ModeloRelatoriosAdd("1AB Por Grupo/Produto + Cor - Volumes")                    ;RM_3062
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("42  Por Grupo/Produto + Venda x Custo")                    ;RM_0170
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGFAMI    =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

ModeloRelatoriosCarregaLista()
  
While True

  ShowDialog "Vendas por Produto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Familia"  For "TG_FAMI"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 06,00 "Grupo"  For "TG_GRP"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"    To VSDGGRP
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP     

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Op‡„o de Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf
  
  Switch
    Case VSDGCODMODELO="15A" OR VSDGCODMODELO="15B" Or VSDGCODMODELO="15C" :
         If Ok="A" Then IMPRIME_ARQUIVO = True Else IMPRIME_ARQUIVO=False EndIf
         
         AGUARDE("Aguarde, gerando o relat¢rio")
         Tabela=Cria_Temp(PrivDir())
        
         switch
           case VSDGCODMODELO="15A" : Copy "\\Base\\Sistemas\\Vendas\\RM_3100"  Tabela
           case VSDGCODMODELO="15B" : Copy "\\Base\\Sistemas\\Vendas\\RM_3100a" Tabela
           case VSDGCODMODELO="15C" : Copy "\\Base\\Sistemas\\Vendas\\RM_3100a" Tabela
            
         endswitch
         empty Tabela
          
         Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
         While Novo_Dir_Trab()
           Seleciona()
         EndWhile
         
         If IsEmpty(Tabela)
            Then MENSAGEM("N„o existem registros a processar")
                 Delete Tabela
                 Loop
         EndIf
         Processa()
        
         If IMPRIME_ARQUIVO
            Then If VSDGCODMODELO="15C" 
                    Then Gera_Arquivo_Rm3100()
                 endif    
         EndIf   
         
         Switch
           Case VSDGCODMODELO="15A":  
                If VSDGOPRELCODALF="1"
                  Then IMPRIREL(Tabela,"12")
                  Else IMPRIREL(Tabela,"13")
                EndIf
           Case VSDGCODMODELO="15B":
                IMPRIREL(Tabela,"4")
          Case VSDGCODMODELO="15C":
                IMPRIREL(Tabela,"5")
         EndSwitch
         Delete Tabela
    Case VSDGCODMODELO="16A" : Play "RM_3060a"
    Case VSDGCODMODELO="16B" : Play "RM_3060a"
    Case VSDGCODMODELO="1QA" : Play "RM_3063a"
    Case VSDGCODMODELO="1QB" : Play "RM_3063a"
    Case VSDGCODMODELO="1AA" : Play "RM_3062a"
    Case VSDGCODMODELO="1AB" : Play "RM_3062a"
    Case VSDGCODMODELO="42"  : Play "RM_0170a"     
  EndSwitch
EndWhile
ClearAll
Release Vars All
Release Procs All