;** Rm_0365  *******************************************************************
;*  Emissao de Carregamento por Cidade                                         *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 19/05/2003 por Karen Lauar Nery
;Motivo Alteracao: Mudan‡a Base
;Ultima Alteracao: 10/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO]
                               
;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SELECIONA()
ClearAll
If VSDGCIDADE="TODAS"
   Then VSDGCIDADE2=""
   Else VSDGCIDADE2=VSDGCIDADE
EndIf

{Ask} {FaturaC}
Moveto [Numero da OF           ] Example "of"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Cidade                 ] TypeIn "..~VSDGCIDADE2.."
Moveto [UF                     ] TypeIn "~VSDGESTADO.."
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Descricao CondPagto    ] TypeIn "Not CONTRA APRES.."
;;;Moveto [Origem do Pedido       ] TypeIn "Not BALCAO"
Moveto [Numero Ordem de Volumes] TypeIn "Not Blank"

{Ask} {FaturaI} Check
Moveto [Numero da OF           ] Example "of"

Do_It!
ClearAll

If Not IsEmpty("Answer")
   Then CopyReport "\\Base\\Sistemas\\Vendas\\RM_0365" "R" "Answer" "R"

        Empty("RM_0365a")

        View "Rm_0365a"
        View "FaturaV"
        CoEdit "Answer"
        NOF="****"
        Scan
           If [Numero da OF]<>NOF
              Then NOF=[Numero da OF]
                   Moveto "FaturaV"
                   Moveto [Numero da OF]
                   Locate [Answer->Numero da OF]
                   If RetVal
                      Then i=0
                           Moveto "Rm_0365a"
                           End Down
                           [Numero da OF] = [Answer->Numero da OF]
                           While [Numero da OF] = [Answer->Numero da OF]
                             i=i+1
                             Moveto "Rm_0365a"
                             Execute "[Valor Vencimento " + StrVal(I) +       "] = [FaturaV->Valor]"
                             Execute "[Numero Dias Vencimento " + StrVal(I) + "] = [FaturaV->Numero de Dias]"
                             Execute "[Data Vencimento " + StrVal(I) +        "] = [FaturaV->Data]"

                             Moveto "FaturaV"
                             Skip
                             If EOT()
                                Then QuitLoop
                             Endif
                           EndWhile
                   Endif
                   Moveto "Answer"
           EndIf

        EndScan
        Do_It!
        ClearAll
EndIf
EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc SELECIONA2()
ClearAll
{Ask} {FaturaC}
Moveto [Numero da OF           ] Example "of"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Cidade                 ] TypeIn "..~VSDGCIDADE2.."
Moveto [UF                     ] TypeIn "~VSDGESTADO.."
Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
Moveto [Forma de Pagamento     ] TypeIn "NP"
Moveto [Descricao CondPagto    ] TypeIn "Not CONTRA APRES.."
;;;;Moveto [Origem do Pedido       ] TypeIn "Not BALCAO"
Moveto [Numero Ordem de Volumes] TypeIn "Not Blank"

{Ask} {FaturaV} Check
Moveto [Numero da OF           ] Example "of"

Do_It!
ClearAll

If Not IsEmpty("Answer")
   Then CopyReport "\\Base\\sistemas\\Vendas\\RM_0365B" "R" "Answer" "R"
EndIf

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_CIDADE"        : Campo="TG_EMPRESA"
            Case Campo="TG_ESTADO"        : Campo="TG_CIDADE"
            Case Campo="TG_DTINI"         : Campo="TG_ESTADO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" :Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"  :Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"  :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"   :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"   :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGCIDADE  =""
VSDGESTADO  =""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

While True

  ShowDialog "Relacao de Carregamento por Cidade/Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 11 Width 56

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 26 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Cidade"  For "TG_CIDADE"
    Accept @ 03,01 Width 28 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE

    Label  @ 02,28 "Estado"  For "TG_ESTADO"
    Accept @ 03,29 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO 

    Label  @ 04,00 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 05,00 "de" For "TG_DTINI"
    Accept @ 05,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,17 "at‚" For "TG_DTFIM"
    Accept @ 05,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 07,15 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o Existem Registros a Processar!")
          Loop
  EndIf

  IMPRIREL("Answer","R")

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  SELECIONA2()

  If IsEmpty("Answer")
     Then Loop
  EndIf

  NUMCOPIA=1
  IMPRIREL("Answer","R")

  Delete "Answer"
  Empty("RM_0365a")

EndWhile
ClearAll
Release Vars All
Release Procs All
