;** Rm_3160C *******************************************************************
;* Resumo de Vendas/Custo por Familia/Marca/Produto                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/09/2012 por Bruno Carvalho
;Ultima Alteracao: 17/10/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes layout e processo 
;Ultima Alteracao: 18/10/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao modelo sintetico 
;Ultima Alteracao: 01/07/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao modelo sintetico III
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 20/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_3160D" (1I), "RM_3160E" (1T) neste script "RM_3160C" (85)

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        EndIf
        If Not IsBlank(VSDGFAMI) or
           Not IsBlank(VSDGMARCA)
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] Check TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."   
        If VSDGCODMODELO="1T"
           Then Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
                Moveto [Nome Fantasia Represent] Check
           Else Moveto [Codigo do Representante]       Example "crep" TypeIn ", ~VSDGREPRESEN.."
        EndIf
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"                
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp"
        Moveto [Numero do Documento    ] Check Example "ndoc"
        Moveto [Serie do Documento     ] Check Example "sdoc"
        Moveto [Item do Documento      ] Check
        Moveto [Codigo do Item         ] Check Example "cite"
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] Check
        Moveto [Preco Unitario         ] Check
        Moveto [Preco Total            ] Check
        Moveto [Valor Desconto Total   ] Check
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll
        
        {Ask} {Answer} Check
        Moveto [Descricao da Destinacao] TypeIn "Not ..TRANSF.."
        Do_It!
        ClearAll

        Adiciona_Dados("VENDAS")
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Numero do Documento    ] Example "numd"
If VSDGCODMODELO="1T"
   Then Moveto [Codigo do Representante] Example "crep"
        Moveto [Nome Fantasia Represent] Example "nrep"
EndIf
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Unitario         ] Example "prun"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"    
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
If VSDGCODMODELO="1T"
   Then Moveto [Codigo do Representante] Example "crep"
        Moveto [Nome Fantasia Represent] Example "nrep"
EndIf
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Vendas_Embalagem       ] Example "prun"   
Moveto [Descricao da Destinacao] Example "numd"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Quantidade      ] Example "qtde"
       Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
  Case Tipo="DEVOLUCOES":
       Moveto [Vendas_Quantidade      ] TypeIn "_qtde*-1"
       Moveto [Vendas_Preco Total     ] TypeIn "(_ptot-_vdes)*-1"
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf
             
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Unidade Embalagem      ] Example "une"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Descricao da Familia   ] Example "dfam"
Switch
  Case VSDGCODMODELO="1I" Or  VSDGCODMODELO="1T" :
       Moveto [Codigo da Marca        ] Example "cmar"
       Moveto [Descricao da Marca     ] Example "dmar"
       Moveto [Codigo Fornecedor      ] Example "codf"
EndSwitch
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Moveto [Unidade Embalagem      ] TypeIn "changeto _une"
Moveto [Codigo da Familia      ] TypeIn "changeto _cfam"
Moveto [Descricao da Familia   ] TypeIn "changeto _dfam"
Switch
  Case VSDGCODMODELO="1T" :
       Moveto [Codigo da Marca        ] TypeIn "changeto _cmar"
       Moveto [Descricao da Marca     ] TypeIn "changeto _dmar"
       Moveto [Descricao CondPagto    ] TypeIn "changeto _codf" ;Codigo do Fornecedor (Ir  constar apenas uma ocorrˆncia)
  Case VSDGCODMODELO="1I" :    
       Moveto [Codigo da Marca        ] TypeIn "changeto _cmar"
       Moveto [Descricao da Marca     ] TypeIn "changeto _dmar"
       Moveto [Nome Fantasia Represent] TypeIn "changeto _codf" ;Codigo do Fornecedor (Ir  constar apenas uma ocorrˆncia)       
EndSwitch
Do_It!
ClearAll    

;***** Tabela de Preco*********
{Ask} {\\Sistemas\\Vendas\\TbPrite}
Moveto [Codigo da Tabela         ] TypeIn "~VSDGTABELA"
Moveto [Codigo do Item           ] example "item"
Moveto [Preco Unitario           ] example "vr"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item           ] example "item"
Moveto [Total_Vendas_TipoItem    ] TypeIn "Changeto " example "vr"
Do_It!
ClearAll

;***** Calculos **********
CoEdit Tabela
Scan
  [Vendas_Embalagem     ]=Round([Vendas_Preco Total       ]/[Vendas_Quantidade],2)
  [Total_Vendas_Area    ]=Round([Total_Vendas_TipoItem    ]*[Vendas_Quantidade],2)
EndScan
Do_It!
ClearAll 
             
EndProc    ;  (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"  
            Case Campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
            Case Campo="TG_FAMI"          : Campo="TG_GERENCIA"
            Case Campo="TG_MARCA"         : Campo="TG_FAMI"
            Case Campo="TG_TABELA"        : Campo="TG_MARCA"
            Case Campo="TG_DTINI"         : Campo="TG_TABELA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELANALSINT" : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPRELANALSINT"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog       
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"   : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"    : Campo="TG_GERENCIA"  
                    Case Campo="TG_GERENCIA"    : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"        : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_TABELA"
                    Case Campo="TG_TABELA"      : 
                         If IsBlank(VSDGTABELA)
                            Then VSDGNOMTAB=""
                                 Campo="TG_TABELA" 
                            Else Campo="TG_DTINI"         
                         EndIf     
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_OPRELANALSINT"
                    Case Campo="TG_OPRELANALSINT" : Campo="TG_CODMODELO"
                         VSDGOPRELANALSINT=ControlValue("TG_OPRELANALSINT")
                         If IsBlank(VSDGOPRELANALSINT)
                            Then VSDGOPRELANALSINT="1"
                         EndIf   
                         Switch
                           Case VSDGOPRELANALSINT="1" : VSDGNOMOPRELANALSINT="ANALITICO"
                           Case VSDGOPRELANALSINT="2" : VSDGNOMOPRELANALSINT="SINTETICO"
                           Case VSDGOPRELANALSINT="3" : VSDGNOMOPRELANALSINT="SINTETICO II"
                           Case VSDGOPRELANALSINT="4" : VSDGNOMOPRELANALSINT="SINTETICO III"
                         EndSwitch 
                    Case Campo="TG_CODMODELO"         : Campo="YES"      
                  EndSwitch
          EndIf
          RefreshDialog                                           
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
  Case Campo="TG_OPRELANALSINT":
     MSG_CAMPO="1-Analitico 2-Sintetico 3-Sintetico II 4-Sintetico III"
  Case Campo="TG_TABELA":
     MSG_CAMPO="Informe uma tabela"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc


;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("85  Comparativo de Venda x Tabela de Pre‡o - Fam¡lia/Marca")    ;RM_3160C
ModeloRelatoriosAdd("1I  Comparativo de Venda x Tabela de Pre‡o - Marca/Fam¡lia")    ;RM_3160D
ModeloRelatoriosAdd("1T  Comparativo de Venda x Tabela de Pre‡o - Vendedor/Marca")   ;RM_3160E
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA      = ""
VSDGFAMI         = ""
VSDGGRUP         = ""
VSDGCODMODELO    = ""
VSDGMODELO       = ""
VSDGREPRESEN     = ""
VSDGNOMREPR      = ""
VSDGGERENCIA     = ""
VSDGDESCGERENCIA = ""
VSDGDTINI        = BlankDate()
VSDGDTFIM        = BlankDate()

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Vendas/Vr Ref. por Familia/Marca/Produto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 22 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP
    
    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN"  To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR
                                                           
    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA    
    
    Label  @ 06,00 "Familia"  For "TG_FAMI"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 08,01 "Marca"  For "TG_MARCA"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 09,09 Width 25 "A24" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 10,00 "Tabela de Pre‡o"  For "TG_TABELA"
    Accept @ 11,01 Width 08 "A5"  Picture "#*#" Tag "TG_TABELA"    To VSDGTABELA
    Accept @ 11,09 Width 25 "A70" Picture "!*!" Tag "TG_NOMTAB" To VSDGNOMTAB
                      
    Label  @ 12,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 13,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 13,16 "at‚" For "TG_DTFIM"
    Accept @ 13,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    @ 11,01 ?? "** Sem Transferencias **"

    Label  @ 15,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 16,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 16,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO
    
    Label  @ 00,35 "Op‡„o do Relat¢rio" For "TG_OPRELANALSINT"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPRELANALSINT" To VSDGOPRELANALSINT
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELANASINT" To VSDGNOMOPRELANALSINT
    
    Pushbutton @ 18,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If VSDGOPRELANALSINT="4" And VSDGCODMODELO<>"85"
     Then Mensagem("Modelo Sint‚tico III espec¡fico para o relat¢rio 85!")
          Loop
  EndIF        

  If IsBlank(VSDGTABELA)
     Then Mensagem("Tabela de Pre‡o deve ser informada !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  VSDGMES=AlinhM(StrVal(Month(VSDGDTFIM)),2)
  VSDGANO=StrVal(Year(VSDGDTFIM))

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\RM_3104"
  Copy "\\Base\\Sistemas\\Vendas\\RM_3104" Tabela

  Tabela2=Cria_Temp(PrivDir())
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()
  
  Switch
    Case VSDGCODMODELO="85" :
         Switch
           Case VSDGOPRELANALSINT="1": IMPRIREL(Tabela,"2")
           Case VSDGOPRELANALSINT="2": IMPRIREL(Tabela,"3")
           Case VSDGOPRELANALSINT="3": IMPRIREL(Tabela,"7")
           Case VSDGOPRELANALSINT="4": IMPRIREL(Tabela,"11")
         EndSwitch
    Case VSDGCODMODELO="1I" :
         Switch
            Case VSDGOPRELANALSINT="1": IMPRIREL(Tabela,"4")
            Case VSDGOPRELANALSINT="2": IMPRIREL(Tabela,"6")
            Case VSDGOPRELANALSINT="3": IMPRIREL(Tabela,"5")
         EndSwitch
    Case VSDGCODMODELO="1T" :
         Switch
            Case VSDGOPRELANALSINT="1": IMPRIREL(Tabela,"8")
            Case VSDGOPRELANALSINT="2": IMPRIREL(Tabela,"9")
            Case VSDGOPRELANALSINT="3": IMPRIREL(Tabela,"10")
         EndSwitch    
  EndSwitch
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
