;** Rm_0120 ********************************************************************
;*  Relatorio de Fornecedores com compras no periodo informado                 *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 22/03/2012 por Bruno Carvalho 
;Ultima Alteracao: 18/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 11/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO]
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 08/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   

;*******************************************************************************
;* Rotina p/ Selecionar Estoque                                                *
;*******************************************************************************
Proc Sel_Estoque()
ClearAll

If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC")
   Then {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
        Moveto [Numero do Lancamento] Check
        Moveto [Codigo da Empresa      ] Check
        Moveto [Numero do Documento    ] Check
        Moveto [Serie do Documento     ] Check 
        Moveto [Codigo                 ] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Do_It!
        ClearAll
EndIf

If Not IsEmpty("Answer")
   Then {Ask} {Answer} Check
        Moveto [Numero do Lancamento] Example "NLanc"
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
        Moveto [Numero do Lancamento] Example "NLanc"
        Moveto [Quantidade          ] TypeIn "Calc Sum as Quantidade"
        Do_It!
        ClearAll
EndIf

EndProc   ;Sel_Estoque()

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Estoque\\Cotacao}
Moveto [Codigo        ] Example "COD"
Moveto [Data de Compra] TypeIn "Calc Max as Data da Ultima Compra"

{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Check TypeIn "~VSDGCLIENTE.. ," Example "COD" TypeIn "!" ;
Moveto [Tipo                   ] TypeIn "F"
Moveto [Razao Social           ] Check
Moveto [Cidade                 ] Check
If UPPER(VSDGCIDADE)<>"TODAS"
   Then TypeIn VSDGCIDADE
EndIf
Moveto [UF                     ] Check TypeIn "~VSDGESTADO.."
Moveto [Telefone               ] Check
Moveto [Contato                ] Check
Moveto [Endereco               ] Check
Moveto [Bairro                 ] Check
Moveto [CEP                    ] Check
Moveto [Celular                ] Check 
Do_It!
ClearAll

{Ask} {Answer} Check
Moveto [Codigo                  ] Example "COD"
{Ask} TypeIn Tabela Enter
Moveto [Codigo                  ] Example "COD"
Moveto [Quantidade              ] TypeIn "Calc Sum as Quantidade"
Do_It!
ClearAll

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_CIDADE"        : Campo="NO"
            Case Campo="TG_ESTADO"        : Campo="TG_CIDADE"
            Case Campo="TG_CLIENTE"       : Campo="TG_ESTADO"
            Case Campo="TG_DTINI"         : Campo="TG_CLIENTE"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALF"   : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPRELCODALF"
            Case Campo="YES" Or Campo="NO": Campo="TG_CIDADE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_CIDADE"     :Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"     :Campo="TG_CLIENTE"
                    Case Campo="TG_CLIENTE"    :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      :Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF":Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a Data Inicial do Periodo"
  Case Campo="TG_DTFIM":
       MSG_CAMPO="Informe a Data Final do Periodo"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Cidade/Fornecedor")
ModeloRelatoriosAdd("01B Por Cidade/Fornecedor + Endere‡o")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*****************************************************************************+*
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGDTINI       = BlankDate()
VSDGDTFIM       = BlankDate()
VSDGCIDADE      = ""
VSDGESTADO      = ""
VSDGREPRESEN    = ""
VSDGOPRELCODALF = ""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Fornecedores com compras no per¡odo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,09   Height 14 Width 72

    Label  @ 00,00 "Cidade"  For "TG_CIDADE"
    Accept @ 01,01 Width 27 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE
                                   
    Label  @ 00,27 "Estado"  For "TG_ESTADO"
    Accept @ 01,28 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO    

    Label  @ 02,00 "Fornecedor"  For "TG_CLIENTE"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_CLIENTE" To VSDGCLIENTE
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLIE"  To VSDGNOMCLIE

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Ordem" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 07,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 08,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 08,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 10,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf  
  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  If VSDGDTFIM < VSDGDTINI
     Then Mensagem("Data Final deve ser maior que Data Inicial !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Sel_Estoque()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  Seleciona()
                 
  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Delete "Answer"
          Loop
  EndIf                     

  Switch
    case VSDGCODMODELO="01" :   
         If VSDGOPRELCODALF="1"
            Then CopyReport "\\Base\\Sistemas\\Estoque\\Rm_0110" "4" "Answer" "R"
            Else CopyReport "\\Base\\Sistemas\\Estoque\\Rm_0110" "5" "Answer" "R"
         EndIf
    case VSDGCODMODELO="01B" :   
      If VSDGOPRELCODALF="1"
         Then CopyReport "\\Base\\Sistemas\\Estoque\\Rm_0110" "8" "Answer" "R"
         Else CopyReport "\\Base\\Sistemas\\Estoque\\Rm_0110" "9" "Answer" "R"
      EndIf
  endswitch
  IMPRIREL("Answer","R")

  If IsTable(Tabela)       Then Delete Tabela   EndIf

EndWhile
ClearAll
Release Vars All
Release Procs All
