;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bib_Proc"

;Gera uma ASK com dados dos itens, com pre‡o de venda, ultimo custo entre outros
;Usar CTRL + P para gertar a "ANSWER" em Excel

If Not ConfGeral("Ja foi realizado o Reprocessamento?")
   Then Return
EndIf        

EMPRESA  = "0001"
TBPRECO  = "00001"
ANO      = "2020"
MES      = "03"
Debug

SetDir "\\Sistemas\\Estoque"
Copy "Cotacao" "A_COT"

;---- Itens --------------------------------------------------------------------
{Ask} {Itens}
Moveto [Codigo do Item   ] Check TypeIn "as Codigo"
Moveto [Descricao do Item] Check TypeIn "as Descricao"
Moveto [Unidade Interna  ] Check TypeIn "as UnInterna"
Do_it!
debug
ClearAll

Tabela=Adiciona_Indice_Temp("Codigo")

;---- Saldo de Estoque ---------------------------------------------------------
{Ask} TypeIn Tabela Enter Check
Moveto [Codigo           ]       TypeIn "_Item" 
{Ask} {Sdestq}
Moveto [Codigo da Empresa]       TypeIn EMPRESA
Moveto [Codigo do Item   ]       TypeIn "_Item"
Moveto [Ano Referencia   ]       TypeIn ANO
Moveto [Mes Referencia   ]       TypeIn MES
Moveto [Saldo Atual      ] Check TypeIn "as Saldo"
Moveto [Custo Total Atual] Check TypeIn "as CustTot"
Do_it!
ClearAll

CRIAR_TABELA = False
Adiciona_Campo("Answer","CustUnit($),"+
                        "PrVenda($),"+
                        "PrUltCompra($),"+     
                        "UnUltCompr(A2)")
                                                
Tabela=Adiciona_Indice_Temp("Codigo")

;---- Ajustando o Custo Unitario da Saldo de Estoque ---------------------------
{Ask} TypeIn Tabela Enter
Moveto [Saldo       ]       TypeIn "_Estq"
Moveto [CustTot     ]       TypeIn "_Cust"
Moveto [CustUnit    ]       TypeIn "Changeto _Cust/_Estq"
Do_it!
ClearAll

;---- Pre‡o de Vendas ----------------------------------------------------------
{Ask} {\\Sistemas\\Vendas\\TbPrIte}
Moveto [Codigo da Tabela    ]       TypeIn TBPRECO
Moveto [Codigo do Item      ]       TypeIn "_Item"
Moveto [Preco Unitario      ]       TypeIn "_Preco"
{Ask} TypeIn Tabela Enter
Moveto [Codigo              ]       TypeIn "_Item"
Moveto [PrVenda             ]       TypeIn "Changeto _Preco"
Do_it!
ClearAll 

;---- Cota‡Æo ------------------------------------------------------------------
{Ask} {A_Cot}
Moveto [Codigo do Item      ] Check
Moveto [Data de Compra      ]       TypeIn "Calc Max as Data"
Do_it!
ClearAll

{Ask} {Answer}
Moveto [Codigo do Item      ]       TypeIn "_Item"
Moveto [Data                ]       TypeIn "_Data"
{Ask} {A_Cot}
Moveto [Codigo do Item      ] Check TypeIn "_Item"
Moveto [Data de Compra      ] Check TypeIn "_Data, as Data"
Moveto [Unidade Entrada     ] Check
Moveto [Valor Unitario      ] Check
Do_it!
ClearAll

{Ask} {Answer}
Moveto [Codigo do Item      ]       TypeIn "_Item"
Moveto [Data                ]       TypeIn "_Data"
Moveto [Valor Unitario      ]       TypeIn "_Vr, Changeto _Vr / _FtC"
{Ask} {A_Cot}
Moveto [Codigo do Item      ]       TypeIn "_Item"
Moveto [Data de Compra      ]       TypeIn "_Data"
Moveto [Fator de Conversao  ]       TypeIn "_FtC"
Do_it!
ClearAll

{Ask} {Answer}
Moveto [Codigo do Item           ]       TypeIn "_Item"
Moveto [Unidade Entrada          ]       TypeIn "_UnE"
Moveto [Valor Unitario           ]       TypeIn "_VrU"
{Ask} TypeIn Tabela Enter
Moveto [Codigo                   ]       TypeIn "_Item"
Moveto [PrUltCompra              ]       TypeIn "Changeto _VrU"
Moveto [UnUltCompr               ]       TypeIn "Changeto _UnE"
Do_it!
ClearAll

Delete "A_COT"

Copy Tabela "A1"
View Tabela
