;** Rm_0310 ********************************************************************
;*  Emissao dos Titulos Pagos por Conta                                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 13/11/2003 por Anivel Augusto Rodrigues
;Ultima Alteracao: 25/02/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo da Baixa
;Ultima Alteracao: 20/06/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Opcao de Data
;Ultima Alteracao: 28/09/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado Filtro por Tipo de Pagamento
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 13/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0320" (19) neste script "RM_0310" (18)                   
;Ultima Alteracao: 01/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de pagamento
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivad
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 14/02/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes agrupamento RM_0310, RM_0100, RM_0110       

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()

ClearAll

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos") And
   IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa")
   Then
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
        Moveto [Codigo            ] example "cemit"
        Moveto [Codigo Atividade  ] TypeIn "~VSDGATIVIDADE.."
        If IMPRIME_ARQUIVO
           Then Moveto [CGC       ] Check
        EndIf    
   
       {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
        Moveto [Numero do Lancamento  ] TypeIn "_lanc"
        Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Emitente    ] example "cemit" TypeIn ", ~VSDGDESTINAT.."
        Switch
          Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
          Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
        EndSwitch
        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa" Enter Check
        Moveto [Numero do Lancamento] TypeIn "_lanc"
        If VSDGOPDT="P"
           Then Moveto [Data do Pagamento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
           Else Moveto [Data_Inclusao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndIf
        Moveto [Codigo da Conta     ] TypeIn "~VSDGCONTA.."
        Moveto [Tipo da Baixa       ] TypeIn "Blank or NORMAL"
        Do_It!
        ClearAll
EndIf

EndProc  ;  (Seleciona)

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

EndProc

;*******************************************************************************
;* Rotina para Ajustar Dados a ser exibidos em arquivo                         *
;*******************************************************************************
Proc Ajusta_Dados()

{Ask} TypeIn Tabela Enter Check
Moveto [Pag_1                 ] Check
Moveto [Pag_2                 ] Check
Moveto [Pag_3                 ] Check
Moveto [Pag_4                 ] Check
Moveto [Codigo_Usuario        ] Check
Moveto [Data_Inclusao         ] Check
Moveto [Hora_Inclusao         ] Check
Moveto [Numero_Controle_Dia   ] Check
Moveto [Sistema Gerador       ] Check
Moveto [Lancamento Gerador    ] Check
Moveto [Sequencia Gerador     ] Check
Moveto [Documento Referente   ] Check
Moveto [Tem Rateio            ] Check
Moveto [Numero do Lancamento-1] Check
Moveto [Codigo da Empresa-1   ] Check
Moveto [Codigo_Usuario-1      ] Check
Moveto [Data_Inclusao-1       ] Check
Moveto [Hora_Inclusao-1       ] Check
Moveto [Numero_Controle_Dia-1 ] Check
Moveto [Tem Rateio-1          ] Check
Do_It!
ClearAll

Copy "Answer" Tabela
Adiciona_campo(Tabela,"Documento(A20),Tarifa(A10)")
ClearAll

CoEdit Tabela
Scan
  Barra(NRecords(Tabela), RecNo())
  Aguarde("Aguarde, ajustando dados "+BARRA_STRING)
  
  NDOC = [Numero do Documento]
  For ii From 1 To 2 
    Switch
      Case ii=1 :PosI = Search("/",NDOC)
      Case ii=2 :PosI = Search("-",NDOC)
    EndSwitch
    If PosI>0
       Then NDOC = SubStr(NDOC,1,PosI-1)
            QuitLoop
    EndIf
  EndFor
  [Documento] = NDOC
EndScan
Do_it!
ClearAll

Copy Tabela "Answer"
Delete Tabela
Tabela=Adiciona_Indice_Temp("Numero do Lancamento,Sequencia da Baixa,Codigo da Empresa,Nome Fantasia Empresa,Codigo do Emitente,Nome Fantasia EmitDest,CGC,Documento")

EndProc ;Ajusta_Dados()


;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DESTINAT"      : Campo="TG_CONTA"
            Case Campo="TG_ATIVIDADE"     : Campo="TG_DESTINAT"
            Case Campo="TG_TPPAGTO"       : Campo="TG_ATIVIDADE"
            Case Campo="TG_OPDT"          : Campo="TG_TPPAGTO"
            Case Campo="TG_DTINI"         : Campo="TG_OPDT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE" : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"     : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"  : Campo="TG_ATIVIDADE"
                    Case Campo="TG_ATIVIDADE" : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"   : Campo="TG_OPDT" 
                    Case Campo="TG_OPDT"      : Campo="TG_DTINI"
                         VSDGOPDT=ControlValue("TG_OPDT")
                         Switch
                           Case VSDGOPDT="I": VSDGDESCOPDT="DATA DE INCLUSAO"
                           OtherWise        : VSDGOPDT="P"
                                              VSDGDESCOPDT="DATA DE PAGAMENTO"
                         EndSwitch
                    Case Campo="TG_DTINI"     : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPDT":
     MSG_CAMPO="Op‡„o: P=Pagamento I=Inclus„o "
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("09  Por Emitente/Data de Pagamento")                       ;RM_0100   
ModeloRelatoriosAdd("09A Por Emitente/Data de Pagamento+Observa‡äes")           ;RM_0100   
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("18  Por Conta/Data de Pagamento/Pessoa")                   ;RM_0310   
ModeloRelatoriosAdd("19  Por Conta/Data de Pagamento/Pessoa II")                ;RM_0320
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("10  Por Data de Pagamento/Documento")                      ;RM_0110   

ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()
sys_Valor()

VSDGEMPRESA  =""
VSDGCONTA    =""
VSDGDESTINAT =""
VSDGATIVIDADE=""

VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()

ModeloRelatoriosCarregaLista()

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPPAGTO]")

While True
  ShowDialog "T¡tulos Pagos por ?" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"   
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 06,00 "Atividade"  For "TG_ATIVIDADE"
    Accept @ 07,01 Width 07 "A4"  Picture "!*!" Tag "TG_ATIVIDADE" To VSDGATIVIDADE
    Accept @ 07,09 Width 25 "A30"  Picture "#*#" Tag "TG_NOMATIV" To VSDGNOMATIV

    Label  @ 08,00 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 09,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 00,35 "Op‡äes de Datas" For "TG_OPDT"
    Accept @ 01,39 Width 04 "A1"  Picture "P,I" Tag "TG_OPDT" To VSDGOPDT
    Accept @ 01,44 Width 25 "A20"  Picture "!*!" Tag "TG_DESCOPDT" To VSDGDESCOPDT

    Label  @ 02,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO    

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf
  
  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf
  If Ok="A" 
     Then IMPRIME_ARQUIVO=True 
     Else IMPRIME_ARQUIVO=False 
  EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  
  Processa()
  
  Switch
    Case VSDGCODMODELO="18" : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1010" "8" Tabela "R" 
    Case VSDGCODMODELO="19" : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1010" "9" Tabela "R"   

    Case VSDGCODMODELO="09"  or   
         VSDGCODMODELO="09A" :    
         switch 
           Case IMPRIME_ARQUIVO     : Ajusta_Dados() 
           case VSDGCODMODELO="09"  : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1010" "2"  Tabela "R"  
           case VSDGCODMODELO="09A" : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1010" "13" Tabela "R"   
         endswitch 
         
    Case VSDGCODMODELO="10" : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1010" "4" Tabela "R"   

  EndSwitch
  IMPRIREL(Tabela,"R")
  
  Delete Tabela
EndWhile
ClearAll
Release Vars All
Release Procs All
