;** GR_0019 ********************************************************************
;*  Grafico de Faturamento Mensal por Representante/Marca                      *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/09/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 14/08/2006 por Davi Carrano
;Motivo Alteracao: Criar Meses em branco para o grafico ficar completo
;Ultima Alteracao: 03/12/2007 por Nikolas
;Motivo Alteracao: ajustes
;Ultima Alteracao: 19/09/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes 0000 TOTAL EMPRESAS
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 03/10/2012 por Kamila Gomes          
;Motivo Alteracao: Ajustes rotina Processa e Titulos dos graficos
;Ultima Alteracao: 29/01/2014 por Andrey Fillipe          
;Motivo Alteracao: Adicionado filtro Op‡Æo de Visualiza‡Æo 
;Ultima Alteracao: 05/08/2015 por Andrey Fillipe          
;Motivo Alteracao: Adicionado filtro por Gerencia  
;Ultima Alteracao: 03/06/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Logica
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog    
;Ultima Alteracao: 03/01/2017 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog MensagemRadioButtons()                
;Ultima Alteracao: 17/05/2017 por Bruno Carvalho
;Motivo Alteracao: Alterado GR_0005 -> GR_0008 *GR_0005 pertence a outra estrutura que foi modificada gerando erros
;                  foi entÆo criado a GR_0008 p/ pertencer a estrutura alterada, mantendo a GR_0005 original 
;Ultima Alteracao: 07/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then If VSDGOPAG=1 Or VSDGOPAG=3 Or VSDGOPAG=4 Then
           {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           {Ask} {\\Sistemas\\Estoque\\Itens}
           Moveto [Codigo do Item         ] Example "ite"
           Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
           {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
           Moveto [Codigo da Empresa      ] Check Example "empr" TypeIn ", ~VSDGEMPRESA2.."
           Moveto [Numero do Documento    ] Check Example "ndoc"
           Moveto [Serie do Documento     ] Check Example "sdoc"
           Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
           Moveto [Descricao da Destinacao] TypeIn "..VEND.. Or ..SAIDA.. Or ..SERV.."
           Moveto [Situacao               ] TypeIn "Not C"
           Moveto [Tipo Movimento Estoque ] Check TypeIn "S"
           Moveto [Codigo do Representante ] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
           {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
           Moveto [Codigo da Empresa      ] Example "empr"
           Moveto [Numero do Documento    ] Example "ndoc"
           Moveto [Serie do Documento     ] Example "sdoc"
           Moveto [Item do Documento      ] Check
           Moveto [Codigo do Item         ] Example "ite"
           Moveto [Preco Total            ] Example "prt"
           Moveto [Valor Desconto Total   ] Example "dst" TypeIn ", Calc _prt-_dst as Valor Liquido"
           Moveto [Situacao_Item          ] TypeIn "Not C"
           Do_It!
           ClearAll
           
           {Ask} {Answer}
           Moveto [Data de Emissao        ] Check
           Moveto [Valor Liquido          ] TypeIn "Calc Sum as Valor Total"
           Moveto [Tipo Movimento Estoque ] Check
           Do_It!
           ClearAll
           
           Processa()
        EndIf
        
        If VSDGOPAG=2 Or VSDGOPAG=3 Or VSDGOPAG=4 Then
           {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           {Ask} {\\Sistemas\\Estoque\\Itens}
           Moveto [Codigo do Item         ] Example "ite"
           Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
           {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
           Moveto [Codigo da Empresa      ] Check Example "empr" TypeIn ", ~VSDGEMPRESA2.."
           Moveto [Numero do Documento    ] Check Example "ndoc"
           Moveto [Serie do Documento     ] Check Example "sdoc"
           Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
           Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
           Moveto [Situacao               ] TypeIn "Not C"
           Moveto [Tipo Movimento Estoque ] Check TypeIn "E"
           Moveto [Codigo do Representante ] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
           {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
           Moveto [Codigo da Empresa      ] Example "empr"
           Moveto [Numero do Documento    ] Example "ndoc"
           Moveto [Serie do Documento     ] Example "sdoc"
           Moveto [Item do Documento      ] Check
           Moveto [Codigo do Item         ] Example "ite"
           Moveto [Preco Total            ] Example "prt"
           Moveto [Valor Desconto Total   ] Example "dst" TypeIn ", Calc _prt-_dst as Valor Liquido"
           Moveto [Situacao_Item          ] TypeIn "Not C"
           Do_It!
           ClearAll
           
           {Ask} {Answer}
           Moveto [Data de Emissao        ] Check
           Moveto [Valor Liquido          ] TypeIn "Calc Sum as Valor Total"
           Moveto [Tipo Movimento Estoque ] Check
           Do_It!
           ClearAll
           
           Processa()
        EndIf
EndIf
EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA2()
ClearAll

If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then
        If VSDGOPAG=2 Or VSDGOPAG=3 Or VSDGOPAG=4 Then
           {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           {Ask} {\\Sistemas\\Estoque\\Itens}
           Moveto [Codigo do Item         ] Example "ite"
           Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
           {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
           Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
           Moveto [Numero do Lancamento   ] Example "nlan"
           Moveto [Data de Entrada        ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM, as Data de Emissao"
           Moveto [Tipo de Operacao       ] Check TypeIn "D, as Tipo Movimento Estoque"
           Moveto [Codigo do Representante ] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
           {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
           Moveto [Numero do Lancamento   ] Example "nlan"
           Moveto [Codigo do Item         ] Example "ite"
           Moveto [Preco Total            ] Example "prt"
           Moveto [Valor Desconto Total   ] Example "dst" TypeIn ", Calc _prt-_dst as Valor Liquido"
           Do_It!
           ClearAll

           {Ask} {Answer}
           Moveto [Data de Emissao        ] Check
           Moveto [Valor Liquido          ] TypeIn "Calc Sum as Valor Total"
           Moveto [Tipo Movimento Estoque ] Check
           Do_It!
           ClearAll

           Processa()
        EndIf
EndIf
EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Cria_Registros()
ClearAll

Mes_Aux=NumVal(MESINI)
Ano_Aux=NumVal(ANOINI)
CoEdit PrivDir()+"GR_0008A"
For wi From 1 to 13
    End Down
    [Ano          ]=Ano_Aux
    [Mes          ]=Mes_Aux
    [MesExt       ]=mesext(NumVal(Mes_Aux))
    [Valor 1]=0
    [Valor 2]=0
    If Mes_Aux = 12 
       Then Mes_Aux=0
            Ano_Aux=Ano_Aux+1
    EndIf
    Mes_Aux=Mes_Aux+1
EndFor
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc PROCESSA()
ClearAll

View PrivDir()+"GR_0008a"
CoEdit "Answer"
Scan
   If IsBlank([Data de Emissao]) Then Loop EndIf
   Moveto PrivDir()+"GR_0008a"
   Moveto [Ano]
   Locate Year([Answer->Data de Emissao]),Month([Answer->Data de Emissao])
   If Not RetVal
      Then End Down
           [Ano   ]=Year ([Answer->Data de Emissao])
           [Mes   ]=Month([Answer->Data de Emissao])
   EndIf
   If [Answer->Tipo Movimento Estoque]="S"
      Then [Valor 1]=[Valor 1]+[Answer->Valor Total]
      Else [Valor 2]=[Valor 2]+[Answer->Valor Total]
   EndIf
   Moveto "Answer"
EndScan
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc PROCESSA2()
ClearAll

VRTOTAL=0 
VRTOTALDEV=0 
{Ask} TypeIn PrivDir()+"GR_0008a" Enter Check
Do_It!
ClearAll

View PrivDir()+"GR_0008"
CoEdit "Answer"
Scan
   CopytoArray Reg
   
   Moveto PrivDir()+"GR_0008"
   End Down
   [Mes        ]=StrVal(Reg["Ano"])+"/"+Substr(mesext(NumVal(Reg["Mes"])),1,3)
   Switch
      Case VSDGOPAG=1: [Valor 1 ] =Reg["Valor 1"]
                       VRTOTAL    =VRTOTAL+[Valor 1]
      Case VSDGOPAG=2: [Valor 1 ] =Reg["Valor 2"]
                       VRTOTAL    =VRTOTAL+[Valor 1]
      Case VSDGOPAG=3: [Valor 1 ] =Reg["Valor 1"]
                       [Valor 2 ] =Reg["Valor 2"]
                       VRTOTAL    =VRTOTAL+[Valor 1]
                       VRTOTALDEV =VRTOTALDEV+[Valor 2]
      Case VSDGOPAG=4: [Valor 1 ] =Reg["Valor 1"]-Reg["Valor 2"]
                       VRTOTAL    =VRTOTAL+[Valor 1]
   EndSwitch
   
   Moveto "Answer"
EndScan

Do_It!
ClearAll

If VSDGOPAG<>3 Then
   {Ask} TypeIn PrivDir()+"GR_0008" Enter
   Moveto [Mes    ] Example "dd"
   Moveto [Valor 1] Example "vr"
   {Ask} TypeIn PrivDir()+"GR_0008b" Enter TypeIn "Fast Insert"
   Moveto [Mes    ] Example "dd"
   Moveto [Valor 1] Example "vr"
   Do_It!
   ClearAll
EndIf

EndProc
 
;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_GERENCIA"      : Campo="TG_EMPRESA"
            Case Campo="TG_REPRESEN"      : Campo="TG_GERENCIA"
            Case Campo="TG_MARCA"         : Campo="TG_REPRESEN"
            Case Campo="TG_MESANO"        : Campo="TG_MARCA"
            Case Campo="TG_OPAG"          : Campo="TG_MESANO"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     :Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"    :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"    :Campo="TG_MARCA" 
                    Case Campo="TG_MARCA" :
                         If Not IsBlank(VSDGMARCA)
                            Then Campo="TG_MESANO"
                            Else VSDGNOMMARCA=""
                         Endif
                    Case Campo="TG_MESANO" : Campo="TG_OPAG"
                    Case Campo="TG_OPAG"   : Campo="YES"
                         VSDGOPAG=ControlValue("TG_OPAG")
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_REPRESEN":
     MSG_CAMPO="Informe um Representante"
  Case Campo="TG_MARCA":
     MSG_CAMPO="Informe uma Marca"
  Case Campo="TG_OPAG":
       MensagemRadioButtons()
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGREPRESEN=""
VSDGMARCA   =""
VSDGMESANO = AlinhM(StrVal(Month(Today())),2)+"."+AlinhM(StrVal(Year(Today())),4)
VSDGOPAG    =1

While True
  ShowDialog "Evolu‡„o das vendas mensais por Representante/Marca" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 06,12   Height 15 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_REPRESEN"   To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"    To VSDGNOMREPR

    Label  @ 06,00 "Marca" For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA" To VSDGMARCA
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_MARCA" To VSDGNOMMARCA

    Label  @ 08,00 "At‚ Mes/Ano" For "TG_MESANO"
    Accept @ 09,01 Width 10 "A7"  Picture "##;.####" Tag "TG_MESANO" To VSDGMESANO

    Label  @ 00,35 "Op‡Æo de Visualiza‡Æo: "  For "TG_OPAG"
    RadioButtons @ 01,35 Height 5 Width 33
     "~V~endas",
     "~D~evolu‡”es",
     "~A~mbos [V/D]",
     "~L~¡quido [V-D]"
     Tag "TG_OPAG"
     To VSDGOPAG

    Pushbutton @ 11,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 11,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGEMPRESA=""
     Then Mensagem("Empresa Invalida !")
          Loop
  EndIf
  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf
  
  MES=Substr(VSDGMESANO,1,2)
  ANO=Substr(VSDGMESANO,4,4)
  If NumVal(MES) > 12 Or NumVal(MES) <= 0
     Then Loop
  EndIf

  MESINI=AlinhM(StrVal((NumVal(MES))),2)
  ANOINI=StrVal((NumVal(ANO)-1))
  VSDGDTINI=DateVal(MESINI+"/"+"01"+"/"+ANOINI)

  MESFIM=AlinhM(StrVal((NumVal(MES)+1)),2)
  If NumVal(MESFIM)=13
     Then MESFIM="01"
          ANOFIM=StrVal((NumVal(ANO)+1))
     Else ANOFIM=ANO
  EndIf
  VSDGDTFIM=DateVal(MESFIM+"/"+"01"+"/"+ANOFIM)-1

  DISPOSITIVOG()
  If OK="" Then Loop EndIf

  Copy "\\Base\\Sistemas\\Vendas\\GR_0008"  PrivDir()+"GR_0008"
  Copy "\\Base\\Sistemas\\Vendas\\GR_0008a" PrivDir()+"GR_0008a"
  Copy "\\Base\\Sistemas\\Vendas\\GR_0008b" PrivDir()+"GR_0008b"
  Empty(PrivDir()+"GR_0008")
  Empty(PrivDir()+"GR_0008a")
  Empty(PrivDir()+"GR_0008b")

  AGUARDE("Aguarde, Gerando Dados")
  
  Cria_Registros()

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
    Seleciona2()
  EndWhile

  If IsTable(PrivDir()+"GR_0008a")
     Then View PrivDir()+"GR_0008a"
          Moveto [Valor 1]
          VR1=ImageCsum()
          Moveto [Valor 2]
          VR2=ImageCsum()
          ClearAll
          If VR1=0 And VR2=0
             Then MENSAGEM("N„o existem registros a processar")
                  Loop
          EndIf
  EndIf

  Processa2()

  GRAF_TIPO= "3"
  GRAF_TAB  = PrivDir()+"GR_0008b"
  
  Switch
    Case VSDGOPAG=1 : GRAF_TIT1 = "Evolu‡„o das Vendas"

    Case VSDGOPAG=2 : GRAF_TIT1 = "Evolu‡„o das Devolu‡äes"

    Case VSDGOPAG=3 : GRAF_TIT1 = "Evolu‡„o das Vendas/Devolu‡”es"
                      GRAF_TAB  = PrivDir()+"GR_0008"
                      GRAF_LENG = "Y"
                      GRAF_LENG1= "Vendas"
                      GRAF_LENG2= "Devolucoes"

    Case VSDGOPAG=4 : GRAF_TIT1 = "Evolu‡„o das Vendas L¡quidas [V-D]"

  EndSwitch
  GRAF_TIT1 = GRAF_TIT1 +" por Representante/Marca dos éltimos 13 Meses at‚ "+rTrim(mesext(NumVal(Substr(VSDGMESANO,1,2))))+"/"+Substr(VSDGMESANO,4,4) 
  
  GRAF_TIT2= "Empresa: "+VSDGEMPRESA+"-"+VSDGNOMEMP
  if not isblank(VSDGREPRESEN)
     then GRAF_TIT2=GRAF_TIT2+", Representante: "+VSDGREPRESEN+"-"+VSDGNOMREPR
     else GRAF_TIT2=GRAF_TIT2+", Gerencia: "+VSDGGERENCIA+"-"+VSDGDESCGERENCIA
  endif
  GRAF_TIT2= GRAF_TIT2+", Marca: "+VSDGMARCA+"-"+VSDGNOMMARCA

  Switch
    Case VSDGOPAG=3 : GRAF_TIT2= GRAF_TIT2+" [ Total: V- "+LTrim(Format("W13.2,EIC",VRTOTAL))+" D- "+LTrim(Format("W13.2,EIC",VRTOTALDEV))+" ]"
    OtherWise       : GRAF_TIT2= GRAF_TIT2+" [ Total: "+LTrim(Format("W13.2,EIC",VRTOTAL))+" ]"
  EndSwitch
  
  GRAF_LINX= "Valor"
  GRAF_LINY= "Mes"
  
  MONTAGRAFICO(GRAF_TAB)

  Delete PrivDir()+"GR_0008"
  Delete PrivDir()+"GR_0008a"
  Delete PrivDir()+"GR_0008b"
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
