;** Rm_0240 ********************************************************************
;* Resumo de Vendas Diaria A Vista/A Prazo                                     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 02/09/98 Anivel Augustro Rodrigues
;Ultima Alteracao: 08/09/2004 por Jos‚ Lu¡s Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 15/12/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 19/01/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: inclusao outros  
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 20/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0247" (50), "RM_0071" (49) neste script "RM_0240" (22)
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 09/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes agrupado RM_0230, RM_0255, RM_0248
;Ultima Alteracao: 07/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona_0071()
ClearAll
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")
   Then
         {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
         Moveto [Codigo do Representante] Example "crep"
         If VSDGGERENCIA<>""
            Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
            Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
         EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter Check
         Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
         Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
         Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
         Moveto [Descricao da Destinacao] TypeIn "..VENDA.. ..BALCAO.."
         Moveto [Situacao               ] TypeIn "not C"
         Moveto [Tipo Movimento Estoque ] TypeIn "S"
         Moveto [Tipo de Pagamento      ] TypeIn "V or P"
         Do_It!
         ClearAll
EndIf
EndProc   ;  (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona_0240()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then 
         {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
         Moveto [Codigo do Representante] Example "crep"
         If VSDGGERENCIA<>""
            Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
            Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
         EndIf
   
       {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Tipo de Pagamento      ] Check TypeIn "V Or P"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. OR ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
                        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        If VSDGCODMODELO = "50"
           Then Moveto [Tipo do Item   ] Check 
        EndIf        
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll
                          
        {Ask} {Answer}
        Moveto [Codigo da Empresa       ] Example "cemp"
        Moveto [Nome Fantasia Empresa   ] Example "nemp"
        Moveto [Data de Emissao         ] Example "dtem"
        Moveto [Tipo de Pagamento       ] TypeIn "V"
        If VSDGCODMODELO = "50"
           Then Moveto [Tipo do Item    ] Example "tpi" 
        EndIf
        Moveto [Quantidade              ] Example "qtde"
        Moveto [Preco Total             ] Example "ptot"
        Moveto [Valor Desconto Total    ] Example "vdes"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Codigo da Empresa       ] Example "cemp"
        Moveto [Nome Fantasia Empresa   ] Example "nemp"
        Moveto [Data de Emissao         ] Example "dtem"
        If VSDGCODMODELO = "50"
           Then Moveto [Tipo do Item    ] Example "tpi" 
        EndIf
        Moveto [Vendas_Vista_Quantidade ] Example "qtde"
        Moveto [Vendas_Vista_Preco Total] Example "ptot" TypeIn"-" Example "vdes"
        Do_It!    
        ClearAll

        {Ask} {Answer}
        Moveto [Codigo da Empresa       ] Example "cemp"
        Moveto [Nome Fantasia Empresa   ] Example "nemp"
        Moveto [Data de Emissao         ] Example "dtem"
        Moveto [Tipo de Pagamento       ] TypeIn "P"
        If VSDGCODMODELO = "50" 
           Then Moveto [Tipo do Item    ] Example "tpi"
        EndIf
        Moveto [Quantidade              ] Example "qtde"
        Moveto [Preco Total             ] Example "ptot"
        Moveto [Valor Desconto Total    ] Example "vdes"
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Codigo da Empresa       ] Example "cemp"
        Moveto [Nome Fantasia Empresa   ] Example "nemp"
        Moveto [Data de Emissao         ] Example "dtem"
        If VSDGCODMODELO = "50" 
           Then Moveto [Tipo do Item   ] Example "tpi"
        EndIf
        Moveto [Vendas_Prazo_Quantidade ] Example "qtde"
        Moveto [Vendas_Prazo_Preco Total] Example "ptot" TypeIn"-" Example "vdes"
        Do_It!
        ClearAll
EndIf   

;****** Devolucoes - Vendas ****************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then 
         {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
         Moveto [Codigo do Representante] Example "crep"
         If VSDGGERENCIA<>""
            Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
            Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
         EndIf
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
         Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
         Moveto [Nome Fantasia Empresa  ] Check
         Moveto [Numero do Documento    ] Example "ndoc"
         Moveto [Serie do Documento     ] Example "sdoc"
         Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
         Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
         Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
         Moveto [Tipo Movimento Estoque ] TypeIn "E"
         Moveto [Situacao               ] TypeIn "Not C"
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
         Moveto [Codigo da Empresa      ] Example "cemp"
         Moveto [Numero do Documento    ] Example "ndoc"
         Moveto [Serie do Documento     ] Example "sdoc"
         If VSDGCODMODELO = "50"
            Then Moveto [Tipo do Item   ] Check 
         EndIf
         Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
         Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
         Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
         Moveto [Situacao_Item          ] TypeIn "Not C"
         Do_It!
         ClearAll
                  
         {Ask} {Answer}
         Moveto [Codigo da Empresa       ] Example "cemp"
         Moveto [Nome Fantasia Empresa   ] Example "nemp"
         Moveto [Data de Emissao         ] Example "dtem"
         If VSDGCODMODELO = "50" 
           Then Moveto [Tipo do Item   ] Example "tpi"
         EndIf
         Moveto [Quantidade              ] Example "qtde"
         Moveto [Preco Total             ] Example "ptot"
         Moveto [Valor Desconto Total    ] Example "vdes"

         {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
         Moveto [Codigo da Empresa       ] Example "cemp"
         Moveto [Nome Fantasia Empresa   ] Example "nemp"
         Moveto [Data de Emissao         ] Example "dtem"
         If VSDGCODMODELO = "50" 
           Then Moveto [Tipo do Item   ] Example "tpi"
         EndIf
         Moveto [Devolucoes_Quantidade   ] Example "qtde"
         Moveto [Devolucoes_Preco Total  ] Example "ptot" TypeIn"-" Example "vdes"
         Do_It!
         ClearAll 
EndIf

;****** Devolucoes - Estoque ***************************************************
If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then 
         {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
         Moveto [Codigo do Representante] Example "crep"
         If VSDGGERENCIA<>""
            Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
            Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
         EndIf
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Data de Entrada        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo de Operacao       ] TypeIn "D"
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        If VSDGCODMODELO = "50" 
           Then Moveto [Tipo do Item   ] Check
        EndIf
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Do_It!
        ClearAll
        
        {Ask} {Answer}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        Moveto [Data de Entrada        ] Example "dtem"
        Moveto [Quantidade             ] Example "qtde"
        Moveto [Preco Total            ] Example "ptot"
        Moveto [Valor Desconto Total   ] Example "vdes"
        If VSDGCODMODELO = "50" 
           Then Moveto [Tipo do Item   ] Example "tpi"
        EndIf
        {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        Moveto [Data de Emissao        ] Example "dtem"
        If VSDGCODMODELO = "50"
           Then Moveto [Tipo do Item   ] Example "tpi"
        EndIf
        Moveto [Devolucoes_Quantidade  ] Example "qtde"
        Moveto [Devolucoes_Preco Total ] Example "ptot" TypeIn"-" Example "vdes"
        Do_It!
        ClearAll
EndIf
EndProc   ;  (Seleciona_0240)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Tipo do Item           ] Check
Moveto [Codigo do Item         ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Codigo                 ] Check
Moveto [Nome Fantasia EmitDest ] Check
Moveto [Codigo do Representante] Check
Moveto [Nome Fantasia Represent] Check
Moveto [Tipo de Pagamento      ] Check
Moveto [Data de Emissao        ] Check
Moveto [Vendas_Vista_Quantidade ] TypeIn "Calc Sum as VendasVistaQuantidade"
Moveto [Vendas_Vista_Preco Total] TypeIn "Calc Sum as VendasVistaPreco"
Moveto [Vendas_Prazo_Quantidade ] TypeIn "Calc Sum as VendasPrazoQuantidade"
Moveto [Vendas_Prazo_Preco Total] TypeIn "Calc Sum as VendasPrazoPreco"
Moveto [Vendas_Outras_Quantidade ] TypeIn "Calc Sum as VendasOutrasQuantidade"
Moveto [Vendas_Outras_Preco Total] TypeIn "Calc Sum as VendasOutrasPreco"
Moveto [Devolucoes_Quantidade  ] TypeIn "Calc Sum as DevolucoesQuantidade"
Moveto [Devolucoes_Preco Total ] TypeIn "Calc Sum as DevolucoesPreco"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela

EndProc   ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_GERENCIA"       :Campo="TG_EMPRESATE"
            Case Campo="TG_REPRESEN"      : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_REPRESEN"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE" :Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"  :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"  :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"     :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"     :Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("22  Di ria")                                               ;RM_0240
ModeloRelatoriosAdd("50  Di ria/Tipo do Item")                                  ;RM_0247
ModeloRelatoriosAdd("49  Di ria/Vendas - BALCÇO")                               ;RM_0071
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("21  Por Produto")                                          ;RM_0230
ModeloRelatoriosAdd("28  Por Estado")                                           ;RM_0255
ModeloRelatoriosAdd("64  Por Representante/Data EmissÆo")                       ;RM_0248
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGREPRESEN= ""
VSDGGERENCIA=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Resumo de Vendas A Vista/A Prazo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 16 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_REPRESEN"   To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"    To VSDGNOMREPR

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 09,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 10,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 10,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO
    
    Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf
  
  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  
  Switch
    Case VSDGCODMODELO = "21" :
      Play "RM_0240B"
    
    Case VSDGCODMODELO = "28" :
      Play "RM_0240C"
    
    Case VSDGCODMODELO = "64" :
      Play "RM_0240D"
    
    otherwise:
      Tabela=Cria_Temp(PrivDir())
      If VSDGCODMODELO <> "49" 
         Then Empty "\\Base\\Sistemas\\Vendas\\Rm_0240"
              Copy "\\Base\\Sistemas\\Vendas\\Rm_0240" Tabela
      EndIf
      Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
      If VSDGCODMODELO = "49"
         Then While Novo_Dir_Trab()
                If IsTable("Answer")     Then Delete "Answer" EndIf
                Seleciona_0071()
                If Not IsTable("Answer") Then Loop EndIf
                If IsTable(Tabela)
                   Then Add "Answer" Tabela
                   Else Rename "Answer" Tabela
                EndIf
              EndWhile
         Else While Novo_Dir_Trab()
                Seleciona_0240()      
              EndWhile
      EndIf              
    
      If IsEmpty(Tabela)
         Then MENSAGEM("N„o existem registros a processar")
              Delete Tabela
              Loop
      EndIf
    
      If VSDGCODMODELO <> "49"
         Then Processa()
      EndIf
      
      copy tabela "a1"
      Switch
        Case VSDGCODMODELO = "22" : IMPRIREL(Tabela,"R")
        Case VSDGCODMODELO = "50" : IMPRIREL(Tabela,"1")
        Case VSDGCODMODELO = "49" : CopyReport "\\Base\\Sistemas\\Vendas\\Rm_1000" "5" Tabela "R"
                                    IMPRIREL(Tabela,"R") 
      EndSwitch
      Delete Tabela
    
  EndSwitch
  
EndWhile
ClearAll
Release Vars All
Release Procs All
