;** Rm_3205 ********************************************************************
;* Comparacao Vendas/Tabela por Representante/Item                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 14/05/2004 por Anivel Augusto Rodrigues
;Ultima Alteracao: 28/08/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Novo Relatorio
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 30/08/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes para quando for ser feito os calculos informar o "Valor Desconto Unitario"
;Ultima Alteracao: 12/09/2012 por Bruno Carvalho
;Motivo Alteracao: InclusÆo do Modelo 7 (Coluna de Desconto Unitario e Acrescimo)
;Ultima Alteracao: 24/09/2013 por Karina Andrade
;Motivo Alteracao: Adicionado filtro por tabela de pre‡o
;Ultima Alteracao: 25/09/2013 por Bruno Carvalho
;Motivo Alteracao: Alteradp layout do campo "Opcao" no ShowDialog
;Ultima Alteracao: 01/10/2013 por Bruno Carvalho
;Motivo Alteracao: Ajustes report onde foi adicionado "Codigo da Tabela"
;Ultima Alteracao: 03/10/2013 por Andrey Fillipe          
;Motivo Alteracao: Adicionado filtro por Gerencia 
;Ultima Alteracao: 17/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 31/10/2016 por Bruno Carvalho
;Motivo Alteracao: Ajustado VSDGTABELA na "NotaC" ao inv‚s de pegar no "NotaI" 
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 31/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desconto item
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 07/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc Seleciona()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
           Moveto [Codigo do Representante] Example "crep"
           If VSDGGERENCIA<>""
              Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
              Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
           EndIf
   
        {Ask} TypeIn "\\Sistemas\\Vendas\\CondPgto" Enter
        Moveto [Condicao de Pagamento  ] Example "cpg"
        Moveto [Taxa Desconto          ] Check
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA.."
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Tipo do Documento      ] Check
        Moveto [Data de Emissao        ] Check
        Moveto [Numero do Pedido       ] Check
        Moveto [Codigo                 ] Check
        Moveto [Razao Social           ] Check
        Moveto [Numero do Documento    ] Check Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        If IsBlank(VSDGNCARREG)
           Then Moveto [Data de Emissao] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndIf
        Moveto [Codigo                 ] TypeIn "~VSDGDESTINAT.."
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Condicao de Pagamento  ] Check Example "cpg"
        Moveto [Descricao CondPagto    ] Check
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        Moveto [Numero_Carregamento    ] TypeIn "~VSDGNCARREG.."
        Moveto [Codigo da Tabela       ] Check TypeIn "~VSDGTABELA.."        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter Check
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo do Item         ] TypeIn "~VSDGITEM.."
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        Adiciona_Dados("")
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

View Tabela
CoEdit "Answer"
Scan
  Moveto Tabela
  End
  Down
     
  [Codigo da Empresa      ]=[Answer->Codigo da Empresa      ]
  [Nome Fantasia Empresa  ]=[Answer->Nome Fantasia Empresa  ]
  [Tipo do Documento      ]=[Answer->Tipo do Documento      ]
  [Numero do Documento    ]=[Answer->Numero do Documento    ]
  [Data de Emissao        ]=[Answer->Data de Emissao        ]
  [Codigo                 ]=[Answer->Codigo                 ]
  [Razao Social           ]=[Answer->Razao Social           ]
  [Codigo do Representante]=[Answer->Codigo do Representante]
  [Nome Fantasia Represent]=[Answer->Nome Fantasia Represent]
  [Condicao de Pagamento  ]=[Answer->Condicao de Pagamento  ]
  [Descricao CondPagto    ]=[Answer->Descricao CondPagto    ]
  [Codigo do Item         ]=[Answer->Codigo do Item         ]
  [Descricao do Item      ]=[Answer->Descricao do Item      ]
  [Quantidade             ]=[Answer->Quantidade             ]
  [Preco Unitario         ]=[Answer->Preco Unitario         ]
  [Preco Unitario Tabela  ]=[Answer->Preco Unitario Tabela  ]
  [Valor Desconto Total   ]=[Answer->Valor Desconto Total   ]
  [Codigo da Tabela       ]=[Answer->Codigo da Tabela       ]
  [Taxa Desconto          ]=[Answer->Taxa Desconto          ]
  [Total Tabela           ]=round([Quantidade]*[Preco Unitario Tabela],2)
  [Total Venda            ]=round([Quantidade]*[Preco Unitario       ],2)-[Answer->Valor Desconto Item] 

  [Total Liquido          ]=[Total Venda]-[Valor Desconto Total]
  [Total Diferenca        ]=[Total Liquido]-[Total Tabela      ]
  VRDIF                    =[Total Liquido]-[Total Tabela      ]
  If VRDIF>0
     Then [Total Acrescimo]=[Total Acrescimo]+VRDIF
     Else [Total Desconto ]=[Total Desconto ]+(VRDIF*-1)
  EndIf
  
  If [Preco Unitario]>[Preco Unitario Tabela]
     Then [Total Geral Acrescimo]=[Total Geral Acrescimo]+([Preco Unitario]-[Preco Unitario Tabela])
  EndIf   
  
  [Total Tabela Permitido ]=[Total Tabela]-(([Total Tabela]*[Taxa Desconto])/100)
  [Total Db_Cr            ]=[Total Liquido]-[Total Tabela Permitido]
  [Taxa Db_Cr             ]=(([Total Liquido]/[Total Tabela Permitido])*100)-100

  Moveto "Answer"
EndScan
Do_It!
ClearAll

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Item")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Condi‡Æo de Pagamento")
ModeloRelatoriosAdd("03  Condi‡Æo de Pagamento/Item")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("04  Representante I")
ModeloRelatoriosAdd("05  Representante II")
ModeloRelatoriosAdd("06  Representante/Cliente I")
ModeloRelatoriosAdd("07  Representante/Cliente II")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""

If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_GERENCIA"      : Campo="TG_EMPRESA"
            Case Campo="TG_REPRESEN"      : Campo="TG_GERENCIA"
            Case Campo="TG_NCARREG"       : Campo="TG_REPRESEN"
            Case Campo="TG_DESTINAT"      : Campo="TG_NCARREG"
            Case Campo="TG_TABELA"        : Campo="TG_DESTINAT"
            Case Campo="TG_ITEM"          : Campo="TG_TABELA"
            Case Campo="TG_DTINI"         : Campo="TG_ITEM"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_NCARREG"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"     :Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"    :Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"    :Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG"     :Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"    :Campo="TG_TABELA"
                    Case Campo="TG_TABELA"      :Campo="TG_ITEM"
                    Case Campo="TG_ITEM"        :Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       :Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       :Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   :Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_DTFIM"     : MSG_CAMPO="Informe a Data Final"
Endswitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

If not IsAssigned(SYS_CODIGO_CLIENTE) Then SYS_CODIGO_CLIENTE="" EndIf

VSDGEMPRESA   = ""
VSDGNCARREG   = ""
VSDGDESTINAT  = ""
VSDGREPRESEN  = ""
VSDGDTINI     = BlankDate()
VSDGDTFIM     = BlankDate()
VSDGITEM      = ""
VSDGMODREP    = ""
VSDGICOMODREP = ""

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Comparacao Vendas/Tabela por Representante" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE","SELECT"  
  Mouse "UP"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 20 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_REPRESEN"   To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"    To VSDGNOMREPR

    Label  @ 06,00 "Carregamento" For "TG_NCARREG"
    Accept @ 07,01 Width 9  "A6"  Picture "[&,#][#*#]" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG

    Label  @ 08,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 09,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST
    
    Label  @ 10,00 "Tabela de Pre‡o"  For "TG_TABELA"
    Accept @ 11,01 Width 08 "A5"  Picture "#*#" Tag "TG_TABELA"    To VSDGTABELA
    Accept @ 11,09 Width 25 "A70" Picture "!*!" Tag "TG_NOMTAB" To VSDGNOMTAB

    Label  @ 00,35 "Item"  For "TG_ITEM"
    Accept @ 01,36 Width 33 "A10"  Picture "#*#" Tag "TG_ITEM"    To VSDGITEM
    Accept @ 02,36 Width 33 "A30" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 04,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,51 "at‚" For "TG_DTFIM"
    Accept @ 05,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 13,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 14,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 14,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 16,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 16,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGNCARREG)
     Then If IsBlank(VSDGDTFIM)
             Then Mensagem("Data Final Invalida !")
                  Loop
          EndIf
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())
  Empty "\\Base\\Sistemas\\Vendas\\Rm_3205"
  Copy "\\Base\\Sistemas\\Vendas\\Rm_3205" Tabela

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona()
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf

  Switch
    Case VSDGCODMODELO="01": IMPRIREL(Tabela,"R")
    
    Case VSDGCODMODELO="02": IMPRIREL(Tabela,"2")
    Case VSDGCODMODELO="03": IMPRIREL(Tabela,"1")
    
    Case VSDGCODMODELO="04": IMPRIREL(Tabela,"3")
    Case VSDGCODMODELO="05": IMPRIREL(Tabela,"5")

    Case VSDGCODMODELO="06": IMPRIREL(Tabela,"6")
    Case VSDGCODMODELO="07": IMPRIREL(Tabela,"4")

  EndSwitch

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
