;** Rm_0075 ********************************************************************
;*  Relacao de Vendas a Vista e a Prazo Com Representante  Rel N§ 86           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 22/07/2004 por Nikolas M. Mateus
;Ultima Alteracao: 23/02/2006 por Davi Carrano
;Motivo Alteracao: Ajustes quando usar o troca
;Ultima Alteracao: 15/12/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 31/03/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes . Check por Campo .
;Ultima Alteracao: 14/11/2012 por Kamila Gomes
;Motivo Alteracao: Filtro por Tabela de pre‡o
;Ultima Alteracao: 13/02/2013 por Kamila Gomes
;Motivo Alteracao: Opcao de relatorio sintetico
;Ultima Alteracao: 23/04/2013 por Karina Andrade
;Motivo Alteracao: Adcionado % desconto no report e altera‡Æo da ASK
;Ultima Alteracao: 15/01/2016 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ ser informado as trocas na rela‡Æo caso seja DEBITO #0227
;Ultima Alteracao: 20/01/2016 por Bruno Carvalho
;Motivo Alteracao: Alterado campo [Valor IR] -> [Valor Nota Fiscal] quando destina‡Æo igual a TROCA, p/ totalizador ficar correto no report 
;Ultima Alteracao: 29/08/2016 por Kamila Gomes
;Motivo Alteracao: Ajuste Proc Seleciona() quando nÆo existe tabela notaC no diret¢rio Fechames
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE
;Ultima Alteracao: 05/08/2017 por Bruno Carvalho
;Motivo Alteracao: Substituido [Valor IR] -> [Valor DebitoCredito]                 
;Ultima Alteracao: 13/11/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes valor liquido da opera‡Æo para troca
;Ultima Alteracao: 26/06/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtrar gerencia
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 25/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   

;*******************************************************************************
;* Rotina para Selecionar Registros                                            *
;*******************************************************************************
Proc Seleciona()

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")
   Then
   
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Codigo da Gerencia     ]       TypeIn "~VSDGGERENCIA.."
       {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter ;Check
        Moveto [Numero do Documento     ] Check
        Moveto [Serie do Documento      ] Check
        Moveto [Codigo                  ] Check
        Moveto [Codigo da Empresa       ] Check TypeIn "~VSDGEMPRESA2.."
        Moveto [Nome Fantasia Empresa   ] Check
        Moveto [Razao Social            ] Check
        Moveto [Codigo do Representante ] Check TypeIn "_crep, ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent ] Check
        Moveto [Data de Emissao         ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao ] Check TypeIn "..VEND.. Or ..SAIDA.. Or ..SERV.."
        Moveto [Tipo Movimento Estoque  ] Check TypeIn "S"
        Moveto [Situacao                ] Check TypeIn "Not C"
        Moveto [Tipo de Pagamento       ] Check TypeIn "V or P"
        Moveto [Condicao de Pagamento   ] Check
        Moveto [Descricao CondPagto     ] Check
        Moveto [Forma de Pagamento      ] Check
        Moveto [Numero da OF            ] Check
        Moveto [Valor Devolucao         ] Check
        Moveto [Valor DebitoCredito     ] Check
        Moveto [Valor Nota Fiscal       ] Check
        Moveto [Valor Mercadoria        ] Check
        Moveto [Valor Mercadoria Liquido] Check
        Moveto [Valor Desconto          ] Check
        Moveto [Codigo da Tabela        ] TypeIn "~VSDGTABELA.."
        Do_It!
        ClearAll
                       

        If Not IsEmpty("Answer")
           Then 
                NR = NRecords("Answer")
                Coedit "Answer"
                Scan  
                  Barra(NR, RecNo())
                  Aguarde("Aguarde, verificando as trocas "+BARRA_STRING)
                  
                  If [Tipo Movimento Estoque]="S" and Search("TROCA",[Descricao da Destinacao])>0
                     Then  
                          If ([Valor Mercadoria Liquido]-[Valor Devolucao])>0 
                              Then [Valor Nota Fiscal] = [Valor Mercadoria Liquido]-[Valor Devolucao] 
                              else [Valor Nota Fiscal] = blankNum() 
                          EndIf
                  EndIf
                  
                EndScan
                Do_iT!
                ClearAll
        EndIf

EndIf

EndProc   ;  (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case campo="TG_GERENCIA"      : Campo="TG_EMPRESATE"
            Case Campo="TG_REPRESEN"      : Campo="TG_GERENCIA"
            Case Campo="TG_TABELA"        : Campo="TG_REPRESEN"
            Case Campo="TG_DTINI"         : Campo="TG_TABELA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_GERENCIA"
                    Case campo="TG_GERENCIA"      : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"      : Campo="TG_TABELA"
                    Case Campo="TG_TABELA"        : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTFIM":
     MSG_CAMPO="Informe a Data Final"
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("1   Anal¡tico")
ModeloRelatoriosAdd("2   Sint‚tico")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGREPRESEN=""
VSDGGERENCIA=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Relacao de Vendas a Vista e a Prazo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
    @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 06,00 "Tabela"  For "TG_TABELA"
    Accept @ 07,01 Width 08 "A5"  Picture "#*#" Tag "TG_TABELA" To VSDGTABELA
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMTAB" To VSDGNOMTAB

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp("\\Sistemas\\Vendas\\")

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  If VSDGCODMODELO="1"
     Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_1001" "3" Tabela "R"
     Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_1001" "6" Tabela "R"    
  EndIf     
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
