;** Rm_0150 *******************************************************************
;*  Emissao dos Titulos Pagos por Emitente \Cheques de Terceiros               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 15/06/1998 por Anivel Augusto Rodrigues
;Ultima Alteracao: 25/02/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo da Baixa
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 23/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                    
;Ultima Alteracao: 13/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0140" (13) neste script "RM_0150" (14)
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona1()
ClearAll

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos") And
   IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa") And
   IsTable("\\Sistemas\\CheqRec\\"+Dir_Trab+"ChequeI")
   Then {Ask} TypeIn "\\Sistemas\\CheqRec\\"+Dir_Trab+"ChequeI" Enter
        Moveto [Data Vencimento         ] Check
        Moveto [Codigo_Banco            ] Check
        Moveto [Numero_Cheque           ] Check
        Moveto [Titular_Cheque          ] Check
        Moveto [Valor                   ] Check
        Moveto [Sistema Destino         ] TypeIn "CP"
        Moveto [Lancamento Destino      ] Example "NL"
        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter
        Moveto [Numero do Lancamento   ] Example "NL"
        Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA.."
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Codigo do Emitente     ] Check TypeIn "~VSDGDESTINAT.."
        Moveto [Nome Fantasia EmitDest ] Check
        Moveto [Numero do Documento    ] Check
        Moveto [Tipo do Documento      ] Check
        Moveto [Serie do Documento     ] Check
        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa" Enter
        If Not IsBlank(VSDGNLCTAPAG)
          Then Moveto [Numero do Lancamento] Example "NL" TypeIn ", ..~VSDGNLCTAPAG.."
          Else Moveto [Numero do Lancamento] Example "NL"
        Endif
        Moveto [Data do Pagamento      ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Tipo da Baixa          ] TypeIn "Blank or NORMAL"
        Do_It!
        ClearAll
EndIf

EndProc  ; (Seleciona1)

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona2()
ClearAll

If IsTable("\\Sistemas\\CheqRec\\"+Dir_Trab+"ChequeI") And
   IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos") And
   IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"TitCheq")
  Then {Ask} TypeIn "\\Sistemas\\CheqRec\\"+Dir_Trab+"ChequeI" Enter
       Moveto [Numero do Lancamento    ] Example "NLC"
       Moveto [Sequencia do Cheque     ] Example "SC"
       Moveto [Data Vencimento         ] Check
       Moveto [Codigo_Banco            ] Check
       Moveto [Nome_Banco              ] Check
       Moveto [Numero_Cheque           ] Check
       Moveto [Titular_Cheque          ] Check
       Moveto [Valor                   ] Check
       Moveto [Cidade                  ] Check
       {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter
       Moveto [Numero do Lancamento   ] Example "NL"
       Moveto [Codigo da Empresa      ] Check TypeIn "~VSDGEMPRESA.."
       Moveto [Codigo do Emitente     ] Check
       Moveto [Nome Fantasia EmitDest ] Check
       Moveto [Numero do Documento    ] Check
       Moveto [Tipo do Documento      ] Check
       Moveto [Serie do Documento     ] Check
       if isblank(VSDGNLCTAPAG)
          then 
               {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa" Enter
               Moveto [Numero do Lancamento   ] Example "NL"
               Moveto [Data do Pagamento      ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
       endif   
       {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitCheq" Enter
       Moveto [Numero do Lancamento    ] Check Example "NL" TypeIn ", ..~VSDGNLCTAPAG.."
       Moveto [Numero Lancamento Cheque] Example "NLC"
       Moveto [Sequencia do Cheque     ] Example "SC"
       Do_It!
       ClearAll
EndIf
EndProc   ; (Seleciona2)

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa()

{Modify} {Restructure} TypeIn Tabela Enter Right End Down
"Razao Social Empresa" Right  "A40" Down
"Razao Social" Right "A40" Do_It! ClearImage
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo      ] Example "codigo"
Moveto [Razao Social] Example "razao"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Emitente] Example "codigo"
Moveto [Razao Social      ] TypeIn "Changeto " Example "razao"
Do_It!
ClearAll

EndProc ;(Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_NLCTAPAG"      : Campo="TG_EMPRESA" 
            Case Campo="TG_DESTINAT"      : Campo="TG_NLCTAPAG"
            Case Campo="TG_DTINI"         : Campo="TG_DESTINAT"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"  
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"   : Campo="TG_NLCTAPAG"
                    Case Campo="TG_NLCTAPAG"  : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"  : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"     : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp               

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("13  Por Emitente/Cidade/Banco + Observa‡Æo")               ;RM_0140   
ModeloRelatoriosAdd("14  Por Emitente/Cheque/Fornecedor/Documento")             ;RM_0150
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  = ""
VSDGDESTINAT = ""
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos Pagos por Emitente c/ Cheques de Terceiros" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 16 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Lan‡amento" For "TG_NLCTAPAG"
    Accept @ 03,01 Width 09 "A6" Picture "!*!" Tag "TG_NLCTAPAG" To VSDGNLCTAPAG
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNLCTAPAG" To VSDGNOMNLCTAPAG
    
    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMDEST"  To VSDGNOMDEST

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 09,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 10,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 10,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf
  
  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando o Relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer") Then Delete "Answer" EndIf
    If VSDGCODMODELO="13"
       Then Seleciona2()
       Else Seleciona1()
    EndIf    
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  
  Switch
    Case VSDGCODMODELO="13" : Processa()
                              CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_0140" "1" Tabela "R"
    Case VSDGCODMODELO="14" : CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_0150" "R" Tabela "R"  
  EndSwitch
  IMPRIREL(Tabela,"R")

  Delete Tabela
EndWhile
ClearAll
Release Vars All
Release Procs All
