;** Rm_0011  *******************************************************************
;*  Emissao dos Titulos Recebidos por Tipo de Pagamento/Vencimento/Emissao     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 11/02/2004 por Karen Lauar Nery
;Ultima Alteracao: 02/09/2004 por Jos‚ Lu¡s Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 22/10/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 09/02/2011 por Karina Andrade
;Motivo Alteracao: Ajustes Opcao de Datas
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 11/02/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado modelo 01B  #0274              
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa")

   Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Numero do Lancamento    ] Example "lanc"
        Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Representante ] TypeIn "~VSDGREPRESEN.."
        Switch
          Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
          Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
        EndSwitch 
        Switch
          Case VSDGOPDTCRB="2" :
               Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDTCRB="3" :
               Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch

        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
        Moveto [Numero do Lancamento] Example "lanc"
        Moveto [Codigo da Conta     ] TypeIn "~VSDGCONTA.."
        Moveto [Tipo da Baixa       ] TypeIn "Blank or NORMAL"
        Switch
          Case VSDGOPDTCRB="1" :
               Moveto [Data do Pagamento ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDTCRB="4" :
               Moveto [Data_Inclusao     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
          
        Do_It!
        ClearAll
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
  [Valor do Desconto-1]=([Valor do Desconto-1]*-1)+[Valor do Juros]
  If IsBlank([Valor do Desconto-1])    Then [Valor do Desconto-1   ]=0 EndIf
  If IsBlank([Valor do Juros Devidos]) Then [Valor do Juros Devidos]=0 EndIf

EndScan
Do_It!
ClearAll
EndProc   ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"       : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_REPRESEN"      : Campo="TG_CONTA" 
            Case Campo="TG_TPPAGTO"       : Campo="TG_REPRESEN"
            Case Campo="TG_OPDTCRB"       : Campo="TG_TPPAGTO"
            Case Campo="TG_DTINI"         : Campo="TG_OPDTCRB"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_CONTA" 
                    Case Campo="TG_CONTA"         : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"      : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"       : Campo="TG_OPDTCRB" 
                    Case Campo="TG_OPDTCRB"       : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Vencimento/EmissÆo/Documento")
ModeloRelatoriosAdd("01B Por Vencimento/EmissÆo/Documento + Juros Devido")
ModeloRelatoriosAdd("74  Por Vencimento/EmissÆo/Documento *CARTOES*")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Sint‚tico")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

VSDGEMPRESA =""
VSDGCONTA   =""
VSDGOPDTCRB =""
VSDGDTINI   = BlankDate()
VSDGDTFIM   = BlankDate()
VSDGTPPAGTO   =""

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPPAGTO]")    

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos Recebidos por Forma Pagamento" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 16 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
    
    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR
    
    Label  @ 06,00 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO
  
    Label  @ 00,35 "Op‡äes de Datas" For "TG_OPDTCRB"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPDTCRB" To VSDGOPDTCRB
    Accept @ 01,44 Width 25 "A20"  Picture "!*!" Tag "TG_NOMOPDTCRB" To VSDGNOMOPDTCRB

    Label  @ 02,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 09,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 10,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 10,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, processando")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  switch
   case VSDGCODMODELO="01"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010"  "6" Tabela "R"
   case VSDGCODMODELO="01B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010C" "R" Tabela "R"
   case VSDGCODMODELO="02"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011"  "3" Tabela "R"

   case VSDGCODMODELO="74"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "8" Tabela "R" 
  endswitch


  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
