;** BxComAut *******************************************************************
;*  Baixa Automatica de Comissao                                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 13/12/2001 por Anivel Augusto Rodrigues
;Ultima Alteracao: 14/02/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes Novo Layout de Teclas
;Ultima Alteracao: 20/01/2012 por Karina Andrade
;Motivo Alteracao: Ajustes Seleciona() - Saldo Comissao > 0,01
;Ultima Alteracao: 27/03/2013 por Karina Andrade
;Motivo Alteracao: Ajustes Seleciona() - Saldo Comissao > 0,01
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 06/08/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes savetables
;Ultima Alteracao: 20/05/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes para o Base no CopyReport do "BxComAut" para "\\Base\\Sistemas\\CtaRec\\BxComAut"

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc SELECIONA()
ClearAll

{Ask} {Duplic} Check
Moveto [Numero do Lancamento   ] Example "nlanc"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Destinatario ] Example "cod"
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
;Verificar com Anivel
;Moveto [Saldo da Comissao      ] TypeIn "> 0.01"
{Ask} {DupBaixa} Check
Moveto [Numero do Lancamento   ] Example "nlanc"
Moveto [Data do Pagamento      ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM "
Moveto [Data Pagamento Comissao] TypeIn "Blank"
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Example "cod"
Moveto [Cidade                 ] Check
Do_It!
ClearAll

If Not IsEmpty("Answer")
   Then CopyForm "BxComAut" "F" "Answer" "F"
EndIf
EndProc

;*******************************************************************************
;* Seleciona Titulos para Baixa
;*******************************************************************************
Proc CHAVE()
While True
  End
  Down
  Moveto [Tipo do Documento]
  While True

  TECLA="F5=Total F8=Atualizar"
  AguardaTeclasPadrao()

  If RetVal=-33
     Then Echo Normal
          Echo Off
          ShowPopup " Fun‡”es " CENTERED
           "F4 ~I~mprimir        " : " Imprimir                 " : "F4",
           "~C~ancelar           " : " Cancelar a Opera‡„o      " : "CANCELAR"
          EndMenu
           To MenuVar

          Echo Off
          If MenuVar="CANCELAR" or MenuVar="Esc"
              Then Loop
          EndIf

          RetVal=MenuVar
  EndIf

  Switch
    Case RetVal="F3": SemFicha()
    Case RetVal=-94 : MsgTeclasPadrao()
    Case RetVal="F5" And Field()="Tipo do Documento":
         Moveto [Valor da Comissao-1]
         VR=ImageCSum()
         Mensagem("Total = "+LTrim(Format("W13.2,EIC",VR)))
         Moveto [Tipo do Documento]
    Case RetVal="F4" And Field()="Tipo do Documento":
         Del
         IMPRIME()
         CHAVE=5
         QuitLoop
    Case RetVal="F8":
         CONFIRMA()
         If OK="S"
            Then BAIXA()
                 CHAVE=9
                 QuitLoop
         Endif
    Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME" And Field()="Tipo do Documento":
         While True
           PAGINA("Answer","MR")
           If EDITAR="S"
              Then CHAVE=0
                   Return
              Else If EXCLUIR="S"
                      Then CONFIRMA()
                           If OK="S"
                              Then DEL
                           EndIf
                      Else End
                           Down
                           Moveto [Tipo do Documento]
                           QuitLoop
                   EndIf
           EndIf
           End Down
         EndWhile
    Case Retval="ESC":
         If Field()="Tipo do Documento"
            Then CHAVE=9
                 Do_It!
                 ClearAll
                 Quitloop
         EndIf
    EndSwitch
  EndWhile
  If CHAVE=0 OR CHAVE=9
     Then QuitLoop
  EndIf
EndWhile
EndProc

;*******************************************************************************
;* Rotina De Impressao                                                         *
;*******************************************************************************
Proc IMPRIME()
DISPOSITIVO()
If OK = ""
   Then Return
EndIf
Do_It!
ClearAll

AGUARDE("Aguarde, Imprimindo Rela‡„o")
CopyReport  "\\Base\\Sistemas\\CtaRec\\BxComAut" "R" "Answer" "R"

IMPRIREL("Answer","R")
ClearAll

CoEdit "Answer"
PickForm "F"
LIMPAGUARDE()
EndProc

;*******************************************************************************
;* Seleciona Registros para Atualizacao                                        *
;*******************************************************************************
Proc SELECIONAI()
Edit "Answer"
SetHighLight Current Record 23 Field 31
{Image} {KeepSet}
Do_It!
CoEdit "Answer"
PickForm "F"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
EndWhile
ClearAll
EndProc

;*******************************************************************************
;*Realiza Baixa Automatica de Comissoes                                        *
;*******************************************************************************
Proc BAIXA()
Do_It!
ClearAll

AGUARDE("Aguarde, Atualizando Pagamento de Comissoes")
View   "DupBaixa"
CoEdit "Answer"
Scan
  NLANC=[Numero do Lancamento]
  NITEM=[Sequencia da Baixa  ]

  Moveto "DupBaixa"
  Moveto [Numero do Lancamento]
  Locate NLANC,NITEM
  If Retval
     Then 
          while islockrecord() endwhile
          [Data Pagamento Comissao]=VSDGDTREF
          UnLockRecord
  EndIf

  Moveto "Answer"
EndScan
Do_it!
ClearAll
LIMPAGUARDE()
MENSAGEM("Atualizacao Concluida!")
EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESA"
            Case Campo="TG_DTINI"         : Campo="TG_REPRESEN"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DTREF"         : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_DTREF"
                    Case Campo="TG_DTREF"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a Data Inicial"
  Case Campo="TG_DTREF":
       MSG_CAMPO="Informe a Data de Pagamento da Comiss„o"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA =""
VSDGREPRESEN=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()
VSDGDTREF   =BlankDate()

While True
  ShowDialog "Baixa Autom tica p/ Comiss„o" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 13 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 3,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 3,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 06,00 "Data Pagto Comiss„o" For "TG_DTREF"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTREF" To VSDGDTREF

    Pushbutton @ 09,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 09,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If VSDGDTINI=BlankDate()
     Then Mensagem("Data Inicial Invalida !")
          Loop
  EndIf
  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  If VSDGDTREF<VSDGDTFIM
     Then Mensagem("Data do Pagamento da Comiss„o menor que Data Final !")
          Loop
  EndIf

  AGUARDE("Aguarde, Selecionando registros")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf

  SELECIONAI()
  Echo Normal
  Echo Off

  ClearAll
  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
