;** Rm_0110 ********************************************************************
;*  Emissao dos Titulos Recebidos por Cliente                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE
;Ultima Alteracao: 22/12/2016 por Rafael Matos
;Motivo Alteracao: InclusÆo Filtro TG_TIPOBAIXA                
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog 
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT
;Ultima Alteracao: 09/05/2017 por Rafael Matos
;Motivo Alteracao: Incluso TG_OPCCUSTO  
;Ultima Alteracao: 13/11/2019 por Bruno Carvalho
;Motivo Alteracao: Unifica‡Æo do RM_0283 (81 no Menu) no RM_0126 (79 no Menu)              
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 14/05/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_OPCCUSTO            

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa")

   Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Numero do Lancamento   ] Example "lanc"
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Destinatario ] TypeIn "~VSDGDESTINAT.."
        Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
        
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
        Moveto [Numero do Lancamento  ] Example "lanc"
        Moveto [Data do Pagamento     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo da Baixa         ] 
        Switch
            Case VSDGTIPOBAIXA="N"  : TypeIn "Blank or NORMAL"
            Case VSDGTIPOBAIXA="C"  : TypeIn "Blank or CANCELADO"
            Case VSDGTIPOBAIXA="D"  : TypeIn "Blank or DEVOLUCAO"
        EndSwitch    
        Moveto [Codigo da Conta       ] TypeIn "~VSDGCONTA.."
        Moveto [Codigo Plano_Conta    ] TypeIn PLCONTAS
        If CheckTG_OPCCUSTO[1]
           Then Moveto [Codigo CCusto          ] TypeIn "Not Blank, ~VSDGCCUSTO.."
           Else Moveto [Codigo CCusto          ] TypeIn "~VSDGCCUSTO.."
        Endif
        Do_It!
        ClearAll

EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
  If VSDGCODMODELO="81B"
     Then [Valor do Desconto-1]=([Valor do Desconto-1]*-1)                      ;RM_0283 -> O script nÆo estava somando o juros, criado "81B" p/ essa finalidade
     Else [Valor do Desconto-1]=([Valor do Desconto-1]*-1)+[Valor do Juros]     ;RM_0126 -> Sempre calculou com o juros
  EndIf   
  If IsBlank([Valor do Desconto-1]) Then [Valor do Desconto-1]=0 EndIf
EndScan
Do_It!
ClearAll

EndProc   ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DESTINAT"      : Campo="TG_CONTA"
            Case Campo="TG_REPRESEN"      : Campo="TG_DESTINAT"
            Case Campo="TG_PLCONTAS"      : Campo="TG_REPRESEN"
            Case Campo="TG_CCUSTO"        : Campo="TG_PLCONTAS"
            Case Campo="TG_OPCCUSTO"      : Campo="TG_CCUSTO"
            Case Campo="TG_DTINI"         : Campo="TG_OPCCUSTO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_TIPOBAIXA"     : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"     : Campo="TG_TIPOBAIXA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"  : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"   : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"   : Campo="TG_PLCONTAS"
                    Case Campo="TG_PLCONTAS"   : Campo="TG_CCUSTO"
                    Case Campo="TG_CCUSTO"     : Campo="TG_OPCCUSTO"
                    Case Campo="TG_OPCCUSTO"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_TIPOBAIXA"
                    Case Campo="TG_TIPOBAIXA"  : Campo="TG_CODMODELO" 
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")
                       
ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Plano de Conta/Ct.Custo/Representante")
ModeloRelatoriosAdd("02  Por Plano de Conta")
ModeloRelatoriosAdd("81  Por Representante/Plano de Conta/Ct.Custo")
ModeloRelatoriosAdd("81B Por Representante/Plano de Conta/Ct.Custo - S¢ Desconto")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  =""
VSDGCONTA    =""
VSDGDESTINAT =""
VSDGPLCONTAS =""
VSDGCCUSTO   =""
VSDGDTINI    =BlankDate()
VSDGDTFIM    =BlankDate()
VSDGREPRESEN =""
VSDGNOMREPR  =""
VSDGCODMODELO=""
VSDGMODELO   =""

Array CheckTG_OPCCUSTO[1] CheckTG_OPCCUSTO[1]=False

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos Recebidos por Plano de Conta/Ct.Custo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 03,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 06,00 "Representante"  For "TG_REPRESEN"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR

    Label  @ 08,00 "Plano de Contas" For "TG_PLCONTAS"
    Accept @ 09,01 Width 33 "A13"  Picture "!*!" Tag "TG_PLCONTAS" To VSDGPLCONTAS
    Accept @ 10,01 Width 33 "A40" Picture "!*!" Tag "TG_NOMPLCONTAS"  To VSDGNOMPLCONTAS

    Label  @ 11,00 "CentroDeCusto" For "TG_CCUSTO"
    Accept @ 12,01 Width 33 "A7"  Picture "###.###" Tag "TG_CCUSTO" To VSDGCCUSTO
    Accept @ 13,01 Width 33 "A20" Picture "!*!" Tag "TG_NOMCUST"  To VSDGNOMCUST

    CheckBoxes @ 11,14 Height 1 Width 20 Tag "TG_OPCCUSTO" "NÆoVerEmBrancos" to CheckTG_OPCCUSTO[1]

    Label  @ 00,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 01,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 01,51 "at‚" For "TG_DTFIM"
    Accept @ 01,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 02,35 "Op‡Æo de Baixa"  For "TG_TIPOBAIXA"
    Accept @ 03,39 Width 04 "A1"  Picture "N,D,C" Tag "TG_TIPOBAIXA" To VSDGTIPOBAIXA
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTIPOBAIXA" To VSDGNOMTIPOBAIXA
    
    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  If Len(VSDGPLCONTAS)<13
     Then PLCONTAS=VSDGPLCONTAS + ".."
     Else PLCONTAS=VSDGPLCONTAS
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  Switch
    Case VSDGCODMODELO="01"  :
         CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "2" Tabela "R"
         IMPRIREL(Tabela,"R")
    Case VSDGCODMODELO="02"  :
         CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "8" Tabela "R"
         IMPRIREL(Tabela,"R")
    Case VSDGCODMODELO="81"  :
         CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "3" Tabela "R"
         IMPRIREL(Tabela,"R")
    Case VSDGCODMODELO="81B" :
         CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "9" Tabela "R"
         IMPRIREL(Tabela,"R")
  EndSwitch
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
