;** Exp_Cust  ******************************************************************
;* Exportacao de Dados para Custo                                              *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 11/11/2013 por Bruno Carvalho
;Ultima Alteracao: 26/11/2013 por Bruno Carvalho  
;Motivo Alteracao: Ajustes 
;Ultima Alteracao: 07/07/2014 por Bruno Carvalho
;Motivo Alteracao: Ajustes ao buscar o custo na Ficha de Estoque
;Ultima Alteracao: 01/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                  
;Ultima Alteracao: 14/05/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_CCUSTO            

;*******************************************************************************
;* Rotina para Gerar Arquivo TXT                                               *
;*******************************************************************************
Proc Gera_txt(PARAM)
Private PARAM

Switch
   Case PARAM = "PlConta" : 
        NR=NRecords("\\Sistemas\\CtaCor\\Plcontas")
                
        View "\\Sistemas\\CtaCor\\Plcontas"
        Scan
          Barra(NR, RecNo())
          Aguarde("Aguarde, Importando PlConta "+Format("W8,AR",Recno())+"/"+Format("W8,AR",NR)+" "+BARRA_STRING)
        
          COD_PLC = [Codigo Plano_Conta]
          DES_PLC = Tira_CharEspecial([Descricao Plano_Conta])
        
          Print File ARQ "01"+";"+COD_PLC+";"+DES_PLC+"\n"
        EndScan 
        Clearall

   Case PARAM = "Caixa" :
        {Ask} {\\Sistemas\\CtaCor\\MovCont}
        Moveto [Codigo da Empresa    ] TypeIn "~VSDGEMPRESA"
        Moveto [Codigo da Conta      ] Check TypeIn "~VSDGCONTA.."
        Moveto [Codigo Plano_Conta   ] Check
        Moveto [Descricao Plano_Conta] Check
        Moveto [Data                 ] Check TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Tipo Movimento       ] TypeIn "S" 
        Moveto [Codigo CCusto        ] TypeIn "~VSDGCCUSTO"
        Moveto [Valor                ] TypeIn "Calc Sum as Valor"
        Do_It!
        ClearAll
   
        NR=NRecords("Answer")
        
        View "Answer"
        Scan
          Barra(NR, RecNo())
          Aguarde("Aguarde, Importando Caixa "+Format("W8,AR",Recno())+"/"+Format("W8,AR",NR)+" "+BARRA_STRING)
           
          COD_CONT = [Codigo da Conta      ]
          COD_PLC  = [Codigo Plano_Conta   ]
          DES_PLC  = Tira_CharEspecial([Descricao Plano_Conta]) 
          DATA     = StrVal([Data          ])
          VALOR    = StrVal([Valor         ])
          
          Print File ARQ "02"+";"+COD_CONT+";"+COD_PLC+";"+DES_PLC+";"+DATA+";"+VALOR+"\n"
        EndScan
        Clearall
   Case PARAM = "Itens" : 
        If IsTable("\\FechAno\\"+VSDGANO+"\\Estoque\\Sdestq") 
           Then TAB_TEMP = "\\FechAno\\"+VSDGANO+"\\Estoque\\Sdestq"
           Else TAB_TEMP = "\\Sistemas\\Estoque\\SdEstq"
        EndIf 
        
        NR=NRecords("\\Sistemas\\Estoque\\Itens")
        
        ANO = StrVal(Year(Today()))
        MES = StrVal(Month(Today()))
        
        View TAB_TEMP
        View "\\Sistemas\\Estoque\\Itens"
        Scan for [Tipo do Item]="M" Or [Tipo do Item]="P"
          Barra(NR, RecNo())
          Aguarde("Aguarde, Importando Itens "+Format("W8,AR",Recno())+"/"+Format("W8,AR",NR)+" "+BARRA_STRING)
                    
          COD_ITEM = [Codigo do Item]
          DES_ITEM = [Descricao do Item]
          
          ;**** Apenas Itens de Materia Prima **********************************
          If [Tipo do Item]="M"
             Then Moveto TAB_TEMP
                  Moveto [Codigo da Empresa]
                  Locate VSDGEMPRESA,COD_ITEM,ANO,MES 
                  If RetVal
                     Then CUSTO = StrVal([Preco de Custo])
                          DATA  = StrVal([Data do Preco de Custo])
                     Else CUSTO = "0"
                          DATA  = ""
                  EndIf
                  Moveto "\\Sistemas\\Estoque\\Itens"
             Else CUSTO = "0"
                  DATA  = ""
          EndIf
          Print File ARQ "03"+";"+COD_ITEM+";"+DES_ITEM+";"+CUSTO+";"+DATA+"\n"
        EndScan
        Clearall
EndSwitch

EndProc ;Gera_txt()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_CONTA"          : Campo="TG_EMPRESA"
            Case Campo="TG_CCUSTO"         : Campo="TG_CONTA"
            Case Campo="TG_DTINI"          : Campo="TG_CCUSTO"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA":
                         If Not IsBlank(VSDGEMPRESA)
                            Then Campo="TG_CONTA"
                            Else Mensagem("Informe a Empresa !")
                         EndIf
                    Case Campo="TG_CONTA"  : Campo="TG_CCUSTO"
                    Case Campo="TG_CCUSTO" : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"  : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"  : Campo="YES"
                  EndSwitch
          EndIf
   EndSwitch
EndIf

RefreshDialog
Switch
  Case Campo="TG_EMPRESA":
       MSG_CAMPO="Informe uma Empresa ou Branco desativa"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGDRIVE=SubStr(Directory(),1,2)
VSDGPASTA="\\Sistemas\\EXPORTA\\DADOS\\EXP_CUST"
ARQ = VSDGDRIVE+VSDGPASTA+"\\EXP_CUST.txt"

If DirExists(VSDGDRIVE+VSDGPASTA)=0
   Then Cria_Pasta(VSDGDRIVE+VSDGPASTA)
        Sleep 2000
EndIf

VSDGEMPRESA   = ""
VSDGNOMEMP    = ""
VSDGCONTA     = ""
VSDGNOMCONTA  = ""
VSDGCCUSTO    = ""
VSDGNOMCUST   = ""
VSDGDTINI     = BlankDate()
VSDGDTFIM     = BlankDate()

While True
  ShowDialog "Exporta‡„o de Dados para Custo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB"
   @ 05,12   Height 14 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA                 
                     
    Label  @ 04,00 "CentroDeCusto" For "TG_CCUSTO"
    Accept @ 05,01 Width 33 "A7"  Picture "###.###" Tag "TG_CCUSTO" To VSDGCCUSTO
    Accept @ 06,01 Width 33 "A20" Picture "!*!" Tag "TG_NOMCUST"  To VSDGNOMCUST

    Label  @ 07,00 "Perˇodo Referente de" For "TG_DTINI"
    Accept @ 08,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 08,16 "at‚" For "TG_DTFIM"
    Accept @ 08,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Pushbutton @ 10,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  
  Deleta_Arquivo(ARQ)
  
  Gera_txt("PlConta")
  Gera_txt("Caixa")
  Gera_txt("Itens")
  
  If IsFile(ARQ)
     Then Mensagem("Processo Concluido com Sucesso !////"+Upper(ARQ))
   EndIf     
  
  QuitLoop
EndWhile
ClearAll
Release Vars All
Release Procs All
