;* acpedgi *********************************************************************
;* gerar pedidoi atraves do pedigog                                            *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 14/11/2014 por Anivel Augusto Rodrigues
;Ultima Alteracao: 27/07/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nÆo usar condi‡Æo pagamento por item
;Ultima Alteracao: 19/10/2017 por Bruno Carvalho
;Motivo Alteracao: Removido da Gera_PedidoI() -> Aliquota Reduzida BCIPI, Valor IPI por Unidade, Condicao de Pagamento, Composicao de Dias
;Ultima Alteracao: 20/10/2017 por Bruno Carvalho
;Motivo Alteracao: Removido da Gera_PedidoI() -> Codigo da Marca
;Ultima Alteracao: 31/10/2017 por Bruno Carvalho
;Motivo Alteracao: Removido de Grava_PedidoI() -> Empresa Atendimento
;Ultima Alteracao: 11/09/2018 por Bruno Carvalho
;Motivo Alteracao: Comentados campos que foram removidos da tabela PEDIDOI 
;Ultima Alteracao: 06/05/2020 por Bruno Carvalho
;Motivo Alteracao: Alterado Monta_Array_Grade() p/ Array_Monta_Grade() *Bib_Proc

;*******************************************************************************
;* Rotina Gera Tabela PedidoI                                                  *
;*******************************************************************************
Proc Gera_PedidoI()
Private i,tm, item, ItemNovo, nr, grdant, seq

Moveto "PedidoI"
If RecordStatus("New")=False 
   Then Moveto "PedidoC"
        Return
EndIf    

Moveto "Pedidog"
NR = NIMAGERECORDS()
If NR<1 
   Then Moveto "PedidoC"
        Return
EndIf    

grdant="***"
Seq=0
Scan

  CopyToArray RegPed
  Array_Monta_Grade("")

  Qtd=0 QtdF=0
  For I From 1 To 12
    TM=RTrim(SubStr(Array_TM[i],4,2))
    If TM="" 
       Then Loop 
    EndIf

    Switch
      Case i=1 : Qtd=RegPed["Qtd1"]  QtdF=RegPed["QtdF1"]  
      Case i=2 : Qtd=RegPed["Qtd2"]  QtdF=RegPed["QtdF2"]  
      Case i=3 : Qtd=RegPed["Qtd3"]  QtdF=RegPed["QtdF3"]  
      Case i=4 : Qtd=RegPed["Qtd4"]  QtdF=RegPed["QtdF4"]  
      Case i=5 : Qtd=RegPed["Qtd5"]  QtdF=RegPed["QtdF5"]  
      Case i=6 : Qtd=RegPed["Qtd6"]  QtdF=RegPed["QtdF6"]  
      Case i=7 : Qtd=RegPed["Qtd7"]  QtdF=RegPed["QtdF7"]  
      Case i=8 : Qtd=RegPed["Qtd8"]  QtdF=RegPed["QtdF8"]  
      Case i=9 : Qtd=RegPed["Qtd9"]  QtdF=RegPed["QtdF9"]  
      Case i=10: Qtd=RegPed["Qtd10"] QtdF=RegPed["QtdF10"] 
      Case i=11: Qtd=RegPed["Qtd11"] QtdF=RegPed["QtdF11"] 
      Case i=12: Qtd=RegPed["Qtd12"] QtdF=RegPed["QtdF12"] 
    EndSwitch
    If Qtd<=0 
       Then Loop 
    EndIf

    If Len(TM)=1
       Then Item=SubStr(RegPed["Codigo do Item"],1,9)+TM
       Else Item=SubStr(RegPed["Codigo do Item"],1,8)+TM
    EndIf
    
    ItemNovo=True 
    Moveto "PedidoI"
    Moveto [Codigo do Item]
    Locate Item
    If RetVal
       Then While True 
              If [Preco Unitario]=RegPed["Preco Unitario"]
                 Then ItemNovo=False
                      QuitLoop
              EndIf        
              Skip
              If EOT() Then QuitLoop EndIf
            EndWhile
    EndIf

    If Not ItemNovo
       Then [Quantidade               ]=[Quantidade               ]+Qtd
            [Quantidade Faturada      ]=[Quantidade Faturada      ]+QtdF
            [Peso Liquido             ]=[Peso Liquido             ]+RegPed["Peso Liquido"]
            [Peso Embalagem           ]=[Peso Embalagem           ]+RegPed["Peso Embalagem"]
            [Volumes                  ]=[Volumes                  ]+RegPed["Volumes"]
       Else End Down
            Seq=Seq+1
            [Numero do Pedido         ]=RegPed["Numero do Pedido"]
            [Item do Pedido           ]=Seq
            [Codigo do Item           ]=Item
            [Codigo da Cor_Tecido     ]=RegPed["Codigo da Cor_Tecido"]
            [Tamanho                  ]=RegPed["Tamanho"]
            [Quantidade               ]=Qtd
            [Quantidade Faturada      ]=QtdF
            [Preco Unitario           ]=RegPed["Preco Unitario"]
            [Taxa Desconto Unitario   ]=RegPed["Taxa Desconto Unitario"]
            [Valor Desconto Unitario  ]=RegPed["Valor Desconto Unitario"]
            [Preco Total              ]=RegPed["Preco Total"]
            [Preco Unitario Tabela    ]=RegPed["Preco Unitario Tabela"]
            [Taxa Desconto Total      ]=RegPed["Taxa Desconto Total"]
            [Valor Desconto Total     ]=RegPed["Valor Desconto Total"]
            [Peso Liquido             ]=RegPed["Peso Liquido"]
            [Peso Embalagem           ]=RegPed["Peso Embalagem"]
            [Volumes                  ]=RegPed["Volumes"]
            [Codigo da Tabela         ]=RegPed["Codigo da Tabela"]                                         
            [Tipo Tributacao          ]=RegPed["Tipo Tributacao"]      
            [CFO                      ]=RegPed["CFO"]
          
            [Tributacao de ICMS       ]=RegPed["Tributacao de ICMS"]
            [Aliquota Reduzida BCICMS ]=RegPed["Aliquota Reduzida BCICMS"]
            [Aliquota de ICMS         ]=RegPed["Aliquota de ICMS"]
            [Valor do ICMS            ]=RegPed["Valor do ICMS"]
     
            [CSOSN                    ]=RegPed["CSOSN"]    
            [MVA                      ]=RegPed["MVA"]
            [NCM                      ]=RegPed["NCM"]
                                        
            [ICMS_ST_Aliquota         ]=RegPed["ICMS_ST_Aliquota"] 
            [ICMS_ST_BC               ]=RegPed["ICMS_ST_BC"]            
            [ICMS_ST_Valor            ]=RegPed["ICMS_ST_Valor"] 
            [ICMS_BC                  ]=RegPed["ICMS_BC"] 
            ;[ICMS_CredSN_Aliquota     ]=RegPed["ICMS_CredSN_Aliquota"] 
            ;[ICMS_CredSN_Valor        ]=RegPed["ICMS_CredSN_Valor"] 
                                                       
            [Tributacao de IPI        ]=RegPed["Tributacao de IPI"]
            [Aliquota de IPI          ]=RegPed["Aliquota de IPI"]
            [Valor do IPI             ]=RegPed["Valor do IPI"]
            [IPI_CST                  ]=RegPed["IPI_CST"] 
            [IPI_BC                   ]=RegPed["IPI_BC"]            
                                  
            [Tributacao de ISSQN      ]=RegPed["Tributacao de ISSQN"] 
            [Aliquota de ISSQN        ]=RegPed["Aliquota de ISSQN"] 
            ;[Codigo_Servico           ]=RegPed["Codigo_Servico"]            
            ;[ISSQN_BC                 ]=RegPed["ISSQN_BC"] 
            ;[ISSQN_UF                 ]=RegPed["ISSQN_UF"] 
                                     
            [PIS_CST                  ]=RegPed["PIS_CST"] 
            [PIS_Aliquota             ]=RegPed["PIS_Aliquota"] 
            ;[PIS_BC                   ]=RegPed["PIS_BC"]            
            ;[PIS_Valor                ]=RegPed["PIS_Valor"] 
                                     
            [COFINS_CST               ]=RegPed["COFINS_CST"] 
            [COFINS_Aliquota          ]=RegPed["COFINS_Aliquota"] 
            ;[COFINS_BC                ]=RegPed["COFINS_BC"]            
            ;[COFINS_Valor             ]=RegPed["COFINS_Valor"] 
            UnLockRecord
    EndIf

    If [Taxa Desconto Unitario]>0
       Then [Valor Desconto Unitario]=NDecimal(([Preco Unitario]*[Taxa Desconto Unitario])/100,2)
    EndIf
    If [Quantidade]>0
       Then [Preco Total]=[Quantidade]*([Preco Unitario]-[Valor Desconto Unitario])
       Else If [Preco Unitario]>0
               Then [Preco Total]=[Preco Unitario]-[Valor Desconto Unitario]
            EndIf
    EndIf
    If [Aliquota Reduzida BCICMS]>0 And
       [Aliquota de ICMS        ]>0
       Then [Valor do ICMS]=Round((([Preco Total]-(([Preco Total]*[Aliquota Reduzida BCICMS])/100))*[Aliquota de ICMS])/100,2)
       Else [Valor do ICMS]=Round(([Preco Total]*[Aliquota de ICMS])/100,2)
    EndIf
    If [Tributacao de IPI]<>"D"
       Then If Not IsBlank([Tributacao de IPI])
               Then [Aliquota de IPI]=BlankNum()
                    [Valor do IPI   ]=BlankNum()
            EndIf
    EndIf
    If [Aliquota de IPI        ]>0
       Then [Valor do IPI]=Round(([Preco Total]*[Aliquota de IPI])/100,2)
    EndIf
    UnLockRecord
  EndFor

  Moveto "PedidoG"
EndScan

Moveto "PedidoC"
EndProc

;*******************************************************************************
;* Rotina para Carregar Parametros                                             *
;*******************************************************************************
Proc Carrega_Parametros()

GetRecord "\\Sistemas\\Vendas\\P_Pedido" [PedidoC->Codigo da Empresa] To REG_PPEDIDO 
If Not RetVal
   Then Mensagem("Parametros P_Pedido n„o Cadastrado para a Empresa ["+[PedidoC->Codigo da Empresa]+"] !")
        Moveto "PedidoC"
        Return False
EndIf

PARAM_ALTERA_FP                ="S"
PARAM_DESTINACAO               =REG_PPEDIDO["Codigo_Destinacao"    ]
PARAM_RELATORIO                =REG_PPEDIDO["Script_ImpressaoG"    ]
PARAM_RELATORIO_S              =REG_PPEDIDO["Script_ImpressaoG_S"  ]
PARAM_DATAS_VENCTOS            =REG_PPEDIDO["Datas_Vencimentos"    ]
PARAM_COR_TECIDO               =REG_PPEDIDO["Cor_Tecido"           ]
PARAM_TAMANHO                  =REG_PPEDIDO["Tamanho"              ]
PARAM_DESCUNIT                 =REG_PPEDIDO["Desconto Unitario"    ]
PARAM_VOLUMES                  =REG_PPEDIDO["Volumes"              ]
PARAM_SUBSTICMS                =REG_PPEDIDO["Substituicao ICMS"    ]
PARAM_IMPOSTOS                 =REG_PPEDIDO["Impostos"             ]
PARAM_TABELA_PRECO             =REG_PPEDIDO["Tabela_Preco"         ]
PARAM_TRANSPORTADORA           =REG_PPEDIDO["Codigo_Transportadora"]
PARAM_COMIS_ITEM               =REG_PPEDIDO["Comissao_Item"        ]
PARAM_COMIS_MARCA              =REG_PPEDIDO["Utiliza_Comissao_Marca"   ]

PARAM_TABPR_ITEM               =REG_PPEDIDO["Utiliza_Tabela_Preco_Item"]
PARAM_COMIS_VENCTO             =REG_PPEDIDO["Calcula_Comissao_Vencto"  ]
PARAM_VISITA                   =REG_PPEDIDO["Utiliza_Visita"           ]
PARAM_UTILIZA_TABPR_CLIENTE    =REG_PPEDIDO["Utiliza_TabPreco_Cliente" ]
PARAM_UTILIZA_TABPR_REPRES     =REG_PPEDIDO["Utiliza_TabPreco_Repres"  ]
PARAM_PEGAPRECO_CPAGTO         =REG_PPEDIDO["Pega_Preco_Tabela_CPagto" ]
PARAM_ALTERA_PRECO             =REG_PPEDIDO["Utiliza_Alteracao_Preco"  ]
PARAM_CONDPAGTO                =REG_PPEDIDO["Utiliza CP e FP Cliente"  ]
PARAM_PEDIDOIMP                =REG_PPEDIDO["Altera Pedido PosImpresso"]

If SYS_CODIGO_CLIENTE="0102" Or
   SYS_CODIGO_CLIENTE="0114"
   Then PARAM_CALC_COMIS_ITEM="S"
   Else PARAM_CALC_COMIS_ITEM="N"
EndIf

Moveto "PedidoC"
Return True

EndProc ; (Carrega_Parametros)


;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DTINI"         : Campo="TG_EMPRESA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"  : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"    : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"    : Campo="YES"           
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
      MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;***************************+***************************************************
;* Rotina Principal Pedidos                                                    *
;*******************************************************************************
;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

Sys_Valor()

VSDGEMPRESA  = ""
VSDGDTINI    = BlankDate()
VSDGDTFIM    = BlankDate()

While True

  ShowDialog "Gera‡Æo de itens do pedido [PedidoI] que foram PERDIDOS" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
  @ 05,05   Height 09 Width 65

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP
  
    Label  @ 02,00 "Per¡odo de EmissÆo Referente" For "TG_DTINI"
    Label  @ 03,00 "de" For "TG_DTINI"
    Accept @ 03,04 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,17 "at‚" For "TG_DTFIM"
    Accept @ 03,22 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Pushbutton @ 05,14 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 05,28 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  If SYS_CLIENTE_CONFEC<>"" And 
     ConfGeral("Confirma gerar itens do pedido pelo PedidoG ?")
     then 
          Array Array_TM[12]
          
          Array CODIGO[900]
          Array QUANTI[900]
          Array PRECOU[900]
          
          emprant="****"
          nr=nrecords("PedidoC")
          
          CoEdit "PedidoC"
          PickForm "4"
          Scan
           Barra(NR, RecNo())
           Aguarde("Aguarde, gerando itens no modo padr„o "+BARRA_STRING)

           If VSDGEMPRESA<>"" And
              [Codigo da Empresa]<>VSDGEMPRESA
              Then Loop
           EndIf
           If [Data de Emissao]<VSDGDTINI Or
              [Data de Emissao]>VSDGDTFIM   
              Then Loop
           EndIf
          
           If [Codigo da Empresa]<>emprant
              Then emprant=[Codigo da Empresa]
                   If Carrega_Parametros()
                      Then paramok=true
                      else paramok=false
                   EndIf
           EndIf   

           if paramok then Gera_PedidoI() endif
          
          EndScan        
          Do_It!
          ClearAll
          
          Mensagem("Fim do processo !")
  EndIf   
EndWhile

ClearAll
Release Vars All
Release Procs All
