;** RO_0397B *******************************************************************
;** Romaneio                                                                   *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido  em: 15/05/2020 por Bruno Carvalho
;Ultima Alteracao:   /  /     por                   
;Motivo Alteracao: 

;Imprime 2 vias em folha A4, por‚m se quantidade de itens maior que 14, ir  imprimir 2 vias em folha inteira

;*******************************************************************************
;* Checa linha na area de impressao dos itens                                  *
;*******************************************************************************
Proc Checa_Linha(nl)
private nl, ntab
                              
ntab=table()

If (CONTADOR+nl)>64          
   Then Romaneiomaisdeumafolha=true
        Print File ARQIMP "\n"
        Print File ARQIMP Format("W117,AC","*** CONTINUA PROXIMA FOLHA ***")+"\f"
        Cabecalho()
EndIf   
CONTADOR=CONTADOR+nl
        
moveto ntab
EndProc 
        
 ;*******************************************************************************
;* ImpressÆo do Cabe‡alho                                                      *
;*******************************************************************************
Proc Cabecalho();

If Not IsAssigned(NOMEMPRESA) Then NOMEMPRESA="" EndIf

Moveto "Faturac"
Print File ARQIMP chr(27)+chr(67)+chr(33) ;Imprime 33 Linhas por pagina
Print File ARQIMP "\018"
Print File ARQIMP CI_10CPP
;Print File ARQIMP CI_6LPP

;Print File ARQIMP "\n"
Print File ARQIMP Format("W50,AL","CONTROLE INTERNO - Balcao 3")+"Impressao: "+Format("D10",Today())+"-"+Time()+ "\n\n"
;Print File ARQIMP "\027E"
;Print File ARQIMP Spaces(01)+ "ENTREGA : "+Format("W35,AL",[Endereco de entrega])+"Bairro :" +Format("W15,AL",[Bairro de Entrega])+"\n"

Print File ARQIMP "\014"
Print File ARQIMP "\027E"
Print File ARQIMP Spaces(20)+"Orcamento N§ "+Format("W06.3,AL",NOTAFISC)+"\n"
Print File ARQIMP "\020"

Print File ARQIMP "Cliente : "+Format("W05,AL",[Codigo])+Format("W46,AL",[Razao Social])+"\n"
Print File ARQIMP "\027F"

;Print File ARQIMP CI_8LPP
Print File ARQIMP "\027P"         ;Imprime 10 Caracteres por polegada

Print File ARQIMP Spaces(10)+Format("W40,AL",[Endereco])
Print File ARQIMP Format("W18,AL",[CGC])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Bairro])
Print File ARQIMP Format("W20,AL",[CEP])
Print File ARQIMP Format("W25,AL",[IE])+"\n"

Print File ARQIMP Spaces(10)+Format("W20,AL",[Cidade])
Print File ARQIMP Format("W20,AL",[UF])
Print File ARQIMP Format("W25,AL",[Telefone])+"\n"

Print File ARQIMP "Operacao: "
Print File ARQIMP Chr(27)+Chr(71)
Print File ARQIMP ""+[Codigo da Destinacao]+" "+[Descricao da Destinacao]+"\n"
Print File ARQIMP Chr(27)+Chr(72)

Print File ARQIMP "Vendedor: "+Format("W05,AL",[Codigo do Representante])
Print File ARQIMP Format("W25,AL",[Nome Fantasia Represent])+"\n"

Print File ARQIMP "\015"         ;Imprime 17 Caracteres por polegada

;********************* IMPRESSAO DOS ITENS ********************************
Print File ARQIMP "------------------------------------------------------------------------------------------------------------------------"+"\n"
Print File ARQIMP Spaces(02)+"Item                                                                             Un  Quantidade  Unitario        Total"+"\n"
Print File ARQIMP "------------------------------------------------------------------------------------------------------------------------"+"\n"

CONTADOR = 14

EndProc ;(Cabecalho)

;*******************************************************************************
;* ImpressÆo dos Itens                                                         *
;*******************************************************************************
Proc Itens()

Moveto "FaturaI"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
QUANT    = 0
TOT      = 0
While [Numero da OF]=[FaturaC->Numero da OF]
  Checa_Linha(1)
  
  Print File ARQIMP Spaces(02)+Format("W05,AR",[Item da OF])
  Print File ARQIMP Spaces(01)+Format("W11,AL",[Codigo do Item])
  Print File ARQIMP Spaces(01)+Format("W62,AL",[Descricao do Item])
  Print File ARQIMP Spaces(01)+Format("W03,Al",[Unidade Fiscal])

  If [Quantidade]-Int([Quantidade])>0
     Then Print File ARQIMP Format("W011.3,EIC",[Quantidade])
     Else Print File ARQIMP Format("W011,EIC",[Quantidade])
  EndIf

  Print File ARQIMP Format("W10.2,EIC",[Preco Unitario])
  Print File ARQIMP Format("W13.2,EIC",[Preco Total])+"\n"
  TOT   = TOT + [Preco Total]

  Skip
  If EOT() Then QuitLoop EndIf
EndWhile

For ITEM From CONTADOR To 18          
    Print File ARQIMP "\n"
    CONTADOR=CONTADOR+1  
EndFor 
Print File ARQIMP "------------------------------------------------------------------------------------------------------------------------"+"\n"
;Print File ARQIMP CI_8LPP

EndProc ;(Itens)

;*******************************************************************************
;* ImpressÆo do Rodap‚                                                         *
;*******************************************************************************
Proc Rodape()

Moveto "FaturaC"

Print File ARQIMP Spaces(87)+"Total................."+Format("W11.2,EIC",TOT)+"\n"

Print File ARQIMP "          *** FAVOR MANTER O ENDERECO E O TELEFONE ATUALIZADOS ***"
Print File ARQIMP Spaces(21)+"Desconto"+Format("W06.2,EIC",[Taxa de Desconto]) + "%......"
Print File ARQIMP Format("W12.2,EIC",[Valor Desconto])+"\n"

Print File ARQIMP Spaces(87)+"DespAces.............."+Format("W11.2,EIC",[Valor Despesas Acessorias])+"\n"
Print File ARQIMP Spaces(87)+"Total Liquido........."+Format("W11.2,EIC",[Valor Nota Fiscal])+"\n\n"

Print File ARQIMP "Cond. Pagto: "+[Descricao CondPagto]
Print File ARQIMP "   NP: "+StrVal([Numero de Parcelas])
Print File ARQIMP "   CD: "+[Composicao de Dias]+"\n"
                              
Print File ARQIMP "OBS.: "
Print File ARQIMP Format("W75,AL",SubStr([Observacao na Nota Fiscal],001,73))+"\n\n"

;********************* IMPRESSAO DOS VENCIMENTOS **************************
Print File ARQIMP "\018"
Print File ARQIMP "\027E"
Print File ARQIMP "Vencimentos: "

Array DATA [5]
Array VALOR[5]
Array FPGT [5]
K=0
KV=0
Moveto "FaturaV"
Moveto [Numero da OF]
Locate [FaturaC->Numero da OF]
While [Numero da OF]=[FaturaC->Numero da OF]
  K=K+1
  DATA[K]  = Format("D13",[Data])
  VALOR[K] = Format("W10.2,AR,EIC",[Valor])
  FPGT[K]  = Format("W10","FP: "+[Forma de Pagamento])
  If K=5
     Then VENC()
          K=0
  EndIf
  Skip
  If EOT() Then QuitLoop EndIf
EndWhile
If K>0
   Then VENC()
EndIf
Print File ARQIMP "\027F"              

;************************* IMPRESSAO DO RODAPE *********************************
Print File ARQIMP Spaces(12)+"   /   /     -                                   " + "\n"
Print File ARQIMP Spaces(12)+"-------------------------------------------------" + "\n"
Print File ARQIMP Spaces(12)+"              Data e Assinatura"+"\n"

CONTADOR = CONTADOR + 14  

EndProc

;*******************************************************************************
;* Rotina de Impressao dos Vencimentos                                         *
;*******************************************************************************
Proc VENC()
If KV>0
   Then Print File ARQIMP Spaces(13)
EndIf

For I From 1 to K
  Print File ARQIMP FPGT[I]+Spaces(02)
EndFor
Print File ARQIMP "\n"
Print File ARQIMP Spaces(13)
For I From 1 to K
  Print File ARQIMP DATA[I]+Spaces(02)
EndFor
Print File ARQIMP "\n"
Print File ARQIMP Spaces(13)
For I From 1 to K
  Print File ARQIMP VALOR[I]+Spaces(02)
EndFor
Print File ARQIMP "\n\n"

KV=KV+1
EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
AGUARDE("Imprimindo Romaneio -> "+NOTAFISC)

ArqImp=PrivDir()+"RO_0397B.Txt"
If IsFile(ArqImp)
   Then Deleta_Arquivo(ARQIMP)
EndIf

COPIA = 2
Romaneiomaisdeumafolha=False
VIA=0   
For ty From 1 To COPIA
  VIA = VIA + 1        

  Cabecalho()
  Itens()                                 
  Rodape()
  
  If Mod(VIA,2)>0 and CONTADOR<=33 and COPIA>1 and not Romaneiomaisdeumafolha
     Then Print File ARQIMP "\n\n"                        
     Else Print File ARQIMP "\f"
  Endif
EndFor
ImpriArq(ARQIMP)

LIMPAGUARDE()

Release Vars VALOR,DATA,FPGT,K,VIA,ITEM,ty,wc,
             vrtottc, vrtotou,Romaneiomaisdeumafolha

Release Procs Cabecalho,Checa_Linha,Itens,Rodape