;*******************************************************************************
;* Desenvolvido: 03/08/2020 por Bruno Carvalho                                 *
;*******************************************************************************
Autolib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"

DATAM_DATA   = DateVal("31.07.2020")
DATAM_VERSAO = "2020.G"
 
DATAM_EXECUTA = "SYS_DATAM"
Play "\\Sistemas\\Cadastro\\EXEC_DAT"

If Not DATAM_EXECUTA 
   Then Exit
   Else DATAM_ROTINA  = "Cadastro, Estoque e Vendas"
        DATAM_EXECUTA = "SYS_DATAM_MENSAGEM"
        Play "\\Sistemas\\Cadastro\\EXEC_DAT"
        If Not DATAM_EXECUTA
           Then Exit
        EndIf
EndIf

;*******************************************************************************
;Rotina Corre‡Æo de Tabelas                                                    *
;*******************************************************************************
Proc Correcao_Tabelas_Cadastro()

;---- Em 13/07/2020 por Anivel Augusto Rodrigues ------------------------------- 
If Not IsTable("\\Sistemas\\Cadastro\\Destreds") ;Tabela de redes sociais
   Then Copy "\\Base\\Sistemas\\Cadastro\\Destreds"  "\\Sistemas\\Cadastro\\Destreds"
EndIf


EndProc ;Correcao_Tabelas_Cadastro() 
 
;*******************************************************************************
;Rotina Corre‡Æo de Tabelas                                                    *
;*******************************************************************************
Proc Correcao_Tabelas_Estoque()

;---- Em 10/07/2020 por Bruno Carvalho -----------------------------------------
If Not IsTable("\\Sistemas\\Estoque\\SITE_ERR") ;Tabela para Erros na Exportacao
   Then Copy "\\Base\\Sistemas\\Estoque\\SITE_ERR"  "\\Sistemas\\Estoque\\SITE_ERR"
EndIf

If IsTable("Iten_Eco")
   Then {Modify} {Restructure} {Iten_Eco}
        Moveto [Field Name]
        Locate "IdSite"
        If Not RetVal
           Then End Down
                "IdSite"    Enter  "N"  Enter
        EndIf
        Do_It!
        ClearAll        
        
        {Tools} {Copy} {JustFamily} TypeIn "\\Base\\Sistemas\\Estoque\\Iten_Eco" Enter TypeIn "Iten_Eco" Enter {Replace}
EndIf

;---- Em 21/07/2020 por Bruno Carvalho -----------------------------------------
Array TABELA_ESTOQUE[4]
TABELA_ESTOQUE[1] = "SdLote"
TABELA_ESTOQUE[2] = "NotaEIL"
TABELA_ESTOQUE[3] = "InEIL"
TABELA_ESTOQUE[4] = "RqLote"

For ty From 1 To ArraySize(TABELA_ESTOQUE)
  If Not IsTable("\\Sistemas\\Estoque\\"+TABELA_ESTOQUE[ty]) 
     Then Copy "\\Base\\Sistemas\\Estoque\\"+TABELA_ESTOQUE[ty]  "\\Sistemas\\Estoque\\"+TABELA_ESTOQUE[ty]
  EndIf
EndFor  

EndProc ;Correcao_Tabelas_Estoque()

;*******************************************************************************
;Rotina Corre‡Æo de Tabelas                                                    *
;*******************************************************************************
Proc Correcao_Tabelas_Vendas()

;---- Em 10/07/2020 por Bruno Carvalho -----------------------------------------
Array TABELA_VENDAS[3]
TABELA_VENDAS[1] = "ExpedIL"  
TABELA_VENDAS[2] = "FaturaIL" 
TABELA_VENDAS[3] = "NotaIL"   

For ty From 1 To ArraySize(TABELA_VENDAS)
  If Not IsTable("\\Sistemas\\Vendas\\"+TABELA_VENDAS[ty]) 
     Then Copy "\\Base\\Sistemas\\Vendas\\"+TABELA_VENDAS[ty]  "\\Sistemas\\Vendas\\"+TABELA_VENDAS[ty]
  EndIf
EndFor

If IsTable("ExpedC")
   Then {Modify} {Restructure} {ExpedC}
        Moveto [Field Name]
        Locate "Tipo de Operacao"
        If Not RetVal
           Then End Down
                "Tipo de Operacao"    Enter  "A1"  Enter
        EndIf
        Do_It!
        ClearAll        
        
        {Tools} {Copy} {JustFamily} TypeIn "\\Base\\Sistemas\\Vendas\\ExpedC" Enter TypeIn "ExpedC" Enter {Replace}
EndIf

EndProc ;Correcao_Tabelas_Vendas()

;*******************************************************************************
;Rotina Principal                                                              *
;*******************************************************************************
Aguarde("Atualizando Sistema")
Password("t01avivcl")
Password("FechaSys")

View "SysTable"
SYS_CODIGO_CLIENTE = [Codigo do Cliente]
ClearAll

;-------------------------------------------------------------------------------

DATAM_ROTINA   = "CADASTRO"
DATAM_FECHAMES = ""
DATAM_EXECUTA  = "DATAM_SETDIR"
Play "\\Sistemas\\Cadastro\\EXEC_DAT" 

DATAM_ROTINA   = "ESTOQUE"
DATAM_FECHAMES = "FECHAMES"
DATAM_EXECUTA  = "DATAM_SETDIR"
Play "\\Sistemas\\Cadastro\\EXEC_DAT" 

DATAM_ROTINA   = "VENDAS"
DATAM_FECHAMES = "FECHAMES"
DATAM_EXECUTA  = "DATAM_SETDIR"
Play "\\Sistemas\\Cadastro\\EXEC_DAT" 

{Tools} {More} {Directory} {\\Sistemas\\Cadastro\\}

DATAM_EXECUTA  = "DATAM_SYSTABLE"
Play "\\Sistemas\\Cadastro\\EXEC_DAT" 

UnPassword("t01avivcl")
UnPassword("FechaSys")
LimpAguarde()
FastMsg("Fim da atualiza‡Æo !")

DATAM_EXECUTA  = "DATAM_RELEASE"
Play "\\Sistemas\\Cadastro\\EXEC_DAT"

Release Vars DATAM_EXECUTA   