;** Rm_0101 ********************************************************************
;*  Emissao das programacoes de Corte                                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/09/2010 por Karina
;Ultima Alteracao: 24/11/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajuste de T¡tulo            
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW
;Ultima Alteracao: 02/10/2014 por Andrey Fillipe
;Motivo Alteracao: Retirado Debug
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA
;Ultima Alteracao: 20/02/2017 por Rafael Matos
;Motivo Alteracao: Incluso coluna PERDA
;Ultima Alteracao: 11/05/2017 por Rafael Matos
;Motivo Alteracao: Ajustes Quantidades vindo erradas
;Ultima Alteracao: 15/08/2018 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes nova logica,filtro, report
;Ultima Alteracao: 18/09/2018 por Bruno Carvalho 
;Motivo Alteracao: Ajustes nos modelos  "02B" e "03B" p/ fazer uma ASK da MARCA antes de utilizar o PegaCodigoRaiz()
;Ultima Alteracao: 31/01/2019 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes alterar codigo pai para "P" pegar dados do pai e volta para "S"
;Ultima Alteracao: 25/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 01/07/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro grupo e modelos 01C, 02C e logica

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

;-- Programa‡Æo ----------------------------------------------------------------
AGUARDE("Aguarde, Processando Programa‡Æo Corte")
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ]       TypeIn "_citem"
Moveto [Referencia            ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ]       TypeIn "~VSDGMARCA.."
Moveto [Codigo do Grupo       ]       TypeIn "~VSDGGRP.."
{Ask} {Cfacc}
Moveto [Numero_Corte          ]       TypeIn "_num, ~VSDGCORTE.."
Moveto [Codigo da Empresa     ]       TypeIn "~VSDGEMPRESA.."
Moveto [Data_Programacao      ]
If IsBlank(VSDGCORTE)
  Then TypeIn " >=~VSDGDTINI,<=~VSDGDTFIM"
EndIf
If VSDGSITUACAO<>"TODOS" And VSDGSITUACAO<>""
   Then Moveto [Situacao_Programacao] TypeIn "~VSDGSITUACAO"
EndIf
{Ask} {CfacRI}
Moveto [Numero_Corte         ] Check TypeIn "_num"
Moveto [Codigo do Item       ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade Programada]       TypeIn "Calc Sum as \"Quantidade Programada\""
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

Adiciona_Campo(Tabela,"Quantidade Produzida(N),Quantidade Perda(N)")

{Ask} TypeIn Tabela Enter
Moveto [Numero_Corte            ] Check
Do_it!
ClearAll

TabelaRC=Adiciona_Indice_Temp("Numero_Corte")

;-- Produ‡Æo -------------------------------------------------------------------
AGUARDE("Aguarde, Processando Produ‡Æo Corte")

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item          ]       TypeIn "_citem"
Moveto [Referencia              ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia       ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca         ]       TypeIn "~VSDGMARCA.."
Moveto [Codigo do Grupo         ]       TypeIn "~VSDGGRP.."
{Ask} TypeIn TabelaRC Enter
Moveto [Numero_Corte            ]       Example "num"
{Ask} {PcfaCC}
Moveto [Numero_Producao_Corte   ]       Example "numprod"
Moveto [Numero_Programacao_Corte] Check Example "num" typeIn ", as \"Numero_Corte\""
{Ask} {PcfacRI}      
Moveto [Numero_Producao_Corte   ]       Example "numprod"
Moveto [Codigo do Item          ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade Produzida    ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
Do_It! 
ClearAll 

{Ask} {Answer}
Moveto [Numero_Corte            ] Example "num"
Moveto [Codigo do Item          ] Example "item"
Moveto [Quantidade Produzida    ] Example "qtde"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero_Corte            ] Example "num"
Moveto [Codigo do Item          ] Example "item"
Moveto [Quantidade Produzida    ] Example "qtde"
Do_It! 
ClearAll

;-- Problemas ------------------------------------------------------------------
AGUARDE("Aguarde, Processando Problemas Corte")

{Ask} TypeIn TabelaRC Enter
Moveto [Numero_Corte  ] Example "num"
{Ask} {Pcfacc}
Moveto [Numero_Producao_Corte     ] Example "nprod"
Moveto [Numero_Programacao_Corte  ] Check Example "num" typeIn ", as \"Numero_Corte\""
{Ask} {Cprobc}
Moveto [Numero do Lancamento      ] Check
Moveto [Numero_ProducaoCorte      ] Example "nprod"
Do_It!
ClearAll

Adiciona_Indice("Answer","Numero do Lancamento")

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ]       TypeIn "_citem"
Moveto [Referencia            ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ]       TypeIn "~VSDGMARCA.."
Moveto [Codigo do Grupo       ]       TypeIn "~VSDGGRP.."
{Ask} {Answer}
Moveto [Numero do Lancamento      ] Example "nlanc"
Moveto [Numero_Corte              ] Check
{Ask} {Cprobi}
Moveto [Numero do Lancamento      ] Example "nlanc"
Moveto [Codigo do Item            ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade                ] TypeIn "Calc Sum as Quantidade" 
Moveto [Tipo_Ocorrencia           ] TypeIn "PERDA"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Numero_Corte            ] Example "num"
Moveto [Codigo do Item          ] Example "coditem"
Moveto [Quantidade              ] Example "qtde"

{Ask} TypeIn Tabela Enter typein "Fast Insert"
Moveto [Numero_Corte            ] Example "nprog"
Moveto [Codigo do Item          ] Example "coditem"
Moveto [Quantidade Perda        ] Example "qtde"
Do_It!
ClearAll

;-- Totalizando ----------------------------------------------------------------
AGUARDE("Aguarde, Totalizando dados")

Switch
  Case VSDGCODMODELO="02B" or VSDGCODMODELO="03B":

    LimpaRodape(0)
    
    
    NR=NRecords(Tabela)

    View NoWindow Tabela
    EditKey
    Scan  
      Barra(NR, RecNo())
      Aguarde("Aguarde, agrupando itens 1/2 "+BARRA_STRING)
      
      [Codigo do Item]=PegaCodigoRaiz([Codigo do Item])
      [Codigo do Item]=MudaCodigoPara([Codigo do Item],"P")

    EndScan
    Do_It!
    ClearAll
    
    LimpaRodape(0)
endSwitch


Switch
  Case VSDGCODMODELO="01" or
       VSDGCODMODELO="01C":
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Corte          ] Check
    Moveto [Codigo do Item        ] Check
    Moveto [Quantidade Programada ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Do_It!
    ClearAll

    AGUARDE("Aguarde, Ajustando dados")
    
    {Ask} {Cfacc}
    Moveto [Numero_Corte          ] Example "num"
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Data_Programacao      ] Check
    Moveto [Situacao_Programacao  ] Check
    Moveto [Observacoes           ] Check
    {Ask} {Answer} Check
    Moveto [Numero_Corte          ] Example "num"
    Do_It!
    ClearAll
    

  Case VSDGCODMODELO="02" or VSDGCODMODELO="02B" Or
       VSDGCODMODELO="02C" or 
       VSDGCODMODELO="03" or VSDGCODMODELO="03B":
    {Ask} {Cfacc}
    Moveto [Numero_Corte          ] Example "num"
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Corte          ] Example "num"
    Moveto [Codigo do Item        ] Check
    Moveto [Quantidade Programada ]       TypeIn "Calc Sum as \"Quantidade Programada\""
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Do_It!
    ClearAll

EndSwitch

Delete Tabela

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ]       TypeIn "_citem"
Moveto [Referencia             ] Check
Moveto [Descricao do Item      ] Check
Moveto [Unidade Fiscal         ] Check
Moveto [Tipo do Item           ] Check
Moveto [Codigo da Familia      ] Check
Moveto [Descricao da Familia   ] Check
Moveto [Codigo do Grupo        ] Check
Moveto [Descricao do Grupo     ] Check
Moveto [Codigo da Marca        ] Check
Moveto [Descricao da Marca     ] Check
Moveto [Codigo da Cor_Tecido   ] Check
Moveto [Descricao da Cor_Tecido] Check
{Ask} {Answer} Check
Moveto [Codigo do Item         ]       TypeIn "_citem!"
Do_It!
ClearAll
     
Adiciona_Campo("Answer","Saldo(N),%Concluido(N),Alerta(A20)")


Switch
  Case VSDGCODMODELO="02B" or VSDGCODMODELO="03B":

    LimpaRodape(0)
    
    View NoWindow "Answer"
    EditKey
    Scan  
      Barra(NR, RecNo())
      Aguarde("Aguarde, agrupando itens 2/2 "+BARRA_STRING)

      [Codigo do Item]=MudaCodigoPara([Codigo do Item],"S")

    EndScan
    Do_It!
    ClearAll
    
    LimpaRodape(0)
endSwitch


Delete TabelaRC

;-- Calculos -------------------------------------------------------------------

AGUARDE("Aguarde, Processando Saldo")

If VSDGOPIT="P"
   Then 
        {Ask} {Answer} TypeIn "Fast Delete"
        Moveto [Quantidade Programada] Example "qtd"
        Moveto [Quantidade Produzida ] TypeIn ">=" Example "qtd"
        Do_It!
        ClearAll
EndIf

If VSDGOPIT="D"
   Then 
        {Ask} {Answer} TypeIn "Fast Delete"
        Moveto [Quantidade Programada] Example "qtd"
        Moveto [Quantidade Produzida ] TypeIn "= " Example "qtd"
        Do_It!
        ClearAll
EndIf


{Ask} {Answer} typein "Fast"
Moveto [Quantidade Programada] TypeIn "_qprog"
Moveto [Quantidade Produzida ] TypeIn "_qprod"
Moveto [Quantidade Perda     ] TypeIn "_qperd"
Moveto [Saldo                ] TypeIn "changeto (_qprog - (_qprod + _qperd))"
Do_It!
ClearAll

{Ask} {Answer} typein "Fast"
Moveto [Quantidade Programada] TypeIn "_qprog"
Moveto [Quantidade Produzida ] TypeIn ">_qprog"
Moveto [Alerta               ] TypeIn "changeto \"<-** ATENCAO **\""
Do_It!
ClearAll

{Ask} {Answer} typein "Fast"
Moveto [Quantidade Programada] TypeIn "_qprog"
Moveto [Quantidade Produzida ] TypeIn "_qprod"
Moveto [Quantidade Perda     ] TypeIn "_qperd"
Moveto [%Concluido           ] TypeIn "changeto ( (_qprod - _qperd) / _qprog) * 100"
Do_It!
ClearAll

MudaEstruturaDaTabelaPara("Answer","\\Base\\Sistemas\\Faccao\\Rm_0101")

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"    : Campo="NO"
            Case Campo="TG_CORTE"      : Campo="TG_EMPRESA"
            Case Campo="TG_MARCA"      : Campo="TG_CORTE"
            Case Campo="TG_FAMI"       : Campo="TG_MARCA"
            Case Campo="TG_GRP"        : Campo="TG_FAMI"
            Case Campo="TG_ITEM"       : Campo="TG_GRP"
            Case Campo="TG_REFERENCIA" : Campo="TG_ITEM"
            Case Campo="TG_DTINI"      : Campo="TG_REFERENCIA"
            Case Campo="TG_DTFIM"      : Campo="TG_DTINI"
            Case Campo="TG_SITUACAO"   : Campo="TG_DTFIM"
            Case Campo="TG_OPIT"       : Campo="TG_SITUACAO"
            Case Campo="TG_CODMODELO"  : Campo="TG_OPIT"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_CORTE"
                    Case Campo="TG_CORTE"      : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"      : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"       : Campo="TG_GRP"
                    Case Campo="TG_GRP"        : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"       : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA" : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_SITUACAO"
                    Case Campo="TG_SITUACAO"   : Campo="TG_OPIT"
                         VSDGSITUACAO=ControlValue("TG_SITUACAO")
                         If IsBlank(VSDGSITUACAO)
                            Then VSDGSITUACAO="TODOS"
                         EndIf
                    Case Campo="TG_OPIT"       : Campo="TG_CODMODELO"
                         VSDGOPIT=ControlValue("TG_OPIT")
                         Switch
                           Case VSDGOPIT="P": VSDGDESCOPIT="PENDENTES"
                           Case VSDGOPIT="D": VSDGDESCOPIT="COM DIFEREN€A"
                           OtherWise        : VSDGOPIT    ="T"
                                              VSDGDESCOPIT="TODOS"
                         EndSwitch
                    Case Campo="TG_CODMODELO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_CORTE"      :
     MSG_CAMPO="Em Branco = Todas" 
  Case Campo="TG_SITUACAO":
     MSG_CAMPO="P=PROGRAMADA  E=EM PRODUCAO  S=SUSPENSA  F=FINALIZADA  Branco=Todos"
  Case Campo="TG_OPIT":
     MSG_CAMPO="Op‡„o: T=Todos  P=Pendentes  D=Com Diferen‡a"
  Case Campo="":
     MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Anal¡tico por Programa‡Æo/Marca/Familia")
ModeloRelatoriosAdd("01C Anal¡tico por Programa‡Æo/Marca/Grupo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Sint‚tico por Marca/Familia")
ModeloRelatoriosAdd("02B Sint‚tico por Marca/Familia/Referˆncia")
ModeloRelatoriosAdd("02C Sint‚tico por Marca/Grupo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("03  Sint‚tico por Familia/Marca")
ModeloRelatoriosAdd("03B Sint‚tico por Familia/Marca/Referˆncia")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

sys_Valor()

VSDGEMPRESA   =""
VSDGCORTE     =""
VSDGFAMI      = ""
VSDGMARCA     = ""
VSDGTPITEM    =""
VSDGREFERENCIA= ""
VSDGDTINI     =BlankDate()
VSDGDTFIM     =BlankDate()
VSDGSITUACAO  =""
VSDGOPDT      ="T"

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Posi‡Æo da Programa‡„o de Corte" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Corte"  For "TG_CORTE"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_CORTE" To VSDGCORTE
    Accept @ 03,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMCORTE" To VSDGNOMCORTE

    Label  @ 04,00 "Marca"  For "TG_MARCA"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA
    
    Label  @ 06,00 "Familia"  For "TG_FAMI"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 08,00 "Grupo"  For "TG_GRP"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"    To VSDGGRP
    Accept @ 09,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP

    Label  @ 10,00 "Item"  For "TG_ITEM"
    Accept @ 11,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 12,01 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 10,13 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 11,13 Width 21 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 13,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 14,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 14,16 "at‚" For "TG_DTFIM"
    Accept @ 14,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Situa‡„o"  For "TG_SITUACAO"
    Accept @ 01,36 Width 33 "A11"  Picture "PROGRAMADA,EM PRODUCAO,SUSPENSA,FINALIZADA,TODOS" Tag "TG_SITUACAO"  To VSDGSITUACAO
    
    Label  @ 02,35 "Op‡„o para Itens" For "TG_OPIT"
    Accept @ 03,39 Width 04 "A1"  Picture "T,P,D" Tag "TG_OPIT" To VSDGOPIT
    Accept @ 03,44 Width 25 "A25"  Picture "!*!" Tag "TG_DESCOPIT" To VSDGDESCOPIT
    
    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If IsBlank(VSDGCORTE) And VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  
  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")

  Seleciona()

  If Not IsEmpty(Tabela)
     Then
          Switch
            Case VSDGCODMODELO="01"    :   CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0101" "R" Tabela "R"
            Case VSDGCODMODELO="01C"   :   CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0101" "3" Tabela "R"

            Case VSDGCODMODELO="02" or  
                 VSDGCODMODELO="02B"   :
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0101" "1" Tabela "R"

            Case VSDGCODMODELO="02C"   :   CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0101" "4" Tabela "R"

            Case VSDGCODMODELO="03" or     
                 VSDGCODMODELO="03B"   :   
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0101" "2" Tabela "R"
          EndSwitch
          IMPRIREL(Tabela,"R")

     Else MENSAGEM("N„o existem registros a processar")
  EndIf

  Delete Tabela

EndWhile                                              
ClearAll
Release Vars All
Release Procs All
