;** Inativa ********************************************************************
;* Processo para inativar itens                                                *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/07/2014 por Bruno Carvalho
;Ultima Alteracao: 10/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 30/07/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask tipo do item nova fun‡Æo

;*******************************************************************************
;* Rotina p/ selecao de registros                                              *
;*******************************************************************************
Proc Seleciona()
AGUARDE("Aguarde, Selecionado Itens")
ClearAll

{Ask} {Itens}
Moveto [Codigo do Item        ] Check TypeIn "~VSDGITEM.."  
Moveto [Descricao do Item     ] Check
Moveto [Tipo do Item          ] Check 
Ask_EstoqueTpItem("")
Moveto [Descricao Tipo do Item] Check  
Moveto [Codigo do Grupo       ] Check TypeIn "~VSDGGRP.."  
Moveto [Descricao do Grupo    ] Check
Moveto [Codigo da Familia     ] Check TypeIn "~VSDGFAMI.."  
Moveto [Descricao da Familia  ] Check
Moveto [Codigo da Marca       ] Check TypeIn "~VSDGMARCA.."  
Moveto [Descricao da Marca    ] Check
Moveto [Inativo               ] TypeIn "N"
Do_It!
ClearAll

{Ask} {Answer} TypeIn "Delete" Enter 
Moveto [Codigo do Item        ] TypeIn "_CodI"
{Ask} {\\Sistemas\\Estoque\\Sdestq}
Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Item        ] TypeIn "_CodI"
Moveto [Ano Referencia        ] TypeIn "~ANO"
Moveto [Mes Referencia        ] TypeIn "~MES" 
Do_It!
ClearAll

Tabela = Cria_Temp(PrivDir())
Copy "\\Base\\Sistemas\\Estoque\\RM_0007" Tabela

If Not IsEmpty("Answer")
   Then {Ask} {Answer}
        Moveto [Codigo do Item        ] TypeIn "_CodI"  
        Moveto [Descricao do Item     ] TypeIn "_DesI"
        Moveto [Tipo do Item          ] TypeIn "_TipI"
        Moveto [Descricao Tipo do Item] TypeIn "_DTpI"  
        Moveto [Codigo do Grupo       ] TypeIn "_CodG"  
        Moveto [Descricao do Grupo    ] TypeIn "_DesG"
        Moveto [Codigo da Familia     ] TypeIn "_CodF"  
        Moveto [Descricao da Familia  ] TypeIn "_DesF"
        Moveto [Codigo da Marca       ] TypeIn "_CodM"  
        Moveto [Descricao da Marca    ] TypeIn "_DesD"
        {Ask} TypeIn Tabela Enter TypeIn "Insert"
        Moveto [Codigo do Item        ] TypeIn "_CodI"  
        Moveto [Descricao do Item     ] TypeIn "_DesI"
        Moveto [Tipo do Item          ] TypeIn "_TipI"
        Moveto [Descricao Tipo do Item] TypeIn "_DTpI"  
        Moveto [Codigo do Grupo       ] TypeIn "_CodG"  
        Moveto [Descricao do Grupo    ] TypeIn "_DesG"
        Moveto [Codigo da Familia     ] TypeIn "_CodF"  
        Moveto [Descricao da Familia  ] TypeIn "_DesF"
        Moveto [Codigo da Marca       ] TypeIn "_CodM"  
        Moveto [Descricao da Marca    ] TypeIn "_DesD"   
        Do_It!
        ClearAll
        
        {Ask} TypeIn Tabela Enter
        Moveto [Codigo da Empresa     ] TypeIn "Blank, Changeto ~VSDGEMPRESA"
        Do_It!
        ClearAll
         
        Delete "Answer"
EndIf   
                  
If IsTable("Deleted")                  
   Then If Not IsEmpty("Deleted")
           Then {Ask} {Deleted} Check 
                Moveto [Codigo do Item        ] TypeIn "_CodI"
                {Ask} {\\Sistemas\\Estoque\\Sdestq}
                Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA.."
                Moveto [Codigo do Item        ] TypeIn "_CodI"
                Moveto [Ano Referencia        ] TypeIn "~ANO"
                Moveto [Mes Referencia        ] TypeIn "~MES"                 
                Moveto [Saldo Atual           ] Check
                Moveto [Ultimo Custo Atual    ] Check
                Do_It!
                ClearAll   
               
                {Ask} {Answer}
                Moveto [Codigo da Empresa     ] TypeIn "_CodE"
                Moveto [Codigo do Item        ] TypeIn "_CodI"  
                Moveto [Descricao do Item     ] TypeIn "_DesI"
                Moveto [Tipo do Item          ] TypeIn "_TipI"
                Moveto [Descricao Tipo do Item] TypeIn "_DTpI"  
                Moveto [Codigo do Grupo       ] TypeIn "_CodG"  
                Moveto [Descricao do Grupo    ] TypeIn "_DesG"
                Moveto [Codigo da Familia     ] TypeIn "_CodF"  
                Moveto [Descricao da Familia  ] TypeIn "_DesF"
                Moveto [Codigo da Marca       ] TypeIn "_CodM"  
                Moveto [Descricao da Marca    ] TypeIn "_DesD"
                Moveto [Saldo Atual           ] TypeIn "_Sald"
                Moveto [Ultimo Custo Atual    ] TypeIn "_UltC"
                {Ask} TypeIn Tabela Enter TypeIn "Insert"
                Moveto [Codigo da Empresa     ] TypeIn "_CodE"
                Moveto [Codigo do Item        ] TypeIn "_CodI"  
                Moveto [Descricao do Item     ] TypeIn "_DesI"
                Moveto [Tipo do Item          ] TypeIn "_TipI"
                Moveto [Descricao Tipo do Item] TypeIn "_DTpI"  
                Moveto [Codigo do Grupo       ] TypeIn "_CodG"  
                Moveto [Descricao do Grupo    ] TypeIn "_DesG"
                Moveto [Codigo da Familia     ] TypeIn "_CodF"  
                Moveto [Descricao da Familia  ] TypeIn "_DesF"
                Moveto [Codigo da Marca       ] TypeIn "_CodM"  
                Moveto [Descricao da Marca    ] TypeIn "_DesD"   
                Moveto [Saldo Atual           ] TypeIn "_Sald"
                Moveto [Custo Atual           ] TypeIn "_UltC"
                Do_It!
                ClearAll
                  
                {Ask} TypeIn Tabela Enter
                Moveto [Saldo Atual           ] TypeIn "0, Changeto Blank"
                Do_It!
                ClearAll
                
                {Ask} TypeIn Tabela Enter
                Moveto [Custo Atual           ] TypeIn "0, Changeto Blank"
                Do_It!
                ClearAll
        EndIf        
EndIf                           

EndProc                 

;*******************************************************************************
;* Seleciona Titulos para Baixa                                                *
;*******************************************************************************
Proc CHAVE()
While True
  End
  Down
  Moveto [Codigo do Item]                
  While True

    Prompt " Esc=Retornar  Alt+F=Fun‡”es  "

    Wait Field
         Until "ESC","ENTER","F7","HOME","UP","PGUP",-33,"F4","F5","F6","F8"

    If RetVal=-33
       Then Echo Normal
            Echo Off
            ShowPopup " Fun‡”es " CENTERED
             "~I~nativar    [F5]" : " Fun‡„o para inativar os itens                   " : "F5",
             "~I~mprimir    [F6]" : " Impress„o dos itens a serem inativados          " : "F6",
             "~R~ecarregar  [F8]" : " Recarrega os itens referente ao filtro informado" : "F8",
             Separator,
             "~C~ancelar        " : " Cancelar a Opera‡„o                             " : "CANCELAR"
            EndMenu
             To MenuVar

            Echo Off
            If MenuVar="CANCELAR" or MenuVar="Esc"
                Then Loop
                Else RetVal=MenuVar
            EndIf
    EndIf

    Switch
    Case RetVal="F5" :
         If IsEmpty(Tabela) 
            Then Mensagem("Dever  ser informado pelo menos 1(um) item na rela‡„o!")
            Else CONFGERAL("Deseja inativar o(s) item(ns) listado(s) nesta rela‡„o ?")
                 If OK="S"                                                           
                    Then ;---- Se PARAM2 = "S", ‚ porque usu rio ir  escolher se deseja imprimir a listagem -----
                         If Not Inativa_Itens("INATIVA","S")
                            Then Mensagem("N„o foi poss¡vel identificar item(ns) a ser(em) inativado(s)!") 
                         EndIf   
                         CHAVE=9
                         Do_It!
                         ClearAll       
                         Quitloop
                 Endif
         EndIf
    Case RetVal="F6" :
         DISPOSITIVO()
         If OK="" 
            Then 
            Else If Inativa_Itens("","")
                    Then ImpriArq(ARQIMP)
                         If INATIVA_ITEM
                            Then CHAVE=9
                                 Do_It!
                                 ClearAll       
                                 Quitloop
                            Else
                         EndIf        
                    Else Mensagem("N„o foi poss¡vel identificar item(ns) a ser(em) inativado(s)!")      
                 EndIf
         EndIf        
         Do_It!
         ClearAll
         Seleciona()
         Seleciona_Itens()
         Return     
    Case RetVal="F8" :
         CONFGERAL("Deseja recarregar os itens conforme o filtro ?")
         If OK="S"
            Then Do_It!
                 ClearAll
                 Seleciona()
                 Seleciona_Itens()
                 Return
         Endif
    Case RetVal="F7" Or RetVal="UP" Or RetVal="PGUP" Or RetVal="HOME" And Field()="Codigo da Empresa":
         While True
           PAGINA(Tabela,"MR")
           If EDITAR="S"
              Then CHAVE=0
                   Return
              Else If EXCLUIR="S"
                      Then CONFIRMA()
                           If OK="S"
                              Then DEL
                              Else UnLockRecord
                           EndIf
                      Else QuitLoop
                   EndIf
           EndIf
         EndWhile
         CHAVE=5
         QuitLoop
    Case Retval="ESC":
         CONFGERAL("Deseja abandonar o processo?")
         If OK="S"
            Then CHAVE=9
                 Do_It!
                 ClearAll
                 Quitloop
         EndIf
    EndSwitch
  EndWhile
  If CHAVE=0 Or CHAVE=9
     Then QuitLoop
  EndIf
EndWhile
EndProc

;*******************************************************************************
;* Seleciona Registros para Atualizacao                                        *
;*******************************************************************************
Proc Seleciona_Itens()
ClearAll
Edit Tabela
SetHighLight Current Record 23 Field 31
{Image} {KeepSet}
Do_It!

Sort Tabela On "Codigo do Item"
ClearAll

CoEdit Tabela
PickForm "F"
While True
  CHAVE()
  If CHAVE=9
     Then QuitLoop
  EndIf
EndWhile
ClearAll

EndProc ;Seleciona_Itens()          

;*******************************************************************************
;* Rotina de ImpressÆo                                                         *
;*******************************************************************************
Proc Imprimir(PARAM)
Private PARAM
If Not IsAssigned(PAGINA) Then PAGINA = 0 EndIf

PAGINA = PAGINA + 1

If Not IsAssigned(NOMEMPRESA)
   Then NOMEMPRESA=""
EndIf

Switch
  Case PARAM = "DELETED" : MSG_ITEM = "Itens com Saldo (Nao seram inativados)"
  Case PARAM = ""        : MSG_ITEM = "Item(ns) a ser(em) Inativado(s)"
EndSwitch  
                 
Print File ARQIMP CI_15CPP
Print File ARQIMP "\n\n"
Print File ARQIMP "  --------------------------------------------------------------------------------------------------------------------------------------" + "\n"
Print File ARQIMP "  "+Format("W32,AL",NOMEMPRESA)+Format("W65,AC",MSG_ITEM)+"Emissao: "+Format("D13",Today())+"-"+Time()+" Pag.: "+Format("W2,AR",StrVal(PAGINA))+"\n"
Print File ARQIMP "  --------------------------------------------------------------------------------------------------------------------------------------" + "\n\n"

Switch
  Case PARAM = "DELETED" : Print File ARQIMP "  Item                                       Saldo Atual  Custo Atual" + "\n"
                           Print File ARQIMP "  ----------------------------------------- ------------ ------------" + "\n"
  Case PARAM = ""        : Print File ARQIMP "  Item                                     " + "\n"
                           Print File ARQIMP "  -----------------------------------------" + "\n"                         
EndSwitch
            
NLINHA = 8 

EndProc ;Imprimir()

;*******************************************************************************
;* Rotina p/ Inativar Itens                                                    *
;*******************************************************************************
Proc Inativa_Itens(PARAM,PARAM2)
Private PARAM,PARAM2
AGUARDE("Aguarde, processando... ")

IMPRIME = False
If PARAM2 = "S" And PARAM = "INATIVA"
   Then CONFGERAL("Deseja imprimir esta rela‡„o ?")
        If OK="S"
           Then DISPOSITIVO()
                If OK="" 
                   Then 
                   Else IMPRIME = True
                EndIf    
        EndIf
   Else If PARAM = ""
           Then IMPRIME = True
        EndIf        
EndIf   

Do_It!
ClearAll

INATIVA_ITEM = False
IMPRIME_ITENS_COM_SALDO = False

Tabela2 = Cria_Temp(PrivDir())
Copy Tabela Tabela2

{Ask} TypeIn Tabela2 Enter 
Moveto [Codigo do Item    ] Example "CodI"
{Ask} {\\Sistemas\\Estoque\\Sdestq}
Moveto [Codigo da Empresa] Check
Moveto [Codigo do Item    ] Check Example "CodI"
Moveto [Ano Referencia    ] TypeIn "~ANO"
Moveto [Mes Referencia    ] TypeIn "~MES"
Moveto [Saldo Atual       ] Check TypeIn "> 0"
Moveto [Ultimo Custo Atual] Check TypeIn "as Custo Atual"
Do_It!
ClearAll

If Not IsEmpty("Answer") And IMPRIME
  Then IMPRIME_ITENS_COM_SALDO = True
       EMPRESA = "***"
  
       Sort "Answer" On "Codigo da Empresa","Codigo do Item"
       ClearAll
       
       View "\\Sistemas\\Estoque\\Itens"
       View "Answer"
       Scan                
         If EMPRESA = "***"
            Then EMPRESA = [Codigo da Empresa]
                 Imprimir("DELETED")
                 
                 GetRecord "\\Sistemas\\Cadastro\\Empresas" [Codigo da Empresa] To NOME_FANTASIA
                 If RetVal
                    Then NOME_FANTASIA = NOME_FANTASIA["Nome Fantasia Empresa"]
                    Else NOME_FANTASIA = ""
                 EndIf          
                 Print File ARQIMP "  Empresa: "+Format("W4",[Codigo da Empresa])+Spaces(1)+NOME_FANTASIA+"\n\n"
                 NLINHA = NLINHA + 2
         EndIf                                                                                      
         
         If EMPRESA <> [Codigo da Empresa]
            Then EMPRESA = [Codigo da Empresa]
                 GetRecord "\\Sistemas\\Cadastro\\Empresas" [Codigo da Empresa] To NOME_FANTASIA
                 If RetVal
                    Then NOME_FANTASIA = NOME_FANTASIA["Nome Fantasia Empresa"]
                    Else NOME_FANTASIA = ""
                 EndIf 
                 Print File ARQIMP "\n\n"
                 Print File ARQIMP "  "+Fill("-",134)+"\n"
                 Print File ARQIMP "\n\n"
                 Print File ARQIMP "  Empresa: "+Format("W4",[Codigo da Empresa])+Spaces(1)+NOME_FANTASIA+"\n\n"
                 NLINHA = NLINHA + 7
         EndIf
         
         GetRecord "\\Sistemas\\Estoque\\Itens" [Codigo do Item] To DESCRICAO_ITEM
         If RetVal
            Then DESCRICAO_ITEM = DESCRICAO_ITEM["Descricao do Item"]
            Else DESCRICAO_ITEM = ""
         EndIf
         
         If [Custo Atual] = 0
            Then CUSTO_TOTAL = BlankNum()
            Else CUSTO_TOTAL = [Custo Atual]
         EndIf    
         
         NLINHA = NLINHA + 1 
         Print File ARQIMP "  "+Format("W10",[Codigo do Item])+Spaces(1)+Format("W30",DESCRICAO_ITEM)+Spaces(1)+Format("W12.2,EIC",[Saldo Atual])
         Print File ARQIMP Spaces(1)+Format("W12.2,EIC",CUSTO_TOTAL)+"\n"                 
         
         If NLINHA >= 64
            Then Print File ARQIMP "\f"
                 Imprimir("DELETED")
                 Print File ARQIMP "  Empresa: "+Format("W4",[Codigo da Empresa])+Spaces(1)+NOME_FANTASIA+"\n\n"
                 NLINHA = NLINHA + 2
         EndIf
       EndScan               
       ClearImage
EndIf 

ClearAll
{Ask} TypeIn Tabela2 Enter TypeIn "Delete"
Moveto [Codigo do Item] Example "CodI"
{Ask} {\\Sistemas\\Estoque\\Sdestq}
Moveto [Codigo do Item] Example "CodI"
Moveto [Ano Referencia] TypeIn "~ANO"
Moveto [Mes Referencia] TypeIn "~MES"
Moveto [Saldo Atual   ] TypeIn "> 0"
Do_It!
ClearAll

If PARAM <> "INATIVA"
   Then If IMPRIME_ITENS_COM_SALDO 
           Then Print File ARQIMP "\f"
                If IsEmpty(Tabela2)
                   Then Return True
                EndIf
           Else If IsEmpty(Tabela2)
                   Then Return False
                EndIf
        EndIf
EndIf

If IMPRIME
   Then EMPRESA = "***"

        View Tabela2
        Scan
          If EMPRESA = "***"
             Then EMPRESA = ""
                  Imprimir("")
          EndIf
          
          NLINHA = NLINHA + 1
          Print File ARQIMP "  "+Format("W10",[Codigo do Item])+Spaces(1)+Format("W30",[Descricao do Item])+"\n"
        
          If NLINHA >= 64
             Then Print File ARQIMP "\f"
                  Imprimir("")
          EndIf  
        EndScan
        ClearImage
        
        ImpriArq(ARQIMP)
EndIf 

Release Vars PAGINA

;---- Pergunta se deseja imprimir os itens a serem inativados ------------------
If PARAM = "INATIVA"
   Then If IsEmpty(Tabela2)
           Then Return False
        EndIf

        INATIVA_ITEM = True
        {Ask} TypeIn Tabela2 Enter
        Moveto [Codigo do Item] Example "CodI"
        {Ask} {Itens}
        Moveto [Codigo do Item] Example "CodI"
        Moveto [Inativo       ] TypeIn "Changeto S"
        Do_It!
        ClearAll

        {Ask} TypeIn Tabela2 Enter
        Moveto [Codigo do Item     ] Example "CodI"
        {Ask} {Estqprm}
        Moveto [Codigo do Item     ] Example "CodI"
        Moveto [Data de Inatividade] TypeIn "Changeto ~HOJE"
        Do_It!
        ClearAll            
EndIf

Return True

EndProc ;Inativa_Itens()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_ITEM"           : Campo="TG_EMPRESA"
            Case Campo="TG_TIPOEST"        : Campo="TG_ITEM"
            Case Campo="TG_FAMI"           : Campo="TG_TIPOEST"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_MARCA"          : Campo="TG_GRP"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA" : 
                         If VSDGEMPRESA = ""
                            Then Mensagem("Informe a empresa para prosseguir !") 
                            Else Campo="TG_ITEM"
                         EndIf    
                    Case Campo="TG_ITEM"    : Campo="TG_TIPOEST"
                         VSDGITEM = ControlValue("TG_ITEM")
                         If Not IsBlank(VSDGITEM) 
                            Then VSDGITEM = AlinhM(VSDGITEM,10)
                            
                                 VSDGTIPOEST     = ""
                                 VSDGDESCTIPOEST = ""
                                 VSDGFAMI        = ""
                                 VSDGNOMFAMI     = ""
                                 VSDGGRP         = ""                                
                                 VSDGNOMGRP      = ""
                                 VSDGMARCA       = ""
                                 VSDGNOMMARCA    = ""
                            
                                 Campo="YES"
                            Else VSDGNOMITEM = "TODOS"     
                         EndIf
                    Case Campo="TG_TIPOEST" : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"    : Campo="TG_GRP"
                    Case Campo="TG_GRP"     : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"   : Campo="YES"
                  EndSwitch
          EndIf  
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_ITEM":
     MSG_CAMPO="Em Branco = Todos"
Endswitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGITEM      = ""
VSDGTIPOEST   = ""
VSDGFAMI      = ""
VSDGGRP       = ""                                
VSDGMARCA     = ""
VSDGEMPRESA   = ""

ARQIMP=PrivDir()+"Inativa.Txt"
If IsFile(ARQIMP)
   Then Deleta_Arquivo(ARQIMP)
EndIf

While True
  ShowDialog "Inativa Itens" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 18 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Item"  For "TG_ITEM"
    Accept @ 03,01 Width 33 "A10" Picture "#*#" Tag "TG_ITEM"    To VSDGITEM
    Accept @ 04,01 Width 33 "A30" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 05,00 "Tipo do Estoque"  For "TG_TIPOEST"
    Accept @ 06,04 Width 04 "A1"  Picture "!" Tag "TG_TIPOEST" To VSDGTIPOEST
    Accept @ 06,09 Width 25 "A30"  Picture "!*!" Tag "TG_DESCTIPOEST" To VSDGDESCTIPOEST

    Label  @ 07,00 "Familia"  For "TG_FAMI"
    Accept @ 08,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"      To VSDGFAMI
    Accept @ 08,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI"   To VSDGNOMFAMI

    Label  @ 09,00 "Grupo"  For "TG_GRP"
    Accept @ 10,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"       To VSDGGRP
    Accept @ 10,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMGRP"    To VSDGNOMGRP

    Label  @ 11,00 "Marca" For "TG_MARCA"
    Accept @ 12,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"     To VSDGMARCA
    Accept @ 12,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMMARCA"  To VSDGNOMMARCA

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGITEM)   And
     IsBlank(VSDGTIPOEST) And
     IsBlank(VSDGFAMI)   And
     IsBlank(VSDGGRP)    And
     IsBlank(VSDGMARCA)
     Then Mensagem("Nenhum filtro foi informado!")
          Loop
  EndIf   

  If Not Checa_Supervisor()
     Then Loop 
  EndIf   
  
  HOJE = Today()
  ANO  = StrVal(Year(HOJE))
  MES  = AlinhM(StrVal(Month(HOJE)),2)  
  
  Seleciona()
  If IsEmpty(Tabela)
     Then Mensagem("N„o existem itens para inativar!")
          Loop
  EndIf
  Seleciona_Itens()
  Echo Normal
  Echo Off

  ClearAll
EndWhile
ClearAll
Release Vars All
Release Procs All