;** Rm_4100  *******************************************************************
;*  Itens nao Movimentados                                                     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/08/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 14/10/2004 por Davi Pereira Carrano
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 19/02/2013 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajuste ignorar item inativo com saldo zerado       
;Ultima Alteracao: 07/07/2014 por Bruno Carvalho
;Motivo Alteracao: Ajustes ao buscar o custo na Ficha de Estoque
;Ultima Alteracao: 23/06/2016 por Bruno Carvalho
;Motivo Alteracao: Removido Link nos Report "RM_4100" e utilizado fun‡Æo Adiciona_Dados_Tabela()
;Ultima Alteracao: 10/11/2016 por Kamila Gomes
;Motivo Alteracao: Ajustes quando nÆo existe Answer depois do SelecionaV()
;Ultima Alteracao: 10/11/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes e filtrar marca       
;Ultima Alteracao: 16/01/2019 por Bruno Carvalho
;Motivo Alteracao: Adicionado modelo 02 p/ ser exibido no relat¢rio a data da ultima venda 
;Ultima Alteracao: 16/01/2019 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro para departamento  
;Ultima Alteracao: 18/01/2019 por Bruno Carvalho
;Motivo Alteracao: Ajustes ao escolher departamento
;Ultima Alteracao: 07/11/2019 por Anivel Augusto Rodrigues     
;Motivo Alteracao: Ajustes item data cadastro, inativo
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 25/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 05/08/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtrar saldo de estoque
 
;*******************************************************************************
;* Rotina p/ Selecionar e Itens Vendidos                                       *
;*******************************************************************************
Proc SelecionaV()
ClearAll
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then  {Ask} TypeIn "\\Sistemas\\Estoque\\Itens" Enter
         Moveto [Codigo do Item          ] Example "ite"
         Moveto [Codigo da Familia       ] TypeIn "~VSDGFAMI.."
         Moveto [Codigo do Grupo         ] TypeIn "~VSDGGRP.."
         Moveto [Codigo da Marca         ] TypeIn "~VSDGMARCA.."
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
         Moveto [Codigo da Empresa      ] Example "Empresa" TypeIn ", ~VSDGEMPRESA.."
         Moveto [Numero do Documento    ] Example "Docto"
         Moveto [Serie do Documento     ] Example "Serie"
         Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
         Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
         Moveto [Tipo Movimento Estoque ] TypeIn "S"
         Moveto [Situacao               ] TypeIn "Not C"
         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"Notai" Enter
         Moveto [Codigo da Empresa      ] Example "Empresa"
         Moveto [Numero do Documento    ] Example "Docto"
         Moveto [Serie do Documento     ] Example "Serie"
         Moveto [Codigo do Item         ] Check Example "ite"
         Moveto [Tipo do Item           ] TypeIn "P or T"
         Moveto [Situacao_Item          ] TypeIn "Not C"
         Do_It!
         ClearAll

         If IsTable(Tabela)
            Then Add "Answer" Tabela
            Else Rename "Answer" Tabela
         EndIf                                          
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
private vsdgdtcad

ClearAll

{Ask} TypeIn "\\Sistemas\\Estoque\\Itens" Enter
Moveto [Codigo do Item         ] Check 
Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
Moveto [Codigo do Departamento ] TypeIn "~VSDGDEPART.."
Moveto [Tipo do Item           ] TypeIn "P or T"
Do_It!
ClearAll

Subtract Tabela "Answer" ClearImage
Delete Tabela

{Ask} TypeIn "\\Sistemas\\Estoque\\EstqPrm" Enter Check
Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Item          ] Example "ite"
{Ask} {Answer}
Moveto [Codigo do Item          ] Example "ite!"
Do_It!
ClearAll

{Ask} {Answer} Check
Moveto [Codigo da Empresa       ] Example "emp" TypeIn "!"
Moveto [Codigo do Item          ] Example "ite" TypeIn "!"

;---- Custo Atual --------------------------------------------------------------
If IsTable("\\FechAno\\"+ANO+"\\Estoque\\Sdestq") 
   Then TAB_TEMP = "\\FechAno\\"+ANO+"\\Estoque\\Sdestq"
   Else TAB_TEMP = "\\Sistemas\\Estoque\\SdEstq"
EndIf      

{Ask} TypeIn TAB_TEMP Enter
Moveto [Codigo da Empresa       ] Example "emp"
Moveto [Codigo do Item          ] Example "ite"
Moveto [Ano Referencia          ] TypeIn "~ANO"
Moveto [Mes Referencia          ] TypeIn "~MES"
Moveto [Saldo Atual             ] Check
Moveto [Custo Total Atual       ] Check
Do_It!
ClearAll

Switch
  Case VSDGZERADO="0" :  ;Sem Estoque Zerado
       {Ask} {Answer} TypeIn "Fast Delete"
       Moveto [Saldo Atual      ] TypeIn "blank or 0"
       Do_It!
       ClearAll
  Case VSDGZERADO="2" : ;S¢ Estoque Zerado
       {Ask} {Answer} TypeIn "Fast Delete"
       Moveto [Saldo Atual      ] TypeIn "not blank, not 0"
       Do_It!
       ClearAll
  Case VSDGZERADO="3" : ;S¢ Negativo
       {Ask} {Answer} TypeIn "Fast Delete"
       Moveto [Saldo Atual      ] TypeIn ">=0"
       Do_It!
       ClearAll
EndSwitch

{Ask} {Answer} Check
Moveto [Codigo da Empresa    ] TypeIn "_Cod"
{Ask} {\\Sistemas\\Cadastro\\Empresas} 
Moveto [Codigo da Empresa    ] TypeIn "_Cod"
Moveto [Nome Fantasia Empresa] Check
Do_It!
ClearAll

{Ask} {Answer} Check
Moveto [Codigo do Item       ] TypeIn "_Cod!"
{Ask} {\\Sistemas\\Estoque\\Itens} 
Moveto [Codigo do Item       ] TypeIn "_Cod"
Moveto [Descricao do Item    ] Check
Moveto [Unidade Interna      ] Check
Do_It!
ClearAll

Tabela = Cria_Temp(PrivDir())
Copy "\\Base\\Sistemas\\Vendas\\RM_4100" Tabela
Empty(Tabela)
Adiciona_Dados_Tabela(Tabela)    

If VSDGCODMODELO = "02" And Not IsEmpty(Tabela)
   Then ;Ser  verificado a data da ultima venda
        
        {Ask} TypeIn Tabela Enter
        Moveto [Data da Ultima Saida] TypeIn "Changeto Blank"
        Do_It!
        ClearAll
        
        Seleciona2()
EndIf   
     
EndProc   ;  (Seleciona)

;*******************************************************************************
;* Rotina para verificar a data da ultima venda                                *
;*******************************************************************************
Proc Seleciona2()

AGUARDE("Aguarde, gerando o relat¢rio")
  
VSDGDTINI = VSDGDTINI-365
Tabela2   = Cria_Temp(PrivDir())

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
     IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
     Then {Ask} TypeIn Tabela Enter
          Moveto [Codigo do Item          ] Example "ite"
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
          Moveto [Codigo da Empresa      ] Check Example "Empresa" TypeIn ", ~VSDGEMPRESA.."
          Moveto [Numero do Documento    ] Example "Docto"
          Moveto [Serie do Documento     ] Example "Serie"
          Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM, Calc Max as Data"
          Moveto [Descricao da Destinacao] TypeIn "..VENDA.."
          Moveto [Tipo Movimento Estoque ] TypeIn "S"
          Moveto [Situacao               ] TypeIn "Not C"
          {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"Notai" Enter
          Moveto [Codigo da Empresa      ] Example "Empresa"
          Moveto [Numero do Documento    ] Example "Docto"
          Moveto [Serie do Documento     ] Example "Serie"
          Moveto [Codigo do Item         ] Check Example "ite"
          Do_It!
          ClearAll
  
          If IsTable(Tabela2)
             Then Add "Answer" Tabela2
             Else Rename "Answer" Tabela2
          EndIf                                          
  EndIf  
EndWhile

If Not IsEmpty(Tabela2)
   Then {Ask} TypeIn Tabela2 Enter
        Moveto [Codigo da Empresa   ] Check
        Moveto [Codigo do Item      ] Check
        Moveto [Data                ] TypeIn "CalC Max as Data"
        Do_It!
        ClearAll
   
        {Ask} TypeIn Tabela2 Enter
        Moveto [Codigo da Empresa   ] TypeIn "_Emp"
        Moveto [Codigo do Item      ] TypeIn "_Ite"
        Moveto [Data                ] TypeIn "_Data"
        {Ask} TypeIn Tabela  Enter
        Moveto [Codigo da Empresa   ] TypeIn "_Emp"
        Moveto [Codigo do Item      ] TypeIn "_Ite"
        Moveto [Data da Ultima Saida] TypeIn "Changeto _Data"
        Do_It!
        ClearAll
EndIf

Delete Tabela2

EndProc ;Seleciona2()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_FAMI"           : Campo="TG_EMPRESA"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_MARCA"          : Campo="TG_GRP"
            Case Campo="TG_DEPART"         : Campo="TG_MARCA"
            Case Campo="TG_DTINI"          : Campo="TG_DEPART" 
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_MESANO"         : Campo="TG_DTFIM"
            Case Campo="TG_ZERADO"         : Campo="TG_MESANO"
            Case Campo="TG_CODMODELO"      : Campo="TG_ZERADO"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"   : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"      : Campo="TG_GRP"
                    Case Campo="TG_GRP"       : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"     : Campo="TG_DEPART"
                    Case Campo="TG_DEPART"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"     :
                         If Not IsBlank(VSDGDTINI)
                            Then Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM"     : Campo="TG_MESANO"
                    Case Campo="TG_MESANO"    : Campo="TG_ZERADO"
                    Case Campo="TG_ZERADO"    : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_EMPRESA":
       MSG_CAMPO="Informe uma empresa"
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a Data Inicial"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Itens em estoque nÆo vendidos com Data da Ultima Saida")
ModeloRelatoriosAdd("02  Itens em estoque nÆo vendidos com Data da Ultima Venda")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA  = ""
VSDGFAMI     = ""
VSDGGRP      = ""
VSDGMARCA    = ""
VSDGDTINI    = BlankDate()
VSDGDTFIM    = Today()
VSDGMESANO   = AlinhM(StrVal(Month(Today())),2)+"."+AlinhM(StrVal(Year(Today())),4)

VSDGZERADO   = ""

ModeloRelatoriosCarregaLista()

While True
 
  ShowDialog "Itens n„o vendidos" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 03,12   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Familia"  For "TG_FAMI"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 04,00 "Grupo"  For "TG_GRP"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"    To VSDGGRP
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP

    Label  @ 06,00 "Marca"  For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 07,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA
    
    Label  @ 08,00 "Departamento"  For "TG_DEPART"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_DEPART"    To VSDGDEPART
    Accept @ 09,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMDEPART" To VSDGNOMDEPART    

    Label  @ 10,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 11,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,16 "at‚" For "TG_DTFIM"
    Accept @ 11,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 12,00 "Mˆs/Ano Estoque"  For "TG_MESANO"
    Accept @ 13,01  Width 10 "A07"  Picture "##.####" Tag "TG_MESANO" To VSDGMESANO

    Label  @ 00,35 "Op‡„o do Estoque" For "TG_ZERADO"
    Accept @ 01,39 Width 04 "A1"  Picture "0,1,2,3" Tag "TG_ZERADO" To VSDGZERADO
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_DESCZERADO" To VSDGDESCZERADO  

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf

  If VSDGEMPRESA="" or           
     VSDGEMPRESA="000"           
     Then Mensagem("Empresa Invalida !")
          Loop
  EndIf
  If VSDGDTINI=BlankDate()
     Then Mensagem("Data Inicial Invalida !")
          Loop
  EndIf
  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

	ANO = SubStr(VSDGMESANO,4,4)
	MES = SubStr(VSDGMESANO,1,2)
	If (NumVal(MES)<1 Or NumVal(MES)>12)
		 Then Mensagem("Mˆs inv lido !")
					Loop
	EndIf

	DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer") Then Delete "Answer" EndIf
    SelecionaV()
  EndWhile
  
  Seleciona()              
  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
     Else Switch
            Case VSDGCODMODELO = "01" : IMPRIREL(Tabela,"R") 
            Case VSDGCODMODELO = "02" : IMPRIREL(Tabela,"1") 
          EndSwitch 
  EndIf
  
  If IsTable("Answer") Then Delete "Answer" EndIf
  If IsTable(Tabela)   Then Delete Tabela   EndIf
EndWhile
ClearAll
Release Vars All
Release Procs All
