;** Rc_0100  *******************************************************************
;* Releacao de itens em Estoque                                                *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 11/12/2003 por Karen Lauar Nery
;Motivo Alteracao: Inclusao Status
;Ultima Alteracao: 18/02/2011 por Bruno Carvalho
;Motivo Alteracao: Nova op‡Æo de relatorio
;Ultima Alteracao: 16/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 25/05/2018 por Bruno Carvalho
;Motivo Alteracao: Ajustes no campo TG_ZERADO p/ as op‡äes serem verificadas pelo F1
;Ultima Alteracao: 30/05/2018 por Bruno Carvalho
;Motivo Alteracao: Movido TG_ZERADO na BibShow e ajustado neste script
;Ultima Alteracao: 30/07/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask tipo do item nova fun‡Æo

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll
Empty "RC_0100"

{Ask} {\\Sistemas\\Cadastro\\Empresas}
Moveto [Codigo da Empresa    ] Check Example "empresa" TypeIn ", ~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa] Check
{Ask} {Itens}
Moveto [Codigo do Item        ] Check Example "item"
Moveto [Descricao do Item     ] Check
Moveto [Tipo do Item          ] Check 
Ask_EstoqueTpItem("")
Moveto [Descricao Tipo do Item] Check
Moveto [Unidade Interna       ] Check
Moveto [NCM                   ] Check
{Ask} {SdEstq}
Moveto [Codigo da Empresa     ] Example "empresa"
Moveto [Codigo do Item        ] Example "item"
Moveto [Ano Referencia        ] TypeIn "~ANO"
Moveto [Mes Referencia        ] TypeIn "~MES"
Moveto [Saldo Atual           ] Check
Do_It!
ClearAll

If Not IsEmpty("Answer")
   Then Switch
          Case VSDGZERADO="0" :  ;Sem Estoque Zerado
               {Ask} {Answer} TypeIn "Fast Delete"
               Moveto [Saldo Atual      ] TypeIn "blank or 0"
               Do_It!
               ClearAll
          Case VSDGZERADO="2" : ;S¢ Estoque Zerado
               {Ask} {Answer} TypeIn "Fast Delete"
               Moveto [Saldo Atual      ] TypeIn "not blank, not 0"
               Do_It!
               ClearAll
          Case VSDGZERADO="3" : ;S¢ Negativo
               {Ask} {Answer} TypeIn "Fast Delete"
               Moveto [Saldo Atual      ] TypeIn ">=0"
               Do_It!
               ClearAll
        EndSwitch
        If VSDGOPRELCODALF="1"
           Then CopyReport "\\Base\\Sistemas\\Estoque\\Rc_0100" "R" "Answer" "R"
           Else CopyReport "\\Base\\Sistemas\\Estoque\\Rc_0100" "1" "Answer" "R"
        EndIf
EndIf

EndProc   ; (Seleciona)

;*******************************************************************************
;*Rotina                                                                       *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp      = True
MSG_CAMPO = ""
TECLA     = ""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9   : Temp=False
     Case Evento["KeyCode"] = -59 : Dialog_F1()   
     Case Evento["KeyCode"] = 27  :
          Temp=False
          Switch
             Case Campo = "TG_EMPRESA"         : Campo = "NO"
             Case Campo = "TG_TIPOEST"         : Campo = "TG_EMPRESA"
             Case Campo = "TG_MESANO"          : Campo = "TG_TIPOEST"
             Case Campo = "TG_ZERADO"          : Campo = "TG_MESANO"
             Case Campo = "TG_OPRELCODALF"     : Campo = "TG_ZERADO" 
             Case Campo = "YES" Or Campo="NO"  : Campo = "TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp = False
          If Checa_TAG()
             Then Switch
                     Case Campo = "TG_EMPRESA" : Campo = "TG_TIPOEST"
                     Case Campo = "TG_TIPOEST" : Campo = "TG_MESANO"
                     Case Campo = "TG_MESANO"  : Campo = "TG_ZERADO"
                     Case Campo = "TG_ZERADO"  : Campo = "TG_OPRELCODALF"
                     Case Campo="TG_OPRELCODALF" : 
                          VSDGOPRELCODALF=ControlValue("TG_OPRELCODALF")
                          If IsBlank(VSDGOPRELCODALF) Or VSDGOPRELCODALF="1"
                             Then VSDGOPRELCODALF="1"
                                  VSDGNOMOPRELCODALF="SINTETICO"
                             Else VSDGOPRELCODALF="2" 
                                  VSDGNOMOPRELCODALF="ANALITICO"
                          EndIf
                          Campo = "YES"    
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPRELCODALF":
       MSG_CAMPO = "1=Sint‚tico  2=Anal¡tico"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib     ="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

VSDGEMPRESA = ""
VSDGTIPOEST = ""
VSDGMESANO  = AlinhM(StrVal(Month(Today())),2)+"."+AlinhM(StrVal(Year(Today())),4)
While True

  ShowDialog "Rela‡„o de Itens em Estoque por Empresa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
  @ 05,12   Height 11 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Tipo do Estoque"  For "TG_TIPOEST"
    Accept @ 03,04 Width 04 "A1"  Picture "!" Tag "TG_TIPOEST" To VSDGTIPOEST
    Accept @ 03,09 Width 25 "A30"  Picture "!*!" Tag "TG_DESCTIPOEST" To VSDGDESCTIPOEST

    Label  @ 04,00 "Mˆs/Ano Estoque"  For "TG_MESANO"
    Accept @ 05,01 Width 10 "A7"  Picture "##.####" Tag "TG_MESANO"        To VSDGMESANO

    Label  @ 00,35 "Op‡„o de Estoque" For "TG_ZERADO"
    Accept @ 01,39 Width 04 "A1"  Picture "0,1,2,3" Tag "TG_ZERADO" To VSDGZERADO
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_DESCZERADO" To VSDGDESCZERADO

    Label  @ 02,35 "Ordem" For "TG_OPRELCODALF"
    Accept @ 03,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 03,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Pushbutton @ 07,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 07,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If IsBlank(VSDGZERADO)
     Then Loop
  EndIf
  ANO = SubStr(VSDGMESANO,4,4)
	MES = SubStr(VSDGMESANO,1,2)
  If (NumVal(MES)<1 Or NumVal(MES)>12)
		 Then Mensagem("Mˆs inv lido !")
					Loop
	EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")

  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf
    
  IMPRIREL("Answer","R")

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All

