;** Rm_0275H *******************************************************************
;*  Producao Familia/Item                                                      *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 18/07/2018 por Anivel Augusto Rodrigues
;Ultima Alteracao: 30/07/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask tipo do item nova fun‡Æo

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SelecionaRm_0275H()
ClearAll

If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"RqCabeca") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"RqItem")
   Then
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ] Example "cite"
        Moveto [Descricao do Item      ] Check 
        Moveto [Unidade Interna        ] Check 
        Moveto [Tipo do Item           ] Check 
        Ask_EstoqueTpItem("")
        Moveto [Descricao Tipo do Item ] Check 
        Moveto [Codigo da Familia      ] Check TypeIn "~VSDGFAMI.."
        Moveto [Descricao da Familia   ] Check 
        Moveto [Codigo do Grupo        ] Check TypeIn "~VSDGGRP.."
        Moveto [Descricao do Grupo     ] Check 
        Moveto [Codigo da Marca        ] Check TypeIn "~VSDGMARCA.."
        Moveto [Descricao da Marca     ] Check 
        Moveto [Referencia             ] Check TypeIn "~VSDGREFERENCIA.."
        Moveto [Codigo da Grade        ] Check 
        Moveto [Codigo da Cor_Tecido   ] Check 
        Moveto [Descricao da Cor_Tecido] Check 
        
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"RqCabeca" Enter
        Moveto [Numero do Lancamento  ] Example "NUMERO"
        Moveto [Codigo da Empresa     ] Check TypeIn "~VSDGEMPRESA2.."
        Moveto [Nome Fantasia Empresa ] Check
        Moveto [Data de Ocorrencia    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Tipo de Movimento     ] TypeIn "E"
        Moveto [Tipo de Operacao      ] TypeIn "P Or I"
        Moveto [Requisitante          ] Check TypeIn "~VSDGREQUISIT.."
        Moveto [Descricao Requisitante] Check
        
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"RqItem" Enter
        Moveto [Numero do Lancamento  ] Example "NUMERO"
        Moveto [Codigo do Item        ] Check Example "cite" TypeIn ", ~VSDGITEM.."
        Moveto [Quantidade            ] TypeIn "Calc Sum as Quantidade"
        Moveto [Custo Total           ] TypeIn "Calc Sum as Custo Total"
        If CheckTG_OPCCUSTO[1]
          Then Moveto [Codigo CCusto          ] Check TypeIn "Not Blank, ~VSDGCCUSTO.."
          Else Moveto [Codigo CCusto          ] Check TypeIn "~VSDGCCUSTO.."
        Endif
        Moveto [Descricao CCusto       ] Check
        Do_It!
        ClearAll
        
        If IsTable(Tabela)
          Then Add "Answer" Tabela
          Else Rename "Answer" Tabela
        EndIf 
        ClearAll
EndIf

EndProc   ; (SelecionaRm_0275H)

;*******************************************************************************
;* ROTINA Ajusta Dados Empresa                                                 *
;*******************************************************************************
Proc ProcessaRm_0275H()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

{Ask} TypeIn Tabela Enter 
Moveto [Codigo da Empresa      ] Check
Moveto [Nome Fantasia Empresa  ] Check
Moveto [Tipo do Item           ] Check 
Moveto [Descricao Tipo do Item ] Check 
Moveto [Codigo da Familia      ] Check 
Moveto [Descricao da Familia   ] Check 
Moveto [Codigo do Item         ] Check 
Moveto [Descricao do Item      ] Check 
Moveto [Unidade Interna        ] Check 
Moveto [Referencia             ] Check 
Moveto [Codigo da Grade        ] Check 
Moveto [Codigo da Cor_Tecido   ] Check 
Moveto [Descricao da Cor_Tecido] Check 
Moveto [Quantidade             ]       TypeIn "Calc Sum as Quantidade"
Moveto [Custo Total            ]       TypeIn "Calc Sum as Custo Total"
Do_It!
ClearAll

Delete Tabela

AgrupaItensRm_0275H()
                            
EndProc

;*******************************************************************************
;* Rotina p/ Agrupar Itens nos tamanhos respectivos                            *
;*******************************************************************************
Proc AgrupaItensRm_0275H()

LimpaRodape(0)

Tabela=Cria_Temp(PrivDir())
Copy "\\base\\sistemas\\estoque\\rm_0275H" Tabela
Empty(Tabela)
ClearAll

Adiciona_Indice(Tabela,"Codigo da Empresa,Tipo do Item,Codigo do Item,Codigo da Cor_Tecido")

Array Array_TM[12]

Sort "Answer" On "Codigo da Grade","Tipo do Item","Referencia"

NR=NRecords("Answer")

View "\\Sistemas\\Estoque\\TpGrade"
Coedit Tabela,"Answer"
CGRADANT= "*****"
Scan
  Barra(NR, RecNo())
  Aguarde("Aguarde, agrupando referˆncias "+BARRA_STRING)

  If [Codigo da Grade] <> CGRADANT 
     Then 
          Verifica_Array_GradeRm_0275H()
          CGRADANT=[Codigo da Grade]
  EndIF
  
  If VSDGCODMODELO="20"
     Then [Codigo da Cor_Tecido   ]=""
          [Descricao da Cor_Tecido]=""
  EndIf
  
  Moveto Tabela
  Moveto [Codigo da Empresa]
  Locate [Answer->Codigo da Empresa    ],
         [Answer->Tipo do Item         ],
         [Answer->Referencia           ],
         [Answer->Codigo da Cor_Tecido ]
  If Not RetVal
     Then End
          Down
          [Codigo da Empresa      ]=[Answer->Codigo da Empresa    ]
          [Tipo do Item           ]=[Answer->Tipo do Item         ]  
          [Codigo do Item         ]=[Answer->Referencia           ]
          [Codigo da Cor_Tecido   ]=[Answer->Codigo da Cor_Tecido ]

          [Nome Fantasia Empresa  ]=[Answer->Nome Fantasia Empresa]
          [Referencia             ]=[Answer->Referencia           ]
          If VSDGCODMODELO="20B"
             Then 
                  [Descricao do Item      ]=Substr([Answer->Descricao do Item],1,27)
             Else 
                  [Descricao do Item      ]=Substr([Answer->Descricao do Item],1,23)
          EndIf
          [Unidade Interna        ]=[Answer->Unidade Interna        ]
          [Codigo da Familia      ]=[Answer->Codigo da Familia      ]
          [Descricao da Familia   ]=[Answer->Descricao da Familia   ]
          [Codigo da Grade        ]=[Answer->Codigo da Grade        ]
          [Descricao Tipo do Item ]=[Answer->Descricao Tipo do Item ]
          [Descricao da Cor_Tecido]=[Answer->Descricao da Cor_Tecido]
          
          [Titulo Grade1 ]=substr(Array_TM[1] ,4,2)
          [Titulo Grade2 ]=substr(Array_TM[2] ,4,2)
          [Titulo Grade3 ]=substr(Array_TM[3] ,4,2)
          [Titulo Grade4 ]=substr(Array_TM[4] ,4,2)
          [Titulo Grade5 ]=substr(Array_TM[5] ,4,2)
          [Titulo Grade6 ]=substr(Array_TM[6] ,4,2)
          [Titulo Grade7 ]=substr(Array_TM[7] ,4,2)
          [Titulo Grade8 ]=substr(Array_TM[8] ,4,2)
          [Titulo Grade9 ]=substr(Array_TM[9] ,4,2)
          [Titulo Grade10]=substr(Array_TM[10],4,2)
          [Titulo Grade11]=substr(Array_TM[11],4,2)
          [Titulo Grade12]=substr(Array_TM[12],4,2)
  EndIf
  
  Coluna=0
  For Wi from 1 to 12
    If Len(RTrim(SubStr(Array_TM[Wi],1,2)))=1
       Then If SubStr([Answer->Codigo do Item],10,1)=SubStr(Array_TM[Wi],1,1)
               Then Coluna=Wi
                    QuitLoop
            EndIf
       Else If SubStr([Answer->Codigo do Item],9,2)=SubStr(Array_TM[Wi],1,2)
               Then Coluna=Wi
                    QuitLoop
            EndIf
    EndIf
  EndFor

  Switch
    Case Coluna=0 : [Qtd1  ]=[Qtd1  ]+[Answer->Quantidade]
    Case Coluna=1 : [Qtd1  ]=[Qtd1  ]+[Answer->Quantidade]
    Case Coluna=2 : [Qtd2  ]=[Qtd2  ]+[Answer->Quantidade]
    Case Coluna=3 : [Qtd3  ]=[Qtd3  ]+[Answer->Quantidade]
    Case Coluna=4 : [Qtd4  ]=[Qtd4  ]+[Answer->Quantidade]
    Case Coluna=5 : [Qtd5  ]=[Qtd5  ]+[Answer->Quantidade]
    Case Coluna=6 : [Qtd6  ]=[Qtd6  ]+[Answer->Quantidade]
    Case Coluna=7 : [Qtd7  ]=[Qtd7  ]+[Answer->Quantidade]
    Case Coluna=8 : [Qtd8  ]=[Qtd8  ]+[Answer->Quantidade]
    Case Coluna=9 : [Qtd9  ]=[Qtd9  ]+[Answer->Quantidade]
    Case Coluna=10: [Qtd10 ]=[Qtd10 ]+[Answer->Quantidade]
    Case Coluna=11: [Qtd11 ]=[Qtd11 ]+[Answer->Quantidade]
    Case Coluna=12: [Qtd12 ]=[Qtd12 ]+[Answer->Quantidade]
  EndSwitch
  
  [Quantidade ]=[Quantidade ]+[Answer->Quantidade]
  [Custo Total]=[Custo Total]+[Answer->Custo Total]
  [Custo Unitario Medio]=[Custo Total]/[Quantidade]

  Moveto "Answer"
        
EndScan
Do_It!
ClearAll

{Ask} typein Tabela Enter Check
do_it!
ClearAll

Delete Tabela

MudaEstruturaDaTabelaPara("Answer","\\base\\sistemas\\estoque\\rm_0275H")

Rename "Answer" Tabela

LimpaRodape(0)

EndProc ;AgrupaItens()

;*******************************************************************************
;* Rotina Monta Array Grade                                                     *
;*******************************************************************************
Proc Verifica_Array_GradeRm_0275H()
private regTpGrade,Wh

For Wh From 1 To 12
  Array_TM[Wh]="" 
EndFor

if isblank([Answer->Codigo da Grade])
   then return
endif
   
getrecord "\\Sistemas\\Estoque\\TpGrade" [Answer->Codigo da Grade] to regTpGrade
If Not RetVal
   Then Mensagem("Item "+[Answer->Codigo do Item]+" sem grade definida !")
        Return
EndIf

Array_TM[1] =format("W2",regTpGrade["Codigo Item1" ])+"|"+format("W2",regTpGrade["Titulo Grade1" ])
Array_TM[2] =format("W2",regTpGrade["Codigo Item2" ])+"|"+format("W2",regTpGrade["Titulo Grade2" ])
Array_TM[3] =format("W2",regTpGrade["Codigo Item3" ])+"|"+format("W2",regTpGrade["Titulo Grade3" ])
Array_TM[4] =format("W2",regTpGrade["Codigo Item4" ])+"|"+format("W2",regTpGrade["Titulo Grade4" ])
Array_TM[5] =format("W2",regTpGrade["Codigo Item5" ])+"|"+format("W2",regTpGrade["Titulo Grade5" ])
Array_TM[6] =format("W2",regTpGrade["Codigo Item6" ])+"|"+format("W2",regTpGrade["Titulo Grade6" ])
Array_TM[7] =format("W2",regTpGrade["Codigo Item7" ])+"|"+format("W2",regTpGrade["Titulo Grade7" ])
Array_TM[8] =format("W2",regTpGrade["Codigo Item8" ])+"|"+format("W2",regTpGrade["Titulo Grade8" ])
Array_TM[9] =format("W2",regTpGrade["Codigo Item9" ])+"|"+format("W2",regTpGrade["Titulo Grade9" ])
Array_TM[10]=format("W2",regTpGrade["Codigo Item10"])+"|"+format("W2",regTpGrade["Titulo Grade10"])
Array_TM[11]=format("W2",regTpGrade["Codigo Item11"])+"|"+format("W2",regTpGrade["Titulo Grade11"])
Array_TM[12]=format("W2",regTpGrade["Codigo Item12"])+"|"+format("W2",regTpGrade["Titulo Grade12"])

EndProc ;Verifica_Array_GradeRm_0275H()

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc PrincipalRm_0275H()

AGUARDE("Aguarde, Gerando o Relat¢rio")
Tabela=Cria_Temp(PrivDir())

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  SelecionaRm_0275H()
EndWhile

If not IsEmpty(Tabela)
   then
        ProcessaRm_0275H()

        CopyReport "\\base\\sistemas\\estoque\\rm_0275H" "R" Tabela "R"
        
        Impressao_Orientacao="Paisagem"
        switch
          case VSDGOPRELCODALFRANK2="2"  : Seta_Ordem_Report(Tabela,"R","Referencia","Descricao do Item","")
          case VSDGOPRELCODALFRANK2="3"  : Seta_Ordem_Report(Tabela,"R","Referencia","Quantidade"       ,"D")
          case VSDGOPRELCODALFRANK2="4"  : Seta_Ordem_Report(Tabela,"R","Referencia","Custo Total"      ,"D")
        endswitch
   
        IMPRIREL(Tabela,"R")
   else 
        MENSAGEM("N„o existem registros a processar")
EndIf

If IsTable(Tabela)   Then Delete Tabela   EndIf
If IsTable("Answer") Then Delete "Answer" EndIf

EndProc

;-- Chamada principal ----------------------------------------------------------
PrincipalRm_0275H()

Release Vars Tabela, Array_TM
Release Procs PrincipalRm_0275H, SelecionaRm_0275H, ProcessaRm_0275H,
              AgrupaItensRm_0275H, Verifica_Array_GradeRm_0275H

