;** Rm_0060  *******************************************************************
;*  Fluxo de Caixa                                                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 03/05/2018 por Anivel Augusto Rodrigues
;Ultima Alteracao: 03/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao novo processo concetrador RM_0030, RM_0040, RM_0050, RM_0060             
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 06/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes modelo 20
;Ultima Alteracao: 07/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ListaRegra_TGAtivado="[TG_EMPRESATE]"
;Ultima Alteracao: 22/01/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desprezar t¡tulos de credito
;Ultima Alteracao: 09/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ListaRegra_F2, TG_CONTA                
;Ultima Alteracao: 26/09/2020 por Bruno Carvalho             
;Motivo Alteracao: Alterado Picture "TG_CONTA" e "TG_EMPRESATE" de "[&,#][#*#]" para "!*!", permitir caracter "?" p/ ListaRegra

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc ValidarRelatorio(tipo)
private tipo, result

result=true

switch
  case VSDGCODMODELO="01" Or
       VSDGCODMODELO="02" Or
       VSDGCODMODELO="03" Or
       VSDGCODMODELO="10" or
       VSDGCODMODELO="20" Or
       VSDGCODMODELO="21" :

    If VSDGEMPRESA=""
       Then result=false
            if tipo="SD"
               then  FastMsg("Empresa Inv lida !")
               else Mensagem("Empresa Inv lida !")
            endif
            return result   
       else
            VSDGCONTA   =""
            VSDGNOMCONTA="TODAS"
    EndIf

  case VSDGCODMODELO="09" Or
       VSDGCODMODELO="11" : 

    If VSDGCONTA  =""
       Then result=false
            if tipo="SD"
               then  FastMsg("Conta Inv lida !")
               else Mensagem("Conta Inv lida !")
            endif   
            return result   
       else
            VSDGEMPRESA =""
            VSDGNOMEMP  ="TODAS"
            
            VSDGEMPRESA2=VSDGEMPRESA
    EndIf

endswitch

return result
endproc 

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
private Disparo,Campo,Evento,Elemento, Temp

Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60: If Campo="TG_EMPRESATE" or
                                      Campo="TG_CONTA"             
                                      Then ListaRegra_F2() 
                                   EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"      : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"         : Campo="TG_CONTA"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_OPFLUXOCX"     : Campo="TG_DTFIM"
            Case Campo="TG_OPCTAANALITICA": Campo="TG_OPFLUXOCX"
            case Campo="TG_OPCTATRANSF"   : Campo="TG_OPCTAANALITICA"
            Case Campo="TG_CODMODELO"     : Campo="TG_OPCTATRANSF"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"  : Campo="TG_CONTA"   
                    Case Campo="TG_CONTA"      : Campo="TG_DTINI"
                    Case Campo="TG_DTINI" :
                         If Not IsBlank(VSDGDTINI)
                            Then Campo="TG_DTFIM"
                         EndIf
                    Case Campo="TG_DTFIM"      : Campo="TG_OPFLUXOCX"
                    Case Campo="TG_OPFLUXOCX"  : Campo="TG_OPCTAANALITICA"
                    Case Campo="TG_OPCTAANALITICA": Campo="TG_OPCTATRANSF"
                    case Campo="TG_OPCTATRANSF"   : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  :
                      if ValidarRelatorio("SD")
                         then Campo="YES"
                      endif   
                     
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_DTINI":
     MSG_CAMPO="Informe a Data Inicial"
  Case Campo="TG_OPFLUXOCX":
     MensagemCheckBoxes()
  Case Campo="TG_OPCTAANALITICA" or Campo="TG_OPCTATRANSF":
     MensagemCheckBoxes()
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Sint‚tico Empresa/Di rio")
ModeloRelatoriosAdd("02  Sint‚tico Empresa/Mensal")
ModeloRelatoriosAdd("03  Sint‚tico Empresa/Mensal-Sem Saldos")
ModeloRelatoriosAdd("20  Sint‚tico Empresa/Plano de Conta/Mensal")
ModeloRelatoriosAdd("21  Sint‚tico Empresa/Plano de Conta/Semanal")
ModeloRelatoriosAdd("10  Anal¡tico Empresa")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("11  Sint‚tico Conta")
ModeloRelatoriosAdd("09  Anal¡tico Conta")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA   = ""
VSDGCONTA     =""
VSDGDTINI     = Today()
VSDGDTFIM     = Today()+30

Array TG_OPFLUXOCX[08]
TG_OPFLUXOCX[1] ="~1~ A receber cartäes Crˆd/D‚b"
TG_OPFLUXOCX[2] ="~2~ A receber todos"
TG_OPFLUXOCX[3] ="~3~ Entradas/Saida realizadas"
TG_OPFLUXOCX[4] ="~4~ Saldo inicial"
TG_OPFLUXOCX[5] ="~5~ Conta tipo Aplica‡Æo"
TG_OPFLUXOCX[6] ="~6~ T¡tulos de Cr‚dito"
TG_OPFLUXOCX[7] ="~7~ Crˆdito conta corrente"
TG_OPFLUXOCX[8] ="~8~ Cheques de terceiros"

Array CheckTG_OPFLUXOCX[08]
CheckTG_OPFLUXOCX[1]=False
CheckTG_OPFLUXOCX[2]=False
CheckTG_OPFLUXOCX[3]=False
CheckTG_OPFLUXOCX[4]=False
CheckTG_OPFLUXOCX[5]=False
CheckTG_OPFLUXOCX[6]=False
CheckTG_OPFLUXOCX[7]=False
CheckTG_OPFLUXOCX[8]=False


Array TG_OPCTAANALITICA[2] 
TG_OPCTAANALITICA[1]="NÆo Visualizar"
TG_OPCTAANALITICA[2]="Desprezar sem Valor"

Array CheckTG_OPCTAANALITICA[ArraySize(TG_OPCTAANALITICA)]
CheckTG_OPCTAANALITICA[1]=False
CheckTG_OPCTAANALITICA[2]=False


Array TG_OPCTATRANSF[2] 
TG_OPCTATRANSF[1]="NÆo Visualizar [Por plano de contas]"
TG_OPCTATRANSF[2]="Desprezar Valores Apurados"

Array CheckTG_OPCTATRANSF[ArraySize(TG_OPCTATRANSF)]
CheckTG_OPCTATRANSF[1]=False
CheckTG_OPCTATRANSF[2]=False

ListaRegra_VSDGEMPRESA_Ativo=False
ListaRegra_TGAtivado        ="[TG_EMPRESATE],[TG_CONTA]"

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "Fluxo de Caixa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140,-60  
    @ 01,00 Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "!*!" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "!*!" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    

    Label  @ 07,00 "Desprezar op‡äes:" For "TG_OPFLUXOCX"
    CheckBoxes @ 08,00 Height 10 Width 42 Tag "TG_OPFLUXOCX" 
    TG_OPFLUXOCX[1] to CheckTG_OPFLUXOCX[1],
    TG_OPFLUXOCX[2] to CheckTG_OPFLUXOCX[2],
    TG_OPFLUXOCX[3] to CheckTG_OPFLUXOCX[3],
    TG_OPFLUXOCX[4] to CheckTG_OPFLUXOCX[4],
    TG_OPFLUXOCX[5] to CheckTG_OPFLUXOCX[5],
    TG_OPFLUXOCX[6] to CheckTG_OPFLUXOCX[6],
    TG_OPFLUXOCX[7] to CheckTG_OPFLUXOCX[7],
    TG_OPFLUXOCX[8] to CheckTG_OPFLUXOCX[8] 

    Label @ 00,35 "Contas An liticas  [Por plano de contas]" For "TG_OPCTAANALITICA"
    CheckBoxes @ 01,35 Height 2 Width 33 Tag "TG_OPCTAANALITICA"
    TG_OPCTAANALITICA[1] to CheckTG_OPCTAANALITICA[1],
    TG_OPCTAANALITICA[2] to CheckTG_OPCTAANALITICA[2] 

    Label @ 04,35 "Transferˆncias entre Contas" For "TG_OPCTATRANSF"
    CheckBoxes @ 05,35 Height 2 Width 42 Tag "TG_OPCTATRANSF"
    TG_OPCTATRANSF[1] to CheckTG_OPCTATRANSF[1],
    TG_OPCTATRANSF[2] to CheckTG_OPCTATRANSF[2]

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         
       
  If VSDGDTINI=BlankDate()
     Then Mensagem("Data Inicial Invalida !")
          Loop
  EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  if VSDGCODMODELO="20" and
     (VSDGDTFIM-VSDGDTINI)>365
     Then Mensagem("Per¡odo Referente m ximo de 12 meses !")
          Loop
  EndIf

  if not ValidarRelatorio("")
     then Loop
  endif   

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  ANOREF=StrVal(Year(VSDGDTINI))
  MESREF=StrVal(Month(VSDGDTINI))
  ALINHM(MESREF, 2)
  MESREF=NVR
  VSDGDTREF=DateVal("01."+MESREF+"."+ANOREF)

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  switch
    case VSDGCODMODELO="20": 
      TipoFluxo ="Analitico"
      TipoFiltro="Empresa"
      Play "RM_0060M" 

    case VSDGCODMODELO="21": 
      TipoFluxo ="Analitico"
      TipoFiltro="Empresa"
      Play "RM_0060S"

    otherwise              :   
      Release Vars TipoFluxo,TipoFiltro
    
      switch
        case VSDGCODMODELO="01" Or
             VSDGCODMODELO="02" Or
             VSDGCODMODELO="03" :
          TipoFluxo ="Sintetico"
          TipoFiltro="Empresa"
          Impressao_Orientacao="Paisagem"
    
        case VSDGCODMODELO="11" :
          TipoFluxo ="Sintetico"
          TipoFiltro="Conta"
          Impressao_Orientacao="Paisagem"
              
        case VSDGCODMODELO="09" :
          TipoFluxo ="Analitico"
          TipoFiltro="Conta"
          Impressao_Orientacao="Retrato"
              
        case VSDGCODMODELO="10" :
          TipoFluxo ="Analitico"
          TipoFiltro="Empresa"
          Impressao_Orientacao="Retrato"
    
      endswitch
    
      Play "RM_FlxCx"
      
      switch
        case VSDGCODMODELO="01" : IMPRIREL(Tabela,"R")
        case VSDGCODMODELO="02" : IMPRIREL(Tabela,"3")
        case VSDGCODMODELO="03" : IMPRIREL(Tabela,"4")
    
        case VSDGCODMODELO="09" : IMPRIREL(Tabela,"3")
    
        case VSDGCODMODELO="10" : IMPRIREL(Tabela,"8")
    
        case VSDGCODMODELO="11" : IMPRIREL(Tabela,"1")
    
      endswitch
    
      Delete Tabela

  endswitch

EndWhile
ClearAll
Release Vars All
Release Procs All
