;** Rm_0500 ********************************************************************
;*  Posicao Expedicao/Carregamento                                             *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 02/04/2008 por Anivel Augusto Rodrigues
;Ultima Alteracao: 18/04/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 25/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao Modelo Sintetico
;Ultima Alteracao: 28/05/2009 por Humberto F. Santos.
;Motivo Alteracao: Inclusao Modelo 4 Item\Pedido.
;Ultima Alteracao: 31/03/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado ASK p/ ¤ pegar FATURADOS 
;Ultima Alteracao: 12/04/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Inclusao TG_REFERENCIA/BIB_SHOW
;Ultima Alteracao: 23/10/2013 por Bruno Carvalho
;Motivo Alteracao: Adicionado novo modelo e ajustado modelos para consulta com F1
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA
;Ultima Alteracao: 07/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     
;Ultima Alteracao: 20/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     
;Ultima Alteracao: 07/10/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtrar cor     

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Vendas\\ExpedC}
Moveto [Numero da OE           ] CheckPlus Example "noe"
Moveto [Numero do Pedido       ] CheckPlus TypeIn "~VSDGPEDIDO.."
Moveto [Codigo da Empresa      ] CheckPlus TypeIn "~VSDGEMPRESA.."
Moveto [Nome Fantasia Empresa  ] CheckPlus
Moveto [Razao Social           ] CheckPlus
Moveto [Numero_Carregamento    ] CheckPlus TypeIn "~VSDGNCARREG.."
Moveto [Data_Liberacao         ] CheckPlus

If VSDGCODMODELO="02"
   Then Moveto [Data_Inclusao  ] CheckPlus TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"  
EndIf

If VSDGCODMODELO<>"06" 
    Then Moveto [Situacao da OE         ] TypeIn "Not FATURADO"
    Else Moveto [Situacao da OE         ] CheckPlus 
EndIf

{Ask} {\\Sistemas\\Vendas\\ExpedI}
Moveto [Numero da OE           ] Example "noe"
Moveto [Codigo do Item         ] CheckPlus TypeIn "~VSDGITEM.."
Moveto [Referencia             ] CheckPlus TypeIn "~VSDGREFERENCIA.."
Moveto [Descricao do Item      ] CheckPlus
Moveto [Quantidade_Pedido      ] CheckPlus
Moveto [Quantidade_Expedida    ] CheckPlus
Moveto [Unidade Fiscal         ] CheckPlus
Moveto [Codigo da Cor_Tecido   ]           TypeIn "~VSDGCORTECIDO.."   
Do_It!
ClearAll

If VSDGOPSALDO="T"
   Then Return
EndIf

{Ask} {Answer} TypeIn "Fast Delete"
Moveto [Quantidade_Pedido      ] Example "qtd"
Moveto [Quantidade_Expedida    ] TypeIn "= " Example "qtd"
Do_It!
ClearAll

EndProc  ; (Seleciona)

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Ajusta_Dados()
ClearAll

{Ask} {Answer}
Moveto [Numero da OE         ] Example"NumOe"         
Moveto [Numero do Pedido     ] Example"NumPd"      
Moveto [Codigo da Empresa    ] Example"CodEm"       
Moveto [Nome Fantasia Empresa] Example"NomFa"      
Moveto [Razao Social         ] Example"RazSo"       
Moveto [Data_Liberacao       ] Example"DtLib"           
Moveto [Numero_Carregamento  ] Example"NumCa"       
Moveto [Codigo do Item       ] Example"CodIt"         
Moveto [Referencia           ] Example"Refer"            
Moveto [Descricao do Item    ] Example"DesIt"        
Moveto [Quantidade_Pedido    ] Example"QtdPd"       
Moveto [Quantidade_Expedida  ] Example"QtdEx"      
Moveto [Unidade Fiscal       ] Example"UnFis"       

If VSDGCODMODELO="06"
   Then Moveto [Situacao da OE] Example"SitOe"
EndIf          

If VSDGCODMODELO="02"
   Then Moveto [Data_Inclusao] Example"DtInc"
EndIf          

{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Numero da OE         ] Example"NumOe"      
Moveto [Numero do Pedido     ] Example"NumPd"      
Moveto [Codigo da Empresa    ] Example"CodEm"      
Moveto [Nome Fantasia Empresa] Example"NomFa"      
Moveto [Razao Social         ] Example"RazSo"      
Moveto [Numero_Carregamento  ] Example"NumCa"       
Moveto [Codigo do Item       ] Example"CodIt"       
Moveto [Referencia           ] Example"Refer"      
Moveto [Descricao do Item    ] Example"DesIt"      
Moveto [Quantidade_Pedido    ] Example"QtdPd"      
Moveto [Quantidade_Expedida  ] Example"QtdEx"      
Moveto [Unidade Fiscal       ] Example"UnFis"
Moveto [Data_Liberacao       ] Example"DtLib"      

If VSDGCODMODELO="06"
   Then Moveto [Situacao da OE] Example"SitOe"
EndIf         

If VSDGCODMODELO="02"
   Then Moveto [Data_Inclusao] Example"DtInc"
EndIf        

Do_It!
ClearAll 

EndProc ;(Ajusta_Dados)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"        : Campo="NO"
            Case Campo="TG_PEDIDO"         : Campo="TG_EMPRESA"
            Case Campo="TG_NCARREG"        : Campo="TG_PEDIDO"
            Case Campo="TG_ITEM"           : Campo="TG_NCARREG"
            Case Campo="TG_REFERENCIA"     : Campo="TG_ITEM"
            Case Campo="TG_COR_TECIDO"     : Campo="TG_REFERENCIA"
            Case Campo="TG_OPSALDO"        : Campo="TG_COR_TECIDO"
            Case Campo="TG_DTINI"          : Campo="TG_OPSALDO"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"      : Campo="TG_OPSALDO"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_PEDIDO"
                    Case Campo="TG_PEDIDO"     : Campo="TG_NCARREG"
                    Case Campo="TG_NCARREG"    : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"       : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA" : Campo="TG_COR_TECIDO"
                    Case Campo="TG_COR_TECIDO" : Campo="TG_OPSALDO"
                    Case Campo="TG_OPSALDO"    : Campo="TG_DTINI"
                         VSDGOPSALDO=ControlValue("TG_OPSALDO")
                         Switch
                          Case VSDGOPSALDO="T": VSDGDESCOPSALDO="Todos"
                          OtherWise           : VSDGOPSALDO="P"
                                                VSDGDESCOPSALDO="PENDENTES"
                         EndSwitch
                    Case Campo="TG_DTINI"     : Campo="TG_DTFIM" 
                    Case Campo="TG_DTFIM"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_OPSALDO":
     MSG_CAMPO="T=Todos os Itens, P=Somente Itens pendentes"
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc


;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Carregamento")
ModeloRelatoriosAdd("02  Carregamento/Data Inclus„o")
ModeloRelatoriosAdd("03  Carregamento/Pedido")
ModeloRelatoriosAdd("04  Item")
ModeloRelatoriosAdd("05  Item/Pedido")
ModeloRelatoriosAdd("06  N§ da OE/Pedido")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
VSDGPEDIDO       = ""
VSDGEMPRESA      = ""
VSDGNCARREG      = ""
VSDGREFERENCIA   = ""
VSDGITEM         = ""
VSDGCODMODELO      = ""
VSDGOPSALDO      = ""
VSDGDESCOPSALDO  = ""
VSDGDTINI        = BlankDate()
VSDGDTFIM        = BlankDate()
VSDGCORTECIDO    = ""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Posi‡Æo Expedi‡Æo em ABERTO/LIBERADO" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
  @ 05,12   Height 19 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Pedido"  For "TG_PEDIDO"
    Accept @ 03,01 Width 9  "A6"  Picture "[&,#][#*#]" Tag "TG_PEDIDO"    To VSDGPEDIDO
    Accept @ 03,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMPEDIDO" To VSDGNOMPEDIDO
      
    Label  @ 04,00 "Carregamento" For "TG_NCARREG"
    Accept @ 05,01 Width 9  "A6"  Picture "[&,#][#*#]" Tag "TG_NCARREG"    To VSDGNCARREG
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMNCARREG" To VSDGNOMNCARREG

    Label  @ 06,00 "Item"  For "TG_ITEM"
    Accept @ 07,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 08,01 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 06,13 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 07,13 Width 21 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 09,00 "Cor do Tecido"  For "TG_COR_TECIDO"
    Accept @ 10,01 Width 07 "A4"  Picture "#*#" Tag "TG_COR_TECIDO"    To VSDGCORTECIDO
    Accept @ 10,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMCOR_TECIDO" To VSDGNOMCORTECIDO

    Label  @ 00,35 "Op‡Æo de Saldo" For "TG_OPSALDO"
    Accept @ 01,39 Width 04 "A1"  Picture "T,P" Tag "TG_OPSALDO" To VSDGOPSALDO
    Accept @ 01,44 Width 25 "A30"  Picture "!*!" Tag "TG_DESCOPSALDO" To VSDGDESCOPSALDO

    Label  @ 02,35 "Per¡odo InclusÆo de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 12,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 13,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 13,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO  

    Pushbutton @ 15,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGCODMODELO="02" And IsBlank(VSDGDTINI) And IsBlank(VSDGDTFIM)
     Then Mensagem("A data inicial ou final dever  ser informada para prosseguir !")
          Loop
  EndIf   

  If VSDGCODMODELO<>"02" And (Not IsBlank(VSDGDTINI) Or Not IsBlank(VSDGDTFIM))
     Then ;;;Mensagem("A data de inclus„o apenas poder  ser informada caso selecionado o //Modelo 2 - Carregamento/Data Inclus„o !")
          VSDGDTINI=BlankDate() 
          VSDGDTFIM=BlankDate()
  EndIf 

 DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando Relat¢rio")
  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("NÆo existem registros a processar!")
          Loop
  EndIf
  
  Tabela=Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Vendas\\Rm_0500" Tabela
  Empty(Tabela)
  
  Ajusta_Dados()
  Switch
    Case VSDGCODMODELO="01": Modelo = "R"
    Case VSDGCODMODELO="02": Modelo = "5"
    Case VSDGCODMODELO="03": Modelo = "1"
    Case VSDGCODMODELO="04": Modelo = "2"
    Case VSDGCODMODELO="05": Modelo = "3"
    Case VSDGCODMODELO="06": Modelo = "4"
  EndSwitch
  IMPRIREL(Tabela,Modelo)

  Delete "Answer"

EndWhile
ClearAll
Release Vars All
Release Procs All
