;** EncerraE *******************************************************************
;*  Programa p/ Fechamento de Meses Selecionados                               *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 08/10/2020 por Bruno Carvalho
;Ultima Alteracao:   /  /     por                             
;Motivo Alteracao: 

;*******************************************************************************
; EXPEDC/EXPEDI/EXPEDIQ/EXPEDTG/EXPEDIL                                        *
;*******************************************************************************
Proc Encerra_Expedicao()
ClearAll
MSG_AGUARDE="Aguarde, fechando expedi‡”es "+ANO_MES+" "

Aguarde(MSG_AGUARDE+Barra(6,1))
{Ask} {ExpedC} Check
Moveto [Data_Inclusao    ] TypeIn "...~MESANO"
Moveto [Situacao da OE   ] TypeIn "FATURADO"
Do_It!
ClearAll
                                                           
If IsEmpTy("Answer")
   Then Fastmsg("Mˆs sem movimenta‡„o p/ expedi‡”es!")
        Return
EndIf

Rename "Answer" "ExpTemp"
ClearAll

Aguarde(MSG_AGUARDE+Barra(6,2))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedI} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Encerra_Crea_Add_Sub_Tabela("Answer","ExpedI")

Aguarde(MSG_AGUARDE+Barra(6,3))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedIQ} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Encerra_Crea_Add_Sub_Tabela("Answer","ExpedIQ")

Aguarde(MSG_AGUARDE+Barra(6,4))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedTG} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Encerra_Crea_Add_Sub_Tabela("Answer","ExpedTG")

Aguarde(MSG_AGUARDE+Barra(6,5))
{Ask} {ExpedC}
Moveto [Numero da OE  ] Example "noe"
Moveto [Data_Inclusao ] TypeIn "...~MESANO"
Moveto [Situacao da OE] TypeIn "FATURADO"
{Ask} {ExpedIL} Check
Moveto [Numero da OE  ] Example "noe"
Do_It!
ClearAll
Encerra_Crea_Add_Sub_Tabela("Answer","ExpedIL")

Aguarde(MSG_AGUARDE+Barra(6,6))
Encerra_Crea_Add_Sub_Tabela("ExpTemp","ExpedC")

EndProc

;*******************************************************************************
;* Rotina Create/Add/Subtract                                                  *
;*******************************************************************************
Proc Encerra_Crea_Add_Sub_Tabela(TABORIG,TABDEST)
Private TABORIG,TABDEST,TABDESTINO

TABDESTINO = DiretorioFechames+TABDEST
If Not IsTable(TABDESTINO)
   Then Create TABDESTINO Like TABDEST
        {Tools} {Copy} {JustFamily} TypeIn TABDEST Enter TypeIn TABDESTINO Enter {Replace}
        Delete "Struct"
EndIf
Add TABORIG TABDESTINO ClearImage
SaveTables

SubTract TABORIG TABDEST ClearImage
SaveTables

If SubStr(Upper(TABDEST),Len(TABDEST),1)="C"
   Then Encerra_DesbloqueiaTabelas(Diretorio)
        Encerra_DesbloqueiaTabelas(DiretorioFechames)
EndIf   

{Modify} {Restructure} TypeIn TABDEST Enter Do_It! ClearImage
Delete TABORIG

SAVETABLES
EndProc

;*******************************************************************************
;* Rotina Bloqueia Tabelas da Pasta                                            *
;*******************************************************************************
Proc Encerra_BloqueiaTabelas(Pasta)
Private MSG, Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)                 
  If IsTable(Pasta+Array_Tabelas[i])
     Then Lock Pasta+Array_Tabelas[i] FL
          If Not RetVal
             Then MSG="O usu rio "+Upper(ErrorUser())+" esta usando o Sistema !// //"
                  MSG=MSG+Completa("- Contact -lo para liberar o Sistema;",40," ")+"//"
                  MSG=MSG+Completa("- Esta rotina ser  abortado.",40," ")+"// //"
                  MSG=MSG+"Execute esta rotina novamente para que//"
                  MSG=MSG+"a mesma seja concluida corretamente !"
                  Mensagem(MSG)
                  Return False
          EndIf
  EndIf
EndFor

Return True
EndProc
  
;*******************************************************************************
;* Rotina Desbloqueia Tabelas da Pasta                                         *
;*******************************************************************************
Proc Encerra_DesbloqueiaTabelas(Pasta)
Private Pasta, i

For i From 1 to DynArraySize(Array_Tabelas)                   
  If IsTable(Pasta+Array_Tabelas[i])
     Then UnLock Pasta+Array_Tabelas[i] FL
  EndIf
EndFor
            
EndProc

;*******************************************************************************
;* Rotina Monta Lista de Tabelas a Processar                                   *
;*******************************************************************************
Proc Encerra_ListadeTabelas()
If IsAssigned(Array_Tabelas)
   Then Release Vars Array_Tabelas
EndIf
DynArray Array_Tabelas[]
                                         
Array_Tabelas[01]="EXPEDC"
Array_Tabelas[02]="EXPEDI"
Array_Tabelas[03]="EXPEDIQ"
Array_Tabelas[04]="EXPEDTG"
Array_Tabelas[05]="EXPEDIL"
Array_Tabelas[06]="EXPEDOFI"

EndProc

;*******************************************************************************
;* Rotina Lista de Mes/Ano em Aberto                                           *
;*******************************************************************************
Proc Encerra_Lista_MesAno()
ClearAll                                                   
Aguarde("Aguarde, Verificando Mes/Ano em Aberto")

If IsAssigned(Array_ListaMesAno)
   Then Release Vars Array_ListaMesAno
EndIf
DynArray Array_ListaMesAno[]


{Ask} {ExpedC}
Moveto [Data_Inclusao ] Check TypeIn "as Data de Emissao"
Moveto [Situacao da OE] TypeIn "FATURADO"
Do_It!
ClearAll

Rename "Answer" PrivDir()+"Temp000"
If IsEmpty(PrivDir()+"Temp000")
   Then LimpAguarde()
        Return
EndIf

if istable("Keyviol") then delete "Keyviol" endif

{Modify} {Restructure} TypeIn PrivDir()+"Temp000" Enter
Right CtrlBackspace  "Data"
Down  "Mes" Enter  "a2" Enter  "Ano" Enter  "a4"
Do_It!

EditKey
Scan
  If Not IsBlank([Data])
     Then [Mes]=AlinhM(StrVal(Month([Data])),2)
          [Ano]=AlinhM(StrVal(Year([Data])),4)
  EndIf
EndScan
Do_It!
ClearAll

{Ask} TypeIn PrivDir()+"Temp000" Enter
Moveto [Mes] Check
Moveto [Ano] Check
Do_It!
ClearAll

Sort "Answer" on "Ano","Mes"

wcs=0
Scan
  wcs=wcs+1
  Array_ListaMesAno[wcs]=[Ano]+"_"+[Mes]
EndScan
ClearAll

LimpAguarde()
EndProc    ;  (Lista_MesAno)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc Encerra_SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True                                                        
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_DIRETORIOS"    : Campo="TG_EMPRESA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
          SYS_TECLA_ACIONADA=Evento["KeyCode"]
          Seta_Tecla_Acionada()
          CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_DIRETORIOS"
                    Case Campo="TG_DIRETORIOS" : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="":
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

If Not Isassigned(PARAM_ENCERRA_SHOWDIALOG) Then PARAM_ENCERRA_SHOWDIALOG = True EndIf 

If Not PARAM_ENCERRA_SHOWDIALOG
  Then Encerra_Expedicao()
       Release Procs Encerra_Expedicao,Encerra_Crea_Add_Sub_Tabela,Encerra_BloqueiaTabelas,
                     Encerra_DesbloqueiaTabelas,Encerra_ListadeTabelas,Encerra_Lista_MesAno,Encerra_SD_Dialog 
       Return
EndIf

VSDGEMPRESA   =""

COR_MENSAGEM="1"
MSG=    "Antes de fechar um mˆs, observe se j //"
MSG=MSG+"existem lan‡amentos existentes no mˆs seguinte !// //"
MSG=MSG+"Fique atento a ordem crescente dos lan‡amentos//"
MSG=MSG+"pra que os mesmos n„o retrocedam !"
Mensagem(MSG)
Release Vars COR_MENSAGEM

While True
  Encerra_Lista_MesAno()                                   

  ShowDialog "Fechamento mensal [ Expedi‡Æo ]" Proc "Encerra_SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 04,17   Height 19 Width 75

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 0,09 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 0,16 Width 23 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    PickDynArray @2,01 Height 12 width 69
     Columns 7
      Array_ListaMesAno
       Tag "TG_DIRETORIOS"                                           
        To ArrayElement
    Label @ 01,00 "Ano_Mes em aberto"  For "TG_DIRETORIOS"

    Pushbutton @ 15,24 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 15,38 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If DynArraySize(Array_ListaMesAno)<1
     Then Mensagem("Sem Mes/Ano p/ Fechar !")
          Loop
  EndIf

  ANO_MES=Array_ListaMesAno[ArrayElement]

  MES=Substr(ANO_MES,6,2)
  ANO=Substr(ANO_MES,1,4)
  If NumVal(ANO) < 2000
     Then MESANO=MES+"."+SubStr(ANO,3,2)
     Else MESANO=MES+"."+ANO
  EndIf

  If DirExists("\\Fechano\\"+ANO)<>0
     Then MSG="No fechamento Anual de "+ANO+" j  existem lan‡amentos arquivados !// //"
          MSG=MSG+Completa("Para poder fechar este mˆs, siga os passos:",70," ")+"// //"
          MSG=MSG+Completa("1) Restaure o ano de "+ANO+";",70," ")+"//"
          MSG=MSG+Completa("2) Aproveite e feche os mˆses de todos m¢dulos referente a "+ANO+";",70," ")+"//"
          MSG=MSG+Completa("   * Assim estes novos lan‡amentos ser„o agrupados aos",70," ")+"//"
          MSG=MSG+Completa("     lan‡amentos anteriores",70," ")+"//"
          MSG=MSG+Completa("3) Se necess rio feche novamente o ano de "+ANO+" !",70," ")
          Mensagem(MSG)
          Loop
  Endif

  If Not Verifica_Usuario() Then Loop EndIf
  Diretorio="\\Sistemas\\Vendas\\"
  DiretorioFechames=Diretorio+"Fechames\\"+ANO+"_"+MES+"\\"
  If DirExists(Diretorio+"Fechames")=0
    Then Cria_Pasta(Diretorio+"FechaMes")
  EndIf
  If DirExists(Diretorio+"Fechames\\"+ANO+"_"+MES)=0
     Then Cria_Pasta(Diretorio+"Fechames\\"+ANO+"_"+MES)
  EndIf

  Encerra_ListadeTabelas()
  If (Encerra_BloqueiaTabelas(Diretorio)) And
     (Encerra_BloqueiaTabelas(DiretorioFechames))
     Then Encerra_Expedicao()
  EndIf
         
  LimpAguarde()
  Fastmsg("Fim de Opera‡„o !")

EndWhile
ClearAll
Release Vars All
Release Procs All
