;** Rm_0050 *******************************************************************
;*  Emissao dos Titulos nao Pagos                                             *
;******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 25/02/2005 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo da Baixa
;Ultima Alteracao: 08/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/07/2014 por Luis Gustavo
;Motivo Alteracao: Ajuste na data de emissao, estava pegando totdos os titulos, e nao os do periodo selecionado
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 08/06/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 13/01/2021 por Bruno Carvalho                        
;Motivo Alteracao: Ajustes p/ chamar filtro padrao *RM_0330*

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc RM_0330E_Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos") And
   IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa")
   Then If VSDGATIVIDADE<>""
           Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
                Moveto [Codigo            ] example "cemit"
                Moveto [Codigo Atividade  ] TypeIn "~VSDGATIVIDADE.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
        Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
        If VSDGATIVIDADE<>""
           Then Moveto [Codigo do Emitente   ] Example "cemit" TypeIn ", ~VSDGDESTINAT.."
           Else Moveto [Codigo do Emitente   ]                 TypeIn "~VSDGDESTINAT.."
        EndIf
        Switch
          Case VSDGOPDATA="1" : Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Case VSDGOPDATA="2" : Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Case VSDGOPDATA="3" : Moveto [Data Competencia  ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM" 
        EndSwitch
        Moveto [Codigo da Conta   ] TypeIn "~VSDGCONTA.."
        Moveto [Codigo Plano_Conta] TypeIn PLCONTAS
        If CheckTG_OPCCUSTO[1]
           Then Moveto [Codigo CCusto] TypeIn "Not Blank, ~VSDGCCUSTO.."
           Else Moveto [Codigo CCusto] TypeIn "~VSDGCCUSTO.."
        Endif
        Do_It!
        ClearAll
        If Not CriaC
           Then TabelaC=Cria_Temp(PrivDir())
                CriaC=True
        EndIf
        If IsTable(TabelaC)
           Then Add "Answer" TabelaC
           Else Rename "Answer" TabelaC
        EndIf

        If VSDGATIVIDADE<>""
           Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
                Moveto [Codigo            ] example "cemit"
                Moveto [Codigo Atividade  ] TypeIn "~VSDGATIVIDADE.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter
        Moveto [Numero do Lancamento] Example "numero"
        Moveto [Codigo da Empresa   ] TypeIn "~VSDGEMPRESA2.."
        If VSDGATIVIDADE<>""
           Then Moveto [Codigo do Emitente   ] Example "cemit" TypeIn ", ~VSDGDESTINAT.."
           Else Moveto [Codigo do Emitente   ]                 TypeIn "~VSDGDESTINAT.."
        EndIf
        Switch
          Case VSDGOPDATA="1" : Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Case VSDGOPDATA="2" : Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
          Case VSDGOPDATA="3" : Moveto [Data Competencia  ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM" 
        EndSwitch
        Moveto [Codigo da Conta   ] TypeIn "~VSDGCONTA.."
        Moveto [Codigo Plano_Conta] TypeIn PLCONTAS
        If CheckTG_OPCCUSTO[1]
           Then Moveto [Codigo CCusto] TypeIn "Not Blank, ~VSDGCCUSTO.."
           Else Moveto [Codigo CCusto] TypeIn "~VSDGCCUSTO.."
        Endif
        {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"TitBaixa" Enter Check
        Moveto [Numero do Lancamento] Example "numero"
        Moveto [Tipo da Baixa       ] TypeIn "Blank or NORMAL"
        Do_It!
        ClearAll
        If Not CriaI
           Then TabelaI=Cria_Temp(PrivDir())
                CriaI=True
        EndIf
        If IsTable(TabelaI)
           Then Add "Answer" TabelaI
           Else Rename "Answer" TabelaI
        EndIf
EndIf





EndProc  ;  (RM_0330E_Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc RM_0330E_Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn TabelaC Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

{Ask} TypeIn TabelaC Enter TypeIn "Fast"
Moveto [Valor do Documento  ] Example "vr"
Moveto [Saldo do Documento  ] TypeIn "Changeto "  Example "vr"
Do_It!
ClearAll

Coedit TabelaI,TabelaC
Moveto [Numero do Lancamento]
Scan
   Numero=[Numero do Lancamento]
   Moveto TabelaI
   Moveto [Numero do Lancamento]
   Locate Numero
   If Not RetVal
      Then Moveto TabelaC
           Loop
   EndIf
   VRPG=0
   While [Numero do Lancamento]=Numero And Not RecordStatus("New")
     If [Data do Pagamento]<=VSDGDTFIM
        Then VRPG=VRPG+([Valor do Pagamento]+[Valor do Desconto])
     EndIf
     Down
   EndWhile
   Moveto TabelaC
   [Saldo do Documento]=[Saldo do Documento]-VRPG
EndScan
Do_It!
ClearAll

{Ask} TypeIn TabelaC Enter TypeIn "Fast Delete"
Moveto [Saldo do Documento  ] TypeIn "<=0.01"
Do_It!
ClearAll

Coedit TabelaC
Scan
   If [Data a Pagar]<VSDGDTFIM
      Then NDA=VSDGDTFIM-[Data a Pagar]
           TXM=[Multa]
      Else NDA=0
           TXM=0
   EndIf
   If [Data Limite Desconto]<=VSDGDTFIM
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)
   [Data de Vencimento]=[Data a Pagar]
EndScan
Do_It!
ClearAll
EndProc  ; (RM_0330E_Processa)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_0330E_Principal()

AGUARDE("Aguarde, Gerando o RelatĒrio")
CriaC=False
CriaI=False
                     
Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  RM_0330E_Seleciona()
EndWhile

If IsEmpty(TabelaC)
   Then MENSAGEM("No existem registros a processar")
        Delete TabelaC
        Delete TabelaI
        Return
EndIf
RM_0330E_Processa()

CopyReport "\\Base\\Sistemas\\CtaPag\\Rm_1000" "9" TabelaC "R"

IMPRIREL(TabelaC,"R")

Delete TabelaC
Delete TabelaI

EndProc

;-- Chamada principal ----------------------------------------------------------
RM_0330E_Principal()

Release Vars Tabela
Release Procs RM_0330E_Principal,RM_0330E_Seleciona,RM_0330E_Processa