;** Rm_0101  *******************************************************************
;*  Relacao de Recebimentos e Pagamentos por Usuario                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 27/01/2005 por Nikolas M. Mateus
;Motivo Alteracao: Aproveitado para inclusao de usuario, controle dia pela
;                   data que foi realizado incluindo entrada/saida junto
;Ultima Alteracao: 05/05/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 05/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_NCONTROLE                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 22/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 30/06/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro todas contas      
;Ultima Alteracao: 15/05/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes titulo showdialog              
;Ultima Alteracao: 18/05/2020 por Bruno Carvalho
;Motivo Alteracao: Alterado CopyReport "...\\Ctacor\\MovCont" p/ "...\\Ctacor\\RM_0030"
;Ultima Alteracao: 22/01/2021 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ chamar filtro padrÆo *RM_0130*

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc RM_0101A_Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont")
  Then {Ask} TypeIn "\\Sistemas\\Ctacor\\"+Dir_Trab+"MovCont" Enter Check
       Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo da Conta    ] TypeIn "~VSDGCONTA.."       
       Moveto [Codigo_Usuario     ] TypeIn "~VSDGCHAPA.."
       Moveto [Numero_Controle_Dia] TypeIn "~VSDGNCONTROLE.."       
       If IsBlank(VSDGNCONTROLE)
        Then If VSDGOPDTEMISCOMP = "1"
                Then Moveto [Data Competencia] Check
                     Moveto [Data            ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
                Else Moveto [Data            ] Check
                     Moveto [Data Competencia] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM, as Data"
             EndIf
       EndIf
       If CheckTG_OPCCUSTO[1]
          Then Moveto [Codigo CCusto         ] TypeIn "Not Blank, ~VSDGCCUSTO.."
          Else Moveto [Codigo CCusto         ] TypeIn "~VSDGCCUSTO.."
       Endif
       Moveto [Tipo Movimento    ] TypeIn "~VSDGOPERACAO.."       
       Moveto [Tipo do Lancamento] TypeIn "~VSDGTPLANC.."                                                
       Do_It!
       ClearAll
EndIf

EndProc ;RM_0101A_Seleciona()

;*******************************************************************************
;* ROTINA Ajusta Dados Empresa                                                 *
;*******************************************************************************
Proc RM_0101A_Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

EndProc ;RM_0101A_Processa()

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
While True
  AGUARDE("Aguarde, gerando o relat¢rio")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    RM_0101A_Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Return
  EndIf

  RM_0101A_Processa()

  CopyReport "\\Base\\Sistemas\\Ctacor\\RM_0030" "R" Tabela "R"

  IMPRIREL(Tabela,"R")

  Delete Tabela
  QuitLoop
EndWhile
ClearAll

Release Vars RM_0101A_Seleciona,RM_0101A_Processa