;** Rm_3060 ********************************************************************
;* Resumo de Vendas por Familia/Grupo/Produto                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 17/09/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 08/09/2004 por Jos‚ Lu¡s Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 15/12/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 11/12/2014 por Luis Gustavo
;Motivo Alteracao: Implementado filtro por Gerencia
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues         
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 18/01/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes chamada principal RM_3070

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc RM_3060_Seleciona()
ClearAll

;****** Vendas *****************************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then if Not IsBlank(VSDGTIPOEST) or
           Not IsBlank(VSDGFAMI)    or
           Not IsBlank(VSDGGRP)     or
           Not IsBlank(VSDGMARCA)   or
           Not IsBlank(VSDGNCM)     or
           Not IsBlank(VSDGREFERENCIA) 
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Ask_EstoqueTpItem("") 
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
                Moveto [NCM                    ] TypeIn "~VSDGNCM.."
                Moveto [Referencia             ] TypeIn "~VSDGREFERENCIA.."    
        EndIf
        If VSDGAREA<>""
           Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
                Moveto [Codigo                 ] Example "clie"
                Moveto [Codigo da Area         ] TypeIn "~VSDGAREA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc" 
        Moveto [Nome Fantasia Represent] Check
        If VSDGOPDTES="2"
           Then Moveto [Data de Saida  ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
           Else Moveto [Data de Emissao] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndIf
        switch
          case ListaRegra_VSDGDESTIN_Ativo  : Moveto [Codigo da Destinacao] TypeIn ListaRegra_VSDGDESTIN
          otherwise                         : Moveto [Codigo da Destinacao] TypeIn "~VSDGDESTIN.."
        endswitch
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        If VSDGAREA<>""
           Then Moveto [Codigo         ] Example "clie" TypeIn ", ~VSDGDESTINAT.."
           Else Moveto [Codigo         ]                TypeIn "~VSDGDESTINAT.."
        EndIf
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo do Item         ] Check
        if Not IsBlank(VSDGTIPOEST) or
           Not IsBlank(VSDGFAMI)    or
           Not IsBlank(VSDGGRP)     or
           Not IsBlank(VSDGMARCA)   or
           Not IsBlank(VSDGNCM)     or
           Not IsBlank(VSDGREFERENCIA) 
           Then Moveto [Codigo do Item ] Example "cite" TypeIn ", ~VSDGITEM.."   
           Else Moveto [Codigo do Item ]                TypeIn   "~VSDGITEM.."    
        EndIf
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Moveto [Volumes                ] TypeIn "Calc Sum as Volumes"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        RM_3060_Adiciona_Dados("VENDAS")
EndIf

;****** Devolucoes - Estoque ***************************************************
If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
   Then if Not IsBlank(VSDGTIPOEST) or
           Not IsBlank(VSDGFAMI)    or
           Not IsBlank(VSDGGRP)     or
           Not IsBlank(VSDGMARCA)   or
           Not IsBlank(VSDGNCM)     or
           Not IsBlank(VSDGREFERENCIA) 
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Ask_EstoqueTpItem("") 
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
                Moveto [NCM                    ] TypeIn "~VSDGNCM.."
                Moveto [Referencia             ] TypeIn "~VSDGREFERENCIA.."    
        EndIf
        If VSDGAREA<>""
           Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
                Moveto [Codigo                 ] Example "clie"
                Moveto [Codigo da Area         ] TypeIn "~VSDGAREA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Data de Entrada        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
        Moveto [Nome Fantasia Represent] Check
        Moveto [Tipo de Operacao       ] TypeIn "D"
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        If VSDGAREA<>""
           Then Moveto [Codigo         ] Example "clie" TypeIn ", ~VSDGDESTINAT.."
           Else Moveto [Codigo         ]                TypeIn "~VSDGDESTINAT.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
        Moveto [Numero do Lancamento   ] Example "nlan"
        Moveto [Codigo do Item         ] Check
        if Not IsBlank(VSDGTIPOEST) or
           Not IsBlank(VSDGFAMI)    or
           Not IsBlank(VSDGGRP)     or
           Not IsBlank(VSDGMARCA)   or
           Not IsBlank(VSDGNCM)     or
           Not IsBlank(VSDGREFERENCIA) 
           Then Moveto [Codigo do Item ] Example "cite" TypeIn ", ~VSDGITEM.."   
           Else Moveto [Codigo do Item ]                TypeIn   "~VSDGITEM.."    
        EndIf
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Do_It!
        ClearAll

        RM_3060_Adiciona_Dados("DEVOLUCOES")
EndIf

;****** Devolucoes - Vendas ****************************************************
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then if Not IsBlank(VSDGTIPOEST) or
           Not IsBlank(VSDGFAMI)    or
           Not IsBlank(VSDGGRP)     or
           Not IsBlank(VSDGMARCA)   or
           Not IsBlank(VSDGNCM)     or
           Not IsBlank(VSDGREFERENCIA) 
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Ask_EstoqueTpItem("") 
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
                Moveto [NCM                    ] TypeIn "~VSDGNCM.."
                Moveto [Referencia             ] TypeIn "~VSDGREFERENCIA.."    
        EndIf
        If VSDGAREA<>""
           Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
                Moveto [Codigo                 ] Example "clie"
                Moveto [Codigo da Area         ] TypeIn "~VSDGAREA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] Check TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA2.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc" 
        Moveto [Nome Fantasia Represent] Check
        If VSDGOPDTES="2"
           Then Moveto [Data de Saida  ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
           Else Moveto [Data de Emissao] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndIf
        Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
        Moveto [Tipo Movimento Estoque ] TypeIn "E"
        Moveto [Situacao               ] TypeIn "Not C"
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        If VSDGAREA<>""
           Then Moveto [Codigo         ] Example "clie" TypeIn ", ~VSDGDESTINAT.."
           Else Moveto [Codigo         ]                TypeIn "~VSDGDESTINAT.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo do Item         ] Check
        if Not IsBlank(VSDGTIPOEST) or
           Not IsBlank(VSDGFAMI)    or
           Not IsBlank(VSDGGRP)     or
           Not IsBlank(VSDGMARCA)   or
           Not IsBlank(VSDGNCM)     or
           Not IsBlank(VSDGREFERENCIA) 
           Then Moveto [Codigo do Item ] Example "cite" TypeIn ", ~VSDGITEM.."   
           Else Moveto [Codigo do Item ]                TypeIn   "~VSDGITEM.."    
        EndIf
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        RM_3060_Adiciona_Dados("DEVOLUCOES")
EndIf

EndProc   ; (RM_3060_Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc RM_3060_Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
Moveto [Codigo da Gerencia     ] Example "Ger" ;Gerˆncia
If Tipo="VENDAS" And VSDGCODMODELO="16B"
   Then Moveto [Volumes        ] Example "vol"
EndIf
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Nome Fantasia EmitDest ] Example "Ger" ;Gerˆncia 
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Quantidade      ] Example "qtde"
       Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
       If VSDGCODMODELO="16B"
          Then Moveto [Vendas_Embalagem] Example "vol"
       EndIf
  Case Tipo="DEVOLUCOES":
       Moveto [Devolucoes_Quantidade  ] Example "qtde"
       Moveto [Devolucoes_Preco Total ] Example "ptot" TypeIn"-" Example "vdes"
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc RM_3060_Processa()

If VSDGCODMODELO="16A"
   Then VSDGNOMOPANALISE="Embalagem"
   Else VSDGNOMOPANALISE="Volumes"
EndIf

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Cadastro\\Represen}
Moveto [Codigo do Representante  ] Example "crep"
Moveto [Nome Fantasia Represent  ] Example "nrep"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Representante  ] Example "crep"
Moveto [Nome Fantasia Represent  ] TypeIn "changeto _nrep"
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Unidade Embalagem      ] Example "une"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Descricao da Familia   ] Example "dfam"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [Descricao do Grupo     ] Example "dgru"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Unidade Fiscal         ] TypeIn "changeto _unf"
Moveto [Unidade Embalagem      ] TypeIn "changeto _une"
Moveto [Codigo da Familia      ] TypeIn "changeto _cfam"
Moveto [Descricao da Familia   ] TypeIn "changeto _dfam"
Moveto [Codigo do Grupo        ] TypeIn "changeto _cgru"
Moveto [Descricao do Grupo     ] TypeIn "changeto _dgru"
Do_It!
ClearAll

If VSDGCODMODELO="16A"
   Then {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item            ] Example "cite"
        Moveto [Fator Conversao Embalagem ] Example "fce"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo do Item            ] Example "cite"
        Moveto [Unidade Fiscal            ] Example "unf"
        Moveto [Unidade Embalagem         ] TypeIn "not = " Example "unf"
        Moveto [Vendas_Quantidade         ] Example "qtd"
        Moveto [Vendas_Embalagem          ] TypeIn "changeto _qtd*_fce"
        Do_It!
        ClearAll
   Else {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Unidade Embalagem      ] TypeIn "Changeto Blank"
        Do_It!
        ClearAll
EndIf

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Embalagem       ] Check TypeIn "Calc Sum as VendasEmbalagem"
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as VendasPreco"
Moveto [Devolucoes_Quantidade  ] Check TypeIn "Calc Sum as DevolucoesQuantidade"
Moveto [Devolucoes_Preco Total ] Check TypeIn "Calc Sum as DevolucoesPreco"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Vendas_Embalagem          ] TypeIn "<=0, changeto blank"
Moveto [Unidade Embalagem         ] TypeIn "changeto Blank"
Do_It!
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Familia *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Familia      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Total_Vendas_Familia   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Grupo *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo da Familia      ] Check
Moveto [Codigo do Grupo        ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo da Familia      ] Example "cfam"
Moveto [Codigo do Grupo        ] Example "cgru"
Moveto [Total_Vendas_Grupo     ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (RM_3060_Processa)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_3060_Principal()

AGUARDE("Aguarde, gerando o relat¢rio")
Tabela=Cria_Temp(PrivDir())
Empty "\\Base\\Sistemas\\Vendas\\RM_3100"
Copy "\\Base\\Sistemas\\Vendas\\RM_3100" Tabela

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  RM_3060_Seleciona()
EndWhile

If Not IsEmpty(Tabela)
   Then RM_3060_Processa()
        If VSDGOPRELCODALF="1" 
           Then IMPRIREL(Tabela,"10")
           Else IMPRIREL(Tabela,"11")
        EndIf
   Else MENSAGEM("N„o existem registros a processar")
EndIf    

Delete Tabela

EndProc
          
;-- Chamada principal ----------------------------------------------------------
RM_3060_Principal()

Release Vars Tabela
Release Procs RM_3060_Principal, RM_3060_Seleciona, RM_3060_Adiciona_Dados, RM_3060_Processa