;** Rm_2010  *******************************************************************
;* Inclusao de Baixa de Titulos a Receber por Usuario                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 29/01/2005 por Anivel Augusto Rodrigues
;Ultima Alteracao: 13/08/2014 por Luis Gustavo
;Motivo Alteracao: Implementado Filtro Op‡ao de Relatorio
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 05/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_NCONTROLE                   
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 31/12/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ chamar filtro padrao *RM_0200*

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc RM_2010A_Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa")
   Then {Ask} {\\sistemas\\cadastro\\Destinat}
        Moveto [Codigo                 ] Example "dest" 
        If Not IsBlank (VSDGAREA) 
           Then Moveto [Codigo da Area] TypeIn "~VSDGAREA.." 
        EndIf   
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Numero do Lancamento   ] Example "lanc"
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
        Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
        Moveto [Codigo do Destinatario ] Example "dest" TypeIn ", ~VSDGDESTINAT.."
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
        Moveto [Numero do Lancamento   ] Example "lanc"
        Moveto [Codigo_Usuario         ] TypeIn "~VSDGCHAPA.."
        Moveto [Numero_Controle_Dia    ] TypeIn "~VSDGNCONTROLE.."
        Moveto [Codigo da Conta        ] TypeIn "~VSDGCONTA.."
        Moveto [Tipo da Baixa          ] TypeIn "~VSDGTPBAIXA.."
        Switch
           Case VSDGOPDT="1" :
                Moveto [Data do Pagamento] TypeIn ">=~VSDGDTINI ,<=~VSDGDTFIM"
           Case VSDGOPDT="2" :
                Moveto [Data_Inclusao    ] TypeIn ">=~VSDGDTINI ,<=~VSDGDTFIM"        
        EndSwitch
        Do_It!
        ClearAll
EndIf

EndProc  ; (RM_2010A_Seleciona)

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AGUARDE("Aguarde, gerando o relat˘rio")
While True
  AGUARDE("Aguarde, processando")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    RM_2010A_Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          QuitLoop
  EndIf
  
  Switch
    Case VSDGCODMODELO="61A" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "6" Tabela "R"
    Case VSDGCODMODELO="61B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "9" Tabela "R"
    Case VSDGCODMODELO="61C" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "7" Tabela "R"
    Case VSDGCODMODELO="61D" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "10" Tabela "R"
  EndSwitch   
  
  IMPRIREL(Tabela,"R")

  Delete Tabela
  QuitLoop
EndWhile
ClearAll

Release Vars RM_2010A_Seleciona      