;** Rm_3200 ********************************************************************
;* Resumo de Vendas por Representante/Cliente  Faturado/Tabela                 *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 23/10/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 08/09/2004 por Jos‚ Lu¡s Ameno da Silva
;Motivo Alteracao: PrivDir
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 03/10/2013 por Andrey Fillipe          
;Motivo Alteracao: Adicionado filtro por Gerencia 
;Ultima Alteracao: 17/06/2014 por Luis Gustavo
;Motivo Alteracao: Ajustes no filtro Gerencia
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 20/01/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes chamada principal RM_3110
;Ultima Alteracao: 26/01/2021 por Bruno Carvalho                                       
;Motivo Alteracao: Adicionado filtro [Codigo da Marca] na ASK **RM_3110**

;*******************************************************************************
;* Rotina p/ Selecionar Registros                                              *
;*******************************************************************************
Proc RM_3200_Seleciona()
ClearAll

;****** Vendas *****************************************************************

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        EndIf
        If VSDGMARCA<>""
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA.."
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        Moveto [Codigo                 ] Check TypeIn "~VSDGDESTINAT.."
        Moveto [Razao Social           ] Check
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter Check
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Numero do Documento    ] Example "ndoc"
        Moveto [Serie do Documento     ] Example "sdoc"
        If VSDGMARCA<>""
           Then Moveto [Codigo do Item ] Example "cite"
        EndIf   
        Moveto [Situacao_Item          ] TypeIn "Not C"
        Do_It!
        ClearAll

        RM_3200_Adiciona_Dados("VENDAS")
EndIf

;****** Devolucoes - Estoque ***************************************************
;If IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC") And
;   IsTable("\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI")
;   Then
;        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEC" Enter
;        Moveto [Numero do Lancamento   ] Example "nlan"
;        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA.."
;        Moveto [Codigo                 ] Check
;        Moveto [Razao Social           ] Check
;        Moveto [Codigo do Representante] Check TypeIn "~VSDGREPRESEN.."
;        Moveto [Nome Fantasia Represent] Check
;        Moveto [Data de Entrada        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
;        Moveto [Tipo de Operacao       ] TypeIn "D"
;        {Ask} TypeIn "\\Sistemas\\Estoque\\"+Dir_Trab+"NotaEI" Enter
;        Moveto [Numero do Lancamento   ] Example "nlan" Check
;        Do_It!
;        ClearAll
;
;        RM_3200_Adiciona_Dados("DEVOLUCOES")
;EndIf
;
;;****** Devolucoes - Vendas ****************************************************
;If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC") And
;   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI")
;   Then
;        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
;        Moveto [Codigo da Empresa      ] Check Example "cemp" TypeIn ", ~VSDGEMPRESA.."
;        Moveto [Numero do Documento    ] Example "ndoc"
;        Moveto [Serie do Documento     ] Example "sdoc"
;        Moveto [Codigo                 ] Check
;        Moveto [Razao Social           ] Check
;        Moveto [Codigo do Representante] Check TypeIn "~VSDGREPRESEN.."
;        Moveto [Nome Fantasia Represent] Check
;        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
;        Moveto [Descricao da Destinacao] TypeIn "..DEVOL.."
;        Moveto [Tipo Movimento Estoque ] TypeIn "E"
;        Moveto [Situacao               ] TypeIn "Not C"
;        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter Check
;        Moveto [Codigo da Empresa      ] Example "cemp"
;        Moveto [Numero do Documento    ] Example "ndoc"
;        Moveto [Serie do Documento     ] Example "sdoc"
;        Moveto [Situacao_Item          ] TypeIn "Not C"
;        Do_It!
;        ClearAll
;
;        RM_3200_Adiciona_Dados("DEVOLUCOES")
;EndIf

EndProc   ; (RM_3200_Seleciona)

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc RM_3200_Adiciona_Dados(Tipo)

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo                 ] Example "ccli"
Moveto [Razao Social           ] Example "ncli"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Unitario         ] Example "pruv"
Moveto [Preco Unitario Tabela  ] Example "prut"
Moveto [Valor Desconto Total   ] Example "vdes"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo                 ] Example "ccli"
Moveto [Razao Social           ] Example "ncli"
Moveto [Codigo do Representante] Example "crep"
Moveto [Nome Fantasia Represent] Example "nrep"
Switch
  Case Tipo="VENDAS":
       Moveto [Vendas_Preco Total       ] TypeIn "(_qtde*_pruv)-_vdes"
       Moveto [Vendas_Preco Total Tabela] TypeIn "_qtde*_prut"
  Case Tipo="DEVOLUCOES":
       Moveto [Devolucoes_Preco Total   ] TypeIn "_qtde*_pruv"
EndSwitch
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc RM_3200_Processa()

;***** Ajusta Dados ************************************
{Ask} {\\Sistemas\\Cadastro\\Empresas}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] Example "nemp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
Do_It!
ClearAll

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade        ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Embalagem         ] Check TypeIn "Calc Sum as VendasEmbalagem"
Moveto [Vendas_Preco Total       ] Check TypeIn "Calc Sum as VendasPreco"
Moveto [Vendas_Preco Total Tabela] Check TypeIn "Calc Sum as VendasTabela"
Moveto [Devolucoes_Quantidade    ] Check TypeIn "Calc Sum as DevolucoesQuantidade"
Moveto [Devolucoes_Preco Total   ] Check TypeIn "Calc Sum as DevolucoesPreco"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Vendas_Embalagem          ] TypeIn "<=0, changeto blank"
Moveto [Unidade Embalagem         ] TypeIn "changeto Blank"
Do_It!
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza Representante ***
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Codigo do Representante] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Representante] Example "crep"
Moveto [Total_Vendas_Represent ] TypeIn "changeto _vp"
Do_It!
ClearAll

EndProc    ;  (RM_3200_Processa)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_3200_Principal()

AGUARDE("Aguarde, gerando o relat¢rio")
Tabela=Cria_Temp(PrivDir())
Empty "\\Base\\Sistemas\\Vendas\\RM_3200"
Copy "\\Base\\Sistemas\\Vendas\\RM_3200" Tabela

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  RM_3200_Seleciona()
EndWhile

If not IsEmpty(Tabela)
   then RM_3200_Processa()

        If VSDGOPRELCODALF="1"
           Then IMPRIREL(Tabela,"R")
           Else IMPRIREL(Tabela,"1")
         EndIf
   else MENSAGEM("N„o existem registros a processar")
EndIf

If IsTable(Tabela)   Then Delete Tabela   EndIf
If IsTable("Answer") Then Delete "Answer" EndIf

EndProc

;-- Chamada principal ----------------------------------------------------------
RM_3200_Principal()

Release Vars Tabela
Release Procs RM_3200_Principal, RM_3200_Seleciona, RM_3200_Adiciona_Dados, RM_3200_Processa