;** Rm_0237  *******************************************************************
;*  Emissao dos Titulos a Receber por Repres/Cliente/Vencto+ Cheques Pendentes *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 24/03/2003 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 07/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Cheques em Cobranca
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 01/07/2010 por Bruno Carvalho
;Motivo Alteracao: Ajustes Cheques Trocados
;Ultima Alteracao: 22/03/2011 por Bruno Carvalho
;Motivo Alteracao: Ajustes de Layout
;Ultima Alteracao: 27/09/2012 por Kamila Gomes  
;Motivo Alteracao: Ajustes pesquisa de cheque por data de inclusao
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog modelo relatorio  
;Ultima Alteracao: 14/01/2021 por Bruno Carvalho
;Motivo Alteracao: Processo adaptado para fazer o fechames, no entanto a ask SELECIONA() nÆo estava se adequando a regra 
  
;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
   Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic" Enter Check
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
        Moveto [Data de Vencimento     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Saldo do Documento     ] TypeIn "> 0.01"
        Do_It!
        ClearAll
EndIf

EndProc

;*******************************************************************************
;* Rotina p/ processar Cheques a Descontar                                     *
;*******************************************************************************
Proc Cheque()
ClearAll

{Ask} {\\Sistemas\\CheqRec\\ChequeC} Check
Moveto [Numero do Lancamento   ] Example "NUM"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
Moveto [Codigo                 ] Example "cod"
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Data de Entrada     ] Check
Moveto [Data_Inclusao       ] Check
{Ask} {\\Sistemas\\CheqRec\\ChequeI} Check
Moveto [Numero do Lancamento] Example "NUM"
Moveto [Situacao            ] TypeIn "Not \"LIQUIDADO\", Not \"EM COBRANCA\", Not \"TROCADO..\""
Moveto [Data Vencimento     ] TypeIn ">=~VSDGDTINI ,<=~VSDGDTFIM"
Do_It!
ClearAll
If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                ] Example "codigo"
Moveto [Nome Fantasia EmitDest] Example "nome"
{Ask} {Answer} TypeIn "Fast"
Moveto [Codigo      ] Example "codigo"
Moveto [Razao Social] TypeIn "Changeto " Example "nome"
Do_It!
ClearAll

CoEdit Tabela,"Answer"
Moveto [Codigo]
Scan
  Moveto Tabela
  End
  Down
  [Codigo da Empresa     ] = [Answer->Codigo da Empresa    ]
  [Nome Fantasia Empresa ] = [Answer->Nome Fantasia Empresa]
  [Codigo do Destinatario] = [Answer->Codigo               ]
  If Len([Answer->Razao Social])>20
     Then [Nome Fantasia EmitDest] = SubStr([Answer->Razao Social],1,20)
     Else [Nome Fantasia EmitDest] = [Answer->Razao Social]
  EndIf
  [Data de Vencimento     ] = [Answer->Data Vencimento]
  [Data a Receber         ] = [Answer->Data Vencimento]
  [Tipo do Documento      ] = "CH"
  [Numero do Documento    ] = [Answer->Numero_Cheque  ]
  [Valor do Documento     ] = [Answer->Valor          ]
  [Saldo do Documento     ] = [Answer->Valor          ]
  [Valor do Desconto      ] = 0
  [Data de Emissao        ] = [Answer->Data_Inclusao  ]
  [Numero do Lancamento   ] = StrVal([Answer->Numero do Lancamento])
  [Codigo da Conta        ] = ""
  [Codigo do Representante] = [Answer->Codigo do Representante]
  [Nome Fantasia Represent] = [Answer->Nome Fantasia Represent]
  [Descricao do Lancamento] = ""
  [Tipo do Pagamento      ] = ""

  Moveto "Answer"

EndScan
Do_It!
ClearAll
EndProc ; (Cheque)

;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll
EndProc    ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_REPRESEN"      : Campo="TG_EMPRESATE"
            Case Campo="TG_DTINI"         : Campo="TG_REPRESEN"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_DDPROTESTO"    : Campo="TG_DTFIM"
            Case Campo="TG_SN_OPCHEQ"     : Campo="TG_DDPROTESTO"
            Case Campo="TG_CODMODELO"     : Campo="TG_SN_OPCHEQ"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"     : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"      : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"         : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"         : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO"    : Campo="TG_SN_OPCHEQ"
                    Case Campo="TG_SN_OPCHEQ"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"     : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
       MSG_CAMPO=""
  Case Campo="TG_DDPROTESTO":
       MSG_CAMPO="Informe o Numero de Dias"    
  Case Campo="TG_SN_OPCHEQ":
       MSG_CAMPO="Incluir cheques?"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Representante/Pessoa/Titulos")
ModeloRelatoriosAdd("01B Por Representante/Pessoa         - Sint‚tico")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()
VSDGEMPRESA   =""
VSDGDTINI  =BlankDate()
VSDGDTFIM  =BlankDate()
VSDGDDPROTESTO=""
VSDGREPRESEN=""

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos a Receber por Representante/Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 14 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP   
    
    Label  @ 02,00 "Representante"  For "TG_REPRESEN"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 04,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,16 "at‚" For "TG_DTFIM"
    Accept @ 05,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Op‡„o Cheque" For "TG_SN_OPCHEQ"
    Accept @ 03,36 Width 07 "A3"  Picture "SIM,NAO" Tag "TG_SN_OPCHEQ" To VSDGSIM_NAO

    Label  @ 07,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 08,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 08,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 10,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 10,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If VSDGSIM_NAO="SIM"
     Then Cheque()
  EndIf

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  PROCESSA()

  switch
    case VSDGCODMODELO="01"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230" "4" Tabela "R" 
    case VSDGCODMODELO="01B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230" "5" Tabela "R" 
  endswitch
  IMPRIREL(Tabela,"R")

  If IsTable("Answer")
     Then Delete "Answer"
  EndIf

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All
