;** RM_0600 ********************************************************************
;* Conferencia/Resumo de Vendas por Cartao                                     *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/06/2014 por Bruno Carvalho
;Ultima Alteracao: 23/06/2014 por Bruno Carvalho 
;Motivo Alteracao: Add filtro p/ op‡Æo de data 
;Ultima Alteracao: 24/06/2014 por Bruno Carvalho 
;Motivo Alteracao: Ajustes Sistema_Gerador 
;Ultima Alteracao: 16/07/2014 por Bruno Carvalho 
;Motivo Alteracao: Adicionado filtro por Tipo de CartÆo (Cr‚dito ou D‚bito)  
;Ultima Alteracao: 23/07/2014 por Bruno Carvalho 
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 25/09/2014 por Kamila Gomes
;Motivo Alteracao: Ajustes ask sistema gerador GD gera‡Æo de duplicatas
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 11/07/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes CL=CartÆo Parcelado
;Ultima Alteracao: 25/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes logica     
;Ultima Alteracao: 03/11/2017 por Kamila Gomes
;Motivo Alteracao: Ajustes moveto Tabela no else do Processa()                  
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 25/11/2020 por Nikolas
;Motivo Alteracao: destina‡Æo com SAIDA tamb‚m puxar era s¢ com VEND
;Ultima Alteracao: 25/11/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes rodape cartao e destina‡äes
;Ultima Alteracao: 14/01/2021 por Bruno Carvalho 
;Motivo Alteracao: Separado Seleciona() p/ Seleciona_CtaRec() e Seleciona_Vendas() *Consulta Mˆs Fechado em seus diret¢rios 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros 2                                 *
;*******************************************************************************
Proc Seleciona_CtaRec()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic") 
   Then 
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic" Enter
        Moveto [Numero do Lancamento   ] Check 
        Moveto [Codigo da Empresa      ] Check TypeIn "_CodE, ~VSDGEMPRESA.."
        Moveto [Codigo do Destinatario ] Check 
        Moveto [Nome Fantasia EmitDest ] Check
        Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Valor do Documento     ] Check 
        Switch
          Case VSDGTPCART2 = "1" : Moveto [Tipo do Pagamento] Check TypeIn "CD"
          Case VSDGTPCART2 = "2" : Moveto [Tipo do Pagamento] Check TypeIn "CT"
          Case VSDGTPCART2 = "3" : Moveto [Tipo do Pagamento] Check TypeIn "CL"
          otherwise              : Moveto [Tipo do Pagamento] Check TypeIn "CT or CD or CL"
        EndSwitch
        Moveto [Sistema Gerador        ] Check 
        Moveto [Tipo Docto Gerador     ] Check
        Moveto [Numero Docto Gerador   ] Check  
        Moveto [Sequencia Gerador      ] Check
        Do_It!
        ClearAll

        Adiciona_Dados("Duplicatas")
endif

EndProc ;Selecion_CtaRec()

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona_Vendas()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"Notac") And 
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"Notav")
   Then 
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"Notac" Enter
        Moveto [Codigo da Empresa      ] Check Example "CodE" TypeIn ", ~VSDGEMPRESA.."         
        Moveto [Numero do Documento    ] Check Example "NDoc"
        Moveto [Serie do Documento     ] Check Example "SDoc"
        Moveto [Nome Fantasia Empresa  ] Check
        Moveto [Codigo do Documento    ] Check
        Moveto [Tipo do Documento      ] Check
        Moveto [Data de Emissao        ] Check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        Moveto [Codigo                 ] Check
        Moveto [Nome Fantasia EmitDest ] Check
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"Notav" Enter
        Moveto [Codigo da Empresa      ] Example "CodE"
        Moveto [Numero do Documento    ] Example "NDoc"
        Moveto [Serie do Documento     ] Example "SDoc"
        Moveto [Sequencia              ] Check
        Moveto [Data                   ] Check 
        Moveto [Valor                  ] Check 
        Switch
          Case VSDGTPCART2 = "1" : Moveto [Forma de Pagamento] Check TypeIn "CD"
          Case VSDGTPCART2 = "2" : Moveto [Forma de Pagamento] Check TypeIn "CT"
          Case VSDGTPCART2 = "3" : Moveto [Forma de Pagamento] Check TypeIn "CL"
          otherwise              : Moveto [Forma de Pagamento] Check TypeIn "CT or CD or CL"
        EndSwitch
        Moveto [Nome do Cartao         ] Check TypeIn "~VSDGNOMECARTAO.."
        Do_It!
        ClearAll

        Adiciona_Dados("Notas")
endif

EndProc ;Seleciona_Vendas()

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Adiciona_Dados(PARAM)
Private PARAM

if isempty("Answer")
   then return
endif    

Switch
  Case PARAM = "Notas" :  
       {Ask} {Answer}
       Moveto [Codigo da Empresa      ] Example "CodE"  
       Moveto [Numero do Documento    ] Example "NDoc"  
       Moveto [Serie do Documento     ] Example "SDoc"
       Moveto [Codigo do Documento    ] Example "CDoc"       
       Moveto [Tipo do Documento      ] Example "TDoc"       
       Moveto [Sequencia              ] Example "Seq" 
       Moveto [Nome Fantasia Empresa  ] Example "Nfan"
       Moveto [Data de Emissao        ] Example "DtE"
       Moveto [Codigo                 ] Example "Cod" 
       Moveto [Nome Fantasia EmitDest ] Example "NFE" 
       Moveto [Data                   ] Example "DatV" 
       Moveto [Valor                  ] Example "VrV" 
       Moveto [Forma de Pagamento     ] Example "FP"  
       Moveto [Nome do Cartao         ] Example "NC" 
       
       {Ask} TypeIn Tabela Enter TypeIn "Fast Insert" Enter
       Moveto [Codigo da Empresa      ] Example "CodE"  
       Moveto [Numero do Documento    ] Example "NDoc"  
       Moveto [Serie do Documento     ] Example "SDoc"
       Moveto [Codigo do Documento    ] Example "CDoc"       
       Moveto [Tipo do Documento      ] Example "TDoc"       
       Moveto [Sequencia              ] Example "Seq" 
       Moveto [Nome Fantasia Empresa  ] Example "Nfan"
       Moveto [Data de Emissao        ] Example "DtE"
       Moveto [Codigo                 ] Example "Cod" 
       Moveto [Nome Fantasia EmitDest ] Example "NFE"
       Moveto [Data NotaV             ] Example "DatV" 
       Moveto [Valor NotaV            ] Example "VrV" 
       Moveto [Forma de Pagamento     ] Example "FP"  
       Moveto [Nome do Cartao         ] Example "NC" 
       Do_It!
       ClearAll

  Case PARAM = "Duplicatas" :  
       If IsTable(TabelaRD)
          Then Add "Answer" TabelaRD
          Else Rename "Answer" TabelaRD
       EndIf
EndSwitch


EndProc ;Adiciona_Dados()


;*******************************************************************************
;* Rotina p/ processar                                                         *
;*******************************************************************************
Proc Processa()

If IsEmpty(TabelaRD)
   Then return
endif   

Adiciona_Indice(TabelaRD,"Codigo da Empresa,Tipo Docto Gerador,Numero Docto Gerador,Sequencia Gerador,Numero do Lancamento")

NR=NRecords(Tabela)

View "\\Sistemas\\Vendas\\P_Cartao"
View TabelaRD            ; Ctarec
Coedit Tabela            ; NotaV
Scan
 copytoarray regrn

 Barra(NR, RecNo())
 Aguarde("Aguarde, Verificando Notas no Contas a Receber "+BARRA_STRING)                  

 GetRecord "\\Sistemas\\Vendas\\P_Cartao" regrn["Codigo da Empresa"],regrn["Nome do Cartao"] To regp_cartao
 If ReTval
    Then CODIGO_CARTAO = regp_cartao["Codigo Destinat"]
    Else CODIGO_CARTAO = ""
 EndIf   

 switch
   Case [Forma de Pagamento]="CD" : [TipoCartao]="DEBITO"
   Case [Forma de Pagamento]="CT" : [TipoCartao]="CREDITO"
   Case [Forma de Pagamento]="CL" : [TipoCartao]="CREDITO PARCELADO"
 endswitch

 moveto TabelaRD
 moveto [Codigo da Empresa]
 locate regrn["Codigo da Empresa"],regrn["Codigo do Documento"],regrn["Numero do Documento"],regrn["Sequencia"]
 if retval
    then
         copytoarray regrr
    
         Moveto Tabela
         [Lancto Contas a Receber] = regrr["Numero do Lancamento"   ]
         [Data de Emissao        ] = regrr["Data de Emissao"        ]
         [Valor Contas a Receber ] = regrr["Valor do Documento"     ]
         [Codigo do Cartao       ] = regrr["Codigo do Destinatario" ] 
         [Diferenca              ] = regrn["Valor NotaV"] - regrr["Valor do Documento"]
         [Diferenca Porcent      ] = 100 - ((regrr["Valor do Documento"]*100) / regrn["Valor NotaV"])
         [Sistema Gerador        ] = regrr["Sistema Gerador"       ]
         [Tipo Docto Gerador     ] = regrr["Tipo Docto Gerador"    ]
         [Numero Docto Gerador   ] = regrr["Numero Docto Gerador"  ]
         [Sequencia Gerador      ] = regrr["Sequencia Gerador"     ]
    
         msg=""
         if regrr["Tipo do Pagamento"      ]<>regrn["Forma de Pagamento"]
            then msg=msg+"FP,"
         endif
         if regrr["Codigo do Destinatario" ]<>CODIGO_CARTAO
            then msg=msg+"Pessoa,"
         endif
         
         if format("W12.2,EIC",[Valor NotaV])=format("W12.2,EIC",[Valor Contas a Receber])
            then msg=msg+"Valor"
         endif
         
         if msg<>"" 
            then
                 [Erro]="X"
            
                 if VSDGCODMODElo="03"
                    then [Codigo                 ]="Erro"         
                         [Nome Fantasia EmitDest ]=msg
                 endif        
         endif        
         UnLockRecord

    else 
         Moveto Tabela 
         [Erro]="X"
 EndIf

 Moveto Tabela
EndScan
Do_It!
ClearAll

Delete TabelaRD

switch
  case VSDGCODMODElo="03":
    {Ask} TypeIn Tabela Enter TypeIN "Fast Delete"
    Moveto [Erro] TyPeIn "Blank"
    Do_It!
    ClearAll
    
  case VSDGCODMODElo="04":
    Agrupa()
    
endswitch

EndProc ;Processa()

;*******************************************************************************
;* Rotina p/ processar                                                         *
;*******************************************************************************
Proc Agrupa()

{Ask} TypeIn Tabela Enter Check
Moveto [Erro] TyPeIn "X"
Do_It!
ClearAll

If Not IsEmpty("Answer")
   Then MSG_1 = "** H  lan‡amentos de vendas nÆo localizados no contas a receber,"
        MSG_2 = "   escolha a op‡Æo analitica com erros para mais detalhes."
   Else MSG_1 = ""
        MSG_2 = ""
EndIf
  
{Ask} TypeIn Tabela Enter TypeIN "Fast"
Moveto [Diferenca Porcent      ] TyPeIn "changeto Blank"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Nome do Cartao         ] Check
Moveto [Valor NotaV            ] TypeIn "Calc Sum as Valor NotaV" 
Moveto [Valor Contas a Receber ] TypeIn "Calc Sum as Valor Contas a Receber" 
Moveto [Diferenca              ] TypeIn "Calc Sum as Diferenca"
Do_It!
ClearAll  

Empty Tabela

{Ask} {Answer}
Moveto [Nome do Cartao         ] Example "NomC"
Moveto [Valor NotaV            ] Example "VrNV"
Moveto [Valor Contas a Receber ] Example "VrCR"
Moveto [Diferenca              ] Example "Dif"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert" Enter
Moveto [Nome do Cartao         ] Example "NomC"
Moveto [Valor NotaV            ] Example "VrNV"
Moveto [Valor Contas a Receber ] Example "VrCR"
Moveto [Diferenca              ] Example "Dif"
Do_It!
ClearAll  

Edit Tabela
scan
  [Diferenca Porcent      ] = 100 - (([Valor Contas a Receber]*100) / [Valor NotaV])
endscan
Do_it!
Clearall

EndProc ;Agrupa()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)

Temp      = True
TECLA     = ""
MSG_CAMPO = ""

If Disparo="OPEN"  Then AoCriarShowDialog() EndIf

If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: 
          Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_TPCART2"       : Campo="TG_EMPRESA"
            Case Campo="TG_NOMECARTAO"    : Campo="TG_TPCART2"
            Case Campo="TG_DTINI"         : Campo="TG_NOMECARTAO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_TPCART2"
                    Case Campo="TG_TPCART2"    : Campo="TG_NOMECARTAO"
                         VSDGTPCART2 = ControlValue("TG_TPCART2")
                         Switch
                           Case VSDGTPCART2 = "1" : VSDGNOMTPCART = "DEBITO"
                           Case VSDGTPCART2 = "2" : VSDGNOMTPCART = "CREDITO"
                           Case VSDGTPCART2 = "3" : VSDGNOMTPCART = "CREDITO PARCELADO"
                           OtherWise              : VSDGNOMTPCART = "TODOS"
                         EndSwitch
                    Case Campo="TG_NOMECARTAO" : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Switch
  Case Campo="TG_TPCART2" : MSG_CAMPO="Em Branco=Todos, 1=D‚bito  2=Cr‚dito  3=Cr‚dito Parcelado"
  Case Campo="TG_CARTAO"  : MSG_CAMPO="Informe o Nome do Cart„o"
  Case Campo=""           : MSG_CAMPO=""
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Anal¡tico Tipo Documento/Data EmissÆo")
ModeloRelatoriosAdd("02  Anal¡tico Tipo Documento/Forma Pagto/Tipo CartÆo")
ModeloRelatoriosAdd("03  Anal¡tico com erros")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("04  Sintetico")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista


;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA    = ""
VSDGDESTINAT   = ""
VSDGNOMECARTAO = ""
VSDGDTINI      = BlankDate()
VSDGDTFIM      = BlankDate()
VSDGTPCART2    = ""
VSDGNOMTPCART  = ""

ModeloRelatoriosCarregaLista()

While True  
  ShowDialog "Resumo de Vendas por CartÆo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
	  @ 05,12	 Height 16 Width 72
	 
    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Tipo de Cart„o" For "TG_TPCART2"
    Accept @ 03,04 Width 04 "A1"  Picture "1,2,3" Tag "TG_TPCART2" To VSDGTPCART2
    Accept @ 03,09 Width 25 "A20"  Picture "!*!" Tag "TG_NOMTPCART" To VSDGNOMTPCART

    Label  @ 04,00 "Cartao"  For "TG_NOMECARTAO"
    Accept @ 05,01 Width 33 "A15"  Picture "!*!" Tag "TG_NOMECARTAO" To VSDGNOMECARTAO

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 09,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 10,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 10,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

		Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
		Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM = BlankDate()
     Then Mensagem("Data Final Inv lida !")
          Loop
  EndIf       

  DISPOSITIVO()
  If OK="" Then Loop EndIf
  
  AGUARDE("Aguarde, Processando Dados")
  Tabela = Cria_Temp(PrivDir())
  Copy "\\Base\\Sistemas\\Ctarec\\Rm_0600" Tabela

  TabelaRD=Cria_Temp(PrivDir())
  
  ;---- Contasa a Receber ------------------------------------------------------
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona_CtaRec()
  EndWhile
  
  ;---- Vendas ------------------------------------------------------------------
  SetDir "\\Sistemas\\Vendas"
  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    Seleciona_Vendas()
  EndWhile
  SetDir "\\Sistemas\\CtaRec"

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
     Else Processa()
          switch
            case VSDGCODMODElo="01" : IMPRIREL(Tabela,"R")
            case VSDGCODMODElo="02" : IMPRIREL(Tabela,"2")
            case VSDGCODMODElo="03" : IMPRIREL(Tabela,"R")
            case VSDGCODMODElo="04" : IMPRIREL(Tabela,"1")
          endswitch
  EndIf

  Delete Tabela
  if istable(TabelaRD) then Delete TabelaRD endif
  
EndWhile
ClearAll
Release Vars All
Release Procs All
