;** PC_0000 *******************************************************************
;*  ShowDialog parametros para gera‡Æo de comissao no contas a pagar          *
;******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 28/02/2019 por Anivel Augusto Rodrigues
;Ultima Alteracao: 16/03/2019 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes Numero_Lancamento("Interno","Locked_Down")
;Ultima Alteracao: 12/04/2019 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes liberacao #0388
;Ultima Alteracao: 30/04/2019 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes liberacao #0427
;Ultima Alteracao: 13/05/2019 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes liberacao #0390
;Ultima Alteracao: 04/06/2019 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes liberacao #0418
;Ultima Alteracao: 22/11/2019 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes Sistema Gerador
;Ultima Alteracao: 11/05/2020 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes liberacao #0391
;Ultima Alteracao: 11/05/2020 por Anivel Augusto Rodrigues                           
;Motivo Alteracao: Ajustes liberacao #0373

;*******************************************************************************
;* Exportacao p/ Contas a Pagar                                                *
;*******************************************************************************
Proc PC_0000_Atualiza_CTAPG()
private CP_LANC, PROXLANCTO_NLANC, regrepresen, regdestinat, mesanoref, NR, tabcomis, regtabcomis, tabcomisok

mesanoref=alinhm(strval(month(VSDGDTCOMPET)),2)+"/"+substr(alinhM(strval(year(VSDGDTCOMPET)),4),3,2)

if VSDGOPCOES=1
   then tabcomis=PC_0000_TabelaComissaoBruta 
   Else tabcomis=PC_0000_TabelaComissaoLiquida
endif
NR = NRecords(tabcomis)


View "\\Sistemas\\Cadastro\\Destinat"
View "\\Sistemas\\Cadastro\\Represen"
View "\\Sistemas\\CtaPag\\Titulos"
Coedit tabcomis


;checagem de erros !!
tabcomisok=true
Scan
  copytoarray regtabcomis

  getrecord "\\Sistemas\\Cadastro\\Represen" regtabcomis["Codigo do Representante"] to regrepresen
  if not retval
     then Mensagem("Representante ["+regtabcomis["Codigo do Representante"]+"] nÆo cadastrado !// //"+
                   "Verificar Cadastro de Representantes")
          tabcomisok=false         
          loop     
  endif   

  getrecord "\\Sistemas\\Cadastro\\Destinat" regrepresen["Codigo_Pessoa"] to regdestinat 
  if not retval
     then Mensagem("Pessoa do Representante ["+regrepresen["Codigo_Pessoa"]+"] nÆo cadastrada !// //"+
                   "Verificar Representante ["+regtabcomis["Codigo do Representante"]+"]")
          tabcomisok=false         
          loop     
  endif   

endscan

; gerando registros
if not tabcomisok
   then
        Mensagem("Erros foram detectados !// //Lan‡amentos nÆo foram gerados !// // Verificar Cadastros !")
   else
        Scan
          copytoarray regtabcomis
                                 
          Barra(NR, RecNo())
          Aguarde("Aguarde, gerando lan‡amentos "+regtabcomis["Codigo do Representante"]+" "+BARRA_STRING)
        
          if [ValorComissao]<=0 then loop endif
        
          getrecord "\\Sistemas\\Cadastro\\Represen" regtabcomis["Codigo do Representante"] to regrepresen
          if not retval
             then loop     
          endif   
        
          moveto "\\Sistemas\\CtaPag\\Titulos"
          While True
            End
            Moveto [Numero do Lancamento]
            If Numero_Lancamento("Interno","Locked_Down")
               Then CP_LANC = PROXLANCTO_NLANC
                    Release Vars PROXLANCTO_NLANC
                    quitloop
            EndIf    
          EndWhile
          
          [Codigo da Conta         ]=VSDGCONTA
          [Codigo da Empresa       ]=VSDGEMPRESA
          [Codigo do Documento     ]="REC"
          [Numero do Documento     ]=regtabcomis["Codigo do Representante"]+" "+mesanoref
          [Documento Referente     ]="COM "+regtabcomis["Codigo do Representante"]+" "+mesanoref
        
          [Codigo do Emitente      ]=regrepresen["Codigo_Pessoa"]
          [Data de Emissao         ]=today()            
          [Data de Entrada         ]=today()            
          [Data de Vencimento      ]=VSDGDTVENCTO    
          [Data a Pagar            ]=VSDGDTVENCTO
          [Data Competencia        ]=VSDGDTCOMPET     
          [Valor do Documento      ]=regtabcomis["ValorComissao"]
          [Saldo do Documento      ]=regtabcomis["ValorComissao"]
          [Observacoes             ]="COMISSAO APURADA REF. "+mesanoref+" DIRETO DE RELATàRIO"
          [Tipo do Lancamento      ]=VSDGTPLANC     
          [Tipo do Pagamento       ]=VSDGTPPAGTO
          [Codigo Plano_Conta      ]=VSDGPLCONTAS  
          [Sistema Gerador         ]="FT"
          Controle_Dia()
          UnLockRecord
        
          moveto tabcomis
        endscan
        
        Mensagem("Fim do processo !// // Conferir lan‡amentos no Contas a Pagar")

endif
Do_It!
Clearall

LimpAguarde()
endproc


;*******************************************************************************
;* Rotina gravar/ler configura‡äes/parametros                                  *
;*******************************************************************************
Proc PC_0000_ConfigOpcoesPC(operacao)
private operacao,arquivo,arqini,arqsc

arqini=PC_0000_AquivoDeParametrosGeraComissao+".ini"
arqsc =PC_0000_AquivoDeParametrosGeraComissao+".sc"

Switch
  Case operacao="Ler":

    VSDGCONTA       =""
    VSDGTPLANC      =""
    VSDGTPPAGTO     =""
    VSDGPLCONTAS    =""
    VSDGDTCOMPET    = blankdate()
    VSDGDTVENCTO    = blankdate()
    VSDGOPCOES      =1

    If IsFile(arqini)
       Then
             FileRead           arqini To   vartemp
            FileWrite Privdir()+arqsc  From vartemp
                 Play Privdir()+PC_0000_AquivoDeParametrosGeraComissao
            Deleta_Arquivo(Privdir()+arqsc)
            Deleta_Arquivo(Privdir()+PC_0000_AquivoDeParametrosGeraComissao+".sc2")
    EndIf
       
  Case operacao="Gravar":
       FileWrite        arqini From ";****** Variaveis de Parƒmetros PC_0000 Vise Informatica"+"\n"
       FileWrite Append arqini From "VSDGCONTA=\""   +VSDGCONTA+"\""     +"\n"
       FileWrite Append arqini From "VSDGTPLANC=\""  +VSDGTPLANC+"\""    +"\n"
       FileWrite Append arqini From "VSDGTPPAGTO=\"" +VSDGTPPAGTO+"\""   +"\n"
       FileWrite Append arqini From "VSDGPLCONTAS=\"" +VSDGPLCONTAS+"\"" +"\n"
       FileWrite Append arqini From "VSDGPLCONTAS=\"" +VSDGPLCONTAS+"\"" +"\n"
       FileWrite Append arqini From "VSDGOPCOES="     +strval(VSDGOPCOES)+"\n"
       
EndSwitch

endproc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc PC_0000_SD_Dialog(Disparo,Campo,Evento,Elemento)
private Disparo,Campo,Evento,Elemento

Temp=True
TECLA=""
MSG_CAMPO=""
If Disparo="OPEN"  
   Then 
        AoCriarShowDialog()

        Campo="TG_CONTA"        Checa_TAG()
        Campo="TG_TPLANC"       Checa_TAG()
        Campo="TG_TPPAGTO"      Checa_TAG()
        Campo="TG_PLCONTAS"     Checa_TAG()

        Campo="TG_CONTA"
         
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_CONTA"         : Campo="NO"
            Case Campo="TG_TPLANC"        : Campo="TG_CONTA"
            Case Campo="TG_TPPAGTO"       : Campo="TG_TPLANC"
            Case Campo="TG_PLCONTAS"      : Campo="TG_TPPAGTO"
            Case Campo="TG_DTCOMPET"      : Campo="TG_PLCONTAS"
            Case Campo="TG_DTVENCTO"      : Campo="TG_DTCOMPET"
            Case Campo="TG_OPCOES"        : Campo="TG_DTVENCTO"
            Case Campo="YES" Or Campo="NO": Campo="TG_CONTA"
          EndSwitch
    Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13: 
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_CONTA"        : Campo="TG_TPLANC"
                    Case Campo="TG_TPLANC"       : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"      : Campo="TG_PLCONTAS"
                    Case Campo="TG_PLCONTAS"     : Campo="TG_DTCOMPET"
                    Case Campo="TG_DTCOMPET"     : Campo="TG_DTVENCTO"
                    Case Campo="TG_DTVENCTO"     : Campo="TG_OPCOES"
                    Case Campo="TG_OPCOES"       : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPOES": MensagemRadioButtons()
  Case Campo=""        : MSG_CAMPO=""
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
Proc PC_0000_Principal()
private rotinaok

LimpAguarde()

;fazer verifica‡Æo de clientes, liber rotina mediante pagamento de valor, ver com An¡vel
;verificar rotina que gera os dados, padronizar e personalizar conforme necessario
;orientar cliente do funcionamento desta rotina 

rotinaok=false
switch
  case sys_Codigo_Cliente="0391" and PC_0000_AquivoDeParametrosGeraComissao="PC_0621"  : rotinaok=true 
  case sys_Codigo_Cliente="0391" and PC_0000_AquivoDeParametrosGeraComissao="PC_0065B" : rotinaok=true

  case sys_Codigo_Cliente="0388" and PC_0000_AquivoDeParametrosGeraComissao="PC_0623"  : rotinaok=true 
  case sys_Codigo_Cliente="0427" and PC_0000_AquivoDeParametrosGeraComissao="PC_0623"  : rotinaok=true 
  case sys_Codigo_Cliente="0390" and PC_0000_AquivoDeParametrosGeraComissao="PC_0623"  : rotinaok=true 
  case sys_Codigo_Cliente="0418" and PC_0000_AquivoDeParametrosGeraComissao="PC_0623"  : rotinaok=true
  case sys_Codigo_Cliente="0373" and PC_0000_AquivoDeParametrosGeraComissao="PC_0623"  : rotinaok=true
   
;;case                               PC_0000_AquivoDeParametrosGeraComissao="PC_0068"  : rotinaok=true 
  
endswitch

if not rotinaok
   then
        Mensagem("Gerar lan‡amentos das comissäes no Contas a Pagar// //"+
                 "Rotina nÆo configurada e personalizada para o cliente !!// //"+
                 " Verificar com Suporte da Vise !")
        return
endif   

PC_0000_ConfigOpcoesPC("Ler")

While True
  ShowDialog "Gerar lan‡amentos das comissäes no Contas a Pagar" Proc "PC_0000_SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 16 Width 72

    Label  @ 00,00 "Empresa"     For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP
    
    Label  @ 02,00 "Conta * "  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA"    To VSDGCONTA
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCONTA" To VSDGNOMCONTA

    Label  @ 04,00 "Tipo de Lan‡amento * "  For "TG_TPLANC"
    Accept @ 05,04 Width 04 "A1"  Picture "!*!" Tag "TG_TPLANC" To VSDGTPLANC
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMLANC"  To VSDGNOMLANC

    Label  @ 06,00 "Forma de Pagamento * "  For "TG_TPPAGTO"
    Accept @ 07,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 08,00 "Plano de Contas" For "TG_PLCONTAS"
    Accept @ 09,01 Width 33 "A13"  Picture "!*!" Tag "TG_PLCONTAS" To VSDGPLCONTAS
    Accept @ 10,01 Width 33 "A40" Picture "!*!" Tag "TG_NOMPLCONTAS"  To VSDGNOMPLCONTAS
    
    Label  @ 00,35 "Data de Competˆncia * " For "TG_DTCOMPET"
    Accept @ 01,36 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTCOMPET" To VSDGDTCOMPET

    Label  @ 02,35 "Data de Vencimento * " For "TG_DTVENCTO"
    Accept @ 03,36 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTVENCTO" To VSDGDTVENCTO

    Label  @ 05,35 "Op‡”es de valores" For "TG_OPCOES"
    RadioButtons @ 06,35 Height 4 Width 34
      "Valor da ComissÆo ~B~ruto  ",
      "Valor da ComissÆo ~L~¡quida"
        Tag "TG_OPCOES"
        To VSDGOPCOES

    Pushbutton @ 12,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 12,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf

  If isblank(VSDGEMPRESA)     or
     isblank(VSDGCONTA)       or
     isblank(VSDGTPPAGTO)     or
     isblank(VSDGTPLANC)      or
     VSDGDTCOMPET=BlankDate() or
     VSDGDTVENCTO=BlankDate()
     Then FastMsg("Verificar campos obrigat¢rios (*) !")
          Loop
  EndIf

  if VSDGOPCOES=1
     then if isempty(PC_0000_TabelaComissaoBruta)   then Mensagem("NÆo h  comissÆo a pagar !") loop endif
     Else if isempty(PC_0000_TabelaComissaoLiquida) then Mensagem("NÆo h  comissÆo a pagar !") loop endif
  endif

  PC_0000_ConfigOpcoesPC("Gravar")

  AGUARDE("Aguarde, Gerando Dados")

  PC_0000_Atualiza_CTAPG()
  
  QuitLoop
  
EndWhile
ClearAll

if istable(PC_0000_TabelaComissaoBruta)   then delete PC_0000_TabelaComissaoBruta   endif
if istable(PC_0000_TabelaComissaoLiquida) then delete PC_0000_TabelaComissaoLiquida endif

endproc

;*******************************************************************************
;*                                                                             *
;*******************************************************************************

PC_0000_Principal()

Release Vars VSDGCONTA, VSDGTPLANC, VSDGTPPAGTO, VSDGPLCONTAS, VSDGDTCOMPET, VSDGDTVENCTO, VSDGOPCOES,
             PC_0000_AquivoDeParametrosGeraComissao,
             PC_0000_TabelaComissaoBruta, PC_0000_TabelaComissaoLiquida

Release Procs PC_0000_Atualiza_CTAPG, PC_0000_ConfigOpcoesPC , PC_0000_SD_Dialog, PC_0000_Principal
