;** Rm_0200 ********************************************************************
;*  Emissao dos Titulos Baixados por Data de Operacao                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 10/12/2001 por Anivel Augusto Rodrigues
;Ultima Alteracao: 31/05/2006 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_NCARREG
;Ultima Alteracao: 21/05/2008 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Tipo de Baixa
;Ultima Alteracao: 27/05/2015 por Andrey Fillipe
;Motivo Alteracao: Adicionado para pegar Mes Fechado
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog  
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT
;Ultima Alteracao: 31/12/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ chamar filtro padrao *RM_0200*                 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc RM_0200A_Seleciona()
ClearAll

{Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
Moveto [Numero do Lancamento   ] Example "lanc"
Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA.."
Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
Moveto [Codigo do Destinatario ] Example "dest" TypeIn ", ~VSDGDESTINAT.."
{Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
Moveto [Numero do Lancamento   ] Example "lanc"
Switch
   Case VSDGOPDT="1" :
        Moveto [Data do Pagamento] TypeIn ">=~VSDGDTINI ,<=~VSDGDTFIM"
   Case VSDGOPDT="2" :
        Moveto [Data_Inclusao    ] TypeIn ">=~VSDGDTINI ,<=~VSDGDTFIM"        
EndSwitch
Moveto [Codigo da Conta        ] TypeIn "~VSDGCONTA.."
Moveto [Codigo_Usuario         ] TypeIn "~VSDGCHAPA.."
Moveto [Tipo da Baixa          ] TypeIn "~VSDGTPBAIXA.."
Moveto [Numero_Controle_Dia    ] TypeIn "~VSDGNCONTROLE.."

{Ask} {\\sistemas\\cadastro\\Destinat}
Moveto [Codigo                 ] Example "dest"
Moveto [Codigo da Area         ] Check
If Not IsBlank (VSDGAREA)
   Then TypeIn "~VSDGAREA.."
EndIf
Moveto [Descricao da Area      ] Check
Do_It!
ClearAll

EndProc   ; (RM_0200A_Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc RM_0200A_Processa()
Coedit Tabela
Scan
  [Valor do Desconto-1]=([Valor do Desconto-1]*-1)+[Valor do Juros]
  If IsBlank([Valor do Desconto-1]) Then [Valor do Desconto-1]=0 EndIf
EndScan
Do_It!
ClearAll
EndProc   ; (RM_0200A_Processa)

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AGUARDE("Aguarde, gerando o relatĒrio")
While True
  AGUARDE("Aguarde, processando dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer") Then Delete "Answer" EndIf
    RM_0200A_Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile  

  If IsEmpty(Tabela)
     Then MENSAGEM("No existem registros a processar")
          Delete Tabela
          QuitLoop
  EndIf
  RM_0200A_Processa()

  If Not IsBlank(VSDGNCARREG)
     Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010" "1" Tabela "R"
     Else If VSDGOPDT="1" 
             Then CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "2" Tabela "R"
             Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "1" Tabela "R"
          EndIf
  EndIf
  IMPRIREL(Tabela,"R")

  Delete Tabela
  QuitLoop
EndWhile
ClearAll

Release Vars RM_0200A_Seleciona,RM_0200A_Processa