;** Rm_0330  *******************************************************************
;*  Emissao dos Titulos por Emitente/EmissÆo                                   *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 08/10/2009 por Cleber
;Ultima Alteracao: 30/07/2012 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes titulo
;Ultima Alteracao: 08/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 27/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT 
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog modelo relatorio
;Ultima Alteracao: 13/01/2021 por Bruno Carvalho                        
;Motivo Alteracao: Ajustes p/ chamar filtro padrao *RM_0330*  

;*******************************************************************************
;* Rotina p/ Selecionar e Ordenar Registros                                    *
;*******************************************************************************
Proc RM_0330A_Seleciona()
ClearAll

If IsTable("\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos")
  Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
       Moveto [Codigo            ] example "cemit"
       Moveto [Codigo Atividade  ] TypeIn "~VSDGATIVIDADE.."
       {Ask} TypeIn "\\Sistemas\\Ctapag\\"+Dir_Trab+"Titulos" Enter Check
       Moveto [Codigo da Empresa ] TypeIn "~VSDGEMPRESA2.."
       Moveto [Codigo do Emitente] example "cemit" TypeIn ", ~VSDGDESTINAT.."
       Switch
         Case VSDGOPDATA="1" : Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM "
         Case VSDGOPDATA="2" : Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM "
         Case VSDGOPDATA="3" : Moveto [Data Competencia  ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM "
       EndSwitch   
       Moveto [Codigo da Conta   ] TypeIn "~VSDGCONTA.."
       Moveto [Codigo Plano_Conta] TypeIn PLCONTAS
       If CheckTG_OPCCUSTO[1]
          Then Moveto [Codigo CCusto          ] TypeIn "Not Blank, ~VSDGCCUSTO.."
          Else Moveto [Codigo CCusto          ] TypeIn "~VSDGCCUSTO.."
       Endif
       Do_It!
       ClearAll
EndIf

EndProc  ; (RM_0330A_Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc RM_0330A_Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf
   
Coedit Tabela
Scan

   If IsBlank([Data a Pagar])
      Then [Data a Pagar]= Today()
   Else If [Data a Pagar]<Today()
      Then NDA=Today()-[Data a Pagar]
           TXM=[Multa]
      Else NDA=0
           TXM=0
   EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)
   [Data de Vencimento]=[Data a Pagar]

EndScan
Do_It!                                                             
ClearAll
EndProc  

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RM_0330A_Principal()

AGUARDE("Aguarde, Gerando o Relat¢rio")
Tabela=Cria_Temp(PrivDir())

Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
While Novo_Dir_Trab()
  If IsTable("Answer")     Then Delete "Answer" EndIf
  RM_0330A_Seleciona()
  If Not IsTable("Answer") Then Loop EndIf
  If IsTable(Tabela)
     Then Add "Answer" Tabela
     Else Rename "Answer" Tabela
  EndIf
EndWhile

If IsEmpty(Tabela)
   Then MENSAGEM("N„o existem registros a processar")
        Delete Tabela
        Return
EndIf
RM_0330A_Processa()

switch
  case VSDGCODMODELO="26A" : CopyReport "\\Base\\Sistemas\\CtaPag\\RM_1001" "5"   Tabela "R"
  case VSDGCODMODELO="26B" : CopyReport "\\Base\\Sistemas\\CtaPag\\RM_1010" "12"  Tabela "R"
endswitch
IMPRIREL(Tabela,"R")

Delete Tabela

EndProc

;-- Chamada principal ----------------------------------------------------------
RM_0330A_Principal()

Release Vars Tabela
Release Procs RM_0330A_Principal,RM_0330A_Seleciona,RM_0330A_Processa