;** Rm_0210 ********************************************************************
;*  Emissao das producoes                                                      *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 24/02/2015 por Anivel Augusto Rodrigues
;Ultima Alteracao: 26/03/2015 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtrar op‡Æo destinatario e destinatario
;Ultima Alteracao: 26/10/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 14/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                
;Ultima Alteracao: 29/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 27/01/2017 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes TG_REFERENCIA
;Ultima Alteracao: 11/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes c¢cigos modelo de relatorios
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 28/06/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                           
;Ultima Alteracao: 04/09/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes nova logica e ajustes reports 
;Ultima Alteracao: 18/09/2018 por Bruno Carvalho 
;Motivo Alteracao: Ajustes nos modelos  "02B", "03B" e "04B" p/ fazer uma ASK da MARCA antes de utilizar o PegaCodigoRaiz()
;Ultima Alteracao: 24/09/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro origem da producao     
;Ultima Alteracao: 25/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 27/11/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro dt/hora inclusÆo
;Ultima Alteracao: 09/02/2021 por Bruno Carvalho
;Motivo Alteracao: Adicionado modelo 05 #0227# 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
private i
ClearAll

;-- Filtro Produ‡Æo ----------------------------------------------------------
Switch
  Case VSDGNPRODCORTE<>"": 
       {Ask} {Pfacri}
       Moveto [Numero_Programacao      ] Check 
       Moveto [Numero_Producao_Corte   ] TypeIn "~VSDGNPRODCORTE"
       Do_It!
       ClearAll

       {Ask} {Answer}
       Moveto [Numero_Programacao      ] TypeIn "_nprog"
       {Ask} {Rfacc}
       Moveto [Numero_Producao         ] Check
       Moveto [Numero_Programacao      ] TypeIn "_nprog"

       switch   
         case VSDGOPDTLI="1" : Moveto [Data_Producao]       TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
         case VSDGOPDTLI="2" : Moveto [Data_Inclusao] check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                               Moveto [Hora_Inclusao] check 
       endswitch   

       If VSDGOPDEST<>"TODOS" 
          Then Moveto [Destino_Producao      ]
               If VSDGOPDEST="INTERNO + FACCAO"
                  Then TypeIn "INTERNO Or FACCAO"
                  Else TypeIn "~VSDGOPDEST" 
               EndIf
       EndIf
       Moveto [Codigo                  ] TypeIn "~VSDGDESTINAT.."
       Do_It!
       ClearAll
      
  Case VSDGNPROG<>"": 
       {Ask} {Rfacc}
       Moveto [Numero_Producao         ] Check
       Moveto [Numero_Programacao      ] TypeIn "~VSDGNPROG.."

       switch   
         case VSDGOPDTLI="1" : Moveto [Data_Producao]       TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
         case VSDGOPDTLI="2" : Moveto [Data_Inclusao] check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                               Moveto [Hora_Inclusao] check 
       endswitch   

       If VSDGOPDEST<>"TODOS" 
          Then Moveto [Destino_Producao      ]
               If VSDGOPDEST="INTERNO + FACCAO"
                  Then TypeIn "INTERNO Or FACCAO"
                  Else TypeIn "~VSDGOPDEST" 
               EndIf
       EndIf
       Moveto [Codigo                  ] TypeIn "~VSDGDESTINAT.."
       Do_It!
       ClearAll

  Case VSDGCORTE<>"": 
       {Ask} {Rfacc}
       Moveto [Numero_Producao         ] Check
       Moveto [Numero_Corte            ] TypeIn "~VSDGCORTE"

       switch   
         case VSDGOPDTLI="1" : Moveto [Data_Producao]       TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
         case VSDGOPDTLI="2" : Moveto [Data_Inclusao] check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                               Moveto [Hora_Inclusao] check 
       endswitch   

       If VSDGOPDEST<>"TODOS" 
          Then Moveto [Destino_Producao      ]
               If VSDGOPDEST="INTERNO + FACCAO"
                  Then TypeIn "INTERNO Or FACCAO"
                  Else TypeIn "~VSDGOPDEST" 
               EndIf
       EndIf
       Moveto [Codigo                  ] TypeIn "~VSDGDESTINAT.."
       Do_It!
       ClearAll

  OtherWise: 
       {Ask} {Rfacc} 
       Moveto [Numero_Producao         ] Check
       Moveto [Codigo da Empresa       ] TypeIn "~VSDGEMPRESA.."

       switch   
         case VSDGOPDTLI="1" : Moveto [Data_Producao]       TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" 
         case VSDGOPDTLI="2" : Moveto [Data_Inclusao] check TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
                               Moveto [Hora_Inclusao] check 
       endswitch   

       If VSDGOPDEST<>"TODOS" 
          Then Moveto [Destino_Producao      ]
               If VSDGOPDEST="INTERNO + FACCAO"
                  Then TypeIn "INTERNO Or FACCAO"
                  Else TypeIn "~VSDGOPDEST" 
               EndIf
       EndIf
       Moveto [Codigo                  ] TypeIn "~VSDGDESTINAT.."
       Do_It!
       ClearAll

EndSwitch

If VSDGOPDTLI="2" 
   then
        For i From 1 To 2
          {Ask} {Answer} TypeIn "Fast Delete"
          If i=1
             Then Moveto [Data_Inclusao          ] TypeIn "~VSDGDTINI"
                  Moveto [Hora_Inclusao          ] TypeIn "<~VSDGHRINI"
             Else Moveto [Data_Inclusao          ] TypeIn "~VSDGDTFIM"
                  Moveto [Hora_Inclusao          ] TypeIn ">~VSDGHRFIM"
          EndIf
          Do_It!
          ClearAll
        EndFor
Endif   

switch
  case VSDGORIGPROD=2: ;03.Producao
    tabelatmp=Adiciona_Indice_Temp("Numero_Producao")

    {Ask} TypeIn tabelatmp Enter
    Moveto [Numero_Producao       ]       Example "num"
    {Ask} {RfacRIG}
    Moveto [Numero_Producao       ] check Example "num"
    Do_It!
    ClearAll

    Delete tabelatmp

  case VSDGORIGPROD=3: ;36.Producao II
    tabelatmp=Adiciona_Indice_Temp("Numero_Producao")

    {Ask} TypeIn tabelatmp Enter
    Moveto [Numero_Producao       ]       Example "num"
    {Ask} {RfacRIR}
    Moveto [Numero_Producao       ] check Example "num"
    Do_It!
    ClearAll

    Delete tabelatmp

endswitch

TabelaRP=Cria_Temp(PrivDir())
Copy "Answer" TabelaRP

Adiciona_Indice(TabelaRP,"Numero_Producao")

;-- Producao -------------------------------------------------------------------
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ]       TypeIn "_citem"
Moveto [Referencia            ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ]       TypeIn "~VSDGMARCA.."
{Ask} TypeIn TabelaRP Enter
Moveto [Numero_Producao       ]       Example "num"
{Ask} {RfacRI}
Moveto [Numero_Producao       ] check Example "num"
Moveto [Codigo do Item        ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
Do_It!
ClearAll

Tabela=Cria_Temp(PrivDir())
Rename "Answer" Tabela

Adiciona_Campo(Tabela,"Quantidade Produzida(N),Quantidade Perda(N),Quantidade LD(N),Quantidade Reciclagem(N)")

;-- Problemas ------------------------------------------------------------------
{Ask} TypeIn TabelaRP Enter
Moveto [Numero_Producao     ] Example "nprod"
{Ask} {Cprobc}
Moveto [Numero do Lancamento] Check
Moveto [Numero_ProducaoIE   ] Check Example "nprod"
Do_It!
ClearAll

Adiciona_Indice("Answer","Numero do Lancamento")

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ]       TypeIn "_citem"
Moveto [Referencia            ]       TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Familia     ]       TypeIn "~VSDGFAMI.."
Moveto [Codigo da Marca       ]       TypeIn "~VSDGMARCA.."
{Ask} {Answer}
Moveto [Numero do Lancamento  ] Example "nlanc"
Moveto [Numero_ProducaoIE     ] Check 
{Ask} {Cprobi}
Moveto [Numero do Lancamento  ] Example "nlanc"
Moveto [Codigo do Item        ] Check TypeIn "_citem, ~VSDGITEM.."
Moveto [Quantidade            ] TypeIn "Calc Sum as Quantidade" 
Moveto [Tipo_Ocorrencia       ] Check
Do_It!
ClearAll

For i from 1 to 3

  {Ask} {Answer}
  Moveto [Numero_ProducaoIE      ] Example "num" 
  Moveto [Codigo do Item         ] Example "coditem"
  Moveto [Quantidade             ] Example "qtde"
  Moveto [Tipo_Ocorrencia        ] 
  Switch
      Case i=1  :  []="LD"
      Case i=2  :  []="PERDA"
      Otherwise :  []="RECICLAGEM"
  EndSwitch
  
  {Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
  Moveto [Numero_Producao        ] Example "num"
  Moveto [Codigo do Item         ] Example "coditem"
  Switch
      Case i=1  :  Moveto [Quantidade LD        ] Example "qtde"
      Case i=2  :  Moveto [Quantidade Perda     ] Example "qtde"
      OtherWise :  Moveto [Quantidade Reciclagem] Example "qtde"
  EndSwitch 
  Do_It!
  ClearAll

EndFor

Delete TabelaRP

;-- Totalizando ----------------------------------------------------------------
AGUARDE("Aguarde, Totalizando dados")

Switch
  Case VSDGCODMODELO="02B" or VSDGCODMODELO="03B" or VSDGCODMODELO="04B":

    LimpaRodape(0)
    
    NR=NRecords(Tabela)
    
    {Ask} TypeIn Tabela Enter Check
    Moveto [Codigo do Item         ]       TypeIn "_citem!"
    {Ask} {\\Sistemas\\Estoque\\Itens}
    Moveto [Codigo do Item         ]       TypeIn "_citem!"
    Moveto [Codigo da Marca        ] Check
    Moveto [Descricao da Marca     ] Check
    Do_it!
    ClearAll
    Rename "Answer" Tabela    
    
    View NoWindow Tabela
    EditKey
    Scan  
      Barra(NR, RecNo())
      Aguarde("Aguarde, agrupando itens "+BARRA_STRING)
      
      [Codigo do Item]=PegaCodigoRaiz([Codigo do Item])
    EndScan
    Do_It!
    ClearAll
    
    LimpaRodape(0)

endSwitch

Switch
  Case VSDGCODMODELO="01":
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Producao       ] Check
    Moveto [Codigo do Item        ] Check
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Moveto [Quantidade LD         ]       TypeIn "Calc Sum as \"Quantidade LD\""
    Moveto [Quantidade Reciclagem ]       TypeIn "Calc Sum as \"Quantidade Reciclagem\""
    Do_It!
    ClearAll
    
    AGUARDE("Aguarde, Ajustando dados")
    {Ask} {Rfacc}
    Moveto [Numero_Producao       ] Example "num"
    Moveto [Numero_Programacao    ] Check
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Data_Producao         ] Check
    Moveto [Destino_Producao      ] Check
    Moveto [Codigo                ] Check
    Moveto [Nome Fantasia EmitDest] Check
    Moveto [Razao Social          ] Check
    Moveto [Numero_Corte          ] Check 
    Moveto [Observacoes           ] Check
    {Ask} {Answer} Check
    Moveto [Numero_Producao       ] Example "num"
    Do_It!
    ClearAll

  Case VSDGCODMODELO="02" or VSDGCODMODELO="02B" :
    {Ask} {Rfacc}
    Moveto [Numero_Producao       ] Example "num"
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Destino_Producao      ] Check
    Moveto [Codigo                ] Check
    Moveto [Nome Fantasia EmitDest] Check
    Moveto [Razao Social          ] Check
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Producao       ] Example "num"
    Moveto [Codigo do Item        ] Check
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Moveto [Quantidade LD         ]       TypeIn "Calc Sum as \"Quantidade LD\""
    Moveto [Quantidade Reciclagem ]       TypeIn "Calc Sum as \"Quantidade Reciclagem\""
    If VSDGCODMODELO="02B" 
       Then Moveto [Codigo da Marca   ] Check
            Moveto [Descricao da Marca] Check
    EndIf      
    Do_It!
    ClearAll

  Case VSDGCODMODELO="03" or VSDGCODMODELO="03B" or
       VSDGCODMODELO="04" or VSDGCODMODELO="04B" :
    {Ask} {Rfacc}
    Moveto [Numero_Producao       ] Example "num"
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Destino_Producao      ] Check
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Producao       ] Example "num"
    Moveto [Codigo do Item        ] Check
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Moveto [Quantidade Perda      ]       TypeIn "Calc Sum as \"Quantidade Perda\""
    Moveto [Quantidade LD         ]       TypeIn "Calc Sum as \"Quantidade LD\""
    Moveto [Quantidade Reciclagem ]       TypeIn "Calc Sum as \"Quantidade Reciclagem\""
    If VSDGCODMODELO="03B" or VSDGCODMODELO="04B"
       Then Moveto [Codigo da Marca   ] Check
            Moveto [Descricao da Marca] Check
    EndIf         
    Do_It!
    ClearAll
    
  Case VSDGCODMODELO="05" Or VSDGCODMODELO="05B":
    {Ask} {Rfacc}
    Moveto [Numero_Producao       ] Example "num"
    Moveto [Codigo da Empresa     ] Check
    Moveto [Nome Fantasia Empresa ] Check
    Moveto [Destino_Producao      ] Check
    {Ask} TypeIn Tabela Enter 
    Moveto [Numero_Producao       ] Example "num"
    Moveto [Codigo do Item        ] Check
    Moveto [Quantidade Produzida  ]       TypeIn "Calc Sum as \"Quantidade Produzida\""
    Do_It!
    ClearAll    

EndSwitch

AGUARDE("Aguarde, Ajustando dados")

Delete Tabela

Switch
   Case VSDGCODMODELO="05" Or
        VSDGCODMODELO="05B": Seleciona_Dados()
   OtherWise               : 
        Tabela=Cria_Temp(PrivDir())
        
        ;-- Ajustando Dados ----------------------------------------------------
        {Ask} {\\Sistemas\\Estoque\\Itens}
        Moveto [Codigo do Item         ]       TypeIn "_citem"
        Moveto [Referencia             ] Check
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Tipo do Item           ] Check
        Moveto [Codigo da Cor_Tecido   ] Check
        Moveto [Descricao da Cor_Tecido] Check    
        If VSDGCODMODELO<>"02B" And VSDGCODMODELO<>"03B" And VSDGCODMODELO<>"04B" 
           Then Moveto [Codigo da Marca   ] Check
                Moveto [Descricao da Marca] Check
        EndIf
        Moveto [Codigo da Familia      ] Check
        Moveto [Descricao da Familia   ] Check
        {Ask} {Answer} Check
        Moveto [Codigo do Item         ]       TypeIn "_citem!"   
        Do_It!
        ClearAll
             
        MudaEstruturaDaTabelaPara("Answer","\\Base\\Sistemas\\Faccao\\Rm_0210")
        Rename "Answer" Tabela
EndSwitch    

EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ ajustar dados para o modelo 05                                    *
;*******************************************************************************
Proc Seleciona_Dados()

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item      ]       TypeIn "_citem"
Moveto [Codigo da Marca     ] Check
Moveto [Descricao da Marca  ] Check
Moveto [Codigo da Familia   ] Check
Moveto [Descricao da Familia] Check
{Ask} {Answer} Check
Moveto [Codigo do Item      ] Check TypeIn "_citem!" 
Do_It!
ClearAll

Ajusta_Dados()

EndProc ;Seleciona_Dados()

;*******************************************************************************
;* Rotina p/ ajustar dados para o modelo 05                                    *
;*******************************************************************************
Proc Ajusta_Dados()

Tabela=Cria_Temp(PrivDir())
Copy "\\Base\\Sistemas\\Faccao\\Rm_0211" Tabela
Empty Tabela

{Ask} {Answer} 
Moveto [Codigo da Empresa    ] Check 
Moveto [Nome Fantasia Empresa] Check 
Moveto [Destino_Producao     ] Check
Moveto [Codigo da Marca      ] Check 
Moveto [Descricao da Marca   ] Check   
Moveto [Codigo da Familia    ] Check 
Moveto [Descricao da Familia ] Check
Moveto [Quantidade Produzida ] TypeIn "Calc Sum as Quantidade Produzida"
Do_iT!
ClearAll

{Ask} {Answer} 
Moveto [Codigo da Empresa    ] TypeIn "_CodE" 
Moveto [Nome Fantasia Empresa] TypeIn "_NomE" 
Moveto [Destino_Producao     ] TypeIn "_Dest"
Moveto [Codigo da Marca      ] TypeIn "_CodM" 
Moveto [Descricao da Marca   ] TypeIn "_DesM"   
Moveto [Codigo da Familia    ] TypeIn "_CodF" 
Moveto [Descricao da Familia ] TypeIn "_DesF"
Moveto [Quantidade Produzida ] TypeIn "_QtdP"        
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert" Enter 
Moveto [Codigo da Empresa    ] TypeIn "_CodE" 
Moveto [Nome Fantasia Empresa] TypeIn "_NomE" 
Moveto [Destino_Producao     ] TypeIn "_Dest"
Moveto [Codigo da Marca      ] TypeIn "_CodM" 
Moveto [Descricao da Marca   ] TypeIn "_DesM"   
Moveto [Codigo da Familia    ] TypeIn "_CodF" 
Moveto [Descricao da Familia ] TypeIn "_DesF"
Moveto [Quantidade Produzida ] TypeIn "_QtdP"
Do_iT!
ClearAll

{Ask} TypeIn Tabela Enter 
Moveto [Codigo da Familia   ] TypeIn "Blank"
Moveto [Descricao da Familia] TypeIn "Blank, changeto TOTAL SEM FAMILIA" 
Do_iT!
ClearAll

If VSDGCODMODELO="05B"
   Then CoEdit Tabela
        Scan For [Codigo da Familia]="001" Or [Codigo da Familia]="011"
          Barra(NRecords(Tabela), RecNo())
          Aguarde("Aguarde, ajustando dados "+BARRA_STRING)
          
          QTD = [Quantidade Produzida]/2
          Moveto [Quantidade Produzida] CtrlBackSpace
          [Quantidade Produzida] = QTD
          [Descricao da Familia] = [Descricao da Familia] + " **" 
        EndScan   
        Do_iT!
        ClearAll
EndIF 

EndProc ;Ajusta_Dados()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp      = True
TECLA     = ""
MSG_CAMPO = ""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
          If Campo="TG_OPDEST"
             Then Seleciona_Opcoes("Op‡”es de Desinat rio","7,7")
          EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"    : Campo="NO"
            Case Campo="TG_CORTE"      : Campo="TG_EMPRESA"
            Case Campo="TG_NPRODCORTE" : Campo="TG_CORTE"
            Case Campo="TG_NPROG"      : Campo="TG_NPRODCORTE" 
            Case Campo="TG_OPDEST"     : Campo="TG_NPROG"
            Case Campo="TG_DESTINAT"   : Campo="TG_OPDEST"
            Case Campo="TG_ORIGPROD"   : Campo="TG_DESTINAT"
            Case Campo="TG_FAMI"       : Campo="TG_ORIGPROD"
            Case Campo="TG_MARCA"      : Campo="TG_FAMI"
            Case Campo="TG_ITEM"       : Campo="TG_MARCA"
            Case Campo="TG_REFERENCIA" : Campo="TG_ITEM"
            Case Campo="TG_OPDTLI"     : Campo="TG_REFERENCIA"
            Case Campo="TG_DTINI"      : Campo="TG_OPDTLI"
            Case Campo="TG_DTINI"      : Campo="TG_HRINI"
            Case Campo="TG_HRINI"      : Campo="TG_DTINI"
            Case Campo="TG_DTFIM"      : Campo="TG_HRINI"
            Case Campo="TG_HRFIM"      : Campo="TG_DTFIM"
            Case Campo="TG_CODMODELO"  : Campo="TG_HRFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"      : Campo="TG_CORTE"
                    Case Campo="TG_CORTE"        : 
                         VSDGCORTE = ControlValue("TG_CORTE")
                         If Not ISBlank(VSDGCORTE)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_OPDEST"      
                            Else Campo="TG_NPRODCORTE"    
                         EndIf
                    Case Campo="TG_NPRODCORTE"   :
                         If Not ISBlank(VSDGNPRODCORTE)
                            Then LimpaCamposTag(Campo) 
                                 Campo="TG_OPDEST"      
                            Else Campo="TG_NPROG"    
                         EndIf
                    Case Campo="TG_NPROG"        :
                         If Not ISBlank(VSDGNPROG)
                            Then LimpaCamposTag(Campo) 
                         EndIf
                         Campo="TG_OPDEST"
                    Case Campo="TG_OPDEST"     : 
                         VSDGOPDEST=ControlValue("TG_OPDEST")
                         If IsBlank(VSDGOPDEST) Then VSDGOPDEST="TODOS" EndIf
                         If Not Checa_Opcoes("Op‡”es de Desinat rio",VSDGOPDEST) And VSDGOPDEST<>"TODOS"
                            Then Mensagem("Destino inv lido !")
                            Else Campo="TG_DESTINAT"
                        EndIf
                    Case Campo="TG_DESTINAT"    : Campo="TG_ORIGPROD" 
                    Case Campo="TG_ORIGPROD"    : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"        : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"       : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"        : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA"  : Campo="TG_OPDTLI"    
                    Case Campo="TG_OPDTLI"      : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"       : Campo="TG_HRINI"
                    Case Campo="TG_HRINI"       : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"       : Campo="TG_HRFIM"
                    Case Campo="TG_HRFIM"       : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"   : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_OPDEST":
     MSG_CAMPO="Em Branco=Todos, [F1]Consultar tabela"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

Proc LimpaCamposTag(Tipo)

Switch
  Case Tipo="Todos":
    VSDGEMPRESA    = ""
    VSDGNOMEMP     = ""     
    VSDGCORTE      = ""
    VSDGNPRODCORTE = ""
    VSDGNPROG      = ""
    VSDGOPDEST     = ""
    VSDGDESTINAT   = ""
    VSDGNOMDEST    = ""    
    VSDGDTINI      = BlankDate()
    VSDGDTFIM      = BlankDate()
    VSDGHRINI      = ""
    VSDGHRFIM      = ""
    VSDGFAMI       = ""
    VSDGNOMFAMI    = ""
    VSDGMARCA      = ""
    VSDGNOMMARCA   = ""
    VSDGREFERENCIA = ""
    VSDGOPDTLI     = ""
  Case Tipo="TG_CORTE":
    VSDGNPRODCORTE = ""
    VSDGNPROG      = ""
  Case Tipo="TG_NPROG":
    VSDGCORTE      = ""
    VSDGNPRODCORTE = ""
  Case Tipo="TG_NPRODCORTE":
    VSDGCORTE      = ""
    VSDGNPROG      = ""
EndSwitch

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Anal¡tico por Produ‡Æo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("02  Sint‚tico por Destino/Destinat rio/Marca/Item")
ModeloRelatoriosAdd("02B Sint‚tico por Destino/Destinat rio/Marca/Referˆncia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("03  Sint‚tico por Destino/Familia/Marca/Item")
ModeloRelatoriosAdd("03B Sint‚tico por Destino/Familia/Marca/Referˆncia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("04  Sint‚tico por Destino/Marca/Familia/Item")
ModeloRelatoriosAdd("04B Sint‚tico por Destino/Marca/Familia/Referˆncia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("05  Sint‚tico por Destino/Marca/Familia")
If SYS_CODIGO_CLIENTE="0227"
   Then ModeloRelatoriosAdd("05B Sint‚tico por Destino/Marca/Familia  *[001] *[011]")
EndIf        
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CODIGO_CLIENTE)  Then SYS_CODIGO_CLIENTE=""  EndIf
LimpAguarde()

sys_Valor()

LimpaCamposTag("Todos")

Coedit "P_DESTI"
Monta_Opcoes("Op‡”es de Desinat rio","INTERNO + FACCAO") 
Do_It!
ClearAll   

ModeloRelatoriosCarregaLista()

VSDGORIGPROD=1

While True
  ShowDialog "Posi‡Æo da Produ‡Æo - Interna/Externa" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 05,12   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Corte"  For "TG_CORTE"
    Accept @ 03,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_CORTE" To VSDGCORTE
    Accept @ 03,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMCORTE" To VSDGNOMCORTE

    Label  @ 04,00 "Corte/Produ‡Æo"  For "TG_NPRODCORTE"
    Accept @ 05,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_NPRODCORTE" To VSDGNPRODCORTE
    Accept @ 05,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMNPRODCORTE" To VSDGNOMNPRODCORTE

    Label  @ 06,00 "Prog.Interno/Externo"  For "TG_NPROG"
    Accept @ 07,01 Width 09 "A6"  Picture "[&,#][#*#]" Tag "TG_NPROG"    To VSDGNPROG
    Accept @ 07,09 Width 25 "A25" Picture "!*!"        Tag "TG_NOMNPROG" To VSDGNOMNPROG

    Label  @ 08,00 "Op‡”es Destinat rio" For "TG_OPDEST"
    Accept @ 09,01 Width 33 "A31"  Picture "!*!" Tag "TG_OPDEST" To VSDGOPDEST

    Label  @ 10,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 11,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 11,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label @ 12,00 "Origem da Produ‡Æo" For "TG_ORIGPROD"
    RadioButtons @ 13,00 Height 3 Width 33
      "~T~odos 03+36",
      "~1~ 03.Produ‡Æo",
      "~2~ 36.Produ‡Æo II"
        Tag "TG_ORIGPROD"
        To VSDGORIGPROD

    Label  @ 00,35 "Familia"  For "TG_FAMI"
    Accept @ 01,37 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI" To VSDGFAMI
    Accept @ 01,44 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI
 
    Label  @ 02,35 "Marca"  For "TG_MARCA"
    Accept @ 03,37 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 03,44 Width 25 "A22" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 04,36 "Item"  For "TG_ITEM"
    Accept @ 05,36 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 06,36 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 04,48 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 05,48 Width 21 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 08,35 "Op‡äes de Datas" For "TG_OPDTLI"
    Accept @ 09,39 Width 04 "A1"  Picture "1,2"  Tag "TG_OPDTLI"  To VSDGOPDTLI
    Accept @ 09,44 Width 25 "A20" Picture "!*!"      Tag "TG_NOMOPDTLIE" To VSDGNOMOPDTLI

    @ 08, 52 ?? "=\"1\" sem hora !"
    
    Label  @ 10,35 "Per¡odo Referente" For "TG_DTINI"
    Label  @ 11,39 " de" For "TG_DTINI"
    Accept @ 11,44 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 11,57 "as" For "TG_DTINI"
    Accept @ 11,61 Width 08 "A5"  Picture "##:##" Tag "TG_HRINI" To VSDGHRINI
    Label  @ 12,39 "at‚" For "TG_DTFIM"
    Accept @ 12,44 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    Label  @ 12,57 "as" For "TG_DTFIM"
    Accept @ 12,61 Width 08 "A5"  Picture "##:##" Tag "TG_HRFIM" To VSDGHRFIM

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  if VSDGOPDTLI="1" then VSDGHRINI="00:00" VSDGHRFIM="24:00" endif
  
  AGUARDE("Aguarde, Processando Dados")
  
  Seleciona()
  If Not IsEmpty(Tabela)
     Then
          switch
            case VSDGORIGPROD=2: titorigprod="03.Producao"
            case VSDGORIGPROD=3: titorigprod="36.Producao II"
            otherwise          : titorigprod="Todos 03+36"
          endswitch


          Switch
            Case VSDGCODMODELO="01"    :   CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0210" "R" Tabela "R"

            Case VSDGCODMODELO="02" or  
                 VSDGCODMODELO="02B"   :
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0210" "1" Tabela "R"

            Case VSDGCODMODELO="03" or     
                 VSDGCODMODELO="03B"   :   
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0210" "2" Tabela "R"

            Case VSDGCODMODELO="04" or     
                 VSDGCODMODELO="04B"   :   
                                           CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0210" "3" Tabela "R"
            Case VSDGCODMODELO="05" Or
                 VSDGCODMODELO="05B"   :   CopyReport "\\Base\\Sistemas\\Faccao\\Rm_0211" "R" Tabela "R"
          EndSwitch
          IMPRIREL(Tabela,"R")

     Else MENSAGEM("N„o existem registros a processar")
  EndIf

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All