;** Rm_0082 ********************************************************************
;*  Emissao do Ranking de Pedidos - Produtos                                   *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 20/01/2018 por Anivel Augusto Rodrigues
;Ultima Alteracao: 22/01/2018 por Anivel Augusto Rodrigues 
;Motivo Alteracao: Ajustes op‡Æo de analise
;Ultima Alteracao: 05/02/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Seta_Ordem_Report()                
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 27/11/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask com representante nÆo cadastrado
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 15/02/2021 por Bruno Carvalho
;Motivo Alteracao: Agrupado relat¢rio referente ao script "RM_3102" 

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc Seleciona()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC") And
   IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI")
   Then 
        {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
   
        {Ask} {\\Sistemas\\Vendas\\Destin}
        Moveto [Codigo da Destinacao   ] Example "cd"
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Atualiza Pedidos       ] TypeIn "S"
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Numero do Pedido       ] Example "Pedido"
        Moveto [Codigo da Empresa      ] Check     TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Representante]           Example "crep" TypeIn ", ~VSDGREPRESEN.."

        if VSDGOPDTPEEIR="1" Then Moveto [Data de Entrega ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" endif
        If VSDGOPDTPEEIR="2" Then Moveto [Data de Emissao ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" endif
        if VSDGOPDTPEEIR="3" Then Moveto [Data_Inclusao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM" endif
        
        Moveto [Codigo da Destinacao   ] Example "cd"        
        Moveto [Descricao da Destinacao] TypeIn "..VEND.."
        Moveto [Situacao do Pedido     ]
        switch
          case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
          case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
          case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
        endswitch
     
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoI" Enter
        Moveto [Numero do Pedido       ] Example "Pedido"
        Moveto [Tipo do Item           ] Check 
        Moveto [Codigo do Item         ] Check Example "cite" TypeIn ", ~VSDGITEM.."
        Moveto [Descricao do Item      ] Check
        Moveto [Unidade Fiscal         ] Check
        Moveto [Quantidade             ] TypeIn "Calc Sum as Quantidade"
        Moveto [Preco Total            ] TypeIn "Calc Sum as Preco Total"
        Moveto [Valor Desconto Total   ] TypeIn "Calc Sum as Valor Desconto Total"
        
        If Not IsBlank(VSDGMARCA) or
           Not IsBlank(VSDGFAMI) or
           Not IsBlank(VSDGGRP)
           Then {Ask} {\\Sistemas\\Estoque\\Itens}
                Moveto [Codigo do Item         ] Example "cite"
                Moveto [Codigo da Familia      ] TypeIn "~VSDGFAMI.."
                Moveto [Codigo do Grupo        ] TypeIn "~VSDGGRP.."
                Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
        EndIf
        Do_It!
        ClearAll

        Adiciona_Dados()
EndIf  
      
EndProc

;*******************************************************************************
;* Rotina adicionar dados na Db temporaria                                     *
;*******************************************************************************
Proc Adiciona_Dados() 

If IsEmpty("Answer")
   Then Return
EndIf

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Quantidade             ] Example "qtde"
Moveto [Preco Total            ] Example "ptot"
Moveto [Valor Desconto Total   ] Example "vdes"
{Ask} TypeIn Tabela Enter TypeIn "Fast Insert"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Vendas_Quantidade      ] Example "qtde"
Moveto [Vendas_Preco Total     ] Example "ptot" TypeIn"-" Example "vdes"
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()
private ref 

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
   Else {Ask} {\\Sistemas\\Cadastro\\Empresas}
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] Example "nemp"
        {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] Example "cemp"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto _nemp"
        Do_It!
        ClearAll
EndIf

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] Example "dite"
Moveto [Tipo do Item           ] Example "tite"
Moveto [Descricao Tipo do Item ] Example "dtpi"
Moveto [Unidade Fiscal         ] Example "unf"
Moveto [Referencia             ] Example "ref"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo do Item         ] Example "cite"
Moveto [Descricao do Item      ] TypeIn "changeto _dite"
Moveto [Tipo do Item           ] TypeIn "changeto _tite"
Moveto [Descricao Tipo do Item ] TypeIn "changeto _dtpi"
Moveto [Referencia             ] TypeIn "changeto _ref"
Do_It!
ClearAll

If VSDGOPANALISE="2"
   Then View "\\Sistemas\\Estoque\\Itens"
        CoEdit Tabela
        Scan
          If SYS_CLIENTE_CONFEC<>""
             Then
                 [Codigo do Item         ]=PegaCodigoRaiz([Codigo do Item])
                 [Descricao do Item      ]=TiraCorTamanhoDescricaoItem([Descricao do Item])
             else
                  ref=[Referencia]
                  moveto "\\Sistemas\\Estoque\\Itens"
                  moveto [Referencia]
                  Locate IndexOrder by "refcor_01" ref, "D"
                  if retval
                     then [Codigo do Item         ]=[\Sistemas\Estoque\Itens->Codigo do Item   ]
                          [Descricao do Item      ]=[\Sistemas\Estoque\Itens->Descricao do Item]
                  endif   
                  moveto Tabela
          EndIf
        EndScan
        Do_It!
        ClearAll
EndIf

If VSDGOPANALISE="1"
   Then CoEdit Tabela
        Scan
          If SYS_CLIENTE_CONFEC<>""
             Then
                 [Codigo do Item         ]=PegaCodigoRaiz([Codigo do Item])
                 [Descricao do Item      ]=TiraTamanhoDescricaoItem([Descricao do Item])
          EndIf
        EndScan
        Do_It!
        ClearAll
EndIf

;***** Totaliza Dados ************************************
{Ask} TypeIn Tabela Enter Check
Moveto [Vendas_Quantidade      ] Check TypeIn "Calc Sum as VendasQuantidade"
Moveto [Vendas_Preco Total     ] Check TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

Empty Tabela
Add "Answer" Tabela
ClearAll

;*** Totaliza Empresa *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Total_Vendas_Empresa   ] TypeIn "changeto _vp"
Do_It!
ClearAll

;*** Totaliza TpItem *****
{Ask} TypeIn Tabela Enter
Moveto [Codigo da Empresa      ] Check
Moveto [Tipo do Item           ] Check
Moveto [Vendas_Preco Total     ] TypeIn "Calc Sum as VendasPreco"
Do_It!
ClearAll

{Ask} {Answer}
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Tipo do Item           ] Example "tpit"
Moveto [VendasPreco            ] Example "vp"
{Ask} TypeIn Tabela Enter TypeIn "Fast"
Moveto [Codigo da Empresa      ] Example "cemp"
Moveto [Tipo do Item           ] Example "tpit"
Moveto [Total_Vendas_TipoItem  ] TypeIn "changeto _vp"
Do_It!
ClearAll


If VSDGCOMVALOR="2"
     Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
          Moveto [Preco Total  ] TypeIn "Changeto Blank"
          Do_It!
          ClearAll
EndIf   
ClearAll

EndProc  ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"      : Campo="NO"
            Case Campo="TG_GERENCIA"       : Campo="TG_EMPRESATE" 
            Case Campo="TG_REPRESEN"       : Campo="TG_GERENCIA"
            Case Campo="TG_FAMI"           : Campo="TG_REPRESEN"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_MARCA"          : Campo="TG_GRP" 
            Case Campo="TG_ITEM"           : Campo="TG_MARCA"
            Case Campo="TG_REFERENCIA"     : Campo="TG_ITEM"
            Case Campo="TG_OPDTPEEIR"      : Campo="TG_REFERENCIA"
            Case Campo="TG_DTINI"          : Campo="TG_OPDTPEEIR"
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"
            Case Campo="TG_OPRELCODALF"    : Campo="TG_DTFIM"
            Case Campo="TG_COMVALOR"       : Campo="TG_OPRELCODALF"
            Case Campo="TG_OPANALISE"      : Campo="TG_COMVALOR"
            Case Campo="TG_SITUACAOPEDIDO" : Campo="TG_OPANALISE"
            Case Campo="TG_CODMODELO"      : Campo="TG_SITUACAOPEDIDO"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"      : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"       : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"       : Campo="TG_FAMI" 
                    Case Campo="TG_FAMI"           : Campo="TG_GRP"
                    Case Campo="TG_GRP"            : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"          : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"           : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA"     : Campo="TG_OPDTPEEIR"
                    Case Campo="TG_OPDTPEEIR"      : Campo="TG_DTINI" 
                    Case Campo="TG_DTINI"          : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"          : Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF"    : Campo="TG_COMVALOR"
                         VSDGOPRELCODALF=ControlValue("TG_OPRELCODALF") 
                         Switch
                           Case  VSDGOPRELCODALF="2" : VSDGNOMOPRELCODALF="Alfab‚tica"
                           Case  VSDGOPRELCODALF="3" : VSDGNOMOPRELCODALF="Quantidade"
                           Case  VSDGOPRELCODALF="4" : VSDGNOMOPRELCODALF="Valor de Venda" 
                           OtherWise                 : VSDGNOMOPRELCODALF="C¢digo"
                                                       VSDGOPRELCODALF="1" 
                         EndSwitch
                    Case Campo="TG_COMVALOR"       : Campo="TG_OPANALISE"
                    Case Campo="TG_OPANALISE"      : Campo="TG_SITUACAOPEDIDO"
                         VSDGOPANALISE=ControlValue("TG_OPANALISE")
                         Switch
                           Case VSDGOPANALISE="2": VSDGNOMOPANALISE="SO REFERENCIA"
                           Case VSDGOPANALISE="1": VSDGNOMOPANALISE="REFERENCIA+COR"
                           OtherWise             : VSDGNOMOPANALISE="CàDIGO"
                                                   VSDGOPANALISE="0"
                         EndSwitch                 
                    
                    Case Campo="TG_SITUACAOPEDIDO" : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"      : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
  Case Campo="TG_OPANALISE":
       MSG_CAMPO="0=C¢digo  1=Referencia+Cor  2=Referencia"
  Case Campo="TG_OPRELCODALF"  :
     MSG_CAMPO="Ordem: 1=C¢digo  2=Alfab‚tica  3=Quantidade  4=Valor de Venda"  
EndSwitch

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Por Tipo Item/Produto")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("35  Por Marca/Representante")
ModeloRelatoriosAdd("36  Por Representante")
ModeloRelatoriosAdd("27  Por Representante/Marca")
ModeloRelatoriosAdd("65  Por Representante/Cliente")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
If Not IsAssigned(SYS_CLIENTE_CONFEC) Then SYS_CLIENTE_CONFEC="" EndIF
If Not IsAssigned(SYS_CODIGO_CLIENTE) Then SYS_CODIGO_CLIENTE="" EndIF
LimpAguarde()

SYS_VALOR()

VSDGEMPRESA        = ""
VSDGREPRESEN       = ""
VSDGGERENCIA       = ""
VSDGMARCA          = ""
VSDGFAMI           = ""
VSDGGRUP           = ""
VSDGITEM           = ""
VSDGREFERENCIA     = ""
VSDGOPDTPEEIR      = ""
VSDGDTINI          = BlankDate()
VSDGDTFIM          = BlankDate()
VSDGOPRELCODALF    =""
VSDGCOMVALOR       = "1"
VSDGOPANALISE      = ""
VSDGSITUACAOPEDIDO = ""

ModeloRelatoriosCarregaLista()

While True
  Mouse Show
  ShowDialog "Ranking de Pedidos - Produto" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140,-59  
  @ 05,12   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4" Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR

    Label  @ 06,00 "Familia"  For "TG_FAMI"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"    To VSDGFAMI
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMFAMI" To VSDGNOMFAMI

    Label  @ 08,00 "Grupo"  For "TG_GRP"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"    To VSDGGRP
    Accept @ 09,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMGRP" To VSDGNOMGRP

    Label  @ 10,00 "Marca"  For "TG_MARCA"
    Accept @ 11,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"    To VSDGMARCA
    Accept @ 11,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMMARCA" To VSDGNOMMARCA

    Label  @ 12,00 "Item"  For "TG_ITEM"
    Accept @ 13,01 Width 13 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 14,01 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 12,13 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 13,13 Width 21 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 00,35 "Op‡äes de Datas" For "TG_OPDTPEEIR"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3,4"  Tag "TG_OPDTPEEIR"    To VSDGOPDTPEEIR
    Accept @ 01,44 Width 25 "A20" Picture "!*!"      Tag "TG_NOMOPDTPEEIR" To VSDGNOMOPDTPEEIR
 
    Label  @ 02,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 04,35 "Op‡„o de Ordem" For "TG_OPRELCODALF"
    Accept @ 05,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 05,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF
    
    Label  @ 06,35 "Op‡„o de Valor" For "TG_COMVALOR"
    Accept @ 07,39 Width 04 "A1"  Picture "1,2" Tag "TG_COMVALOR" To VSDGCOMVALOR
    Accept @ 07,44 Width 25 "A10"  Picture "!*!" Tag "TG_NOMCOMVALOR" To VSDGNOMCOMVALOR
    
    Label  @ 08,35 "Op‡„o de An lise" For "TG_OPANALISE"
    Accept @ 09,39 Width 04 "A1"  Picture "0,1,2" Tag "TG_OPANALISE" To VSDGOPANALISE
    Accept @ 09,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPANALISE" To VSDGNOMOPANALISE

    Label  @ 10,35 "Situacao do Pedido"  For "TG_SITUACAOPEDIDO"
    Accept @ 11,36 Width 33 "A30"  Picture "ABERTO,SUSPENSO,CANCELADO,FATURADO,TODAS,!*!" Tag "TG_SITUACAOPEDIDO"  To VSDGSITUACAOPEDIDO

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  DISPOSITIVO()
  If OK="" Then Loop EndIf
  
  Switch 
    case VSDGCODMODELO="27"  or    ;RM_3102
         VSDGCODMODELO="35"  or    ;RM_3102A
         VSDGCODMODELO="36"  or    ;RM_3102B
         VSDGCODMODELO="65"   : 
         If VSDGEMPRESA="0000"
            Then VSDGEMPRESA2=""
            Else VSDGEMPRESA2=VSDGEMPRESA
         EndIf
         Play "\\Sistemas\\Vendas\\RM_3102D"  
    OtherWise                 :
            If VSDGEMPRESA="0000"
               Then VSDGEMPRESA2=""
               Else VSDGEMPRESA2=VSDGEMPRESA
            EndIf
          
            AGUARDE("Aguarde, Gerando Relat¢rio")
            Tabela=Cria_Temp(PrivDir())
            Empty "\\Base\\Sistemas\\Producao\\RM_3100"
            Copy "\\Base\\Sistemas\\Producao\\RM_3100" Tabela
            
            if not isblank(VSDGDTINI)
               then Monta_Dir_Trab(VSDGDTINI-365,VSDGDTFIM+365)
               Else Monta_Dir_Trab(Today()-365,VSDGDTFIM+365)
            endif   
            While Novo_Dir_Trab()
              Seleciona()
            EndWhile
          
            If IsEmpty(Tabela)
               Then MENSAGEM("N„o existem registros a processar")
                    Delete Tabela
                    Loop
            EndIf
            Processa()
    
            Switch
              Case VSDGOPRELCODALF="1" : Seta_Ordem_Report(Tabela,"R","Vendas_Quantidade","Codigo do Item","")
              Case VSDGOPRELCODALF="2" : Seta_Ordem_Report(Tabela,"R","Vendas_Quantidade","Descricao do Item","")
              Case VSDGOPRELCODALF="3" : Seta_Ordem_Report(Tabela,"R","Vendas_Quantidade","Vendas_Quantidade","D")
              Case VSDGOPRELCODALF="4" : Seta_Ordem_Report(Tabela,"R","Vendas_Quantidade","Vendas_Preco Total","D")
            EndSwitch
            IMPRIREL(Tabela,"8")
          
            Delete Tabela
  EndSwitch 
EndWhile
ClearAll
Release Vars All
Release Procs All