;** Rm_0015 ********************************************************************
;* Relacao de Formulas                                                         *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 27/03/2002 por Anivel Augusto Rodrigues
;Ultima Alteracao: 15/04/2003 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 28/07/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Novo Report
;Ultima Alteracao: 22/09/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes selecao Item da composicao
;Ultima Alteracao: 21/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                  
;Ultima Alteracao: 25/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novo modelo relatorio        
;Ultima Alteracao: 28/08/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes novos reports                
;Ultima Alteracao: 29/05/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 18/09/2018 por Bruno Carvalho 
;Motivo Alteracao: Ajustes nos modelos  "03" p/ fazer uma ASK da MARCA antes de utilizar o PegaCodigoRaiz()
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 03/08/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes substitui‡Æo tpitem por tipoest
;Ultima Alteracao: 04/08/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado "Bib_Proc"
;Ultima Alteracao: 12/03/2021 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes destacar cor dos itens                          
;Ultima Alteracao: 15/03/2021 por Bruno Carvalho
;Motivo Alteracao: Adicionado modelo 03B onde ‚ exebidio a coluna da cor do tecido em modo paisagem
 
;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item    ] Example "ITEM"
Ask_EstoqueTpItem("")
Moveto [Codigo da Familia   ] TypeIn "~VSDGFAMI.."
Moveto [Codigo do Grupo     ] TypeIn "~VSDGGRP.."
Moveto [Codigo da Marca     ] TypeIn "~VSDGMARCA.."
Moveto [Referencia          ] TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Cor_Tecido] TypeIn "~VSDGCORTECIDO.."
Moveto [Inativo             ] TypeIn "Not S"
{Ask} {FormulaC} Check
Moveto [Codigo do Produto   ] Example "ITEM"
Moveto [Descricao da Cor_Tecido] ;campo nÆo usar !
{Ask} {FormulaI}
Moveto [Codigo do Produto   ] Example "ITEM"
Moveto [Codigo do Material  ] TypeIn "~VSDGITEM.."
Do_It!
ClearAll

If RM_0015B_SEMCUSTO="" and VSDGCODMODElo="03" then Media() EndIf

AjustaDados() 

EndProc

;*******************************************************************************
;* Rotina p/                                                                   *
;*******************************************************************************
Proc AjustaDados()
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ] Example "ITEM"
Moveto [Codigo da Familia      ] Check
Moveto [Descricao da Familia   ] Check
Moveto [Codigo do Grupo        ] Check 
Moveto [Descricao do Grupo     ] Check
Moveto [Codigo da Marca        ] Check 
Moveto [Descricao da Marca     ] Check
Moveto [Codigo da Cor_Tecido   ] Check 
Moveto [Descricao da Cor_Tecido] Check 
{Ask} {Answer} Check
Moveto [Codigo do Produto     ] Example "ITEM" typein "!"
Do_It!
ClearAll

switch
  Case RM_0015B_SEMCUSTO="SIM" :
    {Ask} {Answer} typein "Fast"
    Moveto [Custo Total             ] TypeIn "changeto blank"
    Moveto [Custo Unitario          ] TypeIn "changeto blank"
    Moveto [Preco de Venda_Calculado] TypeIn "changeto blank"
    Moveto [Preco de Venda_Livre    ] TypeIn "changeto blank"
    Moveto [Indice Preco de Venda   ] TypeIn "changeto blank"
    Do_It!
    ClearAll

endswitch

endproc

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Media()
ClearAll

{Ask} {Answer} Check
Moveto [Codigo do Produto      ]       TypeIn "_citem"
{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item         ]       TypeIn "_citem"
Moveto [Codigo da Marca        ] Check
Moveto [Descricao da Marca     ] Check
Do_it!
ClearAll

Edit "Answer"
Scan
  [Codigo do Produto]=PegaCodigoRaiz([Codigo do Produto])
endscan
do_IT!
ClearAll

{Ask} {Answer} 
Moveto [Codigo do Produto       ] check
Moveto [Tipo do Item            ] Check
Moveto [Descricao Tipo do Item  ] Check
Moveto [Codigo da Marca         ] Check
Moveto [Descricao da Marca      ] Check
Moveto [Custo Total             ] TypeIn "Calc Average as Custo Total"
Moveto [Custo Unitario          ] TypeIn "Calc Average as Custo Unitario"
Moveto [Preco de Venda_Calculado] TypeIn "Calc Average as \"Preco de Venda_Calculado\""
Moveto [Preco de Venda_Livre    ] TypeIn "Calc Average as \"Preco de Venda_Livre\""
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item        ] Example "ITEM"
Moveto [Descricao do Item     ] Check
Moveto [Referencia            ] Check
Moveto [Unidade Interna       ] Check
{Ask} {Answer} Check
Moveto [Codigo do Produto     ] Example "ITEM" typein "!"
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_TIPOEST"        : Campo="NO"
            Case Campo="TG_FAMI"           : Campo="TG_TIPOEST"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_MARCA"          : Campo="TG_GRP"
            Case Campo="TG_COR_TECIDO"     : Campo="TG_MARCA"
            Case Campo="TG_REFERENCIA"     : Campo="TG_COR_TECIDO"
            Case Campo="TG_ITEM"           : Campo="TG_REFERENCIA"
            Case Campo="TG_CODMODELO"      : Campo="TG_ITEM"
            Case Campo="YES" Or Campo="NO" : Campo="TG_FAMI"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_TIPOEST"    : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"       : Campo="TG_GRP"
                    Case Campo="TG_GRP"        : Campo="TG_MARCA" 
                    Case Campo="TG_MARCA"      : Campo="TG_COR_TECIDO"
                    Case Campo="TG_COR_TECIDO" : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA" : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"       : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

switch
  Case RM_0015B_SEMCUSTO="SIM" :
    ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
    ModeloRelatoriosAdd("01  Tipo do Item/Familia/Grupo/Marca")
    ModeloRelatoriosAdd("02  Tipo do Item/Familia/Grupo/Marca/Referˆncia")
    ModeloRelatoriosAdd("Fim")

  otherwise:
    ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
    ModeloRelatoriosAdd("01  Tipo do Item/Familia/Grupo/Marca")
    ModeloRelatoriosAdd("02  Tipo do Item/Familia/Grupo/Marca/Referˆncia")
    ModeloRelatoriosAdd("02B Tipo do Item/Familia/Grupo/Marca/Referˆncia+Cor - Paisagem")
    ModeloRelatoriosAdd("03  Tipo do Item/Familia/Grupo/Marca/Referˆncia II")
    ModeloRelatoriosAdd("03B Tipo do Item/Familia/Grupo/Marca/Referˆncia II+Cor - Paisagem")
    ModeloRelatoriosAdd("Fim")
  
endswitch

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

sys_valor()

VSDGTIPOEST = ""
VSDGFAMI    = ""
VSDGGRP     = ""
VSDGMARCA   = ""
VSDGCORTECIDO= ""
VSDGPRODUTO = ""
VSDGREFERENCIA  = ""

If Not IsAssigned(RM_0015B_SEMCUSTO)  Then RM_0015B_SEMCUSTO=""    EndIf
switch
  Case RM_0015B_SEMCUSTO="SIM" : TituloShowDialog="Rela‡„o de F¢rmulas II"
  otherwise                    : TituloShowDialog="Rela‡„o de F¢rmulas"
endswitch

ModeloRelatoriosCarregaLista()

While True

  ShowDialog TituloShowDialog Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
    @ 01,00 Height 22 Width 80

    Label  @ 00,00 "Tipo do Estoque"  For "TG_TIPOEST"
    Accept @ 01,04 Width 04 "A1"  Picture "!" Tag "TG_TIPOEST" To VSDGTIPOEST
    Accept @ 01,09 Width 25 "A30"  Picture "!*!" Tag "TG_DESCTIPOEST" To VSDGDESCTIPOEST

    Label  @ 02,00 "Familia"  For "TG_FAMI"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"      To VSDGFAMI
    Accept @ 03,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI"   To VSDGNOMFAMI

    Label  @ 04,00 "Grupo"  For "TG_GRP"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"       To VSDGGRP
    Accept @ 05,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMGRP"    To VSDGNOMGRP

    Label  @ 06,00 "Marca" For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA" To VSDGMARCA
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_MARCA" To VSDGNOMMARCA

    Label  @ 08,00 "Cor" For "TG_COR_TECIDO"
    Accept @ 09,01 Width 07 "A4"  Picture "#*#" Tag "TG_COR_TECIDO"    To VSDGCORTECIDO
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCOR_TECIDO" To VSDGNOMCORTECIDO

    Label  @ 10,00 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 11,01 Width 33 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 00,35 "Item Consumo da F¢rmula"  For "TG_ITEM"
    Accept @ 01,36 Width 33 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 02,36 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  if not ValidarModelosRelatorios() then loop endif         

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")

  SELECIONA()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf
    
  switch
    Case RM_0015B_SEMCUSTO="SIM" :
      switch
        case VSDGCODMODElo="01" : CopyReport "\\Base\\Sistemas\\Producao\\Rm_0015" "6" "Answer" "R"
        case VSDGCODMODElo="02" : CopyReport "\\Base\\Sistemas\\Producao\\Rm_0015" "7" "Answer" "R"
      endswitch
     
    otherwise:
      Impressao_Orientacao=""
      switch
        case VSDGCODMODElo="01"  : CopyReport "\\Base\\Sistemas\\Producao\\Rm_0015" "R" "Answer" "R"
        case VSDGCODMODElo="02"  : CopyReport "\\Base\\Sistemas\\Producao\\Rm_0015" "1" "Answer" "R"
        case VSDGCODMODElo="02B" : Impressao_Orientacao="Paisagem"
                                   CopyReport "\\Base\\Sistemas\\Producao\\Rm_0015" "3" "Answer" "R"
        case VSDGCODMODElo="03"  : CopyReport "\\Base\\Sistemas\\Producao\\Rm_0015" "2" "Answer" "R"
        case VSDGCODMODElo="03B" : Impressao_Orientacao="Paisagem"
                                   CopyReport "\\Base\\Sistemas\\Producao\\Rm_0015" "4" "Answer" "R"
      endswitch
    
  endswitch
  IMPRIREL("Answer","R")

  Delete "Answer"
EndWhile
ClearAll
Release Vars All
Release Procs All
