;** Rm_0120 ********************************************************************
;*  Relatorio de Clientes que compraram em um periodo                          *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/11/1997 por Anivel Augusto Rodrigues
;Ultima Alteracao: 18/06/2007 por Anivel Augusto Rodrigues
;Motivo Alteracao: Periodo/Modelo Relatorio
;Ultima Alteracao: 20/10/2009 por Bruno Carvalho
;Motivo Alteracao: Inclusao do Campo VCDGESTADO
;Ultima Alteracao: 28/10/2009 por Bruno Carvalho
;Motivo Alteracao: Ajustes Seleciona()         
;Ultima Alteracao: 09/08/2011 por Bruno Carvalho
;Motivo Alteracao: Adicionado Celular no 1§ Modelo de Report
;Ultima Alteracao: 19/01/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado valores de compras e quantidade faturada conforme sele‡Æo
;Ultima Alteracao: 10/07/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro na ask do NotaI "Situacao_Item"
;Ultima Alteracao: 24/09/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ quando for o mesmo cliente, somar as quantidades
;Ultima Alteracao: 08/01/2014 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro por marca
;Ultima Alteracao: 05/01/2016 por Bruno Carvalho
;Motivo Alteracao: Adicionado Gerˆncia
;Ultima Alteracao: 12/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()                
;Ultima Alteracao: 12/12/2019 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes desfazer ask com representante nÆo cadastrado
;Ultima Alteracao: 10/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO]
;Ultima Alteracao: 25/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 07/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog     
;Ultima Alteracao: 21/01/2021 por Bruno Carvalho
;Motivo Alteracao: Adicionado modelo de relat¢rio dos scripts "RM_0100" e "RM_0110"
;Ultima Alteracao: 20/04/2021 por Bruno Carvalho             
;Motivo Alteracao: Ajustes no processo do filtro "TG_STATUS" na "Bib_Show"
;Ultima Alteracao: 27/04/2021 por Bruno Carvalho             
;Motivo Alteracao: Alterado TG_SITUACAO p/ TG_SITUACAOCLIENTE

;*******************************************************************************
;* Rotina p/ Selecionar Vendas                                                 *
;*******************************************************************************
Proc RM_0120_Sel_Vendas()
ClearAll
  
If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC")     
   Then {Ask} {\\Sistemas\\Cadastro\\Represen}
        Moveto [Codigo do Representante] Example "crep"
        If VSDGGERENCIA<>""
           Then Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA"
           Else Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
        EndIf
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaC" Enter
        If VSDGOPVALORES="S" Or VSDGMARCA<>"" ;Para Informar Quantidade de Itens Faturados
           Then Moveto [Codigo da Empresa  ] Check TypeIn "~VSDGEMPRESA.."
                Moveto [Numero do Documento] Check
                Moveto [Serie do Documento ] Check
           else Moveto [Codigo da Empresa  ] TypeIn "~VSDGEMPRESA.."     
           
        EndIf                                 
        Moveto [Codigo                 ] Check
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"        
        Moveto [Codigo do Representante] Check Example "crep" TypeIn ", ~VSDGREPRESEN.."
        Moveto [Nome Fantasia Represent] Check
        Moveto [Descricao da Destinacao] TypeIn "..VEND.. or ..SERV.. or ..SAIDA.."
        Moveto [Tipo Movimento Estoque ] TypeIn "S"
        Moveto [Situacao               ] TypeIn "Not C"
        Do_It!
        ClearAll
        
        If VSDGOPVALORES="S" Or VSDGMARCA<>""  
           Then If Not IsEmpty("Answer")
                    Then {Ask} {Answer} Check
                         Moveto [Codigo da Empresa  ] Example "CodE"
                         Moveto [Numero do Documento] Example "Ndoc"
                         Moveto [Serie do Documento ] Example "Sdoc"
                         {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"NotaI" Enter
                         Moveto [Codigo da Empresa  ] Example "CodE"
                         Moveto [Numero do Documento] Example "Ndoc"
                         Moveto [Serie do Documento ] Example "Sdoc"
                         If VSDGOPVALORES="S"
                            Then Moveto [Quantidade         ] TypeIn "Calc Sum as Quantidade"
                                 Moveto [Situacao_Item      ] TypeIn "Not C"
                         EndIf
                         If VSDGMARCA<>""  
                            Then Moveto [Codigo do Item         ] Example "CodI"
                                 {Ask} {\\Sistemas\\Estoque\\Itens}
                                 Moveto [Codigo do Item         ] Example "CodI"
                                 Moveto [Codigo da Marca        ] TypeIn "~VSDGMARCA.."
                         EndIf  
                         Do_It!
                         ClearAll 
                EndIf
        Endif
Endif

EndProc ;RM_0120_Sel_Vendas

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc RM_0120_Seleciona()
ClearAll
          
{Ask} TypeIn Tabela2 Enter
Moveto [Codigo                  ] Example "COD"           
{Ask} {\\Sistemas\\Cadastro\\FichaCli}
Moveto [Codigo                  ] Example "COD"
Moveto [Data da Primeira Compra ] Check
Moveto [Data da Ultima Compra   ] Check
If VSDGOPVALORES="S"
   Then Moveto [Valor da Primeira Compra] Check
        Moveto [Valor da Ultima Compra  ] Check
EndIf                                           
{Ask} {\\Sistemas\\Cadastro\\Destinat}
Moveto [Codigo                 ] Check Example "COD" ;TypeIn "!"
Moveto [Tipo                   ] TypeIn "C"
Moveto [Razao Social           ] Check
Moveto [Cidade                 ] Check
If UPPER(VSDGCIDADE)<>"TODAS"
   Then TypeIn VSDGCIDADE
EndIf
Moveto [UF                     ] Check TypeIn "~VSDGESTADO.."
Moveto [Telefone               ] Check
Moveto [Contato                ] Check
Moveto [Codigo do Representante] Check 
Moveto [Nome Fantasia Represent] Check
Moveto [Endereco               ] Check
Moveto [Bairro                 ] Check
Moveto [CEP                    ] Check
Moveto [Celular                ] Check 
Do_It!
ClearAll

{Ask} {Answer} 
Moveto [Codigo do Representante] TypeIn "Changeto Blank"
Do_It!
ClearAll

 {Ask} {Answer}
Moveto [Nome Fantasia Represent] TypeIn "Changeto Blank"
Do_It!
ClearAll

{Ask} TypeIn Tabela2 Enter
Moveto [Codigo                 ] Example "COD"
Moveto [Nome Fantasia Represent] Example "NomF"
Moveto [Codigo do Representante] Example "CodR"
{Ask} {Answer}
Moveto [Codigo                 ] Example "COD"
Moveto [Nome Fantasia Represent] TypeIn "Changeto _NomF"
Moveto [Codigo do Representante] TypeIn "Changeto _CodR"
Do_It!
ClearAll
                                                        
{Ask} {Answer} Check
Moveto [Codigo                  ] Example "COD"
{Ask} TypeIn Tabela2 Enter
Moveto [Codigo                  ] Example "COD"
If VSDGOPVALORES="S"
   Then Moveto [Quantidade      ] Check
EndIf   
Do_It!
ClearAll

If VSDGOPVALORES="S" ;Tava gerando duplicidade de clientes, e foi feito entÆo a soma das quantidades se cliente = mesmo !
   Then {Ask} {Answer} Check
        Moveto [Quantidade] Check TypeIn "Calc Sum as Quantidade"
        Do_It!
        ClearAll
EndIf        

EndProc ;RM_0120_Seleciona

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60: ListaRegra_F2()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"         : Campo="NO"
            Case Campo="TG_GERENCIA"        : Campo="TG_EMPRESA"
            Case Campo="TG_REPRESEN"        : Campo="TG_GERENCIA"
            Case Campo="TG_CIDADE"          : Campo="TG_REPRESEN"
            Case Campo="TG_ESTADO"          : Campo="TG_CIDADE"
            Case Campo="TG_MARCA"           : Campo="TG_ESTADO"
            Case Campo="TG_SITUACAOCLIENTE" : Campo="TG_MARCA"  
            Case Campo="TG_STATUS"          : Campo="TG_SITUACAOCLIENTE" 
            Case Campo="TG_DTINI"           : Campo="TG_STATUS"
            Case Campo="TG_DTFIM"           : Campo="TG_DTINI"
            Case Campo="TG_OPVALORES"       : Campo="TG_DTFIM"
            Case Campo="TG_OPRELCODALF"     : Campo="TG_OPVALORES"
            Case Campo="TG_CODMODELO"       : Campo="TG_OPRELCODALF"
            Case Campo="YES" Or Campo="NO"  : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"         : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"        : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"        : Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"          : Campo="TG_ESTADO"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf 
                    Case Campo="TG_ESTADO"          : Campo="TG_MARCA"
                    Case Campo="TG_MARCA"           : Campo="TG_SITUACAOCLIENTE"
                    Case Campo="TG_SITUACAOCLIENTE" : Campo="TG_STATUS"  
                    Case Campo="TG_STATUS"          : Campo="TG_DTINI"       
                    Case Campo="TG_DTINI"           : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"           : Campo="TG_OPVALORES"
                    Case Campo="TG_OPVALORES"       : Campo="TG_OPRELCODALF"
                         VSDGOPVALORES= ControlValue("TG_OPVALORES")
                         Switch
                           Case VSDGOPVALORES="S"   : VSDGNOMOPVALORES="SIM"  
                           OtherWise                : VSDGOPVALORES="N"  
                                                      VSDGNOMOPVALORES="NAO"
                         EndSwitch   
                    Case Campo="TG_OPRELCODALF"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"       : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DTINI":
       MSG_CAMPO="Informe a Data Inicial do Periodo"
  Case Campo="TG_DTFIM":
       MSG_CAMPO="Informe a Data Final do Periodo"
  Case Campo="TG_OPVALORES" :
       MSG_CAMPO="Exibe Valores? Sim/NÆo"            
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("11A Clientes que compraram em um per¡odo SIMPLES [*]")
ModeloRelatoriosAdd("11B Clientes que compraram em um per¡odo COM ENDERE€O [*]")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("09  Clientes que compraram em um per¡odo")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("10A Clientes que n„o compraram em um per¡odo SIMPLES [*]")
ModeloRelatoriosAdd("10B Clientes que n„o compraram em um per¡odo COM ENDERE€O [*]")
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*****************************************************************************+*
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

VSDGEMPRESA         = ""
VSDGDTINI           = BlankDate()
VSDGDTFIM           = BlankDate()
VSDGCIDADE          = ""
VSDGESTADO          = ""
VSDGMARCA           = ""
VSDGNOMMARCA        = ""
VSDGREPRESEN        = ""
VSDGOPRELCODALF     = ""
VSDGGERENCIA        = "" 
VSDGESTADO          = ""
VSDGOPVALORES       = ""
VSDGNOMOPVALORES    = ""
VSDGSITUACAOCLIENTE = ""
VSDGSTATUS          = ""

ModeloRelatoriosCarregaLista()
ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_SITUACAOCLIENTE]")

While True
  ShowDialog "Clientes com/sem compras no per¡odo" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140,-60,-59  
   @ 05,09   Height 22 Width 80

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Representante"  For "TG_REPRESEN"
    Accept @ 05,01 Width 07 "A4"  Picture "#*#" Tag "TG_REPRESEN"   To VSDGREPRESEN
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"    To VSDGNOMREPR

    Label  @ 06,00 "Cidade"  For "TG_CIDADE"
    Accept @ 07,01 Width 27 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE
                                   
    Label  @ 06,27 "Estado"  For "TG_ESTADO"                                                                          
    Accept @ 07,28 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    
    Label  @ 08,00 "Marca" For "TG_MARCA"
    Accept @ 09,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA"     To VSDGMARCA
    Accept @ 09,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMMARCA"  To VSDGNOMMARCA
    
    Label  @ 10,00 "Situa‡Æo do Cliente" For "TG_SITUACAOCLIENTE"
    Accept @ 11,01 Width 33 "A30" Picture "!*!" Tag "TG_SITUACAOCLIENTE" To VSDGSITUACAOCLIENTE
    
    Label  @ 12,00  "Status do Cliente" For "TG_STATUS"
    Accept @ 13,01 Width 33 "A12" Picture "ATIVO,INATIVO,TODOS" Tag "TG_STATUS" To VSDGSTATUS      

    Label  @ 14,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 15,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 15,16 "at‚" For "TG_DTFIM"
    Accept @ 15,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
                                                                                                        
    Label  @ 00,35 "Exibe Valores [*]" For "TG_OPVALORES"
    Accept @ 01,39 Width 04 "A1"  Picture "S,N" Tag "TG_OPVALORES" To VSDGOPVALORES
    Accept @ 01,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPVALORES" To VSDGNOMOPVALORES
    
    Label  @ 02,35 "Ordem" For "TG_OPRELCODALF"
    Accept @ 03,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 03,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 17,00 "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01 Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06 Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf
  If VSDGDTFIM < VSDGDTINI
     Then Mensagem("Data Final deve ser maior que Data Inicial !")
          Loop
  EndIf

  DISPOSITIVO()
  If OK=""  Then Loop EndIf

  Switch
    Case VSDGCODMODELO="09"                         : Play "RM_0120A"           ;RM_0100
    Case VSDGCODMODELO="10A" Or VSDGCODMODELO="10B" : Play "RM_0120B"           ;RM_0110
    Case VSDGCODMODELO="11A" Or VSDGCODMODELO="11B" :                           ;RM_0120
         AGUARDE("Aguarde, gerando o relat¢rio")
         Tabela2=Cria_Temp(PrivDir())
        
         Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
         While Novo_Dir_Trab()
            If IsTable("Answer")     Then Delete "Answer" EndIf
            RM_0120_Sel_Vendas()
            If Not IsTable("Answer") Then Loop EndIf
            If IsTable(Tabela2)
               Then Add "Answer" Tabela2
               Else Rename "Answer" Tabela2
            EndIf
         EndWhile
                         
         RM_0120_Seleciona()  
                         
         If IsEmpty("Answer")
            Then MENSAGEM("N„o existem registros a processar")
                 Delete "Answer"
                 Loop
         EndIf
          
         If VSDGOPVALORES="S"
            Then Impressao_Orientacao="Paisagem"
         EndIf                       
        
         If VSDGMARCA="" Then VSDGNOMMARCA="" EndIf    
         Switch
           Case VSDGCODMODELO="11A" And VSDGOPVALORES="S": ;Op‡Æo com Quantidade Faturada e Exibi‡Æo de Valores  
                If VSDGOPRELCODALF="1"
                   Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0111" "R" "Answer" "R"   
                   Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0111" "1" "Answer" "R"  
                EndIf   
           Case VSDGCODMODELO="11A" :
                If VSDGOPRELCODALF="1"
                   Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "4" "Answer" "R"
                   Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "5" "Answer" "R"
                EndIf
           Case VSDGCODMODELO="11B":
             If VSDGOPRELCODALF="1"
                Then CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "8" "Answer" "R"
                Else CopyReport "\\Base\\Sistemas\\Vendas\\Rm_0110" "9" "Answer" "R"
             EndIf
         EndSwitch
        
         IMPRIREL("Answer","R")
        
         If IsTable("Answer")     Then Delete "Answer" EndIf
         If IsTable(Tabela2)      Then Delete Tabela2  EndIf
  EndSwitch       
EndWhile
ClearAll
Release Vars All
Release Procs All