;** Rm_0087 ********************************************************************
;*  Emissao dos Titulos a Receber por Cliente/Obs                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 14/03/2008 por Nikolas
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 05/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT
;Ultima Alteracao: 08/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0080C" (50), "RM_0095" (48), "RM_0082" (30), "RM_0096B" (75) neste script "RM_0087" (66)
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento                
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 07/07/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0080" (01), "RM_0081" (23) neste script "RM_0087" (66)
;Ultima Alteracao: 11/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO]
;Ultima Alteracao: 20/02/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ordem codigo/alfabetica
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 20/11/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Seta_Ordem_Report
;Ultima Alteracao: 26/04/2021 por Bruno Carvalho             
;Motivo Alteracao: Alterado TG_SITUACAO p/ TG_SITUACAOCLIENTE

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona_RM0087()
ClearAll

;---- Clientes Vinculados ------------------------------------------------------
COD_GRUPO = ""
If VSDGCODMODELO="30B" And VSDGDESTINAT<>""
   Then {Ask} {\\Sistemas\\Cadastro\\GPessoaI}
        Moveto [CodigoGrupoPessoa     ] Check
        Moveto [Codigo                ] Check TypeIn "~VSDGDESTINAT.."                  
        Do_it!
        CleaRall
        
        If Not IsEmpty("Answer")
           Then View "Answer"
                COD_GRUPO = [CodigoGrupoPessoa]
                Clearall
        EndIf         
EndIf    

For ii From 1 To 2  
  If ii=2 And VSDGCODMODELO<>"30B" Then QuitLoop EndIf

  If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
    Then 
         If CIDADE<>"" Or VSDGESTADO<>""  
            Then {Ask} {\\Sistemas\\Cadastro\\Destinat}
                 Moveto [Codigo             ] Example "cod"
                 If CIDADE<>""
                    Then Moveto [Cidade     ] TypeIn CIDADE
                 EndIf   
                 If VSDGESTADO<>""
                    Then Moveto [UF        ] TypeIn "~VSDGESTADO.."
                 EndIf   
         EndIf

         If VSDGGERENCIA<>""
           Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
                Moveto [Codigo do Representante] Example "crep"
                Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."
         EndIf
         {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
         Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
         Switch
           Case VSDGCODMODELO="30B" And ii=1 : Moveto [Codigo do Destinatario] Example "cod"
           Case CIDADE<>"" Or VSDGESTADO<>"" : Moveto [Codigo do Destinatario] Example "cod" TypeIn " ,~VSDGDESTINAT.."
           OtherWise                         : Moveto [Codigo do Destinatario] TypeIn "~VSDGDESTINAT.."
         EndSwitch
         Switch
           Case VSDGOPDTEMISVENC="2": Moveto [Data de Emissao    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
           Case VSDGOPDTEMISVENC="1": Moveto [Data de Vencimento ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
         EndSwitch
         Moveto [Saldo do Documento    ] TypeIn "> 0.01" 
         switch
           case ListaRegra_VSDGTPPAGTO_Ativo : Moveto [Tipo do Pagamento      ] TypeIn ListaRegra_VSDGTPPAGTO
           case VSDGTPPAGTO<>""              : Moveto [Tipo do Pagamento      ] TypeIn "~VSDGTPPAGTO.." 
           otherwise                         : If SYS_CODIGO_CLIENTE="0272" And VSDGCODMODELO="30"
                                                  Then Moveto [Tipo do Pagamento] TypeIn "Not CD, Not CT, Not CL"
                                               EndIf 
        endswitch
        switch
          case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento     ] TypeIn ListaRegra_VSDGTPCART 
          otherwise                         : Moveto [Tipo do Lancamento     ] TypeIn "~VSDGTPCART.."
        endswitch
         Moveto [Codigo da Conta       ] TypeIn "~VSDGCONTA.."
         Switch
           Case VSDGGERENCIA<>"" : Moveto [Codigo do Representante] Example "crep" TypeIn ", ~VSDGREPRESEN.."
           Case VSDGREPRESEN<>"" : Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
         Endswitch
         
         
         ;---- Clientes Vinculados ---------------------------------------------
         If VSDGCODMODELO="30B" And ii=1
            Then {Ask} {\\Sistemas\\Cadastro\\GPessoaI}
                 If COD_GRUPO<>""
                    Then Moveto [CodigoGrupoPessoa     ] TypeIn "~COD_GRUPO"
                         Moveto [Codigo                ] Example "Cod"
                    Else Moveto [Codigo                ] Example "cod" TypeIn " ,~VSDGDESTINAT.."                                              
                 EndIf   
         EndIf
         Do_It!
         ClearAll
         
         If VSDGSITUACAOCLIENTE<>"" And VSDGSITUACAOCLIENTE<>"TODAS"
            Then  {Ask} {\\Sistemas\\Cadastro\\Destinat}
                  Moveto [Codigo                ] Example "cod"
                  Switch
                    Case ListaRegra_VSDGSITUACAOCLIENTE_Ativo : Moveto [Situacao do Cliente] TypeIn ListaRegra_VSDGSITUACAOCLIENTE
                    Case VSDGSITUACAOCLIENTE<>"TODAS"         : Moveto [Situacao do Cliente] TypeIn "~VSDGSITUACAOCLIENTE.."
                  EndSwitch
                  {Ask} {Answer} Check
                  Moveto [Codigo do Destinatario] Example "cod"
                  Do_It!
                  ClearAll
         EndIf
         
  EndIf
  If ii =1 And VSDGCODMODELO="30B"  
     Then Rename "Answer" PrivDir()+"RM_0082"
     Else If ii =2 
             Then {Ask} TypeIn PrivDir()+"RM_0082" Enter
                  Moveto [Codigo do Destinatario] Example "Cod"
                  {Ask} {Answer} TypeIn "Fast Delete"
                  Moveto [Codigo do Destinatario] Example "Cod"
                  Do_It!                        
                  ClearAll
                  
                  Add "Answer" PrivDir()+"RM_0082"
          EndIf        
  EndIf   
EndFor

If VSDGCODMODELO="30B"
   Then Copy PrivDir()+"RM_0082" "Answer"
        Delete PrivDir()+"RM_0082" 
EndIf

If VSDGCODMODELO="30"
   Then If IsTable("\\Sistemas\\Cadastro\\"+Dir_Trab+"Destinat")
           Then TabelaAnswer=Adiciona_Indice_Temp("Numero do Lancamento")
           
                {Ask} {\\Sistemas\\Cadastro\\Destinat}
                Moveto [Codigo                  ] Check
                Moveto [Endereco                ] Check
                Moveto [Bairro                  ] Check 
                Moveto [Cidade                  ] Check
                Moveto [UF                      ] Check
                Moveto [Contato                 ] Check
                Moveto [Telefone                ] Check
                Do_It!
                ClearAll
                
                TabelaDestinat=Adiciona_Indice_Temp("Codigo")
                
                {Ask} TypeIn TabelaDestinat Enter
                Moveto [Codigo                  ] Example "Cod"
                Moveto [Endereco                ] Example "End"
                Moveto [Bairro                  ] Example "Bai" 
                Moveto [Cidade                  ] Example "Cid"
                Moveto [UF                      ] Example "Uf"
                Moveto [Contato                 ] Example "Con"
                Moveto [Telefone                ] Example "Tel"
                {Ask} TypeIn TabelaAnswer Enter
                Moveto [Codigo do Destinatario  ] Example "cod"
                Moveto [Descricao Plano_Conta   ] TypeIn "Changeto " Example "End"  ;(Endereco A40)  A48
                Moveto [Nome Fantasia Represent ] TypeIn "Changeto " Example "Bai"  ;(Bairro   A20)  A20
                Moveto [Documento no Banco      ] TypeIn "Changeto " Example "Cid"  ;(Cidade   A20)  A20
                Moveto [Codigo do Cobrador      ] TypeIn "Changeto " Example "Uf"   ;(UF       A2 )  A2
                Moveto [Descricao do Cobrador   ] TypeIn "Changeto " Example "Con"  ;(Contato  A20)  A30
                Moveto [Descricao Tipo Pagamento] TypeIn "Changeto " Example "Tel"  ;(Telefone A20)  A20
                Do_It!
                ClearAll
                
                Copy TabelaAnswer "Answer"
                
                Delete TabelaDestinat
                Delete TabelaAnswer
        EndIf
EndIf

EndProc ;(Seleciona_RM0087()

;*******************************************************************************
;* Rotina p/ processar Db Temporaria                                           *
;*******************************************************************************
Proc Processa_RM0087()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf
 
Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
  If [Data de Vencimento]<Today()
     Then NDA=Today()-[Data de Vencimento]
          TXM=[Multa]
          If VSDGCODMODELO<>"66"
             Then [Observacoes]="Vencida" 
          EndIf   
     Else NDA=0
          TXM=0
          If VSDGCODMODELO<>"66" 
             Then [Observacoes]="" 
          EndIf   
  EndIf
 
  If VSDGCODMODELO<>"66"
     Then If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
             Then If [Descricao do Lancamento]="PROTESTADA"
                     Then [Observacoes]="Cartorio"
                     Else [Observacoes]="Protestar"
                  EndIf
         EndIf
  EndIf        

  If [Data Limite Desconto]>=Today()
     Then VRDESCT=[Valor do Desconto]
     Else VRDESCT=0
  EndIf
                     
  If [Taxa de Juros]>0
     Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
          VRJUROS=Round((([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100),2)
     Else VRJUROS=Round((([Valor de Juros]/[NDias Taxa de Juros])*NDA),2)
          VRJUROS=VRJUROS+Round((([Saldo do Documento]*TXM)/100),2)
  EndIf
 
  [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
  [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll


If VSDGCODMODELO="30B"
   Then ;---- Para nÆo ter que mexer com altera‡Æo de tabela ------------ 
        {Modify} {Restructure} TypeIn Tabela Enter
        Moveto [Field Name]
        Locate "Descricao"
        If Not ReTval
           Then End Down    
                "Descricao" Enter "A30" Enter
        Endif
        Do_it!
        ClearAll
        ;----------------------------------------------------------------
              
        {Ask} TypeIn Tabela Enter
        Moveto [Numero Lancamento Pai] TypeIn "Changeto Blank"
        Do_it!
        ClearAll
   
        {Ask} TypeIn Tabela Enter
        Moveto [Codigo do Destinatario  ] Example "Cod"
        Moveto [Numero Lancamento Pai   ] TypeIn "Changeto _CodG"
        Moveto [Descricao               ] TypeIn "Changeto _DesG" 
        {Ask} {\\Sistemas\\Cadastro\\GPessoaI}
        Moveto [Codigo                  ] Example "Cod"
        Moveto [CodigoGrupoPessoa       ] Example "CodG"
        {Ask} {\\Sistemas\\Cadastro\\GPessoaC}
        Moveto [CodigoGrupoPessoa       ] Example "CodG"
        Moveto [DescricaoGrupoPessoa    ] Example "DesG" 
        Do_it!
        ClearAll
        
        ;Incluido em 18/12/2018 pois TABELA havia campo chave e p/ o caso a baixo nao poderia ter chave primaria
        {Ask} TypeIn Tabela Enter Check
        Do_it!
        ClearAll
        Copy "Answer" Tabela
        
        Sort Tabela On "Numero Lancamento Pai"
        ClearAll
        
        {Ask} TypeIn Tabela Enter
        Moveto [Numero Lancamento Pai   ] TypeIn "Blank"
        Moveto [Descricao               ] TypeIn "Changeto CLIENTES SEM VINCULOS"
        Do_it!
        ClearAll
EndIf 

EndProc  ;Processa_RM0087()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp = True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf   
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : ListaRegra_F2()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"      : Campo="NO"        
            Case Campo="TG_DESTINAT"       : Campo="TG_EMPRESATE"     
            Case Campo="TG_GERENCIA"       : Campo="TG_DESTINAT"
            Case Campo="TG_REPRESEN"       : Campo="TG_GERENCIA"      
            Case Campo="TG_CIDADE"         : Campo="TG_REPRESEN"
            Case Campo="TG_ESTADO"         : Campo="TG_CIDADE"
            Case Campo="TG_CONTA"          : Campo="TG_ESTADO"        
            Case Campo="TG_OPDTEMISVENC"   : Campo="TG_CONTA"         
            Case Campo="TG_DTINI"          : Campo="TG_OPDTEMISVENC"  
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"         
            Case Campo="TG_SITUACAOCLIENTE"      : Campo="TG_DTFIM"         
            Case Campo="TG_TPPAGTO"        : Campo="TG_SITUACAOCLIENTE"         
            Case Campo="TG_TPCART"         : Campo="TG_TPPAGTO"       
            Case Campo="TG_DDPROTESTO"     : Campo="TG_TPCART"        
            Case Campo="TG_OPRELCODALF"    : Campo="TG_DDPROTESTO"   
            Case Campo="TG_CODMODELO"      : Campo="TG_OPRELCODALF"   
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch                                                
                    Case Campo="TG_EMPRESATE"      : Campo="TG_DESTINAT"         
                    Case Campo="TG_DESTINAT"       : Campo="TG_GERENCIA"
                         VSDGOPSIT    = "1"
                         VSDGNOMOPSIT = "Todas"      
                    Case Campo="TG_GERENCIA"       : Campo="TG_REPRESEN"
                    Case Campo="TG_REPRESEN"       : Campo="TG_CIDADE"      
                    Case Campo="TG_CIDADE"         : Campo="TG_ESTADO"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf         
                    Case Campo="TG_ESTADO"         : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"          : Campo="TG_OPDTEMISVENC"  
                    Case Campo="TG_OPDTEMISVENC"   : Campo="TG_DTINI"         
                    Case Campo="TG_DTINI"          : Campo="TG_DTFIM"         
                    Case Campo="TG_DTFIM"          : Campo="TG_SITUACAOCLIENTE"         
                    Case Campo="TG_SITUACAOCLIENTE": Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"        : Campo="TG_TPCART"        
                    Case Campo="TG_TPCART"         : Campo="TG_DDPROTESTO"    
                    Case Campo="TG_DDPROTESTO"     : Campo="TG_OPRELCODALF"    
                    Case Campo="TG_OPRELCODALF"    : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"      : Campo="YES"  
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO" :
       MSG_CAMPO="Informe o Numero de Dias"
  Case Campo=""      :
       MSG_CAMPO=""
  Case Campo="TG_DDPROTESTO":
       MSG_CAMPO="Informe o Numero de Dias"            
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("01A Cliente/Vencimento")                                           ;RM_0080 
ModeloRelatoriosAdd("01B Sint‚tico por Cliente/Vencimento")                             ;RM_0080
ModeloRelatoriosAdd("01C Sint‚tico por Ranking")                                        ;RM_0080
ModeloRelatoriosAdd("01D Sint‚tico por Ranking/Valor Original")                         ;RM_0080                         
ModeloRelatoriosAdd("01E Saldo Anterior")                                               ;RM_0080
ModeloRelatoriosAdd("Separator")                                                                   
ModeloRelatoriosAdd("23A Por Vencimento + Cheque Pendente (Somente a Descontar)")       ;RM_0081
ModeloRelatoriosAdd("23B Por Vencimento + Cheque Pendente (a Descontar + SEM FUNDO)")   ;RM_0081
ModeloRelatoriosAdd("Separator")    
ModeloRelatoriosAdd("30A Por Vencimento/Emissao + Fone/Contato")                        ;RM_0082                          
ModeloRelatoriosAdd("30B Por Vencimento/Emissao + Fone/Contato c/ clientes vinculados") ;RM_0082
ModeloRelatoriosAdd("75  Por Vencimento/Emissao + Fone/Contato II")                     ;RM_0096B
ModeloRelatoriosAdd("Separator")   
ModeloRelatoriosAdd("66  Por Vencimento/Emissao + Observa‡Æo")                          ;RM_0087
ModeloRelatoriosAdd("50  Por Vencimento/Emissao - Modelo Bobina")                       ;RM_0080C
ModeloRelatoriosAdd("48  Por Vencimento/Emissao + Cliente")                             ;RM_0095
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()
SYS_VALOR()

VSDGEMPRESA   =""
VSDGDESTINAT  =""
VSDGTPCART    =""
VSDGTPPAGTO   =""
VSDGDDPROTESTO=""
VSDGDTINI     =BlankDate()
VSDGDTFIM     =BlankDate()
VSDGOPSITCLIE = ""
VSDGCONTA     = ""
VSDGCIDADE    =""
VSDGESTADO    =""
CIDADE        =""
VSDGOPRELCODALF= ""
VSDGSITUACAOCLIENTE    = ""

ModeloRelatoriosCarregaLista()
           
ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPPAGTO],[TG_TPCART],[TG_SITUACAOCLIENTE]")   
          
While True
  ShowDialog "Titulos a Receber por Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
    -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"   
    @ 05,12   Height 22 Width 80
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST

    Label  @ 04,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 05,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA
    
    Label  @ 06,00 "Representante"  For "TG_REPRESEN"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMREPR"  To VSDGNOMREPR

    Label  @ 08,00 "Cidade"  For "TG_CIDADE"
    Accept @ 09,01 Width 27 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE
                                   
    Label  @ 08,27 "Estado"  For "TG_ESTADO"
    Accept @ 09,28 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    
    Label  @ 10,00 "Conta"  For "TG_CONTA"
    Accept @ 11,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
  	Accept @ 11,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 12,00 "Op‡äes de Datas" For "TG_OPDTEMISVENC"
    Accept @ 13,04 Width 04 "A1"  Picture "1,2"  Tag "TG_OPDTEMISVENC"    To VSDGOPDTEMISVENC
    Accept @ 13,09 Width 25 "A20" Picture "!*!"  Tag "TG_NOMOPDTEMISVENC" To VSDGNOMOPDTEMISVENC

    Label  @ 14,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 15,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 15,16 "at‚" For "TG_DTFIM"
    Accept @ 15,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 00,35 "Situa‡Æo do Cliente" For "TG_SITUACAOCLIENTE"
    Accept @ 01,36 Width 33 "A30" Picture "!*!" Tag "TG_SITUACAOCLIENTE" To VSDGSITUACAOCLIENTE

    Label  @ 02,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 03,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 04,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 05,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 05,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART
    
    Label  @ 06,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 07,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 07,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 08,35 "Op‡„o de Ordem" For "TG_OPRELCODALF"
    Accept @ 09,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 09,44 Width 25 "A12" Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  Switch
    Case VSDGCODMODELO="66"  Or    
         VSDGCODMODELO="50"  Or
         VSDGCODMODELO="48"  Or
         VSDGCODMODELO="30A" Or
         VSDGCODMODELO="30B" Or
         VSDGCODMODELO="75"   :  
         
         AGUARDE("Aguarde, Processando Dados")
         Tabela=Cria_Temp(PrivDir())

         Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
         While Novo_Dir_Trab()
           If IsTable("Answer")     Then Delete "Answer" EndIf
           Seleciona_RM0087()
           If Not IsTable("Answer") Then Loop EndIf
           If IsTable(Tabela)
              Then Add "Answer" Tabela
              Else Rename "Answer" Tabela
           EndIf
         EndWhile
         
         If IsEmpty(Tabela)
            Then MENSAGEM("N„o existem registros a processar")
                 Delete Tabela
                 Loop
         EndIf
         Processa_RM0087()
         Switch
          
          Case VSDGCODMODELO="66"   : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001" "9"  Tabela "R"
          Case VSDGCODMODELO="50"   : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001" "1"  Tabela "R"
          Case VSDGCODMODELO="48"   : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "12" Tabela "R"
          Case VSDGCODMODELO="30A"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "11" Tabela "R"
          Case VSDGCODMODELO="30B"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1100" "R"  Tabela "R"
          Case VSDGCODMODELO="75"   : If SYS_CODIGO_CLIENTE="0298"
                                         Then Impressao_Orientacao="Paisagem"
                                              CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001A" "1" Tabela "R"
                                         Else CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1001A" "R" Tabela "R"
                                      EndIf
        EndSwitch
        if VSDGOPRELCODALF="1" then Seta_Ordem_Report(Tabela,"R","Razao Social","Codigo do Destinatario","") endif
        IMPRIREL(Tabela,"R")
        Delete Tabela 
    Case VSDGCODMODELO="23A" Or
         VSDGCODMODELO="23B"  : Play "RM_0081A"
    Case VSDGCODMODELO="01A" Or
         VSDGCODMODELO="01B" Or
         VSDGCODMODELO="01C" Or
         VSDGCODMODELO="01D" Or
         VSDGCODMODELO="01E"  : Play "RM_0080A"             
  EndSwitch
EndWhile
ClearAll
Release Vars All
Release Procs All
