;** GR_0106 ********************************************************************
;*  Grafico de Fatia de Pedidos por Representante                              *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 28/04/2008 por Anivel Augusto Rodrigues
;Ultima Alteracao: 08/10/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtragem por Estado
;Ultima Alteracao: 06/12/2010 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes de criterios
;Ultima Alteracao: 19/09/2011 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes 0000 TOTAL EMPRESAS
;Ultima Alteracao: 24/07/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes Diret¢rio Mˆs Fechado
;Ultima Alteracao: 03/10/2012 por Kamila Gomes          
;Motivo Alteracao: Ajustes nos Titulos do Grafico 
;Ultima Alteracao: 13/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 29/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes MensagemCheckBoxes()                    
;Ultima Alteracao: 27/11/2018 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro gerencia                   
;Ultima Alteracao: 28/04/2021 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado filtro "Situa‡Æo do Pedido"
;Ultima Alteracao: 04/05/2021 por Bruno Carvalho                                     
;Motivo Alteracao: Ajuste para a formata‡Æo da exibi‡Æo do valor total, valor com ****  

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

If IsTable("\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC")
   Then 
       {Ask} TypeIn "\\Sistemas\\Cadastro\\Represen" Enter
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Codigo da Gerencia     ] TypeIn "~VSDGGERENCIA.."

        {Ask} {\\Sistemas\\Vendas\\Destin}
        Moveto [Codigo da Destinacao  ] Example "cd"
        Moveto [Tipo Movimento Estoque] TypeIn "S"
        
        {Ask} TypeIn "\\Sistemas\\Vendas\\"+Dir_Trab+"PedidoC" Enter
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
        Moveto [UF                     ] TypeIn "~VSDGESTADO.."
        Moveto [Data de Emissao        ] TypeIn ">=~VSDGDTINI, <=~VSDGDTFIM"
        Moveto [Valor Nota Fiscal      ] TypeIn "Calc Sum as Valor Total"
        Moveto [Codigo do Representante] Example "crep"
        Moveto [Nome Fantasia Represent] Check
        Moveto [Codigo da Destinacao   ] Example "cd"
        Moveto [Descricao da Destinacao] TypeIn "..VEND.."
        Moveto [Situacao do Pedido     ] 
        Switch
          Case VSDGSITUACAOPEDIDO="JUNTAR ABERTO+SUSPENSO"     : TypeIn "ABERTO or SUSPENSO"
          Case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO+SUSPENSO" : TypeIn "not CANCELADO, not SUSPENSO"
          Case VSDGSITUACAOPEDIDO="IGNORAR CANCELADO"          : TypeIn "not CANCELADO"
          Case VSDGSITUACAOPEDIDO<>"TODAS"                     : TypeIn "~VSDGSITUACAOPEDIDO.."
        EndSwitch
        Do_It!
        ClearAll
EndIf        
EndProc

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc PROCESSA()
ClearAll

{Ask} TypeIn Tabela Enter
Moveto [Nome Fantasia Represent] Check
Moveto [Valor Total            ] TypeIn "Calc Sum as Valor Total"
Do_It!
ClearAll

Sort "Answer" on "Valor Total" D

CoEdit "Answer"
;;SetHighLight Current Record 23 Field 31
Moveto [Valor Total]
VRTOT=ImagecSum()
VRABC=0
VRDIF=0
While Not EOT()
  VRABC=VRABC+[Valor Total]
  TX_CALCABC=((VRABC*100)/VRTOT)
  If TX_CALCABC>VSDGTXPIZZA
     Then VRDIF=VRDIF+[Valor Total]
          Del
          If TX_CALCABC>=100
             Then QuitLoop
             Else Loop
          EndIf
  EndIf
  Skip
EndWhile
If VRDIF>0 And Not CheckTG_OPPIZZA[1]
   Then End Down
        [Nome Fantasia Represent]="[OUTROS]"
        [Valor Total       ]=VRDIF
EndIf
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = 9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESA"       : Campo="NO"
            Case Campo="TG_GERENCIA"      : Campo="TG_EMPRESA"
            Case Campo="TG_ESTADO"        : Campo="TG_GERENCIA"
            Case Campo="TG_DTINI"         : Campo="TG_ESTADO"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_SITUACAOPEDIDO" : Campo="TG_DTFIM"
            Case Campo="TG_TXPIZZA"       : Campo="TG_SITUACAOPEDIDO"
            Case Campo="TG_OPPIZZA"       : Campo="TG_TXPIZZA"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESA"    : Campo="TG_GERENCIA"
                    Case Campo="TG_GERENCIA"   : Campo="TG_ESTADO"
                    Case Campo="TG_ESTADO"     : Campo="TG_DTINI"     
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_SITUACAOPEDIDO"
                    Case Campo="TG_SITUACAOPEDIDO" : Campo="TG_TXPIZZA" 
                    Case Campo="TG_TXPIZZA"    : Campo="TG_OPPIZZA"
                    Case Campo="TG_OPPIZZA"    : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="":
     MSG_CAMPO=""
  Case Campo="TG_DTINI":
     MSG_CAMPO="Informe a Data Inicial"
  Case Campo="TG_OPPIZZA":    
       MensagemCheckBoxes()     
Endswitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot"
LimpAguarde()

VSDGEMPRESA = ""
VSDGGERENCIA = ""
VSDGESTADO  = ""
VSDGSITUACAOPEDIDO=""
VSDGDTINI   = BlankDate()
VSDGDTFIM   = BlankDate()
            
VSDGTXPIZZA  =100
Array TG_OPPIZZA[1]
TG_OPPIZZA[1]=""
Array CheckTG_OPPIZZA[ArraySize(TG_OPPIZZA)]
CheckTG_OPPIZZA[1]=False

While True
  ShowDialog "Fatia de pedidos por representante" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
   @ 06,12   Height 17 Width 72

    Label  @ 00,00 "Empresa"  For "TG_EMPRESA"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA"    To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMPRESA" To VSDGNOMEMP

    Label  @ 02,00 "Gerˆncia " For "TG_GERENCIA"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_GERENCIA" To VSDGGERENCIA
    Accept @ 03,09 Width 25 "A10"  Picture "!*!" Tag "TG_DESCGERENCIA" To VSDGDESCGERENCIA

    Label  @ 04,00 "Estado"  For "TG_ESTADO"
    Accept @ 05,01 Width 07 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMESTADO"  To VSDGNOMESTADO

    Label  @ 06,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 07,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 07,16 "at‚" For "TG_DTFIM"
    Accept @ 07,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 08,00 "Situacao do Pedido"  For "TG_SITUACAOPEDIDO"
    Accept @ 09,01 Width 33 "A30"  Picture "ABERTO,SUSPENSO,CANCELADO,FATURADO,TODAS,!*!" Tag "TG_SITUACAOPEDIDO"  To VSDGSITUACAOPEDIDO

    Label  @ 10,00 "% An lise" For "TG_TXPIZZA"
    Accept @ 11,01 Width 06 "S" Tag "TG_TXPIZZA" To VSDGTXPIZZA
                                                                  
    CheckBoxes @ 11,07 Height 1 Width 5 Tag "TG_OPPIZZA"
    TG_OPPIZZA[1] to CheckTG_OPPIZZA[1]
    Accept @ 11,11 Width 23 "A35" Tag "TG_OPPIZZA" To VSDGDSCPIZZA

    Pushbutton @ 13,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 13,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If VSDGEMPRESA=""
     Then Mensagem("Empresa Invalida !")
          Loop
  EndIf
  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf
  If ((IsBlank(VSDGDTINI) or IsBlank(VSDGDTFIM))) or
     (VSDGDTINI>VSDGDTFIM)
     Then Mensagem("Data Invalida !")
          Loop
  EndIf

  DISPOSITIVOG()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Gerando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  GRAF_TAB= "Answer"
  GRAF_TIPO= "P"
  If VSDGESTADO="" 
     Then GRAF_TIT1= "Fatia de Pedidos por Representante no Per¡odo de "+StrVal(VSDGDTINI)+" a "+StrVal(VSDGDTFIM)
     Else GRAF_TIT1= "Fatia de Pedidos por Representante no Estado de "+VSDGNOMESTADO+" de "+StrVal(VSDGDTINI)+" a "+StrVal(VSDGDTFIM)
  EndIf  
  GRAF_TIT2= "Empresa: "+VSDGEMPRESA+"-"+VSDGNOMEMP+" [ Total: "+LTrim(Format("W15.2,EIC",VRTOT))+" ]"
  GRAF_LENG= "Y"

  MONTAGRAFICO(GRAF_TAB)

  Delete "Answer"
  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs All

