;** Rm_0230  *******************************************************************
;*  Emissao dos Titulos a Receber por Cidade/Cliente/Vencto                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 03/12/1999 por Anivel Augusto Rodrigues
;Ultima Alteracao: 14/05/2003 por Karen Lauar Nery
;Motivo Alteracao: Mudan‡a Base
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 25/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Correcao Data de Vencimento em Branco
;Ultima Alteracao: 02/12/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado Filtro por Conta
;Ultima Alteracao: 15/08/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes "0228" rotina criada pra informar a Condi‡Æo de Pagamento do Titulo
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 24/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 09/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0083" (31) neste script "RM_0230" (35)                   
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento 
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 11/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO]
;Ultima Alteracao: 26/04/2021 por Bruno Carvalho             
;Motivo Alteracao: Alterado TG_SITUACAO p/ TG_SITUACAOCLIENTE

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc SELECIONA()
ClearAll

If IsTable("\\Sistemas\\Cadastro\\Destinat") And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")
   Then {Ask} TypeIn "\\Sistemas\\Cadastro\\Destinat" Enter
        Moveto [Codigo   ] Example "cli"
        Moveto [Cidade   ] Check TypeIn CIDADE
        Moveto [UF       ]       TypeIn "~VSDGESTADO.."
        If VSDGCODMODELO="31"
           Then Moveto [UF       ] check 
                Moveto [Telefone ] check
                Moveto [Contato  ] check
        EndIf        
        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Destinatario] Example "cli" TypeIn ", ~VSDGDESTINAT.."
        Moveto [Codigo da Conta       ] TypeIn "~VSDGCONTA.."
        Switch
          Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
          Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
        EndSwitch   
        Switch                                                                                         
          Case ListaRegra_VSDGTPCART_Ativo          : Moveto [Tipo do Lancamento] TypeIn ListaRegra_VSDGTPCART
          Case VSDGTPCART<>""                       : Moveto [Tipo do Lancamento] TypeIn "~VSDGTPCART.."
          Case VSDGTPCART="" And VSDGCODMODELO="31" : Moveto [Tipo do Lancamento] TypeIn "Not P, Not J"
        EndSwitch
        Moveto [Data de Vencimento    ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"        
        Moveto [Saldo do Documento    ] TypeIn "> 0.01"
        Do_It!
        ClearAll
EndIf

If VSDGSITUACAOCLIENTE<>"" And VSDGSITUACAOCLIENTE<>"TODAS"
  Then  {Ask} {\\Sistemas\\Cadastro\\Destinat}
        Moveto [Codigo             ] Example "codigo"
        Switch
          Case ListaRegra_VSDGSITUACAOCLIENTE_Ativo : Moveto [Situacao do Cliente] TypeIn ListaRegra_VSDGSITUACAOCLIENTE
          Case VSDGSITUACAOCLIENTE<>"TODAS"         : Moveto [Situacao do Cliente] TypeIn "~VSDGSITUACAOCLIENTE.."
        EndSwitch
        {Ask} {Answer} Check
        Moveto [Codigo do Destinatario] Example "codigo"
        Do_It!
        ClearAll
EndIf

EndProc
                                              
;*******************************************************************************
;* Rotina p/ Processar db Temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan For Not IsBlank([Data de Vencimento])
   If [Data de Vencimento]<Today()
      Then NDA=Today()-[Data de Vencimento]
           TXM=[Multa]
           [Observacoes]="Vencida"
      Else NDA=0
           TXM=0
           [Observacoes]=""
   EndIf
   If (Today()-[Data de Vencimento])>=NumVal(VSDGDDPROTESTO)
       Then If [Descricao do Lancamento]="PROTESTADA"
               Then [Observacoes]="Cartorio"
               Else [Observacoes]="Protestar"
            EndIf
   EndIf

   If [Data Limite Desconto]>=Today()
      Then VRDESCT=[Valor do Desconto]
      Else VRDESCT=0
   EndIf

   If [Taxa de Juros]>0
      Then TXJ=([Taxa de Juros]/[NDias Taxa de Juros])*NDA
           VRJUROS=(([Saldo do Documento]*TXJ)/100)+([Saldo do Documento]*TXM/100)
      Else VRJUROS=(([Valor de Juros]/[NDias Taxa de Juros])*NDA)
           VRJUROS=VRJUROS+(([Saldo do Documento]*TXM)/100)
   EndIf

   [Valor do Documento]=([Saldo do Documento]+VRJUROS)-VRDESCT
   [Valor do Desconto ]=VRJUROS+(VRDESCT*-1)

EndScan
Do_It!
ClearAll

If VSDGCODMODELO="31"
   Then Ordem_Campo_Tabela(Tabela,"Codigo da Empresa,Nome Fantasia Empresa,Numero do Lancamento,Codigo do Destinatario,Razao Social,Contato,Telefone,UF,Cidade")
EndIf   

EndProc    ; (Processa)

;*******************************************************************************
;* Rotina para verificar a Condi‡Æo de Pagamento do Titulo                     *
;*******************************************************************************
Proc Condicao_Pagamento()

{Ask} TypeIn Tabela Enter 
Moveto [Numero_Carregamento_Cheq] TypeIn "Changeto Blank"
Moveto [Observacoes             ] TypeIn "Changeto Blank"
Do_It!
ClearAll

{Ask} TypeIn Tabela Enter 
Moveto [Numero Docto Gerador    ] Example "NDoc"
Moveto [Sistema Gerador         ] TypeIn "FT"
Moveto [Numero_Carregamento_Cheq] TypeIn "Changeto " Example "CPgto"
{Ask} {\\Sistemas\\Vendas\\Notac}
Moveto [Numero do Documento     ] Example "NDoc"
Moveto [Condicao de Pagamento   ] Example "CPgto"
Do_It!
ClearAll

CoEdit Tabela
Scan
  [Observacoes]=[Numero_Carregamento_Cheq]+" "+[Observacoes]
EndScan
Do_It!
ClearAll

EndProc ;(Condicao_Pagamento)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : ListaRegra_F2()     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch             
            Case Campo="TG_EMPRESATE"      : Campo="NO"     
            Case Campo="TG_DESTINAT"       : Campo="TG_EMPRESATE"
            Case Campo="TG_CIDADE"         : Campo="TG_DESTINAT"
            Case Campo="TG_ESTADO"         : Campo="TG_CIDADE"
            Case Campo="TG_CONTA"          : Campo="TG_ESTADO"
            Case Campo="TG_DTINI"          : Campo="TG_CONTA"     
            Case Campo="TG_DTFIM"          : Campo="TG_DTINI"     
            Case Campo="TG_DDPROTESTO"     : Campo="TG_DTFIM"     
            Case Campo="TG_TPPAGTO"        : Campo="TG_DDPROTESTO"
            Case Campo="TG_TPCART"         : Campo="TG_TPPAGTO"   
            Case Campo="TG_SITUACAOCLIENTE": Campo="TG_TPCART"
            Case Campo="TG_CODMODELO"      : Campo="TG_SITUACAOCLIENTE"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch                              
                    Case Campo="TG_EMPRESATE"  : Campo="TG_DESTINAT"  
                    Case Campo="TG_DESTINAT"   : Campo="TG_CIDADE"    
                    Case Campo="TG_CIDADE"     : Campo="TG_ESTADO"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                    Case Campo="TG_ESTADO"     : Campo="TG_CONTA"           
                    Case Campo="TG_CONTA"      : Campo="TG_DTINI"     
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"     
                    Case Campo="TG_DTFIM"      : Campo="TG_DDPROTESTO"
                    Case Campo="TG_DDPROTESTO" : Campo="TG_TPPAGTO"   
                    Case Campo="TG_TPPAGTO"    : Campo="TG_TPCART"    
                    Case Campo="TG_TPCART"     : Campo="TG_SITUACAOCLIENTE"  
                    Case Campo="TG_SITUACAOCLIENTE": Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_DDPROTESTO":
       MSG_CAMPO="Informe o Numero de Dias"
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("31  Cliente/Data de Vencimento")                           ;RM_0083
ModeloRelatoriosAdd("35  Cliente/Data de Vencimento + Fone/Contato")            ;RM_0230
ModeloRelatoriosAdd("Fim")

EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()
VSDGEMPRESA    = ""
VSDGTPPAGTO    = ""
VSDGDDPROTESTO = ""
VSDGCIDADE     = ""
VSDGESTADO     = ""
VSDGSITUACAOCLIENTE    = ""
VSDGDTINI      = BlankDate()
VSDGDTFIM      = BlankDate()

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPCART],[TG_TPPAGTO],[TG_SITUACAOCLIENTE]")

ModeloRelatoriosCarregaLista()

While True
  ShowDialog "T¡tulos a Receber por Cidade/Cliente" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"     
   @ 05,12   Height 18 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 03,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 03,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST    

    Label  @ 04,00 "Cidade"  For "TG_CIDADE"
    Accept @ 05,01 Width 27 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE
                                   
    Label  @ 04,27 "Estado"  For "TG_ESTADO"
    Accept @ 05,28 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO

    Label  @ 06,00 "Conta"  For "TG_CONTA"
    Accept @ 07,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 08,00 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 09,03 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 09,16 "at‚" For "TG_DTFIM"
    Accept @ 09,21 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM
    
    Label  @ 00,35 "Protestar ap¢s"  For "TG_DDPROTESTO"
    Accept @ 01,36 Width 07 "A4"  Picture "#*#" Tag "TG_DDPROTESTO" To VSDGDDPROTESTO
    Label  @ 01,43 "Dias em atraso"  For "TG_DDPROTESTO"

    Label  @ 02,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 03,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 03,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO
    
    Label  @ 04,35 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 05,39 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 05,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART
    
    Label  @ 06,35 "Situa‡Æo do Cliente" For "TG_SITUACAOCLIENTE"
    Accept @ 07,36 Width 33 "A30" Picture "!*!" Tag "TG_SITUACAOCLIENTE" To VSDGSITUACAOCLIENTE
    
    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO    
    
    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue
  EndDialog

  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf
  
  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf
  
  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile
  
  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  If SYS_CODIGO_CLIENTE="0228" And VSDGCODMODELO<>"31"
     Then Condicao_Pagamento()
  EndIf   
  
  Switch
    Case VSDGCODMODELO="31" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1000" "8" Tabela "R"
    Case VSDGCODMODELO="35" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_0230" "R" Tabela "R"
  EndSwitch
  IMPRIREL(Tabela,"R")
  Delete Tabela 
EndWhile
ClearAll
Release Vars All
Release Procs All