;** P_Orca *********************************************************************
;*  Configuracao de Paramentos p/ Orcamento                                    *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 21/08/2000 por Douglas Rodrigues
;Ultima Alteracao: 28/09/2004 por Davi Pereira Carrano
;Motivo Alteracao: Acrescimo campos: Utiliza_TabPreco_Repres
;Ultima Alteracao: 04/08/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: Acrescimo campos: Exibe_Custo_Item_Consulta
;Ultima Alteracao: 17/06/2011 por Karina Andrade
;Motivo Alteracao: Ajustes TECLAS
;Ultima Alteracao: 16/08/2012 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ 11 Colunas "Script Impressao" e "Script Gravacao"
;Ultima Alteracao: 12/03/2013 por Kamila Gomes
;Motivo Alteracao: Adicionado campo "Altera Preco Unitario"
;Ultima Alteracao: 13/03/2013 por Kamila Gomes
;Motivo Alteracao: Adicionado campos de desconto
;Ultima Alteracao: 04/05/2021 por Bruno Carvalho
;Motivo Alteracao: Adicionado parƒmetro VSD_UTILIZA_EMAIL  

;*******************************************************************************
;* Rotina de Controle de Paramentros                                           *
;*******************************************************************************
Proc PARAM_DIALOG(Disparo,Campo,Evento,Elemento)
Temp=True

TECLA   =""
MSGCAMPO=""
If INICIO_DIALOGO
   Then INICIO_DIALOGO=False
EndIf
If Disparo="OPEN"
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf

If Disparo="EVENT" And DynArraySize(Evento)>0 And Evento["Type"]="KEY" Then
   Switch
     Case (Evento["KeyCode"] = -6 Or Evento["KeyCode"] = -147):
          If CHAVE=0
             Then Confirma()
                  If OK="S"
                     Then Del
                          PARAM_OPCAO("Inicio")
                          Campo="I_EMPRESA"
                  EndIf
           EndIf
      Case Evento["KeyCode"] = 9:
           Temp=False
      Case Evento["KeyCode"] = -59:
            If Campo="I_EMPRESA" Or
               Campo="I_DESTINACAO" Or
               Campo="I_TABELA_PRECO" Or
               Campo="I_TRANSPORTADORA"
               Then
                    Dynarray WinArray5[]
                    Window Handle Dialog to JANELA
                    Window GetAttributes JANELA To WinArray5
                    WinArray5["FLOATING"]=False
                    Window SetAttributes JANELA From WinArray5

                    If Campo="I_EMPRESA"        Then Moveto [Codigo_Empresa       ] EndIf
                    If Campo="I_DESTINACAO"     Then Moveto [Codigo_Destinacao    ] EndIf
                    If Campo="I_TABELA_PRECO"   Then Moveto [Tabela_Preco         ] EndIf
                    If Campo="I_TRANSPORTADORA" Then Moveto [Codigo_Transportadora] EndIf
                    ConsultaF1()

                    Window Select JANELA
                    WinArray5["FLOATING"]=True
                    Window SetAttributes JANELA From WinArray5

                    echo Normal
                    echo off

                    Switch
                      Case Campo="I_EMPRESA":
                           VSD_EMPRESA=[Codigo_Empresa]
                      Case Campo="I_DESTINACAO":
                           VSD_DESTINACAO=[Codigo_Destinacao]
                      Case Campo="I_TABELA_PRECO":
                           VSD_TABELA_PRECO=[Tabela_Preco]
                      Case Campo="I_TRANSPORTADORA":
                           VSD_TRANSPORTADORA=[Codigo_Transportadora]
                    EndSwitch
           EndIf
      Case Evento["KeyCode"] = 27:
           Switch
             Case Campo="I_EMPRESA"             :
                  If IsBlank([Codigo_Empresa])
                     Then Del
                  EndIf
                  Home
                  If IsBlank([Codigo_Empresa])
                     Then Del
                  EndIf
                  CancelDialog
             Case Campo="I_DESTINACAO"          :
                  If Chave=1
                     Then Moveto [Codigo_Empresa]
                          Locate VSD_EMPRESA
                          Del
                  EndIf
                  PARAM_OPCAO("Inicio")
                  Campo="I_EMPRESA"
             Case Campo="I_TABELA_PRECO"  : Campo= "I_DESTINACAO"
             Case Campo="I_TRANSPORTADORA": Campo= "I_TABELA_PRECO"
             Case Campo="I_DESCTO"        : Campo= "I_TRANSPORTADORA"
             Case Campo="I_TPDESCTO"      : Campo= "I_DESCTO"
             Case Campo="I_TXDESCTO"      : Campo= "I_TPDESCTO"
             Case Campo="I_DESCUNIT"      : Campo= "I_DESCTO"
             Case Campo="I_DESCTOUNIT"    : Campo= "I_DESCUNIT"
             Case Campo="I_TPDESCTOUNIT"  : Campo= "I_DESCTOUNIT"
             Case Campo="I_TXDESCTOUNIT"  : Campo= "I_TPDESCTOUNIT"
             Case Campo="I_LOCAL"         : Campo= "I_TXDESCTOUNIT"
             Case Campo="I_ALTERA_PRECO"  : Campo= "I_LOCAL"
             Case Campo="I_IMPOSTOS"      : Campo= "I_ALTERA_PRECO"
             Case Campo="I_IMPRESSAO"     : Campo= "I_IMPOSTOS"
             Case Campo="I_GRAVACAO"      : Campo= "I_IMPRESSAO"
;             Case Campo="I_TABPR_CPAGTO"  : Campo= "I_GRAVACAO"
;             Case Campo="I_TABPR_REPRES"  : Campo="I_GRAVACAO"
             Case Campo="I_TABPR_CLIENTE" : Campo="I_GRAVACAO"
             Case Campo="I_EXIBE_CUSTO"   : Campo="I_TABPR_CLIENTE"
             Case Campo="I_UTILIZA_EMAIL" : Campo="I_EXIBE_CUSTO"
           EndSwitch

      Case Evento["KeyCode"] = 13:
           Switch
             Case Campo="I_EMPRESA":
                  VSD_EMPRESA=ControlValue("I_EMPRESA")
                  If Not IsBlank(VSD_EMPRESA)
                     Then VSD_EMPRESA=Alinhm(VSD_EMPRESA,4)
                          Moveto [Codigo_Empresa]
                          Ativa_Lookup()
                          Locate VSD_EMPRESA
                          If Not RetVal
                             Then Mensagem("Codigo n„o Cadastrado !")
                                  KeyPress "ESC"
                             Else VSD_EMPRESA=[Codigo da Empresa]
                                  KeyPress "ESC"
                                  Chave()
                                  Campo="I_DESTINACAO"
                          EndIf
                  EndIf
             Case Campo="I_DESTINACAO":
                  VSD_DESTINACAO=ControlValue("I_DESTINACAO")
                  If Not IsBlank(VSD_DESTINACAO)
                     Then VSD_DESTINACAO=AlinhM(VSD_DESTINACAO,3)
                          Moveto [Codigo_Destinacao]
                          Ativa_Lookup()
                          Moveto [Codigo da Destinacao]
                          Locate VSD_DESTINACAO
                          If RetVal
                             Then Campo= "I_TABELA_PRECO"
                             Else Mensagem("Destina‡„o n„o Cadastrada !")
                          EndIf
                          KeyPress "ESC"
                     Else Campo= "I_TABELA_PRECO"
                  EndIf
             Case Campo="I_TABELA_PRECO":
                  VSD_TABELA_PRECO=ControlValue("I_TABELA_PRECO")
                  If Not IsBlank(VSD_TABELA_PRECO)
                     Then Moveto [Tabela_Preco]
                          Ativa_Lookup()
                          Moveto [Codigo da Tabela]
                          Locate VSD_TABELA_PRECO
                          If RetVal
                             Then Campo= "I_TRANSPORTADORA"
                             Else Mensagem("Tabela de Pre‡o n„o Cadastrada !")
                          EndIf
                          KeyPress "ESC"
                     Else Campo= "I_TRANSPORTADORA"
                  EndIf
             Case Campo="I_TRANSPORTADORA":
                  VSD_TRANSPORTADORA=ControlValue("I_TRANSPORTADORA")
                  If Not IsBlank(VSD_TRANSPORTADORA)
                     Then VSD_TRANSPORTADORA=Alinhm(VSD_TRANSPORTADORA,4)
                          Moveto [Codigo_Transportadora]
                          Ativa_Lookup()
                          Moveto [Codigo da Transportadora]
                          Locate VSD_TRANSPORTADORA
                          If RetVal
                             Then Campo= "I_DESCTO"
                             Else Mensagem("Transportadora n„o Cadastrada !")
                          EndIf
                          KeyPress "ESC"
                     Else Campo= "I_DESCTO"
                  EndIf
             Case Campo="I_DESCTO":
                  VSD_DESCTO=ControlValue("I_DESCTO")
                  If IsBlank(VSD_DESCTO)
                     Then VSD_DESCTO="N"
                  EndIf
                  If VSD_DESCTO="N"
                     Then VSD_TPDESCTO=""
                          VSD_TXDESCTO=BlankNum()
                          Campo= "I_DESCUNIT"
                     Else Campo="I_TPDESCTO"
                  EndIf
             Case Campo="I_TPDESCTO":
                  VSD_TPDESCTO=ControlValue("I_TPDESCTO")
                  If IsBlank(VSD_TPDESCTO)
                     Then VSD_TPDESCTO="I"
                  EndIf
                  If VSD_TPDESCTO="I"
                     Then Campo="I_TXDESCTO"
                     Else VSD_TXDESCTO=BlankNum()
                          Campo= "I_DESCUNIT"
                  EndIf
             Case Campo="I_TXDESCTO":
                  VSD_TXDESCTO=ControlValue("I_TXDESCTO")
                  Campo= "I_DESCUNIT"
                  
              Case Campo="I_DESCUNIT":
                  VSD_DESCUNIT=ControlValue("I_DESCUNIT")
                  If IsBlank(VSD_DESCUNIT) Or
                     VSD_DESCUNIT="N"
                     Then VSD_DESCUNIT    ="N"
                          VSD_DESCTOUNIT  ="N"
                          VSD_TPDESCTOUNIT=""
                          VSD_TXDESCTOUNIT=BlankNum()
                          Campo="I_LOCAL"
                     Else Campo="I_DESCTOUNIT"
                  EndIf
             Case Campo="I_DESCTOUNIT":
                  VSD_DESCTOUNIT=ControlValue("I_DESCTOUNIT")
                  If IsBlank(VSD_DESCTOUNIT)
                     Then VSD_DESCTOUNIT="N"
                  EndIf
                  If VSD_DESCTOUNIT="N"
                     Then VSD_TPDESCTOUNIT=""
                          VSD_TXDESCTOUNIT=BlankNum()
                          Campo="I_LOCAL"
                     Else Campo="I_TPDESCTOUNIT"
                  EndIf
             Case Campo="I_TPDESCTOUNIT":
                  VSD_TPDESCTOUNIT=ControlValue("I_TPDESCTOUNIT")
                  If IsBlank(VSD_TPDESCTOUNIT)
                     Then VSD_TPDESCTOUNIT="I"
                  EndIf
                  If VSD_TPDESCTOUNIT="I"
                     Then Campo="I_TXDESCTOUNIT"
                     Else VSD_TXDESCTOUNIT=BlankNum()
                          Campo="I_COMIS_ITEM"
                  EndIf
             Case Campo="I_TXDESCTOUNIT":
                  VSD_TXDESCTOUNIT=ControlValue("I_TXDESCTOUNIT")
                  Campo="I_LOCAL"
             Case Campo="I_LOCAL":
                  VSD_LOCAL=ControlValue("I_LOCAL")
                  If IsBlank(VSD_LOCAL)
                     Then VSD_LOCAL="N"
                  EndIf
                  Campo="I_ALTERA_PRECO"
             Case Campo="I_ALTERA_PRECO":
                  VSD_ALTERA_PRECO=ControlValue("I_ALTERA_PRECO")
                  If IsBlank(VSD_ALTERA_PRECO)
                     Then VSD_ALTERA_PRECO="S"
                  EndIf
									Campo="I_IMPOSTOS"
             Case Campo="I_IMPOSTOS":
                  VSD_IMPOSTOS=ControlValue("I_IMPOSTOS")
                  If IsBlank(VSD_IMPOSTOS)
                     Then VSD_IMPOSTOS="S"
                  EndIf
                  Campo="I_IMPRESSAO"
             Case Campo="I_IMPRESSAO":
                  VSD_IMPRESSAO=ControlValue("I_IMPRESSAO")
                  Campo="I_GRAVACAO"
             Case Campo="I_GRAVACAO":
                  VSD_GRAVACAO=ControlValue("I_GRAVACAO")
                  Campo="I_TABPR_CLIENTE"
                  VSD_TABPR_CPAGTO = "N"
;                  Campo="I_TABPR_CPAGTO"
             Case Campo="I_TABPR_CPAGTO":
                  VSD_TABPR_CPAGTO=ControlValue("I_TABPR_CPAGTO")
                  If IsBlank(VSD_TABPR_CPAGTO)
                     Then VSD_TABPR_CPAGTO="N"
                  EndIf
                  Campo="I_TABPR_REPRES"
             Case Campo="I_TABPR_REPRES":
                  VSD_TABPR_REPRES=ControlValue("I_TABPR_REPRES")
                  If IsBlank(VSD_TABPR_REPRES)
                     Then VSD_TABPR_REPRES="N"
                  EndIf
                  Campo="I_TABPR_CLIENTE"
             Case Campo="I_TABPR_CLIENTE":
                  VSD_TABPR_CLIENTE=ControlValue("I_TABPR_CLIENTE")
                  If IsBlank(VSD_TABPR_CLIENTE)
                     Then VSD_TABPR_CLIENTE="N"
                  EndIf
                  Campo="I_EXIBE_CUSTO"
             Case Campo="I_EXIBE_CUSTO":
                  VSD_EXIBE_CUSTO=ControlValue("I_EXIBE_CUSTO")
                  If IsBlank(VSD_EXIBE_CUSTO) Then VSD_EXIBE_CUSTO="N" EndIf
                  Campo="I_UTILIZA_EMAIL"
             Case Campo="I_UTILIZA_EMAIL":
                  VSD_UTILIZA_EMAIL=ControlValue("I_UTILIZA_EMAIL")
                  If IsBlank(VSD_UTILIZA_EMAIL) Then VSD_UTILIZA_EMAIL="N" EndIf
                  ConfGeral("Confirma novos parametros ?")
                  If OK="S"
                     Then PARAM_OPCAO("Gravar")
                     Else If Chave=1
                             Then Del   ; Registro Novo
                             Else Undo  ; Registro Existente
                          EndIf
                  EndIf
                  Chave=9
                  AcceptDialog
           EndSwitch

      Case Evento["KeyCode"] = -81:
           If Campo<>"I_EMPRESA" And Chave=0
              Then ConfGeral("Confirma novos parametros?")
                   If OK="S"
                      Then PARAM_OPCAO("Gravar")
                   EndIf
                   PARAM_OPCAO("Inicio")
                   Campo="I_EMPRESA"
           EndIf
   EndSwitch
EndIf

TECLA="//Esc=Retornar  "
If Campo="I_EMPRESA" Or
   Campo="I_DESTINACAO" Or
   Campo="I_TABELA_PRECO" Or
   Campo="I_TRANSPORTADORA"
   Then TECLA=TECLA+"F1=Tabelas  "
EndIf

If Campo<>"I_EMPRESA" And Chave=0
   Then TECLA=TECLA+"Ctrl+Del=Excluir  PgDn=Finalizar  "
   else TECLA=TECLA+"                  PgDn=Finalizar  "
EndIf

MSGCAMPO="Utiliza este recurso? Sim/N„o"
Switch
  Case Campo="I_EMPRESA":
       MSGCAMPO="Codigo da Empresa Padr„o"
  Case Campo="I_DESTINACAO":
       MSGCAMPO="Codigo da Destina‡„o Padr„o"
  Case Campo="I_TABELA_PRECO":
       MSGCAMPO="Codigo da Tabela de Preco Padr„o"
  Case Campo="I_TRANSPORTADORA":
       MSGCAMPO="Codigo da Transportadora Padr„o"
  Case Campo="I_IMPRESSAO":
       MSGCAMPO="Script Utilizado na Impressao do Orcamento"
  Case Campo="I_GRAVACAO":
       MSGCAMPO="Script Utilizado na Gravacao do Orcamento"
  Case Campo="I_TABPR_CPAGTO":
       MSGCAMPO="Utilizar Pre‡o da Tabela conforme Cond.Pagto ? Sim/N„o"
  Case Campo="I_TABPR_CLIENTE":
       MSGCAMPO="Utilizar Pre‡o da Tabela conforme Cliente ? Sim/N„o"
  Case Campo="I_TABPR_REPRES":
       MSGCAMPO="Utilizar Pre‡o da Tabela conforme Representante? Sim/N„o"
  Case Campo="I_ALTERA_PRECO"    : 
       MSGCAMPO="Utiliza Altera‡„o do Pre‡o Unitario do Item? Sim/N„o/Permiss„o"
       
  Case Campo="I_DESCTO":
       MSGCAMPO="Utiliza Bloqueio Desconto Total? Sim/N„o/Permiss„o"
  Case Campo="I_TPDESCTO":
       MSGCAMPO="Qual Tipo Desconto Total? Informar/Condi‡„o Pagto"
  Case Campo="I_TXDESCTO":
       MSGCAMPO="Informe % M xima de Desconto Total Permitida"

  Case Campo="I_DESCTOUNIT":
       MSGCAMPO="Utiliza bloqueio desconto unit rio? Sim/N„o/Permiss„o"
  Case Campo="I_TPDESCTOUNIT":
       MSGCAMPO="Qual tipo desconto unit rio? Informar/Condi‡„o pagto/Produto"
  Case Campo="I_TXDESCTOUNIT":
       MSGCAMPO="Informe % m xima de desconto unit rio permitida"
  Case Campo="I_UTILIZA_EMAIL"   : 
       MSGCAMPO="Utiliza Email: (H)abilitado (D)esabilitado (N)Æo Utiliza Email"
EndSwitch

Monta_Prompt(MSGCAMPO,TECLA)

Return TEMP
EndProc   ;(Param_Dialog)

;*******************************************************************************
;* Rotina Gravacao ou Leitura dos Parametros                                   *
;*******************************************************************************
Proc PARAM_OPCAO(OP)
Private OP
Switch
  Case OP = "Gravar":
       Moveto [Codigo_Empresa]
       Locate VSD_EMPRESA
       [Codigo_Destinacao        ] = VSD_DESTINACAO
       [Tabela_Preco             ] = VSD_TABELA_PRECO
       [Codigo_Transportadora    ] = VSD_TRANSPORTADORA
       
       [Utiliza_Bloqueio_Descto  ] = VSD_DESCTO
       [Tipo_Bloqueio_Descto     ] = VSD_TPDESCTO
       [Taxa_Bloqueio_Descto     ] = VSD_TXDESCTO

       [Desconto Unitario        ] = VSD_DESCUNIT
       [Utiliza_Bloqueio_DesctoUn] = VSD_DESCTOUNIT
       [Tipo_Bloqueio_DesctoUn   ] = VSD_TPDESCTOUNIT
       [Taxa_Bloqueio_DesctoUn   ] = VSD_TXDESCTOUNIT
       
       [Utiliza_Local            ] = VSD_LOCAL
       [Impostos                 ] = VSD_IMPOSTOS
       [Script_Impressao         ] = VSD_IMPRESSAO
       [Script_Gravacao          ] = VSD_GRAVACAO
       [Pega_Preco_Tabela_CPagto ] = VSD_TABPR_CPAGTO
       [Utiliza_TabPreco_Cliente ] = VSD_TABPR_CLIENTE
       [Utiliza_TabPreco_Repres  ] = VSD_TABPR_REPRES
       [Exibe_Custo_Item_Consulta] = VSD_EXIBE_CUSTO
       [Utiliza_Alteracao_Preco  ] = VSD_ALTERA_PRECO
       [Utiliza_Email            ] = VSD_UTILIZA_EMAIL
       UnLockRecord

  Case OP = "Ler":
       VSD_EMPRESA         =[Codigo_Empresa           ]
       VSD_DESTINACAO      =[Codigo_Destinacao        ]
       VSD_TABELA_PRECO    =[Tabela_Preco             ]
       VSD_TRANSPORTADORA  =[Codigo_Transportadora    ]
       
       VSD_DESCTO        = [Utiliza_Bloqueio_Descto   ]
       VSD_TPDESCTO      = [Tipo_Bloqueio_Descto      ]
       VSD_TXDESCTO      = [Taxa_Bloqueio_Descto      ]

       VSD_DESCUNIT      = [Desconto Unitario         ]
       VSD_DESCTOUNIT    = [Utiliza_Bloqueio_DesctoUn ]
       VSD_TPDESCTOUNIT  = [Tipo_Bloqueio_DesctoUn    ]
       VSD_TXDESCTOUNIT  = [Taxa_Bloqueio_DesctoUn    ]
       
       VSD_LOCAL           =[Utiliza_Local            ]
       VSD_IMPOSTOS        =[Impostos                 ]
       VSD_IMPRESSAO       =[Script_Impressao         ]
       VSD_GRAVACAO        =[Script_Gravacao          ]
       VSD_TABPR_CPAGTO    =[Pega_Preco_Tabela_CPagto ]
       VSD_TABPR_CLIENTE   =[Utiliza_TabPreco_Cliente ]
       VSD_TABPR_REPRES    =[Utiliza_TabPreco_Repres  ]
       VSD_EXIBE_CUSTO     =[Exibe_Custo_Item_Consulta]
       VSD_ALTERA_PRECO    =[Utiliza_Alteracao_Preco  ]
       VSD_UTILIZA_EMAIL   =[Utiliza_Email            ]

  Case OP = "Inicio":
       VSD_DESTINACAO    =""
       VSD_TABELA_PRECO  =""
       VSD_TRANSPORTADORA=""
       VSD_DESCUNIT      =""
       VSD_LOCAL         =""
       VSD_IMPOSTOS      =""
       VSD_IMPRESSAO     =""
       VSD_GRAVACAO      =""
       VSD_TABPR_CPAGTO  ="N"
       VSD_TABPR_REPRES  ="N"
       VSD_TABPR_CLIENTE =""
       VSD_EXIBE_CUSTO   =""
       VSD_ALTERA_PRECO  =""
       VSD_DESCTO        = ""
       VSD_TPDESCTO      = ""
       VSD_TXDESCTO      = BlankNum()

       VSD_DESCUNIT      =""
       VSD_DESCTOUNIT    = ""
       VSD_TPDESCTOUNIT  = ""
       VSD_TXDESCTOUNIT  = BlankNum()

       VSD_UTILIZA_EMAIL =""
EndSwitch
If OP<>"Ler" Then Posiciona() EndIf
EndProc   ; (Param_Opcao)

;*******************************************************************************
;* Rotina Localiza_Registro                                                    *
;*******************************************************************************
Proc Chave()
Moveto [Codigo_Empresa]
Del
Locate VSD_EMPRESA
If RetVal
   Then While True
          If Not IsLockRecord() Then QuitLoop EndIf
        EndWhile
        Chave=0
        PARAM_OPCAO("Ler")
   Else Chave=1
        End Down
        [Codigo_Empresa]=VSD_EMPRESA
        PARAM_OPCAO("Inicio")
EndIf

EndProc  ; (Chave)

;*******************************************************************************
;* Rotina para posicionar registro                                             *
;*******************************************************************************
Proc Posiciona()
If IsBlank([Codigo_Empresa])
   Then Del
EndIf
Moveto [Codigo_Empresa]
End Down
EndProc    ;  (Posiciona)

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Autolib="\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Show"
If Not IsAssigned(SYS_EMPRESA_DEFAULT) Then SYS_EMPRESA_DEFAULT="" EndIf
VSD_EMPRESA=SYS_EMPRESA_DEFAULT
If Not Checa_Supervisor()
   Then Return
EndIf
CoEdit NoWindow "P_Orca"
Chave=8
INICIO_DIALOGO=True
PARAM_OPCAO("Inicio")
Posiciona()

Showdialog "Configura‡„o Or‡amento" Proc "Param_Dialog"
   Trigger "OPEN","ARRIVE"
    Key "F1","TAB","ReverseTab","ENTER","ESC","F4","ClearArea","PGDN"
     @ 01,00 height 22 width 80

   Label  @ 00,00 "Empresa" for "I_EMPRESA"
   Accept @ 01,01 Width 07 "A4" picture "#*#" Tag "I_EMPRESA" to VSD_EMPRESA

   Label  @ 00,10 "Destina‡„o" for "I_DESTINACAO"
   Accept @ 01,11 Width 06 "A3" picture "#*#" Tag "I_DESTINACAO" to VSD_DESTINACAO

   Label  @ 00,22 "Tabela Pre‡o" for "I_TABELA_PRECO"
   Accept @ 01,23 Width 08 "A5" picture "#*#" Tag "I_TABELA_PRECO" to VSD_TABELA_PRECO

   Label  @ 00,36 "Transportadora" for "I_TRANSPORTADORA"
   Accept @ 01,37 Width 07 "A4" picture "#*#" Tag "I_TRANSPORTADORA" to VSD_TRANSPORTADORA
   
   Label  @ 03,00 "[    ] Bloqueia Desconto Total" for "I_DESCTO"
   Accept @ 03,02 Width 04 "A1" picture "S,N,P" Tag "I_DESCTO" to VSD_DESCTO

   Label  @ 04,00 "[    ] Origem % Desconto Total" for "I_TPDESCTO"
   Accept @ 04,02 Width 04 "A1" picture "I,C" Tag "I_TPDESCTO" to VSD_TPDESCTO

   Label  @ 05,00 "[          ] % Desconto Total" for "I_TXDESCTO"
   Accept @ 05,02 Width 10 "N" picture "#*#.[####]" Tag "I_TXDESCTO" to VSD_TXDESCTO

   Label  @ 06,00 "[    ] Desconto Unitario" for "I_DESCUNIT"
   Accept @ 06,02 Width 04 "A1" picture "S,N" Tag "I_DESCUNIT" to VSD_DESCUNIT
   
   Label  @ 07,00 "[    ] Bloqueia Desconto Unit rio" for "I_DESCTOUNIT"
   Accept @ 07,02 Width 04 "A1" picture "S,N,P" Tag "I_DESCTOUNIT" to VSD_DESCTOUNIT

   Label  @ 08,00 "[    ] Origem % Desconto Unit rio" for "I_TPDESCTOUNIT"
   Accept @ 08,02 Width 04 "A1" picture "I,C,P" Tag "I_TPDESCTOUNIT" to VSD_TPDESCTOUNIT

   Label  @ 09,00 "[          ] % Desconto Unit rio" for "I_TXDESCTOUNIT"
   Accept @ 09,02 Width 10 "N" picture "#*#.[####]" Tag "I_TXDESCTOUNIT" to VSD_TXDESCTOUNIT

   Label  @ 10,00 "[    ] Local" for "I_LOCAL"
   Accept @ 10,02 Width 04 "A1" picture "S,N" Tag "I_LOCAL" to VSD_LOCAL
   
   Label  @ 11,00 "[    ] Altera Pre‡o Unit rio" for "I_ALTERA_PRECO"
   Accept @ 11,02 Width 04 "A1" picture "S,N,P" Tag "I_ALTERA_PRECO" to VSD_ALTERA_PRECO

   Label  @ 03,36 "[    ] Impostos" for "I_IMPOSTOS"
   Accept @ 03,38 Width 04 "A1" picture "S,N" Tag "I_IMPOSTOS" to VSD_IMPOSTOS

   Label  @ 04,36 "[           ] Script Impressao" for "I_IMPRESSAO"                               
   Accept @ 04,38 Width 11 "A8" picture "!*!" Tag "I_IMPRESSAO" to VSD_IMPRESSAO

   Label  @ 05,36 "[           ] Script Gravacao" for "I_GRAVACAO"
   Accept @ 05,38 Width 11 "A8" picture "!*!" Tag "I_GRAVACAO" to VSD_GRAVACAO

   Label  @ 06,36 "[    ] Utiliza Pre‡o Tab. Cond.Pagto" for "I_TABPR_CPAGTO"
   Accept @ 06,38 Width 4 "A1" picture "S,N" Tag "I_TABPR_CPAGTO" to VSD_TABPR_CPAGTO
   
   Label  @ 07,36 "[    ] Utiliza TabPreco Repres/Item" for "I_TABPR_REPRES"
   Accept @ 07,38 Width 4 "A1" picture "S,N" Tag "I_TABPR_REPRES" to VSD_TABPR_REPRES

   Label  @ 08,36 "[    ] Utiliza TabPreco Cliente/Item" for "I_TABPR_CLIENTE"
   Accept @ 08,38 Width 4 "A1" picture "S,N" Tag "I_TABPR_CLIENTE" to VSD_TABPR_CLIENTE

   Label  @ 09,36 "[    ] Exibe Custo no Item/Consulta" for "I_EXIBE_CUSTO"
   Accept @ 09,38 Width 4 "A1" picture "S,N" Tag "I_EXIBE_CUSTO" to VSD_EXIBE_CUSTO

   Label  @ 10,36 "[    ] Utiliza E-Mail" for "I_UTILIZA_EMAIL"
   Accept @ 10,38 Width 4 "A1" picture "H,D,N" Tag "I_UTILIZA_EMAIL" to VSD_UTILIZA_EMAIL

Enddialog
Do_It!
ClearAll
Release Vars All
Release Procs All
