;** Rm_0130 ********************************************************************
;*  Emissao dos Titulos Recebidos por Data de Pagamento                        *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 09/02/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro tipocarteira          
;Ultima Alteracao: 29/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de um tipo de carteira
;Ultima Alteracao: 04/02/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes agrupado RM_0130, RM_0135, RM_0360
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 11/02/2020 por Bruno Carvalho
;Motivo Alteracao: Ajustes de padroniza‡Æo nos campos [TG_CIDADE] e [TG_ESTADO]
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 05/05/2021 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro por Cobrador e modelo espec¡fico de relat¢rio 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll
If IsTable("\\Sistemas\\CtaRec\\"+Dir_Trab+"Duplic") And
   IsTable("\\Sistemas\\CtaRec\\"+Dir_Trab+"DupBaixa")
   Then 
        {Ask} {\\Sistemas\\Cadastro\\Destinat}
        Moveto [Codigo                 ] Example "cod"
        Moveto [Cidade                 ] TypeIn CIDADE
        Moveto [UF                     ] TypeIn "~VSDGESTADO.."
        Moveto [CGC                    ] Check
        Moveto [Codigo da Area         ] Check TypeIn "~VSDGAREA.."
        Moveto [Descricao da Area      ] Check

       {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
        Moveto [Numero do Lancamento   ] Example "lanc"
        Moveto [Codigo da Empresa      ] TypeIn "~VSDGEMPRESA2.."
        Moveto [Codigo do Representante] TypeIn "~VSDGREPRESEN.."
        Moveto [Codigo do Cobrador     ] TypeIn "~VSDGCOBRADOR.." 
        Switch
          Case VSDGOPDTCRB="2" :
               Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDTCRB="3" :
               Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
        switch
          case ListaRegra_VSDGTPPAGTO_Ativo : Moveto [Tipo do Pagamento      ] TypeIn ListaRegra_VSDGTPPAGTO
          case VSDGTPPAGTO<>""              : Moveto [Tipo do Pagamento      ] TypeIn "~VSDGTPPAGTO.." 
        endswitch
        switch
          case ListaRegra_VSDGTPCART_Ativo  : Moveto [Tipo do Lancamento     ] TypeIn ListaRegra_VSDGTPCART 
          otherwise                         : Moveto [Tipo do Lancamento     ] TypeIn "~VSDGTPCART.."
        endswitch
        Moveto [Codigo do Destinatario] Example "cod" TypeIn ", ~VSDGDESTINAT.."

        {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
        Moveto [Numero do Lancamento   ] Example "lanc"
        Moveto [Codigo da Conta        ] TypeIn "~VSDGCONTA.."
        Moveto [Tipo da Baixa          ] TypeIn "Blank or NORMAL"
        Switch
          Case VSDGOPDTCRB="1" :
               Moveto [Data do Pagamento ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDTCRB="4" :
               Moveto [Data_Inclusao     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
        
        Do_It!
        ClearAll
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela
Scan
  [Valor do Desconto-1]=([Valor do Desconto-1]*-1)+[Valor do Juros]
  If IsBlank([Valor do Desconto-1]) Then [Valor do Desconto-1]=0 EndIf
EndScan
Do_It!
ClearAll
EndProc  ; (Processa)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf   
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO" Or Campo="TG_TPCART"  
                                        Then ListaRegra_F2() 
                                     EndIf
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_AREA"          : Campo="TG_EMPRESATE"
            Case Campo="TG_CIDADE"        : Campo="TG_AREA"
            Case Campo="TG_ESTADO"        : Campo="TG_CIDADE"
            Case Campo="TG_REPRESEN"      : Campo="TG_ESTADO"
            Case Campo="TG_DESTINAT"      : Campo="TG_REPRESEN"
            Case Campo="TG_COBRADOR"      : Campo="TG_DESTINAT"
            Case Campo="TG_CONTA"         : Campo="TG_COBRADOR"
            Case Campo="TG_TPCART"        : Campo="TG_CONTA"    
            Case Campo="TG_TPPAGTO"       : Campo="TG_TPCART"        
            Case Campo="TG_OPDTCRB"       : Campo="TG_TPPAGTO"
            Case Campo="TG_DTINI"         : Campo="TG_OPDTCRB"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"  
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE" : Campo="TG_AREA"
                    Case Campo="TG_AREA"      : Campo="TG_CIDADE"
                    Case Campo="TG_CIDADE"    : Campo="TG_ESTADO"
                         If Upper(VSDGCIDADE)="TODAS"
                            Then CIDADE=""
                            Else CIDADE=VSDGCIDADE
                         EndIf
                    Case Campo="TG_ESTADO"    : Campo="TG_REPRESEN"     
                    Case Campo="TG_REPRESEN"  : Campo="TG_DESTINAT"
                    Case Campo="TG_DESTINAT"  : Campo="TG_COBRADOR"
                    Case Campo="TG_COBRADOR"  : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"     : Campo="TG_TPCART"
                    Case Campo="TG_TPCART"    : Campo="TG_TPPAGTO"    
                    Case Campo="TG_TPPAGTO"   : Campo="TG_OPDTCRB"        
                    Case Campo="TG_OPDTCRB"   : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"     : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"     : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO" : Campo="YES"  
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""
                         
;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial     
ModeloRelatoriosAdd("01  Por Cobrador/Data de Vencimento/EmissÆo/Documento")                            
ModeloRelatoriosAdd("12  Por Data de Pagamento/EmissÆo/Documento")                       
ModeloRelatoriosAdd("29  Por Data de EmissÆo/Documento")                       
ModeloRelatoriosAdd("55  Por µrea/Conta/Data InclusÆo")                       
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

VSDGEMPRESA =""
VSDGCIDADE  =""
VSDGESTADO  =""
CIDADE      =""
VSDGREPRESEN=""
VSDGCONTA   =""
VSDGAREA    =""
VSDGDESTINAT=""
VSDGTPCART  =""
VSDGTPPAGTO =""
VSDGOPDTCRB =""
VSDGCOBRADOR=""
VSDGNOMCOBRADOR=""
VSDGDTINI   =BlankDate()
VSDGDTFIM   =BlankDate()

ModeloRelatoriosCarregaLista()

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPPAGTO],[TG_TPCART]")       

While True

  ShowDialog "T¡tulos Recebidos por ?" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"  
    @ 01,00 Height 22 Width 80
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,01 "Area"  For "TG_AREA"
    Accept @ 03,03 Width 05 "A2"  Picture "#*#" Tag "TG_AREA" To VSDGAREA
    Accept @ 03,09 Width 25 "A30"  Picture "!*!" Tag "TG_NOMAREA" To VSDGNOMAREA

    Label  @ 04,00 "Cidade"  For "TG_CIDADE"
    Accept @ 05,01 Width 27 "A20"  Picture "!*!" Tag "TG_CIDADE"  To VSDGCIDADE
                                   
    Label  @ 04,27 "Estado"  For "TG_ESTADO"
    Accept @ 05,28 Width 06 "A2"  Picture "!*!" Tag "TG_ESTADO" To VSDGESTADO

    Label  @ 06,00 "Representante"  For "TG_REPRESEN"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_REPRESEN" To VSDGREPRESEN
    Accept @ 07,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMREPR" To VSDGNOMREPR

    Label  @ 08,01 "Pessoa"  For "TG_DESTINAT"
    Accept @ 09,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST
    
    Label  @ 10,00 "Cobrador"  For "TG_COBRADOR"
    Accept @ 11,01 Width 07 "A4"  Picture "#*#" Tag "TG_COBRADOR" To VSDGCOBRADOR
    Accept @ 11,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCOBRADOR"  To VSDGNOMCOBRADOR
    
    Label  @ 12,00 "Conta"  For "TG_CONTA"
    Accept @ 13,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 13,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 14,00 "Tipo de Carteira"  For "TG_TPCART"
    Accept @ 15,04 Width 04 "A1"  Picture "!" Tag "TG_TPCART"  To VSDGTPCART
    Accept @ 15,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCART" To VSDGNOMCART

    Label  @ 00,35 "Forma de Pagamento"  For "TG_TPPAGTO"
    Accept @ 01,38 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO
    Accept @ 01,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO

    Label  @ 02,35 "Op‡äes de Datas" For "TG_OPDTCRB"
    Accept @ 03,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPDTCRB" To VSDGOPDTCRB
    Accept @ 03,44 Width 25 "A20"  Picture "!*!" Tag "TG_NOMOPDTCRB" To VSDGNOMOPDTCRB

    Label  @ 04,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 05,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 05,51 "at‚" For "TG_DTFIM"
    Accept @ 05,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf
  
  If IsBlank(VSDGDTFIM)
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela)
       Then Add "Answer" Tabela
       Else Rename "Answer" Tabela
    EndIf
  EndWhile

  If IsEmpty(Tabela)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela
          Loop
  EndIf
  Processa()

  Switch
    Case VSDGCODMODELO="01"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "10" Tabela "R"
    
    Case VSDGCODMODELO="12"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "7" Tabela "R" 

    Case VSDGCODMODELO="29"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010" "10" Tabela "R" 

    Case VSDGCODMODELO="55"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1011" "4"  Tabela "R"

  EndSwitch
  IMPRIREL(Tabela,"R")

  Delete Tabela

EndWhile
ClearAll
Release Vars All
Release Procs Allrm_1011
