;** Rm_0010 ********************************************************************
;* Ficha de Formulas                                                           *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 04/04/2002 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes
;Ultima Alteracao: 12/05/2010 por Bruno Carvalho
;Motivo Alteracao: Adicionado em Rel. de F¢rmula "Venda a Praticar"  (Report 2)
;Ultima Alteracao: 12/12/2013 por Bruno Carvalho
;Motivo Alteracao: Adicionado no cabe‡alho o campo de Observa‡Æo nos Reports
;Ultima Alteracao: 19/12/2013 por Kamila Gomes
;Motivo Alteracao: Alterada exibi‡Æo do campo de Observa‡Æo nos Reports
;Ultima Alteracao: 19/09/2014 por Kamila Gomes
;Motivo Alteracao: Ajuste variaveis VSDGANO e VSDGMES
;Ultima Alteracao: 21/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog.                  
;Ultima Alteracao: 04/05/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ordem dos itens da formula   
;Ultima Alteracao: 24/03/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog   
;Ultima Alteracao: 20/05/2020 por Bruno Carvalho
;Motivo Alteracao: Alterado CopyReport "...\\Producao\\Formulai" p/ "...\\Producao\\RM_0041"
;Ultima Alteracao: 03/08/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes substitui‡Æo tpitem por tipoest
;Ultima Alteracao: 04/08/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado "Bib_Proc"
;Ultima Alteracao: 05/02/2021 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog, modelo report, quebra de pagina
;Ultima Alteracao: 18/02/2021 por Bruno Carvalho
;Motivo Alteracao: Adicionado modelo "04", onde ‚ informado apenas a referˆncia com o maior custo 
;Ultima Alteracao: 12/03/2021 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes destacar cor dos itens                          
;Ultima Alteracao: 15/03/2021 por Bruno Carvalho
;Motivo Alteracao: Ajustes p/ permitir mover para o campo da empresa quando VSDGOPCUSTO="F"   
;Ultima Alteracao: 08/04/2021 por Bruno Carvalho
;Motivo Alteracao: Adicionado Modelo "05" 

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona()
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item          ] typein "_it"
Ask_EstoqueTpItem("")
Moveto [Codigo da Familia       ] TypeIn "~VSDGFAMI.."
Moveto [Codigo do Grupo         ] TypeIn "~VSDGGRP.."
Moveto [Codigo da Marca         ] TypeIn "~VSDGMARCA.."
Moveto [Referencia              ] TypeIn "~VSDGREFERENCIA.."
Moveto [Codigo da Cor_Tecido    ] TypeIn "~VSDGCORTECIDO.."
{Ask} {FormulaC}       
Moveto [Codigo do Produto       ] check TypeIn "_it, ~VSDGITEM.., as \"PACodigo do Produto\""
Moveto [Descricao do Item       ] check typein "as \"PADescricao do Item\""
Moveto [Unidade Interna         ] check typein "as \"PAUnidade Interna\""
Moveto [Tipo do Item            ] check typein "as \"PATipo do Item\""
Moveto [Descricao Tipo do Item  ] check typein "as \"PADescricao Tipo do Item\""
Moveto [Quantidade Produzida    ] check typein "as \"PAQuantidade Produzida\""
Moveto [Custo Total             ] check typein "as \"PACusto Total\""
Moveto [Custo Unitario          ] check typein "as \"PACusto Unitario\""
Moveto [Baixa_Automatica        ] check typein "as \"PABaixa_Automatica\"" 
Moveto [Indice Preco de Venda   ] check typein "as \"PAIndice Preco de Venda\"" 
Moveto [Preco de Venda_Calculado] check typein "as \"PAPrecodeVenda_Calculado\"" 
Moveto [Preco de Venda_Livre    ] check typein "as \"PAPrecodeVenda_Livre\"" 
Moveto [Observacoes             ] check typein "as \"PAObservacoes\"" 
Moveto [Referencia              ] check typein "as \"PAReferencia\"" 
Moveto [ProducaoMaximaDia       ] check typein "as \"PAProducaoMaximaDia\"" 
{Ask} {FormulaI}       
Moveto [Codigo do Produto       ]       TypeIn "_it, ~VSDGITEM.."
Moveto [Sequencia               ] check typein "as \"MPSequencia\""
Moveto [Codigo do Material      ] check typein "as \"MPCodigo do Material\""
Moveto [Descricao do Item       ] check typein "as \"MPDescricao do Item\""
Moveto [Tipo do Item            ] check typein "as \"MPTipo do Item\""
Moveto [Descricao Tipo do Item  ] check typein "as \"MPDescricao Tipo do Item\""
Moveto [Unidade Interna         ] check typein "as \"MPUnidade Interna\""
Moveto [Quantidade              ] check typein "as \"MPQuantidade\""
Moveto [Valor Unitario          ] check typein "as \"MPValor Unitario\""
Moveto [Item_Baixa_Automatica   ] check typein "as \"MPItem_Baixa_Automatica\"" 
Moveto [Porc_Perda              ] check typein "as \"MPPorc_Perda\"" 
Do_It!      
ClearAll

If IsEmpty("Answer")
  Then return
endif          

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item          ] typein "_it"
Moveto [Codigo da Cor_Tecido    ] check typein "as \"PACodigoCor_Tecido\""
Moveto [Descricao da Cor_Tecido ] check typein "as \"PADescricaoCor_Tecido\""
{Ask} {Answer} Check 
Moveto [PACodigo do Produto     ] typein "_it!" 
Do_It!
ClearAll

{Ask} {\\Sistemas\\Estoque\\Itens}
Moveto [Codigo do Item          ] typein "_it"
Moveto [Codigo da Cor_Tecido    ] check typein "as \"MPCodigoCor_Tecido\""
Moveto [Descricao da Cor_Tecido ] check typein "as \"MPDescricaoCor_Tecido\""
{Ask} {Answer} Check 
Moveto [MPCodigo do Material    ] typein "_it!" 
Do_It!      
ClearAll         

MudaEstruturaDaTabelaPara("Answer","\\Base\\Sistemas\\Producao\\Rm_0041")

If VSDGOPCUSTO<>"F"
   Then 
        
        If IsTable("\\FechAno\\"+VSDGANO+"\\Estoque\\Sdestq") 
           Then TAB_TEMP = "\\FechAno\\"+VSDGANO+"\\Estoque\\Sdestq"
           Else TAB_TEMP = "\\Sistemas\\Estoque\\SdEstq"
        EndIf 
        
        View TAB_TEMP
        Coedit "Answer"
        Scan
          Moveto TAB_TEMP
          Moveto [Codigo da Empresa]
          Locate VSDGEMPRESA,[Answer->MPCodigo do Material],VSDGANO,VSDGMES
          If RetVal
             Then Switch
                    Case VSDGOPCUSTO="U": VRUNIT=[Preco de Custo]
                    Case VSDGOPCUSTO="M": VRUNIT=NDecimal([Custo Total Atual]/[Saldo Atual],5)
                  EndSwitch
             Else VRUNIT=BlankNum()
          EndIf
          Moveto "Answer"
          [MPValor Unitario]=VRUNIT
        EndScan
        Do_It!
        ClearAll
EndIf        

EndProc ; (Seleciona)

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog(Disparo,Campo,Evento,Elemento)
Temp=True
MSG_CAMPO=""
TECLA=""

If Disparo="OPEN"  
   Then AoCriarShowDialog()
        TiraSombraShowDialog()
EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] =   9: Temp=False
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_TIPOEST"        : Campo="NO"
            Case Campo="TG_FAMI"           : Campo="TG_TIPOEST"
            Case Campo="TG_GRP"            : Campo="TG_FAMI"
            Case Campo="TG_MARCA"          : Campo="TG_GRP"
            Case Campo="TG_COR_TECIDO"     : Campo="TG_MARCA"
            Case Campo="TG_ITEM"           : Campo="TG_COR_TECIDO"
            Case Campo="TG_REFERENCIA"     : Campo="TG_ITEM"
            Case Campo="TG_OPRELCODALF"    : Campo="TG_REFERENCIA"
            Case Campo="TG_QUEBRAPAGINA"   : Campo="TG_OPRELCODALF"
            Case Campo="TG_OPCUSTO"        : Campo="TG_QUEBRAPAGINA"
            Case Campo="TG_EMPRESA"        : Campo="TG_OPCUSTO"
            Case Campo="TG_MESANO"         : Campo="TG_EMPRESA"
            Case Campo="TG_CODMODELO"      : Campo="TG_OPCUSTO"
            Case Campo="YES" Or Campo="NO" : Campo="TG_EMPRESA"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_TIPOEST"    : Campo="TG_FAMI"
                    Case Campo="TG_FAMI"       : Campo="TG_GRP"
                    Case Campo="TG_GRP"        : Campo="TG_MARCA" 
                    Case Campo="TG_MARCA"      : Campo="TG_COR_TECIDO"
                    Case Campo="TG_COR_TECIDO" : Campo="TG_ITEM"
                    Case Campo="TG_ITEM"       : Campo="TG_REFERENCIA"
                    Case Campo="TG_REFERENCIA" : Campo="TG_OPRELCODALF"
                    Case Campo="TG_OPRELCODALF": Campo="TG_QUEBRAPAGINA"

                    Case Campo="TG_QUEBRAPAGINA"    : Campo="TG_OPCUSTO"
                         VSDGQUEBRAPAGINA=ControlValue("TG_QUEBRAPAGINA")
                         Switch
                           Case VSDGQUEBRAPAGINA="C": VSDGNOMQUEBRAPAGINA="COM QUEBRA"
                           OtherWise:
                                VSDGQUEBRAPAGINA="S"  VSDGNOMQUEBRAPAGINA="SEM QUEBRA"
                         EndSwitch

                    Case Campo="TG_OPCUSTO"    :
                         VSDGOPCUSTO=ControlValue("TG_OPCUSTO")
                         CAMPO="TG_EMPRESA"
                         Switch
                           Case VSDGOPCUSTO="U": VSDGNOMOPCUSTO="ULTIMO CUSTO"
                           Case VSDGOPCUSTO="M": VSDGNOMOPCUSTO="CUSTO MEDIO"
                           OtherWise:
                                VSDGOPCUSTO="F"  VSDGNOMOPCUSTO="CUSTO DA FORMULA"
                                VSDGMESANO=""
                               ;CAMPO="TG_CODMODELO"
                         EndSwitch
                    Case Campo="TG_EMPRESA"    : Campo="TG_MESANO"
                         If VSDGOPCUSTO="F"
                            Then VSDGMESANO=""
                                 CAMPO="TG_CODMODELO"
                         EndIf        
                    Case Campo="TG_MESANO"     :
                         VSDGMES=SubStr(VSDGMESANO,1,2)
                         VSDGANO=SubStr(VSDGMESANO,4,4)
                         If NumVal(VSDGANO) < 2000
                            Then VSDGANO=SubStr(VSDGANO,3,2)
                            Else VSDGANO=VSDGANO
                         EndIf
                         If NumVal(VSDGMES) > 12 Or NumVal(VSDGMES) = 0
                            Then MENSAGEM("Mˆs Inv lido!")
                                 Campo="TG_MESANO"
                            Else VSDGDTINI = DateVal("01."+VSDGMES+"."+VSDGANO)
                                 VSDGDTREF=Ultimo_Dia(VSDGMES+VSDGANO)
                                 If Month(VSDGDTREF)=Month(Today())
                                    Then VSDGDTREF=Today()
                                 EndIf
                                 Campo="TG_CODMODELO"
                         EndIf
                    Case Campo="TG_CODMODELO"  : Campo="YES"
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf
Switch
  Case Campo="TG_OPREL"  :
       MSG_CAMPO="Op‡”es: 1=Sem Custo  2=Com Custo"
  Case Campo="TG_OPCUSTO":
       MSG_CAMPO="M=M‚dio, U=éltimo, F=F¢rmula"
  Case Campo="TG_QUEBRAPAGINA":
       MSG_CAMPO="S=Sem quebra, C=Com quebra"
       
EndSwitch
Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp
EndProc   ;(Rotina)

;*******************************************************************************
;* Reagrupa o Grupo do Report de acordo com o informado afim de ordena‡Æo      *
;*******************************************************************************
Proc Seta_Ordem_Report(Tabela,NReport,Campo_ORIG,Campo_Novo,Ordem)
Private Tabela, NReport, Campo_ORIG, Campo_Novo, Ordem

;Tabela         = Tabela temporaria
;NReport        = Numero do Report (Ex: "8","R")
;Campo_ORIG     = Campo Original do Report
;Campo_Novo     = Campo a Ser Modificado para a ImpressÆo
;Ordem          = Ascendente/Descendente = Se ‚ forma Descendente, informe "D", senÆo, em branco, manter  a padrÆo Ascendente

Campo_Novo="{"+Campo_Novo+"}"

{Report} {Change} TypeIn Tabela Enter TypeIn NReport Enter Enter
 
While True  
  Linha=CursorLine()
  If Search("group ",Linha)>0  
     Then PosIni=SearchFrom("group ",Linha,1)
          Linha=Substr(Linha,PosIni+6,Len(Linha))
          If Search(chr(196),Linha)>0
             Then PosFim=SearchFrom(chr(196),Linha,1)
                  Linha=Substr(Linha,1,PosFim-1)
                  If Linha = Campo_ORIG
                     Then {Group} {Regroup} Enter {Field} Execute Campo_Novo
                          If Ordem="D"
                             Then {Group} {SortDirection} Enter {Descending}
                             Else {Group} {SortDirection} Enter {Ascending}
                          EndIf   
                          Do_It!
                          ClearAll
                          QuitLoop
                  EndIf 
          EndIf 
  EndIf         
  Down   
  If Search(chr(30)+"page",Linha)>0  
     Then Do_It!
          ClearAll
          QuitLoop
  EndIf   
EndWhile

EndProc ; Seta_Ordem_Report()

;*******************************************************************************
;* Pegar maior custo da referˆncia                                             *
;*******************************************************************************
Proc Pega_Referencia_MaiorCusto()
Private TabelaTemp

TabelaTemp=Cria_Temp(PrivDir())
Copy "Answer" TabelaTemp
  
{Ask} TypeIn TabelaTemp Enter
Moveto [PACodigo do Produto]       TypeIn "_Prod"
{Ask} {FormulaC}
Moveto [Codigo do Produto  ]       TypeIn "_Prod, Calc Max as Codigo do Produto"
Moveto [Referencia         ] Check    
Moveto [Custo Unitario     ]       TypeIn ">0, Calc Max"
Do_it!
ClearAll

{Ask} TypeIn TabelaTemp Enter Check
Moveto [PACodigo do Produto]       TypeIn "_Prod"
{Ask} {Answer}
Moveto [Codigo do Produto  ]       TypeIn "_Prod"  
Do_it!
ClearAll
          
EndProc ;Pega_Referencia_MaiorCusto()

;*******************************************************************************
;* Reagrupa o Grupo do Report de acordo com o informado afim de ordena‡Æo      *
;*******************************************************************************
Proc InserirQuebraPagina_Report(Tabela,NReport,Campo)
Private Tabela, NReport, Campo

;Tabela         = Tabela temporaria
;NReport        = Numero do Report (Ex: "8","R")
;Campo          = Campo grupo report

{Report} {Change} TypeIn Tabela Enter TypeIn NReport Enter Enter

While True  
  Linha=CursorLine()
  If Search("Group Header for "+Campo,bandinfo())>0 and Search("group "+Campo,Linha)>0 and Search(chr(196),Linha)>0  
     Then 
          DOWN INS Enter UP TypeIn "PAGEBREAK"
          Do_It!
          ClearAll
          QuitLoop
  EndIf         
  Down   
  If Search(chr(30)+"page",Linha)>0  
     Then Do_It!
          ClearAll
          QuitLoop
  EndIf   
EndWhile

EndProc ; Seta_Ordem_Report()

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial
ModeloRelatoriosAdd("01  Ficha de F¢rmula I - Sem Valores")
ModeloRelatoriosAdd("02  Ficha de F¢rmula II")
ModeloRelatoriosAdd("03  Ficha de F¢rmula II")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("04  Ficha de F¢rmula - Maior Custo por Referˆncia")
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("05  Ficha de F¢rmula - Maior Custo por Referˆncia - Pre‡o de Venda baseado na F¢rmula")
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()
sys_valor()

If Not IsAssigned(SYS_CLIENTE_CONFEC) Then SYS_CLIENTE_CONFEC = "" EndIf
If Not IsAssigned(NOMEMPRESA)         Then NOMEMPRESA = ""         EndIf

VSDGEMPRESA  = ""
VSDGTIPOEST  = ""
VSDGFAMI     = ""
VSDGGRP      = ""
VSDGMARCA    = ""
VSDGCORTECIDO= ""
VSDGOPRELCODALF = ""
VSDGMESANO   = ""
VSDGOPCUSTO  = ""
VSDGNOMOPREL = ""
VSDGNOMOPCUSTO=""
VSDGMES       =""
VSDGANO       =""
VSDGQUEBRAPAGINA=""
VSDGREFERENCIA=""

ModeloRelatoriosCarregaLista()

While True

  ShowDialog "Ficha de F¢rmulas" Proc "SD_Dialog"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC","TAB",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140  
    @ 01,00 Height 22 Width 80

    Label  @ 00,00 "Tipo do Estoque"  For "TG_TIPOEST"
    Accept @ 01,04 Width 04 "A1"  Picture "!" Tag "TG_TIPOEST" To VSDGTIPOEST
    Accept @ 01,09 Width 25 "A30"  Picture "!*!" Tag "TG_DESCTIPOEST" To VSDGDESCTIPOEST

    Label  @ 02,00 "Familia"  For "TG_FAMI"
    Accept @ 03,02 Width 06 "A3"  Picture "#*#" Tag "TG_FAMI"      To VSDGFAMI
    Accept @ 03,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMFAMI"   To VSDGNOMFAMI

    Label  @ 04,00 "Grupo"  For "TG_GRP"
    Accept @ 05,02 Width 06 "A3"  Picture "#*#" Tag "TG_GRP"       To VSDGGRP
    Accept @ 05,09 Width 25 "A25" Picture "!*!" Tag "TG_NOMGRP"    To VSDGNOMGRP

    Label  @ 06,00 "Marca" For "TG_MARCA"
    Accept @ 07,02 Width 06 "A3"  Picture "#*#" Tag "TG_MARCA" To VSDGMARCA
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_MARCA" To VSDGNOMMARCA

    Label  @ 08,00 "Cor" For "TG_COR_TECIDO"
    Accept @ 09,01 Width 07 "A4"  Picture "#*#" Tag "TG_COR_TECIDO"    To VSDGCORTECIDO
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCOR_TECIDO" To VSDGNOMCORTECIDO

    Label  @ 10,00 "Item"  For "TG_ITEM"
    Accept @ 11,01 Width 33 "A10" Picture "#*#" Tag "TG_ITEM"     To VSDGITEM
    Accept @ 12,01 Width 33 "A35" Picture "!*!" Tag "TG_NOMITEM" To VSDGNOMITEM

    Label  @ 10,13 "Referˆncia"  For "TG_REFERENCIA"
    Accept @ 11,13 Width 21 "A20" Picture "!*!" Tag "TG_REFERENCIA"     To VSDGREFERENCIA

    Label  @ 00,35 "Op‡„o de Ordem/Itens da Formula" For "TG_OPRELCODALF"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2" Tag "TG_OPRELCODALF" To VSDGOPRELCODALF
    Accept @ 01,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPRELCODALF" To VSDGNOMOPRELCODALF

    Label  @ 02,35 "Op‡„o quebra p gina por Formula" For "TG_QUEBRAPAGINA"
    Accept @ 03,39 Width 04 "A1"  Picture "S,C" Tag "TG_QUEBRAPAGINA" To VSDGQUEBRAPAGINA
    Accept @ 03,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMQUEBRAPAGINA" To VSDGNOMQUEBRAPAGINA

    Label  @ 04,35 "Op‡„o de Custo/Itens da Formula" For "TG_OPCUSTO"
    Accept @ 05,39 Width 04 "A1"  Picture "M,U,F" Tag "TG_OPCUSTO" To VSDGOPCUSTO
    Accept @ 05,44 Width 25 "A25"  Picture "!*!" Tag "TG_NOMOPCUSTO" To VSDGNOMOPCUSTO

    Label  @ 06,35 "Empresa"  For "TG_EMPRESA"
    Accept @ 07,36 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESA" To VSDGEMPRESA
    Accept @ 07,44 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 08,35 "Mˆs/Ano Estoque"  For "TG_MESANO"
    Accept @ 09,36  Width 10 "A07"  Picture "##.####" Tag "TG_MESANO" To VSDGMESANO

    Label  @ 17,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 18,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 18,06  Width 47 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO        

    Pushbutton @ 18,54 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 18,66 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf

  If Not IsBlank(VSDGMESANO)
     Then If IsBlank(VSDGEMPRESA)
             Then Mensagem("Informar Empresa p/ Ficha de Estoque !")
                  Loop
          EndIf
  EndIf
  
  If VSDGCODMODElO="05" And VSDGTIPOEST=""
     Then Mensagem("Informe o Tipo do Item para esse modelo de relat¢rio!")
          Loop
  EndIf             
                   
  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, gerando o relat¢rio")

  Seleciona()

  If IsEmpty("Answer")
     Then MENSAGEM("N„o existem registros a processar")
          Loop
  EndIf

  switch                                  
    case VSDGCODMODElO="01"  : CopyReport "\\Base\\Sistemas\\Producao\\RM_0041" "1" "Answer" "R"
    case VSDGCODMODElO="02"  : CopyReport "\\Base\\Sistemas\\Producao\\RM_0041" "R" "Answer" "R"
    case VSDGCODMODElO="03"  : CopyReport "\\Base\\Sistemas\\Producao\\RM_0041" "2" "Answer" "R"
    case VSDGCODMODElO="04"  : Pega_Referencia_MaiorCusto()
                               CopyReport "\\Base\\Sistemas\\Producao\\RM_0041" "2" "Answer" "R"
    case VSDGCODMODElO="05"  : RM_0010T = True
                               Play "RM_0010T"
                               If Not RM_0010T Then Loop EndIf  
                               
  endswitch

  If VSDGCODMODElO="01" Or
     VSDGCODMODElO="02" Or
     VSDGCODMODElO="03" Or
     VSDGCODMODElO="04"
     Then if VSDGOPRELCODALF="2"
             then Seta_Ordem_Report("Answer","R","MPCodigo do Material","MPDescricao do Item","C")
          endif   
          if VSDGQUEBRAPAGINA="C"
             then InserirQuebraPagina_Report("Answer","R","PACodigo do Produto")
          endif  
          IMPRIREL("Answer","R")
        
          Delete "Answer" 
  EndIf
  
EndWhile
ClearAll
Release Vars All
Release Procs All