;** Rm_0110 ********************************************************************
;*  Emissao dos Titulos Recebidos por Cliente                                  *
;*******************************************************************************
;Autor           : Vise Informatica (VISERP)
;Desenvolvido    : 05/12/1995 por Anivel Augusto Rodrigues
;Ultima Alteracao: 17/02/2004 por Anivel Augusto Rodrigues
;Motivo Alteracao: Mudan‡a Tabela Temporaria PrivDir()
;Ultima Alteracao: 13/01/2009 por Anivel Augusto Rodrigues
;Motivo Alteracao: TOTALIZA EMPRESAS
;Ultima Alteracao: 15/08/2012 por Bruno Carvalho
;Motivo Alteracao: Adicionado filtro "Tipo do Pagamento" 
;Ultima Alteracao: 14/02/2014 por Andrey Fillipe
;Motivo Alteracao: Adicionado Opcao de Relatorio 
;Ultima Alteracao: 15/10/2014 por Luis Gustavo
;Motivo Alteracao: Implementado filtro de Atividade e Reports que quebram por atividade
;Ultima Alteracao: 26/06/2015 por Bruno Carvalho
;Motivo Alteracao: Na proc Seleciona(), havia verifica‡Æo de Dir_Trab para a tabela Destinat
;Ultima Alteracao: 06/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 17/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes TG_EMPRESATE                 
;Ultima Alteracao: 26/12/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog
;Ultima Alteracao: 28/12/2016 por Rafael Matos
;Motivo Alteracao: Ajustes showdialog TG_DESTINAT                   
;Ultima Alteracao: 02/06/2017 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtro Conta
;Ultima Alteracao: 14/06/2017 por Bruno Carvalho
;Motivo Alteracao: Adicionado PARAM_CCLIEC -> Chamado pela Ficha do Cliente (C_CLIEC)
;Ultima Alteracao: 10/01/2020 por Bruno Carvalho                                     
;Motivo Alteracao: Adicionado scripts "RM_0110B" (70), "RM_0014" (85), "RM_0290" (27) neste script "RM_0110" (10)
;Ultima Alteracao: 31/01/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado processo para escolher mais de uma forma de pagamento 
;Ultima Alteracao: 04/02/2020 por Bruno Carvalho             
;Motivo Alteracao: Adicionado proc ListaRegra_Funcao(), onde foi ajustado ListaRegra_TGAtivado
;Ultima Alteracao: 05/02/2020 por Bruno Carvalho
;Motivo Alteracao: Adicionado ValidarModelosRelatorios()
;Ultima Alteracao: 06/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 29/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes filtrar op‡Æo de datas       
;Ultima Alteracao: 25/06/2021 por Bruno Carvalho
;Motivo Alteracao: Ajustes na quebra dos reports, para destacar o cliente e adicionado coluna de observacao da baixa  

;*******************************************************************************
;* Rotina p/ Selecionar e Ordernar Registros                                   *
;*******************************************************************************
Proc Seleciona_RM0110()
ClearAll

If IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"Duplic")   And
   IsTable("\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa") 
   Then 
        If VSDGCODMODELO="10A" Or VSDGCODMODELO="10B" Or VSDGCODMODELO="10C" Or VSDGCODMODELO="10D" Or VSDGCODMODELO="27" 
           Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter Check
           Else {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupliC" Enter 
        EndIf    
        Moveto [Numero do Lancamento  ] Example "lanc"
        Moveto [Codigo da Empresa     ] TypeIn "~VSDGEMPRESA2.."
        Switch
          Case VSDGOPDTCRB="2" :
               Moveto [Data de Vencimento] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDTCRB="3" :
               Moveto [Data de Emissao   ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
        Switch
          Case ListaRegra_VSDGTPPAGTO_Ativo  : Moveto [Tipo do Pagamento] TypeIn ListaRegra_VSDGTPPAGTO
          Otherwise                          : Moveto [Tipo do Pagamento] TypeIn "~VSDGTPPAGTO.."
        EndSwitch

        Switch
          Case VSDGCODMODELO="27"  :
               Moveto [Codigo do Destinatario  ]       TypeIn "~VSDGDESTINAT.."  

          Case VSDGCODMODELO="10A" Or VSDGCODMODELO="10B" Or VSDGCODMODELO="10C" Or VSDGCODMODELO="10D" :  
               Moveto [Codigo do Destinatario  ]       TypeIn "_Cod, ~VSDGDESTINAT.."

          Case VSDGCODMODELO="70" Or VSDGCODMODELO="85" :  
               Moveto [Codigo da Empresa       ] Check                
               Moveto [Codigo do Destinatario  ] Check TypeIn "~VSDGDESTINAT.."
               Moveto [Razao Social            ] Check
               Switch
                 Case VSDGCODMODELO="70" : 
                      Moveto [Tipo do Pagamento] TypeIn "CH or CP"

                 Case VSDGCODMODELO="85" : 
                      Moveto [Tipo do Pagamento] Check

               EndSwitch      
               Moveto [Nome Fantasia Empresa   ] Check
               Moveto [Codigo do Representante ] Check
               Moveto [Nome Fantasia EmitDest  ] Check
               Moveto [Tipo do Documento       ] Check
               Moveto [Numero do Documento     ] Check
               Moveto [Data de Emissao         ] Check        
               Moveto [Numero Lancamento Cheque] Check TypeIn "Not Blank" 
               Moveto [Data de Vencimento      ] Check   
        EndSwitch
        
        If VSDGCODMODELO="10A" Or VSDGCODMODELO="10B" Or VSDGCODMODELO="10C" Or VSDGCODMODELO="10D"
           Then {Ask} {\\Sistemas\\Cadastro\\Destinat} 
                Moveto [Codigo                ] TypeIn "_cod"
                Moveto [Codigo Atividade      ] TypeIn "~VSDGATIVIDADE.."
        EndIf               
        
        If VSDGCODMODELO="10A" Or VSDGCODMODELO="10B" Or VSDGCODMODELO="10C" Or VSDGCODMODELO="10D" Or VSDGCODMODELO="27" 
           Then {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter Check
                Moveto [Numero do Lancamento  ] Example "lanc"
           Else {Ask} TypeIn "\\Sistemas\\Ctarec\\"+Dir_Trab+"DupBaixa" Enter
                Moveto [Numero do Lancamento] Check Example "lanc"        
        EndIf
        Moveto [Codigo da Conta       ] TypeIn "~VSDGCONTA.."
        Moveto [Tipo da Baixa         ] TypeIn "Blank or NORMAL"
        Switch
          Case VSDGOPDTCRB="1" :
               Moveto [Data do Pagamento ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
          Case VSDGOPDTCRB="4" :
               Moveto [Data_Inclusao     ] TypeIn ">=~VSDGDTINI,<=~VSDGDTFIM"
        EndSwitch
        
        Switch
          Case VSDGCODMODELO="85" :
               Moveto [Sequencia da Baixa  ] Check
               Moveto [Data do Pagamento   ] Check 
               Moveto [Valor do Recebimento] Check
               Moveto [Valor do Desconto   ] Check
               Moveto [Valor do juros      ] Check
               Moveto [Valor da Comissao   ] Check TypeIn "as Valor da Comissao-1"
               Moveto [ObServacoes         ] Check
               
          Case VSDGCODMODELO="70" :     
               Moveto [Sequencia da Baixa  ] Check 
               Moveto [Data do Pagamento   ] Check 
               Moveto [Valor do Recebimento] Check
               Moveto [Valor do Desconto   ] Check
               Moveto [Valor do juros      ] Check
               Moveto [ObServacoes         ] Check
        EndSwitch
        Do_It!   
        ClearAll
        
        Switch
          Case VSDGCODMODELO="10A" Or VSDGCODMODELO="10B" Or VSDGCODMODELO="10C" Or VSDGCODMODELO="10D" : 
               {Ask} {Answer} 
               Moveto [Codigo CCusto   ] TypeIn "Changeto Blank" Down
               Moveto [Descricao CCusto] TypeIn "Changeto Blank" 
               Do_It!
               ClearAll
               
               Tabela_Aux=Cria_Temp(PrivDir())
               Copy "Answer" Tabela_Aux                              

               {Ask} {\\Sistemas\\Cadastro\\Destinat} 
               Moveto [Codigo                ] Check TypeIn "_Cod"
               Moveto [Codigo Atividade      ] Check 
               Moveto [Descricao Atividade   ] Check
               {Ask} TypeIn Tabela_Aux Enter
               Moveto [Codigo do Destinatario]       TypeIn "_Cod"
               Do_It!
               ClearAll
               
               {Ask} {Answer}
               Moveto [Codigo                ] TypeIn "_cod"
               Moveto [Codigo Atividade      ] TypeIn "_CodC" 
               Moveto [Descricao Atividade   ] TypeIn "_DesC"
               {Ask} TypeIn Tabela_Aux Enter
               Moveto [Codigo do Destinatario] TypeIn "_cod"
               Moveto [Codigo CCusto         ] TypeIn "Changeto _CodC"
               Moveto [Descricao CCusto      ] TypeIn "Changeto _DesC"
               Do_It!
               ClearAll
               
               Rename Tabela_Aux "Answer"
          
          Case VSDGCODMODELO="70" :     
               {Ask} Typein "\\Sistemas\\Cheqrec\\Chequei"  Enter
               Moveto [Numero do Lancamento     ] Example "Nche" 
               Moveto [Numero_Cheque            ] Check
               Moveto [Data Vencimento          ] Check
               Moveto [Valor                    ] Check
               Moveto [Codigo_Banco             ] Check
               {Ask} {Answer} Check
               Moveto [Numero Lancamento Cheque ] Example "Nche" TypeIn "!"
               Do_It!
               ClearAll
               
          Case VSDGCODMODELO="85" : 
               {Ask} Typein "\\Sistemas\\Cheqrec\\Chequei"  Enter
               Moveto [Numero do Lancamento     ] Example "Nche" 
               Moveto [Numero_Cheque            ] Check
               Moveto [Data Vencimento          ] Check
               Moveto [Data_Entrada             ] Example "dtpag"
               Moveto [Valor                    ] Check
               Moveto [Codigo_Banco             ] Check
               {Ask} {Answer} Check
               Moveto [Numero Lancamento Cheque ] Example "Nche"
               Moveto [Data do Pagamento        ] Example "dtpag"
               Do_It!
               ClearAll     
        EndSwitch       
EndIf
EndProc   ; (Seleciona)

;*******************************************************************************
;* Rotina p/ processar Db temporaria                                           *
;*******************************************************************************
Proc Processa_RM0110()

;***** Ajusta Dados ************************************
If VSDGEMPRESA="0000"
   Then {Ask} TypeIn Tabela2 Enter TypeIn "Fast"
        Moveto [Codigo da Empresa      ] TypeIn "changeto 0000"
        Moveto [Nome Fantasia Empresa  ] TypeIn "changeto TOTALIZA EMPRESAS"
        Do_It!
        ClearAll
EndIf

Coedit Tabela2
Scan
  If VSDGCODMODELO="70" Or VSDGCODMODELO="85" 
     Then [Valor do Desconto]=([Valor do Desconto]*-1)+[Valor do Juros]
          If IsBlank([Valor do Desconto]) Then [Valor do Desconto]=0 EndIf
     Else [Valor do Desconto-1]=([Valor do Desconto-1]*-1)+[Valor do Juros]
          If IsBlank([Valor do Desconto-1]) Then [Valor do Desconto-1]=0 EndIf
  EndIf        
EndScan
Do_It!
ClearAll   

Switch
  Case VSDGCODMODELO="70" :
       Sort Tabela2 On "Codigo da Empresa","Tipo do Documento","Numero do Documento","Sequencia da Baixa"

       EditKey 
       COD_EMP="*"
       Tip_Doc="*" 
       Num_Doc="*"
       Seq_Baix="*"
       Scan
       If [Codigo da Empresa  ]=COD_EMP  and 
          [Tipo do Documento  ]=Tip_Doc  and
          [Numero do Documento]=Num_Doc       
          Then 
               If [Sequencia da Baixa ]<>Seq_Baix            
                  Then seq=seq+1
                  Else [Data do Pagamento      ]=Blankdate()                  
                       [Valor do Recebimento   ]=Blanknum()
                       [Valor do Desconto      ]=Blanknum()
                       [Valor do juros         ]=Blanknum()
               EndIf    
               [Data de Emissao        ]=Blankdate()
               [Numero do Lancamento   ]=""
               [Codigo do Representante]="" 
                     
               If Seq>0
                  Then [Data Vencimento        ]=Blankdate()
                       [Data de Vencimento     ]=Blankdate()
                       [Codigo_Banco           ]=""
                       [Numero_Cheque          ]=""
                       [Valor                  ]=Blanknum()
               EndIf   
      
          else
               COD_EMP = [Codigo da Empresa  ]  
               Tip_Doc = [Tipo do Documento  ] 
               Num_Doc = [Numero do Documento] 
               Seq_Baix= [Sequencia da Baixa ]
               Seq     = 0            
       EndIF 
       EndScan
       Do_It!
       ClearAll
  
  Case VSDGCODMODELO="85" : 
       Sort Tabela2 On "Codigo da Empresa","Tipo do Documento","Numero do Documento","Sequencia da Baixa"
        
       CoEditKey 
       COD_EMP="***"
       TIP_DOC="***" 
       NUM_DOC="***"
       SEQ_BAIX="***"
       Scan
         [Valor da Comissao-1] = [Data Vencimento]-[Data de Vencimento]
         If [Codigo da Empresa  ]=COD_EMP  And 
            [Tipo do Documento  ]=TIP_DOC  And
            [Numero do Documento]=NUM_DOC       
            Then If [Sequencia da Baixa ]=SEQ_BAIX            
                    Then [Data de Emissao         ] = BlankDate()
                         [Data do Pagamento       ] = BlankDate()
                         [Valor do Recebimento    ] = BlankNum()
                         [Valor do Desconto       ] = BlankNum()
                         [Valor do Juros          ] = BlankNum()
                         [Numero do Lancamento    ] = ""
                         [Codigo do Representante ] = ""
                         [Data de Vencimento      ] = BlankDate()
                 EndIf
            Else COD_EMP = [Codigo da Empresa  ]  
                 TIP_DOC = [Tipo do Documento  ] 
                 NUM_DOC = [Numero do Documento] 
                 SEQ_BAIX= [Sequencia da Baixa ]
         EndIf
       EndScan
       Do_It!
       ClearAll
EndSwitch

EndProc ;Processa_RM0110()

;*******************************************************************************
;* Rotina                                                                      *
;*******************************************************************************
Proc SD_Dialog_RM0110(Disparo,Campo,Evento,Elemento)
Temp=True
TECLA    =""
MSG_CAMPO=""
If Disparo="OPEN"  Then AoCriarShowDialog() EndIf
If Disparo="EVENT" And Evento["Type"]="KEY" Then
   Switch
     Case Evento["KeyCode"] = -59: Dialog_F1()
     Case Evento["KeyCode"] = -60 Or 
          Evento["KeyCode"] = "F2" : If Campo="TG_TPPAGTO"                      
                                        Then ListaRegra_F2() 
                                     EndIf     
     Case Evento["KeyCode"] =  27:
          Temp=False
          Switch
            Case Campo="TG_EMPRESATE"     : Campo="NO"
            Case Campo="TG_CONTA"         : Campo="TG_EMPRESATE"
            Case Campo="TG_DESTINAT"      : Campo="TG_CONTA"
            Case Campo="TG_ATIVIDADE"     : If PARAM_CCLIEC
                                              Then Campo="TG_CONTA"
                                              Else Campo="TG_DESTINAT"
                                            EndIf   
            Case Campo="TG_TPPAGTO"       : Campo="TG_ATIVIDADE"
            Case Campo="TG_OPDTCRB"       : Campo="TG_TPPAGTO"
            Case Campo="TG_DTINI"         : Campo="TG_OPDTCRB"
            Case Campo="TG_DTFIM"         : Campo="TG_DTINI"
            Case Campo="TG_CODMODELO"     : Campo="TG_DTFIM"
            Case Campo="YES" Or Campo="NO": Campo="TG_EMPRESATE"
          EndSwitch
     Case (Evento["KeyCode"] <= -104 And Evento["KeyCode"] >= -113) Or 
           Evento["KeyCode"]  = -139 Or  Evento["KeyCode"]  = -140:
           SYS_TECLA_ACIONADA=Evento["KeyCode"]
           Seta_Tecla_Acionada()
           CancelDialog
     Case Evento["KeyCode"] = 13:
          Temp=False
          If Checa_TAG()
             Then Switch
                    Case Campo="TG_EMPRESATE"  : Campo="TG_CONTA"
                    Case Campo="TG_CONTA"      : If PARAM_CCLIEC
                                                    Then Campo="TG_ATIVIDADE"
                                                    Else Campo="TG_DESTINAT"
                                                 EndIf    
                    Case Campo="TG_DESTINAT"   : Campo="TG_ATIVIDADE" 
                    Case Campo="TG_ATIVIDADE"  : Campo="TG_TPPAGTO"
                    Case Campo="TG_TPPAGTO"    : Campo="TG_OPDTCRB"
                    Case Campo="TG_OPDTCRB"    : Campo="TG_DTINI"
                    Case Campo="TG_DTINI"      : Campo="TG_DTFIM"
                    Case Campo="TG_DTFIM"      : Campo="TG_CODMODELO"
                    Case Campo="TG_CODMODELO"  : Campo="YES"       
                  EndSwitch
          EndIf
          RefreshDialog
   EndSwitch
EndIf

Monta_Prompt(MSG_CAMPO,TECLA)
Return Temp

EndProc

;************************************
;* ROTINA PARA Ler/Gravacao Opcao   *
;************************************
Proc ModeloRelatoriosCarregaLista()

VSDGCODMODELO     = ""
VSDGMODELO        = ""

;ModeloRelatoriosAdd("XXX XX maximo 70 XX")

ModeloRelatoriosAdd("Criar") ; linha obrigatoria inicial                                 
ModeloRelatoriosAdd("10A Data Pagamento Com Hist¢rico/Simples")                 ;RM_0110
ModeloRelatoriosAdd("10B Data Pagamento Sem Hist¢rico/Simples")                 ;RM_0110
ModeloRelatoriosAdd("Separator")
ModeloRelatoriosAdd("10C Data Pagamento Com Hist¢rico/Por Atividade")           ;RM_0110
ModeloRelatoriosAdd("10D Data Pagamento Sem Hist¢rico/Por Atividade")           ;RM_0110
ModeloRelatoriosAdd("Separator")   
ModeloRelatoriosAdd("70  Data Pagamento/Cheque")                                ;RM_0110B
ModeloRelatoriosAdd("85  Com cheque na baixa")                                  ;RM_0014
ModeloRelatoriosAdd("27  Data de EmissÆo")                                      ;RM_0290
ModeloRelatoriosAdd("Fim")
                           
EndProc ;ModeloRelatoriosCarregaLista   

;*******************************************************************************
;* ROTINA PRINCIPAL                                                            *
;*******************************************************************************
AutoLib="\\Sistemas\\Cadastro\\Bib_Show,\\Sistemas\\Cadastro\\Bibliot,\\Sistemas\\Cadastro\\Bib_Proc"
LimpAguarde()

;PARAM_CCLIEC -> Chamado da Ficha do Cliente 
If Not IsAssigned(PARAM_CCLIEC) Then PARAM_CCLIEC = False EndIf

If Not PARAM_CCLIEC
   Then VSDGEMPRESA   =""
        VSDGDESTINAT  =""
EndIf        

VSDGCONTA     =""
VSDGATIVIDADE =""
VSDGOPRELHIST   =""
VSDGOPDTCRB =""
VSDGDTINI  =BlankDate()                       
VSDGDTFIM  =BlankDate()

ModeloRelatoriosCarregaLista()

ListaRegra_Funcao("ListaRegra_TGAtivado","[TG_TPPAGTO]")      

While True
  ShowDialog "T¡tulos Recebidos por Cliente" Proc "SD_Dialog_RM0110"
  Trigger "OPEN","ARRIVE"
  Key "F1","ENTER","ESC",
      -104, -105, -106, -107, -108, -109, -110, -111, -112, -113, -139, -140, -60, "F2"   
   @ 05,12   Height 18 Width 72
   
    Label  @ 00,00 "Empresa"  For "TG_EMPRESATE"
    Accept @ 01,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_EMPRESATE" To VSDGEMPRESA
    Accept @ 01,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMEMP" To VSDGNOMEMP

    Label  @ 02,00 "Conta"  For "TG_CONTA"
    Accept @ 03,01 Width 07 "A4"  Picture "#*#" Tag "TG_CONTA" To VSDGCONTA
    Accept @ 03,09 Width 25 "A30" Picture "!*!" Tag "TG_NOMCONT" To VSDGNOMCONTA

    Label  @ 04,00 "Pessoa"  For "TG_DESTINAT"
    Accept @ 05,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_DESTINAT" To VSDGDESTINAT
    Accept @ 05,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMCLI" To VSDGNOMDEST
    
    Label  @ 06,00 "Atividade"  For "TG_ATIVIDADE"
    Accept @ 07,01 Width 07 "A4"  Picture "[&,#][#*#]" Tag "TG_ATIVIDADE" To VSDGATIVIDADE
    Accept @ 07,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMATIV" To VSDGNOMATIV

    Label  @ 08,00 "Forma de Pagamento"  For "TG_TPPAGTO"                                                
    Accept @ 09,03 Width 05 "A2"  Picture "!*!" Tag "TG_TPPAGTO"    To VSDGTPPAGTO                            
    Accept @ 09,09 Width 25 "A20" Picture "!*!" Tag "TG_NOMTPPG"    To VSDGNOMTPPAGTO
    
    Label  @ 00,35 "Op‡äes de Datas" For "TG_OPDTCRB"
    Accept @ 01,39 Width 04 "A1"  Picture "1,2,3,4" Tag "TG_OPDTCRB" To VSDGOPDTCRB
    Accept @ 01,44 Width 25 "A20"  Picture "!*!" Tag "TG_NOMOPDTCRB" To VSDGNOMOPDTCRB

    Label  @ 02,35 "Per¡odo Referente de" For "TG_DTINI"
    Accept @ 03,38 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTINI" To VSDGDTINI
    Label  @ 03,51 "at‚" For "TG_DTFIM"
    Accept @ 03,56 Width 13 "D"  Picture "#[#];.##;.##[##]" Tag "TG_DTFIM" To VSDGDTFIM

    Label  @ 11,00  "Modelo de ~R~elat¢rio"  For "TG_CODMODELO"
    Accept @ 12,01  Width 06 "A3"  Picture "!*!" Tag "TG_CODMODELO" To VSDGCODMODELO
    Accept @ 12,06  Width 63 "A60"  Picture "!*!" Tag "TG_MODELO" To VSDGMODELO

    Pushbutton @ 14,22 width 11 "~O~k"      OK     Default Value "Ok" Tag "YES" To BottonValue
    Pushbutton @ 14,36 width 11 "~C~ancela" CANCEL                    Tag "NO"  To BottonValue

  EndDialog
  If Not RetVal Then QuitLoop EndIf
  If Not Valida_ShowDialog("") Then Loop EndIf
  If Not ValidarModelosRelatorios() Then Loop EndIf
  
  If PARAM_CCLIEC And VSDGDESTINAT <> VSDGDESTINAT2
     Then Mensagem("Cliente informado ‚ diferente desta ficha!")
          Loop
  EndIf        

  If VSDGDTFIM=BlankDate()
     Then Mensagem("Data Final Invalida !")
          Loop
  EndIf

  If VSDGEMPRESA="0000"
     Then VSDGEMPRESA2=""
     Else VSDGEMPRESA2=VSDGEMPRESA
  EndIf

  DISPOSITIVO()
  If OK="" Then Loop EndIf

  AGUARDE("Aguarde, Processando Dados")
  Tabela2=Cria_Temp(PrivDir())

  Monta_Dir_Trab(VSDGDTINI,VSDGDTFIM)
  While Novo_Dir_Trab()
    If IsTable("Answer")     Then Delete "Answer" EndIf
    Seleciona_RM0110()
    If Not IsTable("Answer") Then Loop EndIf
    If IsTable(Tabela2)
       Then Add "Answer" Tabela2
       Else Rename "Answer" Tabela2
    EndIf
  EndWhile

  If IsEmpty(Tabela2)
     Then MENSAGEM("N„o existem registros a processar")
          Delete Tabela2
          Loop
  EndIf
  Processa_RM0110()
  
  Switch
    Case VSDGCODMODELO="10A" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010" "12" Tabela2 "R"
    Case VSDGCODMODELO="10B" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010" "9"  Tabela2 "R"
    Case VSDGCODMODELO="10C" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "5" Tabela2 "R"
    Case VSDGCODMODELO="10D" : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010a" "4" Tabela2 "R"
    Case VSDGCODMODELO="70"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010b" "R" Tabela2 "R"
    Case VSDGCODMODELO="85"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010b" "R" Tabela2 "R"
    Case VSDGCODMODELO="27"  : CopyReport "\\Base\\Sistemas\\CtaRec\\Rm_1010" "11" Tabela2 "R" 
  EndSwitch
  IMPRIREL(Tabela2,"R")
  Delete Tabela2

EndWhile
ClearAll

If PARAM_CCLIEC
   Then Release Vars VSDGEMPRESA,VSDGEMPRESA2,VSDGNOMEMP,VSDGCONTA,VSDGNOMCONTA,VSDGATIVIDADE,VSDGNOMATIV,
                     VSDGOPRELHIST,VSDGNOMOPRELHIST,VSDGDTINI,VSDGDTFIM,VSDGTPPAGTO,VSDGNOMTPPAGTO,VSDGOPREL,
                     VSDGNOMOPREL,Seq,COD_EMP,Tip_Doc,Num_Doc,Seq_Baix
        Release Procs Seleciona_RM0110,Processa_RM0110,SD_Dialog_RM0110
   Else Release Vars All
        Release Procs All
EndIf             
