;** RC_0090C ******************************************************************
;*  Relatorio de Itens por C.S.T                                               *
;*******************************************************************************
;Autor: Visao/Vise
;Desenvolvido    : 09/06/2010 por Bruno Carvalho
;Ultima Alteracao: 11/07/2011 por Karina Andrade
;Motivo Alteracao: Add Opcao 3 = CST/Imposto/Aliquota
;Ultima Alteracao: 18/09/2016 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes showdialog                   
;Ultima Alteracao: 13/04/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes Agrupado RC_0090, substituido RC_0140 
;Ultima Alteracao: 30/07/2020 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes ask tipo do item nova fun‡Æo
;Ultima Alteracao: 16/07/2021 por Anivel Augusto Rodrigues
;Motivo Alteracao: Ajustes VSDGSTATUS

;*******************************************************************************
;* Rotina p/ Selecionar e Order Registros                                      *
;*******************************************************************************
Proc RC_0090C_SELECIONA()
ClearAll

{Ask} {Itens} Check
moveto [Codigo do Item      ] typein "_coditem!"
Ask_EstoqueTpItem("")
Moveto [Codigo da Familia   ] TypeIn "~VSDGFAMI.."
Moveto [Codigo do Grupo     ] TypeIn "~VSDGGRP.."
Moveto [Codigo da Marca     ] TypeIn "~VSDGMARCA.."
Moveto [Codigo da Cor_Tecido] TypeIn "~VSDGCORTECIDO.."
Moveto [Referencia          ] TypeIn "~VSDGREFERENCIA.."
if search("..",VSDGLOCAL)>0
   then Moveto [Localizacao         ] TypeIn VSDGLOCAL
   else Moveto [Codigo_Localizacao  ] TypeIn "~VSDGLOCAL.."
endif   
Switch
  Case VSDGSTATUS="INATIVO" : Moveto [Inativo] TypeIn "S"
  Case VSDGSTATUS="ATIVO"   : Moveto [Inativo] TypeIn "Not S"
EndSwitch     
Moveto [Tipo Codigo_Barras]
If CDBAR <> ""
   Then TypeIn CDBAR
EndIf
Moveto [Codigo do Departamento] TypeIn "~VSDGDEPART.."
Moveto [NCM                   ] TypeIn "~VSDGNCM.."
Moveto [Tipo Tributacao       ] TypeIn "~VSDGTPTRIBUT.."

{Ask} {Iten_Com} Check
moveto [Codigo do Item      ] Check typein "_coditem"
Do_It!
ClearAll

if not isblank(VSDGCOMPTECIDO) and VSDGCOMPTECIDO<>".."
   then 
        {Ask} {Answer} Check
        moveto [Codigo do Item      ]       typein "_coditem"
        {Ask} {Iten_Tec} Check
        moveto [Codigo do Item      ] Check typein "_coditem"
        Moveto [Composicao          ]       TypeIn VSDGCOMPTECIDO
endif
Do_It!
ClearAll

{Ask} {Answer} Check
Moveto [Tipo Tributacao     ] Example "tribut"
{Ask} {Tptribut} Check
Moveto [Tipo Tributacao     ] Example "tribut"
Do_It!
ClearAll

{Modify} {Restructure} {Answer}
Moveto [Field Name]
End Down
"Descricao Tributacao ICMS"       Enter  "A25"  Enter
Do_IT!
ClearAll

CoEdit "Answer"
Scan
Switch 
    Case [Tributacao de ICMS]="D" : [Descricao Tributacao ICMS]="DEBITADO"
    Case [Tributacao de ICMS]="I" : [Descricao Tributacao ICMS]="ISENTO"
    Case [Tributacao de ICMS]="O" : [Descricao Tributacao ICMS]="OUTROS" 
    Case [Tributacao de ICMS]="N" : [Descricao Tributacao ICMS]="NAO TRIBUTARIA"
    Case [Tributacao de ICMS]="S" : [Descricao Tributacao ICMS]="SUBSTITUICAO"
EndSwitch
EndScan
Do_It!
ClearAll

EndProc

;*******************************************************************************
;* Rotina Principal                                                            *
;*******************************************************************************
Proc RC_0090C_Principal()

AGUARDE("Aguarde, gerando o relat¢rio")

RC_0090C_Seleciona()

If IsEmpty("Answer")
   Then 
        MENSAGEM("N„o existem registros a processar")
   else
        Switch
          Case VSDGCODMODELO="18" : CopyReport "\\Base\\Sistemas\\Estoque\\Rc_0140" "R" "Answer" "R" 
          Case VSDGCODMODELO="18A": CopyReport "\\Base\\Sistemas\\Estoque\\Rc_0140" "1" "Answer" "R"
          Case VSDGCODMODELO="18B": CopyReport "\\Base\\Sistemas\\Estoque\\Rc_0140" "2" "Answer" "R"
        EndSwitch
        IMPRIREL("Answer","R")
EndIf
;;Delete Tabela

EndProc

;-- Chamada principal ----------------------------------------------------------
RC_0090C_Principal()

Release Vars Tabela      
Release Procs RC_0090C_Principal, RC_0090C_Seleciona
